configure.ac

   1 AC_PREREQ([2.68])
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/pre
   8 AC_INIT([GStreamer Good Plug-ins],[1.5.0.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gst-plugins-good])
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.11 no-dist-gzip dist-xz tar-ustar subdir-objects])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  23
  24 dnl define the output header for config
  25 AC_CONFIG_HEADERS([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output with automake >= 1.11
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  35   [AM_DEFAULT_VERBOSITY=1
  36    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  37
  38 dnl our libraries and install dirs use GST_API_VERSION in the filename
  39 dnl to allow side-by-side installation of different API versions
  40 GST_API_VERSION=1.0
  41 AC_SUBST(GST_API_VERSION)
  42 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  43   [GStreamer API Version])
  44
  45 AG_GST_LIBTOOL_PREPARE
  46 AS_LIBTOOL(GST, 501, 0, 501)
  47
  48 dnl *** required versions of GStreamer stuff ***
  49 GST_REQ=1.5.0.1
  50 GSTPB_REQ=1.5.0.1
  51
  52 dnl *** autotools stuff ****
  53
  54 dnl allow for different autotools
  55 AS_AUTOTOOLS_ALTERNATE
  56
  57 dnl Add parameters for aclocal
  58 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  59
  60 dnl set up gettext
  61 dnl the version check needs to stay here because autopoint greps for it
  62 AM_GNU_GETTEXT_VERSION([0.17])
  63 AM_GNU_GETTEXT([external])
  64 AG_GST_GETTEXT([gst-plugins-good-$GST_API_VERSION])
  65
  66 dnl *** check for arguments to configure ***
  67
  68 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  69
  70 AG_GST_ARG_DEBUG
  71 AG_GST_ARG_PROFILING
  72 AG_GST_ARG_VALGRIND
  73 AG_GST_ARG_GCOV
  74
  75 AG_GST_ARG_EXAMPLES
  76
  77 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  78 AG_GST_ARG_WITH_PACKAGE_NAME
  79 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  80
  81 AG_GST_ARG_WITH_PLUGINS
  82
  83 AG_GST_ARG_ENABLE_EXTERNAL
  84
  85 AG_GST_ARG_ENABLE_EXPERIMENTAL
  86
  87 dnl *** checks for platform ***
  88
  89 dnl * hardware/architecture *
  90
  91 dnl common/m4/gst-arch.m4
  92 dnl check CPU type
  93 AG_GST_ARCH
  94
  95 dnl Determine endianness
  96 AC_C_BIGENDIAN
  97
  98 dnl *** checks for programs ***
  99
 100 dnl find a compiler
 101 AC_PROG_CC
 102 AC_PROG_CC_STDC
 103
 104 dnl determine c++ compiler
 105 AC_PROG_CXX
 106 dnl determine if c++ is available on this system
 107 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 108
 109 dnl determine c++ preprocessor
 110 dnl FIXME: do we need this ?
 111 AC_PROG_CXXCPP
 112
 113 AC_PROG_OBJC
 114
 115 dnl check if the compiler supports '-c' and '-o' options
 116 AM_PROG_CC_C_O
 117
 118 dnl find an assembler
 119 AM_PROG_AS
 120
 121 dnl check if the compiler supports do while(0) macros
 122 AG_GST_CHECK_DOWHILE_MACROS
 123
 124 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 125 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 126
 127 dnl check for documentation tools
 128 GTK_DOC_CHECK([1.12])
 129 AG_GST_PLUGIN_DOCS([1.12])
 130
 131 dnl *** checks for libraries ***
 132
 133 dnl check for libm, for sin()
 134 LT_LIB_M
 135 AC_SUBST(LIBM)
 136
 137 AC_CHECK_FUNCS(clock_gettime, [], [
 138   AC_CHECK_LIB(rt, clock_gettime, [
 139     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 140     LIBRT="-lrt"
 141     AC_SUBST([LIBRT])
 142   ])
 143 ])
 144
 145 dnl *** checks for header files ***
 146
 147 dnl check if we have ANSI C header files
 148 AC_HEADER_STDC
 149
 150 dnl used by ext/wavpack
 151 AX_CREATE_STDINT_H
 152
 153 dnl used in gst/udp
 154 AC_CHECK_HEADERS([sys/time.h])
 155
 156 dnl used in gst/udp
 157 AC_CHECK_HEADERS([sys/socket.h])
 158
 159 dnl *** checks for types/defines ***
 160
 161 dnl Check for FIONREAD ioctl declaration.  This check is needed
 162 dnl for the UDP plugin to build on Solaris
 163 GST_CHECK_FIONREAD
 164
 165 dnl *** checks for structures ***
 166
 167 dnl *** checks for compiler characteristics ***
 168
 169 dnl check if we have GCC inline-asm
 170 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 171 if test x$HAVE_GCC_ASM = xyes ; then
 172   AC_DEFINE(HAVE_GCC_ASM, 1,
 173     [Define if compiler supports gcc inline assembly])
 174 fi
 175 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 176
 177 dnl *** checks for library functions ***
 178
 179 LIBS_SAVE=$LIBS
 180 LIBS="$LIBS $LIBM"
 181 AC_CHECK_FUNCS(rint sinh cosh asinh fpclass)
 182 LIBS=$LIBS_SAVE
 183
 184 dnl Check whether isinf() is defined by math.h
 185 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
 186     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; int i=isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
 187 if test "$ac_cv_have_isinf" = "yes"
 188 then
 189     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
 190 fi
 191
 192 dnl Check for mmap (needed by electricfence plugin)
 193 AC_FUNC_MMAP
 194 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 195
 196 dnl Check for mmap (needed by electricfence plugin)
 197
 198 AC_CHECK_TYPE([struct ip_mreqn], [
 199               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
 200               [#include <netinet/in.h>])
 201
 202 dnl *** checks for dependency libraries ***
 203
 204
 205 dnl GLib
 206 GLIB_REQ=2.32.0
 207 AG_GST_GLIB_CHECK([$GLIB_REQ])
 208
 209 dnl Orc
 210 ORC_CHECK([0.4.17])
 211
 212 dnl checks for gstreamer
 213 dnl uninstalled is selected preferentially -- see pkg-config(1)
 214 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 215 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 216 AG_GST_CHECK_GST_CONTROLLER($GST_API_VERSION, [$GST_REQ], yes)
 217 AG_GST_CHECK_GST_NET($GST_API_VERSION, [$GST_REQ], yes)
 218 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 219 AG_GST_CHECK_GST_PLUGINS_BASE($GST_API_VERSION, [$GSTPB_REQ], yes)
 220
 221 GST_TOOLS_DIR=`$PKG_CONFIG --variable=toolsdir gstreamer-$GST_API_VERSION`
 222 if test -z $GST_TOOLS_DIR; then
 223   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 224 fi
 225 AC_SUBST(GST_TOOLS_DIR)
 226
 227 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 228 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 229
 230 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 231
 232 dnl Check for documentation xrefs
 233 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 234 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 235 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_API_VERSION`"
 236 AC_SUBST(GLIB_PREFIX)
 237 AC_SUBST(GST_PREFIX)
 238 AC_SUBST(GSTPB_PREFIX)
 239
 240 dnl GTK is optional and used in examples
 241 HAVE_GTK=no
 242 GTK_REQ=3.0.0
 243 if test "x$BUILD_EXAMPLES" = "xyes"; then
 244   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 245   dnl some examples need gtk+-x11
 246   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 247   AC_SUBST(GTK_LIBS)
 248   AC_SUBST(GTK_CFLAGS)
 249 fi
 250 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 251 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 252
 253 dnl *** set variables based on configure arguments ***
 254
 255 dnl set license and copyright notice
 256 GST_LICENSE="LGPL"
 257 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 258 AC_SUBST(GST_LICENSE)
 259
 260 dnl set location of plugin directory
 261 AG_GST_SET_PLUGINDIR
 262
 263 dnl set release date/time
 264 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 265   ["${srcdir}/gst-plugins-good.doap"],
 266   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 267
 268 dnl build static plugins or not
 269 AC_MSG_CHECKING([whether to build static plugins or not])
 270 AC_ARG_ENABLE(
 271   static-plugins,
 272   AC_HELP_STRING(
 273     [--enable-static-plugins],
 274     [build static plugins @<:@default=no@:>@]),
 275   [AS_CASE(
 276     [$enableval], [no], [], [yes], [],
 277     [AC_MSG_ERROR([bad value "$enableval" for --enable-static-plugins])])],
 278   [enable_static_plugins=no])
 279 AC_MSG_RESULT([$enable_static_plugins])
 280 if test "x$enable_static_plugins" = xyes; then
 281   AC_DEFINE(GST_PLUGIN_BUILD_STATIC, 1,
 282     [Define if static plugins should be built])
 283   GST_PLUGIN_LIBTOOLFLAGS=""
 284 else
 285   GST_PLUGIN_LIBTOOLFLAGS="--tag=disable-static"
 286 fi
 287 AC_SUBST(GST_PLUGIN_LIBTOOLFLAGS)
 288 AM_CONDITIONAL(GST_PLUGIN_BUILD_STATIC, test "x$enable_static_plugins" = "xyes")
 289
 290 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 291 dnl make sure it doesn't complain about unused variables if debugging is disabled
 292 NO_WARNINGS=""
 293 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 294
 295 dnl define an ERROR_CFLAGS Makefile variable
 296 dnl -Wundef: too many broken headers
 297 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 298       -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 299       -Wwrite-strings -Wold-style-definition -Waggregate-return
 300       -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 301       -Wnested-externs $NO_WARNINGS])
 302
 303 dnl define an ERROR_CXXFLAGS Makefile variable
 304 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 305         -Wmissing-declarations -Wredundant-decls
 306         -Wwrite-strings
 307         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 308         $NO_WARNINGS])
 309
 310 dnl define an ERROR_OBJCFLAGS Makefile variable
 311 AG_GST_SET_ERROR_OBJCFLAGS($FATAL_WARNINGS, [
 312       -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 313       -Wwrite-strings -Wold-style-definition
 314       -Winit-self -Wmissing-include-dirs -Wno-multichar
 315       -Wnested-externs $NO_WARNINGS])
 316
 317 dnl define correct level for debugging messages
 318 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 319
 320 dnl used in examples
 321 AG_GST_DEFAULT_ELEMENTS
 322
 323 dnl *** plug-ins to include ***
 324
 325 dnl these are all the gst plug-ins, compilable without additional libs
 326 dnl videofilter is at the top because others depend on it
 327 AG_GST_CHECK_PLUGIN(alpha)
 328 AG_GST_CHECK_PLUGIN(apetag)
 329 AG_GST_CHECK_PLUGIN(audiofx)
 330 AG_GST_CHECK_PLUGIN(audioparsers)
 331 AG_GST_CHECK_PLUGIN(auparse)
 332 AG_GST_CHECK_PLUGIN(autodetect)
 333 AG_GST_CHECK_PLUGIN(avi)
 334 AG_GST_CHECK_PLUGIN(cutter)
 335 AG_GST_CHECK_PLUGIN(debugutils)
 336 AG_GST_CHECK_PLUGIN(deinterlace)
 337 AG_GST_CHECK_PLUGIN(dtmf)
 338 AG_GST_CHECK_PLUGIN(effectv)
 339 AG_GST_CHECK_PLUGIN(equalizer)
 340 AG_GST_CHECK_PLUGIN(flv)
 341 AG_GST_CHECK_PLUGIN(flx)
 342 AG_GST_CHECK_PLUGIN(goom)
 343 AG_GST_CHECK_PLUGIN(goom2k1)
 344 AG_GST_CHECK_PLUGIN(icydemux)
 345 AG_GST_CHECK_PLUGIN(id3demux)
 346 AG_GST_CHECK_PLUGIN(imagefreeze)
 347 AG_GST_CHECK_PLUGIN(interleave)
 348 AG_GST_CHECK_PLUGIN(isomp4)
 349 AG_GST_CHECK_PLUGIN(law)
 350 AG_GST_CHECK_PLUGIN(level)
 351 AG_GST_CHECK_PLUGIN(matroska)
 352 AG_GST_CHECK_PLUGIN(monoscope)
 353 AG_GST_CHECK_PLUGIN(multifile)
 354 AG_GST_CHECK_PLUGIN(multipart)
 355 AG_GST_CHECK_PLUGIN(replaygain)
 356 AG_GST_CHECK_PLUGIN(rtp)
 357 AG_GST_CHECK_PLUGIN(rtpmanager)
 358 AG_GST_CHECK_PLUGIN(rtsp)
 359 AG_GST_CHECK_PLUGIN(shapewipe)
 360 AG_GST_CHECK_PLUGIN(smpte)
 361 AG_GST_CHECK_PLUGIN(spectrum)
 362 AG_GST_CHECK_PLUGIN(udp)
 363 AG_GST_CHECK_PLUGIN(videobox)
 364 AG_GST_CHECK_PLUGIN(videocrop)
 365 AG_GST_CHECK_PLUGIN(videofilter)
 366 AG_GST_CHECK_PLUGIN(videomixer)
 367 AG_GST_CHECK_PLUGIN(wavenc)
 368 AG_GST_CHECK_PLUGIN(wavparse)
 369 AG_GST_CHECK_PLUGIN(y4m)
 370
 371 dnl disable experimental plug-ins
 372 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 373   AG_GST_DISABLE_PLUGIN(monoscope)
 374 fi
 375
 376 dnl *** sys plug-ins ***
 377
 378 echo
 379 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 380 echo
 381
 382 dnl DirectSound
 383 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 384 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 385   HAVE_DIRECTSOUND="no"
 386   save_CFLAGS="$CFLAGS"
 387   save_LDFLAGS="$LDFLAGS"
 388   save_LIBS="$LIBS"
 389   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 390   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 391   LIBS="$LIBS -ldsound -ldxerr9 -luser32"
 392   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 393   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 394 #include <windows.h>
 395 #include <dxerr9.h>
 396 #include <dsound.h>
 397 ]], [[
 398   DXGetErrorString9 (0);
 399   DirectSoundCreate(NULL, NULL, NULL);
 400 ]])
 401 ],
 402     [HAVE_DIRECTSOUND="yes"],
 403     [HAVE_DIRECTSOUND="no"])
 404   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 405   CFLAGS=$save_CFLAGS
 406   LDFLAGS=$save_LDFLAGS
 407   LIBS=$save_LIBS
 408
 409   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 410     dnl this is much more than we want
 411     DIRECTSOUND_LIBS="-ldsound -ldxerr9 -luser32"
 412     AC_SUBST(DIRECTSOUND_CFLAGS)
 413     AC_SUBST(DIRECTSOUND_LDFLAGS)
 414     AC_SUBST(DIRECTSOUND_LIBS)
 415   fi
 416   AC_SUBST(HAVE_DIRECTSOUND)
 417 ])
 418
 419 dnl *** Win32 WaveOut ***
 420 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVEFORM, true)
 421 AG_GST_CHECK_FEATURE(WAVEFORM, [Win32 WaveForm], waveformsink, [
 422   AC_CHECK_HEADER(mmsystem.h, HAVE_WAVEFORM="yes", HAVE_WAVEFORM="no", [#include <windows.h>])
 423 ])
 424
 425 dnl *** OSS audio *** (Linux, *BSD)
 426 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 427 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 428  HAVE_OSS="yes"
 429 dnl Linux and newer BSD versions :
 430  AC_CHECK_HEADER(sys/soundcard.h, [
 431    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 432    ] , [
 433 dnl Some old BSD versions and also newer OpenBSD versions :
 434    AC_CHECK_HEADER(soundcard.h, [
 435      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 436      ], [
 437   dnl Some old BSD versions :
 438      AC_CHECK_HEADER(machine/soundcard.h, [
 439        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 440          [Define if OSS includes are in /machine/])
 441        ], [
 442        HAVE_OSS="no"
 443      ])
 444    ])
 445  ])
 446 ])
 447
 448 dnl *** oss4 ***
 449 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS4, true)
 450 AG_GST_CHECK_FEATURE(OSS4, [Open Sound System 4], oss4, [
 451   AC_MSG_CHECKING([Checking if we can build the OSS4 elements])
 452   AC_CHECK_HEADERS([fcntl.h sys/ioctl.h sys/stat.h sys/types.h],
 453       [test -z "$OSS4_MISSING_HEADER" && HAVE_OSS4="yes"],
 454       [OSS4_MISSING_HEADER="yes";HAVE_OSS4="no"])
 455 ])
 456
 457 dnl *** Sun Audio ***
 458 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 459 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 460   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 461 ])
 462
 463 dnl *** OSX Audio ***
 464 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 465 HAVE_IOS="no"
 466 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 467   AC_CHECK_HEADER(CoreAudio/CoreAudio.h,
 468     [HAVE_OSX_AUDIO="yes"],
 469     [AC_CHECK_HEADER(CoreAudio/CoreAudioTypes.h,
 470     [
 471       HAVE_OSX_AUDIO="yes"
 472       HAVE_IOS="yes"
 473     ], [
 474       HAVE_OSX_AUDIO="no"
 475       HAVE_IOS="no"
 476     ])]
 477   )
 478 ])
 479 if test "x$HAVE_IOS" = "xyes"; then
 480   AC_DEFINE(HAVE_IOS, 1, [building for iOS platofrm])
 481 fi
 482 AM_CONDITIONAL(HAVE_IOS, test "x$HAVE_IOS" = "xyes")
 483
 484 dnl *** OS X video ***
 485 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 486 HAVE_OSX_VIDEO="no"
 487 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 488   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 489
 490   dnl in case header OpenGL/gl.h is found on other platforms (or older, unsupported OS X)
 491   dnl also require Snow Leopard or newer
 492
 493   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 494         #include <AvailabilityMacros.h>
 495         #if MAC_OS_X_VERSION_MIN_REQUIRED < 1060
 496         #error Too old OSX version
 497         #endif
 498       ]], [[return 0;]])],[HAVE_OSX_VIDEO="yes"],[HAVE_OSX_VIDEO="no"])
 499 ])
 500
 501 dnl *** Video 4 Linux 2 ***
 502 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 503 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 504 HAVE_GST_V4L2=no
 505 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], video4linux2, [
 506   AC_MSG_CHECKING([Checking for video4linux2 header ...])
 507   AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_GST_V4L2=yes ],
 508   [
 509     AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_GST_V4L2=yes ])
 510   ])
 511   if test "x$HAVE_VIDEODEV" = "xno"; then
 512      AC_MSG_WARN([video4linux2 was not found])
 513   fi
 514 ])
 515
 516 # Optional gudev for device probing
 517 AC_ARG_WITH([gudev],
 518   AS_HELP_STRING([--with-gudev],[device detection with gudev]),
 519   [],
 520   [with_gudev=check])
 521 if test x$HAVE_GST_V4L2 = xyes; then
 522   if test x$with_gudev != xno; then
 523     PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 147 ],
 524       [ AC_DEFINE(HAVE_GUDEV, 1,
 525           [Whether gudev is available for device detection])
 526       ],
 527       [true])
 528   fi
 529 fi
 530
 531 AC_SUBST(GUDEV_CFLAGS)
 532 AC_SUBST(GUDEV_LIBS)
 533
 534 # Make libv4l2 non-automagic
 535 AC_ARG_WITH([libv4l2],
 536   AS_HELP_STRING([--with-libv4l2],[support video buffer conversion using libv4l2]),
 537   [],
 538   [with_libv4l2=check])
 539 if test x$HAVE_GST_V4L2 = xyes; then
 540   if test x$with_libv4l2 != xno; then
 541       PKG_CHECK_MODULES(LIBV4L2, libv4l2,
 542           [ have_libv4l2=yes
 543             AC_DEFINE(HAVE_LIBV4L2, 1,
 544                 [Whether libv4l2 is available for video buffer conversion])
 545           ], [
 546           have_libv4l2=no
 547           ])
 548   else
 549     have_libv4l2=no
 550   fi
 551 fi
 552
 553 dnl Check for X11
 554 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 555 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 556                   [ximagesrc], [
 557   PKG_CHECK_MODULES(X, x11, [
 558     dnl check for Xfixes
 559     PKG_CHECK_MODULES(XFIXES, xfixes, [
 560       AC_DEFINE(HAVE_XFIXES, 1, [Defined if Xfixes is available])
 561     ])
 562
 563     dnl check for Xdamage
 564     PKG_CHECK_MODULES(XDAMAGE, xdamage, [
 565       AC_DEFINE(HAVE_XDAMAGE, 1, [Defined if Xdamage is available])
 566     ])
 567
 568     dnl check for X Shm
 569     PKG_CHECK_MODULES(XEXT, xext, [
 570       AC_CHECK_LIB(Xext, XShmAttach, [
 571         AC_DEFINE(HAVE_XSHM, 1, [Defined if XShm is available])
 572         XSHM_LIBS="$XEXT_LIBS"
 573         XSHM_CFLAGS="$XEXT_CFLAGS"
 574       ], [ $X_LIBS ])
 575     ])
 576     AC_SUBST(XSHM_LIBS)
 577     AC_SUBST(XSHM_CFLAGS)
 578   ])
 579 ])
 580
 581 dnl *** ext plug-ins ***
 582 dnl keep this list sorted alphabetically !
 583
 584 if test "x$BUILD_EXTERNAL" = "xyes"; then
 585
 586 echo
 587 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 588 echo
 589
 590 dnl *** aalib ***
 591 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 592 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 593   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 594 ])
 595
 596 dnl *** cairo ***
 597 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 598 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering and gobject bindings], cairo, [
 599   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.10.0 cairo-gobject >= 1.10.0)
 600 ])
 601
 602 dnl *** FLAC ***
 603 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 604 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 605   AG_GST_PKG_CHECK_MODULES(FLAC, flac >= 1.1.4)
 606 ])
 607
 608 dnl *** GDK pixbuf ***
 609 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 610 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 611   AG_GST_PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0 >= 2.8.0)
 612 ])
 613
 614 dnl *** Jack ***
 615 translit(dnm, m, l) AM_CONDITIONAL(USE_JACK, true)
 616 AG_GST_CHECK_FEATURE(JACK, Jack, jack, [
 617   PKG_CHECK_MODULES(JACK, jack >= 0.99.10, HAVE_JACK="yes", HAVE_JACK="no")
 618   AC_SUBST(JACK_CFLAGS)
 619   AC_SUBST(JACK_LIBS)
 620
 621   AG_GST_PKG_CHECK_MODULES(JACK_0_120_1, jack >= 0.120.1 jack < 1.0)
 622   if test x$HAVE_JACK_0_120_1 = xyes; then
 623     AC_DEFINE(HAVE_JACK_0_120_1, 1, [defined if jack >= 0.120.1 is available])
 624   fi
 625   AG_GST_PKG_CHECK_MODULES(JACK_1_9_7, jack >= 1.9.7)
 626   if test x$HAVE_JACK_1_9_7 = xyes; then
 627     AC_DEFINE(HAVE_JACK_1_9_7, 1, [defined if jack >= 1.9.7 is available])
 628   fi
 629
 630 ])
 631
 632 dnl *** jpeg ***
 633 dnl FIXME: we could use header checks here as well IMO
 634 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 635 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 636   AC_ARG_WITH(jpeg-mmx,
 637     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 638   OLD_LIBS="$LIBS"
 639   if test x$with_jpeg_mmx != x; then
 640     LIBS="$LIBS -L$with_jpeg_mmx"
 641   fi
 642   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 643   JPEG_LIBS="$LIBS -ljpeg-mmx"
 644   LIBS="$OLD_LIBS"
 645   if test x$HAVE_JPEG != xyes; then
 646     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 647     JPEG_LIBS="-ljpeg"
 648   fi
 649   AC_SUBST(JPEG_LIBS)
 650 ])
 651
 652 dnl *** libcaca ***
 653 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 654 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 655   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 656 ])
 657
 658 dnl *** libdv ***
 659 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 660 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 661   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 662 ])
 663
 664 dnl *** libpng ***
 665 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 666 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 667   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng >= 1.2)
 668 ])
 669
 670 dnl *** pulseaudio ***
 671 translit(dnm, m, l) AM_CONDITIONAL(USE_PULSE, true)
 672 AG_GST_CHECK_FEATURE(PULSE, [pulseaudio plug-in], pulseaudio, [
 673
 674   dnl used in ext/pulse/pulseutil.c
 675   AC_CHECK_HEADERS([process.h])
 676
 677   AG_GST_PKG_CHECK_MODULES(PULSE, libpulse >= 2.0)
 678 ])
 679
 680 dnl *** dv1394 ***
 681 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 682 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 683   dnl first test for libraw1394 >= 2.0.0
 684   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 2.0.0)
 685   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 686   dnl now see how far we got
 687   if test x$HAVE_RAW1394 = xyes && \
 688      test x$HAVE_LIBIEC61883 = xyes; then
 689        AG_GST_CHECK_LIBHEADER(AVC1394,
 690         avc1394, avc1394_send_command, $RAW1394_LIBS,
 691         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 692        AG_GST_CHECK_LIBHEADER(ROM1394,
 693         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 694         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 695        if test x$HAVE_AVC1394 = xyes && \
 696           test x$HAVE_AVC1394 = xyes && \
 697           test x$HAVE_ROM1394 = xyes; then
 698           HAVE_DV1394=yes
 699           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 700           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 701           AC_SUBST(DV1394_CFLAGS)
 702           AC_SUBST(DV1394_LIBS)
 703         fi
 704   else
 705        if test x$HAVE_RAW1394 = xno; then
 706           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 707           AG_GST_CHECK_LIBHEADER(AVC1394,
 708            avc1394, avc1394_send_command, $RAW1394_LIBS,
 709            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 710           AG_GST_CHECK_LIBHEADER(ROM1394,
 711            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 712            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 713           if test x$HAVE_RAW1394 = xyes && \
 714              test x$HAVE_AVC1394 = xyes && \
 715              test x$HAVE_ROM1394 = xyes; then
 716              HAVE_DV1394=yes
 717              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 718              DV1394_CFLAGS="$RAW1394_CFLAGS"
 719              if test x$HAVE_LIBIEC61883 = xyes; then
 720                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 721                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 722              fi
 723              AC_SUBST(DV1394_CFLAGS)
 724              AC_SUBST(DV1394_LIBS)
 725            fi
 726          fi
 727   fi
 728 ])
 729 AM_CONDITIONAL(USE_LIBIEC61883, [ test "x${HAVE_LIBIEC61883}" = xyes ] )
 730
 731 dnl *** shout2 ***
 732 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 733 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 734   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 735 ])
 736
 737 dnl *** soup ***
 738 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUP, true)
 739 AG_GST_CHECK_FEATURE(SOUP, [soup http client plugin (2.4)], souphttpsrc, [
 740   PKG_CHECK_MODULES(SOUP, libsoup-2.4 >= 2.40, [HAVE_SOUP="yes"], [HAVE_SOUP="no"])
 741   AC_SUBST(SOUP_CFLAGS)
 742   AC_SUBST(SOUP_LIBS)
 743 ])
 744
 745 dnl *** speex >= 1.0.4 or >= 1.1.5 ***
 746 dnl   1.1.4 and earlier were not API/ABI compatible with 1.0
 747 dnl   1.1.6 is the first to use a .pc/pkg-config file ***
 748 dnl   speex_jitter.h is 1.1.x only
 749 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 750 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 751   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 752   if test $HAVE_SPEEX = no
 753   then
 754     AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_bits_init, , speex/speex.h, [
 755       AC_CHECK_HEADER(speex/speex_jitter.h, [
 756         dnl speex 1.1.x :
 757         AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_encode_int, , speex/speex.h, [
 758           dnl speex 1.1.5 or + :
 759           HAVE_SPEEX="yes"
 760           SPEEX_LIBS="-lspeex"
 761           AC_SUBST(SPEEX_CFLAGS)
 762           AC_SUBST(SPEEX_LIBS)
 763         ],[
 764           HAVE_SPEEX="no"
 765         ])
 766       ],[
 767         dnl speex 1.0.x :
 768           AC_CHECK_DECL(SPEEX_GET_LOOKAHEAD, [
 769             dnl speex 1.0.4
 770             HAVE_SPEEX="yes"
 771             SPEEX_LIBS="-lspeex"
 772             AC_SUBST(SPEEX_CFLAGS)
 773             AC_SUBST(SPEEX_LIBS)
 774
 775             AC_DEFINE_UNQUOTED(SPEEX_1_0, 1,
 776               [defined if speex 1.0.x API detected])
 777         ],[
 778             HAVE_SPEEX="no"
 779             AC_MSG_NOTICE(You need at least 1.0.4 to compile the speex plugin)
 780         ], [
 781 #include <speex/speex.h>
 782         ])
 783       ])
 784     ])
 785   fi
 786 ])
 787
 788 dnl *** taglib ***
 789 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 790 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 791   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.5)
 792   if test "x$HAVE_CXX" != "xyes"; then
 793     USE_TAGLIB=false
 794     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 795   else
 796     dnl work around bug in taglib 1.5 headers, remove once there is a 1.6
 797     AS_CXX_COMPILER_FLAG([-Wno-attributes], [
 798         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS -Wno-attributes"
 799       ], [
 800         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS"
 801     ])
 802     AC_SUBST(TAGLIB_CXXFLAGS)
 803   fi
 804 ])
 805
 806 dnl *** vpx ***
 807 translit(dnm, m, l) AM_CONDITIONAL(USE_VPX, vpx)
 808 AG_GST_CHECK_FEATURE(VPX, [VPX decoder], vpx, [
 809   PKG_CHECK_MODULES(VPX, vpx >= 1.1.0, [HAVE_VPX="yes"], [HAVE_VPX="no"])
 810   HAVE_VP8=no
 811   HAVE_VP9=no
 812
 813   if test $HAVE_VPX = "yes"; then
 814     OLD_LIBS="$LIBS"
 815     OLD_CFLAGS="$CFLAGS"
 816     CFLAGS="$CFLAGS $VPX_CFLAGS"
 817     LIBS="$LIBS $VPX_LIBS"
 818     AC_CHECK_LIB(vpx, vpx_codec_vp8_cx_algo, [
 819       HAVE_VP8=yes
 820       AC_DEFINE(HAVE_VP8_ENCODER, 1, [Defined if the VP8 encoder is available])
 821     ])
 822     AC_CHECK_LIB(vpx, vpx_codec_vp8_dx_algo, [
 823       HAVE_VP8=yes
 824       AC_DEFINE(HAVE_VP8_DECODER, 1, [Defined if the VP8 decoder is available])
 825     ])
 826
 827     PKG_CHECK_MODULES(VPX_130, vpx >= 1.3.0, [
 828       AC_CHECK_LIB(vpx, vpx_codec_vp9_cx_algo, [
 829         HAVE_VP9=yes
 830         AC_DEFINE(HAVE_VP9_ENCODER, 1, [Defined if the VP9 encoder is available])
 831       ])
 832       AC_CHECK_LIB(vpx, vpx_codec_vp9_dx_algo, [
 833         HAVE_VP9=yes
 834         AC_DEFINE(HAVE_VP9_DECODER, 1, [Defined if the VP9 decoder is available])
 835       ])
 836     ], [true])
 837     LIBS="$OLD_LIBS"
 838     CFLAGS="$OLD_CFLAGS"
 839   fi
 840   AC_SUBST(VPX_LIBS)
 841   AC_SUBST(VPX_CFLAGS)
 842 ])
 843
 844 dnl *** wavpack ***
 845 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 846 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 847   PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.40.0, HAVE_WAVPACK=yes, [
 848     PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.20, [
 849       HAVE_WAVPACK=yes
 850       AC_DEFINE(WAVPACK_OLD_API, 1, [old wavpack API])
 851     ],[
 852       HAVE_WAVPACK=no
 853     ])
 854   ])
 855   AC_SUBST(WAVPACK_CFLAGS)
 856   AC_SUBST(WAVPACK_LIBS)
 857 ])
 858
 859 dnl *** qtdemux & matroska prefer to have zlib ***
 860 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 861 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for qtdemux/matroska],, [
 862   AG_GST_CHECK_LIBHEADER(ZLIB,
 863     z, uncompress,, zlib.h, [
 864     HAVE_ZLIB="yes"
 865     ZLIB_LIBS="-lz"
 866     AC_SUBST(ZLIB_LIBS)
 867   ])
 868 ])
 869
 870 dnl *** matroska prefers to have bz2 ***
 871 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
 872 AG_GST_CHECK_FEATURE(BZ2, [bz2 library for matroska ],, [
 873   save_LIBS=$LIBS
 874   LIBS="$LIBS -lbz2"
 875   AC_MSG_CHECKING([for BZ2_bzlibVersion in -lbz2])
 876   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <bzlib.h>]], [[const char *version = BZ2_bzlibVersion ();]])],[HAVE_BZ2=yes],[HAVE_BZ2=no])
 877   AC_MSG_RESULT($HAVE_BZ2)
 878   LIBS=$save_LIBS
 879   if test "x$HAVE_BZ2" = "xyes"; then
 880     BZ2_LIBS="-lbz2"
 881   fi
 882   AC_SUBST(BZ2_LIBS)
 883 ])
 884
 885 else
 886
 887 dnl not building plugins with external dependencies,
 888 dnl but we still need to set the conditionals
 889 AM_CONDITIONAL(USE_AALIB, false)
 890 AM_CONDITIONAL(USE_BZ2, false)
 891 AM_CONDITIONAL(USE_CAIRO, false)
 892 AM_CONDITIONAL(USE_DIRECTSOUND, false)
 893 AM_CONDITIONAL(USE_DV1394, false)
 894 AM_CONDITIONAL(USE_FLAC, false)
 895 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
 896 AM_CONDITIONAL(USE_JACK, false)
 897 AM_CONDITIONAL(USE_JPEG, false)
 898 AM_CONDITIONAL(USE_LIBCACA, false)
 899 AM_CONDITIONAL(USE_LIBDV, false)
 900 AM_CONDITIONAL(USE_LIBIEC61883, false)
 901 AM_CONDITIONAL(USE_LIBPNG, false)
 902 AM_CONDITIONAL(USE_OSS, false)
 903 AM_CONDITIONAL(USE_OSS4, false)
 904 AM_CONDITIONAL(USE_OSX_AUDIO, false)
 905 AM_CONDITIONAL(USE_OSX_VIDEO, false)
 906 AM_CONDITIONAL(USE_PULSE, false)
 907 AM_CONDITIONAL(USE_SHOUT2, false)
 908 AM_CONDITIONAL(USE_SOUP, false)
 909 AM_CONDITIONAL(USE_SPEEX, false)
 910 AM_CONDITIONAL(USE_SUNAUDIO, false)
 911 AM_CONDITIONAL(USE_TAGLIB, false)
 912 AM_CONDITIONAL(USE_VPX, false)
 913 AM_CONDITIONAL(USE_WAVEFORM, false)
 914 AM_CONDITIONAL(USE_WAVPACK, false)
 915 AM_CONDITIONAL(USE_X, false)
 916 AM_CONDITIONAL(USE_ZLIB, false)
 917
 918 fi dnl of EXT plugins
 919
 920 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 921
 922 dnl Overview:
 923 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 924 dnl GST_*:              flags shared by all built objects
 925 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 926 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
 927 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 928 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 929
 930 dnl GST_OPTION_CFLAGS
 931 if test "x$USE_DEBUG" = xyes; then
 932    PROFILE_CFLAGS="-g"
 933 fi
 934 AC_SUBST(PROFILE_CFLAGS)
 935
 936 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 937   dnl Define _only_ for git (not pre-releases or releases)
 938   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 939 else
 940   DEPRECATED_CFLAGS=""
 941 fi
 942 AC_SUBST(DEPRECATED_CFLAGS)
 943
 944 dnl every flag in GST_OPTION_CFLAGS, GST_OPTION_CXXFLAGS and GST_OPTION_OBJCFLAGS can be overridden
 945 dnl at make time with e.g. make ERROR_CFLAGS=""
 946 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 947 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 948 GST_OPTION_OBJCFLAGS="\$(WARNING_OBJCFLAGS) \$(ERROR_OBJCFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 949 AC_SUBST(GST_OPTION_CFLAGS)
 950 AC_SUBST(GST_OPTION_CXXFLAGS)
 951 AC_SUBST(GST_OPTION_OBJCFLAGS)
 952
 953 dnl our libraries need to be versioned correctly
 954 AC_SUBST(GST_LT_LDFLAGS)
 955
 956 dnl FIXME: do we want to rename to GST_ALL_* ?
 957 dnl prefer internal headers to already installed ones
 958 dnl also add builddir include for enumtypes and marshal
 959 dnl add ERROR_CFLAGS, but overridable
 960 GST_CFLAGS="$GST_CFLAGS -DGST_USE_UNSTABLE_API"
 961 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS)"
 962 GST_OBJCFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_OBJCFLAGS)"
 963 GST_CFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
 964 AC_SUBST(GST_CFLAGS)
 965 AC_SUBST(GST_CXXFLAGS)
 966 AC_SUBST(GST_OBJCFLAGS)
 967 AC_SUBST(GST_LIBS)
 968
 969 dnl LDFLAGS really should only contain flags, not libs - they get added before
 970 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 971 GST_ALL_LDFLAGS="-no-undefined"
 972 AC_SUBST(GST_ALL_LDFLAGS)
 973
 974 dnl this really should only contain flags, not libs - they get added before
 975 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 976 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_.*' $GST_ALL_LDFLAGS"
 977 AC_SUBST(GST_PLUGIN_LDFLAGS)
 978
 979 dnl *** output files ***
 980
 981 $MKDIR_P tests/check/orc
 982
 983 dnl keep this alphabetic per directory, please
 984 AC_CONFIG_FILES(
 985 Makefile
 986 gst/Makefile
 987 gst/alpha/Makefile
 988 gst/apetag/Makefile
 989 gst/audiofx/Makefile
 990 gst/audioparsers/Makefile
 991 gst/auparse/Makefile
 992 gst/autodetect/Makefile
 993 gst/avi/Makefile
 994 gst/cutter/Makefile
 995 gst/deinterlace/Makefile
 996 gst/dtmf/Makefile
 997 gst/debugutils/Makefile
 998 gst/effectv/Makefile
 999 gst/equalizer/Makefile
1000 gst/flv/Makefile
1001 gst/goom/Makefile
1002 gst/goom2k1/Makefile
1003 gst/id3demux/Makefile
1004 gst/icydemux/Makefile
1005 gst/imagefreeze/Makefile
1006 gst/interleave/Makefile
1007 gst/isomp4/Makefile
1008 gst/law/Makefile
1009 gst/level/Makefile
1010 gst/matroska/Makefile
1011 gst/monoscope/Makefile
1012 gst/multifile/Makefile
1013 gst/multipart/Makefile
1014 gst/replaygain/Makefile
1015 gst/rtp/Makefile
1016 gst/rtpmanager/Makefile
1017 gst/rtsp/Makefile
1018 gst/shapewipe/Makefile
1019 gst/smpte/Makefile
1020 gst/spectrum/Makefile
1021 gst/udp/Makefile
1022 gst/videobox/Makefile
1023 gst/videocrop/Makefile
1024 gst/videofilter/Makefile
1025 gst/videomixer/Makefile
1026 gst/wavenc/Makefile
1027 gst/wavparse/Makefile
1028 gst/flx/Makefile
1029 gst/y4m/Makefile
1030 ext/Makefile
1031 ext/aalib/Makefile
1032 ext/cairo/Makefile
1033 ext/dv/Makefile
1034 ext/flac/Makefile
1035 ext/gdk_pixbuf/Makefile
1036 ext/jack/Makefile
1037 ext/jpeg/Makefile
1038 ext/libcaca/Makefile
1039 ext/libpng/Makefile
1040 ext/pulse/Makefile
1041 ext/raw1394/Makefile
1042 ext/shout2/Makefile
1043 ext/soup/Makefile
1044 ext/speex/Makefile
1045 ext/taglib/Makefile
1046 ext/vpx/Makefile
1047 ext/wavpack/Makefile
1048 sys/Makefile
1049 sys/directsound/Makefile
1050 sys/oss/Makefile
1051 sys/oss4/Makefile
1052 sys/osxaudio/Makefile
1053 sys/osxvideo/Makefile
1054 sys/sunaudio/Makefile
1055 sys/v4l2/Makefile
1056 sys/waveform/Makefile
1057 sys/ximage/Makefile
1058 po/Makefile.in
1059 tests/Makefile
1060 tests/check/Makefile
1061 tests/examples/Makefile
1062 tests/examples/audiofx/Makefile
1063 tests/examples/cairo/Makefile
1064 tests/examples/equalizer/Makefile
1065 tests/examples/jack/Makefile
1066 tests/examples/level/Makefile
1067 tests/examples/pulse/Makefile
1068 tests/examples/rtp/Makefile
1069 tests/examples/shapewipe/Makefile
1070 tests/examples/spectrum/Makefile
1071 tests/examples/v4l2/Makefile
1072 tests/files/Makefile
1073 tests/icles/Makefile
1074 common/Makefile
1075 common/m4/Makefile
1076 m4/Makefile
1077 docs/Makefile
1078 docs/plugins/Makefile
1079 docs/version.entities
1080 pkgconfig/Makefile
1081 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1082 gst-plugins-good.spec
1083 )
1084
1085 dnl Create the config.h file for Visual Studio builds
1086 dnl Beware of spaces and /'s in some of the shell variable contents.
1087 sed \
1088     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"\n\n#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
1089     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
1090     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
1091     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
1092     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
1093     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
1094     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
1095     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
1096     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
1097     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
1098     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
1099     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
1100     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
1101     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
1102     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
1103     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
1104     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
1105     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
1106     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
1107     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1108     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1109     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1110     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
1111     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1112     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
1113     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1114     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1115     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1116     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
1117     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
1118     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1119     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
1120     -e "s/.* DEFAULT_AUDIOSRC$/#define DEFAULT_AUDIOSRC \"audiotestsrc\"/" \
1121     -e "s/.* DEFAULT_VIDEOSRC$/#define DEFAULT_VIDEOSRC \"videotestsrc\"/" \
1122     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1123     config.h.in >win32/common/config.h-new
1124
1125 AC_OUTPUT
1126
1127 AG_GST_OUTPUT_PLUGINS
1128 ORC_OUTPUT
1129