configure.ac

   1 AC_PREREQ(2.60)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/pre
   8 AC_INIT(GStreamer Good Plug-ins, 0.11.89.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-good)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability 1.10])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use GST_API_VERSION in the filename
  41 dnl to allow side-by-side installation of different API versions
  42 GST_API_VERSION=1.0
  43 AC_SUBST(GST_API_VERSION)
  44 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  45   [GStreamer API Version])
  46
  47 AG_GST_LIBTOOL_PREPARE
  48
  49 dnl FIXME: this macro doesn't actually work;
  50 dnl the generated libtool script has no support for the listed tags.
  51 dnl So this needs to be fixed first if we want to use this
  52 dnl AS_LIBTOOL_TAGS
  53
  54 AC_LIBTOOL_WIN32_DLL
  55 AM_PROG_LIBTOOL
  56
  57 dnl *** required versions of GStreamer stuff ***
  58 GST_REQ=0.11.3
  59 GSTPB_REQ=0.11.3
  60
  61 dnl *** autotools stuff ****
  62
  63 dnl allow for different autotools
  64 AS_AUTOTOOLS_ALTERNATE
  65
  66 dnl Add parameters for aclocal
  67 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  68
  69 dnl set up gettext
  70 dnl the version check needs to stay here because autopoint greps for it
  71 AM_GNU_GETTEXT_VERSION([0.17])
  72 AM_GNU_GETTEXT([external])
  73 AG_GST_GETTEXT([gst-plugins-good-$GST_API_VERSION])
  74
  75 dnl *** check for arguments to configure ***
  76
  77 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  78
  79 AG_GST_ARG_DEBUG
  80 AG_GST_ARG_PROFILING
  81 AG_GST_ARG_VALGRIND
  82 AG_GST_ARG_GCOV
  83
  84 AG_GST_ARG_EXAMPLES
  85
  86 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  87 AG_GST_ARG_WITH_PACKAGE_NAME
  88 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  89
  90 AG_GST_ARG_WITH_PLUGINS
  91
  92 AG_GST_ARG_ENABLE_EXTERNAL
  93
  94 AG_GST_ARG_ENABLE_EXPERIMENTAL
  95
  96 dnl *** checks for platform ***
  97
  98 dnl * hardware/architecture *
  99
 100 dnl common/m4/gst-arch.m4
 101 dnl check CPU type
 102 AG_GST_ARCH
 103
 104 dnl Determine endianness
 105 AC_C_BIGENDIAN
 106
 107 dnl *** checks for programs ***
 108
 109 dnl find a compiler
 110 AC_PROG_CC
 111 AC_PROG_CC_STDC
 112
 113 dnl determine c++ compiler
 114 AC_PROG_CXX
 115 dnl determine if c++ is available on this system
 116 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 117
 118 dnl determine c++ preprocessor
 119 dnl FIXME: do we need this ?
 120 AC_PROG_CXXCPP
 121
 122 AS_PROG_OBJC
 123
 124 dnl check if the compiler supports '-c' and '-o' options
 125 AM_PROG_CC_C_O
 126
 127 dnl find an assembler
 128 AM_PROG_AS
 129
 130 dnl check if the compiler supports do while(0) macros
 131 AG_GST_CHECK_DOWHILE_MACROS
 132
 133 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 134 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 135
 136 dnl check for documentation tools
 137 GTK_DOC_CHECK([1.3])
 138 AS_PATH_PYTHON([2.1])
 139 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 140
 141 dnl *** checks for libraries ***
 142
 143 dnl check for libm, for sin()
 144 AC_CHECK_LIBM
 145 AC_SUBST(LIBM)
 146
 147 dnl *** checks for header files ***
 148
 149 dnl check if we have ANSI C header files
 150 AC_HEADER_STDC
 151
 152 dnl used by ext/wavpack
 153 AX_CREATE_STDINT_H
 154
 155 dnl used in gst/udp
 156 AC_CHECK_HEADERS([sys/time.h])
 157
 158 dnl used in gst/udp
 159 AC_CHECK_HEADERS([sys/socket.h])
 160
 161 dnl *** checks for types/defines ***
 162
 163 dnl Check for FIONREAD ioctl declaration.  This check is needed
 164 dnl for the UDP plugin to build on Solaris
 165 GST_CHECK_FIONREAD
 166
 167 dnl *** checks for structures ***
 168
 169 dnl *** checks for compiler characteristics ***
 170
 171 dnl check if we have GCC inline-asm
 172 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 173 if test x$HAVE_GCC_ASM = xyes ; then
 174   AC_DEFINE(HAVE_GCC_ASM, 1,
 175     [Define if compiler supports gcc inline assembly])
 176 fi
 177 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 178
 179 dnl *** checks for library functions ***
 180
 181 LIBS_SAVE=$LIBS
 182 LIBS="$LIBS $LIBM"
 183 AC_CHECK_FUNCS(rint sinh cosh asinh fpclass)
 184 LIBS=$LIBS_SAVE
 185
 186 dnl Check whether isinf() is defined by math.h
 187 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
 188     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; int i=isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
 189 if test "$ac_cv_have_isinf" = "yes"
 190 then
 191     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
 192 fi
 193
 194 dnl Check for mmap (needed by electricfence plugin)
 195 AC_FUNC_MMAP
 196 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 197
 198 dnl Check for mmap (needed by electricfence plugin)
 199
 200 AC_CHECK_TYPE([struct ip_mreqn], [
 201               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
 202               [#include <netinet/in.h>])
 203
 204 dnl *** checks for dependency libraries ***
 205
 206
 207 dnl GLib
 208 GLIB_REQ=2.31.14
 209 AG_GST_GLIB_CHECK([$GLIB_REQ])
 210
 211 dnl Orc
 212 ORC_CHECK([0.4.11])
 213
 214 dnl checks for gstreamer
 215 dnl uninstalled is selected preferentially -- see pkg-config(1)
 216 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 217 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 218 AG_GST_CHECK_GST_CONTROLLER($GST_API_VERSION, [$GST_REQ], yes)
 219 AG_GST_CHECK_GST_NET($GST_API_VERSION, [$GST_REQ], yes)
 220 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 221 AG_GST_CHECK_GST_PLUGINS_BASE($GST_API_VERSION, [$GSTPB_REQ], yes)
 222
 223 GST_TOOLS_DIR=`$PKG_CONFIG --variable=toolsdir gstreamer-$GST_API_VERSION`
 224 if test -z $GST_TOOLS_DIR; then
 225   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 226 fi
 227 AC_SUBST(GST_TOOLS_DIR)
 228
 229 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 230 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 231
 232 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 233
 234 dnl Check for documentation xrefs
 235 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 236 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 237 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_API_VERSION`"
 238 AC_SUBST(GLIB_PREFIX)
 239 AC_SUBST(GST_PREFIX)
 240 AC_SUBST(GSTPB_PREFIX)
 241
 242 dnl GTK is optional and used in examples
 243 HAVE_GTK=no
 244 GTK2_REQ=2.14.0
 245 GTK3_REQ=2.91.3
 246 if test "x$BUILD_EXAMPLES" = "xyes"; then
 247   AC_MSG_CHECKING([which gtk+ version to compile examples against (optional)])
 248   AC_ARG_WITH([gtk],
 249     AC_HELP_STRING([--with-gtk=3.0|2.0],
 250                    [which gtk+ version to compile against (default: 2.0)]),
 251     [case "$with_gtk" in
 252         2.0) GTK_REQ=$GTK2_REQ ;;
 253         3.0) GTK_REQ=$GTK3_REQ ;;
 254         *) AC_MSG_ERROR([invalid gtk+ version specified]);;
 255     esac],
 256     [with_gtk=2.0
 257      GTK_REQ=$GTK2_REQ])
 258   AC_MSG_RESULT([$with_gtk (>= $GTK_REQ)])
 259   PKG_CHECK_MODULES(GTK, gtk+-$with_gtk >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 260   dnl some examples need gtk+-x11
 261   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-$with_gtk >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 262   AC_SUBST(GTK_LIBS)
 263   AC_SUBST(GTK_CFLAGS)
 264 fi
 265 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 266 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 267
 268 dnl *** set variables based on configure arguments ***
 269
 270 dnl set license and copyright notice
 271 GST_LICENSE="LGPL"
 272 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 273 AC_SUBST(GST_LICENSE)
 274
 275 dnl set location of plugin directory
 276 AG_GST_SET_PLUGINDIR
 277
 278 dnl set release date/time
 279 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 280   ["${srcdir}/gst-plugins-good.doap"],
 281   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 282
 283 dnl define an ERROR_CFLAGS Makefile variable
 284 dnl -Wundef: too many broken headers
 285 if test "x$HAVE_OSX_VIDEO" != "xyes"; then
 286   AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 287         -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 288         -Wwrite-strings -Wold-style-definition -Waggregate-return
 289         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 290         -Wnested-externs ])
 291 else
 292   dnl work-around for us passing GST_CFLAGS to the ObjC-compiler, which
 293   dnl doesn't understand all warning flags that the C compiler knows about
 294   dnl (e.g. -Waddress) or causes problems with some flags (-Waggregate-return)
 295   AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 296         -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 297         -Wwrite-strings -Wold-style-definition
 298         -Winit-self -Wmissing-include-dirs -Wno-multichar
 299         -Wnested-externs ])
 300 fi
 301
 302 dnl define an ERROR_CXXFLAGS Makefile variable
 303 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 304         -Wmissing-declarations -Wredundant-decls
 305         -Wwrite-strings
 306         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar ])
 307
 308 dnl define correct level for debugging messages
 309 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 310
 311 dnl used in examples
 312 AG_GST_DEFAULT_ELEMENTS
 313
 314 dnl *** plug-ins to include ***
 315
 316 dnl Non ported plugins (non-dependant, then dependant)
 317 dnl Make sure you have a space before and after all plugins
 318 GST_PLUGINS_NONPORTED="deinterlace flx \
 319  videobox \
 320  cairo cairo_gobject dv1394 gdk_pixbuf \
 321  oss oss4 \
 322  osx_video osx_audio "
 323 AC_SUBST(GST_PLUGINS_NONPORTED)
 324
 325 dnl these are all the gst plug-ins, compilable without additional libs
 326 dnl videofilter is at the top because others depend on it
 327 AG_GST_CHECK_PLUGIN(alpha)
 328 AG_GST_CHECK_PLUGIN(apetag)
 329 AG_GST_CHECK_PLUGIN(audiofx)
 330 AG_GST_CHECK_PLUGIN(audioparsers)
 331 AG_GST_CHECK_PLUGIN(auparse)
 332 AG_GST_CHECK_PLUGIN(autodetect)
 333 AG_GST_CHECK_PLUGIN(avi)
 334 AG_GST_CHECK_PLUGIN(cutter)
 335 AG_GST_CHECK_PLUGIN(debugutils)
 336 AG_GST_CHECK_PLUGIN(deinterlace)
 337 AG_GST_CHECK_PLUGIN(effectv)
 338 AG_GST_CHECK_PLUGIN(equalizer)
 339 AG_GST_CHECK_PLUGIN(flv)
 340 AG_GST_CHECK_PLUGIN(flx)
 341 AG_GST_CHECK_PLUGIN(goom)
 342 AG_GST_CHECK_PLUGIN(goom2k1)
 343 AG_GST_CHECK_PLUGIN(icydemux)
 344 AG_GST_CHECK_PLUGIN(id3demux)
 345 AG_GST_CHECK_PLUGIN(imagefreeze)
 346 AG_GST_CHECK_PLUGIN(interleave)
 347 AG_GST_CHECK_PLUGIN(isomp4)
 348 AG_GST_CHECK_PLUGIN(law)
 349 AG_GST_CHECK_PLUGIN(level)
 350 AG_GST_CHECK_PLUGIN(matroska)
 351 AG_GST_CHECK_PLUGIN(monoscope)
 352 AG_GST_CHECK_PLUGIN(multifile)
 353 AG_GST_CHECK_PLUGIN(multipart)
 354 AG_GST_CHECK_PLUGIN(replaygain)
 355 AG_GST_CHECK_PLUGIN(rtp)
 356 AG_GST_CHECK_PLUGIN(rtpmanager)
 357 AG_GST_CHECK_PLUGIN(rtsp)
 358 AG_GST_CHECK_PLUGIN(shapewipe)
 359 AG_GST_CHECK_PLUGIN(smpte)
 360 AG_GST_CHECK_PLUGIN(spectrum)
 361 AG_GST_CHECK_PLUGIN(udp)
 362 AG_GST_CHECK_PLUGIN(videobox)
 363 AG_GST_CHECK_PLUGIN(videocrop)
 364 AG_GST_CHECK_PLUGIN(videofilter)
 365 AG_GST_CHECK_PLUGIN(videomixer)
 366 AG_GST_CHECK_PLUGIN(wavenc)
 367 AG_GST_CHECK_PLUGIN(wavparse)
 368 AG_GST_CHECK_PLUGIN(y4m)
 369
 370 dnl disable experimental plug-ins
 371 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 372   AG_GST_DISABLE_PLUGIN(monoscope)
 373 fi
 374
 375 dnl *** sys plug-ins ***
 376
 377 echo
 378 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 379 echo
 380
 381 dnl DirectSound
 382 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 383 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 384   HAVE_DIRECTSOUND="no"
 385   save_CFLAGS="$CFLAGS"
 386   save_LDFLAGS="$LDFLAGS"
 387   save_LIBS="$LIBS"
 388   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 389   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 390   LIBS="$LIBS -ldsound -ldxerr9 -luser32"
 391   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 392   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 393 #include <windows.h>
 394 #include <dxerr9.h>
 395 #include <dsound.h>
 396 ]], [[
 397   DXGetErrorString9 (0);
 398   DirectSoundCreate(NULL, NULL, NULL);
 399 ]])
 400 ],
 401     [HAVE_DIRECTSOUND="yes"],
 402     [HAVE_DIRECTSOUND="no"])
 403   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 404   CFLAGS=$save_CFLAGS
 405   LDFLAGS=$save_LDFLAGS
 406   LIBS=$save_LIBS
 407
 408   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 409     dnl this is much more than we want
 410     DIRECTSOUND_LIBS="-ldsound -ldxerr9 -luser32"
 411     AC_SUBST(DIRECTSOUND_CFLAGS)
 412     AC_SUBST(DIRECTSOUND_LDFLAGS)
 413     AC_SUBST(DIRECTSOUND_LIBS)
 414   fi
 415   AC_SUBST(HAVE_DIRECTSOUND)
 416 ])
 417
 418 dnl *** Win32 WaveOut ***
 419 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVEFORM, true)
 420 AG_GST_CHECK_FEATURE(WAVEFORM, [Win32 WaveForm], waveformsink, [
 421   AC_CHECK_HEADER(mmsystem.h, HAVE_WAVEFORM="yes", HAVE_WAVEFORM="no", [#include <windows.h>])
 422 ])
 423
 424 dnl *** OSS audio *** (Linux, *BSD)
 425 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 426 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 427  HAVE_OSS="yes"
 428 dnl Linux and newer BSD versions :
 429  AC_CHECK_HEADER(sys/soundcard.h, [
 430    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 431    ] , [
 432 dnl Some old BSD versions and also newer OpenBSD versions :
 433    AC_CHECK_HEADER(soundcard.h, [
 434      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 435      ], [
 436   dnl Some old BSD versions :
 437      AC_CHECK_HEADER(machine/soundcard.h, [
 438        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 439          [Define if OSS includes are in /machine/])
 440        ], [
 441        HAVE_OSS="no"
 442      ])
 443    ])
 444  ])
 445 ])
 446
 447 dnl *** oss4 ***
 448 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS4, true)
 449 AG_GST_CHECK_FEATURE(OSS4, [Open Sound System 4], oss4, [
 450   AC_MSG_CHECKING([Checking if we can build the OSS4 elements])
 451   AC_CHECK_HEADERS([fcntl.h sys/ioctl.h sys/stat.h sys/types.h],
 452       [test -z "$OSS4_MISSING_HEADER" && HAVE_OSS4="yes"],
 453       [OSS4_MISSING_HEADER="yes";HAVE_OSS4="no"])
 454 ])
 455
 456 dnl *** Sun Audio ***
 457 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 458 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 459   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 460 ])
 461
 462 dnl *** OSX Audio ***
 463 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 464 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 465   AC_CHECK_HEADER(CoreAudio/CoreAudio.h, HAVE_OSX_AUDIO="yes", HAVE_OSX_AUDIO="no")
 466 ])
 467
 468 dnl *** OS X video ***
 469 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 470 HAVE_OSX_VIDEO="no"
 471 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 472   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 473 ])
 474 dnl in case header OpenGL/gl.h is found on other platforms
 475 case "$host" in
 476   *-*darwin*)
 477     dnl do nothing
 478     ;;
 479   *)
 480     HAVE_OSX_VIDEO="no"
 481     ;;
 482 esac
 483
 484
 485 dnl *** Video 4 Linux 2 ***
 486 dnl for information about the header/define, see sys/v4l2/gstv4l2element.h
 487 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 488 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 489 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], v4l2src, [
 490   AC_MSG_CHECKING([Checking for up to date v4l2 installation])
 491   AC_TRY_COMPILE([
 492 #include <sys/types.h>
 493 #ifdef __sun /* Solaris */
 494 #include <sys/types.h>
 495 #include <sys/videodev2.h>
 496 #else /* Linux */
 497 #include <linux/types.h>
 498 #define _LINUX_TIME_H
 499 #define __user
 500 #include <linux/videodev2.h>
 501 #endif
 502 #if defined(V4L2_MAJOR_VERSION) || defined(V4L2_MINOR_VERSION)
 503 #error too early v4l2 version or no v4l2 at all
 504 #endif
 505     ], [
 506 return 0;
 507     ], [
 508       HAVE_GST_V4L2="yes"
 509       AC_MSG_RESULT(yes)
 510     ], [
 511       HAVE_GST_V4L2="no"
 512       AC_MSG_RESULT(no)
 513
 514       HAVE_VIDEODEV=no
 515       AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_VIDEODEV=yes ],
 516       [
 517         AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_VIDEODEV=yes ])
 518       ])
 519
 520       if test "x$HAVE_VIDEODEV" = "xyes"; then
 521         AC_MSG_WARN([video4linux2 headers were found, but they're old.])
 522         AC_MSG_WARN([Please update v4l2 to compile the v4l2 plugins])
 523       else
 524         AC_MSG_WARN([video4linux2 was not found])
 525       fi
 526     ])
 527
 528   if [ test x$HAVE_GST_V4L2 = xyes ]; then
 529     dnl check for missing v4l2_buffer declaration (see #135919)
 530     MISSING_DECL=0
 531     AC_MSG_CHECKING(struct v4l2_buffer declaration)
 532     AC_TRY_COMPILE([
 533 #include <sys/types.h>
 534 #ifdef __sun /* Solaris */
 535 #include <sys/types.h>
 536 #include <sys/videodev2.h>
 537 #else /* Linux */
 538 #include <linux/types.h>
 539 #define _LINUX_TIME_H
 540 #define __user
 541 #include <linux/videodev2.h>
 542 #endif
 543     ],[
 544 struct v4l2_buffer buf;
 545 buf.index = 0;
 546 return 0;
 547     ], [ AC_MSG_RESULT(yes) ], [ MISSING_DECL=1 && AC_MSG_RESULT(no) ])
 548     if [ test x$MISSING_DECL = x1 ]; then
 549       AC_DEFINE(GST_V4L2_MISSING_BUFDECL, 1, [struct v4l2_buffer missing])
 550     fi
 551
 552     dnl check for XOverlay libraries
 553     AG_GST_CHECK_XV
 554   fi
 555 ])
 556
 557 # Optional gudev for device probing
 558 AC_ARG_WITH([gudev],
 559   AC_HELP_STRING([--with-gudev],
 560     [device detection with gudev]),
 561   [],
 562   [with_gudev=check])
 563 if test x$HAVE_GST_V4L2 = xyes; then
 564   if test x$with_gudev != xno; then
 565       PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 143 ],
 566           [ have_gudev=yes
 567             AC_DEFINE(HAVE_GUDEV, 1,
 568                [Whether gudev is available for device detection])
 569             AC_DEFINE([G_UDEV_API_IS_SUBJECT_TO_CHANGE], 1, [I know the API is subject to change.])
 570           ], [
 571           have_gudev=no
 572           ])
 573   else
 574     have_gudev=no
 575   fi
 576 fi
 577 AC_SUBST(GUDEV_CFLAGS)
 578 AC_SUBST(GUDEV_LIBS)
 579
 580 # Make libv4l2 non-automagic
 581 AC_ARG_WITH([libv4l2],
 582   AC_HELP_STRING([--with-libv4l2],
 583     [support video buffer conversion using libv4l2]),
 584   [],
 585   [with_libv4l2=check])
 586 if test x$HAVE_GST_V4L2 = xyes; then
 587   if test x$with_libv4l2 != xno; then
 588       PKG_CHECK_MODULES(LIBV4L2, libv4l2,
 589           [ have_libv4l2=yes
 590             AC_DEFINE(HAVE_LIBV4L2, 1,
 591                 [Whether libv4l2 is available for video buffer conversion])
 592           ], [
 593           have_libv4l2=no
 594           ])
 595   else
 596     have_libv4l2=no
 597   fi
 598 fi
 599
 600 dnl Check for X11
 601 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 602 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 603                   [ximagesrc], [
 604   AC_PATH_XTRA
 605
 606   dnl now try to find the HEADER
 607   ac_cflags_save="$CFLAGS"
 608   ac_cppflags_save="$CPPFLAGS"
 609   CFLAGS="$CFLAGS $X_CFLAGS"
 610   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 611   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 612
 613   if test "x$HAVE_X" = "xno"
 614   then
 615     AC_MSG_NOTICE([cannot find X11 development files])
 616   else
 617     dnl this is much more than we want
 618     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 619     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 620     dnl it does not add the libs; therefore we add them here
 621     X_LIBS="$X_LIBS -lX11"
 622     AC_SUBST(X_CFLAGS)
 623     AC_SUBST(X_LIBS)
 624
 625     dnl check for Xfixes
 626     PKG_CHECK_MODULES(XFIXES, xfixes, HAVE_XFIXES="yes", HAVE_XFIXES="no")
 627     if test "x$HAVE_XFIXES" = "xyes"
 628     then
 629         XFIXES_CFLAGS="-DHAVE_XFIXES $XFIXES_CFLAGS"
 630     fi
 631     AC_SUBST(XFIXES_LIBS)
 632     AC_SUBST(XFIXES_CFLAGS)
 633
 634     dnl check for Xdamage
 635     PKG_CHECK_MODULES(XDAMAGE, xdamage, HAVE_XDAMAGE="yes", HAVE_XDAMAGE="no")
 636     if test "x$HAVE_XDAMAGE" = "xyes"
 637     then
 638         XDAMAGE_CFLAGS="-DHAVE_XDAMAGE $XDAMAGE_CFLAGS"
 639     fi
 640     AC_SUBST(XDAMAGE_LIBS)
 641     AC_SUBST(XDAMAGE_CFLAGS)
 642   fi
 643   AC_SUBST(HAVE_X)
 644   CFLAGS="$ac_cflags_save"
 645   CPPFLAGS="$ac_cppflags_save"
 646 ])
 647
 648 dnl FIXME: this should be rolled into the test above, it's just an additional
 649 dnl feature of the ximagesrc plug-in
 650 dnl This is the same as in gst-plugins-base
 651 dnl check for X Shm
 652 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 653 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 654   if test x$HAVE_X = xyes; then
 655     AC_CHECK_LIB(Xext, XShmAttach,
 656                  HAVE_XSHM="yes", HAVE_XSHM="no",
 657                  $X_LIBS)
 658     if test "x$HAVE_XSHM" = "xyes"; then
 659       XSHM_LIBS="-lXext"
 660     else
 661       dnl On AIX, it is in XextSam instead, but we still need -lXext
 662       AC_CHECK_LIB(XextSam, XShmAttach,
 663                    HAVE_XSHM="yes", HAVE_XSHM="no",
 664                    $X_LIBS)
 665       if test "x$HAVE_XSHM" = "xyes"; then
 666         XSHM_LIBS="-lXext -lXextSam"
 667       fi
 668     fi
 669   fi
 670 ], ,[
 671   AC_SUBST(HAVE_XSHM)
 672   AC_SUBST(XSHM_LIBS)
 673 ])
 674
 675 dnl for V4L2, we also need to know if we have XVIDEO
 676 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 677 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 678                   [], [
 679   AG_GST_CHECK_XV
 680 ])
 681
 682 dnl *** ext plug-ins ***
 683 dnl keep this list sorted alphabetically !
 684
 685 if test "x$BUILD_EXTERNAL" = "xyes"; then
 686
 687 echo
 688 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 689 echo
 690
 691 dnl *** aalib ***
 692 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 693 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 694   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 695   AS_SCRUB_INCLUDE(AALIB_CFLAGS)
 696 ])
 697
 698 dnl *** annodex ***
 699 translit(dnm, m, l) AM_CONDITIONAL(USE_ANNODEX, true)
 700 AG_GST_CHECK_FEATURE(ANNODEX, [XML library], annodex, [
 701   AG_GST_PKG_CHECK_MODULES(ANNODEX, libxml-2.0 >= 2.4.9)
 702 ])
 703
 704 dnl *** cairo ***
 705 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 706 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering], cairo, [
 707   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.0.0)
 708 ])
 709
 710 dnl *** cairo-gobject ***
 711 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO_GOBJECT, true)
 712 AG_GST_CHECK_FEATURE(CAIRO_GOBJECT,
 713   [Cairo graphics rendering gobject bindings], cairooverlay, [
 714   AG_GST_PKG_CHECK_MODULES(CAIRO_GOBJECT, cairo-gobject >= 1.10.0)
 715 ])
 716
 717 dnl *** FLAC ***
 718 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 719 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 720   AG_GST_PKG_CHECK_MODULES(FLAC, flac >= 1.1.4)
 721 ])
 722
 723 dnl *** GDK pixbuf ***
 724 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 725 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 726   AG_GST_PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0 >= 2.8.0)
 727 ])
 728
 729 dnl *** Jack ***
 730 translit(dnm, m, l) AM_CONDITIONAL(USE_JACK, true)
 731 AG_GST_CHECK_FEATURE(JACK, Jack, jack, [
 732   PKG_CHECK_MODULES(JACK, jack >= 0.99.10, HAVE_JACK="yes", HAVE_JACK="no")
 733   AC_SUBST(JACK_CFLAGS)
 734   AC_SUBST(JACK_LIBS)
 735
 736   AG_GST_PKG_CHECK_MODULES(JACK_0_120_1, jack >= 0.120.1 jack < 1.0)
 737   if test x$HAVE_JACK_0_120_1 = xyes; then
 738     AC_DEFINE(HAVE_JACK_0_120_1, 1, [defined if jack >= 0.120.1 is available])
 739   fi
 740   AG_GST_PKG_CHECK_MODULES(JACK_1_9_7, jack >= 1.9.7)
 741   if test x$HAVE_JACK_1_9_7 = xyes; then
 742     AC_DEFINE(HAVE_JACK_1_9_7, 1, [defined if jack >= 1.9.7 is available])
 743   fi
 744
 745 ])
 746
 747 dnl *** jpeg ***
 748 dnl FIXME: we could use header checks here as well IMO
 749 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 750 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 751   AC_ARG_WITH(jpeg-mmx,
 752     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 753   OLD_LIBS="$LIBS"
 754   if test x$with_jpeg_mmx != x; then
 755     LIBS="$LIBS -L$with_jpeg_mmx"
 756   fi
 757   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 758   JPEG_LIBS="$LIBS -ljpeg-mmx"
 759   LIBS="$OLD_LIBS"
 760   if test x$HAVE_JPEG != xyes; then
 761     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 762     JPEG_LIBS="-ljpeg"
 763   fi
 764   AC_SUBST(JPEG_LIBS)
 765 ])
 766
 767 dnl *** libcaca ***
 768 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 769 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 770   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 771 ])
 772
 773 dnl *** libdv ***
 774 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 775 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 776   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 777 ])
 778
 779 dnl *** libpng ***
 780 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 781 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 782   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng >= 1.2)
 783 ])
 784
 785 dnl *** pulseaudio ***
 786 translit(dnm, m, l) AM_CONDITIONAL(USE_PULSE, true)
 787 AG_GST_CHECK_FEATURE(PULSE, [pulseaudio plug-in], pulseaudio, [
 788
 789   dnl used in ext/pulse/pulseutil.c
 790   AC_CHECK_HEADERS([process.h])
 791
 792   AG_GST_PKG_CHECK_MODULES(PULSE, libpulse >= 1.0)
 793 ])
 794
 795 dnl *** dv1394 ***
 796 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 797 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 798   dnl first test for libraw1394 >= 2.0.0
 799   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 2.0.0)
 800   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 801   dnl now see how far we got
 802   if test x$HAVE_RAW1394 = xyes && \
 803      test x$HAVE_LIBIEC61883 = xyes; then
 804        AG_GST_CHECK_LIBHEADER(AVC1394,
 805         avc1394, avc1394_send_command, $RAW1394_LIBS,
 806         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 807        AG_GST_CHECK_LIBHEADER(ROM1394,
 808         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 809         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 810        if test x$HAVE_AVC1394 = xyes && \
 811           test x$HAVE_AVC1394 = xyes && \
 812           test x$HAVE_ROM1394 = xyes; then
 813           HAVE_DV1394=yes
 814           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 815           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 816           AC_SUBST(DV1394_CFLAGS)
 817           AC_SUBST(DV1394_LIBS)
 818         fi
 819   else
 820        if test x$HAVE_RAW1394 = xno; then
 821           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 822           AG_GST_CHECK_LIBHEADER(AVC1394,
 823            avc1394, avc1394_send_command, $RAW1394_LIBS,
 824            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 825           AG_GST_CHECK_LIBHEADER(ROM1394,
 826            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 827            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 828           if test x$HAVE_RAW1394 = xyes && \
 829              test x$HAVE_AVC1394 = xyes && \
 830              test x$HAVE_ROM1394 = xyes; then
 831              HAVE_DV1394=yes
 832              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 833              DV1394_CFLAGS="$RAW1394_CFLAGS"
 834              if test x$HAVE_LIBIEC61883 = xyes; then
 835                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 836                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 837              fi
 838              AC_SUBST(DV1394_CFLAGS)
 839              AC_SUBST(DV1394_LIBS)
 840            fi
 841          fi
 842   fi
 843 ])
 844 AM_CONDITIONAL(USE_LIBIEC61883, [ test "x${HAVE_LIBIEC61883}" = xyes ] )
 845
 846 dnl *** shout2 ***
 847 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 848 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 849   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 850 ])
 851
 852 dnl *** soup ***
 853 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUP, true)
 854 AG_GST_CHECK_FEATURE(SOUP, [soup http client plugin (2.4)], souphttpsrc, [
 855   PKG_CHECK_MODULES(SOUP, libsoup-gnome-2.4 >= 2.3.2, [
 856     HAVE_SOUP="yes"
 857     AC_DEFINE(HAVE_LIBSOUP_GNOME, 1, [soup gnome integration])
 858   ],[
 859     PKG_CHECK_MODULES(SOUP, libsoup-2.4 >= 2.26, HAVE_SOUP="yes", [
 860       HAVE_SOUP="no"
 861     ])
 862   ])
 863   AC_SUBST(SOUP_CFLAGS)
 864   AC_SUBST(SOUP_LIBS)
 865 ])
 866
 867 dnl *** speex >= 1.0.4 or >= 1.1.5 ***
 868 dnl   1.1.4 and earlier were not API/ABI compatible with 1.0
 869 dnl   1.1.6 is the first to use a .pc/pkg-config file ***
 870 dnl   speex_jitter.h is 1.1.x only
 871 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 872 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 873   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 874   if test $HAVE_SPEEX = no
 875   then
 876     AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_bits_init, , speex/speex.h, [
 877       AC_CHECK_HEADER(speex/speex_jitter.h, [
 878         dnl speex 1.1.x :
 879         AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_encode_int, , speex/speex.h, [
 880           dnl speex 1.1.5 or + :
 881           HAVE_SPEEX="yes"
 882           SPEEX_LIBS="-lspeex"
 883           AC_SUBST(SPEEX_CFLAGS)
 884           AC_SUBST(SPEEX_LIBS)
 885         ],[
 886           HAVE_SPEEX="no"
 887         ])
 888       ],[
 889         dnl speex 1.0.x :
 890           AC_CHECK_DECL(SPEEX_GET_LOOKAHEAD, [
 891             dnl speex 1.0.4
 892             HAVE_SPEEX="yes"
 893             SPEEX_LIBS="-lspeex"
 894             AC_SUBST(SPEEX_CFLAGS)
 895             AC_SUBST(SPEEX_LIBS)
 896
 897             AC_DEFINE_UNQUOTED(SPEEX_1_0, 1,
 898               [defined if speex 1.0.x API detected])
 899         ],[
 900             HAVE_SPEEX="no"
 901             AC_MSG_NOTICE(You need at least 1.0.4 to compile the speex plugin)
 902         ], [
 903 #include <speex/speex.h>
 904         ])
 905       ])
 906     ])
 907   fi
 908 ])
 909
 910 dnl *** taglib ***
 911 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 912 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 913   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.5)
 914   if test "x$HAVE_CXX" != "xyes"; then
 915     USE_TAGLIB=false
 916     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 917   else
 918     dnl work around bug in taglib 1.5 headers, remove once there is a 1.6
 919     AS_CXX_COMPILER_FLAG([-Wno-attributes], [
 920         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS -Wno-attributes"
 921       ], [
 922         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS"
 923     ])
 924     AC_SUBST(TAGLIB_CXXFLAGS)
 925   fi
 926 ])
 927
 928 dnl *** wavpack ***
 929 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 930 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 931   PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.40.0, HAVE_WAVPACK=yes, [
 932     PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.20, [
 933       HAVE_WAVPACK=yes
 934       AC_DEFINE(WAVPACK_OLD_API, 1, [old wavpack API])
 935     ],[
 936       HAVE_WAVPACK=no
 937     ])
 938   ])
 939   AC_SUBST(WAVPACK_CFLAGS)
 940   AC_SUBST(WAVPACK_LIBS)
 941 ])
 942
 943 dnl *** qtdemux & matroska prefer to have zlib ***
 944 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 945 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for qtdemux/matroska],, [
 946   AG_GST_CHECK_LIBHEADER(ZLIB,
 947     z, uncompress,, zlib.h, [
 948     HAVE_ZLIB="yes"
 949     ZLIB_LIBS="-lz"
 950     AC_SUBST(ZLIB_LIBS)
 951   ])
 952 ])
 953
 954 dnl *** matroska prefers to have bz2 ***
 955 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
 956 AG_GST_CHECK_FEATURE(BZ2, [bz2 library for matroska ],, [
 957   AG_GST_CHECK_LIBHEADER(BZ2, bz2, BZ2_bzCompress, ,bzlib.h, BZ2_LIBS="-lbz2")
 958   AC_SUBST(BZ2_LIBS)
 959 ])
 960
 961 else
 962
 963 dnl not building plugins with external dependencies,
 964 dnl but we still need to set the conditionals
 965 AM_CONDITIONAL(USE_AALIB, false)
 966 AM_CONDITIONAL(USE_ANNODEX, false)
 967 AM_CONDITIONAL(USE_BZ2, false)
 968 AM_CONDITIONAL(USE_CAIRO, false)
 969 AM_CONDITIONAL(USE_CAIRO_GOBJECT, false)
 970 AM_CONDITIONAL(USE_DIRECTSOUND, false)
 971 AM_CONDITIONAL(USE_DV1394, false)
 972 AM_CONDITIONAL(USE_FLAC, false)
 973 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
 974 AM_CONDITIONAL(USE_GST_V4L2, false)
 975 AM_CONDITIONAL(USE_JACK, false)
 976 AM_CONDITIONAL(USE_JPEG, false)
 977 AM_CONDITIONAL(USE_LIBCACA, false)
 978 AM_CONDITIONAL(USE_LIBDV, false)
 979 AM_CONDITIONAL(USE_LIBIEC61883, false)
 980 AM_CONDITIONAL(USE_LIBPNG, false)
 981 AM_CONDITIONAL(USE_OSS, false)
 982 AM_CONDITIONAL(USE_OSS4, false)
 983 AM_CONDITIONAL(USE_OSX_AUDIO, false)
 984 AM_CONDITIONAL(USE_OSX_VIDEO, false)
 985 AM_CONDITIONAL(USE_PULSE, false)
 986 AM_CONDITIONAL(USE_SHOUT2, false)
 987 AM_CONDITIONAL(USE_SOUP, false)
 988 AM_CONDITIONAL(USE_SPEEX, false)
 989 AM_CONDITIONAL(USE_SUNAUDIO, false)
 990 AM_CONDITIONAL(USE_TAGLIB, false)
 991 AM_CONDITIONAL(USE_WAVEFORM, false)
 992 AM_CONDITIONAL(USE_WAVPACK, false)
 993 AM_CONDITIONAL(USE_X, false)
 994 AM_CONDITIONAL(USE_XSHM, false)
 995 AM_CONDITIONAL(USE_XVIDEO, false)
 996 AM_CONDITIONAL(USE_ZLIB, false)
 997
 998 fi dnl of EXT plugins
 999
1000 dnl *** finalize CFLAGS, LDFLAGS, LIBS
1001
1002 dnl Overview:
1003 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
1004 dnl GST_*:              flags shared by all built objects
1005 dnl GST_ALL_LDFLAGS:    linker flags shared by all
1006 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
1007 dnl GST_LT_LDFLAGS:     library versioning of our libraries
1008 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
1009
1010 dnl GST_OPTION_CFLAGS
1011 if test "x$USE_DEBUG" = xyes; then
1012    PROFILE_CFLAGS="-g"
1013 fi
1014 AC_SUBST(PROFILE_CFLAGS)
1015
1016 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
1017   dnl Define _only_ for git (not pre-releases or releases)
1018   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
1019 else
1020   DEPRECATED_CFLAGS=""
1021 fi
1022 AC_SUBST(DEPRECATED_CFLAGS)
1023
1024 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
1025 dnl at make time with e.g. make ERROR_CFLAGS=""
1026 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1027 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1028 AC_SUBST(GST_OPTION_CFLAGS)
1029 AC_SUBST(GST_OPTION_CXXFLAGS)
1030
1031 dnl our libraries need to be versioned correctly
1032 AC_SUBST(GST_LT_LDFLAGS)
1033
1034 dnl FIXME: do we want to rename to GST_ALL_* ?
1035 dnl prefer internal headers to already installed ones
1036 dnl also add builddir include for enumtypes and marshal
1037 dnl add ERROR_CFLAGS, but overridable
1038 GST_CFLAGS="$GST_CFLAGS -DGST_USE_UNSTABLE_API"
1039 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS)"
1040 GST_CFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
1041 AC_SUBST(GST_CFLAGS)
1042 AC_SUBST(GST_CXXFLAGS)
1043 AC_SUBST(GST_LIBS)
1044
1045 dnl LDFLAGS really should only contain flags, not libs - they get added before
1046 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1047 GST_ALL_LDFLAGS="-no-undefined"
1048 AC_SUBST(GST_ALL_LDFLAGS)
1049
1050 dnl this really should only contain flags, not libs - they get added before
1051 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1052 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
1053 AC_SUBST(GST_PLUGIN_LDFLAGS)
1054
1055 dnl *** output files ***
1056
1057 dnl keep this alphabetic per directory, please
1058 AC_CONFIG_FILES(
1059 Makefile
1060 gst/Makefile
1061 gst/alpha/Makefile
1062 gst/apetag/Makefile
1063 gst/audiofx/Makefile
1064 gst/audioparsers/Makefile
1065 gst/auparse/Makefile
1066 gst/autodetect/Makefile
1067 gst/avi/Makefile
1068 gst/cutter/Makefile
1069 gst/deinterlace/Makefile
1070 gst/debugutils/Makefile
1071 gst/effectv/Makefile
1072 gst/equalizer/Makefile
1073 gst/flv/Makefile
1074 gst/goom/Makefile
1075 gst/goom2k1/Makefile
1076 gst/id3demux/Makefile
1077 gst/icydemux/Makefile
1078 gst/imagefreeze/Makefile
1079 gst/interleave/Makefile
1080 gst/isomp4/Makefile
1081 gst/law/Makefile
1082 gst/level/Makefile
1083 gst/matroska/Makefile
1084 gst/monoscope/Makefile
1085 gst/multifile/Makefile
1086 gst/multipart/Makefile
1087 gst/replaygain/Makefile
1088 gst/rtp/Makefile
1089 gst/rtpmanager/Makefile
1090 gst/rtsp/Makefile
1091 gst/shapewipe/Makefile
1092 gst/smpte/Makefile
1093 gst/spectrum/Makefile
1094 gst/udp/Makefile
1095 gst/videobox/Makefile
1096 gst/videocrop/Makefile
1097 gst/videofilter/Makefile
1098 gst/videomixer/Makefile
1099 gst/wavenc/Makefile
1100 gst/wavparse/Makefile
1101 gst/flx/Makefile
1102 gst/y4m/Makefile
1103 ext/Makefile
1104 ext/aalib/Makefile
1105 ext/annodex/Makefile
1106 ext/cairo/Makefile
1107 ext/dv/Makefile
1108 ext/flac/Makefile
1109 ext/gdk_pixbuf/Makefile
1110 ext/jack/Makefile
1111 ext/jpeg/Makefile
1112 ext/libcaca/Makefile
1113 ext/libpng/Makefile
1114 ext/pulse/Makefile
1115 ext/raw1394/Makefile
1116 ext/shout2/Makefile
1117 ext/soup/Makefile
1118 ext/speex/Makefile
1119 ext/taglib/Makefile
1120 ext/wavpack/Makefile
1121 sys/Makefile
1122 sys/directsound/Makefile
1123 sys/oss/Makefile
1124 sys/oss4/Makefile
1125 sys/osxaudio/Makefile
1126 sys/osxvideo/Makefile
1127 sys/sunaudio/Makefile
1128 sys/v4l2/Makefile
1129 sys/waveform/Makefile
1130 sys/ximage/Makefile
1131 po/Makefile.in
1132 tests/Makefile
1133 tests/check/Makefile
1134 tests/examples/Makefile
1135 tests/examples/audiofx/Makefile
1136 tests/examples/cairo/Makefile
1137 tests/examples/equalizer/Makefile
1138 tests/examples/jack/Makefile
1139 tests/examples/level/Makefile
1140 tests/examples/pulse/Makefile
1141 tests/examples/rtp/Makefile
1142 tests/examples/shapewipe/Makefile
1143 tests/examples/spectrum/Makefile
1144 tests/examples/v4l2/Makefile
1145 tests/files/Makefile
1146 tests/icles/Makefile
1147 common/Makefile
1148 common/m4/Makefile
1149 m4/Makefile
1150 docs/Makefile
1151 docs/plugins/Makefile
1152 docs/version.entities
1153 pkgconfig/Makefile
1154 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1155 gst-plugins-good.spec
1156 )
1157
1158 dnl Create the config.h file for Visual Studio builds
1159 dnl Beware of spaces and /'s in some of the shell variable contents.
1160 sed \
1161     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"\n\n#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
1162     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
1163     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
1164     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
1165     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
1166     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
1167     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
1168     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
1169     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
1170     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
1171     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
1172     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
1173     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
1174     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
1175     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
1176     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
1177     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
1178     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
1179     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
1180     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1181     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1182     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1183     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
1184     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1185     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
1186     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1187     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1188     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1189     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
1190     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
1191     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1192     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
1193     -e "s/.* DEFAULT_AUDIOSRC$/#define DEFAULT_AUDIOSRC \"audiotestsrc\"/" \
1194     -e "s/.* DEFAULT_VIDEOSRC$/#define DEFAULT_VIDEOSRC \"videotestsrc\"/" \
1195     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1196     config.h.in >win32/common/config.h-new
1197
1198 AC_OUTPUT
1199
1200 AG_GST_OUTPUT_PLUGINS
1201 ORC_OUTPUT
1202