configure.ac

   1 AC_PREREQ([2.69])
   2
   3 dnl initialize autoconf
   4 dnl releases only do -Wall, git and prerelease does -Werror too
   5 dnl use a three digit version number for releases, and four for git/prerelease
   6 AC_INIT([GStreamer Base Plug-ins],[1.17.0.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gst-plugins-base])
   7
   8 AG_GST_INIT
   9
  10 dnl initialize automake
  11 AM_INIT_AUTOMAKE([-Wno-portability 1.14 no-dist-gzip dist-xz tar-ustar subdir-objects])
  12
  13 dnl define PACKAGE_VERSION_* variables
  14 AS_VERSION
  15
  16 dnl check if this is a release version
  17 AS_NANO(GST_GIT="no", GST_GIT="yes")
  18
  19 dnl can autoconf find the source ?
  20 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  21
  22 dnl define the output header for config
  23 AC_CONFIG_HEADERS([config.h])
  24
  25 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  26 AM_MAINTAINER_MODE([enable])
  27
  28 dnl sets host_* variables
  29 AC_CANONICAL_HOST
  30
  31 dnl use pretty build output with automake >= 1.11
  32 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  33   [AM_DEFAULT_VERBOSITY=1
  34    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  35
  36 dnl our libraries and install dirs use GST_API_VERSION in the filename
  37 dnl to allow side-by-side installation of different API versions
  38 GST_API_VERSION=1.0
  39 AC_SUBST(GST_API_VERSION)
  40 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  41   [GStreamer API Version])
  42
  43 dnl CURRENT, REVISION, AGE
  44 dnl - library source changed -> increment REVISION
  45 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  46 dnl - interfaces added -> increment AGE
  47 dnl - interfaces removed -> AGE = 0
  48 dnl
  49 dnl Keep CURRENT as MINOR * 100 + MICRO
  50 dnl Ex : 1.0.0 => 0
  51 dnl      1.0.3 => 3
  52 dnl      1.1.0 => 100
  53 dnl      1.2.5 => 205
  54 dnl      1.10.9 (who knows) => 1009
  55 dnl
  56 dnl sets GST_LT_LDFLAGS
  57 AS_LIBTOOL(GST, 1700, 0, 1700)
  58
  59 dnl *** required versions of GStreamer stuff ***
  60 GST_REQ=1.17.0.1
  61
  62 dnl *** autotools stuff ****
  63
  64 dnl allow for different autotools
  65 AS_AUTOTOOLS_ALTERNATE
  66
  67 dnl Add parameters for aclocal
  68 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  69
  70 dnl set up gettext
  71 dnl the version check needs to stay here because autopoint greps for it
  72 AM_GNU_GETTEXT_VERSION([0.17])
  73 AM_GNU_GETTEXT([external])
  74 AG_GST_GETTEXT([gst-plugins-base-$GST_API_VERSION])
  75
  76 dnl *** check for arguments to configure ***
  77
  78 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  79 AG_GST_ARG_ENABLE_EXTRA_CHECKS
  80
  81 AG_GST_ARG_DEBUG
  82 AG_GST_ARG_PROFILING
  83 AG_GST_ARG_VALGRIND
  84 AG_GST_ARG_GCOV
  85
  86 AG_GST_ARG_EXAMPLES
  87
  88 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  89 AG_GST_ARG_WITH_PACKAGE_NAME
  90 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  91
  92 AG_GST_PKG_CONFIG_PATH
  93
  94 dnl let distro override plugin install helper path
  95 AC_ARG_WITH(install-plugins-helper,
  96   AS_HELP_STRING([--with-install-plugins-helper],[specify path of helper script to call to install plugins]),
  97   [
  98     case "${withval}" in
  99       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 100       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 101       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
 102     esac
 103   ],
 104   [
 105     dnl Default value
 106     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 107   ]
 108 )
 109 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 110 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 111     [plugin install helper script])
 112 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 113
 114 AG_GST_ARG_WITH_PLUGINS
 115
 116 AG_GST_ARG_ENABLE_EXTERNAL
 117
 118 AG_GST_ARG_ENABLE_EXPERIMENTAL
 119
 120 dnl *** checks for platform ***
 121 AG_GST_PLATFORM
 122
 123 dnl * hardware/architecture *
 124
 125 dnl common/m4/gst-arch.m4
 126 dnl check CPU type
 127 AG_GST_ARCH
 128
 129 dnl check for large file support
 130 dnl affected plugins must include config.h
 131 AC_SYS_LARGEFILE
 132
 133 dnl *** checks for programs ***
 134
 135 dnl find a compiler
 136 AC_PROG_CC
 137 AC_PROG_CC_STDC
 138
 139 dnl check if the compiler supports '-c' and '-o' options
 140 AM_PROG_CC_C_O
 141
 142 dnl determine if c++ is available on this system
 143 AC_PROG_CXX
 144 dnl CXX may be set to some default even if no c++ compiler is available
 145 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 146 AC_LANG_PUSH([C++])
 147 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ class Foo { int bar; };]], [[]])],[working_cxx=yes],[working_cxx=no])
 148 AC_LANG_POP([C++])
 149 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 150 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 151
 152 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 153 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 154
 155 dnl check for gobject-introspection
 156 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 157
 158 dnl *** checks for libraries ***
 159
 160 dnl libm, for sin() etc.
 161 LT_LIB_M
 162 AC_SUBST(LIBM)
 163
 164 dnl check for pthreads
 165 AX_PTHREAD
 166
 167 dnl *** checks for header files ***
 168
 169 dnl check if we have ANSI C header files
 170 AC_HEADER_STDC
 171
 172 dnl check for GCC specific SSE headers
 173 dnl these are used by the speex resampler code
 174 AC_CHECK_HEADERS([xmmintrin.h emmintrin.h smmintrin.h])
 175
 176 dnl also check which architecture we're on for building files with intrinsics
 177 dnl separately
 178 AC_CHECK_DECLS([__i386__], [HAVE_X86=1])
 179 AC_CHECK_DECLS([__x86_64__], [HAVE_X86=1])
 180
 181 dnl check for -m* compiler flags too
 182 SSE_CFLAGS="-msse"
 183 SSE2_CFLAGS="-msse2"
 184 SSE41_CFLAGS="-msse4.1"
 185
 186 AS_COMPILER_FLAG([$SSE_CFLAGS], [HAVE_SSE=1], [HAVE_SSE=0])
 187 AS_COMPILER_FLAG([$SSE2_CFLAGS], [HAVE_SSE2=1], [HAVE_SSE2=0])
 188 AS_COMPILER_FLAG([$SSE41_CFLAGS], [HAVE_SSE41=1], [HAVE_SSE41=0])
 189
 190 AM_CONDITIONAL(HAVE_X86, [test "x${HAVE_X86}" = "x1"])
 191
 192 AC_DEFINE_UNQUOTED(HAVE_SSE, [$HAVE_SSE], [SSE support is enabled])
 193 AC_DEFINE_UNQUOTED(HAVE_SSE2, [$HAVE_SSE2], [SSE2 support is enabled])
 194 AC_DEFINE_UNQUOTED(HAVE_SSE41, [$HAVE_SSE41], [SSE4.1 support is enabled])
 195
 196 AC_SUBST(SSE_CFLAGS)
 197 AC_SUBST(SSE2_CFLAGS)
 198 AC_SUBST(SSE41_CFLAGS)
 199
 200 dnl used in gst/tcp
 201 AC_CHECK_HEADERS([sys/socket.h],
 202   [HAVE_SYS_SOCKET_H="yes"], [HAVE_SYS_SOCKET_H="no"], [AC_INCLUDES_DEFAULT])
 203 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 204
 205 dnl used in gst-libs/gst/rtsp
 206 AC_CHECK_HEADERS([winsock2.h], [HAVE_WINSOCK2_H=yes], [HAVE_WINSOCK2_H=no], [AC_INCLUDES_DEFAULT])
 207 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 208 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 209   WIN32_LIBS="-lws2_32"
 210   AC_SUBST(WIN32_LIBS)
 211 fi
 212
 213 dnl used in gst-libs/gst/pbutils and associated unit test
 214 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h], [], [], [AC_INCLUDES_DEFAULT])
 215
 216 dnl checks for ARM NEON support
 217 dnl this instruction set is used by the speex resampler code
 218 AC_MSG_CHECKING(for ARM NEON support in current arch/CFLAGS)
 219 AC_LINK_IFELSE([
 220 AC_LANG_PROGRAM([[
 221   #include <arm_neon.h>
 222   int32x4_t __attribute__((used)) testfunc(int16_t *a, int16_t *b) {
 223       asm volatile ("vmull.s16 q0, d0, d0" : : : "q0");
 224       return vmull_s16(vld1_s16(a), vld1_s16(b));
 225   }
 226 ]])],
 227 [
 228   AC_DEFINE(HAVE_ARM_NEON,[],[ARM NEON support is enabled])
 229   AC_MSG_RESULT(yes)
 230 ],
 231 [
 232   AC_MSG_RESULT(no)
 233 ])
 234
 235 dnl also, Windows does not have long long
 236 AX_CREATE_STDINT_H
 237
 238 dnl *** checks for functions ***
 239 AC_CHECK_FUNCS([localtime_r gmtime_r])
 240
 241 dnl *** checks for math functions ***
 242 LIBS_SAVE=$LIBS
 243 LIBS="$LIBS $LIBM"
 244 AC_CHECK_FUNCS(log2)
 245 LIBS=$LIBS_SAVE
 246
 247 dnl *** checks for types/defines ***
 248
 249 dnl *** checks for structures ***
 250
 251 dnl *** checks for compiler characteristics ***
 252
 253 dnl *** checks for library functions ***
 254
 255 dnl check for fseeko()
 256 AC_FUNC_FSEEKO
 257
 258 dnl Check for fast float to int casting as defined in C99
 259 dnl used to be used in gst-libs/gst/floatcast/floatcast.h (FIXME: still needed?)
 260 save_libs=$LIBS
 261 LIBS="$LIBS $LIBM"
 262 AC_C99_FUNC_LRINT
 263 AC_C99_FUNC_LRINTF
 264 LIBS=$save_libs
 265
 266 dnl Check for a way to display the function name in debug output
 267 AG_GST_CHECK_FUNCTION
 268
 269 dnl *** checks for dependency libraries ***
 270
 271 dnl GLib
 272 GLIB_REQ=2.44.0
 273 AG_GST_GLIB_CHECK([$GLIB_REQ])
 274
 275 ORC_CHECK([0.4.24])
 276
 277 dnl For Requires.private in pkg-config files
 278 ORC_PC=
 279 if test x"$HAVE_ORC" = "xyes"; then
 280     ORC_PC="orc-0.4"
 281 fi
 282 AC_SUBST(ORC_PC)
 283
 284 dnl checks for gstreamer
 285 dnl uninstalled is selected preferentially -- see pkg-config(1)
 286 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 287 AG_GST_CHECK_GST_NET($GST_API_VERSION, [$GST_REQ], yes)
 288 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 289 AG_GST_CHECK_GST_CONTROLLER($GST_API_VERSION, [$GST_REQ], yes)
 290 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 291 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 292
 293 dnl Check for documentation xrefs
 294 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 295 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 296 AC_SUBST(GLIB_PREFIX)
 297 AC_SUBST(GST_PREFIX)
 298
 299 dnl check for gudev
 300 PKG_CHECK_MODULES(G_UDEV, gudev-1.0 , [
 301         AC_DEFINE([HAVE_GUDEV], 1, [Define if gudev is installed])
 302         HAVE_GUDEV="yes" ],
 303         [HAVE_GUDEV="no"])
 304
 305 AG_GST_GL_CHECKS
 306
 307 dnl GTK is optional and only used in examples
 308 HAVE_GTK=no
 309 HAVE_GTK_X11=no
 310 HAVE_GDK_PIXBUF=no
 311 GTK_REQ=3.10
 312 if test "x$BUILD_EXAMPLES" = "xyes"; then
 313   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 314   dnl some examples need gtk+-x11
 315   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 316   PKG_CHECK_MODULES(GTK_QUARTZ, gtk+-quartz-3.0 >= $GTK_REQ, HAVE_GTK_QUARTZ=yes, HAVE_GTK_QUARTZ=no)
 317   AC_SUBST(GTK_LIBS)
 318   AC_SUBST(GTK_CFLAGS)
 319
 320   PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0, HAVE_GDK_PIXBUF=yes, HAVE_GDK_PIXBUF=no)
 321   AC_SUBST(GDK_PIXBUF_LIBS)
 322   AC_SUBST(GDK_PIXBUF_CFLAGS)
 323 fi
 324 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 325 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 326 AM_CONDITIONAL(HAVE_GTK_QUARTZ, test "x$HAVE_GTK_QUARTZ" = "xyes")
 327 AM_CONDITIONAL(HAVE_GDK_PIXBUF, test "x$HAVE_GDK_PIXBUF" = "xyes")
 328
 329 HAVE_QT=no
 330 HAVE_QT_MOC=no
 331 dnl QT is optional and only used in examples
 332 PKG_CHECK_MODULES(QT, Qt5Gui Qt5Widgets, [
 333   HAVE_QT=yes
 334 ], [
 335   HAVE_QT=no
 336 ])
 337 if test "x$HAVE_QT" = "xyes"; then
 338   AC_CHECK_TOOL(QT_MOC, moc)
 339   AC_MSG_CHECKING([for Qt5 moc])
 340   mocversion=`$QT_MOC -v 2>&1`
 341   mocversiongrep=`echo $mocversion | grep "Qt 5\|moc 5"`
 342   if test x"$mocversiongrep" != x"$mocversion"; then
 343     AC_MSG_RESULT([no])
 344     # moc was not the qt5 one, try with moc-qt5
 345     AC_CHECK_TOOL(QT_MOC, moc-qt5)
 346     AC_MSG_CHECKING([for Qt5 moc-qt5])
 347     mocversion=`$QT_MOC -v 2>&1`
 348     mocversiongrep=`echo $mocversion | grep "Qt 5\|moc 5"`
 349     if test x"$mocversiongrep" != x"$mocversion"; then
 350       AC_CHECK_TOOL(QTCHOOSER, qtchooser)
 351       AC_MSG_CHECKING([for qtchooser])
 352       qt5tooldir=`QT_SELECT=qt5 qtchooser -print-env | grep QTTOOLDIR | cut -d '=' -f 2 | cut -d \" -f 2`
 353       mocversion=`$qt5tooldir/moc -v 2>&1`
 354       mocversiongrep=`echo $mocversion | grep "Qt 5\|moc 5"`
 355       if test x"$mocversiongrep" != x"$mocversion"; then
 356         # no valid moc found
 357         QT_MOC="no"
 358       else
 359         QT_MOC=$qt5tooldir/moc
 360       fi
 361     else
 362       QT_MOC=$QT_MOC
 363     fi
 364   fi
 365   AC_SUBST(QT_MOC)
 366   AC_MSG_RESULT([$QT_MOC])
 367 fi
 368 AM_CONDITIONAL(HAVE_QT, test "x$HAVE_QT" = "xyes")
 369 AM_CONDITIONAL(HAVE_QT_MOC, test "x$HAVE_QT_MOC" != "xno")
 370
 371 dnl Check for OpenGL example dependencies (clutter, sdl, etc.)
 372 AG_GST_GL_EXAMPLES_CHECKS
 373
 374 dnl chck for linux headers needed by the joystick seek example
 375 AC_COMPILE_IFELSE(
 376 [
 377   AC_LANG_PROGRAM([
 378     #include <linux/input.h>
 379     #include <linux/joystick.h>
 380   ],[
 381     struct js_event js;
 382     js.type = JS_EVENT_AXIS;
 383   ])
 384 ], [
 385   HAVE_LINUX_JOYSTICK_HEADERS="yes"
 386 ], [
 387   HAVE_LINUX_JOYSTICK_HEADERS="no"
 388 ])
 389 AM_CONDITIONAL(HAVE_LINUX_JOYSTICK_HEADERS, test "x$HAVE_LINUX_JOYSTICK_HEADERS" = "xyes")
 390
 391 dnl Check for -Bsymbolic-functions linker flag used to avoid
 392 dnl intra-library PLT jumps, if available.
 393 AC_ARG_ENABLE(Bsymbolic,
 394               [AS_HELP_STRING([--disable-Bsymbolic],[avoid linking with -Bsymbolic])],,
 395               [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
 396                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 397                LDFLAGS=-Wl,-Bsymbolic-functions
 398                LIBS=
 399                AC_TRY_LINK([], [return 0],
 400                            AC_MSG_RESULT(yes)
 401                            enable_Bsymbolic=yes,
 402                            AC_MSG_RESULT(no)
 403                            enable_Bsymbolic=no)
 404                LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
 405
 406
 407 dnl *** set variables based on configure arguments ***
 408
 409 dnl set license and copyright notice
 410 GST_LICENSE="LGPL"
 411 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 412 AC_SUBST(GST_LICENSE)
 413
 414 dnl set location of plugin directory
 415 AG_GST_SET_PLUGINDIR
 416
 417 dnl set release date/time
 418 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 419   ["${srcdir}/gst-plugins-base.doap"],
 420   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 421
 422 dnl If only building static libraries, define GST_STATIC_COMPILATION. This is
 423 dnl needed only on Windows, but it doesn't hurt to have it everywhere.
 424 if test x$enable_static = xyes -a x$enable_shared = xno; then
 425   GST_STATIC_CFLAGS="-DGST_STATIC_COMPILATION"
 426 fi
 427
 428 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 429 dnl make sure it doesn't complain about unused variables if debugging is disabled
 430 NO_WARNINGS=""
 431 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 432
 433 dnl define an ERROR_CFLAGS Makefile variable
 434 dnl -Wformat-nonliteral - see ext/pango/gstclockoverlay.c and http://gcc.gnu.org/bugzilla/show_bug.cgi?id=39438
 435 dnl -Waggregate-return - xcb_intern_atom() returns an aggregate value
 436 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 437     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef
 438     -Wwrite-strings  -Wformat-nonliteral -Wformat-security
 439     -Winit-self -Wmissing-include-dirs -Waddress
 440     -Wno-multichar -Wnested-externs $NO_WARNINGS])
 441
 442 dnl define an ERROR_CXXFLAGS Makefile variable
 443 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 444     -Wmissing-declarations -Wredundant-decls -Wundef
 445     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 446     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 447     -Wno-multichar $NO_WARNINGS])
 448
 449 dnl define correct level for debugging messages
 450 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 451
 452 dnl used in examples
 453 AG_GST_DEFAULT_ELEMENTS
 454
 455 dnl needed for encoding-target
 456 GST_DATADIR="$GST_PREFIX/share"
 457 AC_DEFINE_UNQUOTED(GST_DATADIR, "$GST_DATADIR", [system wide data directory])
 458 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION", [major/minor version])
 459
 460 dnl behaviour of speex based audio resampler
 461 AC_MSG_CHECKING(which audio resample format to use for integer)
 462 AC_ARG_WITH([audioresample_format],
 463         AS_HELP_STRING([--with-audioresample-format],[Which implementation should be used for integer audio resampling, int/float/auto, (default is auto)]),
 464         [ac_cv_audioresample_format=$withval], [ac_cv_audioresample_format=auto])dnl
 465 AC_MSG_RESULT($ac_cv_audioresample_format)
 466 case $ac_cv_audioresample_format in
 467   int)
 468     AC_DEFINE(AUDIORESAMPLE_FORMAT_INT,1,[The int implementation should be used for integer audio resampling])
 469     AC_SUBST(AUDIORESAMPLE_FORMAT_INT)
 470   ;;
 471   float)
 472     AC_DEFINE(AUDIORESAMPLE_FORMAT_FLOAT,1,[The float implementation should be used for integer audio resampling])
 473     AC_SUBST(AUDIORESAMPLE_FORMAT_FLOAT)
 474   ;;
 475   auto)
 476     AC_DEFINE(AUDIORESAMPLE_FORMAT_AUTO,1,[The implementation that should be used for integer audio resampling witll be benchmarked at runtime])
 477     AC_SUBST(AUDIORESAMPLE_FORMAT_AUTO)
 478 esac
 479
 480 dnl Check for mmap (needed by allocators library)
 481 AC_CHECK_FUNC([mmap], [AC_DEFINE(HAVE_MMAP, 1, [Defined if mmap is supported])])
 482
 483 dnl Check for DMABuf synchronization ioctl (needed for DMABuf CPU access)
 484 AC_CHECK_HEADERS([linux/dma-buf.h], [])
 485
 486 dnl *** plug-ins to include ***
 487
 488 dnl these are all the gst plug-ins, compilable without additional libs
 489 AG_GST_CHECK_PLUGIN(adder)
 490 AG_GST_CHECK_PLUGIN(app)
 491 AG_GST_CHECK_PLUGIN(audioconvert)
 492 AG_GST_CHECK_PLUGIN(audiomixer)
 493 AG_GST_CHECK_PLUGIN(audiorate)
 494 AG_GST_CHECK_PLUGIN(audiotestsrc)
 495 AG_GST_CHECK_PLUGIN(compositor)
 496 AG_GST_CHECK_PLUGIN(encoding)
 497 AG_GST_CHECK_PLUGIN(videoconvert)
 498 AG_GST_CHECK_PLUGIN(gio)
 499 AG_GST_CHECK_PLUGIN(overlaycomposition)
 500 AG_GST_CHECK_PLUGIN(playback)
 501 AG_GST_CHECK_PLUGIN(audioresample)
 502 AG_GST_CHECK_PLUGIN(rawparse)
 503 AG_GST_CHECK_PLUGIN(subparse)
 504 AG_GST_CHECK_PLUGIN(tcp)
 505 AG_GST_CHECK_PLUGIN(typefind)
 506 AG_GST_CHECK_PLUGIN(videotestsrc)
 507 AG_GST_CHECK_PLUGIN(videorate)
 508 AG_GST_CHECK_PLUGIN(videoscale)
 509 AG_GST_CHECK_PLUGIN(volume)
 510
 511 dnl iso-codes is optional, used by libgsttag
 512 AC_ARG_ENABLE(iso-codes,
 513 AS_HELP_STRING([--enable-iso-codes],[use iso-codes if installed]),
 514 [case "${enableval}" in
 515   yes) enable_iso_codes=yes ;;
 516   no)  enable_iso_codes=no ;;
 517   *) AC_MSG_ERROR(bad value ${enableval} for --enable-iso-codes) ;;
 518 esac
 519 ],
 520 [enable_iso_codes=yes]) dnl Default value
 521
 522 AC_MSG_CHECKING([whether to use iso-codes if they are available])
 523 if test "x$enable_iso_codes" = "xyes"; then
 524   AC_MSG_RESULT([yes])
 525   have_iso_codes=no
 526   AC_MSG_CHECKING([whether iso-codes are available on this system])
 527   if $PKG_CONFIG iso-codes; then
 528     AC_MSG_RESULT([yes])
 529     AC_MSG_CHECKING([whether iso-codes has iso-639 domain])
 530     if $PKG_CONFIG --variable=domains iso-codes | $GREP -q 639 ; then
 531       AC_MSG_RESULT([yes])
 532       AC_MSG_CHECKING([for iso-codes prefix])
 533       ISO_CODES_PREFIX=`$PKG_CONFIG --variable=prefix iso-codes`
 534       if test -d "$ISO_CODES_PREFIX"; then
 535         AC_MSG_RESULT([yes])
 536         AC_MSG_CHECKING([ISO_CODES_PREFIX])
 537         AC_MSG_RESULT([$ISO_CODES_PREFIX])
 538         ISO_639_DOMAIN="iso_639"
 539         AC_MSG_CHECKING([ISO_639_DOMAIN])
 540         AC_MSG_RESULT([$ISO_639_DOMAIN])
 541         have_iso_codes=yes
 542         AC_DEFINE([HAVE_ISO_CODES], [1], [make use of iso-codes for ISO-639])
 543         AC_DEFINE_UNQUOTED([ISO_CODES_PREFIX], ["$ISO_CODES_PREFIX"], [prefix])
 544         ISO_CODES_VERSION=`$PKG_CONFIG --modversion iso-codes`
 545         AC_DEFINE_UNQUOTED([ISO_CODES_VERSION], ["$ISO_CODES_VERSION"], [ ])
 546       else
 547         AC_MSG_RESULT([no])
 548       fi
 549     else
 550       AC_MSG_RESULT([no])
 551     fi
 552   else
 553     AC_MSG_RESULT([no])
 554   fi
 555   AM_CONDITIONAL(USE_ISO_CODES, test "x$have_iso_codes" = "xyes")
 556 else
 557   AC_MSG_RESULT([no (disabled via --disable-iso-codes)])
 558   AM_CONDITIONAL(USE_ISO_CODES, false)
 559 fi
 560
 561 dnl *** zlib is optionally used by id3 tag parsing in libgsttag ***
 562 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 563 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for ID3 parsing in libgsttag],, [
 564   PKG_CHECK_MODULES(ZLIB, [ zlib ], [
 565       HAVE_ZLIB="yes"
 566     ], [
 567       AG_GST_CHECK_LIBHEADER(ZLIB, z, uncompress,, zlib.h, [
 568         HAVE_ZLIB="yes"
 569         ZLIB_LIBS="-lz"
 570         AC_SUBST(ZLIB_LIBS)
 571       ])
 572     ])
 573 ])
 574
 575 dnl *** sys plug-ins ***
 576
 577 echo
 578 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 579 echo
 580
 581 dnl *** X11 ***
 582 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 583 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 584                   [ximagesink], [
 585   AG_GST_PKG_CHECK_MODULES(X, x11)
 586 ])
 587
 588 dnl Check for Xv extension
 589 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 590 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 591                   [xvimagesink], [
 592   AG_GST_PKG_CHECK_MODULES(XVIDEO, x11 xv)
 593 ])
 594
 595 dnl check for X Shm
 596 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 597 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], [ ], [
 598   if test x$HAVE_X = xyes; then
 599     PKG_CHECK_MODULES(XSHM, xext, [
 600       AC_CHECK_LIB(Xext, XShmAttach, [
 601         HAVE_XSHM="yes"
 602       ], [
 603         HAVE_XSHM="no"
 604         XSHM_LIBS=""
 605       ], [ $X_LIBS ])
 606     ], [
 607       HAVE_XSHM="no"
 608     ])
 609   fi
 610 ], , [
 611   AC_SUBST(HAVE_XSHM)
 612   AC_SUBST(XSHM_LIBS)
 613 ])
 614
 615 dnl *** ext plug-ins ***
 616 dnl keep this list sorted alphabetically !
 617
 618 if test "x$BUILD_EXTERNAL" = "xyes"; then
 619
 620 echo
 621 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 622 echo
 623
 624 dnl *** alsa ***
 625 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 626 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 627   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 628     HAVE_ALSA="yes"
 629     AC_SUBST(ALSA_CFLAGS)
 630     AC_SUBST(ALSA_LIBS)
 631   ], [
 632     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 633   ])
 634 ])
 635
 636 dnl *** CDParanoia ***
 637 dnl Note: upstream has a pkg-config file only in post-10.2 SVN so far
 638 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 639 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 640   PKG_CHECK_MODULES(CDPARANOIA, cdparanoia-3 >= 10.2, [
 641     HAVE_CDPARANOIA="yes"
 642   ], [
 643     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 644                         cdda_open, -lm,
 645                         cdda_interface.h,
 646                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 647                         HEADER_DIR="no"
 648                         FOUND_CDPARANOIA="yes")
 649     if test "x$FOUND_CDPARANOIA" != "xyes";
 650     then
 651       AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 652                           cdda_open, -lm,
 653                           cdda/cdda_interface.h,
 654                           CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 655                           HEADER_DIR="yes"
 656                           FOUND_CDPARANOIA="yes")
 657     fi
 658     if test "x$HEADER_DIR" = "xyes";
 659     then
 660       AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 661                          defined if cdda headers are in a cdda/ directory)
 662     fi
 663     if test "x$FOUND_CDPARANOIA" = "xyes";
 664     then
 665       AC_CHECK_LIB(cdda_paranoia,
 666                    paranoia_cachemodel_size,
 667                    : ,
 668                    HAVE_CDPARANOIA=no,
 669                  [-lcdda_interface])
 670     fi
 671
 672     AC_SUBST(CDPARANOIA_LIBS)
 673   ])
 674 ])
 675 dnl FIXME : add second check somehow if that is necessary
 676 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 677 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 678
 679 dnl *** gl ***
 680 translit(dnm, m, l) AM_CONDITIONAL(USE_GL, true)
 681 AG_GST_CHECK_FEATURE(GL, [gl elements], gl, [
 682   HAVE_GL="no"
 683
 684   if test x"$USE_OPENGL" = x"yes" -o x"$USE_GLES2" = x"yes"; then
 685     HAVE_GL="yes"
 686     AG_GST_GL_PLUGIN_CHECKS
 687   fi
 688 ])
 689
 690 dnl *** ivorbis ***
 691 dnl AM_PATH_IVORBIS only takes two options
 692 translit(dnm, m, l) AM_CONDITIONAL(USE_IVORBIS, true)
 693 AG_GST_CHECK_FEATURE(IVORBIS, [integer vorbis plug-in], ivorbisdec, [
 694   AG_GST_PKG_CHECK_MODULES(IVORBIS, vorbisidec)
 695   if test $HAVE_IVORBIS = no
 696   then
 697     IVORBIS_LIBS=
 698     IVORBIS_CFLAGS=
 699     AC_CHECK_LIB(vorbisidec, vorbis_block_init,
 700       [IVORBIS_LIBS=-lvorbisidec
 701       HAVE_IVORBIS=yes
 702       case $host in
 703       arm-*-*)
 704         IVORBIS_CFLAGS="-D_ARM_ASSEM_ $IVORBIS_CFLAGS"
 705       esac
 706       ],
 707       HAVE_IVORBIS=no)
 708     AC_SUBST(IVORBIS_LIBS)
 709     AC_SUBST(IVORBIS_CFLAGS)
 710   else
 711     AC_CHECK_LIB(vorbisidec, vorbis_dsp_pcmout,
 712       AC_DEFINE([USE_TREMOLO],1, "Define if building for android"),
 713       USE_TREMOLO=no)
 714   fi
 715 ])
 716
 717 dnl *** libvisual ***
 718 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 719 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 720   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 721   if test x$HAVE_LIBVISUAL = xyes; then
 722     LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.4`"
 723   fi
 724   AC_MSG_NOTICE([libvisual pluginsdir: $LIBVIS_PLUGINSDIR])
 725   if test x$LIBVIS_PLUGINSDIR != x; then
 726     AC_DEFINE_UNQUOTED(LIBVISUAL_PLUGINSBASEDIR,
 727         "$LIBVIS_PLUGINSDIR",
 728         [directory in which the detected libvisual's plugins are located])
 729   fi
 730 ])
 731
 732 dnl *** ogg ***
 733 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 734 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 735   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 736 ])
 737
 738 dnl *** Opus ***
 739 translit(dnm, m, l) AM_CONDITIONAL(USE_OPUS, true)
 740 AG_GST_CHECK_FEATURE(OPUS, [opus], opus, [
 741   PKG_CHECK_MODULES(OPUS, opus >= 0.9.4, [
 742           AC_DEFINE([HAVE_OPUS], 1, [Define if Opus >= 0.9.4 is installed])
 743           HAVE_OPUS="yes"
 744   ], [
 745           HAVE_OPUS="no"
 746   ])
 747   AC_SUBST(OPUS_CFLAGS)
 748   AC_SUBST(OPUS_LIBS)
 749 ])
 750
 751 dnl *** pango ***
 752 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 753 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 754   AG_GST_PKG_CHECK_MODULES(PANGO, pango >= 1.22.0  pangocairo >= 1.22.0)
 755 ])
 756
 757 dnl *** theora ***
 758 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 759 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 760   AG_GST_PKG_CHECK_MODULES(THEORA, theoradec >= 1.1 theoraenc >= 1.1)
 761 ])
 762
 763 dnl *** vorbis ***
 764 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 765 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 766   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 767 ])
 768
 769 if test "x$HAVE_VORBIS" = "xyes"; then
 770   ac_cflags_save="$CFLAGS"
 771   AC_COMPILE_IFELSE([
 772     AC_LANG_PROGRAM([[
 773 #include <vorbis/codec.h>
 774                      ]],[[
 775 vorbis_dsp_state *v;
 776
 777 vorbis_synthesis_restart (v);
 778                      ]])], HAVE_VSR=yes, HAVE_VSR=no)
 779   if test "x$HAVE_VSR" = "xyes"; then
 780     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 781                        [defined if vorbis_synthesis_restart is present])
 782   fi
 783   CFLAGS="$ac_cflags_save"
 784 fi
 785
 786 else
 787
 788 dnl not building plugins with external dependencies,
 789 dnl but we still need to set the conditionals
 790 AM_CONDITIONAL(USE_ALSA, false)
 791 AM_CONDITIONAL(USE_CDPARANOIA, false)
 792 AM_CONDITIONAL(USE_GL, false)
 793 AM_CONDITIONAL(USE_IVORBIS, false)
 794 AM_CONDITIONAL(USE_LIBVISUAL, false)
 795 AM_CONDITIONAL(USE_OGG, false)
 796 AM_CONDITIONAL(USE_OPUS, false)
 797 AM_CONDITIONAL(USE_PANGO, false)
 798 AM_CONDITIONAL(USE_THEORA, false)
 799 AM_CONDITIONAL(USE_VORBIS, false)
 800
 801 fi dnl of EXT plugins
 802
 803 AM_CONDITIONAL(HAVE_GRAPHENE, test "x$HAVE_GRAPHENE" = "xyes")
 804 AM_CONDITIONAL(HAVE_PNG, test "x$HAVE_PNG" = "xyes")
 805 AM_CONDITIONAL(HAVE_JPEG, test "x$HAVE_JPEG" = "xyes")
 806
 807 dnl *** gio-unix-2.0 for tests/check/pipelines/tcp.c ***
 808 PKG_CHECK_MODULES(GIO_UNIX_2_0, gio-unix-2.0 >= 2.24,
 809     HAVE_GIO_UNIX_2_0="yes",
 810     HAVE_GIO_UNIX_2_0="no")
 811 AM_CONDITIONAL(USE_GIO_UNIX_2_0, test "x$HAVE_GIO_UNIX_2_0" = "xyes")
 812
 813 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 814
 815 dnl Overview:
 816 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 817 dnl GST_*:              flags shared by built objects to link against GStreamer
 818 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 819 dnl                          (compare to other modules) or for i18n
 820 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 821 dnl GST_LIB_LDFLAGS:    additional linker flags for all libraries
 822 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 823 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 824
 825 dnl GST_OPTION_CFLAGS
 826 if test "x$USE_DEBUG" = xyes; then
 827    PROFILE_CFLAGS="-g"
 828 fi
 829 AC_SUBST(PROFILE_CFLAGS)
 830
 831 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 832   dnl Define _only_ when compiling a git version (not pre-releases or releases)
 833   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 834 else
 835   DEPRECATED_CFLAGS=""
 836 fi
 837 AC_SUBST(DEPRECATED_CFLAGS)
 838
 839 VISIBILITY_CFLAGS=""
 840 AS_COMPILER_FLAG([-fvisibility=hidden], [
 841   VISIBILITY_CFLAGS="-fvisibility=hidden"
 842   AC_DEFINE(GST_API_EXPORT, [extern __attribute__ ((visibility ("default")))], [public symbol export define])
 843 ], [
 844   VISIBILITY_CFLAGS=""
 845   AC_DEFINE(GST_API_EXPORT, [extern], [public symbol export define])
 846 ])
 847 AC_SUBST(VISIBILITY_CFLAGS)
 848
 849 VISIBILITY_CXXFLAGS=""
 850 if test "x$HAVE_CXX" = "xyes"; then
 851   AS_CXX_COMPILER_FLAG([-fvisibility=hidden], [VISIBILITY_CXXFLAGS="-fvisibility=hidden"])
 852 fi
 853 AC_SUBST(VISIBILITY_CXXFLAGS)
 854
 855 dnl disable strict aliasing
 856 AS_COMPILER_FLAG([-fno-strict-aliasing], [EXTRA_CFLAGS="-fno-strict-aliasing"])
 857 AC_SUBST(EXTRA_CFLAGS)
 858
 859 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 860 dnl at make time with e.g. make ERROR_CFLAGS=""
 861 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 862 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 863 AC_SUBST(GST_OPTION_CFLAGS)
 864 AC_SUBST(GST_OPTION_CXXFLAGS)
 865
 866 dnl our libraries need to be versioned correctly
 867 AC_SUBST(GST_LT_LDFLAGS)
 868
 869 dnl GST_PLUGINS_BASE_CFLAGS
 870 dnl prefer internal headers to already installed ones
 871 dnl also add builddir include for enumtypes and marshal
 872 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 873 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 874
 875 dnl FIXME: do we want to rename to GST_ALL_* ?
 876 dnl add GST_OPTION_CFLAGS, but overridable
 877 GST_CFLAGS="$GST_CFLAGS $GST_STATIC_CFLAGS"
 878 GST_CXXFLAGS="$GLIB_CFLAGS $GST_CFLAGS $EXTRA_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CXXFLAGS) \$(VISIBILITY_CXXFLAGS)"
 879 GST_CFLAGS="$GLIB_CFLAGS $GST_CFLAGS $EXTRA_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CFLAGS) \$(VISIBILITY_CFLAGS)"
 880 AC_SUBST(GST_CFLAGS)
 881 AC_SUBST(GST_CXXFLAGS)
 882 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 883 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 884 AC_SUBST(GST_LIBS)
 885
 886 dnl LDFLAGS really should only contain flags, not libs - they get added before
 887 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 888 GST_ALL_LDFLAGS="-no-undefined"
 889 if test "x${enable_Bsymbolic}" = "xyes"; then
 890   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 891 fi
 892 AC_SUBST(GST_ALL_LDFLAGS)
 893
 894 dnl GST_LIB_LDFLAGS
 895 dnl linker flags shared by all libraries
 896 dnl LDFLAGS modifier defining exported symbols from built libraries
 897 dnl (export _gst_foo but not __gst_foo)
 898 GST_LIB_LDFLAGS=""
 899 AC_SUBST(GST_LIB_LDFLAGS)
 900
 901 dnl this really should only contain flags, not libs - they get added before
 902 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 903 GST_PLUGIN_LDFLAGS="-module -avoid-version $GST_ALL_LDFLAGS"
 904 AC_SUBST(GST_PLUGIN_LDFLAGS)
 905
 906 dnl *** output files ***
 907
 908 $MKDIR_P tests/check/orc
 909
 910 AC_CONFIG_FILES(
 911 Makefile
 912 gst/Makefile
 913 gst/adder/Makefile
 914 gst/app/Makefile
 915 gst/audioconvert/Makefile
 916 gst/audiomixer/Makefile
 917 gst/audiorate/Makefile
 918 gst/audioresample/Makefile
 919 gst/audiotestsrc/Makefile
 920 gst/compositor/Makefile
 921 gst/encoding/Makefile
 922 gst/videoconvert/Makefile
 923 gst/gio/Makefile
 924 gst/overlaycomposition/Makefile
 925 gst/pbtypes/Makefile
 926 gst/playback/Makefile
 927 gst/rawparse/Makefile
 928 gst/subparse/Makefile
 929 gst/tcp/Makefile
 930 gst/typefind/Makefile
 931 gst/videotestsrc/Makefile
 932 gst/videorate/Makefile
 933 gst/videoscale/Makefile
 934 gst/volume/Makefile
 935 sys/Makefile
 936 sys/ximage/Makefile
 937 sys/xvimage/Makefile
 938 ext/Makefile
 939 ext/alsa/Makefile
 940 ext/cdparanoia/Makefile
 941 ext/gl/Makefile
 942 ext/libvisual/Makefile
 943 ext/ogg/Makefile
 944 ext/opus/Makefile
 945 ext/pango/Makefile
 946 ext/theora/Makefile
 947 ext/vorbis/Makefile
 948 gst-libs/Makefile
 949 gst-libs/gst/Makefile
 950 gst-libs/gst/allocators/Makefile
 951 gst-libs/gst/audio/Makefile
 952 gst-libs/gst/app/Makefile
 953 gst-libs/gst/fft/Makefile
 954 gst-libs/gst/gl/Makefile
 955 gst-libs/gst/gl/android/Makefile
 956 gst-libs/gst/gl/cocoa/Makefile
 957 gst-libs/gst/gl/dispmanx/Makefile
 958 gst-libs/gst/gl/glprototypes/Makefile
 959 gst-libs/gst/gl/eagl/Makefile
 960 gst-libs/gst/gl/egl/Makefile
 961 gst-libs/gst/gl/wayland/Makefile
 962 gst-libs/gst/gl/win32/Makefile
 963 gst-libs/gst/gl/x11/Makefile
 964 gst-libs/gst/gl/viv-fb/Makefile
 965 gst-libs/gst/gl/gbm/Makefile
 966 gst-libs/gst/riff/Makefile
 967 gst-libs/gst/rtp/Makefile
 968 gst-libs/gst/rtsp/Makefile
 969 gst-libs/gst/sdp/Makefile
 970 gst-libs/gst/tag/Makefile
 971 gst-libs/gst/pbutils/Makefile
 972 gst-libs/gst/pbutils/gstpluginsbaseversion.h
 973 gst-libs/gst/video/Makefile
 974 tools/Makefile
 975 pkgconfig/Makefile
 976 pkgconfig/gstreamer-allocators.pc
 977 pkgconfig/gstreamer-allocators-uninstalled.pc
 978 pkgconfig/gstreamer-audio.pc
 979 pkgconfig/gstreamer-audio-uninstalled.pc
 980 pkgconfig/gstreamer-app.pc
 981 pkgconfig/gstreamer-app-uninstalled.pc
 982 pkgconfig/gstreamer-fft.pc
 983 pkgconfig/gstreamer-fft-uninstalled.pc
 984 pkgconfig/gstreamer-pbutils.pc
 985 pkgconfig/gstreamer-pbutils-uninstalled.pc
 986 pkgconfig/gstreamer-riff.pc
 987 pkgconfig/gstreamer-riff-uninstalled.pc
 988 pkgconfig/gstreamer-rtp.pc
 989 pkgconfig/gstreamer-rtp-uninstalled.pc
 990 pkgconfig/gstreamer-rtsp.pc
 991 pkgconfig/gstreamer-rtsp-uninstalled.pc
 992 pkgconfig/gstreamer-sdp.pc
 993 pkgconfig/gstreamer-sdp-uninstalled.pc
 994 pkgconfig/gstreamer-tag.pc
 995 pkgconfig/gstreamer-tag-uninstalled.pc
 996 pkgconfig/gstreamer-video.pc
 997 pkgconfig/gstreamer-video-uninstalled.pc
 998 pkgconfig/gstreamer-gl.pc
 999 pkgconfig/gstreamer-gl-uninstalled.pc
1000 pkgconfig/gstreamer-plugins-base.pc
1001 pkgconfig/gstreamer-plugins-base-uninstalled.pc
1002 tests/Makefile
1003 tests/check/Makefile
1004 tests/examples/Makefile
1005 tests/examples/app/Makefile
1006 tests/examples/audio/Makefile
1007 tests/examples/compositor/Makefile
1008 tests/examples/decodebin_next/Makefile
1009 tests/examples/dynamic/Makefile
1010 tests/examples/encoding/Makefile
1011 tests/examples/fft/Makefile
1012 tests/examples/gio/Makefile
1013 tests/examples/gl/Makefile
1014 tests/examples/gl/generic/Makefile
1015 tests/examples/gl/generic/cube/Makefile
1016 tests/examples/gl/generic/doublecube/Makefile
1017 tests/examples/gl/generic/recordgraphic/Makefile
1018 tests/examples/gl/generic/cubeyuv/Makefile
1019 tests/examples/gl/qt/Makefile
1020 tests/examples/gl/gtk/Makefile
1021 tests/examples/gl/gtk/fxtest/Makefile
1022 tests/examples/gl/gtk/3dvideo/Makefile
1023 tests/examples/gl/gtk/switchvideooverlay/Makefile
1024 tests/examples/gl/gtk/filternovideooverlay/Makefile
1025 tests/examples/gl/gtk/filtervideooverlay/Makefile
1026 tests/examples/gl/cocoa/Makefile
1027 tests/examples/gl/sdl/Makefile
1028 tests/examples/overlay/Makefile
1029 tests/examples/overlaycomposition/Makefile
1030 tests/examples/seek/Makefile
1031 tests/examples/snapshot/Makefile
1032 tests/examples/playback/Makefile
1033 tests/examples/playrec/Makefile
1034 tests/files/Makefile
1035 tests/icles/Makefile
1036 tests/icles/playback/Makefile
1037 po/Makefile.in
1038 common/Makefile
1039 common/m4/Makefile
1040 m4/Makefile
1041 )
1042 AC_OUTPUT
1043
1044 AG_GST_OUTPUT_PLUGINS
1045 ORC_OUTPUT
1046