configure.ac

   1 AC_PREREQ(2.62)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/prerelease
   8 AC_INIT(GStreamer OpenMAX Plug-ins, 1.2.0,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-omx)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability 1.11 no-dist-gzip dist-xz tar-ustar])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([omx/gstomx.c])
  25
  26 dnl define the output header for config
  27 AC_CONFIG_HEADERS([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE([enable])
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use GST_API_VERSION in the filename
  41 dnl to allow side-by-side installation of different API versions
  42 GST_API_VERSION=1.0
  43 AC_SUBST(GST_API_VERSION)
  44 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  45   [GStreamer API Version])
  46
  47 AG_GST_LIBTOOL_PREPARE
  48 AS_LIBTOOL(GST, 0, 0, 0)
  49
  50 dnl *** required versions of GStreamer stuff ***
  51 GST_REQ=1.2.2
  52
  53 dnl *** autotools stuff ****
  54
  55 dnl allow for different autotools
  56 AS_AUTOTOOLS_ALTERNATE
  57
  58 dnl Add parameters for aclocal
  59 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  60
  61 dnl *** check for arguments to configure ***
  62
  63 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  64
  65 AG_GST_ARG_DEBUG
  66 AG_GST_ARG_PROFILING
  67 AG_GST_ARG_VALGRIND
  68 AG_GST_ARG_GCOV
  69
  70 AG_GST_ARG_EXAMPLES
  71
  72 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  73 AG_GST_ARG_WITH_PACKAGE_NAME
  74 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  75
  76 AG_GST_PKG_CONFIG_PATH
  77
  78 AG_GST_ARG_WITH_PLUGINS
  79
  80 AG_GST_ARG_ENABLE_EXPERIMENTAL
  81
  82 dnl *** checks for platform ***
  83
  84 dnl * hardware/architecture *
  85
  86 dnl common/m4/gst-arch.m4
  87 dnl check CPU type
  88 AG_GST_ARCH
  89
  90 dnl check for large file support
  91 dnl affected plugins must include config.h
  92 AC_SYS_LARGEFILE
  93
  94 dnl *** checks for programs ***
  95
  96 dnl find a compiler
  97 AC_PROG_CC
  98 AC_PROG_CC_STDC
  99
 100 dnl check if the compiler supports '-c' and '-o' options
 101 AM_PROG_CC_C_O
 102
 103 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 104 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 105
 106 dnl check for documentation tools
 107 GTK_DOC_CHECK([1.3])
 108 AS_PATH_PYTHON([2.1])
 109 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 110
 111 dnl *** checks for libraries ***
 112
 113 dnl libm, for sin() etc.
 114 LT_LIB_M
 115 AC_SUBST(LIBM)
 116
 117 dnl *** checks for header files ***
 118
 119 dnl check if we have ANSI C header files
 120 AC_HEADER_STDC
 121
 122 AX_CREATE_STDINT_H
 123
 124 dnl *** checks for functions ***
 125
 126 dnl *** checks for types/defines ***
 127
 128 dnl *** checks for structures ***
 129
 130 dnl *** checks for compiler characteristics ***
 131
 132 dnl *** checks for library functions ***
 133
 134 dnl Check for a way to display the function name in debug output
 135 AG_GST_CHECK_FUNCTION
 136
 137 dnl *** checks for dependency libraries ***
 138
 139 dnl GLib is required
 140 AG_GST_GLIB_CHECK([2.32])
 141
 142 dnl Needed by plugins that use g_module_*() API
 143 PKG_CHECK_MODULES(GMODULE_NO_EXPORT, gmodule-no-export-2.0)
 144
 145 dnl checks for gstreamer
 146 dnl uninstalled is selected preferentially -- see pkg-config(1)
 147 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 148 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 149 AG_GST_CHECK_GST_CONTROLLER($GST_API_VERSION, [$GST_REQ], yes)
 150 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 151 AG_GST_CHECK_GST_PLUGINS_BASE($GST_API_VERSION, [$GST_REQ], yes)
 152 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 153 PKG_CHECK_MODULES([GST_GL], [gstreamer-gl-1.0 >= 1.4.0], [
 154   AC_DEFINE(HAVE_GST_GL, 1, [Have gstreamer-gl])
 155   GST_GL=yes
 156 ], [GST_GL=no])
 157 AM_CONDITIONAL(HAVE_GST_GL, test "x$GST_GL" = "xyes")
 158
 159 dnl Check for documentation xrefs
 160 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 161 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 162 AC_SUBST(GLIB_PREFIX)
 163 AC_SUBST(GST_PREFIX)
 164
 165 AC_ARG_WITH([omx-header-path],
 166             AS_HELP_STRING([--with-omx-header-path],[path of external OpenMAX IL header files]),
 167         [omx_header_path="$withval"], [omx_header_path="none"])
 168
 169 if test x"$omx_header_path" != x"none"; then
 170     CPPFLAGS="$CPPFLAGS -I$omx_header_path"
 171 fi
 172 dnl Check for external OpenMAX IL headers
 173 AC_CHECK_HEADER([OMX_Core.h], [HAVE_EXTERNAL_OMX=yes], [HAVE_EXTERNAL_OMX=no], [AC_INCLUDES_DEFAULT])
 174 AM_CONDITIONAL(HAVE_EXTERNAL_OMX, test "x$HAVE_EXTERNAL_OMX" = "xyes")
 175
 176 dnl Our internal OpenMAX IL headers have OMX_VideoExt.h
 177 HAVE_VIDEO_EXT=yes
 178 if test "x$HAVE_EXTERNAL_OMX" = "xyes"; then
 179     AC_CHECK_HEADER([OMX_VideoExt.h], [HAVE_VIDEO_EXT=yes], [HAVE_VIDEO_EXT=no], [AC_INCLUDES_DEFAULT])
 180 fi
 181
 182 VIDEO_HEADERS="#include <OMX_Video.h>"
 183 if test "x$HAVE_VIDEO_EXT" = "xyes"; then
 184     AC_DEFINE(HAVE_VIDEO_EXT, 1, [OpenMAX IL has OMX_VideoExt.h header])
 185     VIDEO_HEADERS="$VIDEO_HEADERS
 186 #include <OMX_VideoExt.h>
 187 "
 188 fi
 189
 190 AC_CHECK_DECLS([OMX_VIDEO_CodingVP8],
 191   [
 192     AC_DEFINE(HAVE_VP8, 1, [OpenMAX IL has VP8 support])
 193     HAVE_VP8=yes
 194   ], [
 195     HAVE_VP8=no
 196   ], [[$VIDEO_HEADERS]])
 197 AM_CONDITIONAL(HAVE_VP8, test "x$HAVE_VP8" = "xyes")
 198
 199 AC_CHECK_DECLS([OMX_VIDEO_CodingTheora],
 200   [
 201     AC_DEFINE(HAVE_THEORA, 1, [OpenMAX IL has Theora support])
 202     HAVE_THEORA=yes
 203   ], [
 204     HAVE_THEORA=no
 205   ], [[$VIDEO_HEADERS]])
 206 AM_CONDITIONAL(HAVE_THEORA, test "x$HAVE_THEORA" = "xyes")
 207
 208 dnl Check for -Bsymbolic-functions linker flag used to avoid
 209 dnl intra-library PLT jumps, if available.
 210 AC_ARG_ENABLE(Bsymbolic,
 211               [AC_HELP_STRING([--disable-Bsymbolic],
 212                               [avoid linking with -Bsymbolic])],,
 213               [SAVED_LDFLAGS="${LDFLAGS}"
 214                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 215                LDFLAGS=-Wl,-Bsymbolic-functions
 216                AC_TRY_LINK([], [int main (void) { return 0; }],
 217                            AC_MSG_RESULT(yes)
 218                            enable_Bsymbolic=yes,
 219                            AC_MSG_RESULT(no)
 220                            enable_Bsymbolic=no)
 221                LDFLAGS="${SAVED_LDFLAGS}"])
 222
 223 AC_ARG_WITH([omx-target],
 224         AS_HELP_STRING([--with-omx-target],[Use this OpenMAX IL target (generic, bellagio, rpi, exynos, exynos64)]),
 225         [ac_cv_omx_target="$withval"], [ac_cv_omx_target="generic"])
 226
 227 ac_cv_omx_target_struct_packing="none"
 228 AC_MSG_NOTICE([Using $ac_cv_omx_target as OpenMAX IL target])
 229 case "${ac_cv_omx_target}" in
 230   generic)
 231     AC_DEFINE(USE_OMX_TARGET_GENERIC, 1, [Use generic OpenMAX IL target])
 232     ;;
 233   rpi)
 234     AC_DEFINE(USE_OMX_TARGET_RPI, 1, [Use RPi OpenMAX IL target])
 235     ac_cv_omx_target_struct_packing=4
 236     ;;
 237   bellagio)
 238     AC_DEFINE(USE_OMX_TARGET_BELLAGIO, 1, [Use Bellagio OpenMAX IL target])
 239     ;;
 240  exynos)
 241     AC_DEFINE(USE_OMX_TARGET_EXYNOS, 1, [Use Exynos OpenMAX IL target])
 242     ;;
 243  exynos64)
 244     AC_DEFINE(USE_OMX_TARGET_EXYNOS64, 1, [Use Exynos64 OpenMAX IL target])
 245     ;;
 246   *)
 247     AC_ERROR([invalid OpenMAX IL target])
 248     ;;
 249 esac
 250 AM_CONDITIONAL(USE_OMX_TARGET_GENERIC, test "x$ac_cv_omx_target" = "xgeneric")
 251 AM_CONDITIONAL(USE_OMX_TARGET_BELLAGIO, test "x$ac_cv_omx_target" = "xbellagio")
 252 AM_CONDITIONAL(USE_OMX_TARGET_RPI, test "x$ac_cv_omx_target" = "xrpi")
 253 AM_CONDITIONAL(USE_OMX_TARGET_EXYNOS, test "x$ac_cv_omx_target" = "xexynos")
 254 AM_CONDITIONAL(USE_OMX_TARGET_EXYNOS64, test "x$ac_cv_omx_target" = "xexynos64")
 255
 256 AC_ARG_WITH([omx-struct-packing],
 257         AS_HELP_STRING([--with-omx-struct-packing],[Force OpenMAX struct packing, (default is none)]),
 258         [ac_cv_omx_struct_packing="$withval"], [ac_cv_omx_struct_packing="none"])
 259
 260 if test x"$ac_cv_omx_struct_packing" != x"none"; then
 261   AC_MSG_NOTICE([Using $ac_cv_omx_struct_packing as OpenMAX struct packing])
 262   AC_DEFINE_UNQUOTED(GST_OMX_STRUCT_PACKING, $ac_cv_omx_struct_packing, [The struct packing used for OpenMAX structures])
 263 elif test x"$ac_cv_omx_target_struct_packing" != x"none"; then
 264   AC_MSG_NOTICE([Using $ac_cv_omx_target_struct_packing as OpenMAX struct packing])
 265   AC_DEFINE_UNQUOTED(GST_OMX_STRUCT_PACKING, $ac_cv_omx_target_struct_packing, [The struct packing used for OpenMAX structures])
 266 fi
 267
 268 dnl *** set variables based on configure arguments ***
 269
 270 dnl set license and copyright notice
 271 GST_LICENSE="LGPL"
 272 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 273 AC_SUBST(GST_LICENSE)
 274
 275 dnl set location of plugin directory
 276 AG_GST_SET_PLUGINDIR
 277
 278 dnl set release date/time
 279 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 280   ["${srcdir}/gst-omx.doap"],
 281   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 282
 283 dnl build static plugins or not
 284 AC_MSG_CHECKING([whether to build static plugins or not])
 285 AC_ARG_ENABLE(
 286   static-plugins,
 287   AC_HELP_STRING(
 288     [--enable-static-plugins],
 289     [build static plugins @<:@default=no@:>@]),
 290   [AS_CASE(
 291     [$enableval], [no], [], [yes], [],
 292     [AC_MSG_ERROR([bad value "$enableval" for --enable-static-plugins])])],
 293   [enable_static_plugins=no])
 294 AC_MSG_RESULT([$enable_static_plugins])
 295 if test "x$enable_static_plugins" = xyes; then
 296   AC_DEFINE(GST_PLUGIN_BUILD_STATIC, 1,
 297     [Define if static plugins should be built])
 298   GST_PLUGIN_LIBTOOLFLAGS=""
 299 else
 300   GST_PLUGIN_LIBTOOLFLAGS="--tag=disable-static"
 301 fi
 302 AC_SUBST(GST_PLUGIN_LIBTOOLFLAGS)
 303 AM_CONDITIONAL(GST_PLUGIN_BUILD_STATIC, test "x$enable_static_plugins" = "xyes")
 304
 305 dnl define an ERROR_CFLAGS Makefile variable
 306 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 307     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef
 308     -Wwrite-strings -Wformat-nonliteral -Wformat-security -Wformat-nonliteral
 309     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 310     -Wno-multichar -Wnested-externs ])
 311
 312 dnl define correct level for debugging messages
 313 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 314
 315 dnl used in examples
 316 AG_GST_DEFAULT_ELEMENTS
 317
 318 dnl *** plug-ins to include ***
 319
 320 dnl these are all the gst plug-ins, compilable without additional libs
 321 AG_GST_CHECK_PLUGIN(omx)
 322
 323 dnl check for gstreamer core features (subsystems)
 324 dnl FIXME: this assumes srcdir == builddir for uninstalled setups
 325 GST_CONFIGPATH=`$PKG_CONFIG --variable=includedir gstreamer-$GST_API_VERSION`"/gst/gstconfig.h"
 326 AG_GST_PARSE_SUBSYSTEM_DISABLES($GST_CONFIGPATH)
 327 dnl AM_CONDITIONAL(USE_FOO, test $GST_DISABLE_FOO != "1")
 328
 329 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 330
 331 dnl Overview:
 332 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 333 dnl GST_*:              flags shared by built objects to link against GStreamer
 334 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 335 dnl                          (compare to other modules) or for i18n
 336 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 337 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 338 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 339 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 340
 341 dnl GST_OPTION_CFLAGS
 342 if test "x$USE_DEBUG" = xyes; then
 343    PROFILE_CFLAGS="-g"
 344 fi
 345 AC_SUBST(PROFILE_CFLAGS)
 346
 347 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 348   dnl Define _only_ when compiling a git version (not pre-releases or releases)
 349   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 350 else
 351   DEPRECATED_CFLAGS=""
 352 fi
 353 AC_SUBST(DEPRECATED_CFLAGS)
 354
 355 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 356 dnl at make time with e.g. make ERROR_CFLAGS=""
 357 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 358 AC_SUBST(GST_OPTION_CFLAGS)
 359
 360 dnl GST_PLUGINS_BASE_CFLAGS
 361 dnl prefer internal headers to already installed ones
 362 dnl also add builddir include for enumtypes and marshal
 363 GST_OMX_CFLAGS=""
 364 AC_SUBST(GST_OMX_CFLAGS)
 365
 366 dnl FIXME: do we want to rename to GST_ALL_* ?
 367 dnl add GST_OPTION_CFLAGS, but overridable
 368 GST_CFLAGS="$GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
 369 AC_SUBST(GST_CFLAGS)
 370 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 371 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 372 AC_SUBST(GST_LIBS)
 373
 374 dnl LDFLAGS really should only contain flags, not libs - they get added before
 375 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 376 GST_ALL_LDFLAGS="-no-undefined"
 377 if test "x${enable_Bsymbolic}" = "xyes"; then
 378   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 379 fi
 380 AC_SUBST(GST_ALL_LDFLAGS)
 381
 382 dnl this really should only contain flags, not libs - they get added before
 383 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 384 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_.*' $GST_ALL_LDFLAGS"
 385 AC_SUBST(GST_PLUGIN_LDFLAGS)
 386
 387 dnl *** output files ***
 388
 389
 390 dnl drm buffer
 391
 392 PKG_CHECK_MODULES(TBM, libtbm)
 393 AC_SUBST(TBM_CFLAGS)
 394 AC_SUBST(TBM_LIBS)
 395
 396 PKG_CHECK_MODULES(MM_COMMON, mm-common)
 397 AC_SUBST(MM_COMMON_CFLAGS)
 398 AC_SUBST(MM_COMMON_LIBS)
 399
 400 AC_CONFIG_FILES(
 401 Makefile
 402 omx/Makefile
 403 common/Makefile
 404 common/m4/Makefile
 405 tools/Makefile
 406 config/Makefile
 407 config/bellagio/Makefile
 408 config/rpi/Makefile
 409 config/exynos/Makefile
 410 config/exynos64/Makefile
 411 examples/Makefile
 412 examples/egl/Makefile
 413 m4/Makefile
 414 )
 415
 416 AC_OUTPUT
 417