configure.ac

   1 AC_PREREQ(2.60)
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, git and prerelease does Werror too
   6 AC_INIT(GStreamer, 0.11.1.1,
   7     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
   8     gstreamer)
   9 AG_GST_INIT
  10
  11 dnl initialize automake (we require GNU make)
  12 AM_INIT_AUTOMAKE([-Wno-portability 1.10])
  13
  14 dnl define PACKAGE_VERSION_* variables
  15 AS_VERSION
  16
  17 dnl check if this is a release version
  18 AS_NANO(GST_GIT="no", GST_GIT="yes")
  19
  20 dnl can autoconf find the source ?
  21 AC_CONFIG_SRCDIR([gst/gst.c])
  22
  23 dnl define the output header for config
  24 AM_CONFIG_HEADER([config.h])
  25
  26 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  27 AM_MAINTAINER_MODE
  28
  29 dnl sets host_* variables
  30 AC_CANONICAL_HOST
  31
  32 dnl use pretty build output with automake >= 1.11
  33 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  34   [AM_DEFAULT_VERBOSITY=1
  35    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  36
  37 dnl our libraries and install dirs use major.minor as a version
  38 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  39 dnl we override it here for release candidates for a new series
  40 GST_MAJORMINOR=0.11
  41 AC_SUBST(GST_MAJORMINOR)
  42 AC_DEFINE_UNQUOTED(GST_MAJORMINOR, "$GST_MAJORMINOR",
  43   [library major.minor version])
  44
  45 dnl CURRENT, REVISION, AGE
  46 dnl - library source changed -> increment REVISION
  47 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  48 dnl - interfaces added -> increment AGE
  49 dnl - interfaces removed -> AGE = 0
  50 dnl sets GST_LT_LDFLAGS
  51 AS_LIBTOOL(GST, 31, 0, 0)
  52
  53 dnl FIXME: this macro doesn't actually work;
  54 dnl the generated libtool script has no support for the listed tags.
  55 dnl So this needs to be fixed first if we want to use this
  56 dnl AS_LIBTOOL_TAGS
  57
  58 AC_LIBTOOL_WIN32_DLL
  59 AM_PROG_LIBTOOL
  60
  61 dnl *** autotools stuff ****
  62
  63 dnl allow for different autotools
  64 AS_AUTOTOOLS_ALTERNATE
  65
  66 dnl Add parameters for aclocal (keep in sync with Makefile.am)
  67 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  68
  69 dnl set up gettext
  70 dnl the version check needs to stay here because autopoint greps for it
  71 AM_GNU_GETTEXT_VERSION([0.17])
  72 AM_GNU_GETTEXT([external])
  73 AG_GST_GETTEXT([gstreamer-$GST_MAJORMINOR])
  74
  75 dnl *** check for arguments to configure ***
  76
  77 dnl subsystems - can influence other decisions so needs to be high up
  78 dnl we need to AM_CONDITIONAL them here for automake 1.6.x compatibility
  79 AG_GST_CHECK_SUBSYSTEM_DISABLE(GST_DEBUG,[debugging subsystem])
  80 AM_CONDITIONAL(GST_DISABLE_GST_DEBUG, test "x$GST_DISABLE_GST_DEBUG" = "xyes")
  81 AG_GST_CHECK_SUBSYSTEM_DISABLE(PARSE,[command-line parser])
  82 AM_CONDITIONAL(GST_DISABLE_PARSE, test "x$GST_DISABLE_PARSE" = "xyes")
  83 if test "x$GST_DISABLE_PARSE" = xyes; then
  84   AC_DEFINE(GST_DISABLE_PARSE, 1,
  85     [Define if pipeline parsing code is disabled])
  86 fi
  87 AG_GST_CHECK_SUBSYSTEM_DISABLE(OPTION_PARSING,[option parsing when gst_init])
  88 AM_CONDITIONAL(GST_DISABLE_OPTION_PARSING, test "x$GST_DISABLE_OPTION_PARSING" = "xyes")
  89 if test "x$GST_DISABLE_OPTION_PARSING" = xyes; then
  90   AC_DEFINE(GST_DISABLE_OPTION_PARSING, 1,
  91     [Define if option parsing is disabled])
  92 fi
  93 AG_GST_CHECK_SUBSYSTEM_DISABLE(TRACE,[tracing subsystem])
  94 AM_CONDITIONAL(GST_DISABLE_TRACE, test "x$GST_DISABLE_TRACE" = "xyes")
  95 AG_GST_CHECK_SUBSYSTEM_DISABLE(ALLOC_TRACE,[allocation tracing])
  96 AM_CONDITIONAL(GST_DISABLE_ALLOC_TRACE, test "x$GST_DISABLE_ALLOC_TRACE" = "xyes")
  97 AG_GST_CHECK_SUBSYSTEM_DISABLE(REGISTRY,[plugin registry])
  98 AM_CONDITIONAL(GST_DISABLE_REGISTRY, test "x$GST_DISABLE_REGISTRY" = "xyes")
  99 dnl define a substitution to use in docs/gst/gstreamer.types
 100 if test "x$GST_DISABLE_REGISTRY" = "xyes"
 101 then
 102   GST_REGISTRY_DOC_TYPES="%"
 103 else
 104   GST_REGISTRY_DOC_TYPES=
 105 fi
 106 AC_SUBST(GST_REGISTRY_DOC_TYPES)
 107 AG_GST_CHECK_SUBSYSTEM_DISABLE(NET,[network distribution])
 108 AM_CONDITIONAL(GST_DISABLE_NET, test "x$GST_DISABLE_NET" = "xyes")
 109 AG_GST_CHECK_SUBSYSTEM_DISABLE(PLUGIN,[plugin])
 110 AM_CONDITIONAL(GST_DISABLE_PLUGIN, test "x$GST_DISABLE_PLUGIN" = "xyes")
 111
 112 AG_GST_ARG_DEBUG
 113 AG_GST_ARG_PROFILING
 114 AG_GST_ARG_VALGRIND
 115 AG_GST_ARG_GCOV
 116
 117 AG_GST_ARG_EXAMPLES
 118
 119 AG_GST_ARG_WITH_PKG_CONFIG_PATH
 120 AG_GST_ARG_WITH_PACKAGE_NAME
 121 AG_GST_ARG_WITH_PACKAGE_ORIGIN
 122
 123 AG_GST_PKG_CONFIG_PATH
 124
 125 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 126   ["${srcdir}/gstreamer.doap"],
 127   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 128
 129 dnl building of tests
 130 AC_ARG_ENABLE(tests,
 131   AC_HELP_STRING([--disable-tests], [disable building test apps]),
 132   [
 133     case "${enableval}" in
 134       yes) BUILD_TESTS=yes ;;
 135       no)  BUILD_TESTS=no ;;
 136       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 137     esac
 138   ],
 139 [BUILD_TESTS=yes]) dnl Default value
 140 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 141
 142 dnl tests known to fail
 143 AC_ARG_ENABLE(failing-tests,
 144   AC_HELP_STRING([--disable-failing-tests],
 145     [disable building tests known to fail]),
 146   [
 147     case "${enableval}" in
 148       yes) BUILD_FAILING_TESTS=yes ;;
 149       no)  BUILD_FAILING_TESTS=no ;;
 150       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-failing-tests) ;;
 151     esac
 152   ],
 153   [BUILD_FAILING_TESTS=no]) dnl Default value
 154 AM_CONDITIONAL(BUILD_FAILING_TESTS, test "x$BUILD_FAILING_TESTS" = "xyes")
 155 if test x$BUILD_FAILING_TESTS = xyes; then
 156   AC_MSG_WARN([building tests known to fail, use --disable-failing-tests to disable])
 157 else
 158   AC_MSG_WARN([Sissy ! By asking to not build the tests known to fail, you hereby waive your right to customer support.  If you do not agree with this EULA, please press Ctrl-C before the next line is printed.  By allowing the next line to be printed, you expressly acknowledge your acceptance of this EULA.])
 159 fi
 160
 161 dnl poison destroyed objects
 162 AC_ARG_ENABLE(poisoning,
 163   AC_HELP_STRING([--enable-poisoning],
 164     [enable poisoning of deallocated objects]),
 165   [
 166     case "${enableval}" in
 167       yes) USE_POISONING=yes ;;
 168       no)  USE_POISONING=no ;;
 169       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-poisoning) ;;
 170     esac
 171   ],
 172   [USE_POISONING=no]) dnl Default value
 173 if test "x$USE_POISONING" = xyes; then
 174   AC_DEFINE(USE_POISONING, 1,
 175     [Define if we should poison deallocated memory])
 176 fi
 177
 178 dnl *** checks for platform ***
 179
 180 dnl * hardware/architecture *
 181
 182 dnl common/m4/gst-arch.m4
 183 dnl check CPU type
 184 AG_GST_ARCH
 185 dnl substitution for win32/common/config.h
 186 HOST_CPU=$host_cpu
 187 AC_SUBST(HOST_CPU)
 188
 189 dnl common/m4/gst-arch.m4
 190 dnl check for unaligned access
 191 AG_GST_UNALIGNED_ACCESS
 192 dnl create a configure variable for gst/gstconfig.h
 193 if test x${as_cv_unaligned_access} = xyes ; then
 194   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 1"
 195 else
 196   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 0"
 197 fi
 198 AC_SUBST(GST_HAVE_UNALIGNED_ACCESS_DEFINE)
 199
 200 dnl check for platform specific settings
 201 AG_GST_PLATFORM
 202
 203 dnl * software *
 204
 205 dnl check for large file support
 206 dnl affected plugins must include config.h
 207 AC_SYS_LARGEFILE
 208
 209 dnl *** checks for programs ***
 210
 211 dnl find a compiler
 212 AC_PROG_CC
 213 AC_PROG_CC_STDC
 214
 215 dnl check if the compiler supports '-c' and '-o' options
 216 AM_PROG_CC_C_O
 217
 218 dnl find an assembler
 219 AM_PROG_AS
 220
 221 dnl determine if c++ is available on this system
 222 AC_PROG_CXX
 223 dnl CXX may be set to some default even if no c++ compiler is available
 224 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 225 AC_LANG_PUSH([C++])
 226 AC_TRY_COMPILE([ class Foo { int bar; };], , working_cxx=yes, working_cxx=no)
 227 AC_LANG_POP([C++])
 228 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 229 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 230
 231 dnl Perl is used in building documentation and in the version checks
 232 AC_PATH_PROG(PERL_PATH, perl, no)
 233 if test x$PERL_PATH = xno; then
 234   AC_MSG_ERROR(Could not find perl)
 235 fi
 236
 237 dnl we require flex and bison for building the parser
 238 if test "x$GST_DISABLE_PARSE" != xyes; then
 239   AG_GST_BISON_CHECK
 240   AG_GST_FLEX_CHECK
 241 fi
 242
 243 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 244 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 245
 246 dnl check for gobject-introspection
 247 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 248
 249 dnl check for documentation tools
 250 AG_GST_DOCBOOK_CHECK
 251 GTK_DOC_CHECK([1.3])
 252 AS_PATH_PYTHON([2.1])
 253 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 254
 255 dnl *** checks for libraries ***
 256
 257 dnl check for libm, for sin()
 258 AC_CHECK_LIBM
 259 AC_SUBST(LIBM)
 260
 261 dnl *** checks for header files ***
 262
 263 dnl check if we have ANSI C header files
 264 AC_HEADER_STDC
 265
 266 dnl Check for ucontext.h
 267 AC_CHECK_HEADERS([ucontext.h])
 268
 269 dnl Check for sys/socket.h
 270 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 271 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 272
 273 dnl check for sys/times.h for tests/examples/adapter/
 274 AC_CHECK_HEADERS([sys/times.h], HAVE_SYS_TIMES_H=yes)
 275 AC_CHECK_HEADERS([unistd.h], HAVE_UNISTD_H=yes)
 276 AM_CONDITIONAL(HAVE_SYS_TIMES_H_AND_UNISTD_H, test "x$HAVE_SYS_TIMES_H" = "xyes" -a "x$HAVE_UNISTD_H" = "xyes")
 277
 278 dnl Check for process.h for getpid() on win32
 279 AC_CHECK_HEADERS([process.h])
 280
 281 dnl Check for sys/utsname.h for uname
 282 AC_CHECK_HEADERS([sys/utsname.h])
 283
 284 dnl Check for stdio_ext.f for __fbufsize
 285 AC_CHECK_HEADERS([stdio_ext.h])
 286
 287 dnl check for pthreads
 288 AC_CHECK_HEADERS([pthread.h], HAVE_PTHREAD_H=yes)
 289 AM_CONDITIONAL(HAVE_PTHREAD_H, test "x$HAVE_PTHREAD_H" = "xyes")
 290
 291 dnl check for sys/prctl for setting thread name on Linux
 292 AC_CHECK_HEADERS([sys/prctl.h], HAVE_SYS_PRCTL_H=yes)
 293
 294 dnl Check for valgrind.h
 295 dnl separate from HAVE_VALGRIND because you can have the program, but not
 296 dnl the dev package
 297 AC_CHECK_HEADERS([valgrind/valgrind.h], HAVE_VALGRIND_H=yes)
 298
 299 dnl used in gst/gstpoll.c
 300 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 301 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 302 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 303   WIN32_LIBS="-lws2_32"
 304   AC_SUBST(WIN32_LIBS)
 305 fi
 306
 307 dnl check for GMP/GSL, used by the gst_util_uint64_scale unit test only
 308 if test "x$BUILD_TESTS" = "xyes"; then
 309   AG_GST_CHECK_LIBHEADER(GMP, gmp,
 310                          __gmpz_init_set_d, ,
 311                          gmp.h,
 312                          GMP_LIBS="-lgmp"
 313                          AC_SUBST(GMP_LIBS)
 314                          AC_DEFINE(HAVE_GMP, [1],[Have GMP library]))
 315   AG_GST_CHECK_LIBHEADER(GSL, gsl,
 316                          gsl_rng_uniform_int, -lgslcblas,
 317                          gsl/gsl_rng.h,
 318                          GSL_LIBS="-lgsl -lgslcblas"
 319                          AC_SUBST(GSL_LIBS)
 320                          AC_DEFINE(HAVE_GSL, [1],[Have GSL library]))
 321 fi
 322
 323 dnl *** checks for types/defines ***
 324
 325 dnl *** checks for structures ***
 326
 327 dnl *** checks for compiler characteristics ***
 328
 329 dnl check if the compiler supports __uint128_t (gcc)
 330 dnl Actually check for 128-bit division, since that's what we use
 331 dnl uint128_t for.
 332 AC_CACHE_CHECK(for __uint128_t, gst_cv_uint128_t,
 333     AC_TRY_LINK([ ], [
 334       static __uint128_t v1 = 100;
 335       static __uint128_t v2 = 10;
 336       static __uint128_t u;
 337       u = v1 / v2;
 338     ], [
 339       gst_cv_uint128_t=yes
 340     ], [
 341       gst_cv_uint128_t=no
 342     ])
 343 )
 344 if test x$gst_cv_uint128_t = xyes; then
 345   AC_DEFINE(HAVE_UINT128_T, 1, [Have __uint128_t type])
 346 fi
 347
 348 dnl *** checking for tm_gmtoff ***
 349 AC_MSG_CHECKING([for tm_gmtoff])
 350 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 351         #include <time.h>
 352         int main(void) {
 353           struct tm t;
 354           t.tm_gmtoff = 0;
 355           exit(0);
 356         }]])],
 357   [have_tm_gmtoff=yes
 358    AC_DEFINE(HAVE_TM_GMTOFF,1,[Have tm_gmtoff field in struct tm])],
 359   [have_tm_gmtoff=no],
 360   [have_tm_gmtoff="no (cross compiling)"])
 361 AC_MSG_RESULT($have_tm_gmtoff)
 362
 363
 364 dnl *** checks for library functions ***
 365
 366 AC_CHECK_FUNCS([gmtime_r])
 367 AC_CHECK_FUNCS([localtime_r])
 368 AC_CHECK_FUNCS([sigaction])
 369
 370 dnl check for fseeko()
 371 AC_FUNC_FSEEKO
 372 dnl check for ftello()
 373 AC_CHECK_FUNCS([ftello])
 374
 375 AC_CHECK_FUNCS([fgetpos])
 376 AC_CHECK_FUNCS([fsetpos])
 377
 378 dnl check for poll(), ppoll() and pselect()
 379 AC_CHECK_FUNCS([poll])
 380 AC_CHECK_FUNCS([ppoll])
 381 AC_CHECK_FUNCS([pselect])
 382
 383 AC_CHECK_HEADERS([sys/poll.h])
 384
 385 dnl ****************************************
 386 dnl *** GLib POLL* compatibility defines ***
 387 dnl ****************************************
 388
 389 AC_MSG_CHECKING([for broken poll])
 390 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 391         #include <stdlib.h>
 392         #include <fcntl.h>
 393         #include <poll.h>
 394         #ifdef HAVE_SYS_POLL_H
 395         #include <sys/poll.h>
 396         #endif
 397         int main(void) {
 398           struct pollfd fds[1];
 399           int fd;
 400           fd = open("/dev/null", 1);
 401           fds[0].fd = fd;
 402           fds[0].events = POLLIN;
 403           fds[0].revents = 0;
 404           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
 405                 exit(1);  /* Does not work for devices -- fail */
 406           }
 407           exit(0);
 408         }]])],
 409   [broken_poll=no],
 410   [broken_poll=yes
 411    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
 412   [broken_poll="no (cross compiling)"])
 413 AC_MSG_RESULT($broken_poll)
 414
 415 dnl check for mmap()
 416 AC_FUNC_MMAP
 417 AM_CONDITIONAL(HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 418
 419 dnl check for posix_memalign(), getpagesize()
 420 AC_CHECK_FUNCS([posix_memalign])
 421 AC_CHECK_FUNCS([getpagesize])
 422
 423 dnl Check for POSIX timers
 424 AC_CHECK_FUNCS(clock_gettime, [], [
 425   AC_CHECK_LIB(rt, clock_gettime, [
 426     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 427     LIBS="$LIBS -lrt"
 428   ])
 429 ])
 430
 431 AC_CACHE_CHECK(for posix timers, gst_cv_posix_timers,
 432     AC_TRY_COMPILE([
 433 #include <time.h>
 434 #ifdef HAVE_UNISTD_H
 435 #include <unistd.h>
 436 #endif
 437     ], [
 438 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 439 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 440 #endif
 441     ], [
 442       gst_cv_posix_timers=yes
 443     ], [
 444       gst_cv_posix_timers=no
 445     ])
 446 )
 447
 448 if test "$gst_cv_posix_timers" = "yes"; then
 449   AC_DEFINE(HAVE_POSIX_TIMERS,1,[Have posix timers])
 450   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 1"
 451 else
 452   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 0"
 453 fi
 454 AC_SUBST(GST_HAVE_POSIX_TIMERS_DEFINE)
 455 AM_CONDITIONAL(GST_HAVE_POSIX_TIMERS, test "$gst_cv_posix_timers" = "yes")
 456
 457 AC_CACHE_CHECK(for monotonic clock, gst_cv_monotonic_clock,
 458     AC_TRY_COMPILE([
 459 #include <time.h>
 460 #ifdef HAVE_UNISTD_H
 461 #include <unistd.h>
 462 #endif
 463     ], [
 464 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 465 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 466 #endif
 467     ], [
 468       gst_cv_monotonic_clock=yes
 469     ], [
 470       gst_cv_monotonic_clock=no
 471     ])
 472 )
 473
 474 if test "$gst_cv_monotonic_clock" = "yes"; then
 475   AC_DEFINE(HAVE_MONOTONIC_CLOCK,1,[Have a monotonic clock])
 476   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 1"
 477 else
 478   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 0"
 479 fi
 480 AC_SUBST(GST_HAVE_MONOTONIC_CLOCK_DEFINE)
 481 AM_CONDITIONAL(GST_HAVE_MONOTONIC_CLOCK, test "$gst_cv_monotonic_clock" = "yes")
 482
 483 dnl Check for a way to display the function name in debug output
 484 AG_GST_CHECK_FUNCTION
 485
 486 dnl test for register_printf_specifier or register_printf_function
 487 AC_CHECK_FUNCS([register_printf_specifier register_printf_function],
 488     [HAVE_PRINTF_EXTENSION=yes])
 489
 490 if test "$HAVE_PRINTF_EXTENSION" = yes; then
 491   GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE="#define GST_PTR_FORMAT \"P\""
 492   GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE="#define GST_SEGMENT_FORMAT \"Q\""
 493   GST_USING_PRINTF_EXTENSION_DEFINE="#define GST_USING_PRINTF_EXTENSION"
 494   AC_DEFINE(HAVE_PRINTF_EXTENSION, 1,
 495       [Defined if we have printf specifier extensions available])
 496 else
 497     GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE="#define GST_PTR_FORMAT \"p\""
 498     GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE="#define GST_SEGMENT_FORMAT \"p\""
 499     GST_USING_PRINTF_EXTENSION_DEFINE="#undef GST_USING_PRINTF_EXTENSION"
 500 fi
 501 AC_SUBST(GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE)
 502 AC_SUBST(GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE)
 503 AC_SUBST(GST_USING_PRINTF_EXTENSION_DEFINE)
 504
 505 dnl test if we have dladdr(); we use it for debugging; see gst/gstinfo.c
 506 save_cflags="$CFLAGS"
 507 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 508 AC_CHECK_LIB(dl, dladdr,
 509    AC_DEFINE(HAVE_DLADDR, 1, [Defined if we have dladdr ()])
 510    LIBS="$LIBS -ldl")
 511 CFLAGS="$save_cflags"
 512
 513 dnl *** checks for socket and nsl libraries ***
 514 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 515 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
 516
 517 dnl check for inet_aton()
 518 save_libs="$LIBS"
 519 AC_CHECK_FUNC(inet_aton, ,
 520    AC_CHECK_LIB(nsl, inet_aton, ,
 521       AC_CHECK_LIB(socket, inet_aton, ,
 522          AC_CHECK_LIB(resolv, inet_aton, ,[AC_DEFINE(NO_INET_ATON, 1, [Define if you have no native inet_aton() function.])]))))
 523 INET_ATON_LIBS=$LIBS
 524 AC_SUBST(INET_ATON_LIBS)
 525 LIBS="$save_libs"
 526
 527 dnl *** checks for dependency libraries ***
 528
 529 dnl GLib
 530 GLIB_REQ=2.26
 531
 532 AG_GST_GLIB_CHECK([$GLIB_REQ])
 533
 534 dnl Check for glib2 without extra fat, useful for the unversioned tool frontends
 535 PKG_CHECK_MODULES(GLIB_ONLY, glib-2.0 >= $GLIB_REQ)
 536
 537 dnl Check for documentation xrefs
 538 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 539 AC_SUBST(GLIB_PREFIX)
 540
 541 dnl building of unit test libraries
 542 AC_ARG_ENABLE(check,
 543   AC_HELP_STRING([--disable-check], [disable building unit test libraries]),
 544   [
 545     case "${enableval}" in
 546       yes) BUILD_CHECK=yes ;;
 547       no)  BUILD_CHECK=no ;;
 548       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-check) ;;
 549     esac
 550   ], [
 551     dnl Default value
 552     case $host_os in
 553       mingw* | msvc* | mks*) BUILD_CHECK=no ;;
 554       *) BUILD_CHECK=yes ;;
 555     esac
 556 ])
 557 dnl bit of a misnomer, but keep the conditional named like this so we don't
 558 dnl have to change too much elsewhere
 559 AM_CONDITIONAL(HAVE_CHECK, test "x$BUILD_CHECK" = "xyes")
 560
 561 dnl configure the desired memory alignment
 562 AC_ARG_WITH([memory-alignment],
 563   AS_HELP_STRING([--with-memory-alignment],[8,N,malloc,pagesize (default is 32)]),
 564   [
 565     if test "x$withval" = "xyes"
 566     then
 567       AC_DEFINE(MEMORY_ALIGNMENT, 32, [Memory alignment to use])
 568     else
 569       case "${withval}" in
 570         malloc) AC_DEFINE(MEMORY_ALIGNMENT_MALLOC, 1, [Memory alignment by malloc default]) ;;
 571         pagesize)  AC_DEFINE(MEMORY_ALIGNMENT_PAGESIZE, 1, [Memory alignment by pagesize]) ;;
 572         *)   AC_DEFINE_UNQUOTED(MEMORY_ALIGNMENT, ${withval}, [Memory alignment to use]) ;;
 573       esac
 574     fi
 575   ], [
 576     AC_DEFINE(MEMORY_ALIGNMENT_MALLOC, 1, [Memory alignment by malloc default])
 577   ]
 578 )
 579
 580 dnl Check for -Bsymbolic-functions linker flag used to avoid
 581 dnl intra-library PLT jumps, if available.
 582 AC_ARG_ENABLE(Bsymbolic,
 583               [AC_HELP_STRING([--disable-Bsymbolic],
 584                               [avoid linking with -Bsymbolic])],,
 585               [SAVED_LDFLAGS="${LDFLAGS}"
 586                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 587                LDFLAGS=-Wl,-Bsymbolic-functions
 588                AC_TRY_LINK([], [int main (void) { return 0; }],
 589                            AC_MSG_RESULT(yes)
 590                            enable_Bsymbolic=yes,
 591                            AC_MSG_RESULT(no)
 592                            enable_Bsymbolic=no)
 593                LDFLAGS="${SAVED_LDFLAGS}"])
 594
 595
 596 dnl *** set variables based on configure arguments
 597
 598 dnl set license and copyright notice
 599 GST_LICENSE="LGPL"
 600 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 601 AC_SUBST(GST_LICENSE)
 602
 603 dnl define LIBDIR, GST_DATADIR so we can inform people where we live
 604 AS_AC_EXPAND(LIBDIR, $libdir)
 605 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [library dir])
 606 AS_AC_EXPAND(DATADIR, $datadir)
 607 AC_DEFINE_UNQUOTED(GST_DATADIR, "$DATADIR", [data dir])
 608
 609 dnl set location of plugin directory
 610 AG_GST_SET_PLUGINDIR
 611
 612 GST_PKG_DEPS="glib-2.0, gobject-2.0, gmodule-no-export-2.0, gthread-2.0"
 613 AC_SUBST(GST_PKG_DEPS)
 614
 615 dnl make sure it doesn't complain about unused variables if debugging is disabled
 616 NO_WARNINGS=""
 617 if test "x${GST_DISABLE_GST_DEBUG}" = "xyes"; then
 618   NO_WARNINGS="-Wno-unused"
 619 fi
 620
 621 dnl define an ERROR_CFLAGS Makefile variable
 622 AG_GST_SET_ERROR_CFLAGS($GST_GIT, [-Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef -Wwrite-strings -Wformat-nonliteral -Wformat-security -Wold-style-definition -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return -Wno-multichar -Wnested-externs $NO_WARNINGS])
 623
 624 dnl define correct level for debugging messages
 625 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 626
 627 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 628
 629 dnl Overview:
 630 dnl GST_OPTION_CFLAGS:  common cflags for profiling, debugging, errors, ...
 631 dnl GST_ALL_*:          vars shared by all built objects
 632 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 633 dnl GST_OBJ_*:          additional vars to link to the core library
 634 dnl                     include GST_ALL_*
 635 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 636 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 637
 638 dnl GST_OPTION_CFLAGS
 639 if test "x$USE_DEBUG" = xyes; then
 640    PROFILE_CFLAGS="-g"
 641 fi
 642 AC_SUBST(PROFILE_CFLAGS)
 643
 644 # GST_DISABLE_DEPRECATED: hide the visibility of deprecated
 645 # functionality from the API that gstreamer uses
 646 # GST_REMOVE_DEPRECATED: don't compile deprecated functionality (breaks ABI)
 647 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 648   dnl Define _only_ when compiling from git (not for pre-releases or releases)
 649   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 650 else
 651   DEPRECATED_CFLAGS=""
 652 fi
 653 AC_SUBST(DEPRECATED_CFLAGS)
 654
 655 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time via e.g.
 656 dnl make DEPRECATED_CFLAGS=''
 657 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 658 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 659 GST_OPTION_CFLAGS="$GST_OPTION_CFLAGS -DGST_USE_UNSTABLE_API"
 660 GST_OPTION_CXXFLAGS="$GST_OPTION_CXXFLAGS -DGST_USE_UNSTABLE_API"
 661 AC_SUBST(GST_OPTION_CFLAGS)
 662 AC_SUBST(GST_OPTION_CXXFLAGS)
 663
 664 dnl GST_ALL_*
 665 dnl vars common to for all internal objects (core libs, elements, applications)
 666 dnl CFLAGS:
 667 dnl - src and build dirs need to be added because every piece that gets built
 668 dnl   will need the GStreamer source and generated headers
 669 dnl LIBS: XML doesn't need to be added because we don't explicitly use symbols
 670 dnl       from LibXML except for in the core library
 671 GST_ALL_CXXFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir)/libs -I\$(top_builddir) $GLIB_CFLAGS \$(GLIB_EXTRA_CFLAGS) $XML_CFLAGS \$(GST_OPTION_CXXFLAGS) \$(ERROR_CXXFLAGS)"
 672 GST_ALL_CFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir)/libs -I\$(top_builddir) $GLIB_CFLAGS \$(GLIB_EXTRA_CFLAGS) $XML_CFLAGS \$(GST_OPTION_CFLAGS) \$(ERROR_CFLAGS)"
 673
 674 dnl FIXME: check if LTLIBINTL is needed everywhere
 675 dnl I presume it is given that it contains the symbols that _() stuff maps to
 676 GST_ALL_LIBS="$GLIB_LIBS $LTLIBINTL \$(GCOV_LIBS)"
 677
 678 dnl LDFLAGS really should only contain flags, not libs - they get added before
 679 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 680 GST_ALL_LDFLAGS="-no-undefined"
 681 if test "x${enable_Bsymbolic}" = "xyes"; then
 682   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 683 fi
 684
 685 AC_SUBST(GST_ALL_CFLAGS)
 686 AC_SUBST(GST_ALL_CXXFLAGS)
 687 AC_SUBST(GST_ALL_LIBS)
 688 AC_SUBST(GST_ALL_LDFLAGS)
 689
 690 dnl GST_LIB_LDFLAGS
 691 dnl linker flags shared by all libraries
 692 dnl LDFLAGS modifier defining exported symbols from built libraries
 693 GST_LIB_LDFLAGS="-export-symbols-regex \^[_]?\(gst_\|Gst\|GST_\).*"
 694 AC_SUBST(GST_LIB_LDFLAGS)
 695
 696 dnl GST_OBJ_*
 697 dnl default vars for all internal objects built on libgstreamer
 698 dnl includes GST_ALL_*
 699 GST_OBJ_CFLAGS="\$(GST_ALL_CFLAGS)"
 700 GST_OBJ_CXXFLAGS="\$(GST_ALL_CXXFLAGS)"
 701 GST_OBJ_LIBS="\$(top_builddir)/gst/libgstreamer-$GST_MAJORMINOR.la \$(GST_ALL_LIBS)"
 702 AC_SUBST(GST_OBJ_CFLAGS)
 703 AC_SUBST(GST_OBJ_CXXFLAGS)
 704 AC_SUBST(GST_OBJ_LIBS)
 705
 706 dnl GST_PLUGIN_LDFLAGS
 707 dnl LDFLAGS for plugins; includes GST_ALL_LDFLAGS
 708 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
 709 AC_SUBST(GST_PLUGIN_LDFLAGS, "$GST_PLUGIN_LDFLAGS")
 710
 711 dnl plugin scanner locations
 712 AS_AC_EXPAND(GST_PLUGIN_SCANNER_INSTALLED,${libexecdir}/gstreamer-$GST_MAJORMINOR/gst-plugin-scanner)
 713 AC_DEFINE_UNQUOTED(GST_PLUGIN_SCANNER_INSTALLED,
 714     "$GST_PLUGIN_SCANNER_INSTALLED", [location of the installed gst-plugin-scanner])
 715 AC_SUBST(GST_PLUGIN_SCANNER_INSTALLED)
 716
 717 dnl things for our internal libcheck (must be called even if building
 718 dnl libcheck is disabled because it defines conditionals)
 719 AG_GST_CHECK_CHECKS()
 720
 721 AC_CONFIG_FILES(
 722 Makefile
 723 gst/Makefile
 724 gst/gstconfig.h
 725 gst/gstversion.h
 726 gst/parse/Makefile
 727 libs/Makefile
 728 libs/gst/Makefile
 729 libs/gst/base/Makefile
 730 libs/gst/check/Makefile
 731 libs/gst/check/libcheck/Makefile
 732 libs/gst/check/libcheck/check.h
 733 libs/gst/controller/Makefile
 734 libs/gst/helpers/Makefile
 735 libs/gst/net/Makefile
 736 plugins/Makefile
 737 plugins/elements/Makefile
 738 po/Makefile.in
 739 tests/Makefile
 740 tests/benchmarks/Makefile
 741 tests/check/Makefile
 742 tests/misc/Makefile
 743 tests/examples/Makefile
 744 tests/examples/adapter/Makefile
 745 tests/examples/controller/Makefile
 746 tests/examples/stepping/Makefile
 747 tests/examples/helloworld/Makefile
 748 tests/examples/launch/Makefile
 749 tests/examples/manual/Makefile
 750 tests/examples/metadata/Makefile
 751 tests/examples/queue/Makefile
 752 tests/examples/streams/Makefile
 753 tests/examples/typefind/Makefile
 754 tools/Makefile
 755 common/Makefile
 756 common/m4/Makefile
 757 docs/Makefile
 758 docs/design/Makefile
 759 docs/faq/Makefile
 760 docs/gst/Makefile
 761 docs/gst/gstreamer.types
 762 docs/libs/Makefile
 763 docs/plugins/Makefile
 764 docs/manual/Makefile
 765 docs/pwg/Makefile
 766 docs/slides/Makefile
 767 docs/xsl/Makefile
 768 docs/version.entities
 769 m4/Makefile
 770 pkgconfig/Makefile
 771 stamp.h
 772 pkgconfig/gstreamer.pc
 773 pkgconfig/gstreamer-uninstalled.pc
 774 pkgconfig/gstreamer-base.pc
 775 pkgconfig/gstreamer-base-uninstalled.pc
 776 pkgconfig/gstreamer-check.pc
 777 pkgconfig/gstreamer-check-uninstalled.pc
 778 pkgconfig/gstreamer-controller.pc
 779 pkgconfig/gstreamer-controller-uninstalled.pc
 780 pkgconfig/gstreamer-net.pc
 781 pkgconfig/gstreamer-net-uninstalled.pc
 782 gst-element-check.m4
 783 gstreamer.spec
 784 )
 785
 786 dnl Create the config.h file for Visual Studio builds
 787 dnl Beware of spaces and /'s in some of the shell variable contents.
 788 sed \
 789     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 790     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 791     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 792     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 793     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 794     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
 795     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 796     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 797     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
 798     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 799     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 800     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 801     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 802     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 803     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 804     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 805     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 806     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 807     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
 808     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 809     -e 's/.* MEMORY_ALIGNMENT_MALLOC/#define MEMORY_ALIGNMENT_MALLOC 1/' \
 810     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 811     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 812     -e 's/.* PACKAGE$/#define PACKAGE "gstreamer"/' \
 813     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 814     -e 's/.* PACKAGE_NAME$/#define PACKAGE_NAME "'$PACKAGE_NAME'"/' \
 815     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 816     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 817     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 818     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
 819     -e 's/.* GST_PLUGIN_SCANNER_INSTALLED$/#define GST_PLUGIN_SCANNER_INSTALLED LIBDIR "\\\\gst-plugin-scanner"/' \
 820     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 821     config.h.in >win32/common/config.h-new
 822
 823 AC_OUTPUT
 824
 825 dnl negate for output
 826 if test "x${GST_DISABLE_GST_DEBUG}" = "xno"; then enable_gst_debug="yes"; fi
 827 if test "x${GST_DISABLE_PARSE}" = "xno"; then enable_parse="yes"; fi
 828 if test "x${GST_DISABLE_OPTION_PARSING}" = "xno"; then enable_option_parsing="yes"; fi
 829 if test "x${GST_DISABLE_TRACE}" = "xno"; then enable_trace="yes"; fi
 830 if test "x${GST_DISABLE_ALLOC_TRACE}" = "xno"; then enable_alloc_trace="yes"; fi
 831 if test "x${GST_DISABLE_PLUGIN}" = "xno"; then enable_plugin="yes"; fi
 832 if test "x${GST_DISABLE_REGISTRY}" = "xno"; then enable_registry="yes"; fi
 833 if test "x${GST_DISABLE_NET}" = "xno"; then enable_net="yes"; fi
 834
 835 echo "
 836
 837 Configuration
 838         Version                    : ${VERSION}
 839         Source code location       : ${srcdir}
 840         Prefix                     : ${prefix}
 841         Compiler                   : ${CC}
 842         Package name               : ${GST_PACKAGE_NAME}
 843         Package origin             : ${GST_PACKAGE_ORIGIN}
 844
 845         Documentation (manuals)    : ${enable_docbook}
 846         Documentation (API)        : ${enable_gtk_doc}
 847
 848         Debug Logging              : ${enable_gst_debug}
 849         Command-line parser        : ${enable_parse}
 850         Option parsing in gst_init : ${enable_option_parsing}
 851         Tracing subsystem          : ${enable_trace}
 852         Allocation tracing         : ${enable_alloc_trace}
 853         Plugin registry            : ${enable_registry}
 854         Plugin support             : ${enable_plugin}
 855         Network support            : ${enable_net}
 856         Unit testing support       : ${BUILD_CHECK}
 857
 858         Debug                      : ${USE_DEBUG}
 859         Profiling                  : ${USE_PROFILING}
 860
 861         Building examples          : ${BUILD_EXAMPLES}
 862         Building test apps         : ${BUILD_TESTS}
 863         Building tests that fail   : ${BUILD_FAILING_TESTS}
 864 "