configure.ac

   1 AC_PREREQ(2.62)
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, cvs and prerelease does Werror too
   6 AC_INIT(GStreamer Editing Services, 1.5.0.1,
   7     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
   8     gstreamer-editing-services)
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.11 no-dist-gzip dist-xz tar-ustar subdir-objects])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([ges/ges-timeline.c])
  23
  24 dnl define the output header for config
  25 AC_CONFIG_HEADERS([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output with automake >= 1.11
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  35  [AM_DEFAULT_VERBOSITY=1
  36  AC_SUBST(AM_DEFAULT_VERBOSITY)])
  37
  38 dnl GES versioning, this is mostly informational
  39 GES_VERSION_MAJOR=$PACKAGE_VERSION_MAJOR
  40 GES_VERSION_MINOR=$PACKAGE_VERSION_MINOR
  41 GES_VERSION_MICRO=$PACKAGE_VERSION_MICRO
  42 GES_VERSION_NANO=$PACKAGE_VERSION_NANO
  43 AC_SUBST(GES_VERSION_MAJOR)
  44 AC_SUBST(GES_VERSION_MINOR)
  45 AC_SUBST(GES_VERSION_MICRO)
  46 AC_SUBST(GES_VERSION_NANO)
  47
  48 dnl our libraries and install dirs use major.minor as a version
  49 GST_API_VERSION=$GST_EDITING_SERVICES_VERSION_MAJOR.$GST_EDITING_SERVICES_VERSION_MINOR
  50 dnl we override it here if we need to for the release candidate of new series
  51 GST_API_VERSION=1.0
  52 AC_SUBST(GST_API_VERSION)
  53
  54 AS_LIBTOOL(GST, 0, 0, 0)
  55
  56 dnl *** required versions of GStreamer stuff ***
  57 GST_REQ=1.4.0
  58 GSTPB_REQ=1.4.0
  59
  60 dnl *** autotools stuff ****
  61
  62 dnl allow for different autotools
  63 AS_AUTOTOOLS_ALTERNATE
  64
  65 dnl Add parameters for aclocal
  66 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  67 AC_CONFIG_MACRO_DIR([m4])
  68
  69 dnl *** check for arguments to configure ***
  70
  71 AG_GST_ARG_DEBUG
  72 AG_GST_ARG_PROFILING
  73 AG_GST_ARG_VALGRIND
  74 AG_GST_ARG_GCOV
  75
  76 AG_GST_ARG_EXAMPLES
  77
  78 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  79 AG_GST_ARG_WITH_PACKAGE_NAME
  80 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  81
  82 AG_GST_PKG_CONFIG_PATH
  83
  84 dnl *** checks for platform ***
  85
  86 dnl * hardware/architecture *
  87
  88 dnl common/m4/gst-arch.m4
  89 dnl check CPU type
  90 AG_GST_ARCH
  91
  92 dnl Determine endianness
  93 AC_C_BIGENDIAN
  94
  95 dnl *** checks for programs ***
  96
  97 dnl find a compiler
  98 AC_PROG_CC
  99
 100 dnl determine c++ compiler
 101 AC_PROG_CXX
 102 dnl determine if c++ is available on this system
 103 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 104
 105 dnl check if the compiler supports '-c' and '-o' options
 106 AM_PROG_CC_C_O
 107
 108 dnl check if the compiler supports do while(0) macros
 109 AG_GST_CHECK_DOWHILE_MACROS
 110
 111 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 112 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 113
 114 dnl check for gobject-introspection
 115 GOBJECT_INTROSPECTION_CHECK([0.9.6])
 116
 117 dnl check for documentation tools
 118 AG_GST_DOCBOOK_CHECK
 119 GTK_DOC_CHECK([1.3])
 120 AS_PATH_PYTHON([2.1])
 121 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 122
 123 dnl check for python
 124 AM_PATH_PYTHON
 125 AC_MSG_CHECKING(for python >= 2.3)
 126 prog="
 127 import sys, string
 128 minver = (2,3,0,'final',0)
 129 if sys.version_info < minver:
 130   sys.exit(1)
 131 sys.exit(0)"
 132
 133 if $PYTHON -c "$prog" 1>&AC_FD_CC 2>&AC_FD_CC
 134 then
 135   HAVE_PYTHON=yes
 136   AC_MSG_RESULT(okay)
 137 else
 138   HAVE_PYTHON=no
 139   AC_MSG_RESULT(no python)
 140 fi
 141
 142 dnl check for pygobject
 143 AC_SUBST(PYGOBJECT_REQ, 4.22)
 144 PKG_CHECK_MODULES(PYGOBJECT, pygobject-3.0 >= $PYGOBJECT_REQ,
 145   [
 146     HAVE_PYGOBJECT=yes
 147   ], HAVE_PYGOBJECT=no)
 148
 149 AM_CONDITIONAL(WITH_PYTHON, [test "x$HAVE_PYGOBJECT" = "xyes"])
 150
 151 dnl check for pygobject
 152 PKG_CHECK_MODULES(GST_VALIDATE, gst-validate-1.0 >= 1.0.0.0,
 153   [
 154     HAVE_GST_VALIDATE=yes
 155     AC_DEFINE(HAVE_GST_VALIDATE, 1, [Define if build with gst-validate support])
 156   ], HAVE_GST_VALIDATE=no)
 157
 158 AC_SUBST(GST_VALIDATE_CFLAGS)
 159 AC_SUBST(GST_VALIDATE_LIBS)
 160 AM_CONDITIONAL(HAVE_GST_VALIDATE, [test "x$HAVE_GST_VALIDATE" = "xyes"])
 161
 162 dnl needed for scenarios definition files
 163 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 164 AC_SUBST(GST_PREFIX)
 165 GST_DATADIR="$GST_PREFIX/share"
 166 AC_DEFINE_UNQUOTED(GST_DATADIR, "$GST_DATADIR", [system wide data directory])
 167
 168
 169 dnl *** checks for libraries ***
 170
 171 dnl check for libm, for sin() etc.
 172 # LT_LIB_M
 173 # AC_SUBST(LIBM)
 174
 175 dnl *** checks for header files ***
 176
 177 AC_CHECK_HEADERS([unistd.h], HAVE_UNISTD_H=yes)
 178 AM_CONDITIONAL(HAVE_UNISTD_H, test "x$HAVE_UNISTD_H" = "xyes")
 179
 180 if test "x$HAVE_UNISTD_H" != "xyes"; then
 181   GST_PLUGINS_SELECTED=`echo $GST_PLUGINS_SELECTED | $SED -e s/festival//`
 182 fi
 183
 184 dnl *** checks for types/defines ***
 185
 186 dnl *** checks for structures ***
 187
 188 dnl *** checks for compiler characteristics ***
 189
 190 dnl *** checks for library functions ***
 191
 192 dnl *** checks for headers ***
 193
 194 dnl *** checks for dependency libraries ***
 195
 196 dnl GLib is required
 197 AG_GST_GLIB_CHECK([2.34.0])
 198
 199 PKG_CHECK_MODULES(GIO, gio-2.0 >= 2.16, HAVE_GIO=yes, HAVE_GIO=no)
 200 AC_SUBST(GIO_CFLAGS)
 201 AC_SUBST(GIO_LIBS)
 202
 203 dnl checks for gstreamer
 204 dnl uninstalled is selected preferentially -- see pkg-config(1)
 205 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 206 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 207 #AG_GST_CHECK_GST_GDP($GST_API_VERSION, [$GST_REQ], yes)
 208 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 209 AG_GST_CHECK_GST_CONTROLLER($GST_API_VERSION, [$GST_REQ], yes)
 210 AG_GST_CHECK_GST_PLUGINS_BASE($GST_API_VERSION, [$GSTPB_REQ], yes)
 211 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 212
 213 GSTPB_PLUGINS_DIR=`$PKG_CONFIG gstreamer-plugins-base-$GST_API_VERSION --variable pluginsdir`
 214 AC_SUBST(GSTPB_PLUGINS_DIR)
 215 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 216
 217 dnl check for gstreamer-pbutils
 218 PKG_CHECK_MODULES(GST_PBUTILS, gstreamer-pbutils-$GST_API_VERSION, HAVE_GST_PBUTILS="yes", HAVE_GST_PBUTILS="no")
 219 if test "x$HAVE_GST_PBUTILS" != "xyes"; then
 220   AC_ERROR([gst-pbutils is required for rendering support])
 221 fi
 222 AC_SUBST(GST_PBUTILS_LIBS)
 223 AC_SUBST(GST_PBUTILS_CFLAGS)
 224
 225 dnl check for gst-controller
 226 PKG_CHECK_MODULES(GST_CONTROLLER, gstreamer-controller-$GST_API_VERSION, HAVE_GST_CONTROLLER="yes", HAVE_GST_CONROLLER="no")
 227 if test "x$HAVE_GST_CONTROLLER" != "xyes"; then
 228   AC_ERROR([gst-controller is required for transition support])
 229 fi
 230 AC_SUBST(GST_CONTROLLER_LIBS)
 231 AC_SUBST(GST_CONTROLLER_CFLAGS)
 232
 233 dnl check for gstvideo
 234 PKG_CHECK_MODULES(GST_VIDEO, gstreamer-video-$GST_API_VERSION, HAVE_GST_VIDEO="yes", HAVE_GST_CONROLLER="no")
 235 if test "x$HAVE_GST_VIDEO" != "xyes"; then
 236   AC_ERROR([gst-video is required for transition support])
 237 fi
 238 AC_SUBST(GST_VIDEO_LIBS)
 239 AC_SUBST(GST_VIDEO_CFLAGS)
 240
 241 dnl Check for documentation xrefs
 242 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 243 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 244 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_API_VERSION`"
 245 AC_SUBST(GLIB_PREFIX)
 246 AC_SUBST(GST_PREFIX)
 247 AC_SUBST(GSTPB_PREFIX)
 248
 249 dnl pitivi formatter needs libxml
 250 PKG_CHECK_MODULES(XML, libxml-2.0, HAVE_LIBXML="yes", HAVE_LIBXML="no")
 251 if test "x$HAVE_LIBXML" != "xyes"; then
 252   AC_ERROR([libxml2 is required])
 253 fi
 254 AC_SUBST(XML_LIBS)
 255 AC_SUBST(XML_CFLAGS)
 256
 257 dnl GTK is optional and only used in examples
 258 HAVE_GTK=no
 259 HAVE_GTK_X11=no
 260 GTK2_REQ=2.14.0
 261 GTK3_REQ=2.91.3
 262 if test "x$BUILD_EXAMPLES" = "xyes"; then
 263   AC_MSG_CHECKING([which gtk+ version to compile examples against (optional)])
 264   AC_ARG_WITH([gtk],
 265     AC_HELP_STRING([--with-gtk=3.0|2.0],
 266                    [which gtk+ version to compile against (default: 2.0)]),
 267     [case "$with_gtk" in
 268         2.0) GTK_REQ=$GTK2_REQ ;;
 269         3.0) GTK_REQ=$GTK3_REQ ;;
 270         *) AC_MSG_ERROR([invalid gtk+ version specified]);;
 271     esac],
 272     [with_gtk=2.0
 273      GTK_REQ=$GTK2_REQ])
 274   AC_MSG_RESULT([$with_gtk (>= $GTK_REQ)])
 275   PKG_CHECK_MODULES(GTK, gtk+-$with_gtk >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 276   dnl some examples need gtk+-x11
 277   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-$with_gtk >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 278   AC_SUBST(GTK_LIBS)
 279   AC_SUBST(GTK_CFLAGS)
 280 fi
 281 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 282 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 283
 284 dnl building of benchmarks
 285 AC_ARG_ENABLE(benchmarks,
 286   AS_HELP_STRING([--disable-benchmarks],[disable building benchmarks apps]),
 287   [
 288     case "${enableval}" in
 289       yes) BUILD_BENCHMARKS=yes ;;
 290       no)  BUILD_BENCHMARKS=no ;;
 291       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-benchmarks) ;;
 292     esac
 293   ],
 294 [BUILD_BENCHMARKS=yes]) dnl Default value
 295 AM_CONDITIONAL(BUILD_BENCHMARKS, test "x$BUILD_BENCHMARKS" = "xyes")
 296
 297 dnl set license and copyright notice
 298 GST_LICENSE="LGPL"
 299 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 300 AC_SUBST(GST_LICENSE)
 301
 302 dnl define LIBDIR so we can inform people where we live
 303 AS_AC_EXPAND(LIBDIR, $libdir)
 304 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [library dir])
 305
 306 dnl set location of plugin directory
 307 AG_GST_SET_PLUGINDIR
 308
 309 dnl define an ERROR_CFLAGS Makefile variable
 310 AG_GST_SET_ERROR_CFLAGS($GST_GIT, [-Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef \
 311                                    -Wwrite-strings -Wformat-security -Wold-style-definition \
 312                                    -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return -Wno-multichar \
 313                                    -Wnested-externs])
 314
 315 dnl define an ERROR_CXXFLAGS Makefile variable
 316 AG_GST_SET_ERROR_CXXFLAGS($GST_GIT)
 317
 318 dnl define correct level for debugging messages
 319 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 320
 321 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 322
 323 dnl Overview:
 324 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 325 dnl GST_*:              flags shared by built objects to link against GStreamer
 326 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 327 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 328 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 329 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 330
 331 dnl GST_OPTION_CFLAGS
 332 if test "x$USE_DEBUG" = xyes; then
 333    PROFILE_CFLAGS="-g"
 334 fi
 335 AC_SUBST(PROFILE_CFLAGS)
 336
 337 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 338   dnl Define _only_ during CVS (not pre-releases or releases)
 339   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 340 else
 341   DEPRECATED_CFLAGS=""
 342 fi
 343 AC_SUBST(DEPRECATED_CFLAGS)
 344
 345 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 346 dnl at make time with e.g. make ERROR_CFLAGS=""
 347 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 348 GST_OPTION_CXXFLAGS="\$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 349 AC_SUBST(GST_OPTION_CFLAGS)
 350 AC_SUBST(GST_OPTION_CXXFLAGS)
 351
 352 dnl FIXME: do we want to rename to GST_ALL_* ?
 353 dnl prefer internal headers to already installed ones
 354 dnl also add builddir include for enumtypes and marshal
 355 dnl add GST_OPTION_CFLAGS, but overridable
 356 GST_CFLAGS="$GST_CFLAGS \$(GST_OPTION_CFLAGS) \$(ERROR_CFLAGS) -DGST_USE_UNSTABLE_API"
 357 GST_CXXFLAGS="$GST_CXXFLAGS \$(GST_OPTION_CXXFLAGS)"
 358 AC_SUBST(GST_CFLAGS)
 359 AC_SUBST(GST_CXXFLAGS)
 360 AC_SUBST(GST_LIBS)
 361
 362 dnl LDFLAGS really should only contain flags, not libs - they get added before
 363 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 364 GST_ALL_LDFLAGS="-no-undefined"
 365 AC_SUBST(GST_ALL_LDFLAGS)
 366
 367 dnl GST_LIB_LDFLAGS
 368 dnl linker flags shared by all libraries
 369 dnl LDFLAGS modifier defining exported symbols from built libraries
 370 GST_LIB_LDFLAGS=" -export-symbols-regex \^_*\(ges_\|GES_\).*"
 371 AC_SUBST(GST_LIB_LDFLAGS)
 372
 373 dnl *** output files ***
 374
 375 dnl po/Makefile.in
 376
 377 AC_CONFIG_FILES(
 378 Makefile
 379 ges/ges-version.h
 380 common/Makefile
 381 common/m4/Makefile
 382 gst-editing-services.spec
 383 m4/Makefile
 384 ges/Makefile
 385 tests/Makefile
 386 tests/check/Makefile
 387 tests/benchmarks/Makefile
 388 tests/examples/Makefile
 389 tests/validate/Makefile
 390 tests/validate/scenarios/Makefile
 391 tools/Makefile
 392 docs/Makefile
 393 docs/version.entities
 394 docs/libs/Makefile
 395 pkgconfig/Makefile
 396 pkgconfig/gst-editing-services.pc
 397 pkgconfig/gst-editing-services-uninstalled.pc
 398 bindings/Makefile
 399 bindings/python/Makefile
 400 bindings/python/gi/Makefile
 401 bindings/python/gi/overrides/Makefile
 402 bindings/python/examples/Makefile
 403 )
 404 AC_OUTPUT