configure.ac

   1 AC_PREREQ([2.68])
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/prerelease
   8 AC_INIT([GStreamer Base Plug-ins],[1.3.0.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gst-plugins-base])
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.11 no-dist-gzip dist-xz tar-ustar subdir-objects])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  23
  24 dnl define the output header for config
  25 AC_CONFIG_HEADERS([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output with automake >= 1.11
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  35   [AM_DEFAULT_VERBOSITY=1
  36    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  37
  38 dnl our libraries and install dirs use GST_API_VERSION in the filename
  39 dnl to allow side-by-side installation of different API versions
  40 GST_API_VERSION=1.0
  41 AC_SUBST(GST_API_VERSION)
  42 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  43   [GStreamer API Version])
  44
  45 dnl CURRENT, REVISION, AGE
  46 dnl - library source changed -> increment REVISION
  47 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  48 dnl - interfaces added -> increment AGE
  49 dnl - interfaces removed -> AGE = 0
  50 dnl
  51 dnl Keep CURRENT as MINOR * 100 + MICRO
  52 dnl Ex : 1.0.0 => 0
  53 dnl      1.0.3 => 3
  54 dnl      1.1.0 => 100
  55 dnl      1.2.5 => 205
  56 dnl      1.10.9 (who knows) => 1009
  57 dnl
  58 dnl sets GST_LT_LDFLAGS
  59 AS_LIBTOOL(GST, 300, 0, 300)
  60
  61 dnl *** required versions of GStreamer stuff ***
  62 GST_REQ=1.3.0.1
  63
  64 dnl *** autotools stuff ****
  65
  66 dnl allow for different autotools
  67 AS_AUTOTOOLS_ALTERNATE
  68
  69 dnl Add parameters for aclocal
  70 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  71
  72 dnl set up gettext
  73 dnl the version check needs to stay here because autopoint greps for it
  74 AM_GNU_GETTEXT_VERSION([0.17])
  75 AM_GNU_GETTEXT([external])
  76 AG_GST_GETTEXT([gst-plugins-base-$GST_API_VERSION])
  77
  78 dnl *** check for arguments to configure ***
  79
  80 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  81
  82 AG_GST_ARG_DEBUG
  83 AG_GST_ARG_PROFILING
  84 AG_GST_ARG_VALGRIND
  85 AG_GST_ARG_GCOV
  86
  87 AG_GST_ARG_EXAMPLES
  88
  89 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  90 AG_GST_ARG_WITH_PACKAGE_NAME
  91 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  92
  93 AG_GST_PKG_CONFIG_PATH
  94
  95 dnl let distro override plugin install helper path
  96 AC_ARG_WITH(install-plugins-helper,
  97   AS_HELP_STRING([--with-install-plugins-helper],[specify path of helper script to call to install plugins]),
  98   [
  99     case "${withval}" in
 100       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 101       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 102       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
 103     esac
 104   ],
 105   [
 106     dnl Default value
 107     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 108   ]
 109 )
 110 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 111 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 112     [plugin install helper script])
 113 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 114
 115 AG_GST_ARG_WITH_PLUGINS
 116
 117 AG_GST_ARG_ENABLE_EXTERNAL
 118
 119 AG_GST_ARG_ENABLE_EXPERIMENTAL
 120
 121 dnl *** checks for platform ***
 122 AG_GST_PLATFORM
 123
 124 dnl * hardware/architecture *
 125
 126 dnl common/m4/gst-arch.m4
 127 dnl check CPU type
 128 AG_GST_ARCH
 129
 130 dnl check for large file support
 131 dnl affected plugins must include config.h
 132 AC_SYS_LARGEFILE
 133
 134 dnl *** checks for programs ***
 135
 136 dnl find a compiler
 137 AC_PROG_CC
 138 AC_PROG_CC_STDC
 139
 140 dnl check if the compiler supports '-c' and '-o' options
 141 AM_PROG_CC_C_O
 142
 143 dnl determine if c++ is available on this system
 144 AC_PROG_CXX
 145 dnl CXX may be set to some default even if no c++ compiler is available
 146 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 147 AC_LANG_PUSH([C++])
 148 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ class Foo { int bar; };]], [[]])],[working_cxx=yes],[working_cxx=no])
 149 AC_LANG_POP([C++])
 150 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 151 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 152
 153 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 154 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 155
 156 dnl check for gobject-introspection
 157 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 158
 159 dnl check for documentation tools
 160 GTK_DOC_CHECK([1.12])
 161 AG_GST_PLUGIN_DOCS([1.12])
 162
 163 dnl *** checks for libraries ***
 164
 165 dnl libm, for sin() etc.
 166 LT_LIB_M
 167 AC_SUBST(LIBM)
 168
 169 dnl *** checks for header files ***
 170
 171 dnl check if we have ANSI C header files
 172 AC_HEADER_STDC
 173
 174 dnl check for GCC specific SSE headers
 175 dnl these are used by the speex resampler code
 176 AC_CHECK_HEADERS([xmmintrin.h emmintrin.h])
 177
 178 dnl used in gst/tcp
 179 AC_CHECK_HEADERS([sys/socket.h],
 180   [HAVE_SYS_SOCKET_H="yes"], [HAVE_SYS_SOCKET_H="no"], [AC_INCLUDES_DEFAULT])
 181 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 182
 183 dnl used in gst-libs/gst/pbutils and associated unit test
 184 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h], [], [], [AC_INCLUDES_DEFAULT])
 185
 186 dnl checks for ARM NEON support
 187 dnl this instruction set is used by the speex resampler code
 188 AC_MSG_CHECKING(for ARM NEON support in current arch/CFLAGS)
 189 AC_LINK_IFELSE([
 190 AC_LANG_PROGRAM([[
 191   #include <arm_neon.h>
 192   int32x4_t testfunc(int16_t *a, int16_t *b) {
 193       asm volatile ("vmull.s16 q0, d0, d0" : : : "q0");
 194       return vmull_s16(vld1_s16(a), vld1_s16(b));
 195   }
 196 ]])],
 197 [
 198   AC_DEFINE(HAVE_ARM_NEON,[],[ARM NEON support is enabled])
 199   AC_MSG_RESULT(yes)
 200 ],
 201 [
 202   AC_MSG_RESULT(no)
 203 ])
 204
 205 dnl also, Windows does not have long long
 206 AX_CREATE_STDINT_H
 207
 208 dnl *** checks for functions ***
 209 AC_CHECK_FUNCS([localtime_r gmtime_r])
 210
 211 dnl *** checks for math functions ***
 212 LIBS_SAVE=$LIBS
 213 LIBS="$LIBS $LIBM"
 214 AC_CHECK_FUNCS(log2)
 215 LIBS=$LIBS_SAVE
 216
 217 dnl *** checks for types/defines ***
 218
 219 dnl *** checks for structures ***
 220
 221 dnl *** checks for compiler characteristics ***
 222
 223 dnl *** checks for library functions ***
 224
 225 dnl check for fseeko()
 226 AC_FUNC_FSEEKO
 227
 228 dnl Check for fast float to int casting as defined in C99
 229 dnl used to be used in gst-libs/gst/floatcast/floatcast.h (FIXME: still needed?)
 230 save_libs=$LIBS
 231 LIBS="$LIBS $LIBM"
 232 AC_C99_FUNC_LRINT
 233 AC_C99_FUNC_LRINTF
 234 LIBS=$save_libs
 235
 236 dnl Check for a way to display the function name in debug output
 237 AG_GST_CHECK_FUNCTION
 238
 239 dnl *** checks for dependency libraries ***
 240
 241 dnl GLib
 242 GLIB_REQ=2.32
 243 AG_GST_GLIB_CHECK([$GLIB_REQ])
 244
 245 ORC_CHECK([0.4.18])
 246
 247 dnl checks for gstreamer
 248 dnl uninstalled is selected preferentially -- see pkg-config(1)
 249 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 250 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 251 AG_GST_CHECK_GST_CONTROLLER($GST_API_VERSION, [$GST_REQ], yes)
 252 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 253 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 254
 255 dnl Check for documentation xrefs
 256 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 257 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 258 AC_SUBST(GLIB_PREFIX)
 259 AC_SUBST(GST_PREFIX)
 260
 261 dnl GTK is optional and only used in examples
 262 HAVE_GTK=no
 263 HAVE_GTK_X11=no
 264 GTK_REQ=3.0.0
 265 if test "x$BUILD_EXAMPLES" = "xyes"; then
 266   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 267   dnl some examples need gtk+-x11
 268   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 269   PKG_CHECK_MODULES(GTK_QUARTZ, gtk+-quartz-3.0 >= $GTK_REQ, HAVE_GTK_QUARTZ=yes, HAVE_GTK_QUARTZ=no)
 270   AC_SUBST(GTK_LIBS)
 271   AC_SUBST(GTK_CFLAGS)
 272 fi
 273 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 274 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 275 AM_CONDITIONAL(HAVE_GTK_QUARTZ, test "x$HAVE_GTK_QUARTZ" = "xyes")
 276
 277 HAVE_QT=no
 278 HAVE_QT_MOC=no
 279 dnl QT is optional and only used in examples
 280 PKG_CHECK_MODULES(QT, Qt5Gui Qt5Widgets, [
 281   HAVE_QT=yes
 282 ], [
 283   HAVE_QT=no
 284 ])
 285 if test "x$HAVE_QT" = "xyes"; then
 286   AC_CHECK_TOOL(QT_MOC, moc)
 287   AC_MSG_CHECKING([for Qt5 moc])
 288   mocversion=`$QT_MOC -v 2>&1`
 289   mocversiongrep=`echo $mocversion | grep "Qt 5\|moc 5"`
 290   if test x"$mocversiongrep" != x"$mocversion"; then
 291     AC_MSG_RESULT([no])
 292     # moc was not the qt5 one, try with moc-qt5
 293     AC_CHECK_TOOL(QT_MOC, moc-qt5)
 294     AC_MSG_CHECKING([for Qt5 moc-qt5])
 295     mocversion=`$QT_MOC -v 2>&1`
 296     mocversiongrep=`echo $mocversion | grep "Qt 5\|moc 5"`
 297     if test x"$mocversiongrep" != x"$mocversion"; then
 298       AC_CHECK_TOOL(QTCHOOSER, qtchooser)
 299       AC_MSG_CHECKING([for qtchooser])
 300       qt5tooldir=`QT_SELECT=qt5 qtchooser -print-env | grep QTTOOLDIR | cut -d '=' -f 2 | cut -d \" -f 2`
 301       mocversion=`$qt5tooldir/moc -v 2>&1`
 302       mocversiongrep=`echo $mocversion | grep "Qt 5\|moc 5"`
 303       if test x"$mocversiongrep" != x"$mocversion"; then
 304         # no valid moc found
 305         QT_MOC="no"
 306       else
 307         QT_MOC=$qt5tooldir/moc
 308       fi
 309     else
 310       QT_MOC=$QT_MOC
 311     fi
 312   fi
 313   AC_SUBST(QT_MOC)
 314   AC_MSG_RESULT([$QT_MOC])
 315 fi
 316 AM_CONDITIONAL(HAVE_QT, test "x$HAVE_QT" = "xyes")
 317 AM_CONDITIONAL(HAVE_QT_MOC, test "x$HAVE_QT_MOC" != "xno")
 318
 319 dnl chck for linux headers needed by the joystick seek example
 320 AC_COMPILE_IFELSE(
 321 [
 322   AC_LANG_PROGRAM([
 323     #include <linux/input.h>
 324     #include <linux/joystick.h>
 325   ],[
 326     struct js_event js;
 327     js.type = JS_EVENT_AXIS;
 328   ])
 329 ], [
 330   HAVE_LINUX_JOYSTICK_HEADERS="yes"
 331 ], [
 332   HAVE_LINUX_JOYSTICK_HEADERS="no"
 333 ])
 334 AM_CONDITIONAL(HAVE_LINUX_JOYSTICK_HEADERS, test "x$HAVE_LINUX_JOYSTICK_HEADERS" = "xyes")
 335
 336 dnl Check for -Bsymbolic-functions linker flag used to avoid
 337 dnl intra-library PLT jumps, if available.
 338 AC_ARG_ENABLE(Bsymbolic,
 339               [AS_HELP_STRING([--disable-Bsymbolic],[avoid linking with -Bsymbolic])],,
 340               [SAVED_LDFLAGS="${LDFLAGS}"
 341                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 342                LDFLAGS=-Wl,-Bsymbolic-functions
 343                AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int main (void) { return 0; }]])],[
 344                            AC_MSG_RESULT(yes)
 345                            enable_Bsymbolic=yes],[
 346                            AC_MSG_RESULT(no)
 347                            enable_Bsymbolic=no])
 348                LDFLAGS="${SAVED_LDFLAGS}"])
 349
 350
 351 dnl *** set variables based on configure arguments ***
 352
 353 dnl set license and copyright notice
 354 GST_LICENSE="LGPL"
 355 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 356 AC_SUBST(GST_LICENSE)
 357
 358 dnl set location of plugin directory
 359 AG_GST_SET_PLUGINDIR
 360
 361 dnl set release date/time
 362 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 363   ["${srcdir}/gst-plugins-base.doap"],
 364   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 365
 366 dnl build static plugins or not
 367 AC_MSG_CHECKING([whether to build static plugins or not])
 368 AC_ARG_ENABLE(
 369   static-plugins,
 370   AC_HELP_STRING(
 371     [--enable-static-plugins],
 372     [build static plugins @<:@default=no@:>@]),
 373   [AS_CASE(
 374     [$enableval], [no], [], [yes], [],
 375     [AC_MSG_ERROR([bad value "$enableval" for --enable-static-plugins])])],
 376   [enable_static_plugins=no])
 377 AC_MSG_RESULT([$enable_static_plugins])
 378 if test "x$enable_static_plugins" = xyes; then
 379   AC_DEFINE(GST_PLUGIN_BUILD_STATIC, 1,
 380     [Define if static plugins should be built])
 381   GST_PLUGIN_LIBTOOLFLAGS=""
 382 else
 383   GST_PLUGIN_LIBTOOLFLAGS="--tag=disable-static"
 384 fi
 385 AC_SUBST(GST_PLUGIN_LIBTOOLFLAGS)
 386 AM_CONDITIONAL(GST_PLUGIN_BUILD_STATIC, test "x$enable_static_plugins" = "xyes")
 387
 388 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 389 dnl make sure it doesn't complain about unused variables if debugging is disabled
 390 NO_WARNINGS=""
 391 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 392
 393 dnl define an ERROR_CFLAGS Makefile variable
 394 dnl -Wformat-nonliteral - see ext/pango/gstclockoverlay.c and http://gcc.gnu.org/bugzilla/show_bug.cgi?id=39438
 395 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 396     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef
 397     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 398     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 399     -Wno-multichar -Wnested-externs $NO_WARNINGS])
 400
 401 dnl define an ERROR_CXXFLAGS Makefile variable
 402 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 403     -Wmissing-declarations -Wredundant-decls -Wundef
 404     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 405     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 406     -Wno-multichar $NO_WARNINGS])
 407
 408 dnl define correct level for debugging messages
 409 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 410
 411 dnl used in examples
 412 AG_GST_DEFAULT_ELEMENTS
 413
 414 dnl needed for encoding-target
 415 GST_DATADIR="$GST_PREFIX/share"
 416 AC_DEFINE_UNQUOTED(GST_DATADIR, "$GST_DATADIR", [system wide data directory])
 417 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION", [major/minor version])
 418
 419 dnl behaviour of speex based audio resampler
 420 AC_MSG_CHECKING(which audio resample format to use for integer)
 421 AC_ARG_WITH([audioresample_format],
 422         AS_HELP_STRING([--with-audioresample-format],[Which implementation should be used for integer audio resampling, int/float/auto, (default is auto)]),
 423         [ac_cv_audioresample_format=$withval], [ac_cv_audioresample_format=auto])dnl
 424 AC_MSG_RESULT($ac_cv_audioresample_format)
 425 case $ac_cv_audioresample_format in
 426   int)
 427     AC_DEFINE(AUDIORESAMPLE_FORMAT_INT,1,[The int implementation should be used for integer audio resampling])
 428     AC_SUBST(AUDIORESAMPLE_FORMAT_INT)
 429   ;;
 430   float)
 431     AC_DEFINE(AUDIORESAMPLE_FORMAT_FLOAT,1,[The float implementation should be used for integer audio resampling])
 432     AC_SUBST(AUDIORESAMPLE_FORMAT_FLOAT)
 433   ;;
 434   auto)
 435     AC_DEFINE(AUDIORESAMPLE_FORMAT_AUTO,1,[The implementation that should be used for integer audio resampling witll be benchmarked at runtime])
 436     AC_SUBST(AUDIORESAMPLE_FORMAT_AUTO)
 437 esac
 438
 439 dnl Check for mmap (needed by allocators library)
 440 AC_CHECK_FUNC([mmap], [AC_DEFINE(HAVE_MMAP, 1, [Defined if mmap is supported])])
 441
 442 dnl *** plug-ins to include ***
 443
 444 dnl these are all the gst plug-ins, compilable without additional libs
 445 AG_GST_CHECK_PLUGIN(adder)
 446 AG_GST_CHECK_PLUGIN(app)
 447 AG_GST_CHECK_PLUGIN(audioconvert)
 448 AG_GST_CHECK_PLUGIN(audiorate)
 449 AG_GST_CHECK_PLUGIN(audiotestsrc)
 450 AG_GST_CHECK_PLUGIN(encoding)
 451 AG_GST_CHECK_PLUGIN(videoconvert)
 452 AG_GST_CHECK_PLUGIN(gio)
 453 AG_GST_CHECK_PLUGIN(playback)
 454 AG_GST_CHECK_PLUGIN(audioresample)
 455 AG_GST_CHECK_PLUGIN(subparse)
 456 AG_GST_CHECK_PLUGIN(tcp)
 457 AG_GST_CHECK_PLUGIN(typefind)
 458 AG_GST_CHECK_PLUGIN(videotestsrc)
 459 AG_GST_CHECK_PLUGIN(videorate)
 460 AG_GST_CHECK_PLUGIN(videoscale)
 461 AG_GST_CHECK_PLUGIN(volume)
 462
 463 dnl iso-codes is optional, used by libgsttag
 464 AC_ARG_ENABLE(iso-codes,
 465 AS_HELP_STRING([--enable-iso-codes],[use iso-codes if installed]),
 466 [case "${enableval}" in
 467   yes) enable_iso_codes=yes ;;
 468   no)  enable_iso_codes=no ;;
 469   *) AC_MSG_ERROR(bad value ${enableval} for --enable-iso-codes) ;;
 470 esac
 471 ],
 472 [enable_iso_codes=yes]) dnl Default value
 473
 474 AC_MSG_CHECKING([whether to use iso-codes if they are available])
 475 if test "x$enable_iso_codes" = "xyes"; then
 476   AC_MSG_RESULT([yes])
 477   have_iso_codes=no
 478   AC_MSG_CHECKING([whether iso-codes are available on this system])
 479   if $PKG_CONFIG iso-codes; then
 480     AC_MSG_RESULT([yes])
 481     AC_MSG_CHECKING([whether iso-codes has iso-639 domain])
 482     if $PKG_CONFIG --variable=domains iso-codes | $GREP -q 639 ; then
 483       AC_MSG_RESULT([yes])
 484       AC_MSG_CHECKING([for iso-codes prefix])
 485       ISO_CODES_PREFIX=`$PKG_CONFIG --variable=prefix iso-codes`
 486       if test -d "$ISO_CODES_PREFIX"; then
 487         AC_MSG_RESULT([yes])
 488         AC_MSG_CHECKING([ISO_CODES_PREFIX])
 489         AC_MSG_RESULT([$ISO_CODES_PREFIX])
 490         ISO_639_DOMAIN="iso_639"
 491         AC_MSG_CHECKING([ISO_639_DOMAIN])
 492         AC_MSG_RESULT([$ISO_639_DOMAIN])
 493         have_iso_codes=yes
 494         AC_DEFINE([HAVE_ISO_CODES], [1], [make use of iso-codes for ISO-639])
 495         AC_DEFINE_UNQUOTED([ISO_CODES_PREFIX], ["$ISO_CODES_PREFIX"], [prefix])
 496         ISO_CODES_VERSION=`$PKG_CONFIG --modversion iso-codes`
 497         AC_DEFINE_UNQUOTED([ISO_CODES_VERSION], ["$ISO_CODES_VERSION"], [ ])
 498       else
 499         AC_MSG_RESULT([no])
 500       fi
 501     else
 502       AC_MSG_RESULT([no])
 503     fi
 504   else
 505     AC_MSG_RESULT([no])
 506   fi
 507   AM_CONDITIONAL(USE_ISO_CODES, test "x$have_iso_codes" = "xyes")
 508 else
 509   AC_MSG_RESULT([no (disabled via --disable-iso-codes)])
 510   AM_CONDITIONAL(USE_ISO_CODES, false)
 511 fi
 512
 513 dnl *** zlib is optionally used by id3 tag parsing in libgsttag ***
 514 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 515 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for ID3 parsing in libgsttag],, [
 516   PKG_CHECK_MODULES(ZLIB, [ zlib ], [
 517       HAVE_ZLIB="yes"
 518     ], [
 519       AG_GST_CHECK_LIBHEADER(ZLIB, z, uncompress,, zlib.h, [
 520         HAVE_ZLIB="yes"
 521         ZLIB_LIBS="-lz"
 522         AC_SUBST(ZLIB_LIBS)
 523       ])
 524     ])
 525 ])
 526
 527 dnl *** sys plug-ins ***
 528
 529 echo
 530 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 531 echo
 532
 533 dnl *** X11 ***
 534 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 535 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 536                   [ximagesink], [
 537   AC_PATH_XTRA
 538   ac_cflags_save="$CFLAGS"
 539   ac_cppflags_save="$CPPFLAGS"
 540   CFLAGS="$CFLAGS $X_CFLAGS"
 541   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 542
 543   dnl now try to find the HEADER
 544   AC_CHECK_HEADER([X11/Xlib.h], [HAVE_X="yes"], [HAVE_X="no"], [AC_INCLUDES_DEFAULT])
 545
 546   if test "x$HAVE_X" = "xno"
 547   then
 548     AC_MSG_NOTICE([cannot find X11 development files])
 549   else
 550     dnl this is much more than we want
 551     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 552     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 553     dnl it does not add the libs; therefore we add them here
 554     X_LIBS="$X_LIBS -lX11"
 555     AC_SUBST(X_CFLAGS)
 556     AC_SUBST(X_LIBS)
 557   fi
 558   AC_SUBST(HAVE_X)
 559   CFLAGS="$ac_cflags_save"
 560   CPPFLAGS="$ac_cppflags_save"
 561 ])
 562
 563 dnl Check for Xv extension
 564 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 565 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 566                   [xvimagesink], [
 567   AG_GST_CHECK_XV
 568 ])
 569
 570 dnl check for X Shm
 571 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 572 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 573   if test x$HAVE_X = xyes; then
 574     AC_CHECK_LIB(Xext, XShmAttach,
 575                  HAVE_XSHM="yes", HAVE_XSHM="no",
 576                  $X_LIBS)
 577     if test "x$HAVE_XSHM" = "xyes"; then
 578       XSHM_LIBS="-lXext"
 579     else
 580       dnl On AIX, it is in XextSam instead, but we still need -lXext
 581       AC_CHECK_LIB(XextSam, XShmAttach,
 582                    HAVE_XSHM="yes", HAVE_XSHM="no",
 583                    $X_LIBS)
 584       if test "x$HAVE_XSHM" = "xyes"; then
 585         XSHM_LIBS="-lXext -lXextSam"
 586       fi
 587     fi
 588   fi
 589 ], , [
 590   AC_SUBST(HAVE_XSHM)
 591   AC_SUBST(XSHM_LIBS)
 592 ])
 593
 594 dnl *** ext plug-ins ***
 595 dnl keep this list sorted alphabetically !
 596
 597 if test "x$BUILD_EXTERNAL" = "xyes"; then
 598
 599 echo
 600 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 601 echo
 602
 603 dnl *** alsa ***
 604 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 605 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 606   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 607     HAVE_ALSA="yes"
 608     AC_SUBST(ALSA_CFLAGS)
 609     AC_SUBST(ALSA_LIBS)
 610   ], [
 611     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 612   ])
 613 ])
 614
 615 dnl *** CDParanoia ***
 616 dnl Note: upstream has a pkg-config file only in post-10.2 SVN so far
 617 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 618 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 619   PKG_CHECK_MODULES(CDPARANOIA, cdparanoia-3 >= 10.2, [
 620     HAVE_CDPARANOIA="yes"
 621   ], [
 622     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 623                         cdda_open, -lm,
 624                         cdda_interface.h,
 625                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 626                         HEADER_DIR="no"
 627                         FOUND_CDPARANOIA="yes")
 628     if test "x$FOUND_CDPARANOIA" != "xyes";
 629     then
 630       AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 631                           cdda_open, -lm,
 632                           cdda/cdda_interface.h,
 633                           CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 634                           HEADER_DIR="yes"
 635                           FOUND_CDPARANOIA="yes")
 636     fi
 637     if test "x$HEADER_DIR" = "xyes";
 638     then
 639       AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 640                          defined if cdda headers are in a cdda/ directory)
 641     fi
 642     if test "x$FOUND_CDPARANOIA" = "xyes";
 643     then
 644       AC_CHECK_LIB(cdda_paranoia,
 645                    paranoia_cachemodel_size,
 646                    : ,
 647                    HAVE_CDPARANOIA=no,
 648                  [-lcdda_interface])
 649     fi
 650
 651     AC_SUBST(CDPARANOIA_LIBS)
 652   ])
 653 ])
 654 dnl FIXME : add second check somehow if that is necessary
 655 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 656 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 657
 658 dnl *** ivorbis ***
 659 dnl AM_PATH_IVORBIS only takes two options
 660 translit(dnm, m, l) AM_CONDITIONAL(USE_IVORBIS, true)
 661 AG_GST_CHECK_FEATURE(IVORBIS, [integer vorbis plug-in], ivorbisdec, [
 662   AG_GST_PKG_CHECK_MODULES(IVORBIS, vorbisidec)
 663   if test $HAVE_IVORBIS = no
 664   then
 665     IVORBIS_LIBS=
 666     IVORBIS_CFLAGS=
 667     AC_CHECK_LIB(vorbisidec, vorbis_block_init,
 668       [IVORBIS_LIBS=-lvorbisidec
 669       HAVE_IVORBIS=yes
 670       case $host in
 671       arm-*-*)
 672         IVORBIS_CFLAGS="-D_ARM_ASSEM_ $IVORBIS_CFLAGS"
 673       esac
 674       ],
 675       HAVE_IVORBIS=no)
 676     AC_SUBST(IVORBIS_LIBS)
 677     AC_SUBST(IVORBIS_CFLAGS)
 678   else
 679     AC_CHECK_LIB(vorbisidec, vorbis_dsp_pcmout,
 680       AC_DEFINE([USE_TREMOLO],1, "Define if building for android"),
 681       USE_TREMOLO=no)
 682   fi
 683 ])
 684
 685 dnl *** libvisual ***
 686 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 687 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 688   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 689   if test $HAVE_LIBVISUAL = no
 690   then
 691     AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0)
 692     if test x$HAVE_LIBVISUAL = xyes; then
 693       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.2`"
 694     fi
 695   else
 696     if test x$HAVE_LIBVISUAL = xyes; then
 697       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.4`"
 698     fi
 699   fi
 700   AC_MSG_NOTICE([libvisual pluginsdir: $LIBVIS_PLUGINSDIR])
 701   if test x$LIBVIS_PLUGINSDIR != x; then
 702     AC_DEFINE_UNQUOTED(LIBVISUAL_PLUGINSBASEDIR,
 703         "$LIBVIS_PLUGINSDIR",
 704         [directory in which the detected libvisual's plugins are located])
 705   fi
 706 ])
 707
 708 dnl *** ogg ***
 709 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 710 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 711   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 712 ])
 713
 714 dnl *** pango ***
 715 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 716 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 717   AG_GST_PKG_CHECK_MODULES(PANGO, pango >= 1.22.0  pangocairo >= 1.22.0)
 718 ])
 719
 720 dnl *** theora ***
 721 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 722 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 723   AG_GST_PKG_CHECK_MODULES(THEORA, theoradec >= 1.1 theoraenc >= 1.1)
 724 ])
 725
 726 dnl *** vorbis ***
 727 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 728 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 729   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 730 ])
 731
 732 if test "x$HAVE_VORBIS" = "xyes"; then
 733   ac_cflags_save="$CFLAGS"
 734   AC_COMPILE_IFELSE([
 735     AC_LANG_PROGRAM([[
 736 #include <vorbis/codec.h>
 737                      ]],[[
 738 vorbis_dsp_state *v;
 739
 740 vorbis_synthesis_restart (v);
 741                      ]])], HAVE_VSR=yes, HAVE_VSR=no)
 742   if test "x$HAVE_VSR" = "xyes"; then
 743     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 744                        [defined if vorbis_synthesis_restart is present])
 745   fi
 746   CFLAGS="$ac_cflags_save"
 747 fi
 748
 749 else
 750
 751 dnl not building plugins with external dependencies,
 752 dnl but we still need to set the conditionals
 753 AM_CONDITIONAL(USE_ALSA, false)
 754 AM_CONDITIONAL(USE_CDPARANOIA, false)
 755 AM_CONDITIONAL(USE_IVORBIS, false)
 756 AM_CONDITIONAL(USE_LIBVISUAL, false)
 757 AM_CONDITIONAL(USE_OGG, false)
 758 AM_CONDITIONAL(USE_PANGO, false)
 759 AM_CONDITIONAL(USE_THEORA, false)
 760 AM_CONDITIONAL(USE_VORBIS, false)
 761
 762 fi dnl of EXT plugins
 763
 764 dnl seeking needs freetype, so check for it here
 765 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 766   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 767 ])
 768 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 769 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 770 AC_SUBST(FT2_CFLAGS)
 771 AC_SUBST(FT2_LIBS)
 772
 773 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 774
 775 dnl Overview:
 776 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 777 dnl GST_*:              flags shared by built objects to link against GStreamer
 778 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 779 dnl                          (compare to other modules) or for i18n
 780 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 781 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 782 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 783 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 784
 785 dnl GST_OPTION_CFLAGS
 786 if test "x$USE_DEBUG" = xyes; then
 787    PROFILE_CFLAGS="-g"
 788 fi
 789 AC_SUBST(PROFILE_CFLAGS)
 790
 791 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 792   dnl Define _only_ when compiling a git version (not pre-releases or releases)
 793   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 794 else
 795   DEPRECATED_CFLAGS=""
 796 fi
 797 AC_SUBST(DEPRECATED_CFLAGS)
 798
 799 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 800 dnl at make time with e.g. make ERROR_CFLAGS=""
 801 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 802 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 803 AC_SUBST(GST_OPTION_CFLAGS)
 804 AC_SUBST(GST_OPTION_CXXFLAGS)
 805
 806 dnl our libraries need to be versioned correctly
 807 AC_SUBST(GST_LT_LDFLAGS)
 808
 809 dnl GST_PLUGINS_BASE_CFLAGS
 810 dnl prefer internal headers to already installed ones
 811 dnl also add builddir include for enumtypes and marshal
 812 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 813 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 814
 815 dnl FIXME: do we want to rename to GST_ALL_* ?
 816 dnl add GST_OPTION_CFLAGS, but overridable
 817 GST_CFLAGS="$GST_CFLAGS"
 818 GST_CXXFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CXXFLAGS)"
 819 GST_CFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CFLAGS)"
 820 AC_SUBST(GST_CFLAGS)
 821 AC_SUBST(GST_CXXFLAGS)
 822 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 823 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 824 AC_SUBST(GST_LIBS)
 825
 826 dnl LDFLAGS really should only contain flags, not libs - they get added before
 827 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 828 GST_ALL_LDFLAGS="-no-undefined"
 829 if test "x${enable_Bsymbolic}" = "xyes"; then
 830   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 831 fi
 832 AC_SUBST(GST_ALL_LDFLAGS)
 833
 834 dnl GST_LIB_LDFLAGS
 835 dnl linker flags shared by all libraries
 836 dnl LDFLAGS modifier defining exported symbols from built libraries
 837 dnl (export _gst_foo but not __gst_foo)
 838 GST_LIB_LDFLAGS="-export-symbols-regex ^_?\(gst_\|Gst\|GST_\).*"
 839 AC_SUBST(GST_LIB_LDFLAGS)
 840
 841 dnl this really should only contain flags, not libs - they get added before
 842 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 843 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_.*' $GST_ALL_LDFLAGS"
 844 AC_SUBST(GST_PLUGIN_LDFLAGS)
 845
 846 dnl *** output files ***
 847
 848 $MKDIR_P tests/check/orc
 849
 850 AC_CONFIG_FILES(
 851 Makefile
 852 gst-plugins-base.spec
 853 gst/Makefile
 854 gst/adder/Makefile
 855 gst/app/Makefile
 856 gst/audioconvert/Makefile
 857 gst/audiorate/Makefile
 858 gst/audiotestsrc/Makefile
 859 gst/encoding/Makefile
 860 gst/videoconvert/Makefile
 861 gst/gio/Makefile
 862 gst/playback/Makefile
 863 gst/audioresample/Makefile
 864 gst/subparse/Makefile
 865 gst/tcp/Makefile
 866 gst/typefind/Makefile
 867 gst/videotestsrc/Makefile
 868 gst/videorate/Makefile
 869 gst/videoscale/Makefile
 870 gst/volume/Makefile
 871 sys/Makefile
 872 sys/ximage/Makefile
 873 sys/xvimage/Makefile
 874 ext/Makefile
 875 ext/alsa/Makefile
 876 ext/cdparanoia/Makefile
 877 ext/libvisual/Makefile
 878 ext/ogg/Makefile
 879 ext/pango/Makefile
 880 ext/theora/Makefile
 881 ext/vorbis/Makefile
 882 gst-libs/Makefile
 883 gst-libs/gst/Makefile
 884 gst-libs/gst/allocators/Makefile
 885 gst-libs/gst/audio/Makefile
 886 gst-libs/gst/app/Makefile
 887 gst-libs/gst/fft/Makefile
 888 gst-libs/gst/riff/Makefile
 889 gst-libs/gst/rtp/Makefile
 890 gst-libs/gst/rtsp/Makefile
 891 gst-libs/gst/sdp/Makefile
 892 gst-libs/gst/tag/Makefile
 893 gst-libs/gst/pbutils/Makefile
 894 gst-libs/gst/pbutils/gstpluginsbaseversion.h
 895 gst-libs/gst/video/Makefile
 896 tools/Makefile
 897 pkgconfig/Makefile
 898 pkgconfig/gstreamer-allocators.pc
 899 pkgconfig/gstreamer-allocators-uninstalled.pc
 900 pkgconfig/gstreamer-audio.pc
 901 pkgconfig/gstreamer-audio-uninstalled.pc
 902 pkgconfig/gstreamer-app.pc
 903 pkgconfig/gstreamer-app-uninstalled.pc
 904 pkgconfig/gstreamer-fft.pc
 905 pkgconfig/gstreamer-fft-uninstalled.pc
 906 pkgconfig/gstreamer-pbutils.pc
 907 pkgconfig/gstreamer-pbutils-uninstalled.pc
 908 pkgconfig/gstreamer-riff.pc
 909 pkgconfig/gstreamer-riff-uninstalled.pc
 910 pkgconfig/gstreamer-rtp.pc
 911 pkgconfig/gstreamer-rtp-uninstalled.pc
 912 pkgconfig/gstreamer-rtsp.pc
 913 pkgconfig/gstreamer-rtsp-uninstalled.pc
 914 pkgconfig/gstreamer-sdp.pc
 915 pkgconfig/gstreamer-sdp-uninstalled.pc
 916 pkgconfig/gstreamer-tag.pc
 917 pkgconfig/gstreamer-tag-uninstalled.pc
 918 pkgconfig/gstreamer-video.pc
 919 pkgconfig/gstreamer-video-uninstalled.pc
 920 pkgconfig/gstreamer-plugins-base.pc
 921 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 922 tests/Makefile
 923 tests/check/Makefile
 924 tests/examples/Makefile
 925 tests/examples/app/Makefile
 926 tests/examples/audio/Makefile
 927 tests/examples/dynamic/Makefile
 928 tests/examples/encoding/Makefile
 929 tests/examples/fft/Makefile
 930 tests/examples/gio/Makefile
 931 tests/examples/overlay/Makefile
 932 tests/examples/seek/Makefile
 933 tests/examples/snapshot/Makefile
 934 tests/examples/playback/Makefile
 935 tests/examples/playrec/Makefile
 936 tests/files/Makefile
 937 tests/icles/Makefile
 938 tests/icles/playback/Makefile
 939 docs/Makefile
 940 docs/design/Makefile
 941 docs/libs/Makefile
 942 docs/plugins/Makefile
 943 docs/version.entities
 944 po/Makefile.in
 945 common/Makefile
 946 common/m4/Makefile
 947 m4/Makefile
 948 )
 949
 950 dnl Create the config.h file for Visual Studio builds
 951 dnl Beware of spaces and /'s in some of the shell variable contents.
 952 sed \
 953     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 954     -e 's/.* GST_INSTALL_PLUGINS_HELPER/#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
 955     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 956     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 957     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 958     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 959     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
 960     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 961     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 962     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
 963     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 964     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 965     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 966     -e 's/.* HAVE_ISO_CODES$/#undef HAVE_ISO_CODES/' \
 967     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 968     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 969     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 970     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 971     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 972     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 973     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 974     -e 's/.* ISO_CODES_PREFIX$/#undef ISO_CODES_PREFIX/' \
 975     -e 's/.* ISO_CODES_VERSION$/#undef ISO_CODES_VERSION/' \
 976     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 977     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 978     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
 979     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 980     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
 981     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 982     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 983     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 984     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
 985     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
 986     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 987     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
 988     -e "s/.* DEFAULT_VIDEOSINK$/#define DEFAULT_VIDEOSINK \"directdrawsink\"/" \
 989     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
 990     config.h.in >win32/common/config.h-new
 991
 992
 993
 994 AC_OUTPUT
 995
 996 AG_GST_OUTPUT_PLUGINS
 997 ORC_OUTPUT
 998