configure.ac

   1 AC_PREREQ(2.60)
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, git and prerelease does Werror too
   6 AC_INIT(GStreamer, 0.10.29.1,
   7     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
   8     gstreamer)
   9 AG_GST_INIT
  10
  11 dnl initialize automake (we require GNU make)
  12 AM_INIT_AUTOMAKE([-Wno-portability])
  13
  14 dnl define PACKAGE_VERSION_* variables
  15 AS_VERSION
  16
  17 dnl check if this is a release version
  18 AS_NANO(GST_GIT="no", GST_GIT="yes")
  19
  20 dnl can autoconf find the source ?
  21 AC_CONFIG_SRCDIR([gst/gst.c])
  22
  23 dnl define the output header for config
  24 AM_CONFIG_HEADER([config.h])
  25
  26 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  27 AM_MAINTAINER_MODE
  28
  29 dnl sets host_* variables
  30 AC_CANONICAL_HOST
  31
  32 dnl use pretty build output with automake >= 1.11
  33 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  34   [AM_DEFAULT_VERBOSITY=1
  35    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  36
  37 dnl our libraries and install dirs use major.minor as a version
  38 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  39 dnl we override it here for release candidates for a new series
  40 GST_MAJORMINOR=0.10
  41 AC_SUBST(GST_MAJORMINOR)
  42 AC_DEFINE_UNQUOTED(GST_MAJORMINOR, "$GST_MAJORMINOR",
  43   [library major.minor version])
  44
  45 dnl CURRENT, REVISION, AGE
  46 dnl - library source changed -> increment REVISION
  47 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  48 dnl - interfaces added -> increment AGE
  49 dnl - interfaces removed -> AGE = 0
  50 dnl sets GST_LT_LDFLAGS
  51 AS_LIBTOOL(GST, 25, 0, 25)
  52
  53 dnl FIXME: this macro doesn't actually work;
  54 dnl the generated libtool script has no support for the listed tags.
  55 dnl So this needs to be fixed first if we want to use this
  56 dnl AS_LIBTOOL_TAGS
  57
  58 AC_LIBTOOL_WIN32_DLL
  59 AM_PROG_LIBTOOL
  60
  61 dnl *** autotools stuff ****
  62
  63 dnl allow for different autotools
  64 AS_AUTOTOOLS_ALTERNATE
  65
  66 dnl Add parameters for aclocal (keep in sync with Makefile.am)
  67 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  68
  69 dnl set up gettext
  70 dnl the version check needs to stay here because autopoint greps for it
  71 AM_GNU_GETTEXT_VERSION([0.17])
  72 AM_GNU_GETTEXT([external])
  73 AG_GST_GETTEXT([gstreamer-$GST_MAJORMINOR])
  74
  75 dnl *** check for arguments to configure ***
  76
  77 dnl subsystems - can influence other decisions so needs to be high up
  78 dnl we need to AM_CONDITIONAL them here for automake 1.6.x compatibility
  79 AG_GST_CHECK_SUBSYSTEM_DISABLE(GST_DEBUG,[debugging subsystem])
  80 AM_CONDITIONAL(GST_DISABLE_GST_DEBUG, test "x$GST_DISABLE_GST_DEBUG" = "xyes")
  81 AG_GST_CHECK_SUBSYSTEM_DISABLE(LOADSAVE,[pipeline XML load/save])
  82 AM_CONDITIONAL(GST_DISABLE_LOADSAVE, test "x$GST_DISABLE_LOADSAVE" = "xyes")
  83 dnl define a substitution to use in docs/gst/gstreamer.types
  84 if test "x$GST_DISABLE_LOADSAVE" = "xyes"
  85 then
  86   GST_LOADSAVE_DOC_TYPES="%"
  87 else
  88   GST_LOADSAVE_DOC_TYPES=
  89 fi
  90 AC_SUBST(GST_LOADSAVE_DOC_TYPES)
  91 AG_GST_CHECK_SUBSYSTEM_DISABLE(PARSE,[command-line parser])
  92 AM_CONDITIONAL(GST_DISABLE_PARSE, test "x$GST_DISABLE_PARSE" = "xyes")
  93 if test "x$GST_DISABLE_PARSE" = xyes; then
  94   AC_DEFINE(GST_DISABLE_PARSE, 1,
  95     [Define if pipeline parsing code is disabled])
  96 fi
  97 AG_GST_CHECK_SUBSYSTEM_DISABLE(OPTION_PARSING,[option parsing when gst_init])
  98 AM_CONDITIONAL(GST_DISABLE_OPTION_PARSING, test "x$GST_DISABLE_OPTION_PARSING" = "xyes")
  99 if test "x$GST_DISABLE_OPTION_PARSING" = xyes; then
 100   AC_DEFINE(GST_DISABLE_OPTION_PARSING, 1,
 101     [Define if option parsing is disabled])
 102 fi
 103 AG_GST_CHECK_SUBSYSTEM_DISABLE(TRACE,[tracing subsystem])
 104 AM_CONDITIONAL(GST_DISABLE_TRACE, test "x$GST_DISABLE_TRACE" = "xyes")
 105 AG_GST_CHECK_SUBSYSTEM_DISABLE(ALLOC_TRACE,[allocation tracing])
 106 AM_CONDITIONAL(GST_DISABLE_ALLOC_TRACE, test "x$GST_DISABLE_ALLOC_TRACE" = "xyes")
 107 AG_GST_CHECK_SUBSYSTEM_DISABLE(REGISTRY,[plugin registry])
 108 AM_CONDITIONAL(GST_DISABLE_REGISTRY, test "x$GST_DISABLE_REGISTRY" = "xyes")
 109 dnl define a substitution to use in docs/gst/gstreamer.types
 110 if test "x$GST_DISABLE_REGISTRY" = "xyes"
 111 then
 112   GST_REGISTRY_DOC_TYPES="%"
 113 else
 114   GST_REGISTRY_DOC_TYPES=
 115 fi
 116 AC_SUBST(GST_REGISTRY_DOC_TYPES)
 117 AG_GST_CHECK_SUBSYSTEM_DISABLE(NET,[network distribution])
 118 AM_CONDITIONAL(GST_DISABLE_NET, test "x$GST_DISABLE_NET" = "xyes")
 119 AG_GST_CHECK_SUBSYSTEM_DISABLE(PLUGIN,[plugin])
 120 AM_CONDITIONAL(GST_DISABLE_PLUGIN, test "x$GST_DISABLE_PLUGIN" = "xyes")
 121
 122 AG_GST_ARG_DEBUG
 123 AG_GST_ARG_PROFILING
 124 AG_GST_ARG_VALGRIND
 125 AG_GST_ARG_GCOV
 126
 127 AG_GST_ARG_EXAMPLES
 128
 129 AG_GST_ARG_WITH_PKG_CONFIG_PATH
 130 AG_GST_ARG_WITH_PACKAGE_NAME
 131 AG_GST_ARG_WITH_PACKAGE_ORIGIN
 132
 133 dnl building of tests
 134 AC_ARG_ENABLE(tests,
 135   AC_HELP_STRING([--disable-tests], [disable building test apps]),
 136   [
 137     case "${enableval}" in
 138       yes) BUILD_TESTS=yes ;;
 139       no)  BUILD_TESTS=no ;;
 140       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 141     esac
 142   ],
 143 [BUILD_TESTS=yes]) dnl Default value
 144 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 145
 146 dnl tests known to fail
 147 AC_ARG_ENABLE(failing-tests,
 148   AC_HELP_STRING([--disable-failing-tests],
 149     [disable building tests known to fail]),
 150   [
 151     case "${enableval}" in
 152       yes) BUILD_FAILING_TESTS=yes ;;
 153       no)  BUILD_FAILING_TESTS=no ;;
 154       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-failing-tests) ;;
 155     esac
 156   ],
 157   [BUILD_FAILING_TESTS=no]) dnl Default value
 158 AM_CONDITIONAL(BUILD_FAILING_TESTS, test "x$BUILD_FAILING_TESTS" = "xyes")
 159 if test x$BUILD_FAILING_TESTS = xyes; then
 160   AC_MSG_WARN([building tests known to fail, use --disable-failing-tests to disable])
 161 else
 162   AC_MSG_WARN([Sissy ! By asking to not build the tests known to fail, you hereby waive your right to customer support.  If you do not agree with this EULA, please press Ctrl-C before the next line is printed.  By allowing the next line to be printed, you expressly acknowledge your acceptance of this EULA.])
 163 fi
 164
 165 dnl poison destroyed objects
 166 AC_ARG_ENABLE(poisoning,
 167   AC_HELP_STRING([--enable-poisoning],
 168     [enable poisoning of deallocated objects]),
 169   [
 170     case "${enableval}" in
 171       yes) USE_POISONING=yes ;;
 172       no)  USE_POISONING=no ;;
 173       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-poisoning) ;;
 174     esac
 175   ],
 176   [USE_POISONING=no]) dnl Default value
 177 if test "x$USE_POISONING" = xyes; then
 178   AC_DEFINE(USE_POISONING, 1,
 179     [Define if we should poison deallocated memory])
 180 fi
 181
 182 dnl *** checks for platform ***
 183
 184 dnl * hardware/architecture *
 185
 186 dnl common/m4/gst-arch.m4
 187 dnl check CPU type
 188 AG_GST_ARCH
 189 dnl substitution for win32/common/config.h
 190 HOST_CPU=$host_cpu
 191 AC_SUBST(HOST_CPU)
 192
 193 dnl common/m4/gst-arch.m4
 194 dnl check for unaligned access
 195 AG_GST_UNALIGNED_ACCESS
 196 dnl create a configure variable for gst/gstconfig.h
 197 if test x${as_cv_unaligned_access} = xyes ; then
 198   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 1"
 199 else
 200   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 0"
 201 fi
 202 AC_SUBST(GST_HAVE_UNALIGNED_ACCESS_DEFINE)
 203
 204 dnl check for platform specific settings
 205 AG_GST_PLATFORM
 206
 207 dnl * software *
 208
 209 dnl check for large file support
 210 dnl affected plugins must include config.h
 211 AC_SYS_LARGEFILE
 212
 213 dnl *** checks for programs ***
 214
 215 dnl find a compiler
 216 AC_PROG_CC
 217
 218 dnl check if the compiler supports '-c' and '-o' options
 219 AM_PROG_CC_C_O
 220
 221 dnl find an assembler
 222 AM_PROG_AS
 223
 224 dnl Perl is used in building documentation and in the version checks
 225 AC_PATH_PROG(PERL_PATH, perl, no)
 226 if test x$PERL_PATH = xno; then
 227   AC_MSG_ERROR(Could not find perl)
 228 fi
 229
 230 dnl we require flex and bison for building the parser
 231 if test "x$GST_DISABLE_PARSE" != xyes; then
 232   AG_GST_BISON_CHECK
 233   AG_GST_FLEX_CHECK
 234 fi
 235
 236 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 237 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 238
 239 dnl check for gobject-introspection
 240 GOBJECT_INTROSPECTION_CHECK([0.6.3])
 241
 242 dnl check for documentation tools
 243 AG_GST_DOCBOOK_CHECK
 244 GTK_DOC_CHECK([1.3])
 245 AS_PATH_PYTHON([2.1])
 246 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 247
 248 dnl *** checks for libraries ***
 249
 250 dnl check for libm, for sin()
 251 AC_CHECK_LIBM
 252 AC_SUBST(LIBM)
 253
 254 dnl *** checks for header files ***
 255
 256 dnl check if we have ANSI C header files
 257 AC_HEADER_STDC
 258
 259 dnl Check for ucontext.h
 260 AC_CHECK_HEADERS([ucontext.h])
 261
 262 dnl Check for sys/socket.h
 263 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 264 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 265
 266 dnl check for sys/times.h for tests/examples/adapter/
 267 AC_CHECK_HEADERS([sys/times.h], HAVE_SYS_TIMES_H=yes)
 268 AC_CHECK_HEADERS([unistd.h], HAVE_UNISTD_H=yes)
 269 AM_CONDITIONAL(HAVE_SYS_TIMES_H_AND_UNISTD_H, test "x$HAVE_SYS_TIMES_H" = "xyes" -a "x$HAVE_UNISTD_H" = "xyes")
 270
 271 dnl Check for process.h for getpid() on win32
 272 AC_CHECK_HEADERS([process.h])
 273
 274 dnl Check for sys/utsname.h for uname
 275 AC_CHECK_HEADERS([sys/utsname.h])
 276
 277 dnl Check for stdio_ext.f for __fbufsize
 278 AC_CHECK_HEADERS([stdio_ext.h])
 279
 280 dnl check for pthreads
 281 AC_CHECK_HEADERS([pthread.h], HAVE_PTHREAD_H=yes)
 282 AM_CONDITIONAL(HAVE_PTHREAD_H, test "x$HAVE_PTHREAD_H" = "xyes")
 283
 284 dnl check for sys/prctl for setting thread name on Linux
 285 AC_CHECK_HEADERS([sys/prctl.h], HAVE_SYS_PRCTL_H=yes)
 286
 287 dnl Check for valgrind.h
 288 dnl separate from HAVE_VALGRIND because you can have the program, but not
 289 dnl the dev package
 290 AC_CHECK_HEADERS([valgrind/valgrind.h], HAVE_VALGRIND_H=yes)
 291
 292 dnl used in gst/gstpoll.c
 293 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 294 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 295 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 296   WIN32_LIBS="-lws2_32"
 297   AC_SUBST(WIN32_LIBS)
 298 fi
 299
 300 dnl check for GMP/GSL, used by the gst_util_uint64_scale unit test only
 301 if test "x$BUILD_TESTS" = "xyes"; then
 302   AG_GST_CHECK_LIBHEADER(GMP, gmp,
 303                          __gmpz_init_set_d, ,
 304                          gmp.h,
 305                          GMP_LIBS="-lgmp"
 306                          AC_SUBST(GMP_LIBS)
 307                          AC_DEFINE(HAVE_GMP, [1],[Have GMP library]))
 308   AG_GST_CHECK_LIBHEADER(GSL, gsl,
 309                          gsl_rng_uniform_int, -lgslcblas,
 310                          gsl/gsl_rng.h,
 311                          GSL_LIBS="-lgsl -lgslcblas"
 312                          AC_SUBST(GSL_LIBS)
 313                          AC_DEFINE(HAVE_GSL, [1],[Have GSL library]))
 314 fi
 315
 316 dnl *** checks for types/defines ***
 317
 318 dnl *** checks for structures ***
 319
 320 dnl *** checks for compiler characteristics ***
 321
 322 dnl check if the compiler supports __uint128_t (gcc)
 323 dnl Actually check for 128-bit division, since that's what we use
 324 dnl uint128_t for.
 325 AC_CACHE_CHECK(for __uint128_t, gst_cv_uint128_t,
 326     AC_TRY_LINK([ ], [
 327       static __uint128_t v1 = 100;
 328       static __uint128_t v2 = 10;
 329       static __uint128_t u;
 330       u = v1 / v2;
 331     ], [
 332       gst_cv_uint128_t=yes
 333     ], [
 334       gst_cv_uint128_t=no
 335     ])
 336 )
 337 if test x$gst_cv_uint128_t = xyes; then
 338   AC_DEFINE(HAVE_UINT128_T, 1, [Have __uint128_t type])
 339 fi
 340
 341 dnl *** checks for library functions ***
 342
 343 AC_CHECK_FUNCS([sigaction])
 344
 345 dnl check for fseeko()
 346 AC_FUNC_FSEEKO
 347 dnl check for ftello()
 348 AC_CHECK_FUNCS([ftello])
 349
 350 AC_CHECK_FUNCS([fgetpos])
 351 AC_CHECK_FUNCS([fsetpos])
 352
 353 dnl check for poll(), ppoll() and pselect()
 354 AC_CHECK_FUNCS([poll])
 355 AC_CHECK_FUNCS([ppoll])
 356 AC_CHECK_FUNCS([pselect])
 357
 358 dnl ****************************************
 359 dnl *** GLib POLL* compatibility defines ***
 360 dnl ****************************************
 361
 362 AC_MSG_CHECKING([for broken poll])
 363 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 364         #include <stdlib.h>
 365         #include <fcntl.h>
 366         #include <poll.h>
 367         #ifdef HAVE_SYS_POLL_H
 368         #include <sys/poll.h>
 369         #endif
 370         int main(void) {
 371           struct pollfd fds[1];
 372           int fd;
 373           fd = open("/dev/null", 1);
 374           fds[0].fd = fd;
 375           fds[0].events = POLLIN;
 376           fds[0].revents = 0;
 377           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
 378                 exit(1);  /* Does not work for devices -- fail */
 379           }
 380           exit(0);
 381         }]])],
 382   [broken_poll=no],
 383   [broken_poll=yes
 384    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
 385   [broken_poll="no (cross compiling)"])
 386 AC_MSG_RESULT($broken_poll)
 387
 388 dnl check for mmap()
 389 AC_FUNC_MMAP
 390 AM_CONDITIONAL(HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 391
 392 dnl check for posix_memalign(), getpagesize()
 393 AC_CHECK_FUNCS([posix_memalign])
 394 AC_CHECK_FUNCS([getpagesize])
 395
 396 dnl Check for POSIX timers
 397 AC_CHECK_FUNCS(clock_gettime, [], [
 398   AC_CHECK_LIB(rt, clock_gettime, [
 399     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 400     LIBS="$LIBS -lrt"
 401   ])
 402 ])
 403
 404 AC_CACHE_CHECK(for posix timers, gst_cv_posix_timers,
 405     AC_TRY_COMPILE([
 406 #include <time.h>
 407 #ifdef HAVE_UNISTD_H
 408 #include <unistd.h>
 409 #endif
 410     ], [
 411 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 412 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 413 #endif
 414     ], [
 415       gst_cv_posix_timers=yes
 416     ], [
 417       gst_cv_posix_timers=no
 418     ])
 419 )
 420
 421 if test "$gst_cv_posix_timers" = "yes"; then
 422   AC_DEFINE(HAVE_POSIX_TIMERS,1,[Have posix timers])
 423   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 1"
 424 else
 425   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 0"
 426 fi
 427 AC_SUBST(GST_HAVE_POSIX_TIMERS_DEFINE)
 428 AM_CONDITIONAL(GST_HAVE_POSIX_TIMERS, test "$gst_cv_posix_timers" = "yes")
 429
 430 AC_CACHE_CHECK(for monotonic clock, gst_cv_monotonic_clock,
 431     AC_TRY_COMPILE([
 432 #include <time.h>
 433 #ifdef HAVE_UNISTD_H
 434 #include <unistd.h>
 435 #endif
 436     ], [
 437 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 438 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 439 #endif
 440     ], [
 441       gst_cv_monotonic_clock=yes
 442     ], [
 443       gst_cv_monotonic_clock=no
 444     ])
 445 )
 446
 447 if test "$gst_cv_monotonic_clock" = "yes"; then
 448   AC_DEFINE(HAVE_MONOTONIC_CLOCK,1,[Have a monotonic clock])
 449   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 1"
 450 else
 451   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 0"
 452 fi
 453 AC_SUBST(GST_HAVE_MONOTONIC_CLOCK_DEFINE)
 454 AM_CONDITIONAL(GST_HAVE_MONOTONIC_CLOCK, test "$gst_cv_monotonic_clock" = "yes")
 455
 456 dnl Check for a way to display the function name in debug output
 457 AG_GST_CHECK_FUNCTION
 458
 459 dnl test for register_printf_specifier or register_printf_function
 460 AC_CHECK_FUNCS([register_printf_specifier register_printf_function],
 461     [HAVE_PRINTF_EXTENSION=yes])
 462
 463 if test "$HAVE_PRINTF_EXTENSION" = yes; then
 464   GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE="#define GST_PTR_FORMAT \"P\""
 465   GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE="#define GST_SEGMENT_FORMAT \"Q\""
 466   GST_USING_PRINTF_EXTENSION_DEFINE="#define GST_USING_PRINTF_EXTENSION"
 467   AC_DEFINE(HAVE_PRINTF_EXTENSION, 1,
 468       [Defined if we have printf specifier extensions available])
 469 else
 470     GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE="#define GST_PTR_FORMAT \"p\""
 471     GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE="#define GST_SEGMENT_FORMAT \"p\""
 472     GST_USING_PRINTF_EXTENSION_DEFINE="#undef GST_USING_PRINTF_EXTENSION"
 473 fi
 474 AC_SUBST(GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE)
 475 AC_SUBST(GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE)
 476 AC_SUBST(GST_USING_PRINTF_EXTENSION_DEFINE)
 477
 478 dnl test if we have dladdr(); we use it for debugging; see gst/gstinfo.c
 479 save_cflags="$CFLAGS"
 480 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 481 AC_CHECK_LIB(dl, dladdr,
 482    AC_DEFINE(HAVE_DLADDR, 1, [Defined if we have dladdr ()])
 483    LIBS="$LIBS -ldl")
 484 CFLAGS="$save_cflags"
 485
 486 dnl *** checks for socket and nsl libraries ***
 487 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 488 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
 489
 490 dnl check for inet_aton()
 491 save_libs="$LIBS"
 492 AC_CHECK_FUNC(inet_aton, ,
 493    AC_CHECK_LIB(nsl, inet_aton, ,
 494       AC_CHECK_LIB(socket, inet_aton, ,
 495          AC_CHECK_LIB(resolv, inet_aton, ,[AC_DEFINE(NO_INET_ATON, 1, [Define if you have no native inet_aton() function.])]))))
 496 INET_ATON_LIBS=$LIBS
 497 AC_SUBST(INET_ATON_LIBS)
 498 LIBS="$save_libs"
 499
 500 dnl *** checks for dependency libraries ***
 501
 502 dnl GLib
 503 GLIB_REQ=2.20
 504
 505 AG_GST_GLIB_CHECK([$GLIB_REQ])
 506
 507 dnl FIXME: 0.11: Guess we need to keep this around until 0.11
 508 GST_HAVE_GLIB_2_8_DEFINE="#define GST_HAVE_GLIB_2_8 1"
 509 AC_SUBST(GST_HAVE_GLIB_2_8_DEFINE)
 510
 511 dnl Check for glib2 without extra fat, useful for the unversioned tool frontends
 512 PKG_CHECK_MODULES(GLIB_ONLY, glib-2.0 >= $GLIB_REQ)
 513
 514 dnl Check for documentation xrefs
 515 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 516 AC_SUBST(GLIB_PREFIX)
 517
 518 dnl libxml2 is only needed for xml loading/saving of pipelines these days
 519 if test "x$GST_DISABLE_LOADSAVE" = "xyes"
 520 then
 521   AC_MSG_NOTICE([XML registry and load/save are disabled, not checking for libxml2])
 522   GST_DISABLE_XML_DEFINE="#define GST_DISABLE_XML 1"
 523 else
 524   dnl check for libxml2 with minimum req version
 525   AG_GST_LIBXML2_CHECK(2.4.9)
 526   GST_DISABLE_XML_DEFINE="/* #undef GST_DISABLE_XML */"
 527 fi
 528 AC_SUBST(GST_DISABLE_XML_DEFINE)
 529
 530 dnl building of unit test libraries
 531 AC_ARG_ENABLE(check,
 532   AC_HELP_STRING([--disable-check], [disable building unit test libraries]),
 533   [
 534     case "${enableval}" in
 535       yes) BUILD_CHECK=yes ;;
 536       no)  BUILD_CHECK=no ;;
 537       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-check) ;;
 538     esac
 539   ], [
 540     dnl Default value
 541     case $host_os in
 542       mingw* | msvc* | mks*) BUILD_CHECK=no ;;
 543       *) BUILD_CHECK=yes ;;
 544     esac
 545 ])
 546 dnl bit of a misnomer, but keep the conditional named like this so we don't
 547 dnl have to change too much elsewhere
 548 AM_CONDITIONAL(HAVE_CHECK, test "x$BUILD_CHECK" = "xyes")
 549
 550 dnl configure the desired buffer alignment
 551 AC_ARG_WITH([buffer-alignment],
 552   AS_HELP_STRING([--with-buffer-alignment],[8,N,malloc,pagesize (default is 32)]),
 553   [
 554     if test "x$withval" = "xyes"
 555     then
 556       AC_DEFINE(BUFFER_ALIGNMENT, 32, [Buffer alignment to use])
 557     else
 558       case "${withval}" in
 559         malloc) AC_DEFINE(BUFFER_ALIGNMENT_MALLOC, 1, [Buffer alignment by malloc default]) ;;
 560         pagesize)  AC_DEFINE(BUFFER_ALIGNMENT_PAGESIZE, 1, [Buffer alignment by pagesize]) ;;
 561         *)   AC_DEFINE_UNQUOTED(BUFFER_ALIGNMENT, ${withval}, [Buffer alignment to use]) ;;
 562       esac
 563     fi
 564   ], [
 565     AC_DEFINE(BUFFER_ALIGNMENT_MALLOC, 1, [Buffer alignment by malloc default])
 566   ]
 567 )
 568
 569 dnl *** set variables based on configure arguments
 570
 571 dnl set license and copyright notice
 572 GST_LICENSE="LGPL"
 573 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 574 AC_SUBST(GST_LICENSE)
 575
 576 dnl define LIBDIR, GST_DATADIR so we can inform people where we live
 577 AS_AC_EXPAND(LIBDIR, $libdir)
 578 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [library dir])
 579 AS_AC_EXPAND(DATADIR, $datadir)
 580 AC_DEFINE_UNQUOTED(GST_DATADIR, "$DATADIR", [data dir])
 581
 582 dnl set location of plugin directory
 583 AG_GST_SET_PLUGINDIR
 584
 585 dnl FIXME: add LIBXML_PKG here if we use it
 586 GST_PKG_DEPS="glib-2.0, gobject-2.0, gmodule-no-export-2.0, gthread-2.0"
 587 AC_SUBST(GST_PKG_DEPS)
 588
 589 dnl define an ERROR_CFLAGS Makefile variable
 590 AG_GST_SET_ERROR_CFLAGS($GST_GIT, [-Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef -Wwrite-strings -Wformat-nonliteral -Wformat-security -Wold-style-definition -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return -Wno-multichar -Wnested-externs])
 591
 592 dnl define correct level for debugging messages
 593 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 594
 595 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 596
 597 dnl Overview:
 598 dnl GST_OPTION_CFLAGS:  common cflags for profiling, debugging, errors, ...
 599 dnl GST_ALL_*:          vars shared by all built objects
 600 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 601 dnl GST_OBJ_*:          additional vars to link to the core library
 602 dnl                     include GST_ALL_*
 603 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 604 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 605
 606 dnl GST_OPTION_CFLAGS
 607 if test "x$USE_DEBUG" = xyes; then
 608    PROFILE_CFLAGS="-g"
 609 fi
 610 AC_SUBST(PROFILE_CFLAGS)
 611
 612 # GST_DISABLE_DEPRECATED: hide the visibility of deprecated
 613 # functionality from the API that gstreamer uses
 614 # GST_REMOVE_DEPRECATED: don't compile deprecated functionality (breaks ABI)
 615 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 616   dnl Define _only_ when compiling from git (not for pre-releases or releases)
 617   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 618 else
 619   DEPRECATED_CFLAGS=""
 620 fi
 621 AC_SUBST(DEPRECATED_CFLAGS)
 622
 623 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time via e.g.
 624 dnl make DEPRECATED_CFLAGS=''
 625 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 626 AC_SUBST(GST_OPTION_CFLAGS)
 627
 628 dnl GST_ALL_*
 629 dnl vars common to for all internal objects (core libs, elements, applications)
 630 dnl CFLAGS:
 631 dnl - XML needs to be added because xmlPtr is used in core
 632 dnl - src and build dirs need to be added because every piece that gets built
 633 dnl   will need the GStreamer source and generated headers
 634 dnl LIBS: XML doesn't need to be added because we don't explicitly use symbols
 635 dnl       from LibXML except for in the core library
 636 GST_ALL_CFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir)/libs -I\$(top_builddir) $GLIB_CFLAGS $GLIB_EXTRA_CFLAGS $XML_CFLAGS \$(GST_OPTION_CFLAGS) \$(ERROR_CFLAGS) -DG_THREADS_MANDATORY"
 637
 638 dnl FIXME: check if LTLIBINTL is needed everywhere
 639 dnl I presume it is given that it contains the symbols that _() stuff maps to
 640 GST_ALL_LIBS="$GLIB_LIBS $LTLIBINTL \$(GCOV_LIBS)"
 641
 642 dnl LDFLAGS really should only contain flags, not libs - they get added before
 643 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 644 GST_ALL_LDFLAGS="-no-undefined"
 645
 646 AC_SUBST(GST_ALL_CFLAGS)
 647 AC_SUBST(GST_ALL_LIBS)
 648 AC_SUBST(GST_ALL_LDFLAGS)
 649
 650 dnl GST_LIB_LDFLAGS
 651 dnl linker flags shared by all libraries
 652 dnl LDFLAGS modifier defining exported symbols from built libraries
 653 GST_LIB_LDFLAGS="-export-symbols-regex \^[_]*\(gst_\|Gst\|GST_\).*"
 654 AC_SUBST(GST_LIB_LDFLAGS)
 655
 656 dnl GST_OBJ_*
 657 dnl default vars for all internal objects built on libgstreamer
 658 dnl includes GST_ALL_*
 659 GST_OBJ_CFLAGS="\$(GST_ALL_CFLAGS)"
 660 GST_OBJ_LIBS="\$(top_builddir)/gst/libgstreamer-$GST_MAJORMINOR.la \$(GST_ALL_LIBS)"
 661 AC_SUBST(GST_OBJ_CFLAGS)
 662 AC_SUBST(GST_OBJ_LIBS)
 663
 664 dnl GST_PLUGIN_LDFLAGS
 665 dnl LDFLAGS for plugins; includes GST_ALL_LDFLAGS
 666 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 667 AC_SUBST(GST_PLUGIN_LDFLAGS, "$GST_PLUGIN_LDFLAGS")
 668
 669 dnl plugin scanner locations
 670 AS_AC_EXPAND(GST_PLUGIN_SCANNER_INSTALLED,${libexecdir}/gstreamer-$GST_MAJORMINOR/gst-plugin-scanner)
 671 AC_DEFINE_UNQUOTED(GST_PLUGIN_SCANNER_INSTALLED,
 672     "$GST_PLUGIN_SCANNER_INSTALLED", [location of the installed gst-plugin-scanner])
 673 AC_SUBST(GST_PLUGIN_SCANNER_INSTALLED)
 674
 675 dnl things for our internal libcheck (must be called even if building
 676 dnl libcheck is disabled because it defines conditionals)
 677 AG_GST_CHECK_CHECKS()
 678
 679 AC_CONFIG_FILES(
 680 Makefile
 681 gst/Makefile
 682 gst/gstconfig.h
 683 gst/gstversion.h
 684 gst/parse/Makefile
 685 libs/Makefile
 686 libs/gst/Makefile
 687 libs/gst/base/Makefile
 688 libs/gst/check/Makefile
 689 libs/gst/check/libcheck/Makefile
 690 libs/gst/check/libcheck/check.h
 691 libs/gst/controller/Makefile
 692 libs/gst/dataprotocol/Makefile
 693 libs/gst/helpers/Makefile
 694 libs/gst/net/Makefile
 695 plugins/Makefile
 696 plugins/indexers/Makefile
 697 plugins/elements/Makefile
 698 po/Makefile.in
 699 tests/Makefile
 700 tests/benchmarks/Makefile
 701 tests/check/Makefile
 702 tests/misc/Makefile
 703 tests/examples/Makefile
 704 tests/examples/adapter/Makefile
 705 tests/examples/controller/Makefile
 706 tests/examples/stepping/Makefile
 707 tests/examples/helloworld/Makefile
 708 tests/examples/launch/Makefile
 709 tests/examples/manual/Makefile
 710 tests/examples/metadata/Makefile
 711 tests/examples/queue/Makefile
 712 tests/examples/streams/Makefile
 713 tests/examples/typefind/Makefile
 714 tests/examples/xml/Makefile
 715 tools/Makefile
 716 common/Makefile
 717 common/m4/Makefile
 718 docs/Makefile
 719 docs/design/Makefile
 720 docs/faq/Makefile
 721 docs/gst/Makefile
 722 docs/gst/gstreamer.types
 723 docs/libs/Makefile
 724 docs/plugins/Makefile
 725 docs/manual/Makefile
 726 docs/pwg/Makefile
 727 docs/slides/Makefile
 728 docs/xsl/Makefile
 729 docs/version.entities
 730 m4/Makefile
 731 pkgconfig/Makefile
 732 stamp.h
 733 pkgconfig/gstreamer.pc
 734 pkgconfig/gstreamer-uninstalled.pc
 735 pkgconfig/gstreamer-base.pc
 736 pkgconfig/gstreamer-base-uninstalled.pc
 737 pkgconfig/gstreamer-check.pc
 738 pkgconfig/gstreamer-check-uninstalled.pc
 739 pkgconfig/gstreamer-controller.pc
 740 pkgconfig/gstreamer-controller-uninstalled.pc
 741 pkgconfig/gstreamer-dataprotocol.pc
 742 pkgconfig/gstreamer-dataprotocol-uninstalled.pc
 743 pkgconfig/gstreamer-net.pc
 744 pkgconfig/gstreamer-net-uninstalled.pc
 745 gst-element-check.m4
 746 gstreamer.spec
 747 )
 748
 749 dnl Create the config.h file for Visual Studio builds
 750 dnl Beware of spaces and /'s in some of the shell variable contents.
 751 sed \
 752     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 753     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 754     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 755     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 756     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 757     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
 758     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 759     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 760     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 761     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 762     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 763     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
 764     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 765     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 766     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 767     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 768     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 769     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 770     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
 771     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 772     -e 's/.* BUFFER_ALIGNMENT_MALLOC/#define BUFFER_ALIGNMENT_MALLOC 1/' \
 773     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 774     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 775     -e 's/.* PACKAGE$/#define PACKAGE "gstreamer"/' \
 776     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 777     -e 's/.* PACKAGE_NAME$/#define PACKAGE_NAME "'$PACKAGE_NAME'"/' \
 778     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 779     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 780     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 781     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.10"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.10"\n#endif/' \
 782     -e 's/.* GST_PLUGIN_SCANNER_INSTALLED$/#define GST_PLUGIN_SCANNER_INSTALLED LIBDIR "\\\\gst-plugin-scanner"/' \
 783     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 784     config.h.in >win32/common/config.h-new
 785
 786 AC_OUTPUT
 787
 788 dnl negate for output
 789 if test "x${GST_DISABLE_GST_DEBUG}" = "xno"; then enable_gst_debug="yes"; fi
 790 if test "x${GST_DISABLE_LOADSAVE}" = "xno"; then enable_loadsave="yes"; fi
 791 if test "x${GST_DISABLE_PARSE}" = "xno"; then enable_parse="yes"; fi
 792 if test "x${GST_DISABLE_OPTION_PARSING}" = "xno"; then enable_option_parsing="yes"; fi
 793 if test "x${GST_DISABLE_TRACE}" = "xno"; then enable_trace="yes"; fi
 794 if test "x${GST_DISABLE_ALLOC_TRACE}" = "xno"; then enable_alloc_trace="yes"; fi
 795 if test "x${GST_DISABLE_PLUGIN}" = "xno"; then enable_plugin="yes"; fi
 796 if test "x${GST_DISABLE_REGISTRY}" = "xno"; then enable_registry="yes"; fi
 797 if test "x${GST_DISABLE_NET}" = "xno"; then enable_net="yes"; fi
 798
 799 echo "
 800
 801 Configuration
 802         Version                    : ${VERSION}
 803         Source code location       : ${srcdir}
 804         Prefix                     : ${prefix}
 805         Compiler                   : ${CC}
 806         Package name               : ${GST_PACKAGE_NAME}
 807         Package origin             : ${GST_PACKAGE_ORIGIN}
 808
 809         Documentation (manuals)    : ${enable_docbook}
 810         Documentation (API)        : ${enable_gtk_doc}
 811
 812         Debug Logging              : ${enable_gst_debug}
 813         Pipeline XML load/save     : ${enable_loadsave}
 814         Command-line parser        : ${enable_parse}
 815         Option parsing in gst_init : ${enable_option_parsing}
 816         Tracing subsystem          : ${enable_trace}
 817         Allocation tracing         : ${enable_alloc_trace}
 818         Plugin registry            : ${enable_registry}
 819         Plugin support             : ${enable_plugin}
 820         Network support            : ${enable_net}
 821         Unit testing support       : ${BUILD_CHECK}
 822
 823         Debug                      : ${USE_DEBUG}
 824         Profiling                  : ${USE_PROFILING}
 825
 826         Building examples          : ${BUILD_EXAMPLES}
 827         Building test apps         : ${BUILD_TESTS}
 828         Building tests that fail   : ${BUILD_FAILING_TESTS}
 829 "