configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, cvs and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for cvs/prerelease
   8 AC_INIT(GStreamer Base Plug-ins, 0.10.22.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-base)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_CVS="no", GST_CVS="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl our libraries and install dirs use major.minor as a version
  36 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  37 dnl we override it here if we need to for the release candidate of new series
  38 GST_MAJORMINOR=0.10
  39 AC_SUBST(GST_MAJORMINOR)
  40
  41 dnl CURRENT, REVISION, AGE
  42 dnl - library source changed -> increment REVISION
  43 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  44 dnl - interfaces added -> increment AGE
  45 dnl - interfaces removed -> AGE = 0
  46 dnl sets GST_LT_LDFLAGS
  47 AS_LIBTOOL(GST, 16, 0, 16)
  48
  49 dnl FIXME: this macro doesn't actually work;
  50 dnl the generated libtool script has no support for the listed tags.
  51 dnl So this needs to be fixed first if we want to use this
  52 dnl AS_LIBTOOL_TAGS
  53
  54 AC_LIBTOOL_WIN32_DLL
  55 AM_PROG_LIBTOOL
  56
  57 dnl *** required versions of GStreamer stuff ***
  58 GST_REQ=0.10.21.1
  59
  60 dnl *** autotools stuff ****
  61
  62 dnl allow for different autotools
  63 AS_AUTOTOOLS_ALTERNATE
  64
  65 dnl Add parameters for aclocal
  66 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  67
  68 dnl set up gettext
  69 dnl the version check needs to stay here because autopoint greps for it
  70 AM_GNU_GETTEXT_VERSION([0.17])
  71 AM_GNU_GETTEXT([external])
  72 AG_GST_GETTEXT([gst-plugins-base-$GST_MAJORMINOR])
  73
  74 dnl *** check for arguments to configure ***
  75
  76 AG_GST_ARG_DEBUG
  77 AG_GST_ARG_PROFILING
  78 AG_GST_ARG_VALGRIND
  79 AG_GST_ARG_GCOV
  80
  81 AG_GST_ARG_EXAMPLES
  82
  83 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  84 AG_GST_ARG_WITH_PACKAGE_NAME
  85 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  86
  87 dnl let distro override plugin install helper path
  88 AC_ARG_WITH(install-plugins-helper,
  89   AC_HELP_STRING([--with-install-plugins-helper],
  90     [specify path of helper script to call to install plugins]),
  91   [
  92     case "${withval}" in
  93       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
  94       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
  95       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
  96     esac
  97   ],
  98   [
  99     dnl Default value
 100     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 101   ]
 102 )
 103 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 104 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 105     [plugin install helper script])
 106 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 107
 108 AG_GST_ARG_WITH_PLUGINS
 109
 110 AG_GST_ARG_ENABLE_EXTERNAL
 111
 112 AG_GST_ARG_ENABLE_EXPERIMENTAL
 113
 114 dnl *** checks for platform ***
 115
 116 dnl * hardware/architecture *
 117
 118 dnl common/m4/gst-arch.m4
 119 dnl check CPU type
 120 AG_GST_ARCH
 121
 122 dnl check for large file support
 123 dnl affected plugins must include config.h
 124 AC_SYS_LARGEFILE
 125
 126 dnl *** checks for programs ***
 127
 128 dnl find a compiler
 129 AC_PROG_CC
 130
 131 dnl check if the compiler supports '-c' and '-o' options
 132 AM_PROG_CC_C_O
 133
 134 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 135 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 136
 137 dnl check for documentation tools
 138 GTK_DOC_CHECK([1.3])
 139 AS_PATH_PYTHON([2.1])
 140 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 141
 142 dnl *** checks for libraries ***
 143
 144 dnl libm, for sin() etc.
 145 AC_CHECK_LIBM
 146 AC_SUBST(LIBM)
 147
 148 dnl *** checks for header files ***
 149
 150 dnl check if we have ANSI C header files
 151 AC_HEADER_STDC
 152
 153 dnl used in gst/ffmpegcolorspace/mem.c
 154 dnl FIXME: could be fixed by redefining av_malloc and av_free to GLib's
 155 AC_CHECK_HEADERS([malloc.h])
 156
 157 dnl used in gst/subparse/gstsubparse.c
 158 AC_CHECK_HEADERS([regex.h], HAVE_REGEX_H="yes", HAVE_REGEX_H="no")
 159 AM_CONDITIONAL(HAVE_REGEX_H, test "x$HAVE_REGEX_H" = "xyes")
 160
 161 if test "x$HAVE_REGEX_H" = "xyes"; then
 162   ac_cppflags_save="$CPPFLAGS"
 163   CPPFLAGS="`$PKG_CONFIG --cflags libxml-2.0`"
 164   AC_COMPILE_IFELSE(
 165     AC_LANG_PROGRAM([
 166 #include <libxml/HTMLparser.h>
 167                      ],[
 168 #ifndef LIBXML_HTML_ENABLED
 169 #error libxml2 has no HTML support
 170 #endif /* LIBXML_HTML_ENABLED */
 171                      ]), HAVE_LIBXML_HTML="yes", HAVE_LIBXML_HTML="no")
 172   CPPFLAGS="$ac_cppflags_save"
 173 else
 174   HAVE_LIBXML_HTML="no"
 175 fi
 176 AM_CONDITIONAL(HAVE_LIBXML_HTML, test "x$HAVE_LIBXML_HTML" = "xyes")
 177
 178 dnl used in gst/tcp
 179 AC_CHECK_HEADERS([sys/socket.h],
 180   HAVE_SYS_SOCKET_H="yes", HAVE_SYS_SOCKET_H="no")
 181 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 182
 183 dnl used in gst-libs/gst/rtsp
 184 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 185 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 186   WIN32_LIBS="-lws2_32"
 187   AC_SUBST(WIN32_LIBS)
 188 fi
 189
 190 dnl check for hstrerror, for gst-libs/gst/rtsp
 191 save_libs="$LIBS"
 192 AC_CHECK_FUNC(hstrerror, ,
 193     AC_CHECK_LIB(resolv, hstrerror, ,
 194         [AC_DEFINE(NO_HSTRERROR, 1,
 195              [Define if you have no native hstrerror() function.])]))
 196 HSTRERROR_LIBS=$LIBS
 197 AC_SUBST(HSTRERROR_LIBS)
 198 LIBS="$save_libs"
 199
 200 dnl used in gst-libs/gst/pbutils and associated unit test
 201 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h])
 202
 203 dnl ffmpegcolorspace includes _stdint.h
 204 dnl also, Windows does not have long long
 205 AX_CREATE_STDINT_H
 206
 207 dnl *** checks for functions ***
 208 AC_CHECK_FUNCS([localtime_r gmtime_r])
 209
 210 dnl *** checks for types/defines ***
 211
 212 dnl Check for FIONREAD ioctl declaration
 213 dnl used in gst/tcp
 214 GST_CHECK_FIONREAD
 215
 216 dnl *** checks for structures ***
 217
 218 dnl *** checks for compiler characteristics ***
 219
 220 dnl make sure we can use "inline" from C code
 221 AC_C_INLINE
 222
 223 dnl *** checks for library functions ***
 224
 225 dnl check for fseeko()
 226 AC_FUNC_FSEEKO
 227
 228 dnl Check for fast float to int casting as defined in C99
 229 dnl used in gst-libs/gst/floatcast/floatcast.h
 230 save_libs=$LIBS
 231 LIBS="$LIBS $LIBM"
 232 AC_C99_FUNC_LRINT
 233 AC_C99_FUNC_LRINTF
 234 LIBS=$save_libs
 235
 236 dnl Check for a way to display the function name in debug output
 237 AG_GST_CHECK_FUNCTION
 238
 239 dnl *** checks for socket and nsl libraries ***
 240 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 241 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
 242
 243 dnl *** checks for dependency libraries ***
 244
 245 dnl GLib is required
 246 AG_GST_GLIB_CHECK([2.12])
 247
 248 dnl liboil is required
 249 PKG_CHECK_MODULES(LIBOIL, liboil-0.3 >= 0.3.14, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 250 if test "x$HAVE_LIBOIL" != "xyes"; then
 251   AC_ERROR([liboil-0.3.14 or later is required])
 252 fi
 253
 254 dnl checks for gstreamer
 255 dnl uninstalled is selected preferentially -- see pkg-config(1)
 256 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 257 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 258 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ], yes)
 259 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 260 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 261 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 262
 263 dnl Check for documentation xrefs
 264 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 265 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 266 AC_SUBST(GLIB_PREFIX)
 267 AC_SUBST(GST_PREFIX)
 268
 269 dnl GTK is optional and only used in examples
 270 PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.12.0, HAVE_GTK=yes, HAVE_GTK=no)
 271 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 272
 273 dnl some examples need gtk+-x11
 274 PKG_CHECK_MODULES(GTK_X11, gtk+-x11-2.0 >= 2.12.0,
 275     HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 276 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 277
 278 dnl *** set variables based on configure arguments ***
 279
 280 dnl set license and copyright notice
 281 GST_LICENSE="LGPL"
 282 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 283 AC_SUBST(GST_LICENSE)
 284
 285 dnl set location of plugin directory
 286 AG_GST_SET_PLUGINDIR
 287
 288 dnl define an ERROR_CFLAGS Makefile variable
 289 AG_GST_SET_ERROR_CFLAGS($GST_CVS)
 290
 291 dnl define correct level for debugging messages
 292 AG_GST_SET_LEVEL_DEFAULT($GST_CVS)
 293
 294 dnl used in examples
 295 AG_GST_DEFAULT_ELEMENTS
 296
 297 dnl behaviour of speex based audio resampler
 298 AC_MSG_CHECKING(which audio resample format to use for integer)
 299 AC_ARG_WITH([audioresample_format],
 300         AS_HELP_STRING([--with-audioresample-format],[Which implementation should be used for integer audio resampling, int/float/auto, (default is auto)]),
 301         [ac_cv_audioresample_format=$withval], [ac_cv_audioresample_format=auto])dnl
 302 AC_MSG_RESULT($ac_cv_audioresample_format)
 303 case $ac_cv_audioresample_format in
 304   int)
 305     AC_DEFINE(AUDIORESAMPLE_FORMAT_INT,1,[The int implementation should be used for integer audio resampling])
 306     AC_SUBST(AUDIORESAMPLE_FORMAT_INT)
 307   ;;
 308   float)
 309     AC_DEFINE(AUDIORESAMPLE_FORMAT_FLOAT,1,[The float implementation should be used for integer audio resampling])
 310     AC_SUBST(AUDIORESAMPLE_FORMAT_FLOAT)
 311   ;;
 312   auto)
 313     AC_DEFINE(AUDIORESAMPLE_FORMAT_AUTO,1,[The implementation that should be used for integer audio resampling witll be benchmarked at runtime])
 314     AC_SUBST(AUDIORESAMPLE_FORMAT_AUTO)
 315 esac
 316
 317 dnl *** plug-ins to include ***
 318
 319 dnl these are all the gst plug-ins, compilable without additional libs
 320 AG_GST_CHECK_PLUGIN(adder)
 321 AG_GST_CHECK_PLUGIN(app)
 322 AG_GST_CHECK_PLUGIN(audioconvert)
 323 AG_GST_CHECK_PLUGIN(audiorate)
 324 AG_GST_CHECK_PLUGIN(audiotestsrc)
 325 AG_GST_CHECK_PLUGIN(ffmpegcolorspace)
 326 AG_GST_CHECK_PLUGIN(gdp)
 327 AG_GST_CHECK_PLUGIN(playback)
 328 AG_GST_CHECK_PLUGIN(audioresample)
 329 AG_GST_CHECK_PLUGIN(subparse)
 330 AG_GST_CHECK_PLUGIN(tcp)
 331 AG_GST_CHECK_PLUGIN(typefind)
 332 AG_GST_CHECK_PLUGIN(videotestsrc)
 333 AG_GST_CHECK_PLUGIN(videorate)
 334 AG_GST_CHECK_PLUGIN(videoscale)
 335 AG_GST_CHECK_PLUGIN(volume)
 336
 337 dnl check for gstreamer core features (subsystems)
 338 GST_CONFIGPATH=`$PKG_CONFIG --variable=includedir gstreamer-0.10`"/gst/gstconfig.h"
 339 AG_GST_PARSE_SUBSYSTEM_DISABLES($GST_CONFIGPATH)
 340 AM_CONDITIONAL(USE_XML, test $GST_DISABLE_XML != "1")
 341
 342 dnl disable plug-ins that require libxml2's HTML support if it is not available
 343 if test "x$HAVE_LIBXML_HTML" != "xyes"; then
 344   AG_GST_DISABLE_PLUGIN(subparse)
 345 fi
 346
 347 dnl disable plug-ins that require sys/socket.h if it is not available
 348 if test "x$HAVE_SYS_SOCKET_H" != "xyes"; then
 349   AG_GST_DISABLE_PLUGIN(tcp)
 350 fi
 351
 352 dnl *** sys plug-ins ***
 353
 354 echo
 355 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 356 echo
 357
 358 dnl *** X11 ***
 359 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 360 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 361                   [ximagesink], [
 362   AC_PATH_XTRA
 363   ac_cflags_save="$CFLAGS"
 364   ac_cppflags_save="$CPPFLAGS"
 365   CFLAGS="$CFLAGS $X_CFLAGS"
 366   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 367
 368   dnl now try to find the HEADER
 369   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 370
 371   if test "x$HAVE_X" = "xno"
 372   then
 373     AC_MSG_NOTICE([cannot find X11 development files])
 374   else
 375     dnl this is much more than we want
 376     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 377     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 378     dnl it does not add the libs; therefore we add them here
 379     X_LIBS="$X_LIBS -lX11"
 380     AC_SUBST(X_CFLAGS)
 381     AC_SUBST(X_LIBS)
 382   fi
 383   AC_SUBST(HAVE_X)
 384   CFLAGS="$ac_cflags_save"
 385   CPPFLAGS="$ac_cppflags_save"
 386 ])
 387
 388 dnl Check for Xv extension
 389 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 390 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 391                   [xvimagesink], [
 392   AG_GST_CHECK_XV
 393 ])
 394
 395 dnl check for X Shm
 396 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 397 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 398   if test x$HAVE_X = xyes; then
 399     AC_CHECK_LIB(Xext, XShmAttach,
 400                  HAVE_XSHM="yes", HAVE_XSHM="no",
 401                  $X_LIBS)
 402     if test "x$HAVE_XSHM" = "xyes"; then
 403       XSHM_LIBS="-lXext"
 404     else
 405       dnl On AIX, it is in XextSam instead, but we still need -lXext
 406       AC_CHECK_LIB(XextSam, XShmAttach,
 407                    HAVE_XSHM="yes", HAVE_XSHM="no",
 408                    $X_LIBS)
 409       if test "x$HAVE_XSHM" = "xyes"; then
 410         XSHM_LIBS="-lXext -lXextSam"
 411       fi
 412     fi
 413   fi
 414 ], , [
 415   AC_SUBST(HAVE_XSHM)
 416   AC_SUBST(XSHM_LIBS)
 417 ])
 418
 419 dnl v4l/v4l2 checks have been moved down because they require X
 420
 421 dnl *** Video 4 Linux ***
 422 dnl for information about the header/define, see sys/v4l/gstv4lelement.h
 423 dnl renamed to GST_V4L in accordance with V4L2 below
 424 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L, true)
 425 AG_GST_CHECK_FEATURE(GST_V4L, [Video 4 Linux], video4linux, [
 426   AC_CHECK_DECL(VID_TYPE_MPEG_ENCODER, HAVE_GST_V4L="yes", HAVE_GST_V4L="no", [
 427 #include <sys/types.h>
 428 #define _LINUX_TIME_H
 429 #define __user
 430 #include <linux/videodev.h>
 431   ])
 432
 433   dnl we can build v4l without Xv, but then we won't have XOverlay support
 434   if test "x$HAVE_GST_V4L" = "xyes" -a "x$HAVE_XVIDEO" != "xyes"
 435   then
 436     AC_MSG_NOTICE([NO XVIDEO FOUND, VIDEO4LINUX WILL BE BUILT])
 437     AC_MSG_NOTICE([WITHOUT XOVERLAY SUPPORT])
 438   fi
 439 ])
 440
 441 dnl *** ext plug-ins ***
 442 dnl keep this list sorted alphabetically !
 443
 444 if test "x$BUILD_EXTERNAL" = "xyes"; then
 445
 446 echo
 447 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 448 echo
 449
 450 dnl *** alsa ***
 451 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 452 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 453   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 454     HAVE_ALSA="yes"
 455     AC_SUBST(ALSA_CFLAGS)
 456     AC_SUBST(ALSA_LIBS)
 457   ], [
 458     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 459   ])
 460 ])
 461
 462 dnl *** CDParanoia ***
 463 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 464 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 465   AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 466                       cdda_open, -lm,
 467                       cdda_interface.h,
 468                       CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 469                       HEADER_DIR="no"
 470                       FOUND_CDPARANOIA="yes")
 471   if test "x$FOUND_CDPARANOIA" != "xyes";
 472   then
 473     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 474                         cdda_open, -lm,
 475                         cdda/cdda_interface.h,
 476                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 477                         HEADER_DIR="yes"
 478                         FOUND_CDPARANOIA="yes")
 479   fi
 480   if test "x$HEADER_DIR" = "xyes";
 481   then
 482     AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 483                        defined if cdda headers are in a cdda/ directory)
 484   fi
 485   AC_SUBST(CDPARANOIA_LIBS)
 486 ])
 487 dnl FIXME : add second check somehow if that is necessary
 488 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 489 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 490
 491 dnl *** GNOME VFS ***
 492 translit(dnm, m, l) AM_CONDITIONAL(USE_GNOME_VFS, true)
 493 AG_GST_CHECK_FEATURE(GNOME_VFS, [GNOME VFS], gnomevfs, [
 494   PKG_CHECK_MODULES(GNOME_VFS, gnome-vfs-2.0, [
 495       HAVE_GNOME_VFS="yes"
 496       AC_SUBST(GNOME_VFS_CFLAGS)
 497       AC_SUBST(GNOME_VFS_LIBS)
 498       GNOME_VFS_MODULES_DIR="`$PKG_CONFIG --variable=modulesdir gnome-vfs-2.0`"
 499       AC_DEFINE_UNQUOTED(GNOME_VFS_MODULES_DIR, "$GNOME_VFS_MODULES_DIR",
 500              [The GnomeVFS modules directory.])
 501     ],[
 502       HAVE_GNOME_VFS="no"
 503     ]
 504     )
 505 ])
 506
 507 dnl *** libgio ***
 508 USE_GIO=$BUILD_EXPERIMENTAL
 509 translit(dnm, m, l) AM_CONDITIONAL(USE_GIO, true)
 510 AG_GST_CHECK_FEATURE(GIO, [GIO library], gio, [
 511   PKG_CHECK_MODULES(GIO, gio-2.0 >= 2.15.2, [
 512     HAVE_GIO="yes"
 513     GIO_MODULE_DIR="`$PKG_CONFIG --variable=giomoduledir gio-2.0`"
 514     AC_DEFINE_UNQUOTED(GIO_MODULE_DIR, "$GIO_MODULE_DIR",
 515            [The GIO modules directory.])
 516     GIO_LIBDIR="`$PKG_CONFIG --variable=libdir gio-2.0`"
 517     AC_DEFINE_UNQUOTED(GIO_LIBDIR, "$GIO_LIBDIR",
 518            [The GIO library directory.])
 519   ], [
 520     HAVE_GIO="no"
 521     AC_MSG_RESULT(no)
 522   ])
 523   AC_SUBST(GIO_CFLAGS)
 524   AC_SUBST(GIO_LIBS)
 525   AC_SUBST(GIO_LDFLAGS)
 526 ])
 527
 528 dnl *** libvisual ***
 529 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 530 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 531   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 532   if test $HAVE_LIBVISUAL = no
 533   then
 534     AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0)
 535     if test x$HAVE_LIBVISUAL == xyes; then
 536       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.2`"
 537     fi
 538   else
 539     if test x$HAVE_LIBVISUAL == xyes; then
 540       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.4`"
 541     fi
 542   fi
 543   AC_MSG_NOTICE([libvisual pluginsdir: $LIBVIS_PLUGINSDIR])
 544   if test x$LIBVIS_PLUGINSDIR != x; then
 545     AC_DEFINE_UNQUOTED(LIBVISUAL_PLUGINSBASEDIR,
 546         "$LIBVIS_PLUGINSDIR",
 547         [directory in which the detected libvisual's plugins are located])
 548   fi
 549 ])
 550
 551 dnl *** ogg ***
 552 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 553 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 554   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 555   if test $HAVE_OGG = no
 556   then
 557     XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
 558     AS_SCRUB_INCLUDE(OGG_CFLAGS)
 559   fi
 560 ])
 561
 562 dnl *** pango ***
 563 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 564 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 565   AG_GST_PKG_CHECK_MODULES(PANGO, pango pangoft2)
 566 ])
 567
 568 dnl *** theora ***
 569 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 570 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 571   dnl theora uses pkg-config version incorrectly, for pkg-config:
 572   dnl 1.0 < 1.0RCX < 1.0alphaX < 1.0betaX < 1.0.0
 573   dnl theoraenc and theoradec appeared in 1.0beta3
 574
 575   AG_GST_PKG_CHECK_MODULES(THEORA, theoradec theoraenc)
 576   if test x$HAVE_THEORA = xno; then
 577     AG_GST_PKG_CHECK_MODULES(THEORA, theora >= 1.0alpha5)
 578   fi
 579 ])
 580
 581 dnl *** vorbis ***
 582 dnl AM_PATH_VORBIS only takes two options
 583 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 584 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 585   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 586   if test $HAVE_VORBIS = no
 587   then
 588     XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
 589     AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
 590   fi
 591 ])
 592
 593 if test "x$HAVE_VORBIS" = "xyes"; then
 594   ac_cflags_save="$CFLAGS"
 595   AC_COMPILE_IFELSE(
 596     AC_LANG_PROGRAM([
 597 #include <vorbis/codec.h>
 598                      ],[
 599 vorbis_dsp_state *v;
 600
 601 vorbis_synthesis_restart (v);
 602                      ]), HAVE_VSR=yes, HAVE_VSR=no)
 603   if test "x$HAVE_VSR" = "xyes"; then
 604     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 605                        [defined if vorbis_synthesis_restart is present])
 606   fi
 607   CFLAGS="$ac_cflags_save"
 608 fi
 609
 610 else
 611
 612 dnl not building plugins with external dependencies,
 613 dnl but we still need to set the conditionals
 614 AM_CONDITIONAL(USE_ALSA, false)
 615 AM_CONDITIONAL(USE_CDPARANOIA, false)
 616 AM_CONDITIONAL(USE_GNOME_VFS, false)
 617 AM_CONDITIONAL(USE_GIO, false)
 618 AM_CONDITIONAL(USE_LIBVISUAL, false)
 619 AM_CONDITIONAL(USE_OGG, false)
 620 AM_CONDITIONAL(USE_PANGO, false)
 621 AM_CONDITIONAL(USE_THEORA, false)
 622 AM_CONDITIONAL(USE_VORBIS, false)
 623
 624 fi dnl of EXT plugins
 625
 626 dnl seeking needs freetype, so check for it here
 627 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 628   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 629 ])
 630 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 631 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 632 AC_SUBST(FT2_CFLAGS)
 633 AC_SUBST(FT2_LIBS)
 634
 635 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 636
 637 dnl Overview:
 638 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 639 dnl GST_*:              flags shared by built objects to link against GStreamer
 640 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 641 dnl                          (compare to other modules) or for i18n
 642 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 643 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 644 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 645 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 646
 647 dnl GST_OPTION_CFLAGS
 648 if test "x$USE_DEBUG" = xyes; then
 649    PROFILE_CFLAGS="-g"
 650 fi
 651 AC_SUBST(PROFILE_CFLAGS)
 652
 653 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 654   dnl Define _only_ during CVS (not pre-releases or releases)
 655   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 656 else
 657   DEPRECATED_CFLAGS=""
 658 fi
 659 AC_SUBST(DEPRECATED_CFLAGS)
 660
 661 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 662 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 663 AC_SUBST(GST_OPTION_CFLAGS)
 664
 665 dnl our libraries need to be versioned correctly
 666 AC_SUBST(GST_LT_LDFLAGS)
 667
 668 dnl GST_PLUGINS_BASE_CFLAGS
 669 dnl prefer internal headers to already installed ones
 670 dnl also add builddir include for enumtypes and marshal
 671 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 672 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 673
 674 dnl FIXME: do we want to rename to GST_ALL_* ?
 675 dnl add GST_OPTION_CFLAGS, but overridable
 676 GST_CFLAGS="$GST_CFLAGS \$(GST_OPTION_CFLAGS)"
 677 AC_SUBST(GST_CFLAGS)
 678 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 679 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 680 AC_SUBST(GST_LIBS)
 681
 682 dnl LDFLAGS really should only contain flags, not libs - they get added before
 683 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 684 GST_ALL_LDFLAGS="-no-undefined"
 685 AC_SUBST(GST_ALL_LDFLAGS)
 686
 687 dnl GST_LIB_LDFLAGS
 688 dnl linker flags shared by all libraries
 689 dnl LDFLAGS modifier defining exported symbols from built libraries
 690 dnl (export _gst_foo but not __gst_foo)
 691 GST_LIB_LDFLAGS="-export-symbols-regex ^_?\(gst_\|Gst\|GST_\).*"
 692 AC_SUBST(GST_LIB_LDFLAGS)
 693
 694 dnl this really should only contain flags, not libs - they get added before
 695 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 696 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 697 AC_SUBST(GST_PLUGIN_LDFLAGS)
 698
 699 dnl *** output files ***
 700
 701 AC_CONFIG_FILES(
 702 Makefile
 703 gst-plugins-base.spec
 704 gst/Makefile
 705 gst/adder/Makefile
 706 gst/app/Makefile
 707 gst/audioconvert/Makefile
 708 gst/audiorate/Makefile
 709 gst/audiotestsrc/Makefile
 710 gst/ffmpegcolorspace/Makefile
 711 gst/gdp/Makefile
 712 gst/playback/Makefile
 713 gst/audioresample/Makefile
 714 gst/subparse/Makefile
 715 gst/tcp/Makefile
 716 gst/typefind/Makefile
 717 gst/videotestsrc/Makefile
 718 gst/videorate/Makefile
 719 gst/videoscale/Makefile
 720 gst/volume/Makefile
 721 sys/Makefile
 722 sys/ximage/Makefile
 723 sys/xvimage/Makefile
 724 sys/v4l/Makefile
 725 ext/Makefile
 726 ext/alsa/Makefile
 727 ext/cdparanoia/Makefile
 728 ext/gnomevfs/Makefile
 729 ext/gio/Makefile
 730 ext/libvisual/Makefile
 731 ext/ogg/Makefile
 732 ext/pango/Makefile
 733 ext/theora/Makefile
 734 ext/vorbis/Makefile
 735 gst-libs/Makefile
 736 gst-libs/gst/Makefile
 737 gst-libs/gst/audio/Makefile
 738 gst-libs/gst/app/Makefile
 739 gst-libs/gst/cdda/Makefile
 740 gst-libs/gst/fft/Makefile
 741 gst-libs/gst/floatcast/Makefile
 742 gst-libs/gst/interfaces/Makefile
 743 gst-libs/gst/netbuffer/Makefile
 744 gst-libs/gst/riff/Makefile
 745 gst-libs/gst/rtp/Makefile
 746 gst-libs/gst/rtsp/Makefile
 747 gst-libs/gst/sdp/Makefile
 748 gst-libs/gst/tag/Makefile
 749 gst-libs/gst/pbutils/Makefile
 750 gst-libs/gst/video/Makefile
 751 tools/Makefile
 752 win32/common/config.h
 753 pkgconfig/Makefile
 754 pkgconfig/gstreamer-audio.pc
 755 pkgconfig/gstreamer-audio-uninstalled.pc
 756 pkgconfig/gstreamer-app.pc
 757 pkgconfig/gstreamer-app-uninstalled.pc
 758 pkgconfig/gstreamer-cdda.pc
 759 pkgconfig/gstreamer-cdda-uninstalled.pc
 760 pkgconfig/gstreamer-fft.pc
 761 pkgconfig/gstreamer-fft-uninstalled.pc
 762 pkgconfig/gstreamer-floatcast.pc
 763 pkgconfig/gstreamer-floatcast-uninstalled.pc
 764 pkgconfig/gstreamer-interfaces.pc
 765 pkgconfig/gstreamer-interfaces-uninstalled.pc
 766 pkgconfig/gstreamer-netbuffer.pc
 767 pkgconfig/gstreamer-netbuffer-uninstalled.pc
 768 pkgconfig/gstreamer-pbutils.pc
 769 pkgconfig/gstreamer-pbutils-uninstalled.pc
 770 pkgconfig/gstreamer-riff.pc
 771 pkgconfig/gstreamer-riff-uninstalled.pc
 772 pkgconfig/gstreamer-rtp.pc
 773 pkgconfig/gstreamer-rtp-uninstalled.pc
 774 pkgconfig/gstreamer-rtsp.pc
 775 pkgconfig/gstreamer-rtsp-uninstalled.pc
 776 pkgconfig/gstreamer-sdp.pc
 777 pkgconfig/gstreamer-sdp-uninstalled.pc
 778 pkgconfig/gstreamer-tag.pc
 779 pkgconfig/gstreamer-tag-uninstalled.pc
 780 pkgconfig/gstreamer-video.pc
 781 pkgconfig/gstreamer-video-uninstalled.pc
 782 pkgconfig/gstreamer-plugins-base.pc
 783 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 784 tests/Makefile
 785 tests/check/Makefile
 786 tests/examples/Makefile
 787 tests/examples/app/Makefile
 788 tests/examples/dynamic/Makefile
 789 tests/examples/seek/Makefile
 790 tests/examples/volume/Makefile
 791 tests/examples/snapshot/Makefile
 792 tests/icles/Makefile
 793 docs/Makefile
 794 docs/design/Makefile
 795 docs/libs/Makefile
 796 docs/plugins/Makefile
 797 docs/version.entities
 798 po/Makefile.in
 799 common/Makefile
 800 common/m4/Makefile
 801 m4/Makefile
 802 )
 803 AC_OUTPUT
 804
 805 AG_GST_OUTPUT_PLUGINS