configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, cvs and prerelease does Werror too
   6 AC_INIT(GStreamer, 0.10.8.1,
   7     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
   8     gstreamer)
   9
  10 dnl initialize automake
  11 AM_INIT_AUTOMAKE
  12
  13 dnl define PACKAGE_VERSION_* variables
  14 AS_VERSION
  15
  16 dnl check if this is a release version
  17 AS_NANO(GST_CVS="no", GST_CVS="yes")
  18
  19 dnl can autoconf find the source ?
  20 AC_CONFIG_SRCDIR([gst/gst.c])
  21
  22 dnl define the output header for config
  23 AM_CONFIG_HEADER([config.h])
  24
  25 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  26 AM_MAINTAINER_MODE
  27
  28 dnl sets host_* variables
  29 AC_CANONICAL_HOST
  30
  31 dnl our libraries and install dirs use major.minor as a version
  32 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  33 dnl we override it here for release candidates for a new series
  34 GST_MAJORMINOR=0.10
  35 AC_SUBST(GST_MAJORMINOR)
  36 AC_DEFINE_UNQUOTED(GST_MAJORMINOR, "$GST_MAJORMINOR",
  37   [library major.minor version])
  38
  39 dnl CURRENT, REVISION, AGE
  40 dnl - library source changed -> increment REVISION
  41 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  42 dnl - interfaces added -> increment AGE
  43 dnl - interfaces removed -> AGE = 0
  44 dnl sets GST_LT_LDFLAGS
  45 AS_LIBTOOL(GST, 8, 0, 8)
  46
  47 dnl FIXME: this macro doesn't actually work;
  48 dnl the generated libtool script has no support for the listed tags.
  49 dnl So this needs to be fixed first if we want to use this
  50 dnl AS_LIBTOOL_TAGS
  51
  52 AM_PROG_LIBTOOL
  53
  54 dnl *** autotools stuff ****
  55
  56 dnl allow for different autotools
  57 AS_AUTOTOOLS_ALTERNATE
  58
  59 dnl Add parameters for aclocal
  60 AC_SUBST(ACLOCAL_AMFLAGS, "-I common/m4")
  61
  62 dnl set up gettext
  63 dnl the version check needs to stay here because autopoint greps for it
  64 AM_GNU_GETTEXT_VERSION([0.11.5])
  65 AM_GNU_GETTEXT([external])
  66 GST_GETTEXT([gstreamer-$GST_MAJORMINOR])
  67
  68 dnl *** check for arguments to configure ***
  69
  70 dnl subsystems - can influence other decisions so needs to be high up
  71 dnl we need to AM_CONDITIONAL them here for automake 1.6.x compatibility
  72 GST_CHECK_SUBSYSTEM_DISABLE(GST_DEBUG,[debugging subsystem])
  73 AM_CONDITIONAL(GST_DISABLE_GST_DEBUG, test "x$GST_GST_DISABLE_DEBUG" = "xyes")
  74 GST_CHECK_SUBSYSTEM_DISABLE(LOADSAVE,[pipeline XML load/save])
  75 AM_CONDITIONAL(GST_DISABLE_LOADSAVE, test "x$GST_DISABLE_LOADSAVE" = "xyes")
  76 dnl define a substitution to use in docs/gst/gstreamer.types
  77 if test "x$GST_DISABLE_LOADSAVE" = "xyes"
  78 then
  79   GST_LOADSAVE_DOC_TYPES="%"
  80 else
  81   GST_LOADSAVE_DOC_TYPES=
  82 fi
  83 AC_SUBST(GST_LOADSAVE_DOC_TYPES)
  84 GST_CHECK_SUBSYSTEM_DISABLE(PARSE,[command-line parser])
  85 AM_CONDITIONAL(GST_DISABLE_PARSE, test "x$GST_DISABLE_PARSE" = "xyes")
  86 if test "x$GST_DISABLE_PARSE" = xyes; then
  87   AC_DEFINE(GST_DISABLE_PARSE, 1,
  88     [Define if pipeline parsing code is disabled])
  89 fi
  90 GST_CHECK_SUBSYSTEM_DISABLE(TRACE,[tracing subsystem])
  91 AM_CONDITIONAL(GST_DISABLE_TRACE, test "x$GST_DISABLE_TRACE" = "xyes")
  92 GST_CHECK_SUBSYSTEM_DISABLE(ALLOC_TRACE,[allocation tracing])
  93 AM_CONDITIONAL(GST_DISABLE_ALLOC_TRACE, test "x$GST_DISABLE_ALLOC_TRACE" = "xyes")
  94 GST_CHECK_SUBSYSTEM_DISABLE(REGISTRY,[plugin registry])
  95 AM_CONDITIONAL(GST_DISABLE_REGISTRY, test "x$GST_DISABLE_REGISTRY" = "xyes")
  96 dnl define a substitution to use in docs/gst/gstreamer.types
  97 if test "x$GST_DISABLE_REGISTRY" = "xyes"
  98 then
  99   GST_REGISTRY_DOC_TYPES="%"
 100 else
 101   GST_REGISTRY_DOC_TYPES=
 102 fi
 103 AC_SUBST(GST_REGISTRY_DOC_TYPES)
 104 GST_CHECK_SUBSYSTEM_DISABLE(ENUMTYPES,[enum types])
 105 AM_CONDITIONAL(GST_DISABLE_ENUMTYPES, test "x$GST_DISABLE_ENUMTYPES" = "xyes")
 106 GST_CHECK_SUBSYSTEM_DISABLE(INDEX,[index])
 107 AM_CONDITIONAL(GST_DISABLE_INDEX, test "x$GST_DISABLE_INDEX" = "xyes")
 108 GST_CHECK_SUBSYSTEM_DISABLE(NET,[network distribution])
 109 AM_CONDITIONAL(GST_DISABLE_NET, test "x$GST_DISABLE_NET" = "xyes")
 110 GST_CHECK_SUBSYSTEM_DISABLE(PLUGIN,[plugin])
 111 AM_CONDITIONAL(GST_DISABLE_PLUGIN, test "x$GST_DISABLE_PLUGIN" = "xyes")
 112 GST_CHECK_SUBSYSTEM_DISABLE(URI,[uri handlers])
 113 AM_CONDITIONAL(GST_DISABLE_URI, test "x$GST_DISABLE_URI" = "xyes")
 114
 115 GST_ARG_DEBUG
 116 GST_ARG_PROFILING
 117 GST_ARG_VALGRIND
 118 GST_ARG_GCOV
 119
 120 GST_ARG_EXAMPLES
 121
 122 GST_ARG_WITH_PKG_CONFIG_PATH
 123 GST_ARG_WITH_PACKAGE_NAME
 124 GST_ARG_WITH_PACKAGE_ORIGIN
 125
 126 dnl use a cache dir for storing element registry info.
 127 GST_CACHE_DIR=${localstatedir}/cache/gstreamer-$GST_MAJORMINOR
 128
 129 AC_ARG_WITH(cachedir,
 130   AC_HELP_STRING([--with-cachedir],
 131     [specify path to use for plugin and command completion registries]),
 132   [
 133     case "${withval}" in
 134       yes) AC_MSG_ERROR(bad value ${withval} for --with-cachedir) ;;
 135       no)  AC_MSG_ERROR(bad value ${withval} for --with-cachedir) ;;
 136       *)   GST_CACHE_DIR="${withval}" ;;
 137     esac
 138   ],
 139   [:]) dnl Default value
 140
 141 AS_AC_EXPAND(GST_CACHE_DIR, $GST_CACHE_DIR)
 142 AC_DEFINE_UNQUOTED(GST_CACHE_DIR, "$GST_CACHE_DIR", [Location of registry])
 143 AC_MSG_NOTICE(Using $GST_CACHE_DIR as registry cache dir)
 144
 145 dnl building of tests
 146 AC_ARG_ENABLE(tests,
 147   AC_HELP_STRING([--disable-tests], [disable building test apps]),
 148   [
 149     case "${enableval}" in
 150       yes) BUILD_TESTS=yes ;;
 151       no)  BUILD_TESTS=no ;;
 152       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 153     esac
 154   ],
 155 [BUILD_TESTS=yes]) dnl Default value
 156 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 157
 158 dnl tests known to fail
 159 AC_ARG_ENABLE(failing-tests,
 160   AC_HELP_STRING([--disable-failing-tests],
 161     [disable building tests known to fail]),
 162   [
 163     case "${enableval}" in
 164       yes) BUILD_FAILING_TESTS=yes ;;
 165       no)  BUILD_FAILING_TESTS=no ;;
 166       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-failing-tests) ;;
 167     esac
 168   ],
 169   [BUILD_FAILING_TESTS=no]) dnl Default value
 170 AM_CONDITIONAL(BUILD_FAILING_TESTS, test "x$BUILD_FAILING_TESTS" = "xyes")
 171 if test x$BUILD_FAILING_TESTS = xyes; then
 172   AC_MSG_WARN([building tests known to fail, use --disable-failing-tests to disable])
 173 else
 174   AC_MSG_WARN([Sissy ! By asking to not build the tests known to fail, you hereby waive your right to customer support.  If you do not agree with this EULA, please press Ctrl-C before the next line is printed.  By allowing the next line to be printed, you expressly acknowledge your acceptance of this EULA.])
 175 fi
 176
 177 dnl poison destroyed objects
 178 AC_ARG_ENABLE(poisoning,
 179   AC_HELP_STRING([--enable-poisoning],
 180     [enable poisoning of deallocated objects]),
 181   [
 182     case "${enableval}" in
 183       yes) USE_POISONING=yes ;;
 184       no)  USE_POISONING=no ;;
 185       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-poisoning) ;;
 186     esac
 187   ],
 188   [USE_POISONING=no]) dnl Default value
 189 if test "x$USE_POISONING" = xyes; then
 190   AC_DEFINE(USE_POISONING, 1,
 191     [Define if we should poison deallocated memory])
 192 fi
 193
 194 dnl *** checks for platform ***
 195
 196 dnl * hardware/architecture *
 197
 198 dnl common/m4/gst-arch.m4
 199 dnl check CPU type
 200 GST_ARCH
 201 dnl substitution for win32/common/config.h
 202 HOST_CPU=$host_cpu
 203 AC_SUBST(HOST_CPU)
 204
 205 dnl common/m4/gst-arch.m4
 206 dnl check for unaligned access
 207 GST_UNALIGNED_ACCESS
 208 dnl create a configure variable for gst/gstconfig.h
 209 if test x${as_cv_unaligned_access} = xyes ; then
 210   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 1"
 211 else
 212   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 0"
 213 fi
 214 AC_SUBST(GST_HAVE_UNALIGNED_ACCESS_DEFINE)
 215
 216 dnl * software *
 217
 218 dnl check for large file support
 219 dnl affected plugins must include config.h
 220 AC_SYS_LARGEFILE
 221
 222 dnl HAVE_WIN32 currently means "disable POSIXisms".
 223 case "$host" in
 224   *-*-mingw*)
 225     AC_DEFINE_UNQUOTED(HAVE_WIN32, 1, [Defined if compiling for Windows])
 226     ;;
 227   *)
 228     ;;
 229 esac
 230
 231 dnl *** checks for programs ***
 232
 233 dnl find a compiler
 234 AC_PROG_CC
 235
 236 dnl find an assembler
 237 AM_PROG_AS
 238
 239 dnl we use awk in the bison version check
 240 AC_PROG_AWK
 241
 242 dnl we require bison for building the parser
 243 dnl FIXME: check if AC_PROG_YACC is suitable here
 244 dnl FIXME: make precious
 245 AC_PATH_PROG(BISON_PATH, bison, no)
 246 if test x$BISON_PATH = xno; then
 247   AC_MSG_ERROR(Could not find bison)
 248 fi
 249
 250 dnl check bison version
 251 AC_MSG_CHECKING([bison version])
 252
 253 if $BISON_PATH --version | head -n 1 | $AWK '{ if ($4 < 1.35) exit 1; else exit 0;}';
 254 then
 255   AC_MSG_RESULT([ok])
 256 else
 257   AC_MSG_RESULT([too old.])
 258   AC_MSG_ERROR([Your bison version is too old, v1.35 or later is required.])
 259 fi
 260
 261 dnl we require flex for building the parser
 262 dnl FIXME: check if AC_PROG_LEX is suitable here
 263 AC_PATH_PROG(FLEX_PATH, flex, no)
 264 if test x$FLEX_PATH = xno; then
 265   AC_MSG_ERROR(Could not find flex)
 266 fi
 267
 268 dnl Perl is used in building documentation
 269 AC_PATH_PROG(PERL_PATH, perl, no)
 270 if test x$PERL_PATH = xno; then
 271   AC_MSG_ERROR(Could not find perl)
 272 fi
 273
 274 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 275 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 276
 277 dnl check for documentation tools
 278 GST_DOCBOOK_CHECK
 279 GTK_DOC_CHECK([1.3])
 280 AS_PATH_PYTHON([2.1])
 281 GST_PLUGIN_DOCS([1.3],[2.1])
 282
 283 dnl *** checks for libraries ***
 284
 285 dnl For interactive UNIX (a Sun thing)
 286 dnl FIXME: this adds -lcposix to LIBS, but I doubt we use LIBS
 287 AC_ISC_POSIX
 288
 289 dnl *** checks for header files ***
 290
 291 dnl check if we have ANSI C header files
 292 AC_HEADER_STDC
 293
 294 dnl Check for ucontext.h
 295 AC_CHECK_HEADERS([ucontext.h])
 296 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 297 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 298 AC_CHECK_HEADERS([process.h])
 299
 300 dnl *** checks for types/defines ***
 301
 302 dnl *** checks for structures ***
 303
 304 dnl *** checks for compiler characteristics ***
 305
 306 dnl make sure we can use "inline" from C code
 307 AC_C_INLINE
 308
 309 OPT_CFLAGS=
 310 dnl Check for some compiler flags that optimize our code.
 311 if test "x$GCC" = xyes; then
 312   AS_COMPILER_FLAG(-fno-common, OPT_CFLAGS="$OPT_CFLAGS -fno-common")
 313 fi
 314
 315 dnl FIXME: decide what kind of flag this is, maybe it's not an optimization
 316 dnl flag
 317 dnl check if we should use -Wa,-mregnames on PowerPC, so we can use
 318 dnl symbolic register names in inline asm
 319 if test x$HAVE_CPU_PPC = xyes ; then
 320   AS_COMPILER_FLAG(["-Wa,-mregnames"],
 321     [OPT_CFLAGS="$OPT_CFLAGS -Wa,-mregnames"])
 322 fi
 323
 324 dnl *** checks for library functions ***
 325
 326 AC_CHECK_FUNCS([sigaction])
 327
 328 dnl we use fork in the registry code
 329 AC_CHECK_FUNCS([fork])
 330
 331 dnl check for fseeko()
 332 AC_FUNC_FSEEKO
 333 dnl check for ftello()
 334 AC_CHECK_FUNCS([ftello])
 335
 336 AC_CHECK_FUNCS([fgetpos])
 337 AC_CHECK_FUNCS([fsetpos])
 338
 339 dnl check for mmap()
 340 AC_FUNC_MMAP
 341 AM_CONDITIONAL(HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 342
 343 dnl Check for a way to display the function name in debug output
 344 GST_CHECK_FUNCTION
 345
 346 dnl test for register_printf_function
 347 AC_CHECK_FUNC(register_printf_function,
 348   [
 349     GST_PRINTF_EXTENSION_FORMAT_DEFINE="#define GST_PTR_FORMAT \"P\""
 350     AC_DEFINE(HAVE_PRINTF_EXTENSION, 1,
 351       [Defined if we have register_printf_function ()])
 352   ],
 353   GST_PRINTF_EXTENSION_FORMAT_DEFINE="#define GST_PTR_FORMAT \"p\""
 354 )
 355 AC_SUBST(GST_PRINTF_EXTENSION_FORMAT_DEFINE)
 356
 357 dnl test if we have dladdr(); we use it for debugging; see gst/gstinfo.c
 358 save_cflags="$CFLAGS"
 359 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 360 AC_CHECK_LIB(dl, dladdr,
 361    AC_DEFINE(HAVE_DLADDR, 1,
 362              [Defined if we have dladdr ()]))
 363 CFLAGS="$save_cflags"
 364
 365 dnl *** checks for dependancy libraries ***
 366
 367 dnl GLib
 368
 369 GST_GLIB_CHECK([2.8])
 370
 371 dnl Guess we need to keep this around until 0.11
 372 GST_HAVE_GLIB_2_8_DEFINE="#define GST_HAVE_GLIB_2_8 1"
 373 AC_SUBST(GST_HAVE_GLIB_2_8_DEFINE)
 374
 375 dnl Check for glib2 without extra fat, useful for the unversioned tool frontends
 376 PKG_CHECK_MODULES(GLIB_ONLY, glib-2.0 >= $GLIB_REQ)
 377
 378 dnl libxml 2, which is/should be optional (FIXME)
 379 if test "x$GST_DISABLE_LOADSAVE" = "xyes" && \
 380    test "x$GST_DISABLE_REGISTRY" = "xyes"
 381 then
 382   AC_MSG_NOTICE([Registry and load/save are disabled, not checking for libxml2])
 383 else
 384   dnl check for libxml2 with minimum req version
 385   GST_LIBXML2_CHECK(2.4.9)
 386 fi
 387
 388 dnl check for "check", unit testing library/header
 389 AM_PATH_CHECK(0.9.2,
 390     [
 391         HAVE_CHECK=yes
 392         AC_MSG_NOTICE(CHECK_CFLAGS: $CHECK_CFLAGS)
 393         AC_MSG_NOTICE(CHECK_LIBS: $CHECK_LIBS)
 394     ],
 395     HAVE_CHECK=no)
 396 AM_CONDITIONAL(HAVE_CHECK, test "x$HAVE_CHECK" = "xyes")
 397
 398 dnl *** set variables based on configure arguments
 399
 400 dnl set license and copyright notice
 401 GST_LICENSE="LGPL"
 402 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 403 AC_SUBST(GST_LICENSE)
 404
 405 dnl define LIBDIR so we can inform people where we live
 406 AS_AC_EXPAND(LIBDIR, $libdir)
 407 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [library dir])
 408
 409 dnl set location of plugin directory
 410 GST_SET_PLUGINDIR
 411
 412 dnl FIXME: add LIBXML_PKG here
 413 GST_PKG_DEPS="glib-2.0, gobject-2.0, gmodule-2.0, gthread-2.0"
 414 AC_SUBST(GST_PKG_DEPS)
 415
 416 dnl define an ERROR_CFLAGS Makefile variable
 417 GST_SET_ERROR_CFLAGS($GST_CVS)
 418
 419 dnl define correct level for debugging messages
 420 GST_SET_LEVEL_DEFAULT($GST_CVS)
 421
 422 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 423
 424 dnl Overview:
 425 dnl GST_OPTION_CFLAGS:  common cflags for profiling, debugging, errors, ...
 426 dnl GST_ALL_*:          vars shared by all built objects
 427 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 428 dnl GST_OBJ_*:          additional vars to link to the core library
 429 dnl                     include GST_ALL_*
 430 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 431 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 432
 433 dnl GST_OPTION_CFLAGS
 434 if test "x$USE_DEBUG" = xyes; then
 435    PROFILE_CFLAGS="-g"
 436 fi
 437 AC_SUBST(PROFILE_CFLAGS)
 438
 439 dnl if gcov is used, we do not want default -O2 CFLAGS
 440 if test "x$GST_GCOV_ENABLED" = "xyes"
 441 then
 442   CFLAGS="-O0"
 443   AC_SUBST(CFLAGS)
 444   CXXFLAGS="-O0"
 445   AC_SUBST(CXXFLAGS)
 446   FFLAGS="-O0"
 447   AC_SUBST(FFLAGS)
 448   CCASFLAGS="-O0"
 449   AC_SUBST(CCASFLAGS)
 450   AC_MSG_NOTICE([gcov enabled, setting CFLAGS and friends to $CFLAGS])
 451 fi
 452
 453 DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 454 AC_SUBST(DEPRECATED_CFLAGS)
 455
 456 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 457 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 458 AC_SUBST(GST_OPTION_CFLAGS)
 459
 460 dnl GST_ALL_*
 461 dnl vars common to for all internal objects (core libs, elements, applications)
 462 dnl CFLAGS:
 463 dnl - XML needs to be added because xmlPtr is used in core
 464 dnl - src and build dirs need to be added because every piece that gets built
 465 dnl   will need the GStreamer source and generated headers
 466 dnl LIBS: XML doesn't need to be added because we don't explicitly use symbols
 467 dnl       from LibXML except for in the core library
 468 GST_ALL_CFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir) $GLIB_CFLAGS $XML_CFLAGS \$(GST_OPTION_CFLAGS)"
 469 dnl FIXME: check if LTLIBINTL is needed everywhere
 470 dnl I presume it is given that it contains the symbols that _() stuff maps to
 471 GST_ALL_LIBS="$GLIB_LIBS $LTLIBINTL \$(GCOV_LIBS)"
 472 dnl LDFLAGS really should only contain flags, not libs - they get added before
 473 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 474 GST_ALL_LDFLAGS="-no-undefined"
 475
 476 AC_SUBST(GST_ALL_CFLAGS)
 477 AC_SUBST(GST_ALL_LIBS)
 478 AC_SUBST(GST_ALL_LDFLAGS)
 479
 480 dnl GST_LIB_LDFLAGS
 481 dnl linker flags shared by all libraries
 482 dnl LDFLAGS modifier defining exported symbols from built libraries
 483 GST_LIB_LDFLAGS="-export-symbols-regex [_]*\(gst_\|Gst\|GST_\).*"
 484 AC_SUBST(GST_LIB_LDFLAGS)
 485
 486 dnl GST_OBJ_*
 487 dnl default vars for all internal objects built on libgstreamer
 488 dnl includes GST_ALL_*
 489 GST_OBJ_CFLAGS="\$(GST_ALL_CFLAGS)"
 490 GST_OBJ_LIBS="\$(top_builddir)/gst/libgstreamer-$GST_MAJORMINOR.la \$(GST_ALL_LIBS)"
 491 AC_SUBST(GST_OBJ_CFLAGS)
 492 AC_SUBST(GST_OBJ_LIBS)
 493
 494 dnl GST_PLUGIN_LDFLAGS
 495 dnl LDFLAGS for plugins; includes GST_ALL_LDFLAGS
 496 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 497 AC_SUBST(GST_PLUGIN_LDFLAGS, "$GST_PLUGIN_LDFLAGS")
 498
 499 AC_CONFIG_FILES(
 500 Makefile
 501 gst/Makefile
 502 gst/gstconfig.h
 503 gst/gstversion.h
 504 gst/parse/Makefile
 505 libs/Makefile
 506 libs/gst/Makefile
 507 libs/gst/base/Makefile
 508 libs/gst/check/Makefile
 509 libs/gst/controller/Makefile
 510 libs/gst/dataprotocol/Makefile
 511 libs/gst/net/Makefile
 512 plugins/Makefile
 513 plugins/indexers/Makefile
 514 plugins/elements/Makefile
 515 po/Makefile.in
 516 tests/Makefile
 517 tests/benchmarks/Makefile
 518 tests/check/Makefile
 519 tests/misc/Makefile
 520 tests/examples/Makefile
 521 tests/examples/controller/Makefile
 522 tests/examples/helloworld/Makefile
 523 tests/examples/launch/Makefile
 524 tests/examples/metadata/Makefile
 525 tests/examples/queue/Makefile
 526 tests/examples/typefind/Makefile
 527 tests/examples/xml/Makefile
 528 tools/Makefile
 529 common/Makefile
 530 common/m4/Makefile
 531 docs/Makefile
 532 docs/design/Makefile
 533 docs/faq/Makefile
 534 docs/gst/Makefile
 535 docs/gst/gstreamer.types
 536 docs/libs/Makefile
 537 docs/plugins/Makefile
 538 docs/manual/Makefile
 539 docs/pwg/Makefile
 540 docs/slides/Makefile
 541 docs/xsl/Makefile
 542 docs/version.entities
 543 win32/common/config.h
 544 pkgconfig/Makefile
 545 stamp.h
 546 pkgconfig/gstreamer.pc
 547 pkgconfig/gstreamer-uninstalled.pc
 548 pkgconfig/gstreamer-base.pc
 549 pkgconfig/gstreamer-base-uninstalled.pc
 550 pkgconfig/gstreamer-check.pc
 551 pkgconfig/gstreamer-check-uninstalled.pc
 552 pkgconfig/gstreamer-controller.pc
 553 pkgconfig/gstreamer-controller-uninstalled.pc
 554 pkgconfig/gstreamer-dataprotocol.pc
 555 pkgconfig/gstreamer-dataprotocol-uninstalled.pc
 556 pkgconfig/gstreamer-net.pc
 557 pkgconfig/gstreamer-net-uninstalled.pc
 558 gstreamer.spec
 559 )
 560
 561 AC_OUTPUT