configure.ac

   1 AC_PREREQ([2.68])
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/prerelease
   8 AC_INIT([GStreamer Base Plug-ins],[1.3.1.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gst-plugins-base])
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.11 no-dist-gzip dist-xz tar-ustar subdir-objects])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  23
  24 dnl define the output header for config
  25 AC_CONFIG_HEADERS([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output with automake >= 1.11
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  35   [AM_DEFAULT_VERBOSITY=1
  36    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  37
  38 dnl our libraries and install dirs use GST_API_VERSION in the filename
  39 dnl to allow side-by-side installation of different API versions
  40 GST_API_VERSION=1.0
  41 AC_SUBST(GST_API_VERSION)
  42 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  43   [GStreamer API Version])
  44
  45 dnl CURRENT, REVISION, AGE
  46 dnl - library source changed -> increment REVISION
  47 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  48 dnl - interfaces added -> increment AGE
  49 dnl - interfaces removed -> AGE = 0
  50 dnl
  51 dnl Keep CURRENT as MINOR * 100 + MICRO
  52 dnl Ex : 1.0.0 => 0
  53 dnl      1.0.3 => 3
  54 dnl      1.1.0 => 100
  55 dnl      1.2.5 => 205
  56 dnl      1.10.9 (who knows) => 1009
  57 dnl
  58 dnl sets GST_LT_LDFLAGS
  59 AS_LIBTOOL(GST, 301, 0, 301)
  60
  61 dnl *** required versions of GStreamer stuff ***
  62 GST_REQ=1.3.1.1
  63
  64 dnl *** autotools stuff ****
  65
  66 dnl allow for different autotools
  67 AS_AUTOTOOLS_ALTERNATE
  68
  69 dnl Add parameters for aclocal
  70 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  71
  72 dnl set up gettext
  73 dnl the version check needs to stay here because autopoint greps for it
  74 AM_GNU_GETTEXT_VERSION([0.17])
  75 AM_GNU_GETTEXT([external])
  76 AG_GST_GETTEXT([gst-plugins-base-$GST_API_VERSION])
  77
  78 dnl *** check for arguments to configure ***
  79
  80 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  81
  82 AG_GST_ARG_DEBUG
  83 AG_GST_ARG_PROFILING
  84 AG_GST_ARG_VALGRIND
  85 AG_GST_ARG_GCOV
  86
  87 AG_GST_ARG_EXAMPLES
  88
  89 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  90 AG_GST_ARG_WITH_PACKAGE_NAME
  91 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  92
  93 AG_GST_PKG_CONFIG_PATH
  94
  95 dnl let distro override plugin install helper path
  96 AC_ARG_WITH(install-plugins-helper,
  97   AS_HELP_STRING([--with-install-plugins-helper],[specify path of helper script to call to install plugins]),
  98   [
  99     case "${withval}" in
 100       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 101       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 102       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
 103     esac
 104   ],
 105   [
 106     dnl Default value
 107     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 108   ]
 109 )
 110 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 111 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 112     [plugin install helper script])
 113 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 114
 115 AG_GST_ARG_WITH_PLUGINS
 116
 117 AG_GST_ARG_ENABLE_EXTERNAL
 118
 119 AG_GST_ARG_ENABLE_EXPERIMENTAL
 120
 121 dnl *** checks for platform ***
 122 AG_GST_PLATFORM
 123
 124 dnl * hardware/architecture *
 125
 126 dnl common/m4/gst-arch.m4
 127 dnl check CPU type
 128 AG_GST_ARCH
 129
 130 dnl check for large file support
 131 dnl affected plugins must include config.h
 132 AC_SYS_LARGEFILE
 133
 134 dnl *** checks for programs ***
 135
 136 dnl find a compiler
 137 AC_PROG_CC
 138 AC_PROG_CC_STDC
 139
 140 dnl check if the compiler supports '-c' and '-o' options
 141 AM_PROG_CC_C_O
 142
 143 dnl determine if c++ is available on this system
 144 AC_PROG_CXX
 145 dnl CXX may be set to some default even if no c++ compiler is available
 146 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 147 AC_LANG_PUSH([C++])
 148 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ class Foo { int bar; };]], [[]])],[working_cxx=yes],[working_cxx=no])
 149 AC_LANG_POP([C++])
 150 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 151 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 152
 153 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 154 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 155
 156 dnl check for gobject-introspection
 157 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 158
 159 dnl check for documentation tools
 160 GTK_DOC_CHECK([1.12])
 161 AG_GST_PLUGIN_DOCS([1.12])
 162
 163 dnl *** checks for libraries ***
 164
 165 dnl libm, for sin() etc.
 166 LT_LIB_M
 167 AC_SUBST(LIBM)
 168
 169 dnl *** checks for header files ***
 170
 171 dnl check if we have ANSI C header files
 172 AC_HEADER_STDC
 173
 174 dnl check for GCC specific SSE headers
 175 dnl these are used by the speex resampler code
 176 AC_CHECK_HEADERS([xmmintrin.h emmintrin.h])
 177
 178 dnl used in gst/tcp
 179 AC_CHECK_HEADERS([sys/socket.h],
 180   [HAVE_SYS_SOCKET_H="yes"], [HAVE_SYS_SOCKET_H="no"], [AC_INCLUDES_DEFAULT])
 181 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 182
 183 dnl used in gst-libs/gst/rtsp
 184 AC_CHECK_HEADERS([winsock2.h], [HAVE_WINSOCK2_H=yes], [HAVE_WINSOCK2_H=no], [AC_INCLUDES_DEFAULT])
 185 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 186 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 187   WIN32_LIBS="-lws2_32"
 188   AC_SUBST(WIN32_LIBS)
 189 fi
 190
 191 dnl used in gst-libs/gst/pbutils and associated unit test
 192 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h], [], [], [AC_INCLUDES_DEFAULT])
 193
 194 dnl checks for ARM NEON support
 195 dnl this instruction set is used by the speex resampler code
 196 AC_MSG_CHECKING(for ARM NEON support in current arch/CFLAGS)
 197 AC_LINK_IFELSE([
 198 AC_LANG_PROGRAM([[
 199   #include <arm_neon.h>
 200   int32x4_t testfunc(int16_t *a, int16_t *b) {
 201       asm volatile ("vmull.s16 q0, d0, d0" : : : "q0");
 202       return vmull_s16(vld1_s16(a), vld1_s16(b));
 203   }
 204 ]])],
 205 [
 206   AC_DEFINE(HAVE_ARM_NEON,[],[ARM NEON support is enabled])
 207   AC_MSG_RESULT(yes)
 208 ],
 209 [
 210   AC_MSG_RESULT(no)
 211 ])
 212
 213 dnl also, Windows does not have long long
 214 AX_CREATE_STDINT_H
 215
 216 dnl *** checks for functions ***
 217 AC_CHECK_FUNCS([localtime_r gmtime_r])
 218
 219 dnl *** checks for math functions ***
 220 LIBS_SAVE=$LIBS
 221 LIBS="$LIBS $LIBM"
 222 AC_CHECK_FUNCS(log2)
 223 LIBS=$LIBS_SAVE
 224
 225 dnl *** checks for types/defines ***
 226
 227 dnl *** checks for structures ***
 228
 229 dnl *** checks for compiler characteristics ***
 230
 231 dnl *** checks for library functions ***
 232
 233 dnl check for fseeko()
 234 AC_FUNC_FSEEKO
 235
 236 dnl Check for fast float to int casting as defined in C99
 237 dnl used to be used in gst-libs/gst/floatcast/floatcast.h (FIXME: still needed?)
 238 save_libs=$LIBS
 239 LIBS="$LIBS $LIBM"
 240 AC_C99_FUNC_LRINT
 241 AC_C99_FUNC_LRINTF
 242 LIBS=$save_libs
 243
 244 dnl Check for a way to display the function name in debug output
 245 AG_GST_CHECK_FUNCTION
 246
 247 dnl *** checks for dependency libraries ***
 248
 249 dnl GLib
 250 GLIB_REQ=2.32
 251 AG_GST_GLIB_CHECK([$GLIB_REQ])
 252
 253 ORC_CHECK([0.4.18])
 254
 255 dnl checks for gstreamer
 256 dnl uninstalled is selected preferentially -- see pkg-config(1)
 257 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 258 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 259 AG_GST_CHECK_GST_CONTROLLER($GST_API_VERSION, [$GST_REQ], yes)
 260 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 261 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 262
 263 dnl Check for documentation xrefs
 264 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 265 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 266 AC_SUBST(GLIB_PREFIX)
 267 AC_SUBST(GST_PREFIX)
 268
 269 dnl GTK is optional and only used in examples
 270 HAVE_GTK=no
 271 HAVE_GTK_X11=no
 272 GTK_REQ=3.0.0
 273 if test "x$BUILD_EXAMPLES" = "xyes"; then
 274   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 275   dnl some examples need gtk+-x11
 276   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 277   PKG_CHECK_MODULES(GTK_QUARTZ, gtk+-quartz-3.0 >= $GTK_REQ, HAVE_GTK_QUARTZ=yes, HAVE_GTK_QUARTZ=no)
 278   AC_SUBST(GTK_LIBS)
 279   AC_SUBST(GTK_CFLAGS)
 280 fi
 281 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 282 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 283 AM_CONDITIONAL(HAVE_GTK_QUARTZ, test "x$HAVE_GTK_QUARTZ" = "xyes")
 284
 285 HAVE_QT=no
 286 HAVE_QT_MOC=no
 287 dnl QT is optional and only used in examples
 288 PKG_CHECK_MODULES(QT, Qt5Gui Qt5Widgets, [
 289   HAVE_QT=yes
 290 ], [
 291   HAVE_QT=no
 292 ])
 293 if test "x$HAVE_QT" = "xyes"; then
 294   AC_CHECK_TOOL(QT_MOC, moc)
 295   AC_MSG_CHECKING([for Qt5 moc])
 296   mocversion=`$QT_MOC -v 2>&1`
 297   mocversiongrep=`echo $mocversion | grep "Qt 5\|moc 5"`
 298   if test x"$mocversiongrep" != x"$mocversion"; then
 299     AC_MSG_RESULT([no])
 300     # moc was not the qt5 one, try with moc-qt5
 301     AC_CHECK_TOOL(QT_MOC, moc-qt5)
 302     AC_MSG_CHECKING([for Qt5 moc-qt5])
 303     mocversion=`$QT_MOC -v 2>&1`
 304     mocversiongrep=`echo $mocversion | grep "Qt 5\|moc 5"`
 305     if test x"$mocversiongrep" != x"$mocversion"; then
 306       AC_CHECK_TOOL(QTCHOOSER, qtchooser)
 307       AC_MSG_CHECKING([for qtchooser])
 308       qt5tooldir=`QT_SELECT=qt5 qtchooser -print-env | grep QTTOOLDIR | cut -d '=' -f 2 | cut -d \" -f 2`
 309       mocversion=`$qt5tooldir/moc -v 2>&1`
 310       mocversiongrep=`echo $mocversion | grep "Qt 5\|moc 5"`
 311       if test x"$mocversiongrep" != x"$mocversion"; then
 312         # no valid moc found
 313         QT_MOC="no"
 314       else
 315         QT_MOC=$qt5tooldir/moc
 316       fi
 317     else
 318       QT_MOC=$QT_MOC
 319     fi
 320   fi
 321   AC_SUBST(QT_MOC)
 322   AC_MSG_RESULT([$QT_MOC])
 323 fi
 324 AM_CONDITIONAL(HAVE_QT, test "x$HAVE_QT" = "xyes")
 325 AM_CONDITIONAL(HAVE_QT_MOC, test "x$HAVE_QT_MOC" != "xno")
 326
 327 dnl chck for linux headers needed by the joystick seek example
 328 AC_COMPILE_IFELSE(
 329 [
 330   AC_LANG_PROGRAM([
 331     #include <linux/input.h>
 332     #include <linux/joystick.h>
 333   ],[
 334     struct js_event js;
 335     js.type = JS_EVENT_AXIS;
 336   ])
 337 ], [
 338   HAVE_LINUX_JOYSTICK_HEADERS="yes"
 339 ], [
 340   HAVE_LINUX_JOYSTICK_HEADERS="no"
 341 ])
 342 AM_CONDITIONAL(HAVE_LINUX_JOYSTICK_HEADERS, test "x$HAVE_LINUX_JOYSTICK_HEADERS" = "xyes")
 343
 344 dnl Check for -Bsymbolic-functions linker flag used to avoid
 345 dnl intra-library PLT jumps, if available.
 346 AC_ARG_ENABLE(Bsymbolic,
 347               [AS_HELP_STRING([--disable-Bsymbolic],[avoid linking with -Bsymbolic])],,
 348               [SAVED_LDFLAGS="${LDFLAGS}"
 349                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 350                LDFLAGS=-Wl,-Bsymbolic-functions
 351                AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int main (void) { return 0; }]])],[
 352                            AC_MSG_RESULT(yes)
 353                            enable_Bsymbolic=yes],[
 354                            AC_MSG_RESULT(no)
 355                            enable_Bsymbolic=no])
 356                LDFLAGS="${SAVED_LDFLAGS}"])
 357
 358
 359 dnl *** set variables based on configure arguments ***
 360
 361 dnl set license and copyright notice
 362 GST_LICENSE="LGPL"
 363 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 364 AC_SUBST(GST_LICENSE)
 365
 366 dnl set location of plugin directory
 367 AG_GST_SET_PLUGINDIR
 368
 369 dnl set release date/time
 370 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 371   ["${srcdir}/gst-plugins-base.doap"],
 372   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 373
 374 dnl build static plugins or not
 375 AC_MSG_CHECKING([whether to build static plugins or not])
 376 AC_ARG_ENABLE(
 377   static-plugins,
 378   AC_HELP_STRING(
 379     [--enable-static-plugins],
 380     [build static plugins @<:@default=no@:>@]),
 381   [AS_CASE(
 382     [$enableval], [no], [], [yes], [],
 383     [AC_MSG_ERROR([bad value "$enableval" for --enable-static-plugins])])],
 384   [enable_static_plugins=no])
 385 AC_MSG_RESULT([$enable_static_plugins])
 386 if test "x$enable_static_plugins" = xyes; then
 387   AC_DEFINE(GST_PLUGIN_BUILD_STATIC, 1,
 388     [Define if static plugins should be built])
 389   GST_PLUGIN_LIBTOOLFLAGS=""
 390 else
 391   GST_PLUGIN_LIBTOOLFLAGS="--tag=disable-static"
 392 fi
 393 AC_SUBST(GST_PLUGIN_LIBTOOLFLAGS)
 394 AM_CONDITIONAL(GST_PLUGIN_BUILD_STATIC, test "x$enable_static_plugins" = "xyes")
 395
 396 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 397 dnl make sure it doesn't complain about unused variables if debugging is disabled
 398 NO_WARNINGS=""
 399 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 400
 401 dnl define an ERROR_CFLAGS Makefile variable
 402 dnl -Wformat-nonliteral - see ext/pango/gstclockoverlay.c and http://gcc.gnu.org/bugzilla/show_bug.cgi?id=39438
 403 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 404     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef
 405     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 406     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 407     -Wno-multichar -Wnested-externs $NO_WARNINGS])
 408
 409 dnl define an ERROR_CXXFLAGS Makefile variable
 410 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 411     -Wmissing-declarations -Wredundant-decls -Wundef
 412     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 413     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 414     -Wno-multichar $NO_WARNINGS])
 415
 416 dnl define correct level for debugging messages
 417 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 418
 419 dnl used in examples
 420 AG_GST_DEFAULT_ELEMENTS
 421
 422 dnl needed for encoding-target
 423 GST_DATADIR="$GST_PREFIX/share"
 424 AC_DEFINE_UNQUOTED(GST_DATADIR, "$GST_DATADIR", [system wide data directory])
 425 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION", [major/minor version])
 426
 427 dnl behaviour of speex based audio resampler
 428 AC_MSG_CHECKING(which audio resample format to use for integer)
 429 AC_ARG_WITH([audioresample_format],
 430         AS_HELP_STRING([--with-audioresample-format],[Which implementation should be used for integer audio resampling, int/float/auto, (default is auto)]),
 431         [ac_cv_audioresample_format=$withval], [ac_cv_audioresample_format=auto])dnl
 432 AC_MSG_RESULT($ac_cv_audioresample_format)
 433 case $ac_cv_audioresample_format in
 434   int)
 435     AC_DEFINE(AUDIORESAMPLE_FORMAT_INT,1,[The int implementation should be used for integer audio resampling])
 436     AC_SUBST(AUDIORESAMPLE_FORMAT_INT)
 437   ;;
 438   float)
 439     AC_DEFINE(AUDIORESAMPLE_FORMAT_FLOAT,1,[The float implementation should be used for integer audio resampling])
 440     AC_SUBST(AUDIORESAMPLE_FORMAT_FLOAT)
 441   ;;
 442   auto)
 443     AC_DEFINE(AUDIORESAMPLE_FORMAT_AUTO,1,[The implementation that should be used for integer audio resampling witll be benchmarked at runtime])
 444     AC_SUBST(AUDIORESAMPLE_FORMAT_AUTO)
 445 esac
 446
 447 dnl Check for mmap (needed by allocators library)
 448 AC_CHECK_FUNC([mmap], [AC_DEFINE(HAVE_MMAP, 1, [Defined if mmap is supported])])
 449
 450 dnl *** plug-ins to include ***
 451
 452 dnl these are all the gst plug-ins, compilable without additional libs
 453 AG_GST_CHECK_PLUGIN(adder)
 454 AG_GST_CHECK_PLUGIN(app)
 455 AG_GST_CHECK_PLUGIN(audioconvert)
 456 AG_GST_CHECK_PLUGIN(audiorate)
 457 AG_GST_CHECK_PLUGIN(audiotestsrc)
 458 AG_GST_CHECK_PLUGIN(encoding)
 459 AG_GST_CHECK_PLUGIN(videoconvert)
 460 AG_GST_CHECK_PLUGIN(gio)
 461 AG_GST_CHECK_PLUGIN(playback)
 462 AG_GST_CHECK_PLUGIN(audioresample)
 463 AG_GST_CHECK_PLUGIN(subparse)
 464 AG_GST_CHECK_PLUGIN(tcp)
 465 AG_GST_CHECK_PLUGIN(typefind)
 466 AG_GST_CHECK_PLUGIN(videotestsrc)
 467 AG_GST_CHECK_PLUGIN(videorate)
 468 AG_GST_CHECK_PLUGIN(videoscale)
 469 AG_GST_CHECK_PLUGIN(volume)
 470
 471 dnl iso-codes is optional, used by libgsttag
 472 AC_ARG_ENABLE(iso-codes,
 473 AS_HELP_STRING([--enable-iso-codes],[use iso-codes if installed]),
 474 [case "${enableval}" in
 475   yes) enable_iso_codes=yes ;;
 476   no)  enable_iso_codes=no ;;
 477   *) AC_MSG_ERROR(bad value ${enableval} for --enable-iso-codes) ;;
 478 esac
 479 ],
 480 [enable_iso_codes=yes]) dnl Default value
 481
 482 AC_MSG_CHECKING([whether to use iso-codes if they are available])
 483 if test "x$enable_iso_codes" = "xyes"; then
 484   AC_MSG_RESULT([yes])
 485   have_iso_codes=no
 486   AC_MSG_CHECKING([whether iso-codes are available on this system])
 487   if $PKG_CONFIG iso-codes; then
 488     AC_MSG_RESULT([yes])
 489     AC_MSG_CHECKING([whether iso-codes has iso-639 domain])
 490     if $PKG_CONFIG --variable=domains iso-codes | $GREP -q 639 ; then
 491       AC_MSG_RESULT([yes])
 492       AC_MSG_CHECKING([for iso-codes prefix])
 493       ISO_CODES_PREFIX=`$PKG_CONFIG --variable=prefix iso-codes`
 494       if test -d "$ISO_CODES_PREFIX"; then
 495         AC_MSG_RESULT([yes])
 496         AC_MSG_CHECKING([ISO_CODES_PREFIX])
 497         AC_MSG_RESULT([$ISO_CODES_PREFIX])
 498         ISO_639_DOMAIN="iso_639"
 499         AC_MSG_CHECKING([ISO_639_DOMAIN])
 500         AC_MSG_RESULT([$ISO_639_DOMAIN])
 501         have_iso_codes=yes
 502         AC_DEFINE([HAVE_ISO_CODES], [1], [make use of iso-codes for ISO-639])
 503         AC_DEFINE_UNQUOTED([ISO_CODES_PREFIX], ["$ISO_CODES_PREFIX"], [prefix])
 504         ISO_CODES_VERSION=`$PKG_CONFIG --modversion iso-codes`
 505         AC_DEFINE_UNQUOTED([ISO_CODES_VERSION], ["$ISO_CODES_VERSION"], [ ])
 506       else
 507         AC_MSG_RESULT([no])
 508       fi
 509     else
 510       AC_MSG_RESULT([no])
 511     fi
 512   else
 513     AC_MSG_RESULT([no])
 514   fi
 515   AM_CONDITIONAL(USE_ISO_CODES, test "x$have_iso_codes" = "xyes")
 516 else
 517   AC_MSG_RESULT([no (disabled via --disable-iso-codes)])
 518   AM_CONDITIONAL(USE_ISO_CODES, false)
 519 fi
 520
 521 dnl *** zlib is optionally used by id3 tag parsing in libgsttag ***
 522 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 523 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for ID3 parsing in libgsttag],, [
 524   PKG_CHECK_MODULES(ZLIB, [ zlib ], [
 525       HAVE_ZLIB="yes"
 526     ], [
 527       AG_GST_CHECK_LIBHEADER(ZLIB, z, uncompress,, zlib.h, [
 528         HAVE_ZLIB="yes"
 529         ZLIB_LIBS="-lz"
 530         AC_SUBST(ZLIB_LIBS)
 531       ])
 532     ])
 533 ])
 534
 535 dnl *** sys plug-ins ***
 536
 537 echo
 538 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 539 echo
 540
 541 dnl *** X11 ***
 542 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 543 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 544                   [ximagesink], [
 545   AC_PATH_XTRA
 546   ac_cflags_save="$CFLAGS"
 547   ac_cppflags_save="$CPPFLAGS"
 548   CFLAGS="$CFLAGS $X_CFLAGS"
 549   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 550
 551   dnl now try to find the HEADER
 552   HAVE_X="yes"
 553   AC_CHECK_HEADER([X11/Xlib.h], [], [HAVE_X="no"], [AC_INCLUDES_DEFAULT])
 554   AC_CHECK_HEADER([X11/XKBlib.h], [], [HAVE_X="no"], [AC_INCLUDES_DEFAULT])
 555
 556   if test "x$HAVE_X" = "xno"
 557   then
 558     AC_MSG_NOTICE([cannot find X11 development files])
 559   else
 560     dnl this is much more than we want
 561     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 562     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 563     dnl it does not add the libs; therefore we add them here
 564     X_LIBS="$X_LIBS -lX11"
 565     AC_SUBST(X_CFLAGS)
 566     AC_SUBST(X_LIBS)
 567   fi
 568   AC_SUBST(HAVE_X)
 569   CFLAGS="$ac_cflags_save"
 570   CPPFLAGS="$ac_cppflags_save"
 571 ])
 572
 573 dnl Check for Xv extension
 574 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 575 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 576                   [xvimagesink], [
 577   AG_GST_CHECK_XV
 578 ])
 579
 580 dnl check for X Shm
 581 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 582 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 583   if test x$HAVE_X = xyes; then
 584     AC_CHECK_LIB(Xext, XShmAttach,
 585                  HAVE_XSHM="yes", HAVE_XSHM="no",
 586                  $X_LIBS)
 587     if test "x$HAVE_XSHM" = "xyes"; then
 588       XSHM_LIBS="-lXext"
 589     else
 590       dnl On AIX, it is in XextSam instead, but we still need -lXext
 591       AC_CHECK_LIB(XextSam, XShmAttach,
 592                    HAVE_XSHM="yes", HAVE_XSHM="no",
 593                    $X_LIBS)
 594       if test "x$HAVE_XSHM" = "xyes"; then
 595         XSHM_LIBS="-lXext -lXextSam"
 596       fi
 597     fi
 598   fi
 599 ], , [
 600   AC_SUBST(HAVE_XSHM)
 601   AC_SUBST(XSHM_LIBS)
 602 ])
 603
 604 dnl *** ext plug-ins ***
 605 dnl keep this list sorted alphabetically !
 606
 607 if test "x$BUILD_EXTERNAL" = "xyes"; then
 608
 609 echo
 610 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 611 echo
 612
 613 dnl *** alsa ***
 614 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 615 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 616   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 617     HAVE_ALSA="yes"
 618     AC_SUBST(ALSA_CFLAGS)
 619     AC_SUBST(ALSA_LIBS)
 620   ], [
 621     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 622   ])
 623 ])
 624
 625 dnl *** CDParanoia ***
 626 dnl Note: upstream has a pkg-config file only in post-10.2 SVN so far
 627 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 628 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 629   PKG_CHECK_MODULES(CDPARANOIA, cdparanoia-3 >= 10.2, [
 630     HAVE_CDPARANOIA="yes"
 631   ], [
 632     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 633                         cdda_open, -lm,
 634                         cdda_interface.h,
 635                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 636                         HEADER_DIR="no"
 637                         FOUND_CDPARANOIA="yes")
 638     if test "x$FOUND_CDPARANOIA" != "xyes";
 639     then
 640       AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 641                           cdda_open, -lm,
 642                           cdda/cdda_interface.h,
 643                           CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 644                           HEADER_DIR="yes"
 645                           FOUND_CDPARANOIA="yes")
 646     fi
 647     if test "x$HEADER_DIR" = "xyes";
 648     then
 649       AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 650                          defined if cdda headers are in a cdda/ directory)
 651     fi
 652     if test "x$FOUND_CDPARANOIA" = "xyes";
 653     then
 654       AC_CHECK_LIB(cdda_paranoia,
 655                    paranoia_cachemodel_size,
 656                    : ,
 657                    HAVE_CDPARANOIA=no,
 658                  [-lcdda_interface])
 659     fi
 660
 661     AC_SUBST(CDPARANOIA_LIBS)
 662   ])
 663 ])
 664 dnl FIXME : add second check somehow if that is necessary
 665 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 666 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 667
 668 dnl *** ivorbis ***
 669 dnl AM_PATH_IVORBIS only takes two options
 670 translit(dnm, m, l) AM_CONDITIONAL(USE_IVORBIS, true)
 671 AG_GST_CHECK_FEATURE(IVORBIS, [integer vorbis plug-in], ivorbisdec, [
 672   AG_GST_PKG_CHECK_MODULES(IVORBIS, vorbisidec)
 673   if test $HAVE_IVORBIS = no
 674   then
 675     IVORBIS_LIBS=
 676     IVORBIS_CFLAGS=
 677     AC_CHECK_LIB(vorbisidec, vorbis_block_init,
 678       [IVORBIS_LIBS=-lvorbisidec
 679       HAVE_IVORBIS=yes
 680       case $host in
 681       arm-*-*)
 682         IVORBIS_CFLAGS="-D_ARM_ASSEM_ $IVORBIS_CFLAGS"
 683       esac
 684       ],
 685       HAVE_IVORBIS=no)
 686     AC_SUBST(IVORBIS_LIBS)
 687     AC_SUBST(IVORBIS_CFLAGS)
 688   else
 689     AC_CHECK_LIB(vorbisidec, vorbis_dsp_pcmout,
 690       AC_DEFINE([USE_TREMOLO],1, "Define if building for android"),
 691       USE_TREMOLO=no)
 692   fi
 693 ])
 694
 695 dnl *** libvisual ***
 696 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 697 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 698   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 699   if test $HAVE_LIBVISUAL = no
 700   then
 701     AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0)
 702     if test x$HAVE_LIBVISUAL = xyes; then
 703       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.2`"
 704     fi
 705   else
 706     if test x$HAVE_LIBVISUAL = xyes; then
 707       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.4`"
 708     fi
 709   fi
 710   AC_MSG_NOTICE([libvisual pluginsdir: $LIBVIS_PLUGINSDIR])
 711   if test x$LIBVIS_PLUGINSDIR != x; then
 712     AC_DEFINE_UNQUOTED(LIBVISUAL_PLUGINSBASEDIR,
 713         "$LIBVIS_PLUGINSDIR",
 714         [directory in which the detected libvisual's plugins are located])
 715   fi
 716 ])
 717
 718 dnl *** ogg ***
 719 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 720 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 721   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 722 ])
 723
 724 dnl *** pango ***
 725 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 726 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 727   AG_GST_PKG_CHECK_MODULES(PANGO, pango >= 1.22.0  pangocairo >= 1.22.0)
 728 ])
 729
 730 dnl *** theora ***
 731 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 732 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 733   AG_GST_PKG_CHECK_MODULES(THEORA, theoradec >= 1.1 theoraenc >= 1.1)
 734 ])
 735
 736 dnl *** vorbis ***
 737 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 738 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 739   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 740 ])
 741
 742 if test "x$HAVE_VORBIS" = "xyes"; then
 743   ac_cflags_save="$CFLAGS"
 744   AC_COMPILE_IFELSE([
 745     AC_LANG_PROGRAM([[
 746 #include <vorbis/codec.h>
 747                      ]],[[
 748 vorbis_dsp_state *v;
 749
 750 vorbis_synthesis_restart (v);
 751                      ]])], HAVE_VSR=yes, HAVE_VSR=no)
 752   if test "x$HAVE_VSR" = "xyes"; then
 753     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 754                        [defined if vorbis_synthesis_restart is present])
 755   fi
 756   CFLAGS="$ac_cflags_save"
 757 fi
 758
 759 else
 760
 761 dnl not building plugins with external dependencies,
 762 dnl but we still need to set the conditionals
 763 AM_CONDITIONAL(USE_ALSA, false)
 764 AM_CONDITIONAL(USE_CDPARANOIA, false)
 765 AM_CONDITIONAL(USE_IVORBIS, false)
 766 AM_CONDITIONAL(USE_LIBVISUAL, false)
 767 AM_CONDITIONAL(USE_OGG, false)
 768 AM_CONDITIONAL(USE_PANGO, false)
 769 AM_CONDITIONAL(USE_THEORA, false)
 770 AM_CONDITIONAL(USE_VORBIS, false)
 771
 772 fi dnl of EXT plugins
 773
 774 dnl seeking needs freetype, so check for it here
 775 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 776   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 777 ])
 778 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 779 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 780 AC_SUBST(FT2_CFLAGS)
 781 AC_SUBST(FT2_LIBS)
 782
 783 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 784
 785 dnl Overview:
 786 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 787 dnl GST_*:              flags shared by built objects to link against GStreamer
 788 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 789 dnl                          (compare to other modules) or for i18n
 790 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 791 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 792 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 793 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 794
 795 dnl GST_OPTION_CFLAGS
 796 if test "x$USE_DEBUG" = xyes; then
 797    PROFILE_CFLAGS="-g"
 798 fi
 799 AC_SUBST(PROFILE_CFLAGS)
 800
 801 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 802   dnl Define _only_ when compiling a git version (not pre-releases or releases)
 803   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 804 else
 805   DEPRECATED_CFLAGS=""
 806 fi
 807 AC_SUBST(DEPRECATED_CFLAGS)
 808
 809 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 810 dnl at make time with e.g. make ERROR_CFLAGS=""
 811 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 812 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 813 AC_SUBST(GST_OPTION_CFLAGS)
 814 AC_SUBST(GST_OPTION_CXXFLAGS)
 815
 816 dnl our libraries need to be versioned correctly
 817 AC_SUBST(GST_LT_LDFLAGS)
 818
 819 dnl GST_PLUGINS_BASE_CFLAGS
 820 dnl prefer internal headers to already installed ones
 821 dnl also add builddir include for enumtypes and marshal
 822 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 823 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 824
 825 dnl FIXME: do we want to rename to GST_ALL_* ?
 826 dnl add GST_OPTION_CFLAGS, but overridable
 827 GST_CFLAGS="$GST_CFLAGS"
 828 GST_CXXFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CXXFLAGS)"
 829 GST_CFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CFLAGS)"
 830 AC_SUBST(GST_CFLAGS)
 831 AC_SUBST(GST_CXXFLAGS)
 832 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 833 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 834 AC_SUBST(GST_LIBS)
 835
 836 dnl LDFLAGS really should only contain flags, not libs - they get added before
 837 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 838 GST_ALL_LDFLAGS="-no-undefined"
 839 if test "x${enable_Bsymbolic}" = "xyes"; then
 840   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 841 fi
 842 AC_SUBST(GST_ALL_LDFLAGS)
 843
 844 dnl GST_LIB_LDFLAGS
 845 dnl linker flags shared by all libraries
 846 dnl LDFLAGS modifier defining exported symbols from built libraries
 847 dnl (export _gst_foo but not __gst_foo)
 848 GST_LIB_LDFLAGS="-export-symbols-regex ^_?\(gst_\|Gst\|GST_\).*"
 849 AC_SUBST(GST_LIB_LDFLAGS)
 850
 851 dnl this really should only contain flags, not libs - they get added before
 852 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 853 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_.*' $GST_ALL_LDFLAGS"
 854 AC_SUBST(GST_PLUGIN_LDFLAGS)
 855
 856 dnl *** output files ***
 857
 858 $MKDIR_P tests/check/orc
 859
 860 AC_CONFIG_FILES(
 861 Makefile
 862 gst-plugins-base.spec
 863 gst/Makefile
 864 gst/adder/Makefile
 865 gst/app/Makefile
 866 gst/audioconvert/Makefile
 867 gst/audiorate/Makefile
 868 gst/audiotestsrc/Makefile
 869 gst/encoding/Makefile
 870 gst/videoconvert/Makefile
 871 gst/gio/Makefile
 872 gst/playback/Makefile
 873 gst/audioresample/Makefile
 874 gst/subparse/Makefile
 875 gst/tcp/Makefile
 876 gst/typefind/Makefile
 877 gst/videotestsrc/Makefile
 878 gst/videorate/Makefile
 879 gst/videoscale/Makefile
 880 gst/volume/Makefile
 881 sys/Makefile
 882 sys/ximage/Makefile
 883 sys/xvimage/Makefile
 884 ext/Makefile
 885 ext/alsa/Makefile
 886 ext/cdparanoia/Makefile
 887 ext/libvisual/Makefile
 888 ext/ogg/Makefile
 889 ext/pango/Makefile
 890 ext/theora/Makefile
 891 ext/vorbis/Makefile
 892 gst-libs/Makefile
 893 gst-libs/gst/Makefile
 894 gst-libs/gst/allocators/Makefile
 895 gst-libs/gst/audio/Makefile
 896 gst-libs/gst/app/Makefile
 897 gst-libs/gst/fft/Makefile
 898 gst-libs/gst/riff/Makefile
 899 gst-libs/gst/rtp/Makefile
 900 gst-libs/gst/rtsp/Makefile
 901 gst-libs/gst/sdp/Makefile
 902 gst-libs/gst/tag/Makefile
 903 gst-libs/gst/pbutils/Makefile
 904 gst-libs/gst/pbutils/gstpluginsbaseversion.h
 905 gst-libs/gst/video/Makefile
 906 tools/Makefile
 907 pkgconfig/Makefile
 908 pkgconfig/gstreamer-allocators.pc
 909 pkgconfig/gstreamer-allocators-uninstalled.pc
 910 pkgconfig/gstreamer-audio.pc
 911 pkgconfig/gstreamer-audio-uninstalled.pc
 912 pkgconfig/gstreamer-app.pc
 913 pkgconfig/gstreamer-app-uninstalled.pc
 914 pkgconfig/gstreamer-fft.pc
 915 pkgconfig/gstreamer-fft-uninstalled.pc
 916 pkgconfig/gstreamer-pbutils.pc
 917 pkgconfig/gstreamer-pbutils-uninstalled.pc
 918 pkgconfig/gstreamer-riff.pc
 919 pkgconfig/gstreamer-riff-uninstalled.pc
 920 pkgconfig/gstreamer-rtp.pc
 921 pkgconfig/gstreamer-rtp-uninstalled.pc
 922 pkgconfig/gstreamer-rtsp.pc
 923 pkgconfig/gstreamer-rtsp-uninstalled.pc
 924 pkgconfig/gstreamer-sdp.pc
 925 pkgconfig/gstreamer-sdp-uninstalled.pc
 926 pkgconfig/gstreamer-tag.pc
 927 pkgconfig/gstreamer-tag-uninstalled.pc
 928 pkgconfig/gstreamer-video.pc
 929 pkgconfig/gstreamer-video-uninstalled.pc
 930 pkgconfig/gstreamer-plugins-base.pc
 931 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 932 tests/Makefile
 933 tests/check/Makefile
 934 tests/examples/Makefile
 935 tests/examples/app/Makefile
 936 tests/examples/audio/Makefile
 937 tests/examples/dynamic/Makefile
 938 tests/examples/encoding/Makefile
 939 tests/examples/fft/Makefile
 940 tests/examples/gio/Makefile
 941 tests/examples/overlay/Makefile
 942 tests/examples/seek/Makefile
 943 tests/examples/snapshot/Makefile
 944 tests/examples/playback/Makefile
 945 tests/examples/playrec/Makefile
 946 tests/files/Makefile
 947 tests/icles/Makefile
 948 tests/icles/playback/Makefile
 949 docs/Makefile
 950 docs/design/Makefile
 951 docs/libs/Makefile
 952 docs/plugins/Makefile
 953 docs/version.entities
 954 po/Makefile.in
 955 common/Makefile
 956 common/m4/Makefile
 957 m4/Makefile
 958 )
 959
 960 dnl Create the config.h file for Visual Studio builds
 961 dnl Beware of spaces and /'s in some of the shell variable contents.
 962 sed \
 963     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 964     -e 's/.* GST_INSTALL_PLUGINS_HELPER/#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
 965     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 966     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 967     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 968     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 969     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
 970     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 971     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 972     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
 973     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 974     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 975     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 976     -e 's/.* HAVE_ISO_CODES$/#undef HAVE_ISO_CODES/' \
 977     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 978     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 979     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 980     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 981     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 982     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 983     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 984     -e 's/.* ISO_CODES_PREFIX$/#undef ISO_CODES_PREFIX/' \
 985     -e 's/.* ISO_CODES_VERSION$/#undef ISO_CODES_VERSION/' \
 986     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 987     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 988     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
 989     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 990     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
 991     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 992     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 993     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 994     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
 995     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
 996     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 997     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
 998     -e "s/.* DEFAULT_VIDEOSINK$/#define DEFAULT_VIDEOSINK \"directdrawsink\"/" \
 999     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1000     config.h.in >win32/common/config.h-new
1001
1002
1003
1004 AC_OUTPUT
1005
1006 AG_GST_OUTPUT_PLUGINS
1007 ORC_OUTPUT
1008