configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, cvs and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for cvs/pre
   8 AC_INIT(GStreamer Good Plug-ins, 0.10.6.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-good)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_CVS="no", GST_CVS="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl our libraries and install dirs use major.minor as a version
  36 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  37 dnl we override it here if we need to for the release candidate of new series
  38 GST_MAJORMINOR=0.10
  39 AC_SUBST(GST_MAJORMINOR)
  40
  41 dnl FIXME: this macro doesn't actually work;
  42 dnl the generated libtool script has no support for the listed tags.
  43 dnl So this needs to be fixed first if we want to use this
  44 dnl AS_LIBTOOL_TAGS
  45
  46 AM_PROG_LIBTOOL
  47
  48 dnl *** required versions of GStreamer stuff ***
  49 GST_REQ=0.10.15
  50 GSTPB_REQ=0.10.15
  51
  52 dnl *** autotools stuff ****
  53
  54 dnl allow for different autotools
  55 AS_AUTOTOOLS_ALTERNATE
  56
  57 dnl Add parameters for aclocal
  58 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  59
  60 dnl set up gettext
  61 dnl the version check needs to stay here because autopoint greps for it
  62 AM_GNU_GETTEXT_VERSION([0.11.5])
  63 AM_GNU_GETTEXT([external])
  64 AG_GST_GETTEXT([gst-plugins-good-$GST_MAJORMINOR])
  65
  66 dnl *** check for arguments to configure ***
  67
  68 AG_GST_ARG_DEBUG
  69 AG_GST_ARG_PROFILING
  70 AG_GST_ARG_VALGRIND
  71 AG_GST_ARG_GCOV
  72
  73 AG_GST_ARG_EXAMPLES
  74
  75 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  76 AG_GST_ARG_WITH_PACKAGE_NAME
  77 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  78
  79 dnl these are all the gst plug-ins, compilable without additional libs
  80 dnl videofilter is at the top because others depend on it
  81 GST_PLUGINS_ALL="\
  82                 videofilter \
  83                 alpha \
  84                 apetag \
  85                 audiofx \
  86                 auparse \
  87                 autodetect \
  88                 avi \
  89                 cutter \
  90                 debug \
  91                 effectv \
  92                 id3demux \
  93                 icydemux \
  94                 flx \
  95                 goom \
  96                 law \
  97                 level \
  98                 matroska \
  99                 monoscope \
 100                 multipart \
 101                 qtdemux \
 102                 rtp     \
 103                 rtsp    \
 104                 smpte   \
 105                 udp     \
 106                 videobox \
 107                 videocrop \
 108                 videomixer \
 109                 wavenc \
 110                 wavparse \
 111                 "
 112 AC_SUBST(GST_PLUGINS_ALL)
 113
 114 GST_PLUGINS_SELECTED=""
 115 AG_GST_ARG_WITH_PLUGINS
 116
 117 dnl disable gst plugins we might not be able to build on this
 118 dnl platform: udp and rtsp (ugly but minimally invasive)
 119 dnl FIXME: maybe move to sys
 120 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 121 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 122
 123 if test "x$HAVE_SYS_SOCKET_H" != "xyes" -a "x$HAVE_WINSOCK2_H" != "xyes"; then
 124   GST_PLUGINS_SELECTED=`echo $GST_PLUGINS_SELECTED | $SED -e s/udp//`
 125   GST_PLUGINS_SELECTED=`echo $GST_PLUGINS_SELECTED | $SED -e s/rtsp//`
 126 fi
 127
 128 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 129   WIN32_LIBS="-lws2_32"
 130   AC_SUBST(WIN32_LIBS)
 131 fi
 132
 133 AG_GST_ARG_ENABLE_EXTERNAL
 134
 135 AG_GST_ARG_ENABLE_EXPERIMENTAL
 136 USE_GST_V4L2=$BUILD_EXPERIMENTAL
 137 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 138         GST_PLUGINS_SELECTED=`echo $GST_PLUGINS_SELECTED | $SED -e s/monoscope//`
 139 fi
 140
 141 AC_SUBST(GST_PLUGINS_SELECTED)
 142
 143 dnl *** checks for platform ***
 144
 145 dnl * hardware/architecture *
 146
 147 dnl common/m4/gst-arch.m4
 148 dnl check CPU type
 149 AG_GST_ARCH
 150
 151 dnl Determine endianness
 152 AC_C_BIGENDIAN
 153
 154 dnl *** checks for programs ***
 155
 156 dnl find a compiler
 157 AC_PROG_CC
 158
 159 dnl determine c++ compiler
 160 AC_PROG_CXX
 161 dnl determine if c++ is available on this system
 162 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 163
 164 dnl determine c++ preprocessor
 165 dnl FIXME: do we need this ?
 166 AC_PROG_CXXCPP
 167
 168 AS_PROG_OBJC
 169
 170 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 171 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 172
 173 dnl check for gconftool-2
 174 dnl this macro defines an am conditional, so it needs to be run always
 175 AM_GCONF_SOURCE_2
 176
 177 dnl check for documentation tools
 178 GTK_DOC_CHECK([1.3])
 179 AS_PATH_PYTHON([2.1])
 180 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 181
 182 dnl *** checks for libraries ***
 183
 184 dnl check for libm, for sin()
 185 AC_CHECK_LIBM
 186 AC_SUBST(LIBM)
 187
 188 dnl *** checks for header files ***
 189
 190 dnl check if we have ANSI C header files
 191 AC_HEADER_STDC
 192
 193 dnl used by ext/wavpack
 194 AX_CREATE_STDINT_H
 195
 196 dnl used in gst/rtp/gstasteriskh263.c
 197 AC_CHECK_HEADERS([netinet/in.h])
 198 AC_CHECK_HEADERS([winsock2.h])
 199 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 200
 201 dnl used in gst/udp
 202 AC_CHECK_HEADERS([sys/time.h])
 203
 204 dnl *** checks for types/defines ***
 205
 206 dnl Check for FIONREAD ioctl declaration.  This check is needed
 207 dnl for the UDP plugin to build on Solaris
 208 GST_CHECK_FIONREAD
 209
 210 dnl *** checks for structures ***
 211
 212 dnl *** checks for compiler characteristics ***
 213
 214 dnl FIXME: check if this is used; was used for floatcast.h in base
 215 dnl Check for fast float to int casting as defined in C99
 216 AC_C99_FUNC_LRINT
 217 AC_C99_FUNC_LRINTF
 218
 219 dnl *** checks for library functions ***
 220
 221 LIBS_SAVE=$LIBS
 222 LIBS="$LIBS $LIBM"
 223 AC_CHECK_FUNCS(rint)
 224 LIBS=$LIBS_SAVE
 225
 226 dnl Check for mmap (needed by electricfence plugin)
 227 AC_FUNC_MMAP
 228 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" == "xyes")
 229
 230 dnl *** checks for dependency libraries ***
 231
 232 dnl GLib is required
 233 AG_GST_GLIB_CHECK([2.6])
 234
 235 dnl liboil is required
 236 PKG_CHECK_MODULES(LIBOIL, liboil-0.3 >= 0.3.8, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 237 if test "x${HAVE_LIBOIL}" != xyes ; then
 238   AC_ERROR([liboil-0.3.8 or later is required])
 239 fi
 240
 241 dnl checks for gstreamer
 242 dnl uninstalled is selected preferentially -- see pkg-config(1)
 243 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ])
 244 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ])
 245 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ])
 246 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ])
 247 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 248 AG_GST_CHECK_GST_PLUGINS_BASE($GST_MAJORMINOR, [$GSTPB_REQ])
 249
 250 GST_TOOLS_DIR=`pkg-config --variable=toolsdir gstreamer-$GST_MAJORMINOR`
 251 if test -z $GST_TOOLS_DIR; then
 252   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 253 fi
 254 AC_SUBST(GST_TOOLS_DIR)
 255
 256 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 257 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 258
 259 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 260
 261 dnl Check for documentation xrefs
 262 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 263 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 264 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_MAJORMINOR`"
 265 AC_SUBST(GLIB_PREFIX)
 266 AC_SUBST(GST_PREFIX)
 267 AC_SUBST(GSTPB_PREFIX)
 268
 269 dnl GTK is optional and used in examples
 270 HAVE_GTK=NO
 271 PKG_CHECK_MODULES(GTK2, gtk+-2.0 >= 2.2.0, HAVE_GTK_22=yes, HAVE_GTK_22=no)
 272 if test "x$HAVE_GTK_22" = "xyes"; then
 273   HAVE_GTK=yes
 274   GTK_VERSION=`$PKG_CONFIG --variable=gtk_binary_version gtk+-2.0`
 275   AC_SUBST(GTK_VERSION)
 276   GTK_PREFIX=`$PKG_CONFIG --variable=prefix gdk-pixbuf-2.0`
 277   AC_SUBST(GTK_BASE_DIR)
 278   GDK_PIXBUF_LIBDIR=`$PKG_CONFIG --variable=libdir gdk-pixbuf-2.0`
 279   GDK_PIXBUF_PREFIXDIR=`$PKG_CONFIG --variable=prefix gdk-pixbuf-2.0`
 280   AC_SUBST(GTK_BASE_DIR)
 281 else
 282   PKG_CHECK_MODULES(GTK2, gtk+-2.0, HAVE_GTK_20=yes, HAVE_GTK_20=no)
 283 fi
 284 if test "x$HAVE_GTK_20" = "xyes"; then
 285   HAVE_GTK=yes
 286 fi
 287 GTK_CFLAGS=$GTK2_CFLAGS
 288 GTK_LIBS=$GTK2_LIBS
 289 AC_SUBST(GTK_LIBS)
 290 AC_SUBST(GTK_CFLAGS)
 291 AC_SUBST(HAVE_GTK)
 292 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 293
 294 dnl should we install schemas ?
 295 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONFTOOL, true)
 296 AG_GST_CHECK_FEATURE(GCONFTOOL, [GConf schemas], , [
 297   AC_PATH_PROG(GCONFTOOL, gconftool-2, no)
 298   if test x$GCONFTOOL = xno; then
 299     AC_MSG_WARN(Not installing GConf schemas)
 300     HAVE_GCONFTOOL="no"
 301   else
 302     HAVE_GCONFTOOL="yes"
 303   fi
 304   AC_SUBST(HAVE_GCONFTOOL)
 305 ])
 306
 307 dnl *** set variables based on configure arguments ***
 308
 309 dnl set license and copyright notice
 310 GST_LICENSE="LGPL"
 311 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 312 AC_SUBST(GST_LICENSE)
 313
 314 dnl set location of plugin directory
 315 AG_GST_SET_PLUGINDIR
 316
 317 dnl define an ERROR_CFLAGS Makefile variable
 318 AG_GST_SET_ERROR_CFLAGS($GST_CVS)
 319
 320 dnl define correct level for debugging messages
 321 AG_GST_SET_LEVEL_DEFAULT($GST_CVS)
 322
 323 dnl used in examples
 324 AG_GST_DEFAULT_ELEMENTS
 325
 326 dnl *** sys plug-ins ***
 327
 328 echo
 329 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 330 echo
 331
 332 dnl DirectDraw
 333 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTDRAW, true)
 334 AG_GST_CHECK_FEATURE(DIRECTDRAW, [DirectDraw plug-in], directdrawsink, [
 335   HAVE_DIRECTDRAW="no"
 336   save_CFLAGS="$CFLAGS"
 337   save_LDFLAGS="$LDFLAGS"
 338   save_LIBS="$LIBS"
 339   CFLAGS="$CFLAGS $DIRECTDRAW_CFLAGS"
 340   LDFLAGS="$LDFLAGS $DIRECTDRAW_LDFLAGS"
 341   LIBS="$LIBS -lddraw -lgdi32"
 342   AC_MSG_CHECKING(for DirectDraw LDFLAGS)
 343   AC_LINK_IFELSE([
 344 #include <windows.h>
 345 #include <ddraw.h>
 346
 347 int main ()
 348 {
 349   GetStockObject(0);
 350   DirectDrawCreate(NULL, NULL, NULL);
 351
 352   return 0;
 353 }
 354 ],
 355     [HAVE_DIRECTDRAW="yes"],
 356     [HAVE_DIRECTDRAW="no"])
 357   AC_MSG_RESULT($HAVE_DIRECTDRAW)
 358   CFLAGS=$save_CFLAGS
 359   LDFLAGS=$save_LDFLAGS
 360   LIBS=$save_LIBS
 361
 362   if test "x$HAVE_DIRECTDRAW" = "xyes";  then
 363     dnl this is much more than we want
 364     DIRECTDRAW_LIBS="-lddraw -ldxguid -lgdi32"
 365     AC_SUBST(DIRECTDRAW_CFLAGS)
 366     AC_SUBST(DIRECTDRAW_LDFLAGS)
 367     AC_SUBST(DIRECTDRAW_LIBS)
 368   fi
 369   AC_SUBST(HAVE_DIRECTDRAW)
 370 ])
 371
 372 dnl DirectSound
 373 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 374 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 375   HAVE_DIRECTSOUND="no"
 376   save_CFLAGS="$CFLAGS"
 377   save_LDFLAGS="$LDFLAGS"
 378   save_LIBS="$LIBS"
 379   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 380   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 381   LIBS="$LIBS -ldsound -ldxerr9"
 382   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 383   AC_LINK_IFELSE([
 384 #include <windows.h>
 385 #include <dxerr9.h>
 386 #include <dsound.h>
 387
 388 int main ()
 389 {
 390   DXGetErrorString9 (0);
 391   DirectSoundCreate(NULL, NULL, NULL);
 392
 393   return 0;
 394 }
 395 ],
 396     [HAVE_DIRECTSOUND="yes"],
 397     [HAVE_DIRECTSOUND="no"])
 398   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 399   CFLAGS=$save_CFLAGS
 400   LDFLAGS=$save_LDFLAGS
 401   LIBS=$save_LIBS
 402
 403   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 404     dnl this is much more than we want
 405     DIRECTSOUND_LIBS="-ldsound -ldxerr9"
 406     AC_SUBST(DIRECTSOUND_CFLAGS)
 407     AC_SUBST(DIRECTSOUND_LDFLAGS)
 408     AC_SUBST(DIRECTSOUND_LIBS)
 409   fi
 410   AC_SUBST(HAVE_DIRECTSOUND)
 411 ])
 412
 413 dnl *** OSS audio *** (Linux, *BSD)
 414 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 415 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 416  HAVE_OSS="yes"
 417 dnl Linux and newer BSD versions :
 418  AC_CHECK_HEADER(sys/soundcard.h, [
 419    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 420    ] , [
 421 dnl Some old BSD versions and also newer OpenBSD versions :
 422    AC_CHECK_HEADER(soundcard.h, [
 423      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 424      ], [
 425   dnl Some old BSD versions :
 426      AC_CHECK_HEADER(machine/soundcard.h, [
 427        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 428          [Define if OSS includes are in /machine/])
 429        ], [
 430        HAVE_OSS="no"
 431      ])
 432    ])
 433  ])
 434 ])
 435
 436 dnl *** Sun Audio ***
 437 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 438 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 439   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 440 ])
 441
 442 dnl *** OSX Audio ***
 443 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 444 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 445   AC_CHECK_HEADER(CoreAudio/CoreAudio.h, HAVE_OSX_AUDIO="yes", HAVE_OSX_AUDIO="no")
 446 ])
 447
 448 dnl *** OS X video ***
 449 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 450 HAVE_OSX_VIDEO="no"
 451 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 452   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 453 ])
 454 dnl in case header OpenGL/gl.h is found on other platforms
 455 case "$host" in
 456   *-*darwin*)
 457     dnl do nothing
 458     ;;
 459   *)
 460     HAVE_OSX_VIDEO="no"
 461     ;;
 462 esac
 463
 464
 465 dnl *** Video 4 Linux 2 ***
 466 dnl for information about the header/define, see sys/v4l2/gstv4l2element.h
 467 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 468 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 469 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], v4l2src, [
 470   AC_MSG_CHECKING([Checking for uptodate v4l2 installation])
 471   AC_TRY_COMPILE([
 472 #include <sys/types.h>
 473 #include <linux/types.h>
 474 #define _LINUX_TIME_H
 475 #define __user
 476 #include <linux/videodev2.h>
 477 #if defined(V4L2_MAJOR_VERSION) || defined(V4L2_MINOR_VERSION)
 478 #error too early v4l2 version or no v4l2 at all
 479 #endif
 480     ], [
 481 return 0;
 482     ], [
 483       HAVE_GST_V4L2="yes"
 484       AC_MSG_RESULT(yes)
 485     ], [
 486       HAVE_GST_V4L2="no"
 487       AC_MSG_RESULT(no)
 488       AC_CHECK_HEADER(linux/videodev2.h,
 489       [
 490         AC_MSG_WARN([video4linux2 headers were found, but they're old.])
 491         AC_MSG_WARN([Please update v4l2 to compile the v4l2 plugins])
 492       ], [
 493         AC_MSG_WARN([video4linux2 was not found])
 494       ])
 495     ])
 496
 497   if [ test x$HAVE_GST_V4L2 = xyes ]; then
 498     dnl check for missing v4l2_buffer declaration (see #135919)
 499     MISSING_DECL=0
 500     AC_MSG_CHECKING(struct v4l2_buffer declaration)
 501     AC_TRY_COMPILE([
 502 #include <sys/types.h>
 503 #include <linux/types.h>
 504 #define _LINUX_TIME_H
 505 #define __user
 506 #include <linux/videodev2.h>
 507     ],[
 508 struct v4l2_buffer buf;
 509 buf.index = 0;
 510 return 0;
 511     ], [ AC_MSG_RESULT(yes) ], [ MISSING_DECL=1 && AC_MSG_RESULT(no) ])
 512     if [ test x$MISSING_DECL = x1 ]; then
 513       AC_DEFINE(GST_V4L2_MISSING_BUFDECL, 1, [struct v4l2_buffer missing])
 514     fi
 515
 516     dnl check for XOverlay libraries
 517     AG_GST_CHECK_XV
 518   fi
 519 ])
 520
 521 dnl Check for X11
 522 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 523 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 524                   [ximagesrc], [
 525   AC_PATH_XTRA
 526
 527   dnl now try to find the HEADER
 528   ac_cflags_save="$CFLAGS"
 529   ac_cppflags_save="$CPPFLAGS"
 530   CFLAGS="$CFLAGS $X_CFLAGS"
 531   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 532   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 533
 534   if test "x$HAVE_X" = "xno"
 535   then
 536     AC_MSG_NOTICE([cannot find X11 development files])
 537   else
 538     dnl this is much more than we want
 539     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 540     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 541     dnl it does not add the libs; therefore we add them here
 542     X_LIBS="$X_LIBS -lX11"
 543     AC_SUBST(X_CFLAGS)
 544     AC_SUBST(X_LIBS)
 545
 546     dnl check for Xfixes
 547     PKG_CHECK_MODULES(XFIXES, xfixes, HAVE_XFIXES="yes", HAVE_XFIXES="no")
 548     if test "x$HAVE_XFIXES" = "xyes"
 549     then
 550         XFIXES_CFLAGS="-DHAVE_XFIXES $XFIXES_CFLAGS"
 551     fi
 552     AC_SUBST(XFIXES_LIBS)
 553     AC_SUBST(XFIXES_CFLAGS)
 554
 555     dnl check for Xdamage
 556     PKG_CHECK_MODULES(XDAMAGE, xdamage, HAVE_XDAMAGE="yes", HAVE_XDAMAGE="no")
 557     if test "x$HAVE_XDAMAGE" = "xyes"
 558     then
 559         XDAMAGE_CFLAGS="-DHAVE_XDAMAGE $XDAMAGE_CFLAGS"
 560     fi
 561     AC_SUBST(XDAMAGE_LIBS)
 562     AC_SUBST(XDAMAGE_CFLAGS)
 563   fi
 564   AC_SUBST(HAVE_X)
 565   CFLAGS="$ac_cflags_save"
 566   CPPFLAGS="$ac_cppflags_save"
 567 ])
 568
 569 dnl FIXME: this should be rolled into the test above, it's just an additional
 570 dnl feature of the ximagesrc plug-in
 571 dnl This is the same as in gst-plugins-base
 572 dnl check for X Shm
 573 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 574 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 575   if test x$HAVE_X = xyes; then
 576     AC_CHECK_LIB(Xext, XShmAttach,
 577                  HAVE_XSHM="yes", HAVE_XSHM="no",
 578                  $X_LIBS)
 579     if test "x$HAVE_XSHM" = "xyes"; then
 580       XSHM_LIBS="-lXext"
 581     else
 582       dnl On AIX, it is in XextSam instead, but we still need -lXext
 583       AC_CHECK_LIB(XextSam, XShmAttach,
 584                    HAVE_XSHM="yes", HAVE_XSHM="no",
 585                    $X_LIBS)
 586       if test "x$HAVE_XSHM" = "xyes"; then
 587         XSHM_LIBS="-lXext -lXextSam"
 588       fi
 589     fi
 590   fi
 591 ], ,[
 592   AC_SUBST(HAVE_XSHM)
 593   AC_SUBST(XSHM_LIBS)
 594 ])
 595
 596 dnl for V4L2, we also need to know if we have XVIDEO
 597 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 598 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 599                   [], [
 600   AG_GST_CHECK_XV
 601 ])
 602
 603 dnl *** ext plug-ins ***
 604 dnl keep this list sorted alphabetically !
 605
 606 if test "x$BUILD_EXTERNAL" = "xyes"; then
 607
 608 echo
 609 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 610 echo
 611
 612 dnl *** aalib ***
 613 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 614 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 615   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 616   AS_SCRUB_INCLUDE(AALIB_CFLAGS)
 617 ])
 618
 619 dnl *** annodex ***
 620 translit(dnm, m, l) AM_CONDITIONAL(USE_ANNODEX, true)
 621 AG_GST_CHECK_FEATURE(ANNODEX, [XML library], annodex, [
 622   AG_GST_PKG_CHECK_MODULES(ANNODEX, libxml-2.0 >= 2.4.9)
 623 ])
 624
 625 dnl *** cairo ***
 626 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 627 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering], cairo, [
 628   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.0.0)
 629 ])
 630
 631 dnl *** cdio ***
 632 translit(dnm, m, l) AM_CONDITIONAL(USE_CDIO, true)
 633 AG_GST_CHECK_FEATURE(CDIO, [cdio library], cdio, [
 634   AG_GST_PKG_CHECK_MODULES(CDIO, libcdio >= 0.71)
 635 ])
 636
 637 dnl **** ESound ****
 638 translit(dnm, m, l) AM_CONDITIONAL(USE_ESD, true)
 639 AG_GST_CHECK_FEATURE(ESD, [ESounD sound daemon], esdsink, [
 640   AG_GST_PKG_CHECK_MODULES(ESD, esound >= 0.2.12)
 641   if test $HAVE_ESD = no
 642   then
 643     AM_PATH_ESD(0.2.12, HAVE_ESD="yes")
 644     AS_SCRUB_INCLUDE(ESD_CFLAGS)
 645   fi
 646 ])
 647
 648 dnl *** FLAC ***
 649 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 650 AC_TRY_COMPILE([#include <FLAC/export.h>], [
 651   #if FLAC_API_VERSION_CURRENT < 8
 652   #error "legacy flac API"
 653   #endif
 654   ], [ legacy_flac=no ], [ legacy_flac=yes ], [ legacy_flac=no ])
 655
 656 if test "x$legacy_flac" = "xyes"; then
 657 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 658   AG_GST_CHECK_LIBHEADER(FLAC, FLAC, FLAC__seekable_stream_encoder_new, -lm, FLAC/all.h, FLAC_LIBS="-lFLAC -lm")
 659   dnl API change in FLAC 1.1.1, so require that...
 660   dnl (this check will also fail with FLAC 1.1.3 which changed API again)
 661   if test x$HAVE_FLAC = xyes; then
 662     AC_CHECK_DECL(FLAC__SEEKABLE_STREAM_ENCODER_TELL_ERROR,
 663                   HAVE_FLAC="yes", HAVE_FLAC="no", [
 664 #include <FLAC/seekable_stream_encoder.h>
 665                   ])
 666   fi
 667   AC_SUBST(FLAC_LIBS)
 668 ])
 669 else
 670 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 671   AG_GST_CHECK_LIBHEADER(FLAC, FLAC, FLAC__stream_encoder_new, -lm, FLAC/all.h, FLAC_LIBS="-lFLAC -lm")
 672   dnl API change in FLAC 1.1.3, so require that...
 673   if test x$HAVE_FLAC = xyes; then
 674     AC_CHECK_DECL(FLAC__STREAM_ENCODER_TELL_STATUS_ERROR,
 675                   HAVE_FLAC="yes", HAVE_FLAC="no", [
 676 #include <FLAC/stream_encoder.h>
 677                   ])
 678   fi
 679   AC_SUBST(FLAC_LIBS)
 680 ])
 681 fi
 682
 683 dnl *** GConf ***
 684 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONF, true)
 685 AG_GST_CHECK_FEATURE(GCONF, [GConf libraries], gconfelements, [
 686   AG_GST_PKG_CHECK_MODULES(GCONF, gconf-2.0)
 687 ])
 688
 689 dnl *** GDK pixbuf ***
 690 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 691 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 692   if test $HAVE_GTK_22 = "yes"; then HAVE_GDK_PIXBUF=yes; fi;
 693 ])
 694
 695 dnl *** HAL ***
 696 translit(dnm, m, l) AM_CONDITIONAL(USE_HAL, true)
 697 AG_GST_CHECK_FEATURE(HAL, [HAL libraries], halelements, [
 698   AG_GST_PKG_CHECK_MODULES(HAL, [hal >= 0.5.6, dbus-1 >= 0.32])
 699 ])
 700
 701 dnl *** jpeg ***
 702 dnl FIXME: we could use header checks here as well IMO
 703 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 704 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 705   AC_ARG_WITH(jpeg-mmx,
 706     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 707   OLD_LIBS="$LIBS"
 708   if test x$with_jpeg_mmx != x; then
 709     LIBS="$LIBS -L$with_jpeg_mmx"
 710   fi
 711   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 712   JPEG_LIBS="$LIBS -ljpeg-mmx"
 713   LIBS="$OLD_LIBS"
 714   if test x$HAVE_JPEG != xyes; then
 715     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 716     JPEG_LIBS="-ljpeg"
 717   fi
 718   AC_SUBST(JPEG_LIBS)
 719 ])
 720
 721 dnl *** ladspa ***
 722 translit(dnm, m, l) AM_CONDITIONAL(USE_LADSPA, true)
 723 AG_GST_CHECK_FEATURE(LADSPA, [ladspa], ladspa, [
 724   AC_CHECK_HEADER(ladspa.h, HAVE_LADSPA="yes", HAVE_LADSPA="no")
 725 ], disabled)
 726
 727 dnl *** libcaca ***
 728 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 729 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 730   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 731   dnl only newer versions of libcaca ship caca.pc, so try caca-config as well
 732   if test "x$HAVE_LIBCACA" != "xyes"; then
 733     AG_GST_CHECK_CONFIGPROG(LIBCACA, caca-config)
 734     dnl see if it compilation works too, might not if we are cross-compiling
 735     if test "x$HAVE_LIBCACA" = "xyes"; then
 736       AC_CHECK_LIB([caca], [caca_init], [HAVE_LIBCACA=yes],
 737                    [HAVE_LIBCACA=no], [$LIBCACA_LIBS])
 738     fi
 739   fi
 740 ])
 741
 742 dnl *** libdv ***
 743 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 744 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 745   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 746 ])
 747
 748 dnl *** libpng ***
 749 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 750 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 751   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng12)
 752 ])
 753
 754 dnl *** dv1394 ***
 755 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 756 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 757   dnl first test for libraw1394 >= 1.2.1
 758   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.2.1)
 759   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 760   dnl now see how far we got
 761   if test x$HAVE_RAW1394 = xyes && \
 762      test x$HAVE_LIBIEC61883 = xyes; then
 763        AG_GST_CHECK_LIBHEADER(AVC1394,
 764         avc1394, avc1394_send_command, $RAW1394_LIBS,
 765         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 766        AG_GST_CHECK_LIBHEADER(ROM1394,
 767         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 768         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 769        if test x$HAVE_AVC1394 = xyes && \
 770           test x$HAVE_AVC1394 = xyes && \
 771           test x$HAVE_ROM1394 = xyes; then
 772           HAVE_DV1394=yes
 773           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 774           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 775           AC_SUBST(DV1394_CFLAGS)
 776           AC_SUBST(DV1394_LIBS)
 777         fi
 778   else
 779        if test x$HAVE_RAW1394 = xno; then
 780           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 781           AG_GST_CHECK_LIBHEADER(AVC1394,
 782            avc1394, avc1394_send_command, $RAW1394_LIBS,
 783            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 784           AG_GST_CHECK_LIBHEADER(ROM1394,
 785            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 786            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 787           if test x$HAVE_RAW1394 = xyes && \
 788              test x$HAVE_AVC1394 = xyes && \
 789              test x$HAVE_ROM1394 = xyes; then
 790              HAVE_DV1394=yes
 791              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 792              DV1394_CFLAGS="$RAW1394_CFLAGS"
 793              if test x$HAVE_LIBIEC61883 = xyes; then
 794                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 795                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 796              fi
 797              AC_SUBST(DV1394_CFLAGS)
 798              AC_SUBST(DV1394_LIBS)
 799            fi
 800          fi
 801   fi
 802 ])
 803
 804 dnl *** shout2 ***
 805 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 806 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 807   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 808   if test $HAVE_SHOUT2 = no
 809   then
 810     AM_PATH_SHOUT2(HAVE_SHOUT2="yes")
 811     AC_SUBST(SHOUT2_CFLAGS)
 812     AC_SUBST(SHOUT2_LIBS)
 813   fi
 814 ])
 815
 816 dnl *** speex >= 1.0.4 or >= 1.1.5 ***
 817 dnl   1.1.4 and earlier were not API/ABI compatible with 1.0
 818 dnl   1.1.6 is the first to use a .pc/pkg-config file ***
 819 dnl   speex_jitter.h is 1.1.x only
 820 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 821 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 822   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 823   if test $HAVE_SPEEX = no
 824   then
 825     AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_bits_init, , speex/speex.h, [
 826       AC_CHECK_HEADER(speex/speex_jitter.h, [
 827         dnl speex 1.1.x :
 828         AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_encode_int, , speex/speex.h, [
 829           dnl speex 1.1.5 or + :
 830           HAVE_SPEEX="yes"
 831           SPEEX_LIBS="-lspeex"
 832           AC_SUBST(SPEEX_CFLAGS)
 833           AC_SUBST(SPEEX_LIBS)
 834         ],[
 835           HAVE_SPEEX="no"
 836         ])
 837       ],[
 838         dnl speex 1.0.x :
 839           AC_CHECK_DECL(SPEEX_GET_LOOKAHEAD, [
 840             dnl speex 1.0.4
 841             HAVE_SPEEX="yes"
 842             SPEEX_LIBS="-lspeex"
 843             AC_SUBST(SPEEX_CFLAGS)
 844             AC_SUBST(SPEEX_LIBS)
 845
 846             AC_DEFINE_UNQUOTED(SPEEX_1_0, 1,
 847               [defined if speex 1.0.x API detected])
 848         ],[
 849             HAVE_SPEEX="no"
 850             AC_MSG_NOTICE(You need at least 1.0.4 to compile the speex plugin)
 851         ], [
 852 #include <speex/speex.h>
 853         ])
 854       ])
 855     ])
 856   fi
 857 ])
 858
 859 dnl *** taglib ***
 860 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 861 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 862   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.4)
 863   if test "x$HAVE_CXX" != "xyes"; then
 864     USE_TAGLIB=false
 865     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 866   fi
 867 ])
 868
 869 dnl *** wavpack ***
 870 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 871 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 872   PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.40.0, HAVE_WAVPACK=yes, [
 873     PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.20, [
 874       HAVE_WAVPACK=yes
 875       AC_DEFINE(WAVPACK_OLD_API, 1, [old wavpack API])
 876     ],[
 877       HAVE_WAVPACK=no
 878       AC_MSG_RESULT(no)
 879     ])
 880   ])
 881   AC_SUBST(WAVPACK_CFLAGS)
 882   AC_SUBST(WAVPACK_LIBS)
 883 ])
 884
 885 dnl *** qtdemux & id3demux prefer to have zlib ***
 886 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 887 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for id3demux/qtdemux],, [
 888   AG_GST_CHECK_LIBHEADER(ZLIB,
 889     z, uncompress,, zlib.h, [
 890     HAVE_ZLIB="yes"
 891     ZLIB_LIBS="-lz"
 892     AC_SUBST(ZLIB_LIBS)
 893   ])
 894 ])
 895
 896 else
 897
 898 dnl not building plugins with external dependencies,
 899 dnl but we still need to set the conditionals
 900 AM_CONDITIONAL(USE_GCONFTOOL, false)
 901 AM_CONDITIONAL(USE_DIRECTDRAW, false)
 902 AM_CONDITIONAL(USE_DIRECTSOUND, false)
 903 AM_CONDITIONAL(USE_OSS, false)
 904 AM_CONDITIONAL(USE_SUNAUDIO, false)
 905 AM_CONDITIONAL(USE_OSX_AUDIO, false)
 906 AM_CONDITIONAL(USE_OSX_VIDEO, false)
 907 AM_CONDITIONAL(USE_X, false)
 908 AM_CONDITIONAL(USE_XSHM, false)
 909 AM_CONDITIONAL(USE_AALIB, false)
 910 AM_CONDITIONAL(USE_ANNODEX, false)
 911 AM_CONDITIONAL(USE_CAIRO, false)
 912 AM_CONDITIONAL(USE_CDIO, false)
 913 AM_CONDITIONAL(USE_ESD, false)
 914 AM_CONDITIONAL(USE_FLAC, false)
 915 AM_CONDITIONAL(USE_GCONF, false)
 916 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
 917 AM_CONDITIONAL(USE_HAL, false)
 918 AM_CONDITIONAL(USE_JPEG, false)
 919 AM_CONDITIONAL(USE_LADSPA, false)
 920 AM_CONDITIONAL(USE_LIBCACA, false)
 921 AM_CONDITIONAL(USE_LIBDV, false)
 922 AM_CONDITIONAL(USE_LIBPNG, false)
 923 AM_CONDITIONAL(USE_DV1394, false)
 924 AM_CONDITIONAL(USE_SHOUT2, false)
 925 AM_CONDITIONAL(USE_SPEEX, false)
 926 AM_CONDITIONAL(USE_TAGLIB, false)
 927 AM_CONDITIONAL(USE_WAVPACK, false)
 928 AM_CONDITIONAL(USE_ZLIB, false)
 929
 930 fi dnl of EXT plugins
 931
 932 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 933
 934 dnl Overview:
 935 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 936 dnl GST_*:              flags shared by all built objects
 937 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 938 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
 939 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 940 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 941
 942 dnl GST_OPTION_CFLAGS
 943 if test "x$USE_DEBUG" = xyes; then
 944    PROFILE_CFLAGS="-g"
 945 fi
 946 AC_SUBST(PROFILE_CFLAGS)
 947
 948 if test "x$GST_CVS" = "xyes"; then
 949   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 950 else
 951   DEPRECATED_CFLAGS=""
 952 fi
 953 AC_SUBST(DEPRECATED_CFLAGS)
 954
 955 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 956 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 957 AC_SUBST(GST_OPTION_CFLAGS)
 958
 959 dnl our libraries need to be versioned correctly
 960 AC_SUBST(GST_LT_LDFLAGS)
 961
 962 dnl FIXME: do we want to rename to GST_ALL_* ?
 963 dnl prefer internal headers to already installed ones
 964 dnl also add builddir include for enumtypes and marshal
 965 dnl add ERROR_CFLAGS, but overridable
 966 GST_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS \$(GST_OPTION_CFLAGS)"
 967 AC_SUBST(GST_CFLAGS)
 968 AC_SUBST(GST_LIBS)
 969
 970 dnl LDFLAGS really should only contain flags, not libs - they get added before
 971 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 972 GST_ALL_LDFLAGS="-no-undefined"
 973 AC_SUBST(GST_ALL_LDFLAGS)
 974
 975 dnl this really should only contain flags, not libs - they get added before
 976 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 977 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 978 AC_SUBST(GST_PLUGIN_LDFLAGS)
 979
 980 dnl *** output files ***
 981
 982 dnl keep this alphabetic per directory, please
 983 AC_CONFIG_FILES(
 984 Makefile
 985 gst/Makefile
 986 gst/alpha/Makefile
 987 gst/apetag/Makefile
 988 gst/audiofx/Makefile
 989 gst/auparse/Makefile
 990 gst/autodetect/Makefile
 991 gst/avi/Makefile
 992 gst/cutter/Makefile
 993 gst/debug/Makefile
 994 gst/effectv/Makefile
 995 gst/id3demux/Makefile
 996 gst/icydemux/Makefile
 997 gst/goom/Makefile
 998 gst/law/Makefile
 999 gst/level/Makefile
1000 gst/matroska/Makefile
1001 gst/monoscope/Makefile
1002 gst/multipart/Makefile
1003 gst/qtdemux/Makefile
1004 gst/rtp/Makefile
1005 gst/rtsp/Makefile
1006 gst/smpte/Makefile
1007 gst/udp/Makefile
1008 gst/videobox/Makefile
1009 gst/videocrop/Makefile
1010 gst/videofilter/Makefile
1011 gst/videomixer/Makefile
1012 gst/wavenc/Makefile
1013 gst/wavparse/Makefile
1014 gst/flx/Makefile
1015 ext/jpeg/Makefile
1016 ext/Makefile
1017 ext/aalib/Makefile
1018 ext/annodex/Makefile
1019 ext/cairo/Makefile
1020 ext/cdio/Makefile
1021 ext/dv/Makefile
1022 ext/esd/Makefile
1023 ext/flac/Makefile
1024 ext/gconf/Makefile
1025 ext/gdk_pixbuf/Makefile
1026 ext/hal/Makefile
1027 ext/ladspa/Makefile
1028 ext/libcaca/Makefile
1029 ext/libpng/Makefile
1030 ext/raw1394/Makefile
1031 ext/shout2/Makefile
1032 ext/speex/Makefile
1033 ext/taglib/Makefile
1034 ext/wavpack/Makefile
1035 sys/Makefile
1036 sys/directdraw/Makefile
1037 sys/directsound/Makefile
1038 sys/oss/Makefile
1039 sys/sunaudio/Makefile
1040 sys/osxaudio/Makefile
1041 sys/osxvideo/Makefile
1042 sys/v4l2/Makefile
1043 sys/waveform/Makefile
1044 sys/ximage/Makefile
1045 po/Makefile.in
1046 tests/Makefile
1047 tests/check/Makefile
1048 tests/examples/Makefile
1049 tests/examples/level/Makefile
1050 tests/examples/rtp/Makefile
1051 tests/files/Makefile
1052 tests/icles/Makefile
1053 gconf/Makefile
1054 gconf/gstreamer.schemas
1055 common/Makefile
1056 common/m4/Makefile
1057 m4/Makefile
1058 docs/Makefile
1059 docs/plugins/Makefile
1060 docs/version.entities
1061 win32/common/config.h
1062 pkgconfig/Makefile
1063 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1064 gst-plugins-good.spec
1065 )
1066 AC_OUTPUT
1067
1068 AG_GST_OUTPUT_PLUGINS