configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, cvs and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for cvs/prerelease
   8 AC_INIT(GStreamer Base Plug-ins, 0.10.17.3,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-base)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_CVS="no", GST_CVS="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl our libraries and install dirs use major.minor as a version
  36 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  37 dnl we override it here if we need to for the release candidate of new series
  38 GST_MAJORMINOR=0.10
  39 AC_SUBST(GST_MAJORMINOR)
  40
  41 dnl CURRENT, REVISION, AGE
  42 dnl - library source changed -> increment REVISION
  43 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  44 dnl - interfaces added -> increment AGE
  45 dnl - interfaces removed -> AGE = 0
  46 dnl sets GST_LT_LDFLAGS
  47 AS_LIBTOOL(GST, 12, 0, 12)
  48
  49 dnl FIXME: this macro doesn't actually work;
  50 dnl the generated libtool script has no support for the listed tags.
  51 dnl So this needs to be fixed first if we want to use this
  52 dnl AS_LIBTOOL_TAGS
  53
  54 AM_PROG_LIBTOOL
  55
  56 dnl *** required versions of GStreamer stuff ***
  57 GST_REQ=0.10.17.1
  58
  59 dnl *** autotools stuff ****
  60
  61 dnl allow for different autotools
  62 AS_AUTOTOOLS_ALTERNATE
  63
  64 dnl Add parameters for aclocal
  65 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  66
  67 dnl set up gettext
  68 dnl the version check needs to stay here because autopoint greps for it
  69 AM_GNU_GETTEXT_VERSION([0.11.5])
  70 AM_GNU_GETTEXT([external])
  71 AG_GST_GETTEXT([gst-plugins-base-$GST_MAJORMINOR])
  72
  73 dnl *** check for arguments to configure ***
  74
  75 AG_GST_ARG_DEBUG
  76 AG_GST_ARG_PROFILING
  77 AG_GST_ARG_VALGRIND
  78 AG_GST_ARG_GCOV
  79
  80 AG_GST_ARG_EXAMPLES
  81
  82 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  83 AG_GST_ARG_WITH_PACKAGE_NAME
  84 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  85
  86 dnl let distro override plugin install helper path
  87 AC_ARG_WITH(install-plugins-helper,
  88   AC_HELP_STRING([--with-install-plugins-helper],
  89     [specify path of helper script to call to install plugins]),
  90   [
  91     case "${withval}" in
  92       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
  93       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
  94       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
  95     esac
  96   ],
  97   [
  98     dnl Default value
  99     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 100   ]
 101 )
 102 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 103 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 104     [plugin install helper script])
 105 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 106
 107 AG_GST_ARG_WITH_PLUGINS
 108
 109 AG_GST_ARG_ENABLE_EXTERNAL
 110
 111 AG_GST_ARG_ENABLE_EXPERIMENTAL
 112
 113 dnl *** checks for platform ***
 114
 115 dnl * hardware/architecture *
 116
 117 dnl common/m4/gst-arch.m4
 118 dnl check CPU type
 119 AG_GST_ARCH
 120
 121 dnl check for large file support
 122 dnl affected plugins must include config.h
 123 AC_SYS_LARGEFILE
 124
 125 dnl *** checks for programs ***
 126
 127 dnl find a compiler
 128 AC_PROG_CC
 129
 130 dnl check if the compiler supports '-c' and '-o' options
 131 AM_PROG_CC_C_O
 132
 133 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 134 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 135
 136 dnl check for documentation tools
 137 GTK_DOC_CHECK([1.3])
 138 AS_PATH_PYTHON([2.1])
 139 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 140
 141 dnl *** checks for libraries ***
 142
 143 dnl For interactive UNIX (a Sun thing)
 144 dnl FIXME: this adds -lcposix to LIBS, but I doubt we use LIBS
 145 AC_ISC_POSIX
 146
 147 dnl libm, for sin() etc.
 148 AC_CHECK_LIBM
 149 AC_SUBST(LIBM)
 150
 151 dnl *** checks for header files ***
 152
 153 dnl check if we have ANSI C header files
 154 AC_HEADER_STDC
 155
 156 dnl used in gst/ffmpegcolorspace/mem.c
 157 dnl FIXME: could be fixed by redefining av_malloc and av_free to GLib's
 158 AC_CHECK_HEADERS([malloc.h])
 159
 160 dnl used in gst/subparse/gstsubparse.c
 161 AC_CHECK_HEADERS([regex.h], HAVE_REGEX_H="yes", HAVE_REGEX_H="no")
 162 AM_CONDITIONAL(HAVE_REGEX_H, test "x$HAVE_REGEX_H" = "xyes")
 163
 164 if test "x$HAVE_REGEX_H" = "xyes"; then
 165   ac_cppflags_save="$CPPFLAGS"
 166   CPPFLAGS="`$PKG_CONFIG --cflags libxml-2.0`"
 167   AC_COMPILE_IFELSE(
 168     AC_LANG_PROGRAM([
 169 #include <libxml/HTMLparser.h>
 170                      ],[
 171 #ifndef LIBXML_HTML_ENABLED
 172 #error libxml2 has no HTML support
 173 #endif /* LIBXML_HTML_ENABLED */
 174                      ]), HAVE_LIBXML_HTML="yes", HAVE_LIBXML_HTML="no")
 175   CPPFLAGS="$ac_cppflags_save"
 176 else
 177   HAVE_LIBXML_HTML="no"
 178 fi
 179 AM_CONDITIONAL(HAVE_LIBXML_HTML, test "x$HAVE_LIBXML_HTML" = "xyes")
 180
 181 dnl used in gst/tcp
 182 AC_CHECK_HEADERS([sys/socket.h],
 183   HAVE_SYS_SOCKET_H="yes", HAVE_SYS_SOCKET_H="no")
 184 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 185
 186 dnl used in gst-libs/gst/rtsp
 187 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 188 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 189   WIN32_LIBS="-lws2_32"
 190   AC_SUBST(WIN32_LIBS)
 191 fi
 192
 193 dnl check for hstrerror, for gst-libs/gst/rtsp
 194 save_libs="$LIBS"
 195 AC_CHECK_FUNC(hstrerror, ,
 196     AC_CHECK_LIB(resolv, hstrerror, ,
 197         [AC_DEFINE(NO_HSTRERROR, 1,
 198              [Define if you have no native hstrerror() function.])]))
 199 HSTRERROR_LIBS=$LIBS
 200 AC_SUBST(HSTRERROR_LIBS)
 201 LIBS="$save_libs"
 202
 203 dnl used in gst-libs/gst/pbutils and associated unit test
 204 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h])
 205
 206 dnl ffmpegcolorspace includes _stdint.h
 207 dnl also, Windows does not have long long
 208 AX_CREATE_STDINT_H
 209
 210 dnl *** checks for functions ***
 211 AC_CHECK_FUNCS([localtime_r gmtime_r])
 212
 213 dnl *** checks for types/defines ***
 214
 215 dnl Check for FIONREAD ioctl declaration
 216 dnl used in gst/tcp
 217 GST_CHECK_FIONREAD
 218
 219 dnl *** checks for structures ***
 220
 221 dnl *** checks for compiler characteristics ***
 222
 223 dnl make sure we can use "inline" from C code
 224 AC_C_INLINE
 225
 226 dnl *** checks for library functions ***
 227
 228 dnl check for fseeko()
 229 AC_FUNC_FSEEKO
 230
 231 dnl Check for fast float to int casting as defined in C99
 232 dnl used in gst-libs/gst/floatcast/floatcast.h
 233 AC_C99_FUNC_LRINT
 234 AC_C99_FUNC_LRINTF
 235
 236 dnl Check for a way to display the function name in debug output
 237 AG_GST_CHECK_FUNCTION
 238
 239 dnl *** checks for dependency libraries ***
 240
 241 dnl GLib is required
 242 AG_GST_GLIB_CHECK([2.6])
 243
 244 dnl liboil is required
 245 PKG_CHECK_MODULES(LIBOIL, liboil-0.3 >= 0.3.8, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 246 if test "x$HAVE_LIBOIL" != "xyes"; then
 247   AC_ERROR([liboil-0.3.8 or later is required])
 248 fi
 249
 250 dnl checks for gstreamer
 251 dnl uninstalled is selected preferentially -- see pkg-config(1)
 252 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ])
 253 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ])
 254 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ])
 255 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ])
 256 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 257 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 258
 259 dnl Check for documentation xrefs
 260 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 261 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 262 AC_SUBST(GLIB_PREFIX)
 263 AC_SUBST(GST_PREFIX)
 264
 265 dnl GTK is optional and used in examples
 266 HAVE_GTK=NO
 267 PKG_CHECK_MODULES(GTK2, gtk+-2.0 >= 2.2.0, HAVE_GTK_22=yes, HAVE_GTK_22=no)
 268 if test "x$HAVE_GTK_22" = "xyes"; then
 269   HAVE_GTK=yes
 270   GTK_VERSION=`$PKG_CONFIG --variable=gtk_binary_version gtk+-2.0`
 271   AC_SUBST(GTK_VERSION)
 272   GTK_PREFIX=`$PKG_CONFIG --variable=prefix gdk-pixbuf-2.0`
 273   AC_SUBST(GTK_BASE_DIR)
 274 else
 275   PKG_CHECK_MODULES(GTK2, gtk+-2.0, HAVE_GTK_20=yes, HAVE_GTK_20=no)
 276 fi
 277 if test "x$HAVE_GTK_20" = "xyes"; then
 278   HAVE_GTK=yes
 279 fi
 280 GTK_CFLAGS=$GTK2_CFLAGS
 281 GTK_LIBS=$GTK2_LIBS
 282 AC_SUBST(GTK_LIBS)
 283 AC_SUBST(GTK_CFLAGS)
 284 AC_SUBST(HAVE_GTK)
 285 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 286
 287 dnl *** set variables based on configure arguments ***
 288
 289 dnl set license and copyright notice
 290 GST_LICENSE="LGPL"
 291 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 292 AC_SUBST(GST_LICENSE)
 293
 294 dnl set location of plugin directory
 295 AG_GST_SET_PLUGINDIR
 296
 297 dnl define an ERROR_CFLAGS Makefile variable
 298 AG_GST_SET_ERROR_CFLAGS($GST_CVS)
 299
 300 dnl define correct level for debugging messages
 301 AG_GST_SET_LEVEL_DEFAULT($GST_CVS)
 302
 303 dnl used in examples
 304 AG_GST_DEFAULT_ELEMENTS
 305
 306 dnl *** plug-ins to include ***
 307
 308 dnl these are all the gst plug-ins, compilable without additional libs
 309 AG_GST_CHECK_PLUGIN(adder)
 310 AG_GST_CHECK_PLUGIN(audioconvert)
 311 AG_GST_CHECK_PLUGIN(audiorate)
 312 AG_GST_CHECK_PLUGIN(audioresample)
 313 AG_GST_CHECK_PLUGIN(audiotestsrc)
 314 AG_GST_CHECK_PLUGIN(ffmpegcolorspace)
 315 AG_GST_CHECK_PLUGIN(gdp)
 316 AG_GST_CHECK_PLUGIN(playback)
 317 AG_GST_CHECK_PLUGIN(subparse)
 318 AG_GST_CHECK_PLUGIN(tcp)
 319 AG_GST_CHECK_PLUGIN(typefind)
 320 AG_GST_CHECK_PLUGIN(videotestsrc)
 321 AG_GST_CHECK_PLUGIN(videorate)
 322 AG_GST_CHECK_PLUGIN(videoscale)
 323 AG_GST_CHECK_PLUGIN(volume)
 324
 325 dnl disable plug-ins that require libxml2's HTML support if it is not available
 326 if test "x$HAVE_LIBXML_HTML" != "xyes"; then
 327   AG_GST_DISABLE_PLUGIN(subparse)
 328 fi
 329
 330 dnl disable plug-ins that require sys/socket.h if it is not available
 331 if test "x$HAVE_SYS_SOCKET_H" != "xyes"; then
 332   AG_GST_DISABLE_PLUGIN(tcp)
 333 fi
 334
 335 dnl *** sys plug-ins ***
 336
 337 echo
 338 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 339 echo
 340
 341 dnl *** X11 ***
 342 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 343 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 344                   [ximagesink], [
 345   AC_PATH_XTRA
 346   ac_cflags_save="$CFLAGS"
 347   ac_cppflags_save="$CPPFLAGS"
 348   CFLAGS="$CFLAGS $X_CFLAGS"
 349   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 350
 351   dnl now try to find the HEADER
 352   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 353
 354   if test "x$HAVE_X" = "xno"
 355   then
 356     AC_MSG_NOTICE([cannot find X11 development files])
 357   else
 358     dnl this is much more than we want
 359     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 360     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 361     dnl it does not add the libs; therefore we add them here
 362     X_LIBS="$X_LIBS -lX11"
 363     AC_SUBST(X_CFLAGS)
 364     AC_SUBST(X_LIBS)
 365   fi
 366   AC_SUBST(HAVE_X)
 367   CFLAGS="$ac_cflags_save"
 368   CPPFLAGS="$ac_cppflags_save"
 369 ])
 370
 371 dnl Check for Xv extension
 372 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 373 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 374                   [xvimagesink], [
 375   AG_GST_CHECK_XV
 376 ])
 377
 378 dnl check for X Shm
 379 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 380 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 381   if test x$HAVE_X = xyes; then
 382     AC_CHECK_LIB(Xext, XShmAttach,
 383                  HAVE_XSHM="yes", HAVE_XSHM="no",
 384                  $X_LIBS)
 385     if test "x$HAVE_XSHM" = "xyes"; then
 386       XSHM_LIBS="-lXext"
 387     else
 388       dnl On AIX, it is in XextSam instead, but we still need -lXext
 389       AC_CHECK_LIB(XextSam, XShmAttach,
 390                    HAVE_XSHM="yes", HAVE_XSHM="no",
 391                    $X_LIBS)
 392       if test "x$HAVE_XSHM" = "xyes"; then
 393         XSHM_LIBS="-lXext -lXextSam"
 394       fi
 395     fi
 396   fi
 397 ], , [
 398   AC_SUBST(HAVE_XSHM)
 399   AC_SUBST(XSHM_LIBS)
 400 ])
 401
 402 dnl v4l/v4l2 checks have been moved down because they require X
 403
 404 dnl *** Video 4 Linux ***
 405 dnl for information about the header/define, see sys/v4l/gstv4lelement.h
 406 dnl renamed to GST_V4L in accordance with V4L2 below
 407 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L, true)
 408 AG_GST_CHECK_FEATURE(GST_V4L, [Video 4 Linux], video4linux, [
 409   AC_CHECK_DECL(VID_TYPE_MPEG_ENCODER, HAVE_GST_V4L="yes", HAVE_GST_V4L="no", [
 410 #include <sys/types.h>
 411 #define _LINUX_TIME_H
 412 #define __user
 413 #include <linux/videodev.h>
 414   ])
 415
 416   dnl we can build v4l without Xv, but then we won't have XOverlay support
 417   if test "x$HAVE_GST_V4L" = "xyes" -a "x$HAVE_XVIDEO" != "xyes"
 418   then
 419     AC_MSG_NOTICE([NO XVIDEO FOUND, VIDEO4LINUX WILL BE BUILT])
 420     AC_MSG_NOTICE([WITHOUT XOVERLAY SUPPORT])
 421   fi
 422 ])
 423
 424 dnl *** ext plug-ins ***
 425 dnl keep this list sorted alphabetically !
 426
 427 if test "x$BUILD_EXTERNAL" = "xyes"; then
 428
 429 echo
 430 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 431 echo
 432
 433 dnl *** alsa ***
 434 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 435 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 436   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 437     HAVE_ALSA="yes"
 438     AC_SUBST(ALSA_CFLAGS)
 439     AC_SUBST(ALSA_LIBS)
 440   ], [
 441     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 442   ])
 443 ])
 444
 445 dnl *** CDParanoia ***
 446 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 447 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 448   AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 449                       cdda_open, -lm,
 450                       cdda_interface.h,
 451                       CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 452                       HEADER_DIR="no"
 453                       FOUND_CDPARANOIA="yes")
 454   if test "x$FOUND_CDPARANOIA" != "xyes";
 455   then
 456     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 457                         cdda_open, -lm,
 458                         cdda/cdda_interface.h,
 459                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 460                         HEADER_DIR="yes"
 461                         FOUND_CDPARANOIA="yes")
 462   fi
 463   if test "x$HEADER_DIR" = "xyes";
 464   then
 465     AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 466                        defined if cdda headers are in a cdda/ directory)
 467   fi
 468   AC_SUBST(CDPARANOIA_LIBS)
 469 ])
 470 dnl FIXME : add second check somehow if that is necessary
 471 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 472 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 473
 474 dnl *** GNOME VFS ***
 475 translit(dnm, m, l) AM_CONDITIONAL(USE_GNOME_VFS, true)
 476 AG_GST_CHECK_FEATURE(GNOME_VFS, [GNOME VFS], gnomevfs, [
 477   AG_GST_PKG_CHECK_MODULES(GNOME_VFS, gnome-vfs-2.0)
 478 ])
 479
 480 dnl *** libgio ***
 481 USE_GIO=$BUILD_EXPERIMENTAL
 482 translit(dnm, m, l) AM_CONDITIONAL(USE_GIO, true)
 483 AG_GST_CHECK_FEATURE(GIO, [GIO library], gio, [
 484   PKG_CHECK_MODULES(GIO, gio-2.0 >= 2.15.2, HAVE_GIO="yes", [
 485     HAVE_GIO="no"
 486     AC_MSG_RESULT(no)
 487   ])
 488   AC_SUBST(GIO_CFLAGS)
 489   AC_SUBST(GIO_LIBS)
 490   AC_SUBST(GIO_LDFLAGS)
 491 ])
 492
 493 dnl *** libvisual ***
 494 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 495 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 496   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 497   if test $HAVE_LIBVISUAL = no
 498   then
 499     AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0)
 500   fi
 501 ])
 502
 503 dnl *** ogg ***
 504 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 505 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 506   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 507   if test $HAVE_OGG = no
 508   then
 509     XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
 510     AS_SCRUB_INCLUDE(OGG_CFLAGS)
 511   fi
 512 ])
 513
 514 dnl *** pango ***
 515 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 516 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 517   AG_GST_PKG_CHECK_MODULES(PANGO, pango pangoft2)
 518 ])
 519
 520 dnl *** theora ***
 521 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 522 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 523   dnl this check will work as long as theora uses 1.0.x or similar for the
 524   dnl first post-alpha release and not just 1.0
 525   AG_GST_PKG_CHECK_MODULES(THEORA, theora >= 1.0alpha5)
 526 ])
 527
 528 dnl *** vorbis ***
 529 dnl AM_PATH_VORBIS only takes two options
 530 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 531 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 532   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 533   if test $HAVE_VORBIS = no
 534   then
 535     XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
 536     AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
 537   fi
 538 ])
 539
 540 if test "x$HAVE_VORBIS" = "xyes"; then
 541   ac_cflags_save="$CFLAGS"
 542   AC_COMPILE_IFELSE(
 543     AC_LANG_PROGRAM([
 544 #include <vorbis/codec.h>
 545                      ],[
 546 vorbis_dsp_state *v;
 547
 548 vorbis_synthesis_restart (v);
 549                      ]), HAVE_VSR=yes, HAVE_VSR=no)
 550   if test "x$HAVE_VSR" = "xyes"; then
 551     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 552                        [defined if vorbis_synthesis_restart is present])
 553   fi
 554   CFLAGS="$ac_cflags_save"
 555 fi
 556
 557 else
 558
 559 dnl not building plugins with external dependencies,
 560 dnl but we still need to set the conditionals
 561 AM_CONDITIONAL(USE_ALSA, false)
 562 AM_CONDITIONAL(USE_CDPARANOIA, false)
 563 AM_CONDITIONAL(USE_GNOME_VFS, false)
 564 AM_CONDITIONAL(USE_GIO, false)
 565 AM_CONDITIONAL(USE_LIBVISUAL, false)
 566 AM_CONDITIONAL(USE_OGG, false)
 567 AM_CONDITIONAL(USE_PANGO, false)
 568 AM_CONDITIONAL(USE_THEORA, false)
 569 AM_CONDITIONAL(USE_VORBIS, false)
 570
 571 fi dnl of EXT plugins
 572
 573 dnl seeking needs freetype, so check for it here
 574 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 575   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 576 ])
 577 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 578 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 579 AC_SUBST(FT2_CFLAGS)
 580 AC_SUBST(FT2_LIBS)
 581
 582 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 583
 584 dnl Overview:
 585 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 586 dnl GST_*:              flags shared by built objects to link against GStreamer
 587 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 588 dnl                          (compare to other modules) or for i18n
 589 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 590 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 591 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 592 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 593
 594 dnl GST_OPTION_CFLAGS
 595 if test "x$USE_DEBUG" = xyes; then
 596    PROFILE_CFLAGS="-g"
 597 fi
 598 AC_SUBST(PROFILE_CFLAGS)
 599
 600 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 601   dnl Define _only_ during CVS (not pre-releases or releases)
 602   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 603 else
 604   DEPRECATED_CFLAGS=""
 605 fi
 606 AC_SUBST(DEPRECATED_CFLAGS)
 607
 608 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 609 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 610 AC_SUBST(GST_OPTION_CFLAGS)
 611
 612 dnl our libraries need to be versioned correctly
 613 AC_SUBST(GST_LT_LDFLAGS)
 614
 615 dnl GST_PLUGINS_BASE_CFLAGS
 616 dnl prefer internal headers to already installed ones
 617 dnl also add builddir include for enumtypes and marshal
 618 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 619 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 620
 621 dnl FIXME: do we want to rename to GST_ALL_* ?
 622 dnl add GST_OPTION_CFLAGS, but overridable
 623 GST_CFLAGS="$GST_CFLAGS \$(GST_OPTION_CFLAGS)"
 624 AC_SUBST(GST_CFLAGS)
 625 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 626 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 627 AC_SUBST(GST_LIBS)
 628
 629 dnl LDFLAGS really should only contain flags, not libs - they get added before
 630 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 631 GST_ALL_LDFLAGS="-no-undefined"
 632 AC_SUBST(GST_ALL_LDFLAGS)
 633
 634 dnl GST_LIB_LDFLAGS
 635 dnl linker flags shared by all libraries
 636 dnl LDFLAGS modifier defining exported symbols from built libraries
 637 dnl (export _gst_foo but not __gst_foo)
 638 GST_LIB_LDFLAGS="-export-symbols-regex ^_?\(gst_\|Gst\|GST_\).*"
 639 AC_SUBST(GST_LIB_LDFLAGS)
 640
 641 dnl this really should only contain flags, not libs - they get added before
 642 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 643 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 644 AC_SUBST(GST_PLUGIN_LDFLAGS)
 645
 646 dnl *** output files ***
 647
 648 AC_CONFIG_FILES(
 649 Makefile
 650 gst-plugins-base.spec
 651 gst/Makefile
 652 gst/adder/Makefile
 653 gst/audioconvert/Makefile
 654 gst/audiorate/Makefile
 655 gst/audioresample/Makefile
 656 gst/audiotestsrc/Makefile
 657 gst/ffmpegcolorspace/Makefile
 658 gst/gdp/Makefile
 659 gst/playback/Makefile
 660 gst/subparse/Makefile
 661 gst/tcp/Makefile
 662 gst/typefind/Makefile
 663 gst/videotestsrc/Makefile
 664 gst/videorate/Makefile
 665 gst/videoscale/Makefile
 666 gst/volume/Makefile
 667 sys/Makefile
 668 sys/ximage/Makefile
 669 sys/xvimage/Makefile
 670 sys/v4l/Makefile
 671 ext/Makefile
 672 ext/alsa/Makefile
 673 ext/cdparanoia/Makefile
 674 ext/gnomevfs/Makefile
 675 ext/gio/Makefile
 676 ext/libvisual/Makefile
 677 ext/ogg/Makefile
 678 ext/pango/Makefile
 679 ext/theora/Makefile
 680 ext/vorbis/Makefile
 681 gst-libs/Makefile
 682 gst-libs/gst/Makefile
 683 gst-libs/gst/audio/Makefile
 684 gst-libs/gst/cdda/Makefile
 685 gst-libs/gst/fft/Makefile
 686 gst-libs/gst/floatcast/Makefile
 687 gst-libs/gst/interfaces/Makefile
 688 gst-libs/gst/netbuffer/Makefile
 689 gst-libs/gst/riff/Makefile
 690 gst-libs/gst/rtp/Makefile
 691 gst-libs/gst/rtsp/Makefile
 692 gst-libs/gst/sdp/Makefile
 693 gst-libs/gst/tag/Makefile
 694 gst-libs/gst/pbutils/Makefile
 695 gst-libs/gst/video/Makefile
 696 tools/Makefile
 697 win32/common/config.h
 698 pkgconfig/Makefile
 699 pkgconfig/gstreamer-audio.pc
 700 pkgconfig/gstreamer-audio-uninstalled.pc
 701 pkgconfig/gstreamer-cdda.pc
 702 pkgconfig/gstreamer-cdda-uninstalled.pc
 703 pkgconfig/gstreamer-fft.pc
 704 pkgconfig/gstreamer-fft-uninstalled.pc
 705 pkgconfig/gstreamer-floatcast.pc
 706 pkgconfig/gstreamer-floatcast-uninstalled.pc
 707 pkgconfig/gstreamer-interfaces.pc
 708 pkgconfig/gstreamer-interfaces-uninstalled.pc
 709 pkgconfig/gstreamer-netbuffer.pc
 710 pkgconfig/gstreamer-netbuffer-uninstalled.pc
 711 pkgconfig/gstreamer-pbutils.pc
 712 pkgconfig/gstreamer-pbutils-uninstalled.pc
 713 pkgconfig/gstreamer-riff.pc
 714 pkgconfig/gstreamer-riff-uninstalled.pc
 715 pkgconfig/gstreamer-rtp.pc
 716 pkgconfig/gstreamer-rtp-uninstalled.pc
 717 pkgconfig/gstreamer-rtsp.pc
 718 pkgconfig/gstreamer-rtsp-uninstalled.pc
 719 pkgconfig/gstreamer-sdp.pc
 720 pkgconfig/gstreamer-sdp-uninstalled.pc
 721 pkgconfig/gstreamer-tag.pc
 722 pkgconfig/gstreamer-tag-uninstalled.pc
 723 pkgconfig/gstreamer-video.pc
 724 pkgconfig/gstreamer-video-uninstalled.pc
 725 pkgconfig/gstreamer-plugins-base.pc
 726 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 727 tests/Makefile
 728 tests/check/Makefile
 729 tests/examples/Makefile
 730 tests/examples/dynamic/Makefile
 731 tests/examples/seek/Makefile
 732 tests/examples/volume/Makefile
 733 tests/examples/snapshot/Makefile
 734 tests/icles/Makefile
 735 docs/Makefile
 736 docs/design/Makefile
 737 docs/libs/Makefile
 738 docs/plugins/Makefile
 739 docs/version.entities
 740 po/Makefile.in
 741 common/Makefile
 742 common/m4/Makefile
 743 m4/Makefile
 744 )
 745 AC_OUTPUT
 746
 747 AG_GST_OUTPUT_PLUGINS