configure.ac

   1 AC_PREREQ(2.69)
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, cvs and prerelease does Werror too
   6 AC_INIT(GStreamer libav, 1.17.0.1,
   7     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
   8     gst-libav)
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.14 no-dist-gzip dist-xz tar-ustar subdir-objects])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([ext/libav/gstav.c])
  23
  24 dnl define the output header for config
  25 AC_CONFIG_HEADERS([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output by default
  34 AM_SILENT_RULES([yes])
  35
  36 dnl our libraries and install dirs use major.minor as a version
  37 GST_API_VERSION=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  38 dnl we override it here if we need to for the release candidate of new series
  39 GST_API_VERSION=1.0
  40 AC_SUBST(GST_API_VERSION)
  41
  42 dnl *** Check for external $AS vs detected by AS_LIBTOOL
  43 orig_AS="$AS"
  44 AG_GST_LIBTOOL_PREPARE
  45 AS_LIBTOOL(GST, 1700, 0, 1700)
  46
  47 dnl *** required versions of GStreamer stuff ***
  48 GST_REQ=1.17.0.1
  49 GST_PBREQ=1.17.0.1
  50
  51 ORC_REQ=0.4.16
  52 ORC_CHECK([$ORC_REQ])
  53
  54 dnl *** autotools stuff ****
  55
  56 dnl allow for different autotools
  57 AS_AUTOTOOLS_ALTERNATE
  58
  59 dnl Add parameters for aclocal
  60 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  61
  62 dnl *** check for arguments to configure ***
  63
  64 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  65 AG_GST_ARG_ENABLE_EXTRA_CHECKS
  66
  67 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  68 AG_GST_ARG_WITH_PACKAGE_NAME
  69 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  70 AG_GST_ARG_VALGRIND
  71 AG_GST_ARG_GCOV
  72
  73 dnl *** checks for platform ***
  74
  75 dnl * hardware/architecture *
  76
  77 dnl common/m4/gst-arch.m4
  78 dnl check CPU type
  79 AG_GST_ARCH
  80
  81 dnl *** software ***
  82
  83 dnl check for large file support
  84 dnl affected plugins must include config.h
  85 AC_SYS_LARGEFILE
  86
  87 dnl *** checks for programs ***
  88
  89 dnl find a compiler
  90 AC_PROG_CC
  91 AC_PROG_CC_STDC
  92
  93 dnl check if the compiler supports '-c' and '-o' options
  94 AM_PROG_CC_C_O
  95
  96 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
  97 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
  98
  99 dnl *** checks for libraries ***
 100
 101 dnl check for libm, for sin()
 102 LT_LIB_M
 103 AC_SUBST(LIBM)
 104
 105 dnl check for pthreads
 106 AX_PTHREAD
 107
 108 dnl *** checks for header files ***
 109
 110 dnl check if we have ANSI C header files
 111 AC_HEADER_STDC
 112
 113 dnl *** checks for types/defines ***
 114
 115 dnl *** checks for structures ***
 116
 117 dnl *** checks for compiler characteristics ***
 118
 119 dnl *** checks for library functions ***
 120
 121 dnl *** checks for dependancy libraries ***
 122
 123 dnl GLib is required
 124 GLIB_REQ=2.40.0
 125 AC_SUBST([GLIB_REQ])
 126 AG_GST_GLIB_CHECK([$GLIB_REQ])
 127
 128 dnl checks for gstreamer
 129 dnl uninstalled is selected preferentially -- see pkg-config(1)
 130 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ])
 131 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ])
 132 AG_GST_CHECK_GST_PLUGINS_BASE($GST_API_VERSION, [$GST_PBREQ])
 133 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 134 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 135
 136 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 137 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 138
 139 dnl Check for -Bsymbolic-functions linker flag used to avoid
 140 dnl intra-library PLT jumps, if available.
 141 AC_ARG_ENABLE(Bsymbolic,
 142               [AS_HELP_STRING([--disable-Bsymbolic],[avoid linking with -Bsymbolic])],,
 143               [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
 144                AC_MSG_CHECKING([for -Bsymbolic linker flag])
 145                LDFLAGS=-Wl,-Bsymbolic
 146                LIBS=
 147                AC_TRY_LINK([], [return 0],
 148                            AC_MSG_RESULT(yes)
 149                            enable_Bsymbolic=yes,
 150                            AC_MSG_RESULT(no)
 151                            enable_Bsymbolic=no)
 152                LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
 153
 154 dnl *** set variables based on configure arguments ***
 155
 156 dnl set location of plugin directory
 157 AG_GST_SET_PLUGINDIR
 158
 159 dnl Detect if we are building static plugins, in which case we need to
 160 dnl generates libav .la files and install the static libraries.
 161 AM_CONDITIONAL(GST_PLUGIN_BUILD_STATIC, test "x$enable_static" = "xyes")
 162
 163 dnl define an ERROR_CFLAGS Makefile variable
 164 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 165     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef
 166     -Wwrite-strings -Wformat-nonliteral -Wformat-security -Wold-style-definition
 167     -Winit-self -Wmissing-include-dirs -Waddress
 168     -Waggregate-return -Wno-multichar -Wnested-externs ])
 169
 170 dnl define correct level for debugging messages
 171 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 172
 173 dnl disable strict aliasing
 174 AS_COMPILER_FLAG([-fno-strict-aliasing], [EXTRA_CFLAGS="-fno-strict-aliasing"])
 175 AC_SUBST(EXTRA_CFLAGS)
 176
 177 dnl *** finalize CFLAGS, LDFLAGS, LIBS ***
 178
 179 dnl Overview:
 180 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 181 dnl GST_*:              flags shared by built objects to link against GStreamer
 182 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 183 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 184 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 185 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 186
 187 dnl GST_OPTION_CFLAGS
 188 if test "x$USE_DEBUG" = xyes; then
 189    PROFILE_CFLAGS="-g"
 190 fi
 191 AC_SUBST(PROFILE_CFLAGS)
 192
 193 if test "x$GST_GIT" = "xyes"; then
 194   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 195 else
 196   DEPRECATED_CFLAGS=""
 197 fi
 198 AC_SUBST(DEPRECATED_CFLAGS)
 199
 200 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 201 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 202
 203 AC_SUBST(GST_OPTION_CFLAGS)
 204
 205 dnl FIXME: do we want to rename to GST_ALL_* ?
 206 dnl prefer internal headers to already installed ones
 207 dnl also add builddir include for enumtypes and marshal
 208 dnl add GST_OPTION_CFLAGS, but overridable
 209 GST_CFLAGS="$GST_CFLAGS"
 210 GST_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS $EXTRA_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
 211 AC_SUBST(GST_CFLAGS)
 212 AC_SUBST(GST_LIBS)
 213
 214 GST_ALL_LDFLAGS="-no-undefined"
 215 if test "x${enable_Bsymbolic}" = "xyes"; then
 216   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic"
 217 fi
 218 AC_SUBST(GST_ALL_LDFLAGS)
 219
 220 dnl this really should only contain flags, not libs - they get added before
 221 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 222 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_.*' $GST_ALL_LDFLAGS"
 223 AC_SUBST(GST_PLUGIN_LDFLAGS)
 224
 225 dnl Add MacOSX specific flags
 226 AC_CANONICAL_HOST
 227 case $host_os in
 228      darwin*)
 229         DARWIN_LDFLAGS="-Wl,-read_only_relocs,suppress"
 230         ;;
 231      *)
 232         DARWIN_LDFLAGS=""
 233         ;;
 234 esac
 235 AC_SUBST(DARWIN_LDFLAGS)
 236
 237 AC_ARG_ENABLE(gpl,
 238               [AC_HELP_STRING([--enable-gpl], [build a GPL licensed gst-libav])])
 239 AM_CONDITIONAL(GST_LIBAV_ENABLE_GPL, test "x$enable_gpl" = "xyes")
 240 if test "x$enable_gpl" = "xyes"; then
 241   AC_DEFINE([GST_LIBAV_ENABLE_GPL], [], [Defined if building a GPL-licensed version of gst-libav])
 242 fi
 243
 244 dnl *** configure external libs ***
 245
 246 HAVE_LIBAV_UNINSTALLED=1
 247
 248 AC_ARG_WITH(system-libav,
 249             [AC_HELP_STRING([--with-system-libav], [use system Libav libraries])])
 250
 251 HAVE_LZMA="no"
 252 HAVE_BZ2="no"
 253 if test "x$with_system_libav" = "xyes"; then
 254   PKG_CHECK_MODULES(LIBAV, libavfilter libavformat libavcodec >= 58 libavutil)
 255   saved_CPPFLAGS="$CPPFLAGS"
 256   CPPFLAGS="$CPPFLAGS $LIBAV_CFLAGS"
 257   AC_CHECK_HEADERS([avi.h])
 258   AC_DEFINE([LIBAV_SOURCE], ["system install"], [Describes where the Libav libraries come from.])
 259   HAVE_LIBAV_UNINSTALLED=0
 260   AC_MSG_NOTICE([Using system-installed libav code])
 261   AC_MSG_CHECKING([whether libav is provided by FFmpeg])
 262   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 263     #include <libavcodec/avcodec.h>
 264     ]],[[
 265         #if LIBAVCODEC_VERSION_MICRO >= 100
 266         /* FFmpeg uses 100+ as its micro version */
 267         #else
 268         #error libav provider should be FFmpeg
 269         #endif
 270     ]])], [is_ffmpeg=yes], [is_ffmpeg=no])
 271   AC_MSG_RESULT([$is_ffmpeg])
 272   CPPFLAGS="$saved_CPPFLAGS"
 273   if test "$is_ffmpeg" = no; then
 274     AC_MSG_ERROR([Uncompatible libavcodec found])
 275   fi
 276 else
 277   AC_MSG_NOTICE([Using local Libav snapshot])
 278
 279   dnl *** Check for bz2
 280   save_LIBS=$LIBS
 281   LIBS="$LIBS -lbz2"
 282   AC_MSG_CHECKING([for BZ2_bzlibVersion in -lbz2])
 283   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <bzlib.h>]], [[const char *version = BZ2_bzlibVersion ();]])],[HAVE_BZ2=yes],[HAVE_BZ2=no])
 284   AC_MSG_RESULT($HAVE_BZ2)
 285   LIBS=$save_LIBS
 286   if test "x$HAVE_BZ2" = "xno"; then
 287     AC_WARN([libbz2 not found, matroska demuxer will not be able to read bz2 tracks])
 288     BZ2_LIBS=
 289   else
 290     BZ2_LIBS="-lbz2"
 291   fi
 292
 293   dnl *** Check for lzma
 294   save_LIBS=$LIBS
 295   LIBS="$LIBS -llzma"
 296   AC_MSG_CHECKING([for lzma_version_string in -llzma])
 297   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <lzma.h>]], [[const char *version = lzma_version_string ();]])],[HAVE_LZMA=yes],[HAVE_LZMA=no])
 298   AC_MSG_RESULT($HAVE_LZMA)
 299   LIBS=$save_LIBS
 300   if test "x$HAVE_LZMA" = "xno"; then
 301     AC_WARN([lzma not found, tiff reader will not be able to read lzma files])
 302     LZMA_LIBS=
 303   else
 304     LZMA_LIBS="-llzma"
 305   fi
 306
 307   dnl libgstlibav.la: include dirs
 308   LIBAV_CPPFLAGS="-I \$(top_srcdir)/gst-libs/ext/libav \
 309                 -I \$(top_builddir)/gst-libs/ext/libav"
 310
 311   LIBAV_CFLAGS="-Wno-deprecated-declarations"
 312
 313   LIBAV_DEPS="\$(top_builddir)/gst-libs/ext/libav/libavfilter/libavfilter.a \
 314               \$(top_builddir)/gst-libs/ext/libav/libavformat/libavformat.a \
 315               \$(top_builddir)/gst-libs/ext/libav/libavcodec/libavcodec.a \
 316               \$(top_builddir)/gst-libs/ext/libav/libswresample/libswresample.a \
 317               \$(top_builddir)/gst-libs/ext/libav/libavutil/libavutil.a"
 318
 319   LIBAV_LIBS="$ac_pwd/gst-libs/ext/libavfilter.la \
 320               $ac_pwd/gst-libs/ext/libavformat.la \
 321               $ac_pwd/gst-libs/ext/libavcodec.la \
 322               $ac_pwd/gst-libs/ext/libswresample.la \
 323               $ac_pwd/gst-libs/ext/libavutil.la"
 324
 325   LIBAV_SUBDIRS=gst-libs
 326   AC_DEFINE(HAVE_AVI_H)
 327   AC_DEFINE([LIBAV_SOURCE], ["local snapshot"], [Describes where the Libav libraries come from.])
 328
 329   AC_ARG_WITH(libav-extra-configure,
 330       AC_HELP_STRING([--with-libav-extra-configure="xxx"],
 331       [extra configure options for internal libav ./configure script]),,
 332       with_libav=no)
 333
 334   # basic arguments
 335   emblibav_configure_args="--prefix=$prefix"
 336
 337   # Enable pic and static so that we get .a files, but with PIC code.
 338   emblibav_configure_args="$emblibav_configure_args \
 339         --enable-static --enable-pic \
 340         --disable-avdevice --disable-postproc --disable-swscale \
 341         --disable-programs --disable-ffplay --disable-ffprobe --disable-ffmpeg \
 342         --disable-encoder=flac --disable-protocols --disable-devices \
 343         --disable-network --disable-hwaccels --disable-dxva2 --disable-vdpau \
 344         --disable-filters --enable-filter=yadif --disable-doc --disable-d3d11va \
 345         --disable-audiotoolbox --disable-videotoolbox --disable-vaapi --disable-crystalhd \
 346         --disable-mediacodec --disable-nvenc --disable-mmal --disable-omx \
 347         --disable-omx-rpi --disable-cuda --disable-cuvid --disable-libmfx \
 348         --disable-libnpp --disable-iconv --disable-jni --disable-v4l2_m2m --enable-optimizations"
 349
 350   if test "x$enable_gpl" == "xyes"; then
 351     emblibav_configure_args="$emblibav_configure_args --enable-gpl"
 352   fi
 353
 354   # if we are cross-compiling, tell libav so
 355   case $host in
 356       *android*)
 357         target_os=linux
 358       ;;
 359       *darwin*)
 360         target_os=darwin
 361       ;;
 362       *)
 363         target_os=`echo $host_os | sed 's/-gnu.*//'`
 364       ;;
 365   esac
 366
 367   if test "x$cross_compiling" = xyes; then
 368     emblibav_configure_args="$emblibav_configure_args --enable-cross-compile \
 369         --target-os=$target_os --arch=$host_cpu --cross-prefix=$host_alias-"
 370   fi
 371
 372   case $host_os in
 373     mingw32*)
 374       WIN32_LIBS="-lws2_32 -lbcrypt"
 375       ;;
 376     *)
 377       WIN32_LIBS=
 378       ;;
 379   esac
 380
 381   if test x"$AR" != x; then
 382     emblibav_configure_args="$emblibav_configure_args --ar=\\\"\\\$AR\\\""
 383   fi
 384
 385   if test x"$orig_AS" != x; then
 386     emblibav_configure_args="$emblibav_configure_args --as=\\\"\\\$orig_AS\\\""
 387     export orig_AS
 388   elif test x"$CC" != x; then
 389     dnl No external $AS - try $CC for the libav assembler
 390     emblibav_configure_args="$emblibav_configure_args --as=\\\"\\\$CC\\\""
 391   fi
 392
 393   if test x"$CC" != x; then
 394     emblibav_configure_args="$emblibav_configure_args --cc=\\\"\\\$CC\\\""
 395   fi
 396
 397   if test x"$LD" != x; then
 398     emblibav_configure_args="$emblibav_configure_args --ld=\\\"\\\$CC\\\""
 399   fi
 400
 401   if test x"$NM" != x; then
 402     emblibav_configure_args="$emblibav_configure_args --nm=\\\"\\\$NM\\\""
 403   fi
 404
 405   dnl checks for extra enable/disable flags
 406   LIBAV_OPTS=`cd $srcdir/gst-libs/ext/libav && ./configure --help`
 407   # Let's check if we can disable the building of the libav binary
 408   can_disable=`echo "$LIBAV_OPTS" | grep 'disable-ffmpeg'`
 409   if test "$can_disable" != ""; then
 410     emblibav_configure_args="$emblibav_configure_args --disable-ffmpeg"
 411   fi
 412
 413   # append extra configure options to emblibav_configure_args if needed
 414   if test "x$with_libav_extra_configure" != "xno"; then
 415     emblibav_configure_args="$emblibav_configure_args $with_libav_extra_configure"
 416   fi
 417
 418   AC_SUBST(LIBAV_CO_DIR)
 419   AC_SUBST(LIBAV_SVN)
 420   AC_SUBST(LIBAV_REVISION)
 421   AC_SUBST(LIBAV_EXTERNALS_REVISION)
 422   AC_CONFIG_COMMANDS([configure-embedded-libav],
 423     [echo "Configuring included Libav instance with args $emblibav_configure_args"
 424      origdir=`pwd`
 425      dnl Don't put path on the configure call when not needed, as FFmpeg's configure relies on it
 426      dnl to detect out-of-tree builds
 427      if test -z "$srcdir" -o "$srcdir" = .; then
 428        confcmd=./configure
 429      else
 430        confcmd="$ac_abs_top_srcdir"/gst-libs/ext/libav/configure
 431      fi
 432      gasppdir="$ac_abs_top_srcdir"/gst-libs/ext/gas-preprocessor
 433
 434      AS_MKDIR_P(["$ac_top_build_prefix"gst-libs/ext/libav])
 435      oldPATH="$PATH"
 436      PATH="$gasppdir:$PATH"
 437      cd "$ac_top_build_prefix"gst-libs/ext/libav &&
 438          eval "$confcmd $emblibav_configure_args" ||
 439          AC_MSG_ERROR([Failed to configure embedded Libav tree])
 440      PATH="$oldPATH"
 441      cd "$origdir"
 442     ],
 443     [emblibav_configure_args="$emblibav_configure_args"])
 444   AC_MSG_NOTICE([Using included Libav code])
 445 fi
 446
 447 AM_CONDITIONAL(HAVE_BZ2, test "x$HAVE_BZ2" = "xyes")
 448 AM_CONDITIONAL(HAVE_LZMA, test "x$HAVE_LZMA" = "xyes")
 449
 450 AC_SUBST(LIBAV_CPPFLAGS)
 451 AC_SUBST(LIBAV_CFLAGS)
 452 AC_SUBST(LIBAV_DEPS)
 453 AC_SUBST(LIBAV_LIBS)
 454 AC_SUBST(LIBAV_SUBDIRS)
 455 AC_SUBST(WIN32_LIBS)
 456 AC_SUBST(BZ2_LIBS)
 457 AC_SUBST(LZMA_LIBS)
 458
 459 if test x$HAVE_LIBAV_UNINSTALLED = x1; then
 460   AC_DEFINE(HAVE_LIBAV_UNINSTALLED, [], [Defined if building against uninstalled Libav source])
 461 fi
 462 AM_CONDITIONAL(HAVE_LIBAV_UNINSTALLED, test x$HAVE_LIBAV_UNINSTALLED = x1)
 463
 464 AC_CONFIG_FILES(
 465 Makefile
 466 common/Makefile
 467 common/m4/Makefile
 468 ext/Makefile
 469 ext/libav/Makefile
 470 gst-libs/Makefile
 471 gst-libs/ext/Makefile
 472 tests/Makefile
 473 tests/check/Makefile
 474 tests/files/Makefile
 475 pkgconfig/Makefile
 476 pkgconfig/gstreamer-plugins-libav-uninstalled.pc
 477 )
 478 AC_OUTPUT
 479
 480 ORC_OUTPUT