configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/prerelease
   8 AC_INIT(GStreamer Base Plug-ins, 0.10.26.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-base)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl our libraries and install dirs use major.minor as a version
  36 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  37 dnl we override it here if we need to for the release candidate of new series
  38 GST_MAJORMINOR=0.10
  39 AC_SUBST(GST_MAJORMINOR)
  40
  41 dnl CURRENT, REVISION, AGE
  42 dnl - library source changed -> increment REVISION
  43 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  44 dnl - interfaces added -> increment AGE
  45 dnl - interfaces removed -> AGE = 0
  46 dnl sets GST_LT_LDFLAGS
  47 AS_LIBTOOL(GST, 19, 0, 19)
  48
  49 dnl FIXME: this macro doesn't actually work;
  50 dnl the generated libtool script has no support for the listed tags.
  51 dnl So this needs to be fixed first if we want to use this
  52 dnl AS_LIBTOOL_TAGS
  53
  54 AC_LIBTOOL_WIN32_DLL
  55 AM_PROG_LIBTOOL
  56
  57 dnl *** required versions of GStreamer stuff ***
  58 GST_REQ=0.10.26
  59
  60 dnl *** autotools stuff ****
  61
  62 dnl allow for different autotools
  63 AS_AUTOTOOLS_ALTERNATE
  64
  65 dnl Add parameters for aclocal
  66 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  67
  68 dnl set up gettext
  69 dnl the version check needs to stay here because autopoint greps for it
  70 AM_GNU_GETTEXT_VERSION([0.17])
  71 AM_GNU_GETTEXT([external])
  72 AG_GST_GETTEXT([gst-plugins-base-$GST_MAJORMINOR])
  73
  74 dnl *** check for arguments to configure ***
  75
  76 AG_GST_ARG_DEBUG
  77 AG_GST_ARG_PROFILING
  78 AG_GST_ARG_VALGRIND
  79 AG_GST_ARG_GCOV
  80
  81 AG_GST_ARG_EXAMPLES
  82
  83 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  84 AG_GST_ARG_WITH_PACKAGE_NAME
  85 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  86
  87 dnl let distro override plugin install helper path
  88 AC_ARG_WITH(install-plugins-helper,
  89   AC_HELP_STRING([--with-install-plugins-helper],
  90     [specify path of helper script to call to install plugins]),
  91   [
  92     case "${withval}" in
  93       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
  94       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
  95       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
  96     esac
  97   ],
  98   [
  99     dnl Default value
 100     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 101   ]
 102 )
 103 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 104 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 105     [plugin install helper script])
 106 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 107
 108 AG_GST_ARG_WITH_PLUGINS
 109
 110 AG_GST_ARG_ENABLE_EXTERNAL
 111
 112 AG_GST_ARG_ENABLE_EXPERIMENTAL
 113
 114 dnl *** checks for platform ***
 115
 116 dnl * hardware/architecture *
 117
 118 dnl common/m4/gst-arch.m4
 119 dnl check CPU type
 120 AG_GST_ARCH
 121
 122 dnl check for large file support
 123 dnl affected plugins must include config.h
 124 AC_SYS_LARGEFILE
 125
 126 dnl *** checks for programs ***
 127
 128 dnl find a compiler
 129 AC_PROG_CC
 130
 131 dnl check if the compiler supports '-c' and '-o' options
 132 AM_PROG_CC_C_O
 133
 134 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 135 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 136
 137 dnl check for gobject-introspection
 138 GOBJECT_INTROSPECTION_CHECK([0.6.3])
 139
 140 dnl check for documentation tools
 141 GTK_DOC_CHECK([1.3])
 142 AS_PATH_PYTHON([2.1])
 143 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 144
 145 dnl *** checks for libraries ***
 146
 147 dnl libm, for sin() etc.
 148 AC_CHECK_LIBM
 149 AC_SUBST(LIBM)
 150
 151 dnl *** checks for header files ***
 152
 153 dnl check if we have ANSI C header files
 154 AC_HEADER_STDC
 155
 156 dnl used in gst/ffmpegcolorspace/mem.c
 157 dnl FIXME: could be fixed by redefining av_malloc and av_free to GLib's
 158 AC_CHECK_HEADERS([malloc.h])
 159
 160 ac_cppflags_save="$CPPFLAGS"
 161 CPPFLAGS="`$PKG_CONFIG --cflags libxml-2.0`"
 162 AC_COMPILE_IFELSE(
 163   AC_LANG_PROGRAM([
 164 #include <libxml/HTMLparser.h>
 165                      ],[
 166 #ifndef LIBXML_HTML_ENABLED
 167 #error libxml2 has no HTML support
 168 #endif /* LIBXML_HTML_ENABLED */
 169                    ]), HAVE_LIBXML_HTML="yes", HAVE_LIBXML_HTML="no")
 170 CPPFLAGS="$ac_cppflags_save"
 171 AM_CONDITIONAL(HAVE_LIBXML_HTML, test "x$HAVE_LIBXML_HTML" = "xyes")
 172
 173 dnl used in gst/tcp
 174 AC_CHECK_HEADERS([sys/socket.h],
 175   HAVE_SYS_SOCKET_H="yes", HAVE_SYS_SOCKET_H="no")
 176 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 177
 178 dnl used in gst-libs/gst/rtsp
 179 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 180 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 181   WIN32_LIBS="-lws2_32"
 182   AC_SUBST(WIN32_LIBS)
 183 fi
 184
 185 dnl check for hstrerror, for gst-libs/gst/rtsp
 186 save_libs="$LIBS"
 187 AC_CHECK_FUNC(hstrerror, ,
 188     AC_CHECK_LIB(resolv, hstrerror, ,
 189         [AC_DEFINE(NO_HSTRERROR, 1,
 190              [Define if you have no native hstrerror() function.])]))
 191 HSTRERROR_LIBS=$LIBS
 192 AC_SUBST(HSTRERROR_LIBS)
 193 LIBS="$save_libs"
 194
 195 dnl used in gst-libs/gst/pbutils and associated unit test
 196 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h])
 197
 198 dnl ffmpegcolorspace includes _stdint.h
 199 dnl also, Windows does not have long long
 200 AX_CREATE_STDINT_H
 201
 202 dnl *** checks for functions ***
 203 AC_CHECK_FUNCS([localtime_r gmtime_r])
 204
 205 dnl *** checks for math functions ***
 206 LIBS_SAVE=$LIBS
 207 LIBS="$LIBS $LIBM"
 208 AC_CHECK_FUNCS(cbrt)
 209 LIBS=$LIBS_SAVE
 210
 211 dnl *** checks for types/defines ***
 212
 213 dnl Check for FIONREAD ioctl declaration
 214 dnl used in gst/tcp
 215 GST_CHECK_FIONREAD
 216
 217 dnl *** checks for structures ***
 218
 219 dnl *** checks for compiler characteristics ***
 220
 221 dnl *** checks for library functions ***
 222
 223 dnl check for fseeko()
 224 AC_FUNC_FSEEKO
 225
 226 dnl Check for fast float to int casting as defined in C99
 227 dnl used in gst-libs/gst/floatcast/floatcast.h
 228 save_libs=$LIBS
 229 LIBS="$LIBS $LIBM"
 230 AC_C99_FUNC_LRINT
 231 AC_C99_FUNC_LRINTF
 232 LIBS=$save_libs
 233
 234 dnl Check for a way to display the function name in debug output
 235 AG_GST_CHECK_FUNCTION
 236
 237 dnl *** checks for socket and nsl libraries ***
 238 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 239 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
 240
 241 dnl *** checks for dependency libraries ***
 242
 243 dnl GLib is required
 244 AG_GST_GLIB_CHECK([2.18])
 245
 246 dnl liboil is required
 247 PKG_CHECK_MODULES(LIBOIL, liboil-0.3 >= 0.3.14, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 248 if test "x$HAVE_LIBOIL" != "xyes"; then
 249   AC_ERROR([liboil-0.3.14 or later is required])
 250 fi
 251
 252 dnl checks for gstreamer
 253 dnl uninstalled is selected preferentially -- see pkg-config(1)
 254 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 255 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 256 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ], yes)
 257 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 258 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 259 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 260
 261 dnl Check for documentation xrefs
 262 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 263 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 264 AC_SUBST(GLIB_PREFIX)
 265 AC_SUBST(GST_PREFIX)
 266
 267 dnl GTK is optional and only used in examples
 268 PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.14.0, HAVE_GTK=yes, HAVE_GTK=no)
 269 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 270
 271 dnl some examples need gtk+-x11
 272 PKG_CHECK_MODULES(GTK_X11, gtk+-x11-2.0 >= 2.14.0,
 273     HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 274 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 275
 276 dnl *** set variables based on configure arguments ***
 277
 278 dnl set license and copyright notice
 279 GST_LICENSE="LGPL"
 280 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 281 AC_SUBST(GST_LICENSE)
 282
 283 dnl set location of plugin directory
 284 AG_GST_SET_PLUGINDIR
 285
 286 dnl define an ERROR_CFLAGS Makefile variable
 287 AG_GST_SET_ERROR_CFLAGS($GST_GIT)
 288
 289 dnl define correct level for debugging messages
 290 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 291
 292 dnl used in examples
 293 AG_GST_DEFAULT_ELEMENTS
 294
 295 dnl behaviour of speex based audio resampler
 296 AC_MSG_CHECKING(which audio resample format to use for integer)
 297 AC_ARG_WITH([audioresample_format],
 298         AS_HELP_STRING([--with-audioresample-format],[Which implementation should be used for integer audio resampling, int/float/auto, (default is auto)]),
 299         [ac_cv_audioresample_format=$withval], [ac_cv_audioresample_format=auto])dnl
 300 AC_MSG_RESULT($ac_cv_audioresample_format)
 301 case $ac_cv_audioresample_format in
 302   int)
 303     AC_DEFINE(AUDIORESAMPLE_FORMAT_INT,1,[The int implementation should be used for integer audio resampling])
 304     AC_SUBST(AUDIORESAMPLE_FORMAT_INT)
 305   ;;
 306   float)
 307     AC_DEFINE(AUDIORESAMPLE_FORMAT_FLOAT,1,[The float implementation should be used for integer audio resampling])
 308     AC_SUBST(AUDIORESAMPLE_FORMAT_FLOAT)
 309   ;;
 310   auto)
 311     AC_DEFINE(AUDIORESAMPLE_FORMAT_AUTO,1,[The implementation that should be used for integer audio resampling witll be benchmarked at runtime])
 312     AC_SUBST(AUDIORESAMPLE_FORMAT_AUTO)
 313 esac
 314 AM_CONDITIONAL(AUDIORESAMPLE_NEEDS_LIBOIL, test "$ac_cv_audioresample_format" = "auto")
 315
 316 dnl *** plug-ins to include ***
 317
 318 dnl these are all the gst plug-ins, compilable without additional libs
 319 AG_GST_CHECK_PLUGIN(adder)
 320 AG_GST_CHECK_PLUGIN(app)
 321 AG_GST_CHECK_PLUGIN(audioconvert)
 322 AG_GST_CHECK_PLUGIN(audiorate)
 323 AG_GST_CHECK_PLUGIN(audiotestsrc)
 324 AG_GST_CHECK_PLUGIN(ffmpegcolorspace)
 325 AG_GST_CHECK_PLUGIN(gdp)
 326 AG_GST_CHECK_PLUGIN(playback)
 327 AG_GST_CHECK_PLUGIN(audioresample)
 328 AG_GST_CHECK_PLUGIN(subparse)
 329 AG_GST_CHECK_PLUGIN(tcp)
 330 AG_GST_CHECK_PLUGIN(typefind)
 331 AG_GST_CHECK_PLUGIN(videotestsrc)
 332 AG_GST_CHECK_PLUGIN(videorate)
 333 AG_GST_CHECK_PLUGIN(videoscale)
 334 AG_GST_CHECK_PLUGIN(volume)
 335
 336 dnl check for gstreamer core features (subsystems)
 337 GST_CONFIGPATH=`$PKG_CONFIG --variable=includedir gstreamer-0.10`"/gst/gstconfig.h"
 338 AG_GST_PARSE_SUBSYSTEM_DISABLES($GST_CONFIGPATH)
 339 AM_CONDITIONAL(USE_XML, test $GST_DISABLE_XML != "1")
 340
 341 dnl disable plug-ins that require libxml2's HTML support if it is not available
 342 if test "x$HAVE_LIBXML_HTML" != "xyes"; then
 343   AG_GST_DISABLE_PLUGIN(subparse)
 344 fi
 345
 346 dnl disable plug-ins that require sys/socket.h if it is not available
 347 if test "x$HAVE_SYS_SOCKET_H" != "xyes"; then
 348   AG_GST_DISABLE_PLUGIN(tcp)
 349 fi
 350
 351 dnl iso-codes is optional, used by libgsttag
 352 AC_ARG_ENABLE(iso-codes,
 353 AC_HELP_STRING([--enable-iso-codes],[use iso-codes if installed]),
 354 [case "${enableval}" in
 355   yes) enable_iso_codes=yes ;;
 356   no)  enable_iso_codes=no ;;
 357   *) AC_MSG_ERROR(bad value ${enableval} for --enable-iso-codes) ;;
 358 esac
 359 ],
 360 [enable_iso_codes=yes]) dnl Default value
 361
 362 AC_MSG_CHECKING([whether to use iso-codes if they are available])
 363 if test "x$enable_iso_codes" = "xyes"; then
 364   AC_MSG_RESULT([yes])
 365   have_iso_codes=no
 366   AC_MSG_CHECKING([whether iso-codes are available on this system])
 367   if $PKG_CONFIG iso-codes; then
 368     AC_MSG_RESULT([yes])
 369     AC_MSG_CHECKING([whether iso-codes has iso-639 domain])
 370     if $PKG_CONFIG --variable=domains iso-codes | $GREP -q 639 ; then
 371       AC_MSG_RESULT([yes])
 372       AC_MSG_CHECKING([for iso-codes prefix])
 373       ISO_CODES_PREFIX=`$PKG_CONFIG --variable=prefix iso-codes`
 374       if test -d "$ISO_CODES_PREFIX"; then
 375         AC_MSG_RESULT([yes])
 376         AC_MSG_CHECKING([ISO_CODES_PREFIX])
 377         AC_MSG_RESULT([$ISO_CODES_PREFIX])
 378         ISO_639_DOMAIN="iso_639"
 379         AC_MSG_CHECKING([ISO_639_DOMAIN])
 380         AC_MSG_RESULT([$ISO_639_DOMAIN])
 381         have_iso_codes=yes
 382         AC_DEFINE([HAVE_ISO_CODES], [1], [make use of iso-codes for ISO-639])
 383         AC_DEFINE_UNQUOTED([ISO_CODES_PREFIX], ["$ISO_CODES_PREFIX"], [prefix])
 384         ISO_CODES_VERSION=`$PKG_CONFIG --modversion iso-codes`
 385         AC_DEFINE_UNQUOTED([ISO_CODES_VERSION], ["$ISO_CODES_VERSION"], [ ])
 386       else
 387         AC_MSG_RESULT([no])
 388       fi
 389     else
 390       AC_MSG_RESULT([no])
 391     fi
 392   else
 393     AC_MSG_RESULT([no])
 394   fi
 395   AM_CONDITIONAL(USE_ISO_CODES, test "x$have_iso_codes" = "xyes")
 396 else
 397   AC_MSG_RESULT([no (disabled via --disable-iso-codes)])
 398   AM_CONDITIONAL(USE_ISO_CODES, false)
 399 fi
 400
 401 dnl *** sys plug-ins ***
 402
 403 echo
 404 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 405 echo
 406
 407 dnl *** X11 ***
 408 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 409 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 410                   [ximagesink], [
 411   AC_PATH_XTRA
 412   ac_cflags_save="$CFLAGS"
 413   ac_cppflags_save="$CPPFLAGS"
 414   CFLAGS="$CFLAGS $X_CFLAGS"
 415   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 416
 417   dnl now try to find the HEADER
 418   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 419
 420   if test "x$HAVE_X" = "xno"
 421   then
 422     AC_MSG_NOTICE([cannot find X11 development files])
 423   else
 424     dnl this is much more than we want
 425     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 426     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 427     dnl it does not add the libs; therefore we add them here
 428     X_LIBS="$X_LIBS -lX11"
 429     AC_SUBST(X_CFLAGS)
 430     AC_SUBST(X_LIBS)
 431   fi
 432   AC_SUBST(HAVE_X)
 433   CFLAGS="$ac_cflags_save"
 434   CPPFLAGS="$ac_cppflags_save"
 435 ])
 436
 437 dnl Check for Xv extension
 438 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 439 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 440                   [xvimagesink], [
 441   AG_GST_CHECK_XV
 442 ])
 443
 444 dnl check for X Shm
 445 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 446 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 447   if test x$HAVE_X = xyes; then
 448     AC_CHECK_LIB(Xext, XShmAttach,
 449                  HAVE_XSHM="yes", HAVE_XSHM="no",
 450                  $X_LIBS)
 451     if test "x$HAVE_XSHM" = "xyes"; then
 452       XSHM_LIBS="-lXext"
 453     else
 454       dnl On AIX, it is in XextSam instead, but we still need -lXext
 455       AC_CHECK_LIB(XextSam, XShmAttach,
 456                    HAVE_XSHM="yes", HAVE_XSHM="no",
 457                    $X_LIBS)
 458       if test "x$HAVE_XSHM" = "xyes"; then
 459         XSHM_LIBS="-lXext -lXextSam"
 460       fi
 461     fi
 462   fi
 463 ], , [
 464   AC_SUBST(HAVE_XSHM)
 465   AC_SUBST(XSHM_LIBS)
 466 ])
 467
 468 dnl v4l/v4l2 checks have been moved down because they require X
 469
 470 dnl *** Video 4 Linux ***
 471 dnl for information about the header/define, see sys/v4l/gstv4lelement.h
 472 dnl renamed to GST_V4L in accordance with V4L2 below
 473 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L, true)
 474 AG_GST_CHECK_FEATURE(GST_V4L, [Video 4 Linux], video4linux, [
 475   AC_CHECK_DECL(VID_TYPE_MPEG_ENCODER, HAVE_GST_V4L="yes", HAVE_GST_V4L="no", [
 476 #include <sys/types.h>
 477 #define _LINUX_TIME_H
 478 #define __user
 479 #include <linux/videodev.h>
 480   ])
 481
 482   dnl we can build v4l without Xv, but then we won't have XOverlay support
 483   if test "x$HAVE_GST_V4L" = "xyes" -a "x$HAVE_XVIDEO" != "xyes"
 484   then
 485     AC_MSG_NOTICE([NO XVIDEO FOUND, VIDEO4LINUX WILL BE BUILT])
 486     AC_MSG_NOTICE([WITHOUT XOVERLAY SUPPORT])
 487   fi
 488 ])
 489
 490 # Optional gudev for device probing
 491 AC_ARG_WITH([gudev],
 492   AC_HELP_STRING([--with-gudev],
 493     [device detection with gudev]),
 494   [],
 495   [with_gudev=check])
 496 if test x$HAVE_GST_V4L = xyes; then
 497   if test x$with_gudev != xno; then
 498       PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 143 ],
 499           [ have_gudev=yes
 500             AC_DEFINE(HAVE_GUDEV, 1,
 501                [Whether gudev is available for device detection])
 502             AC_DEFINE([G_UDEV_API_IS_SUBJECT_TO_CHANGE], 1, [I know the API is subject to change.])
 503           ], [
 504           have_gudev=no
 505           ])
 506   else
 507     have_gudev=no
 508   fi
 509 fi
 510 AC_SUBST(GUDEV_CFLAGS)
 511 AC_SUBST(GUDEV_LIBS)
 512
 513 dnl *** ext plug-ins ***
 514 dnl keep this list sorted alphabetically !
 515
 516 if test "x$BUILD_EXTERNAL" = "xyes"; then
 517
 518 echo
 519 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 520 echo
 521
 522 dnl *** alsa ***
 523 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 524 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 525   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 526     HAVE_ALSA="yes"
 527     AC_SUBST(ALSA_CFLAGS)
 528     AC_SUBST(ALSA_LIBS)
 529   ], [
 530     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 531   ])
 532 ])
 533
 534 dnl *** CDParanoia ***
 535 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 536 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 537   AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 538                       cdda_open, -lm,
 539                       cdda_interface.h,
 540                       CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 541                       HEADER_DIR="no"
 542                       FOUND_CDPARANOIA="yes")
 543   if test "x$FOUND_CDPARANOIA" != "xyes";
 544   then
 545     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 546                         cdda_open, -lm,
 547                         cdda/cdda_interface.h,
 548                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 549                         HEADER_DIR="yes"
 550                         FOUND_CDPARANOIA="yes")
 551   fi
 552   if test "x$HEADER_DIR" = "xyes";
 553   then
 554     AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 555                        defined if cdda headers are in a cdda/ directory)
 556   fi
 557   if test "x$FOUND_CDPARANOIA" = "xyes";
 558   then
 559     AC_CHECK_LIB(cdda_paranoia,
 560                  paranoia_cachemodel_size,
 561                  : ,
 562                  HAVE_CDPARANOIA=no)
 563   fi
 564
 565   AC_SUBST(CDPARANOIA_LIBS)
 566 ])
 567 dnl FIXME : add second check somehow if that is necessary
 568 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 569 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 570
 571 dnl *** GNOME VFS ***
 572 translit(dnm, m, l) AM_CONDITIONAL(USE_GNOME_VFS, true)
 573 AG_GST_CHECK_FEATURE(GNOME_VFS, [GNOME VFS], gnomevfs, [
 574   PKG_CHECK_MODULES(GNOME_VFS, gnome-vfs-2.0, [
 575       HAVE_GNOME_VFS="yes"
 576       AC_SUBST(GNOME_VFS_CFLAGS)
 577       AC_SUBST(GNOME_VFS_LIBS)
 578       GNOME_VFS_MODULES_DIR="`$PKG_CONFIG --variable=modulesdir gnome-vfs-2.0`"
 579       AC_DEFINE_UNQUOTED(GNOME_VFS_MODULES_DIR, "$GNOME_VFS_MODULES_DIR",
 580              [The GnomeVFS modules directory.])
 581     ],[
 582       HAVE_GNOME_VFS="no"
 583     ]
 584     )
 585 ])
 586
 587 dnl *** ivorbis ***
 588 dnl AM_PATH_IVORBIS only takes two options
 589 translit(dnm, m, l) AM_CONDITIONAL(USE_IVORBIS, true)
 590 AG_GST_CHECK_FEATURE(IVORBIS, [integer vorbis plug-in], ivorbisdec, [
 591   AG_GST_PKG_CHECK_MODULES(IVORBIS, vorbisidec)
 592   if test $HAVE_IVORBIS = no
 593   then
 594     IVORBIS_LIBS=
 595     IVORBIS_CFLAGS=
 596     AC_CHECK_LIB(vorbisidec, vorbis_block_init,
 597       [IVORBIS_LIBS=-lvorbisidec
 598       HAVE_IVORBIS=yes
 599       case $host in
 600       arm-*-*)
 601         IVORBIS_CFLAGS="-D_ARM_ASSEM_ $IVORBIS_CFLAGS"
 602       esac
 603       ],
 604       HAVE_IVORBIS=no)
 605     AC_SUBST(IVORBIS_LIBS)
 606     AC_SUBST(IVORBIS_CFLAGS)
 607   fi
 608 ])
 609
 610 dnl *** libgio ***
 611 translit(dnm, m, l) AM_CONDITIONAL(USE_GIO, true)
 612 AG_GST_CHECK_FEATURE(GIO, [GIO library], gio, [
 613   PKG_CHECK_MODULES(GIO, gio-2.0 >= 2.16, [
 614     HAVE_GIO="yes"
 615     GIO_MODULE_DIR="`$PKG_CONFIG --variable=giomoduledir gio-2.0`"
 616     AC_DEFINE_UNQUOTED(GIO_MODULE_DIR, "$GIO_MODULE_DIR",
 617            [The GIO modules directory.])
 618     GIO_LIBDIR="`$PKG_CONFIG --variable=libdir gio-2.0`"
 619     AC_DEFINE_UNQUOTED(GIO_LIBDIR, "$GIO_LIBDIR",
 620            [The GIO library directory.])
 621   ], [
 622     HAVE_GIO="no"
 623     AC_MSG_RESULT(no)
 624   ])
 625   AC_SUBST(GIO_CFLAGS)
 626   AC_SUBST(GIO_LIBS)
 627   AC_SUBST(GIO_LDFLAGS)
 628 ])
 629
 630 dnl *** libvisual ***
 631 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 632 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 633   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 634   if test $HAVE_LIBVISUAL = no
 635   then
 636     AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0)
 637     if test x$HAVE_LIBVISUAL == xyes; then
 638       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.2`"
 639     fi
 640   else
 641     if test x$HAVE_LIBVISUAL == xyes; then
 642       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.4`"
 643     fi
 644   fi
 645   AC_MSG_NOTICE([libvisual pluginsdir: $LIBVIS_PLUGINSDIR])
 646   if test x$LIBVIS_PLUGINSDIR != x; then
 647     AC_DEFINE_UNQUOTED(LIBVISUAL_PLUGINSBASEDIR,
 648         "$LIBVIS_PLUGINSDIR",
 649         [directory in which the detected libvisual's plugins are located])
 650   fi
 651 ])
 652
 653 dnl *** ogg ***
 654 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 655 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 656   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 657   if test $HAVE_OGG = no
 658   then
 659     XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
 660     AS_SCRUB_INCLUDE(OGG_CFLAGS)
 661   fi
 662 ])
 663
 664 dnl *** pango ***
 665 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 666 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 667   AG_GST_PKG_CHECK_MODULES(PANGO, pango >= 1.16.0  pangocairo >= 1.16.0)
 668 ])
 669
 670 dnl *** theora ***
 671 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 672 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 673   dnl theora uses pkg-config version incorrectly, for pkg-config:
 674   dnl 1.0 < 1.0RCX < 1.0alphaX < 1.0betaX < 1.0.0
 675   dnl theoraenc and theoradec appeared in 1.0beta3
 676
 677   AG_GST_PKG_CHECK_MODULES(THEORA, theoradec theoraenc)
 678 ])
 679
 680 dnl *** vorbis ***
 681 dnl AM_PATH_VORBIS only takes two options
 682 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 683 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 684   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 685   if test $HAVE_VORBIS = no
 686   then
 687     XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
 688     AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
 689   fi
 690 ])
 691
 692 if test "x$HAVE_VORBIS" = "xyes"; then
 693   ac_cflags_save="$CFLAGS"
 694   AC_COMPILE_IFELSE(
 695     AC_LANG_PROGRAM([
 696 #include <vorbis/codec.h>
 697                      ],[
 698 vorbis_dsp_state *v;
 699
 700 vorbis_synthesis_restart (v);
 701                      ]), HAVE_VSR=yes, HAVE_VSR=no)
 702   if test "x$HAVE_VSR" = "xyes"; then
 703     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 704                        [defined if vorbis_synthesis_restart is present])
 705   fi
 706   CFLAGS="$ac_cflags_save"
 707 fi
 708
 709 else
 710
 711 dnl not building plugins with external dependencies,
 712 dnl but we still need to set the conditionals
 713 AM_CONDITIONAL(USE_ALSA, false)
 714 AM_CONDITIONAL(USE_CDPARANOIA, false)
 715 AM_CONDITIONAL(USE_GNOME_VFS, false)
 716 AM_CONDITIONAL(USE_GIO, false)
 717 AM_CONDITIONAL(USE_LIBVISUAL, false)
 718 AM_CONDITIONAL(USE_OGG, false)
 719 AM_CONDITIONAL(USE_PANGO, false)
 720 AM_CONDITIONAL(USE_THEORA, false)
 721 AM_CONDITIONAL(USE_VORBIS, false)
 722
 723 fi dnl of EXT plugins
 724
 725 dnl seeking needs freetype, so check for it here
 726 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 727   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 728 ])
 729 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 730 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 731 AC_SUBST(FT2_CFLAGS)
 732 AC_SUBST(FT2_LIBS)
 733
 734 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 735
 736 dnl Overview:
 737 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 738 dnl GST_*:              flags shared by built objects to link against GStreamer
 739 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 740 dnl                          (compare to other modules) or for i18n
 741 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 742 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 743 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 744 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 745
 746 dnl GST_OPTION_CFLAGS
 747 if test "x$USE_DEBUG" = xyes; then
 748    PROFILE_CFLAGS="-g"
 749 fi
 750 AC_SUBST(PROFILE_CFLAGS)
 751
 752 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 753   dnl Define _only_ when compiling a git version (not pre-releases or releases)
 754   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 755 else
 756   DEPRECATED_CFLAGS=""
 757 fi
 758 AC_SUBST(DEPRECATED_CFLAGS)
 759
 760 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 761 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 762 AC_SUBST(GST_OPTION_CFLAGS)
 763
 764 dnl our libraries need to be versioned correctly
 765 AC_SUBST(GST_LT_LDFLAGS)
 766
 767 dnl GST_PLUGINS_BASE_CFLAGS
 768 dnl prefer internal headers to already installed ones
 769 dnl also add builddir include for enumtypes and marshal
 770 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 771 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 772
 773 dnl FIXME: do we want to rename to GST_ALL_* ?
 774 dnl add GST_OPTION_CFLAGS, but overridable
 775 GST_CFLAGS="$GST_CFLAGS \$(GST_OPTION_CFLAGS)"
 776 AC_SUBST(GST_CFLAGS)
 777 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 778 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 779 AC_SUBST(GST_LIBS)
 780
 781 dnl LDFLAGS really should only contain flags, not libs - they get added before
 782 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 783 GST_ALL_LDFLAGS="-no-undefined"
 784 AC_SUBST(GST_ALL_LDFLAGS)
 785
 786 dnl GST_LIB_LDFLAGS
 787 dnl linker flags shared by all libraries
 788 dnl LDFLAGS modifier defining exported symbols from built libraries
 789 dnl (export _gst_foo but not __gst_foo)
 790 GST_LIB_LDFLAGS="-export-symbols-regex ^_?\(gst_\|Gst\|GST_\).*"
 791 AC_SUBST(GST_LIB_LDFLAGS)
 792
 793 dnl this really should only contain flags, not libs - they get added before
 794 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 795 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 796 AC_SUBST(GST_PLUGIN_LDFLAGS)
 797
 798 SHAVE_INIT([common],[enable])
 799
 800 dnl *** output files ***
 801
 802 AC_CONFIG_FILES(
 803 Makefile
 804 common/shave
 805 common/shave-libtool
 806 gst-plugins-base.spec
 807 gst/Makefile
 808 gst/adder/Makefile
 809 gst/app/Makefile
 810 gst/audioconvert/Makefile
 811 gst/audiorate/Makefile
 812 gst/audiotestsrc/Makefile
 813 gst/ffmpegcolorspace/Makefile
 814 gst/gdp/Makefile
 815 gst/playback/Makefile
 816 gst/audioresample/Makefile
 817 gst/subparse/Makefile
 818 gst/tcp/Makefile
 819 gst/typefind/Makefile
 820 gst/videotestsrc/Makefile
 821 gst/videorate/Makefile
 822 gst/videoscale/Makefile
 823 gst/volume/Makefile
 824 sys/Makefile
 825 sys/ximage/Makefile
 826 sys/xvimage/Makefile
 827 sys/v4l/Makefile
 828 ext/Makefile
 829 ext/alsa/Makefile
 830 ext/cdparanoia/Makefile
 831 ext/gnomevfs/Makefile
 832 ext/gio/Makefile
 833 ext/libvisual/Makefile
 834 ext/ogg/Makefile
 835 ext/pango/Makefile
 836 ext/theora/Makefile
 837 ext/vorbis/Makefile
 838 gst-libs/Makefile
 839 gst-libs/gst/Makefile
 840 gst-libs/gst/audio/Makefile
 841 gst-libs/gst/app/Makefile
 842 gst-libs/gst/cdda/Makefile
 843 gst-libs/gst/fft/Makefile
 844 gst-libs/gst/floatcast/Makefile
 845 gst-libs/gst/interfaces/Makefile
 846 gst-libs/gst/netbuffer/Makefile
 847 gst-libs/gst/riff/Makefile
 848 gst-libs/gst/rtp/Makefile
 849 gst-libs/gst/rtsp/Makefile
 850 gst-libs/gst/sdp/Makefile
 851 gst-libs/gst/tag/Makefile
 852 gst-libs/gst/pbutils/Makefile
 853 gst-libs/gst/video/Makefile
 854 tools/Makefile
 855 pkgconfig/Makefile
 856 pkgconfig/gstreamer-audio.pc
 857 pkgconfig/gstreamer-audio-uninstalled.pc
 858 pkgconfig/gstreamer-app.pc
 859 pkgconfig/gstreamer-app-uninstalled.pc
 860 pkgconfig/gstreamer-cdda.pc
 861 pkgconfig/gstreamer-cdda-uninstalled.pc
 862 pkgconfig/gstreamer-fft.pc
 863 pkgconfig/gstreamer-fft-uninstalled.pc
 864 pkgconfig/gstreamer-floatcast.pc
 865 pkgconfig/gstreamer-floatcast-uninstalled.pc
 866 pkgconfig/gstreamer-interfaces.pc
 867 pkgconfig/gstreamer-interfaces-uninstalled.pc
 868 pkgconfig/gstreamer-netbuffer.pc
 869 pkgconfig/gstreamer-netbuffer-uninstalled.pc
 870 pkgconfig/gstreamer-pbutils.pc
 871 pkgconfig/gstreamer-pbutils-uninstalled.pc
 872 pkgconfig/gstreamer-riff.pc
 873 pkgconfig/gstreamer-riff-uninstalled.pc
 874 pkgconfig/gstreamer-rtp.pc
 875 pkgconfig/gstreamer-rtp-uninstalled.pc
 876 pkgconfig/gstreamer-rtsp.pc
 877 pkgconfig/gstreamer-rtsp-uninstalled.pc
 878 pkgconfig/gstreamer-sdp.pc
 879 pkgconfig/gstreamer-sdp-uninstalled.pc
 880 pkgconfig/gstreamer-tag.pc
 881 pkgconfig/gstreamer-tag-uninstalled.pc
 882 pkgconfig/gstreamer-video.pc
 883 pkgconfig/gstreamer-video-uninstalled.pc
 884 pkgconfig/gstreamer-plugins-base.pc
 885 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 886 tests/Makefile
 887 tests/check/Makefile
 888 tests/examples/Makefile
 889 tests/examples/app/Makefile
 890 tests/examples/dynamic/Makefile
 891 tests/examples/seek/Makefile
 892 tests/examples/volume/Makefile
 893 tests/examples/snapshot/Makefile
 894 tests/examples/gio/Makefile
 895 tests/examples/v4l/Makefile
 896 tests/icles/Makefile
 897 docs/Makefile
 898 docs/design/Makefile
 899 docs/libs/Makefile
 900 docs/plugins/Makefile
 901 docs/version.entities
 902 po/Makefile.in
 903 common/Makefile
 904 common/m4/Makefile
 905 m4/Makefile
 906 )
 907
 908 dnl Create the config.h file for Visual Studio builds
 909 dnl Beware of spaces and /'s in some of the shell variable contents.
 910 sed \
 911     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 912     -e 's/.* GST_INSTALL_PLUGINS_HELPER/#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
 913     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 914     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 915     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 916     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 917     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
 918     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 919     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 920     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 921     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 922     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 923     -e 's/.* HAVE_ISO_CODES$/#undef HAVE_ISO_CODES/' \
 924     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
 925     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 926     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 927     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 928     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 929     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 930     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 931     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
 932     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 933     -e 's/.* ISO_CODES_PREFIX$/#undef ISO_CODES_PREFIX/' \
 934     -e 's/.* ISO_CODES_VERSION$/#undef ISO_CODES_VERSION/' \
 935     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 936     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 937     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
 938     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 939     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
 940     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 941     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 942     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 943     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.10"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.10"\n#endif/' \
 944     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
 945     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 946     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directaudiosink\"/" \
 947     -e "s/.* DEFAULT_VIDEOSINK$/#define DEFAULT_VIDEOSINK \"directdrawsink\"/" \
 948     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
 949     config.h.in >win32/common/config.h-new
 950
 951
 952
 953 AC_OUTPUT
 954
 955 AG_GST_OUTPUT_PLUGINS