configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl initialize autoconf
   4 dnl we don't specify PACKAGE and VERSION because AS_VERSION puts it together
   5 AC_INIT
   6
   7 dnl when going to/from release please set the nano (fourth number) right !
   8 dnl releases only do Wall, cvs and prerelease does Werror too
   9 AS_VERSION(gstreamer, GST_VERSION, 0, 10, 4, 1,
  10     GST_CVS="no", GST_CVS="yes")
  11
  12 dnl can autoconf find the source ?
  13 AC_CONFIG_SRCDIR([gst/gst.c])
  14
  15 dnl define the output header for config
  16 AM_CONFIG_HEADER([config.h])
  17
  18 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  19 AM_MAINTAINER_MODE
  20
  21 dnl sets host_* variables
  22 AC_CANONICAL_HOST
  23
  24 dnl initialize automake
  25 dnl FIXME: this is deprecated use, we should move PACKAGE and VERSION to
  26 dnl AC_INIT, but then we need to parse the version to pass to AS_VERSION
  27 AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
  28
  29 dnl our libraries and install dirs use major.minor as a version
  30 GST_MAJORMINOR=$GST_VERSION_MAJOR.$GST_VERSION_MINOR
  31 dnl we override it here for release candidates for a new series
  32 GST_MAJORMINOR=0.10
  33 AC_SUBST(GST_MAJORMINOR)
  34
  35 dnl CURRENT, REVISION, AGE
  36 dnl - library source changed -> increment REVISION
  37 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  38 dnl - interfaces added -> increment AGE
  39 dnl - interfaces removed -> AGE = 0
  40 dnl sets GST_LT_LDFLAGS
  41 AS_LIBTOOL(GST, 4, 0, 4)
  42 AS_LIBTOOL_TAGS
  43 AM_PROG_LIBTOOL
  44
  45 dnl *** autotools stuff ****
  46
  47 dnl allow for different autotools
  48 AS_AUTOTOOLS_ALTERNATE
  49
  50 dnl Add parameters for aclocal
  51 AC_SUBST(ACLOCAL_AMFLAGS, "-I common/m4")
  52
  53 dnl set up gettext
  54 dnl the version check needs to stay here because autopoint greps for it
  55 AM_GNU_GETTEXT_VERSION([0.11.5])
  56 AM_GNU_GETTEXT([external])
  57 GST_GETTEXT([gstreamer-$GST_MAJORMINOR])
  58
  59 dnl *** check for arguments to configure ***
  60
  61 dnl subsystems - can influence other decisions so needs to be high up
  62 dnl we need to AM_CONDITIONAL them here for automake 1.6.x compatibility
  63 GST_CHECK_SUBSYSTEM_DISABLE(GST_DEBUG,[debugging subsystem])
  64 AM_CONDITIONAL(GST_DISABLE_GST_DEBUG, test "x$GST_GST_DISABLE_DEBUG" = "xyes")
  65 GST_CHECK_SUBSYSTEM_DISABLE(LOADSAVE,[pipeline XML load/save])
  66 AM_CONDITIONAL(GST_DISABLE_LOADSAVE, test "x$GST_DISABLE_LOADSAVE" = "xyes")
  67 dnl define a substitution to use in docs/gst/gstreamer.types
  68 if test "x$GST_DISABLE_LOADSAVE" = "xyes"
  69 then
  70   GST_LOADSAVE_DOC_TYPES="%"
  71 else
  72   GST_LOADSAVE_DOC_TYPES=
  73 fi
  74 AC_SUBST(GST_LOADSAVE_DOC_TYPES)
  75 GST_CHECK_SUBSYSTEM_DISABLE(PARSE,[command-line parser])
  76 AM_CONDITIONAL(GST_DISABLE_PARSE, test "x$GST_DISABLE_PARSE" = "xyes")
  77 if test "x$GST_DISABLE_PARSE" = xyes; then
  78   AC_DEFINE(GST_DISABLE_PARSE, 1,
  79     [Define if pipeline parsing code is disabled])
  80 fi
  81 GST_CHECK_SUBSYSTEM_DISABLE(TRACE,[tracing subsystem])
  82 AM_CONDITIONAL(GST_DISABLE_TRACE, test "x$GST_DISABLE_TRACE" = "xyes")
  83 GST_CHECK_SUBSYSTEM_DISABLE(ALLOC_TRACE,[allocation tracing])
  84 AM_CONDITIONAL(GST_DISABLE_ALLOC_TRACE, test "x$GST_DISABLE_ALLOC_TRACE" = "xyes")
  85 GST_CHECK_SUBSYSTEM_DISABLE(REGISTRY,[plugin registry])
  86 AM_CONDITIONAL(GST_DISABLE_REGISTRY, test "x$GST_DISABLE_REGISTRY" = "xyes")
  87 dnl define a substitution to use in docs/gst/gstreamer.types
  88 if test "x$GST_DISABLE_REGISTRY" = "xyes"
  89 then
  90   GST_REGISTRY_DOC_TYPES="%"
  91 else
  92   GST_REGISTRY_DOC_TYPES=
  93 fi
  94 AC_SUBST(GST_REGISTRY_DOC_TYPES)
  95 GST_CHECK_SUBSYSTEM_DISABLE(ENUMTYPES,[enum types])
  96 AM_CONDITIONAL(GST_DISABLE_ENUMTYPES, test "x$GST_DISABLE_ENUMTYPES" = "xyes")
  97 GST_CHECK_SUBSYSTEM_DISABLE(INDEX,[index])
  98 AM_CONDITIONAL(GST_DISABLE_INDEX, test "x$GST_DISABLE_INDEX" = "xyes")
  99 GST_CHECK_SUBSYSTEM_DISABLE(NET,[network distribution])
 100 AM_CONDITIONAL(GST_DISABLE_NET, test "x$GST_DISABLE_NET" = "xyes")
 101 GST_CHECK_SUBSYSTEM_DISABLE(PLUGIN,[plugin])
 102 AM_CONDITIONAL(GST_DISABLE_PLUGIN, test "x$GST_DISABLE_PLUGIN" = "xyes")
 103 GST_CHECK_SUBSYSTEM_DISABLE(URI,[uri handlers])
 104 AM_CONDITIONAL(GST_DISABLE_URI, test "x$GST_DISABLE_URI" = "xyes")
 105
 106 GST_ARG_DEBUG
 107 GST_ARG_PROFILING
 108 GST_ARG_VALGRIND
 109 GST_ARG_GCOV
 110
 111 GST_ARG_EXAMPLES
 112
 113 GST_ARG_WITH_PKG_CONFIG_PATH
 114 GST_ARG_WITH_PACKAGE_NAME([GStreamer])
 115 GST_ARG_WITH_PACKAGE_ORIGIN
 116
 117 dnl use a cache dir for storing element registry info.
 118 GST_CACHE_DIR=${localstatedir}/cache/gstreamer-$GST_MAJORMINOR
 119
 120 AC_ARG_WITH(cachedir,
 121   AC_HELP_STRING([--with-cachedir],
 122     [specify path to use for plugin and command completion registries]),
 123   [
 124     case "${withval}" in
 125       yes) AC_MSG_ERROR(bad value ${withval} for --with-cachedir) ;;
 126       no)  AC_MSG_ERROR(bad value ${withval} for --with-cachedir) ;;
 127       *)   GST_CACHE_DIR="${withval}" ;;
 128     esac
 129   ],
 130   [:]) dnl Default value
 131
 132 AS_AC_EXPAND(GST_CACHE_DIR, $GST_CACHE_DIR)
 133 AC_DEFINE_UNQUOTED(GST_CACHE_DIR, "$GST_CACHE_DIR", [Location of registry])
 134 AC_MSG_NOTICE(Using $GST_CACHE_DIR as registry cache dir)
 135
 136 dnl building of tests
 137 AC_ARG_ENABLE(tests,
 138   AC_HELP_STRING([--disable-tests], [disable building test apps]),
 139   [
 140     case "${enableval}" in
 141       yes) BUILD_TESTS=yes ;;
 142       no)  BUILD_TESTS=no ;;
 143       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 144     esac
 145   ],
 146 [BUILD_TESTS=yes]) dnl Default value
 147 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 148
 149 dnl tests known to fail
 150 AC_ARG_ENABLE(failing-tests,
 151   AC_HELP_STRING([--disable-failing-tests],
 152     [disable building tests known to fail]),
 153   [
 154     case "${enableval}" in
 155       yes) BUILD_FAILING_TESTS=yes ;;
 156       no)  BUILD_FAILING_TESTS=no ;;
 157       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-failing-tests) ;;
 158     esac
 159   ],
 160   [BUILD_FAILING_TESTS=no]) dnl Default value
 161 AM_CONDITIONAL(BUILD_FAILING_TESTS, test "x$BUILD_FAILING_TESTS" = "xyes")
 162 if test x$BUILD_FAILING_TESTS = xyes; then
 163   AC_MSG_WARN([building tests known to fail, use --disable-failing-tests to disable])
 164 else
 165   AC_MSG_WARN([Sissy ! By asking to not build the tests known to fail, you hereby waive your right to customer support.  If you do not agree with this EULA, please press Ctrl-C before the next line is printed.  By allowing the next line to be printed, you expressly acknowledge your acceptance of this EULA.])
 166 fi
 167
 168 dnl poison destroyed objects
 169 AC_ARG_ENABLE(poisoning,
 170   AC_HELP_STRING([--enable-poisoning],
 171     [enable poisoning of deallocated objects]),
 172   [
 173     case "${enableval}" in
 174       yes) USE_POISONING=yes ;;
 175       no)  USE_POISONING=no ;;
 176       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-poisoning) ;;
 177     esac
 178   ],
 179   [USE_POISONING=no]) dnl Default value
 180 if test "x$USE_POISONING" = xyes; then
 181   AC_DEFINE(USE_POISONING, 1,
 182     [Define if we should poison deallocated memory])
 183 fi
 184
 185 dnl *** checks for platform ***
 186
 187 dnl * hardware/architecture *
 188
 189 dnl common/m4/gst-arch.m4
 190 dnl check CPU type
 191 GST_ARCH
 192 dnl substitution for win32/common/config.h
 193 HOST_CPU=$host_cpu
 194 AC_SUBST(HOST_CPU)
 195
 196 dnl common/m4/gst-arch.m4
 197 dnl check for unaligned access
 198 GST_UNALIGNED_ACCESS
 199 dnl create a configure variable for gst/gstconfig.h
 200 if test x${as_cv_unaligned_access} = xyes ; then
 201   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 1"
 202 else
 203   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 0"
 204 fi
 205 AC_SUBST(GST_HAVE_UNALIGNED_ACCESS_DEFINE)
 206
 207 dnl * software *
 208
 209 dnl check for large file support
 210 dnl affected plugins must include config.h
 211 AC_SYS_LARGEFILE
 212
 213 dnl HAVE_WIN32 currently means "disable POSIXisms".
 214 case "$host" in
 215   *-*-mingw*)
 216     AC_DEFINE_UNQUOTED(HAVE_WIN32, 1, [Defined if compiling for Windows])
 217     ;;
 218   *)
 219     ;;
 220 esac
 221
 222 dnl *** checks for programs ***
 223
 224 dnl find a compiler
 225 AC_PROG_CC
 226
 227 dnl find an assembler
 228 AM_PROG_AS
 229
 230 dnl we use awk in the bison version check
 231 AC_PROG_AWK
 232
 233 dnl we require bison for building the parser
 234 dnl FIXME: check if AC_PROG_YACC is suitable here
 235 dnl FIXME: make precious
 236 AC_PATH_PROG(BISON_PATH, bison, no)
 237 if test x$BISON_PATH = xno; then
 238   AC_MSG_ERROR(Could not find bison)
 239 fi
 240
 241 dnl check bison version
 242 AC_MSG_CHECKING([bison version])
 243
 244 if $BISON_PATH --version | head -n 1 | $AWK '{ if ($4 < 1.35) exit 1; else exit 0;}';
 245 then
 246   AC_MSG_RESULT([ok])
 247 else
 248   AC_MSG_RESULT([too old.])
 249   AC_MSG_ERROR([Your bison version is too old, v1.35 or later is required.])
 250 fi
 251
 252 dnl we require flex for building the parser
 253 dnl FIXME: check if AC_PROG_LEX is suitable here
 254 AC_PATH_PROG(FLEX_PATH, flex, no)
 255 if test x$FLEX_PATH = xno; then
 256   AC_MSG_ERROR(Could not find flex)
 257 fi
 258
 259 dnl Perl is used in building documentation
 260 AC_PATH_PROG(PERL_PATH, perl, no)
 261 if test x$PERL_PATH = xno; then
 262   AC_MSG_ERROR(Could not find perl)
 263 fi
 264
 265 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 266 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 267
 268 dnl check for documentation tools
 269 GST_DOCBOOK_CHECK
 270 GTK_DOC_CHECK([1.3])
 271 AS_PATH_PYTHON([2.1])
 272
 273 dnl *** checks for libraries ***
 274
 275 dnl For interactive UNIX (a Sun thing)
 276 dnl FIXME: this adds -lcposix to LIBS, but I doubt we use LIBS
 277 AC_ISC_POSIX
 278
 279 dnl *** checks for header files ***
 280
 281 dnl check if we have ANSI C header files
 282 AC_HEADER_STDC
 283
 284 dnl Check for ucontext.h
 285 AC_CHECK_HEADERS([ucontext.h])
 286 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 287 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 288 AC_CHECK_HEADERS([process.h])
 289
 290 dnl *** checks for types/defines ***
 291
 292 dnl *** checks for structures ***
 293
 294 dnl *** checks for compiler characteristics ***
 295
 296 dnl make sure we can use "inline" from C code
 297 AC_C_INLINE
 298
 299 OPT_CFLAGS=
 300 dnl Check for some compiler flags that optimize our code.
 301 if test "x$GCC" = xyes; then
 302   AS_COMPILER_FLAG(-fno-common, OPT_CFLAGS="$OPT_CFLAGS -fno-common")
 303 fi
 304
 305 dnl FIXME: decide what kind of flag this is, maybe it's not an optimization
 306 dnl flag
 307 dnl check if we should use -Wa,-mregnames on PowerPC, so we can use
 308 dnl symbolic register names in inline asm
 309 if test x$HAVE_CPU_PPC = xyes ; then
 310   AS_COMPILER_FLAG(["-Wa,-mregnames"],
 311     [OPT_CFLAGS="$OPT_CFLAGS -Wa,-mregnames"])
 312 fi
 313
 314 dnl *** checks for library functions ***
 315
 316 AC_CHECK_FUNCS([sigaction])
 317
 318 dnl check for fseeko()
 319 AC_FUNC_FSEEKO
 320 dnl check for ftello()
 321 AC_CHECK_FUNCS([ftello])
 322
 323 AC_CHECK_FUNCS([fgetpos])
 324 AC_CHECK_FUNCS([fsetpos])
 325
 326 dnl check for mmap()
 327 AC_FUNC_MMAP
 328 AM_CONDITIONAL(HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 329
 330 dnl Check for a way to display the function name in debug output
 331 GST_CHECK_FUNCTION
 332
 333 dnl test for register_printf_function
 334 AC_CHECK_FUNC(register_printf_function,
 335   [
 336     GST_PRINTF_EXTENSION_FORMAT_DEFINE="#define GST_PTR_FORMAT \"P\""
 337     AC_DEFINE(HAVE_PRINTF_EXTENSION, 1,
 338       [Defined if we have register_printf_function ()])
 339   ],
 340   GST_PRINTF_EXTENSION_FORMAT_DEFINE="#define GST_PTR_FORMAT \"p\""
 341 )
 342 AC_SUBST(GST_PRINTF_EXTENSION_FORMAT_DEFINE)
 343
 344 dnl test if we have dladdr(); we use it for debugging; see gst/gstinfo.c
 345 save_cflags="$CFLAGS"
 346 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 347 AC_CHECK_LIB(dl, dladdr,
 348    AC_DEFINE(HAVE_DLADDR, 1,
 349              [Defined if we have dladdr ()]))
 350 CFLAGS="$save_cflags"
 351
 352 dnl *** checks for dependancy libraries ***
 353
 354 dnl GLib
 355
 356 GST_GLIB_CHECK([2.6])
 357
 358 dnl GLib 2.8 has some bug fixes that we like, so make sure our code knows
 359 AC_MSG_CHECKING([glib version >= 2.8])
 360 if pkg-config --atleast-version=2.8 glib-2.0; then
 361   AC_MSG_RESULT(yes)
 362   GST_HAVE_GLIB_2_8_DEFINE="#define GST_HAVE_GLIB_2_8 1"
 363 else
 364   AC_MSG_RESULT(no)
 365   GST_HAVE_GLIB_2_8_DEFINE="/* #undef GST_HAVE_GLIB_2_8 */"
 366 fi
 367 AC_SUBST(GST_HAVE_GLIB_2_8_DEFINE)
 368
 369 dnl Check for glib2 without extra fat, useful for the unversioned tool frontends
 370 PKG_CHECK_MODULES(GLIB_ONLY, glib-2.0 >= $GLIB_REQ)
 371
 372 dnl libxml 2, which is/should be optional (FIXME)
 373 if test "x$GST_DISABLE_LOADSAVE" = "xyes" && \
 374    test "x$GST_DISABLE_REGISTRY" = "xyes"
 375 then
 376   AC_MSG_NOTICE([Registry and load/save are disabled, not checking for libxml2])
 377 else
 378   dnl check for libxml2 with minimum req version
 379   GST_LIBXML2_CHECK(2.4.9)
 380 fi
 381
 382 dnl check for "check", unit testing library/header
 383 AM_PATH_CHECK(0.9.2,
 384     [
 385         HAVE_CHECK=yes
 386         AC_MSG_NOTICE(CHECK_CFLAGS: $CHECK_CFLAGS)
 387         AC_MSG_NOTICE(CHECK_LIBS: $CHECK_LIBS)
 388     ],
 389     HAVE_CHECK=no)
 390 AM_CONDITIONAL(HAVE_CHECK, test "x$HAVE_CHECK" = "xyes")
 391
 392 dnl *** set variables based on configure arguments
 393
 394 dnl set license and copyright notice
 395 GST_LICENSE="LGPL"
 396 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 397 AC_SUBST(GST_LICENSE)
 398
 399 dnl define LIBDIR so we can inform people where we live
 400 AS_AC_EXPAND(LIBDIR, $libdir)
 401 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [library dir])
 402
 403 dnl set location of plugin directory
 404 GST_SET_PLUGINDIR
 405
 406 dnl FIXME: add LIBXML_PKG here
 407 GST_PKG_DEPS="glib-2.0, gobject-2.0, gmodule-2.0, gthread-2.0"
 408 AC_SUBST(GST_PKG_DEPS)
 409
 410 dnl define an ERROR_CFLAGS Makefile variable
 411 GST_SET_ERROR_CFLAGS($GST_CVS)
 412
 413 dnl define correct level for debugging messages
 414 GST_SET_LEVEL_DEFAULT($GST_CVS)
 415
 416 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 417
 418 dnl Overview:
 419 dnl GST_OPTION_CFLAGS:  common cflags for profiling, debugging, errors, ...
 420 dnl GST_ALL_*:          vars shared by all built objects
 421 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 422 dnl GST_OBJ_*:          additional vars to link to the core library
 423 dnl                     include GST_ALL_*
 424 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 425 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 426
 427 dnl GST_OPTION_CFLAGS
 428 if test "x$USE_DEBUG" = xyes; then
 429    PROFILE_CFLAGS="-g"
 430 fi
 431 AC_SUBST(PROFILE_CFLAGS)
 432
 433 DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 434 AC_SUBST(DEPRECATED_CFLAGS)
 435
 436 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 437 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 438 AC_SUBST(GST_OPTION_CFLAGS)
 439
 440 dnl GST_ALL_*
 441 dnl vars common to for all internal objects (core libs, elements, applications)
 442 dnl CFLAGS:
 443 dnl - XML needs to be added because xmlPtr is used in core
 444 dnl - src and build dirs need to be added because every piece that gets built
 445 dnl   will need the GStreamer source and generated headers
 446 dnl LIBS: XML doesn't need to be added because we don't explicitly use symbols
 447 dnl       from LibXML except for in the core library
 448 GST_ALL_CFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir) $GLIB_CFLAGS $XML_CFLAGS \$(GST_OPTION_CFLAGS)"
 449 dnl FIXME: check if LTLIBINTL is needed everywhere
 450 dnl I presume it is given that it contains the symbols that _() stuff maps to
 451 GST_ALL_LIBS="$GLIB_LIBS $LTLIBINTL"
 452 dnl LDFLAGS really should only contain flags, not libs - they get added before
 453 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 454 GST_ALL_LDFLAGS="-no-undefined"
 455
 456 AC_SUBST(GST_ALL_CFLAGS)
 457 AC_SUBST(GST_ALL_LIBS)
 458 AC_SUBST(GST_ALL_LDFLAGS)
 459
 460 dnl GST_LIB_LDFLAGS
 461 dnl linker flags shared by all libraries
 462 dnl LDFLAGS modifier defining exported symbols from built libraries
 463 GST_LIB_LDFLAGS="-export-symbols-regex [_]*\(gst_\|Gst\|GST_\).*"
 464 AC_SUBST(GST_LIB_LDFLAGS)
 465
 466 dnl GST_OBJ_*
 467 dnl default vars for all internal objects built on libgstreamer
 468 dnl includes GST_ALL_*
 469 GST_OBJ_CFLAGS="\$(GST_ALL_CFLAGS)"
 470 GST_OBJ_LIBS="\$(top_builddir)/gst/libgstreamer-$GST_MAJORMINOR.la \$(GST_ALL_LIBS)"
 471 AC_SUBST(GST_OBJ_CFLAGS)
 472 AC_SUBST(GST_OBJ_LIBS)
 473
 474 dnl GST_PLUGIN_LDFLAGS
 475 dnl LDFLAGS for plugins; includes GST_ALL_LDFLAGS
 476 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 477 AC_SUBST(GST_PLUGIN_LDFLAGS, "$GST_PLUGIN_LDFLAGS")
 478
 479 AC_CONFIG_FILES(
 480 Makefile
 481 gst/Makefile
 482 gst/gstconfig.h
 483 gst/gstversion.h
 484 gst/parse/Makefile
 485 libs/Makefile
 486 libs/gst/Makefile
 487 libs/gst/base/Makefile
 488 libs/gst/check/Makefile
 489 libs/gst/controller/Makefile
 490 libs/gst/dataprotocol/Makefile
 491 libs/gst/net/Makefile
 492 plugins/Makefile
 493 plugins/indexers/Makefile
 494 plugins/elements/Makefile
 495 po/Makefile.in
 496 tests/Makefile
 497 tests/benchmarks/Makefile
 498 tests/check/Makefile
 499 tests/misc/Makefile
 500 tests/examples/Makefile
 501 tests/examples/controller/Makefile
 502 tests/examples/helloworld/Makefile
 503 tests/examples/launch/Makefile
 504 tests/examples/metadata/Makefile
 505 tests/examples/queue/Makefile
 506 tests/examples/typefind/Makefile
 507 tests/examples/xml/Makefile
 508 tools/Makefile
 509 common/Makefile
 510 common/m4/Makefile
 511 docs/Makefile
 512 docs/design/Makefile
 513 docs/faq/Makefile
 514 docs/gst/Makefile
 515 docs/gst/gstreamer.types
 516 docs/libs/Makefile
 517 docs/plugins/Makefile
 518 docs/manual/Makefile
 519 docs/pwg/Makefile
 520 docs/slides/Makefile
 521 docs/xsl/Makefile
 522 docs/version.entities
 523 win32/common/config.h
 524 pkgconfig/Makefile
 525 stamp.h
 526 pkgconfig/gstreamer.pc
 527 pkgconfig/gstreamer-uninstalled.pc
 528 pkgconfig/gstreamer-base.pc
 529 pkgconfig/gstreamer-base-uninstalled.pc
 530 pkgconfig/gstreamer-check.pc
 531 pkgconfig/gstreamer-check-uninstalled.pc
 532 pkgconfig/gstreamer-controller.pc
 533 pkgconfig/gstreamer-controller-uninstalled.pc
 534 pkgconfig/gstreamer-dataprotocol.pc
 535 pkgconfig/gstreamer-dataprotocol-uninstalled.pc
 536 pkgconfig/gstreamer-net.pc
 537 pkgconfig/gstreamer-net-uninstalled.pc
 538 gstreamer.spec
 539 )
 540
 541 AC_OUTPUT