configure.ac

   1 AC_PREREQ(2.62)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/pre
   8 AC_INIT(GStreamer Good Plug-ins, 1.0.1.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-good)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability 1.11 no-dist-gzip dist-xz tar-ustar])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE([enable])
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use GST_API_VERSION in the filename
  41 dnl to allow side-by-side installation of different API versions
  42 GST_API_VERSION=1.0
  43 AC_SUBST(GST_API_VERSION)
  44 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  45   [GStreamer API Version])
  46
  47 AG_GST_LIBTOOL_PREPARE
  48 AS_LIBTOOL(GST, 1, 0, 1)
  49
  50 dnl *** required versions of GStreamer stuff ***
  51 GST_REQ=1.0.0
  52 GSTPB_REQ=1.0.0
  53
  54 dnl *** autotools stuff ****
  55
  56 dnl allow for different autotools
  57 AS_AUTOTOOLS_ALTERNATE
  58
  59 dnl Add parameters for aclocal
  60 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  61
  62 dnl set up gettext
  63 dnl the version check needs to stay here because autopoint greps for it
  64 AM_GNU_GETTEXT_VERSION([0.17])
  65 AM_GNU_GETTEXT([external])
  66 AG_GST_GETTEXT([gst-plugins-good-$GST_API_VERSION])
  67
  68 dnl *** check for arguments to configure ***
  69
  70 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  71
  72 AG_GST_ARG_DEBUG
  73 AG_GST_ARG_PROFILING
  74 AG_GST_ARG_VALGRIND
  75 AG_GST_ARG_GCOV
  76
  77 AG_GST_ARG_EXAMPLES
  78
  79 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  80 AG_GST_ARG_WITH_PACKAGE_NAME
  81 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  82
  83 AG_GST_ARG_WITH_PLUGINS
  84
  85 AG_GST_ARG_ENABLE_EXTERNAL
  86
  87 AG_GST_ARG_ENABLE_EXPERIMENTAL
  88
  89 dnl *** checks for platform ***
  90
  91 dnl * hardware/architecture *
  92
  93 dnl common/m4/gst-arch.m4
  94 dnl check CPU type
  95 AG_GST_ARCH
  96
  97 dnl Determine endianness
  98 AC_C_BIGENDIAN
  99
 100 dnl *** checks for programs ***
 101
 102 dnl find a compiler
 103 AC_PROG_CC
 104 AC_PROG_CC_STDC
 105
 106 dnl determine c++ compiler
 107 AC_PROG_CXX
 108 dnl determine if c++ is available on this system
 109 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 110
 111 dnl determine c++ preprocessor
 112 dnl FIXME: do we need this ?
 113 AC_PROG_CXXCPP
 114
 115 AC_PROG_OBJC
 116
 117 dnl check if the compiler supports '-c' and '-o' options
 118 AM_PROG_CC_C_O
 119
 120 dnl find an assembler
 121 AM_PROG_AS
 122
 123 dnl check if the compiler supports do while(0) macros
 124 AG_GST_CHECK_DOWHILE_MACROS
 125
 126 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 127 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 128
 129 dnl check for documentation tools
 130 GTK_DOC_CHECK([1.12])
 131 AS_PATH_PYTHON([2.1])
 132 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 133
 134 dnl *** checks for libraries ***
 135
 136 dnl check for libm, for sin()
 137 LT_LIB_M
 138 AC_SUBST(LIBM)
 139
 140 dnl *** checks for header files ***
 141
 142 dnl check if we have ANSI C header files
 143 AC_HEADER_STDC
 144
 145 dnl used by ext/wavpack
 146 AX_CREATE_STDINT_H
 147
 148 dnl used in gst/udp
 149 AC_CHECK_HEADERS([sys/time.h])
 150
 151 dnl used in gst/udp
 152 AC_CHECK_HEADERS([sys/socket.h])
 153
 154 dnl *** checks for types/defines ***
 155
 156 dnl Check for FIONREAD ioctl declaration.  This check is needed
 157 dnl for the UDP plugin to build on Solaris
 158 GST_CHECK_FIONREAD
 159
 160 dnl *** checks for structures ***
 161
 162 dnl *** checks for compiler characteristics ***
 163
 164 dnl check if we have GCC inline-asm
 165 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 166 if test x$HAVE_GCC_ASM = xyes ; then
 167   AC_DEFINE(HAVE_GCC_ASM, 1,
 168     [Define if compiler supports gcc inline assembly])
 169 fi
 170 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 171
 172 dnl *** checks for library functions ***
 173
 174 LIBS_SAVE=$LIBS
 175 LIBS="$LIBS $LIBM"
 176 AC_CHECK_FUNCS(rint sinh cosh asinh fpclass)
 177 LIBS=$LIBS_SAVE
 178
 179 dnl Check whether isinf() is defined by math.h
 180 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
 181     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; int i=isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
 182 if test "$ac_cv_have_isinf" = "yes"
 183 then
 184     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
 185 fi
 186
 187 dnl Check for mmap (needed by electricfence plugin)
 188 AC_FUNC_MMAP
 189 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 190
 191 dnl Check for mmap (needed by electricfence plugin)
 192
 193 AC_CHECK_TYPE([struct ip_mreqn], [
 194               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
 195               [#include <netinet/in.h>])
 196
 197 dnl *** checks for dependency libraries ***
 198
 199
 200 dnl GLib
 201 GLIB_REQ=2.32.0
 202 AG_GST_GLIB_CHECK([$GLIB_REQ])
 203
 204 dnl Orc
 205 ORC_CHECK([0.4.16])
 206
 207 dnl checks for gstreamer
 208 dnl uninstalled is selected preferentially -- see pkg-config(1)
 209 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 210 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 211 AG_GST_CHECK_GST_CONTROLLER($GST_API_VERSION, [$GST_REQ], yes)
 212 AG_GST_CHECK_GST_NET($GST_API_VERSION, [$GST_REQ], yes)
 213 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 214 AG_GST_CHECK_GST_PLUGINS_BASE($GST_API_VERSION, [$GSTPB_REQ], yes)
 215
 216 GST_TOOLS_DIR=`$PKG_CONFIG --variable=toolsdir gstreamer-$GST_API_VERSION`
 217 if test -z $GST_TOOLS_DIR; then
 218   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 219 fi
 220 AC_SUBST(GST_TOOLS_DIR)
 221
 222 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 223 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 224
 225 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 226
 227 dnl Check for documentation xrefs
 228 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 229 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 230 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_API_VERSION`"
 231 AC_SUBST(GLIB_PREFIX)
 232 AC_SUBST(GST_PREFIX)
 233 AC_SUBST(GSTPB_PREFIX)
 234
 235 dnl GTK is optional and used in examples
 236 HAVE_GTK=no
 237 GTK_REQ=3.0.0
 238 if test "x$BUILD_EXAMPLES" = "xyes"; then
 239   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 240   dnl some examples need gtk+-x11
 241   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 242   AC_SUBST(GTK_LIBS)
 243   AC_SUBST(GTK_CFLAGS)
 244 fi
 245 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 246 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 247
 248 dnl *** set variables based on configure arguments ***
 249
 250 dnl set license and copyright notice
 251 GST_LICENSE="LGPL"
 252 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 253 AC_SUBST(GST_LICENSE)
 254
 255 dnl set location of plugin directory
 256 AG_GST_SET_PLUGINDIR
 257
 258 dnl set release date/time
 259 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 260   ["${srcdir}/gst-plugins-good.doap"],
 261   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 262
 263 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 264 dnl make sure it doesn't complain about unused variables if debugging is disabled
 265 NO_WARNINGS=""
 266 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 267
 268 dnl define an ERROR_CFLAGS Makefile variable
 269 dnl -Wundef: too many broken headers
 270 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 271       -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 272       -Wwrite-strings -Wold-style-definition -Waggregate-return
 273       -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 274       -Wnested-externs $NO_WARNINGS])
 275
 276 dnl define an ERROR_CXXFLAGS Makefile variable
 277 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 278         -Wmissing-declarations -Wredundant-decls
 279         -Wwrite-strings
 280         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 281         $NO_WARNINGS])
 282
 283 dnl define an ERROR_OBJCFLAGS Makefile variable
 284 AG_GST_SET_ERROR_OBJCFLAGS($FATAL_WARNINGS, [
 285       -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 286       -Wwrite-strings -Wold-style-definition
 287       -Winit-self -Wmissing-include-dirs -Wno-multichar
 288       -Wnested-externs $NO_WARNINGS])
 289
 290 dnl define correct level for debugging messages
 291 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 292
 293 dnl used in examples
 294 AG_GST_DEFAULT_ELEMENTS
 295
 296 dnl *** plug-ins to include ***
 297
 298 dnl Non ported plugins (non-dependant, then dependant)
 299 dnl Make sure you have a space before and after all plugins
 300 GST_PLUGINS_NONPORTED="cairo cairo_gobject osx_audio "
 301 AC_SUBST(GST_PLUGINS_NONPORTED)
 302
 303 dnl these are all the gst plug-ins, compilable without additional libs
 304 dnl videofilter is at the top because others depend on it
 305 AG_GST_CHECK_PLUGIN(alpha)
 306 AG_GST_CHECK_PLUGIN(apetag)
 307 AG_GST_CHECK_PLUGIN(audiofx)
 308 AG_GST_CHECK_PLUGIN(audioparsers)
 309 AG_GST_CHECK_PLUGIN(auparse)
 310 AG_GST_CHECK_PLUGIN(autodetect)
 311 AG_GST_CHECK_PLUGIN(avi)
 312 AG_GST_CHECK_PLUGIN(cutter)
 313 AG_GST_CHECK_PLUGIN(debugutils)
 314 AG_GST_CHECK_PLUGIN(deinterlace)
 315 AG_GST_CHECK_PLUGIN(effectv)
 316 AG_GST_CHECK_PLUGIN(equalizer)
 317 AG_GST_CHECK_PLUGIN(flv)
 318 AG_GST_CHECK_PLUGIN(flx)
 319 AG_GST_CHECK_PLUGIN(goom)
 320 AG_GST_CHECK_PLUGIN(goom2k1)
 321 AG_GST_CHECK_PLUGIN(icydemux)
 322 AG_GST_CHECK_PLUGIN(id3demux)
 323 AG_GST_CHECK_PLUGIN(imagefreeze)
 324 AG_GST_CHECK_PLUGIN(interleave)
 325 AG_GST_CHECK_PLUGIN(isomp4)
 326 AG_GST_CHECK_PLUGIN(law)
 327 AG_GST_CHECK_PLUGIN(level)
 328 AG_GST_CHECK_PLUGIN(matroska)
 329 AG_GST_CHECK_PLUGIN(median)
 330 AG_GST_CHECK_PLUGIN(monoscope)
 331 AG_GST_CHECK_PLUGIN(multifile)
 332 AG_GST_CHECK_PLUGIN(multipart)
 333 AG_GST_CHECK_PLUGIN(replaygain)
 334 AG_GST_CHECK_PLUGIN(rtp)
 335 AG_GST_CHECK_PLUGIN(rtpmanager)
 336 AG_GST_CHECK_PLUGIN(rtsp)
 337 AG_GST_CHECK_PLUGIN(shapewipe)
 338 AG_GST_CHECK_PLUGIN(smpte)
 339 AG_GST_CHECK_PLUGIN(spectrum)
 340 AG_GST_CHECK_PLUGIN(udp)
 341 AG_GST_CHECK_PLUGIN(videobox)
 342 AG_GST_CHECK_PLUGIN(videocrop)
 343 AG_GST_CHECK_PLUGIN(videofilter)
 344 AG_GST_CHECK_PLUGIN(videomixer)
 345 AG_GST_CHECK_PLUGIN(wavenc)
 346 AG_GST_CHECK_PLUGIN(wavparse)
 347 AG_GST_CHECK_PLUGIN(y4m)
 348
 349 dnl disable experimental plug-ins
 350 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 351   AG_GST_DISABLE_PLUGIN(monoscope)
 352 fi
 353
 354 dnl *** sys plug-ins ***
 355
 356 echo
 357 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 358 echo
 359
 360 dnl DirectSound
 361 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 362 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 363   HAVE_DIRECTSOUND="no"
 364   save_CFLAGS="$CFLAGS"
 365   save_LDFLAGS="$LDFLAGS"
 366   save_LIBS="$LIBS"
 367   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 368   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 369   LIBS="$LIBS -ldsound -ldxerr9 -luser32"
 370   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 371   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 372 #include <windows.h>
 373 #include <dxerr9.h>
 374 #include <dsound.h>
 375 ]], [[
 376   DXGetErrorString9 (0);
 377   DirectSoundCreate(NULL, NULL, NULL);
 378 ]])
 379 ],
 380     [HAVE_DIRECTSOUND="yes"],
 381     [HAVE_DIRECTSOUND="no"])
 382   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 383   CFLAGS=$save_CFLAGS
 384   LDFLAGS=$save_LDFLAGS
 385   LIBS=$save_LIBS
 386
 387   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 388     dnl this is much more than we want
 389     DIRECTSOUND_LIBS="-ldsound -ldxerr9 -luser32"
 390     AC_SUBST(DIRECTSOUND_CFLAGS)
 391     AC_SUBST(DIRECTSOUND_LDFLAGS)
 392     AC_SUBST(DIRECTSOUND_LIBS)
 393   fi
 394   AC_SUBST(HAVE_DIRECTSOUND)
 395 ])
 396
 397 dnl *** Win32 WaveOut ***
 398 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVEFORM, true)
 399 AG_GST_CHECK_FEATURE(WAVEFORM, [Win32 WaveForm], waveformsink, [
 400   AC_CHECK_HEADER(mmsystem.h, HAVE_WAVEFORM="yes", HAVE_WAVEFORM="no", [#include <windows.h>])
 401 ])
 402
 403 dnl *** OSS audio *** (Linux, *BSD)
 404 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 405 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 406  HAVE_OSS="yes"
 407 dnl Linux and newer BSD versions :
 408  AC_CHECK_HEADER(sys/soundcard.h, [
 409    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 410    ] , [
 411 dnl Some old BSD versions and also newer OpenBSD versions :
 412    AC_CHECK_HEADER(soundcard.h, [
 413      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 414      ], [
 415   dnl Some old BSD versions :
 416      AC_CHECK_HEADER(machine/soundcard.h, [
 417        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 418          [Define if OSS includes are in /machine/])
 419        ], [
 420        HAVE_OSS="no"
 421      ])
 422    ])
 423  ])
 424 ])
 425
 426 dnl *** oss4 ***
 427 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS4, true)
 428 AG_GST_CHECK_FEATURE(OSS4, [Open Sound System 4], oss4, [
 429   AC_MSG_CHECKING([Checking if we can build the OSS4 elements])
 430   AC_CHECK_HEADERS([fcntl.h sys/ioctl.h sys/stat.h sys/types.h],
 431       [test -z "$OSS4_MISSING_HEADER" && HAVE_OSS4="yes"],
 432       [OSS4_MISSING_HEADER="yes";HAVE_OSS4="no"])
 433 ])
 434
 435 dnl *** Sun Audio ***
 436 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 437 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 438   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 439 ])
 440
 441 dnl *** OSX Audio ***
 442 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 443 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 444   AC_CHECK_HEADER(CoreAudio/CoreAudio.h, HAVE_OSX_AUDIO="yes", HAVE_OSX_AUDIO="no")
 445 ])
 446
 447 dnl *** OS X video ***
 448 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 449 HAVE_OSX_VIDEO="no"
 450 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 451   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 452 ])
 453 dnl in case header OpenGL/gl.h is found on other platforms
 454 case "$host" in
 455   *-*darwin*)
 456     dnl do nothing
 457     ;;
 458   *)
 459     HAVE_OSX_VIDEO="no"
 460     ;;
 461 esac
 462
 463
 464 dnl *** Video 4 Linux 2 ***
 465 dnl for information about the header/define, see sys/v4l2/gstv4l2element.h
 466 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 467 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 468 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], v4l2src, [
 469   AC_MSG_CHECKING([Checking for up to date v4l2 installation])
 470   AC_TRY_COMPILE([
 471 #include <sys/types.h>
 472 #ifdef __sun /* Solaris */
 473 #include <sys/types.h>
 474 #include <sys/videodev2.h>
 475 #else /* Linux */
 476 #include <linux/types.h>
 477 #define _LINUX_TIME_H
 478 #define __user
 479 #include <linux/videodev2.h>
 480 #endif
 481 #if defined(V4L2_MAJOR_VERSION) || defined(V4L2_MINOR_VERSION)
 482 #error too early v4l2 version or no v4l2 at all
 483 #endif
 484     ], [
 485 return 0;
 486     ], [
 487       HAVE_GST_V4L2="yes"
 488       AC_MSG_RESULT(yes)
 489     ], [
 490       HAVE_GST_V4L2="no"
 491       AC_MSG_RESULT(no)
 492
 493       HAVE_VIDEODEV=no
 494       AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_VIDEODEV=yes ],
 495       [
 496         AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_VIDEODEV=yes ])
 497       ])
 498
 499       if test "x$HAVE_VIDEODEV" = "xyes"; then
 500         AC_MSG_WARN([video4linux2 headers were found, but they're old.])
 501         AC_MSG_WARN([Please update v4l2 to compile the v4l2 plugins])
 502       else
 503         AC_MSG_WARN([video4linux2 was not found])
 504       fi
 505     ])
 506
 507   if [ test x$HAVE_GST_V4L2 = xyes ]; then
 508     dnl check for missing v4l2_buffer declaration (see #135919)
 509     MISSING_DECL=0
 510     AC_MSG_CHECKING(struct v4l2_buffer declaration)
 511     AC_TRY_COMPILE([
 512 #include <sys/types.h>
 513 #ifdef __sun /* Solaris */
 514 #include <sys/types.h>
 515 #include <sys/videodev2.h>
 516 #else /* Linux */
 517 #include <linux/types.h>
 518 #define _LINUX_TIME_H
 519 #define __user
 520 #include <linux/videodev2.h>
 521 #endif
 522     ],[
 523 struct v4l2_buffer buf;
 524 buf.index = 0;
 525 return 0;
 526     ], [ AC_MSG_RESULT(yes) ], [ MISSING_DECL=1 && AC_MSG_RESULT(no) ])
 527     if [ test x$MISSING_DECL = x1 ]; then
 528       AC_DEFINE(GST_V4L2_MISSING_BUFDECL, 1, [struct v4l2_buffer missing])
 529     fi
 530
 531     dnl check for XOverlay libraries
 532     AG_GST_CHECK_XV
 533   fi
 534 ])
 535
 536 # Optional gudev for device probing
 537 AC_ARG_WITH([gudev],
 538   AC_HELP_STRING([--with-gudev],
 539     [device detection with gudev]),
 540   [],
 541   [with_gudev=check])
 542 if test x$HAVE_GST_V4L2 = xyes; then
 543   if test x$with_gudev != xno; then
 544       PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 143 ],
 545           [ have_gudev=yes
 546             AC_DEFINE(HAVE_GUDEV, 1,
 547                [Whether gudev is available for device detection])
 548             AC_DEFINE([G_UDEV_API_IS_SUBJECT_TO_CHANGE], 1, [I know the API is subject to change.])
 549           ], [
 550           have_gudev=no
 551           ])
 552   else
 553     have_gudev=no
 554   fi
 555 fi
 556 AC_SUBST(GUDEV_CFLAGS)
 557 AC_SUBST(GUDEV_LIBS)
 558
 559 # Make libv4l2 non-automagic
 560 AC_ARG_WITH([libv4l2],
 561   AC_HELP_STRING([--with-libv4l2],
 562     [support video buffer conversion using libv4l2]),
 563   [],
 564   [with_libv4l2=check])
 565 if test x$HAVE_GST_V4L2 = xyes; then
 566   if test x$with_libv4l2 != xno; then
 567       PKG_CHECK_MODULES(LIBV4L2, libv4l2,
 568           [ have_libv4l2=yes
 569             AC_DEFINE(HAVE_LIBV4L2, 1,
 570                 [Whether libv4l2 is available for video buffer conversion])
 571           ], [
 572           have_libv4l2=no
 573           ])
 574   else
 575     have_libv4l2=no
 576   fi
 577 fi
 578
 579 dnl Check for X11
 580 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 581 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 582                   [ximagesrc], [
 583   AC_PATH_XTRA
 584
 585   dnl now try to find the HEADER
 586   ac_cflags_save="$CFLAGS"
 587   ac_cppflags_save="$CPPFLAGS"
 588   CFLAGS="$CFLAGS $X_CFLAGS"
 589   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 590   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 591
 592   if test "x$HAVE_X" = "xno"
 593   then
 594     AC_MSG_NOTICE([cannot find X11 development files])
 595   else
 596     dnl this is much more than we want
 597     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 598     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 599     dnl it does not add the libs; therefore we add them here
 600     X_LIBS="$X_LIBS -lX11"
 601     AC_SUBST(X_CFLAGS)
 602     AC_SUBST(X_LIBS)
 603
 604     dnl check for Xfixes
 605     PKG_CHECK_MODULES(XFIXES, xfixes, HAVE_XFIXES="yes", HAVE_XFIXES="no")
 606     if test "x$HAVE_XFIXES" = "xyes"
 607     then
 608         XFIXES_CFLAGS="-DHAVE_XFIXES $XFIXES_CFLAGS"
 609     fi
 610     AC_SUBST(XFIXES_LIBS)
 611     AC_SUBST(XFIXES_CFLAGS)
 612
 613     dnl check for Xdamage
 614     PKG_CHECK_MODULES(XDAMAGE, xdamage, HAVE_XDAMAGE="yes", HAVE_XDAMAGE="no")
 615     if test "x$HAVE_XDAMAGE" = "xyes"
 616     then
 617         XDAMAGE_CFLAGS="-DHAVE_XDAMAGE $XDAMAGE_CFLAGS"
 618     fi
 619     AC_SUBST(XDAMAGE_LIBS)
 620     AC_SUBST(XDAMAGE_CFLAGS)
 621   fi
 622   AC_SUBST(HAVE_X)
 623   CFLAGS="$ac_cflags_save"
 624   CPPFLAGS="$ac_cppflags_save"
 625 ])
 626
 627 dnl FIXME: this should be rolled into the test above, it's just an additional
 628 dnl feature of the ximagesrc plug-in
 629 dnl This is the same as in gst-plugins-base
 630 dnl check for X Shm
 631 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 632 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 633   if test x$HAVE_X = xyes; then
 634     AC_CHECK_LIB(Xext, XShmAttach,
 635                  HAVE_XSHM="yes", HAVE_XSHM="no",
 636                  $X_LIBS)
 637     if test "x$HAVE_XSHM" = "xyes"; then
 638       XSHM_LIBS="-lXext"
 639     else
 640       dnl On AIX, it is in XextSam instead, but we still need -lXext
 641       AC_CHECK_LIB(XextSam, XShmAttach,
 642                    HAVE_XSHM="yes", HAVE_XSHM="no",
 643                    $X_LIBS)
 644       if test "x$HAVE_XSHM" = "xyes"; then
 645         XSHM_LIBS="-lXext -lXextSam"
 646       fi
 647     fi
 648   fi
 649 ], ,[
 650   AC_SUBST(HAVE_XSHM)
 651   AC_SUBST(XSHM_LIBS)
 652 ])
 653
 654 dnl for V4L2, we also need to know if we have XVIDEO
 655 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 656 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 657                   [], [
 658   AG_GST_CHECK_XV
 659 ])
 660
 661 dnl *** ext plug-ins ***
 662 dnl keep this list sorted alphabetically !
 663
 664 if test "x$BUILD_EXTERNAL" = "xyes"; then
 665
 666 echo
 667 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 668 echo
 669
 670 dnl *** aalib ***
 671 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 672 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 673   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 674   AS_SCRUB_INCLUDE(AALIB_CFLAGS)
 675 ])
 676
 677 dnl *** cairo ***
 678 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 679 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering], cairo, [
 680   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.0.0)
 681 ])
 682
 683 dnl *** cairo-gobject ***
 684 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO_GOBJECT, true)
 685 AG_GST_CHECK_FEATURE(CAIRO_GOBJECT,
 686   [Cairo graphics rendering gobject bindings], cairooverlay, [
 687   AG_GST_PKG_CHECK_MODULES(CAIRO_GOBJECT, cairo-gobject >= 1.10.0)
 688 ])
 689
 690 dnl *** FLAC ***
 691 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 692 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 693   AG_GST_PKG_CHECK_MODULES(FLAC, flac >= 1.1.4)
 694 ])
 695
 696 dnl *** GDK pixbuf ***
 697 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 698 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 699   AG_GST_PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0 >= 2.8.0)
 700 ])
 701
 702 dnl *** Jack ***
 703 translit(dnm, m, l) AM_CONDITIONAL(USE_JACK, true)
 704 AG_GST_CHECK_FEATURE(JACK, Jack, jack, [
 705   PKG_CHECK_MODULES(JACK, jack >= 0.99.10, HAVE_JACK="yes", HAVE_JACK="no")
 706   AC_SUBST(JACK_CFLAGS)
 707   AC_SUBST(JACK_LIBS)
 708
 709   AG_GST_PKG_CHECK_MODULES(JACK_0_120_1, jack >= 0.120.1 jack < 1.0)
 710   if test x$HAVE_JACK_0_120_1 = xyes; then
 711     AC_DEFINE(HAVE_JACK_0_120_1, 1, [defined if jack >= 0.120.1 is available])
 712   fi
 713   AG_GST_PKG_CHECK_MODULES(JACK_1_9_7, jack >= 1.9.7)
 714   if test x$HAVE_JACK_1_9_7 = xyes; then
 715     AC_DEFINE(HAVE_JACK_1_9_7, 1, [defined if jack >= 1.9.7 is available])
 716   fi
 717
 718 ])
 719
 720 dnl *** jpeg ***
 721 dnl FIXME: we could use header checks here as well IMO
 722 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 723 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 724   AC_ARG_WITH(jpeg-mmx,
 725     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 726   OLD_LIBS="$LIBS"
 727   if test x$with_jpeg_mmx != x; then
 728     LIBS="$LIBS -L$with_jpeg_mmx"
 729   fi
 730   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 731   JPEG_LIBS="$LIBS -ljpeg-mmx"
 732   LIBS="$OLD_LIBS"
 733   if test x$HAVE_JPEG != xyes; then
 734     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 735     JPEG_LIBS="-ljpeg"
 736   fi
 737   AC_SUBST(JPEG_LIBS)
 738 ])
 739
 740 dnl *** libcaca ***
 741 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 742 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 743   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 744 ])
 745
 746 dnl *** libdv ***
 747 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 748 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 749   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 750 ])
 751
 752 dnl *** libpng ***
 753 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 754 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 755   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng >= 1.2)
 756 ])
 757
 758 dnl *** pulseaudio ***
 759 translit(dnm, m, l) AM_CONDITIONAL(USE_PULSE, true)
 760 AG_GST_CHECK_FEATURE(PULSE, [pulseaudio plug-in], pulseaudio, [
 761
 762   dnl used in ext/pulse/pulseutil.c
 763   AC_CHECK_HEADERS([process.h])
 764
 765   AG_GST_PKG_CHECK_MODULES(PULSE, libpulse >= 1.0)
 766 ])
 767
 768 dnl *** dv1394 ***
 769 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 770 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 771   dnl first test for libraw1394 >= 2.0.0
 772   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 2.0.0)
 773   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 774   dnl now see how far we got
 775   if test x$HAVE_RAW1394 = xyes && \
 776      test x$HAVE_LIBIEC61883 = xyes; then
 777        AG_GST_CHECK_LIBHEADER(AVC1394,
 778         avc1394, avc1394_send_command, $RAW1394_LIBS,
 779         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 780        AG_GST_CHECK_LIBHEADER(ROM1394,
 781         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 782         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 783        if test x$HAVE_AVC1394 = xyes && \
 784           test x$HAVE_AVC1394 = xyes && \
 785           test x$HAVE_ROM1394 = xyes; then
 786           HAVE_DV1394=yes
 787           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 788           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 789           AC_SUBST(DV1394_CFLAGS)
 790           AC_SUBST(DV1394_LIBS)
 791         fi
 792   else
 793        if test x$HAVE_RAW1394 = xno; then
 794           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 795           AG_GST_CHECK_LIBHEADER(AVC1394,
 796            avc1394, avc1394_send_command, $RAW1394_LIBS,
 797            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 798           AG_GST_CHECK_LIBHEADER(ROM1394,
 799            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 800            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 801           if test x$HAVE_RAW1394 = xyes && \
 802              test x$HAVE_AVC1394 = xyes && \
 803              test x$HAVE_ROM1394 = xyes; then
 804              HAVE_DV1394=yes
 805              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 806              DV1394_CFLAGS="$RAW1394_CFLAGS"
 807              if test x$HAVE_LIBIEC61883 = xyes; then
 808                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 809                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 810              fi
 811              AC_SUBST(DV1394_CFLAGS)
 812              AC_SUBST(DV1394_LIBS)
 813            fi
 814          fi
 815   fi
 816 ])
 817 AM_CONDITIONAL(USE_LIBIEC61883, [ test "x${HAVE_LIBIEC61883}" = xyes ] )
 818
 819 dnl *** shout2 ***
 820 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 821 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 822   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 823 ])
 824
 825 dnl *** soup ***
 826 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUP, true)
 827 AG_GST_CHECK_FEATURE(SOUP, [soup http client plugin (2.4)], souphttpsrc, [
 828   PKG_CHECK_MODULES(SOUP, libsoup-gnome-2.4 >= 2.3.2, [
 829     HAVE_SOUP="yes"
 830     AC_DEFINE(HAVE_LIBSOUP_GNOME, 1, [soup gnome integration])
 831   ],[
 832     PKG_CHECK_MODULES(SOUP, libsoup-2.4 >= 2.26.1, HAVE_SOUP="yes", [
 833       HAVE_SOUP="no"
 834     ])
 835   ])
 836   AC_SUBST(SOUP_CFLAGS)
 837   AC_SUBST(SOUP_LIBS)
 838 ])
 839
 840 dnl *** speex >= 1.0.4 or >= 1.1.5 ***
 841 dnl   1.1.4 and earlier were not API/ABI compatible with 1.0
 842 dnl   1.1.6 is the first to use a .pc/pkg-config file ***
 843 dnl   speex_jitter.h is 1.1.x only
 844 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 845 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 846   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 847   if test $HAVE_SPEEX = no
 848   then
 849     AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_bits_init, , speex/speex.h, [
 850       AC_CHECK_HEADER(speex/speex_jitter.h, [
 851         dnl speex 1.1.x :
 852         AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_encode_int, , speex/speex.h, [
 853           dnl speex 1.1.5 or + :
 854           HAVE_SPEEX="yes"
 855           SPEEX_LIBS="-lspeex"
 856           AC_SUBST(SPEEX_CFLAGS)
 857           AC_SUBST(SPEEX_LIBS)
 858         ],[
 859           HAVE_SPEEX="no"
 860         ])
 861       ],[
 862         dnl speex 1.0.x :
 863           AC_CHECK_DECL(SPEEX_GET_LOOKAHEAD, [
 864             dnl speex 1.0.4
 865             HAVE_SPEEX="yes"
 866             SPEEX_LIBS="-lspeex"
 867             AC_SUBST(SPEEX_CFLAGS)
 868             AC_SUBST(SPEEX_LIBS)
 869
 870             AC_DEFINE_UNQUOTED(SPEEX_1_0, 1,
 871               [defined if speex 1.0.x API detected])
 872         ],[
 873             HAVE_SPEEX="no"
 874             AC_MSG_NOTICE(You need at least 1.0.4 to compile the speex plugin)
 875         ], [
 876 #include <speex/speex.h>
 877         ])
 878       ])
 879     ])
 880   fi
 881 ])
 882
 883 dnl *** taglib ***
 884 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 885 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 886   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.5)
 887   if test "x$HAVE_CXX" != "xyes"; then
 888     USE_TAGLIB=false
 889     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 890   else
 891     dnl work around bug in taglib 1.5 headers, remove once there is a 1.6
 892     AS_CXX_COMPILER_FLAG([-Wno-attributes], [
 893         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS -Wno-attributes"
 894       ], [
 895         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS"
 896     ])
 897     AC_SUBST(TAGLIB_CXXFLAGS)
 898   fi
 899 ])
 900
 901 dnl *** vpx ***
 902 translit(dnm, m, l) AM_CONDITIONAL(USE_VPX, vpx)
 903 AG_GST_CHECK_FEATURE(VPX, [VPX decoder], vpx, [
 904   PKG_CHECK_MODULES(VPX, vpx >= 1.1.0, [HAVE_VPX="yes"], [HAVE_VPX="no"])
 905
 906   if test $HAVE_VPX = "yes"; then
 907     OLD_LIBS="$LIBS"
 908     OLD_CFLAGS="$CFLAGS"
 909     CFLAGS="$CFLAGS $VPX_CFLAGS"
 910     LIBS="$LIBS $VPX_LIBS"
 911     AC_CHECK_LIB(vpx, vpx_codec_vp8_cx_algo, [
 912       HAVE_VP8=yes
 913       AC_DEFINE(HAVE_VP8_ENCODER, 1, [Defined if the VP8 encoder is available])
 914     ])
 915     AC_CHECK_LIB(vpx, vpx_codec_vp8_dx_algo, [
 916       HAVE_VP8=yes
 917       AC_DEFINE(HAVE_VP8_DECODER, 1, [Defined if the VP8 decoder is available])
 918     ])
 919     LIBS="$OLD_LIBS"
 920     CFLAGS="$OLD_CFLAGS"
 921   fi
 922   AC_SUBST(VPX_LIBS)
 923   AC_SUBST(VPX_CFLAGS)
 924 ])
 925
 926 dnl *** wavpack ***
 927 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 928 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 929   PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.40.0, HAVE_WAVPACK=yes, [
 930     PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.20, [
 931       HAVE_WAVPACK=yes
 932       AC_DEFINE(WAVPACK_OLD_API, 1, [old wavpack API])
 933     ],[
 934       HAVE_WAVPACK=no
 935     ])
 936   ])
 937   AC_SUBST(WAVPACK_CFLAGS)
 938   AC_SUBST(WAVPACK_LIBS)
 939 ])
 940
 941 dnl *** qtdemux & matroska prefer to have zlib ***
 942 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 943 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for qtdemux/matroska],, [
 944   AG_GST_CHECK_LIBHEADER(ZLIB,
 945     z, uncompress,, zlib.h, [
 946     HAVE_ZLIB="yes"
 947     ZLIB_LIBS="-lz"
 948     AC_SUBST(ZLIB_LIBS)
 949   ])
 950 ])
 951
 952 dnl *** matroska prefers to have bz2 ***
 953 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
 954 AG_GST_CHECK_FEATURE(BZ2, [bz2 library for matroska ],, [
 955   AG_GST_CHECK_LIBHEADER(BZ2, bz2, BZ2_bzCompress, ,bzlib.h, BZ2_LIBS="-lbz2")
 956   AC_SUBST(BZ2_LIBS)
 957 ])
 958
 959 else
 960
 961 dnl not building plugins with external dependencies,
 962 dnl but we still need to set the conditionals
 963 AM_CONDITIONAL(USE_AALIB, false)
 964 AM_CONDITIONAL(USE_BZ2, false)
 965 AM_CONDITIONAL(USE_CAIRO, false)
 966 AM_CONDITIONAL(USE_CAIRO_GOBJECT, false)
 967 AM_CONDITIONAL(USE_DIRECTSOUND, false)
 968 AM_CONDITIONAL(USE_DV1394, false)
 969 AM_CONDITIONAL(USE_FLAC, false)
 970 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
 971 AM_CONDITIONAL(USE_GST_V4L2, false)
 972 AM_CONDITIONAL(USE_JACK, false)
 973 AM_CONDITIONAL(USE_JPEG, false)
 974 AM_CONDITIONAL(USE_LIBCACA, false)
 975 AM_CONDITIONAL(USE_LIBDV, false)
 976 AM_CONDITIONAL(USE_LIBIEC61883, false)
 977 AM_CONDITIONAL(USE_LIBPNG, false)
 978 AM_CONDITIONAL(USE_OSS, false)
 979 AM_CONDITIONAL(USE_OSS4, false)
 980 AM_CONDITIONAL(USE_OSX_AUDIO, false)
 981 AM_CONDITIONAL(USE_OSX_VIDEO, false)
 982 AM_CONDITIONAL(USE_PULSE, false)
 983 AM_CONDITIONAL(USE_SHOUT2, false)
 984 AM_CONDITIONAL(USE_SOUP, false)
 985 AM_CONDITIONAL(USE_SPEEX, false)
 986 AM_CONDITIONAL(USE_SUNAUDIO, false)
 987 AM_CONDITIONAL(USE_TAGLIB, false)
 988 AM_CONDITIONAL(USE_VPX, false)
 989 AM_CONDITIONAL(USE_WAVEFORM, false)
 990 AM_CONDITIONAL(USE_WAVPACK, false)
 991 AM_CONDITIONAL(USE_X, false)
 992 AM_CONDITIONAL(USE_XSHM, false)
 993 AM_CONDITIONAL(USE_XVIDEO, false)
 994 AM_CONDITIONAL(USE_ZLIB, false)
 995
 996 fi dnl of EXT plugins
 997
 998 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 999
1000 dnl Overview:
1001 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
1002 dnl GST_*:              flags shared by all built objects
1003 dnl GST_ALL_LDFLAGS:    linker flags shared by all
1004 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
1005 dnl GST_LT_LDFLAGS:     library versioning of our libraries
1006 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
1007
1008 dnl GST_OPTION_CFLAGS
1009 if test "x$USE_DEBUG" = xyes; then
1010    PROFILE_CFLAGS="-g"
1011 fi
1012 AC_SUBST(PROFILE_CFLAGS)
1013
1014 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
1015   dnl Define _only_ for git (not pre-releases or releases)
1016   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
1017 else
1018   DEPRECATED_CFLAGS=""
1019 fi
1020 AC_SUBST(DEPRECATED_CFLAGS)
1021
1022 dnl every flag in GST_OPTION_CFLAGS, GST_OPTION_CXXFLAGS and GST_OPTION_OBJCFLAGS can be overridden
1023 dnl at make time with e.g. make ERROR_CFLAGS=""
1024 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1025 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1026 GST_OPTION_OBJCFLAGS="\$(WARNING_OBJCFLAGS) \$(ERROR_OBJCFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1027 AC_SUBST(GST_OPTION_CFLAGS)
1028 AC_SUBST(GST_OPTION_CXXFLAGS)
1029 AC_SUBST(GST_OPTION_OBJCFLAGS)
1030
1031 dnl our libraries need to be versioned correctly
1032 AC_SUBST(GST_LT_LDFLAGS)
1033
1034 dnl FIXME: do we want to rename to GST_ALL_* ?
1035 dnl prefer internal headers to already installed ones
1036 dnl also add builddir include for enumtypes and marshal
1037 dnl add ERROR_CFLAGS, but overridable
1038 GST_CFLAGS="$GST_CFLAGS -DGST_USE_UNSTABLE_API"
1039 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS)"
1040 GST_OBJCFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_OBJCFLAGS)"
1041 GST_CFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
1042 AC_SUBST(GST_CFLAGS)
1043 AC_SUBST(GST_CXXFLAGS)
1044 AC_SUBST(GST_OBJCFLAGS)
1045 AC_SUBST(GST_LIBS)
1046
1047 dnl LDFLAGS really should only contain flags, not libs - they get added before
1048 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1049 GST_ALL_LDFLAGS="-no-undefined"
1050 AC_SUBST(GST_ALL_LDFLAGS)
1051
1052 dnl this really should only contain flags, not libs - they get added before
1053 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1054 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
1055 AC_SUBST(GST_PLUGIN_LDFLAGS)
1056
1057 dnl *** output files ***
1058
1059 dnl keep this alphabetic per directory, please
1060 AC_CONFIG_FILES(
1061 Makefile
1062 gst/Makefile
1063 gst/alpha/Makefile
1064 gst/apetag/Makefile
1065 gst/audiofx/Makefile
1066 gst/audioparsers/Makefile
1067 gst/auparse/Makefile
1068 gst/autodetect/Makefile
1069 gst/avi/Makefile
1070 gst/cutter/Makefile
1071 gst/deinterlace/Makefile
1072 gst/debugutils/Makefile
1073 gst/effectv/Makefile
1074 gst/equalizer/Makefile
1075 gst/flv/Makefile
1076 gst/goom/Makefile
1077 gst/goom2k1/Makefile
1078 gst/id3demux/Makefile
1079 gst/icydemux/Makefile
1080 gst/imagefreeze/Makefile
1081 gst/interleave/Makefile
1082 gst/isomp4/Makefile
1083 gst/law/Makefile
1084 gst/level/Makefile
1085 gst/matroska/Makefile
1086 gst/median/Makefile
1087 gst/monoscope/Makefile
1088 gst/multifile/Makefile
1089 gst/multipart/Makefile
1090 gst/replaygain/Makefile
1091 gst/rtp/Makefile
1092 gst/rtpmanager/Makefile
1093 gst/rtsp/Makefile
1094 gst/shapewipe/Makefile
1095 gst/smpte/Makefile
1096 gst/spectrum/Makefile
1097 gst/udp/Makefile
1098 gst/videobox/Makefile
1099 gst/videocrop/Makefile
1100 gst/videofilter/Makefile
1101 gst/videomixer/Makefile
1102 gst/wavenc/Makefile
1103 gst/wavparse/Makefile
1104 gst/flx/Makefile
1105 gst/y4m/Makefile
1106 ext/Makefile
1107 ext/aalib/Makefile
1108 ext/cairo/Makefile
1109 ext/dv/Makefile
1110 ext/flac/Makefile
1111 ext/gdk_pixbuf/Makefile
1112 ext/jack/Makefile
1113 ext/jpeg/Makefile
1114 ext/libcaca/Makefile
1115 ext/libpng/Makefile
1116 ext/pulse/Makefile
1117 ext/raw1394/Makefile
1118 ext/shout2/Makefile
1119 ext/soup/Makefile
1120 ext/speex/Makefile
1121 ext/taglib/Makefile
1122 ext/vpx/Makefile
1123 ext/wavpack/Makefile
1124 sys/Makefile
1125 sys/directsound/Makefile
1126 sys/oss/Makefile
1127 sys/oss4/Makefile
1128 sys/osxaudio/Makefile
1129 sys/osxvideo/Makefile
1130 sys/sunaudio/Makefile
1131 sys/v4l2/Makefile
1132 sys/waveform/Makefile
1133 sys/ximage/Makefile
1134 po/Makefile.in
1135 tests/Makefile
1136 tests/check/Makefile
1137 tests/examples/Makefile
1138 tests/examples/audiofx/Makefile
1139 tests/examples/cairo/Makefile
1140 tests/examples/equalizer/Makefile
1141 tests/examples/jack/Makefile
1142 tests/examples/level/Makefile
1143 tests/examples/pulse/Makefile
1144 tests/examples/rtp/Makefile
1145 tests/examples/shapewipe/Makefile
1146 tests/examples/spectrum/Makefile
1147 tests/examples/v4l2/Makefile
1148 tests/files/Makefile
1149 tests/icles/Makefile
1150 common/Makefile
1151 common/m4/Makefile
1152 m4/Makefile
1153 docs/Makefile
1154 docs/plugins/Makefile
1155 docs/version.entities
1156 pkgconfig/Makefile
1157 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1158 gst-plugins-good.spec
1159 )
1160
1161 dnl Create the config.h file for Visual Studio builds
1162 dnl Beware of spaces and /'s in some of the shell variable contents.
1163 sed \
1164     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"\n\n#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
1165     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
1166     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
1167     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
1168     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
1169     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
1170     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
1171     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
1172     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
1173     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
1174     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
1175     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
1176     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
1177     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
1178     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
1179     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
1180     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
1181     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
1182     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
1183     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1184     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1185     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1186     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
1187     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1188     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
1189     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1190     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1191     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1192     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
1193     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
1194     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1195     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
1196     -e "s/.* DEFAULT_AUDIOSRC$/#define DEFAULT_AUDIOSRC \"audiotestsrc\"/" \
1197     -e "s/.* DEFAULT_VIDEOSRC$/#define DEFAULT_VIDEOSRC \"videotestsrc\"/" \
1198     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1199     config.h.in >win32/common/config.h-new
1200
1201 AC_OUTPUT
1202
1203 AG_GST_OUTPUT_PLUGINS
1204 ORC_OUTPUT
1205