configure.ac

   1 AC_PREREQ([2.68])
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/prerelease
   8 AC_INIT([GStreamer Base Plug-ins],[1.1.0.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gst-plugins-base])
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.11 no-dist-gzip dist-xz tar-ustar])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  23
  24 dnl define the output header for config
  25 AC_CONFIG_HEADERS([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output with automake >= 1.11
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  35   [AM_DEFAULT_VERBOSITY=1
  36    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  37
  38 dnl our libraries and install dirs use GST_API_VERSION in the filename
  39 dnl to allow side-by-side installation of different API versions
  40 GST_API_VERSION=1.0
  41 AC_SUBST(GST_API_VERSION)
  42 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  43   [GStreamer API Version])
  44
  45 dnl CURRENT, REVISION, AGE
  46 dnl - library source changed -> increment REVISION
  47 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  48 dnl - interfaces added -> increment AGE
  49 dnl - interfaces removed -> AGE = 0
  50 dnl sets GST_LT_LDFLAGS
  51 AS_LIBTOOL(GST, 2, 0, 2)
  52
  53 dnl *** required versions of GStreamer stuff ***
  54 GST_REQ=1.1.0
  55
  56 dnl *** autotools stuff ****
  57
  58 dnl allow for different autotools
  59 AS_AUTOTOOLS_ALTERNATE
  60
  61 dnl Add parameters for aclocal
  62 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  63
  64 dnl set up gettext
  65 dnl the version check needs to stay here because autopoint greps for it
  66 AM_GNU_GETTEXT_VERSION([0.17])
  67 AM_GNU_GETTEXT([external])
  68 AG_GST_GETTEXT([gst-plugins-base-$GST_API_VERSION])
  69
  70 dnl *** check for arguments to configure ***
  71
  72 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  73
  74 AG_GST_ARG_DEBUG
  75 AG_GST_ARG_PROFILING
  76 AG_GST_ARG_VALGRIND
  77 AG_GST_ARG_GCOV
  78
  79 AG_GST_ARG_EXAMPLES
  80
  81 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  82 AG_GST_ARG_WITH_PACKAGE_NAME
  83 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  84
  85 AG_GST_PKG_CONFIG_PATH
  86
  87 dnl let distro override plugin install helper path
  88 AC_ARG_WITH(install-plugins-helper,
  89   AS_HELP_STRING([--with-install-plugins-helper],[specify path of helper script to call to install plugins]),
  90   [
  91     case "${withval}" in
  92       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
  93       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
  94       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
  95     esac
  96   ],
  97   [
  98     dnl Default value
  99     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 100   ]
 101 )
 102 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 103 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 104     [plugin install helper script])
 105 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 106
 107 AG_GST_ARG_WITH_PLUGINS
 108
 109 AG_GST_ARG_ENABLE_EXTERNAL
 110
 111 AG_GST_ARG_ENABLE_EXPERIMENTAL
 112
 113 dnl *** checks for platform ***
 114 AG_GST_PLATFORM
 115
 116 dnl * hardware/architecture *
 117
 118 dnl common/m4/gst-arch.m4
 119 dnl check CPU type
 120 AG_GST_ARCH
 121
 122 dnl check for large file support
 123 dnl affected plugins must include config.h
 124 AC_SYS_LARGEFILE
 125
 126 dnl *** checks for programs ***
 127
 128 dnl find a compiler
 129 AC_PROG_CC
 130 AC_PROG_CC_STDC
 131
 132 dnl check if the compiler supports '-c' and '-o' options
 133 AM_PROG_CC_C_O
 134
 135 dnl determine if c++ is available on this system
 136 AC_PROG_CXX
 137 dnl CXX may be set to some default even if no c++ compiler is available
 138 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 139 AC_LANG_PUSH([C++])
 140 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ class Foo { int bar; };]], [[]])],[working_cxx=yes],[working_cxx=no])
 141 AC_LANG_POP([C++])
 142 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 143 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 144
 145 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 146 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 147
 148 dnl check for gobject-introspection
 149 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 150
 151 dnl check for documentation tools
 152 GTK_DOC_CHECK([1.12])
 153 AG_GST_PLUGIN_DOCS([1.12])
 154
 155 dnl *** checks for libraries ***
 156
 157 dnl libm, for sin() etc.
 158 LT_LIB_M
 159 AC_SUBST(LIBM)
 160
 161 dnl *** checks for header files ***
 162
 163 dnl check if we have ANSI C header files
 164 AC_HEADER_STDC
 165
 166 dnl check for GCC specific SSE headers
 167 dnl these are used by the speex resampler code
 168 AC_CHECK_HEADERS([xmmintrin.h emmintrin.h])
 169
 170 ac_cppflags_save="$CPPFLAGS"
 171 CPPFLAGS="`$PKG_CONFIG --cflags libxml-2.0`"
 172 AC_COMPILE_IFELSE([
 173   AC_LANG_PROGRAM([[
 174 #include <libxml/HTMLparser.h>
 175 ]],[[
 176 #ifndef LIBXML_HTML_ENABLED
 177 #error libxml2 has no HTML support
 178 #endif /* LIBXML_HTML_ENABLED */
 179 ]])], [
 180   HAVE_LIBXML_HTML="yes"
 181 ], [
 182   HAVE_LIBXML_HTML="no"
 183 ])
 184 CPPFLAGS="$ac_cppflags_save"
 185 AM_CONDITIONAL(HAVE_LIBXML_HTML, test "x$HAVE_LIBXML_HTML" = "xyes")
 186
 187 dnl used in gst/tcp
 188 AC_CHECK_HEADERS([sys/socket.h],
 189   [HAVE_SYS_SOCKET_H="yes"], [HAVE_SYS_SOCKET_H="no"], [AC_INCLUDES_DEFAULT])
 190 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 191
 192 dnl used in gst-libs/gst/pbutils and associated unit test
 193 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h], [], [], [AC_INCLUDES_DEFAULT])
 194
 195 dnl checks for ARM NEON support
 196 dnl this instruction set is used by the speex resampler code
 197 AC_MSG_CHECKING(for ARM NEON support in current arch/CFLAGS)
 198 AC_LINK_IFELSE([
 199 AC_LANG_PROGRAM([[
 200   #include <arm_neon.h>
 201   int32x4_t testfunc(int16_t *a, int16_t *b) {
 202       return vmull_s16(vld1_s16(a), vld1_s16(b));
 203   }
 204 ]])],
 205 [
 206   AC_DEFINE(HAVE_ARM_NEON,[],[ARM NEON support is enabled])
 207   AC_MSG_RESULT(yes)
 208 ],
 209 [
 210   AC_MSG_RESULT(no)
 211 ])
 212
 213 dnl also, Windows does not have long long
 214 AX_CREATE_STDINT_H
 215
 216 dnl *** checks for functions ***
 217 AC_CHECK_FUNCS([localtime_r gmtime_r])
 218
 219 dnl *** checks for math functions ***
 220 LIBS_SAVE=$LIBS
 221 LIBS="$LIBS $LIBM"
 222 AC_CHECK_FUNCS(log2)
 223 LIBS=$LIBS_SAVE
 224
 225 dnl *** checks for types/defines ***
 226
 227 dnl *** checks for structures ***
 228
 229 dnl *** checks for compiler characteristics ***
 230
 231 dnl *** checks for library functions ***
 232
 233 dnl check for fseeko()
 234 AC_FUNC_FSEEKO
 235
 236 dnl Check for fast float to int casting as defined in C99
 237 dnl used to be used in gst-libs/gst/floatcast/floatcast.h (FIXME: still needed?)
 238 save_libs=$LIBS
 239 LIBS="$LIBS $LIBM"
 240 AC_C99_FUNC_LRINT
 241 AC_C99_FUNC_LRINTF
 242 LIBS=$save_libs
 243
 244 dnl Check for a way to display the function name in debug output
 245 AG_GST_CHECK_FUNCTION
 246
 247 dnl *** checks for dependency libraries ***
 248
 249 dnl GLib
 250 GLIB_REQ=2.32
 251 AG_GST_GLIB_CHECK([$GLIB_REQ])
 252
 253 ORC_CHECK([0.4.16])
 254
 255 dnl checks for gstreamer
 256 dnl uninstalled is selected preferentially -- see pkg-config(1)
 257 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 258 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 259 AG_GST_CHECK_GST_CONTROLLER($GST_API_VERSION, [$GST_REQ], yes)
 260 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 261 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 262
 263 dnl Check for documentation xrefs
 264 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 265 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 266 AC_SUBST(GLIB_PREFIX)
 267 AC_SUBST(GST_PREFIX)
 268
 269 dnl GTK is optional and only used in examples
 270 HAVE_GTK=no
 271 HAVE_GTK_X11=no
 272 GTK_REQ=3.0.0
 273 if test "x$BUILD_EXAMPLES" = "xyes"; then
 274   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 275   dnl some examples need gtk+-x11
 276   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 277   PKG_CHECK_MODULES(GTK_QUARTZ, gtk+-quartz-3.0 >= $GTK_REQ, HAVE_GTK_QUARTZ=yes, HAVE_GTK_QUARTZ=no)
 278   AC_SUBST(GTK_LIBS)
 279   AC_SUBST(GTK_CFLAGS)
 280 fi
 281 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 282 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 283 AM_CONDITIONAL(HAVE_GTK_QUARTZ, test "x$HAVE_GTK_QUARTZ" = "xyes")
 284
 285 dnl QT is optional and only used in examples
 286 PKG_CHECK_MODULES(QT, QtGui >= 4.6, [
 287   HAVE_QT_GV=yes
 288   HAVE_QT=yes
 289 ], [
 290   HAVE_QT_GV=no
 291   PKG_CHECK_MODULES(QT, QtGui >= 4.0, HAVE_QT=yes, HAVE_QT=no)
 292 ])
 293 if test "x$HAVE_QT" = "xyes"; then
 294   AC_MSG_CHECKING([Qt moc])
 295   QT4_MOC=`$PKG_CONFIG --variable=moc_location QtGui`
 296   AC_MSG_RESULT($QT4_MOC)
 297   AC_SUBST(QT4_MOC)
 298 fi
 299 AM_CONDITIONAL(HAVE_QT, test "x$HAVE_QT" = "xyes")
 300 AM_CONDITIONAL(HAVE_QT_GV, test "x$HAVE_QT_GV" = "xyes")
 301
 302 dnl chck for linux headers needed by the joystick seek example
 303 AC_COMPILE_IFELSE(
 304 [
 305   AC_LANG_PROGRAM([
 306     #include <linux/input.h>
 307     #include <linux/joystick.h>
 308   ],[
 309     struct js_event js;
 310     js.type = JS_EVENT_AXIS;
 311   ])
 312 ], [
 313   HAVE_LINUX_JOYSTICK_HEADERS="yes"
 314 ], [
 315   HAVE_LINUX_JOYSTICK_HEADERS="no"
 316 ])
 317 AM_CONDITIONAL(HAVE_LINUX_JOYSTICK_HEADERS, test "x$HAVE_LINUX_JOYSTICK_HEADERS" = "xyes")
 318
 319 dnl Check for -Bsymbolic-functions linker flag used to avoid
 320 dnl intra-library PLT jumps, if available.
 321 AC_ARG_ENABLE(Bsymbolic,
 322               [AS_HELP_STRING([--disable-Bsymbolic],[avoid linking with -Bsymbolic])],,
 323               [SAVED_LDFLAGS="${LDFLAGS}"
 324                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 325                LDFLAGS=-Wl,-Bsymbolic-functions
 326                AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int main (void) { return 0; }]])],[
 327                            AC_MSG_RESULT(yes)
 328                            enable_Bsymbolic=yes],[
 329                            AC_MSG_RESULT(no)
 330                            enable_Bsymbolic=no])
 331                LDFLAGS="${SAVED_LDFLAGS}"])
 332
 333
 334 dnl *** set variables based on configure arguments ***
 335
 336 dnl set license and copyright notice
 337 GST_LICENSE="LGPL"
 338 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 339 AC_SUBST(GST_LICENSE)
 340
 341 dnl set location of plugin directory
 342 AG_GST_SET_PLUGINDIR
 343
 344 dnl set release date/time
 345 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 346   ["${srcdir}/gst-plugins-base.doap"],
 347   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 348
 349 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 350 dnl make sure it doesn't complain about unused variables if debugging is disabled
 351 NO_WARNINGS=""
 352 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 353
 354 dnl define an ERROR_CFLAGS Makefile variable
 355 dnl -Wformat-nonliteral - see ext/pango/gstclockoverlay.c and http://gcc.gnu.org/bugzilla/show_bug.cgi?id=39438
 356 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 357     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef
 358     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 359     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 360     -Wno-multichar -Wnested-externs $NO_WARNINGS])
 361
 362 dnl define an ERROR_CXXFLAGS Makefile variable
 363 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 364     -Wmissing-declarations -Wredundant-decls -Wundef
 365     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 366     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 367     -Wno-multichar $NO_WARNINGS])
 368
 369 dnl define correct level for debugging messages
 370 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 371
 372 dnl used in examples
 373 AG_GST_DEFAULT_ELEMENTS
 374
 375 dnl needed for encoding-target
 376 GST_DATADIR="$GST_PREFIX/share"
 377 AC_DEFINE_UNQUOTED(GST_DATADIR, "$GST_DATADIR", [system wide data directory])
 378 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION", [major/minor version])
 379
 380 dnl behaviour of speex based audio resampler
 381 AC_MSG_CHECKING(which audio resample format to use for integer)
 382 AC_ARG_WITH([audioresample_format],
 383         AS_HELP_STRING([--with-audioresample-format],[Which implementation should be used for integer audio resampling, int/float/auto, (default is auto)]),
 384         [ac_cv_audioresample_format=$withval], [ac_cv_audioresample_format=auto])dnl
 385 AC_MSG_RESULT($ac_cv_audioresample_format)
 386 case $ac_cv_audioresample_format in
 387   int)
 388     AC_DEFINE(AUDIORESAMPLE_FORMAT_INT,1,[The int implementation should be used for integer audio resampling])
 389     AC_SUBST(AUDIORESAMPLE_FORMAT_INT)
 390   ;;
 391   float)
 392     AC_DEFINE(AUDIORESAMPLE_FORMAT_FLOAT,1,[The float implementation should be used for integer audio resampling])
 393     AC_SUBST(AUDIORESAMPLE_FORMAT_FLOAT)
 394   ;;
 395   auto)
 396     AC_DEFINE(AUDIORESAMPLE_FORMAT_AUTO,1,[The implementation that should be used for integer audio resampling witll be benchmarked at runtime])
 397     AC_SUBST(AUDIORESAMPLE_FORMAT_AUTO)
 398 esac
 399
 400 dnl *** plug-ins to include ***
 401
 402 dnl these are all the gst plug-ins, compilable without additional libs
 403 AG_GST_CHECK_PLUGIN(adder)
 404 AG_GST_CHECK_PLUGIN(app)
 405 AG_GST_CHECK_PLUGIN(audioconvert)
 406 AG_GST_CHECK_PLUGIN(audiorate)
 407 AG_GST_CHECK_PLUGIN(audiotestsrc)
 408 AG_GST_CHECK_PLUGIN(encoding)
 409 AG_GST_CHECK_PLUGIN(videoconvert)
 410 AG_GST_CHECK_PLUGIN(gio)
 411 AG_GST_CHECK_PLUGIN(playback)
 412 AG_GST_CHECK_PLUGIN(audioresample)
 413 AG_GST_CHECK_PLUGIN(subparse)
 414 AG_GST_CHECK_PLUGIN(tcp)
 415 AG_GST_CHECK_PLUGIN(typefind)
 416 AG_GST_CHECK_PLUGIN(videotestsrc)
 417 AG_GST_CHECK_PLUGIN(videorate)
 418 AG_GST_CHECK_PLUGIN(videoscale)
 419 AG_GST_CHECK_PLUGIN(volume)
 420
 421 dnl FIXME 0.11: check for libxml, split subparse and move libxml parts to ext/
 422 AM_CONDITIONAL(USE_XML, false)
 423 AC_DEFINE([GST_DISABLE_XML], [1], [set to disable libxml2-dependent code in subparse])
 424
 425 dnl disable plug-ins that require libxml2's HTML support if it is not available
 426 if test "x$HAVE_LIBXML_HTML" != "xyes"; then
 427   AG_GST_DISABLE_PLUGIN(subparse)
 428 fi
 429
 430 dnl iso-codes is optional, used by libgsttag
 431 AC_ARG_ENABLE(iso-codes,
 432 AS_HELP_STRING([--enable-iso-codes],[use iso-codes if installed]),
 433 [case "${enableval}" in
 434   yes) enable_iso_codes=yes ;;
 435   no)  enable_iso_codes=no ;;
 436   *) AC_MSG_ERROR(bad value ${enableval} for --enable-iso-codes) ;;
 437 esac
 438 ],
 439 [enable_iso_codes=yes]) dnl Default value
 440
 441 AC_MSG_CHECKING([whether to use iso-codes if they are available])
 442 if test "x$enable_iso_codes" = "xyes"; then
 443   AC_MSG_RESULT([yes])
 444   have_iso_codes=no
 445   AC_MSG_CHECKING([whether iso-codes are available on this system])
 446   if $PKG_CONFIG iso-codes; then
 447     AC_MSG_RESULT([yes])
 448     AC_MSG_CHECKING([whether iso-codes has iso-639 domain])
 449     if $PKG_CONFIG --variable=domains iso-codes | $GREP -q 639 ; then
 450       AC_MSG_RESULT([yes])
 451       AC_MSG_CHECKING([for iso-codes prefix])
 452       ISO_CODES_PREFIX=`$PKG_CONFIG --variable=prefix iso-codes`
 453       if test -d "$ISO_CODES_PREFIX"; then
 454         AC_MSG_RESULT([yes])
 455         AC_MSG_CHECKING([ISO_CODES_PREFIX])
 456         AC_MSG_RESULT([$ISO_CODES_PREFIX])
 457         ISO_639_DOMAIN="iso_639"
 458         AC_MSG_CHECKING([ISO_639_DOMAIN])
 459         AC_MSG_RESULT([$ISO_639_DOMAIN])
 460         have_iso_codes=yes
 461         AC_DEFINE([HAVE_ISO_CODES], [1], [make use of iso-codes for ISO-639])
 462         AC_DEFINE_UNQUOTED([ISO_CODES_PREFIX], ["$ISO_CODES_PREFIX"], [prefix])
 463         ISO_CODES_VERSION=`$PKG_CONFIG --modversion iso-codes`
 464         AC_DEFINE_UNQUOTED([ISO_CODES_VERSION], ["$ISO_CODES_VERSION"], [ ])
 465       else
 466         AC_MSG_RESULT([no])
 467       fi
 468     else
 469       AC_MSG_RESULT([no])
 470     fi
 471   else
 472     AC_MSG_RESULT([no])
 473   fi
 474   AM_CONDITIONAL(USE_ISO_CODES, test "x$have_iso_codes" = "xyes")
 475 else
 476   AC_MSG_RESULT([no (disabled via --disable-iso-codes)])
 477   AM_CONDITIONAL(USE_ISO_CODES, false)
 478 fi
 479
 480 dnl *** zlib is optionally used by id3 tag parsing in libgsttag ***
 481 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 482 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for ID3 parsing in libgsttag],, [
 483   PKG_CHECK_MODULES(ZLIB, [ zlib ], [
 484       HAVE_ZLIB="yes"
 485     ], [
 486       AG_GST_CHECK_LIBHEADER(ZLIB, z, uncompress,, zlib.h, [
 487         HAVE_ZLIB="yes"
 488         ZLIB_LIBS="-lz"
 489         AC_SUBST(ZLIB_LIBS)
 490       ])
 491     ])
 492 ])
 493
 494 dnl *** sys plug-ins ***
 495
 496 echo
 497 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 498 echo
 499
 500 dnl *** X11 ***
 501 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 502 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 503                   [ximagesink], [
 504   AC_PATH_XTRA
 505   ac_cflags_save="$CFLAGS"
 506   ac_cppflags_save="$CPPFLAGS"
 507   CFLAGS="$CFLAGS $X_CFLAGS"
 508   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 509
 510   dnl now try to find the HEADER
 511   AC_CHECK_HEADER([X11/Xlib.h], [HAVE_X="yes"], [HAVE_X="no"], [AC_INCLUDES_DEFAULT])
 512
 513   if test "x$HAVE_X" = "xno"
 514   then
 515     AC_MSG_NOTICE([cannot find X11 development files])
 516   else
 517     dnl this is much more than we want
 518     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 519     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 520     dnl it does not add the libs; therefore we add them here
 521     X_LIBS="$X_LIBS -lX11"
 522     AC_SUBST(X_CFLAGS)
 523     AC_SUBST(X_LIBS)
 524   fi
 525   AC_SUBST(HAVE_X)
 526   CFLAGS="$ac_cflags_save"
 527   CPPFLAGS="$ac_cppflags_save"
 528 ])
 529
 530 dnl Check for Xv extension
 531 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 532 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 533                   [xvimagesink], [
 534   AG_GST_CHECK_XV
 535 ])
 536
 537 dnl check for X Shm
 538 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 539 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 540   if test x$HAVE_X = xyes; then
 541     AC_CHECK_LIB(Xext, XShmAttach,
 542                  HAVE_XSHM="yes", HAVE_XSHM="no",
 543                  $X_LIBS)
 544     if test "x$HAVE_XSHM" = "xyes"; then
 545       XSHM_LIBS="-lXext"
 546     else
 547       dnl On AIX, it is in XextSam instead, but we still need -lXext
 548       AC_CHECK_LIB(XextSam, XShmAttach,
 549                    HAVE_XSHM="yes", HAVE_XSHM="no",
 550                    $X_LIBS)
 551       if test "x$HAVE_XSHM" = "xyes"; then
 552         XSHM_LIBS="-lXext -lXextSam"
 553       fi
 554     fi
 555   fi
 556 ], , [
 557   AC_SUBST(HAVE_XSHM)
 558   AC_SUBST(XSHM_LIBS)
 559 ])
 560
 561 dnl *** ext plug-ins ***
 562 dnl keep this list sorted alphabetically !
 563
 564 if test "x$BUILD_EXTERNAL" = "xyes"; then
 565
 566 echo
 567 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 568 echo
 569
 570 dnl *** alsa ***
 571 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 572 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 573   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 574     HAVE_ALSA="yes"
 575     AC_SUBST(ALSA_CFLAGS)
 576     AC_SUBST(ALSA_LIBS)
 577   ], [
 578     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 579   ])
 580 ])
 581
 582 dnl *** CDParanoia ***
 583 dnl Note: upstream has a pkg-config file only in post-10.2 SVN so far
 584 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 585 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 586   PKG_CHECK_MODULES(CDPARANOIA, cdparanoia-3 >= 10.2, [
 587     HAVE_CDPARANOIA="yes"
 588   ], [
 589     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 590                         cdda_open, -lm,
 591                         cdda_interface.h,
 592                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 593                         HEADER_DIR="no"
 594                         FOUND_CDPARANOIA="yes")
 595     if test "x$FOUND_CDPARANOIA" != "xyes";
 596     then
 597       AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 598                           cdda_open, -lm,
 599                           cdda/cdda_interface.h,
 600                           CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 601                           HEADER_DIR="yes"
 602                           FOUND_CDPARANOIA="yes")
 603     fi
 604     if test "x$HEADER_DIR" = "xyes";
 605     then
 606       AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 607                          defined if cdda headers are in a cdda/ directory)
 608     fi
 609     if test "x$FOUND_CDPARANOIA" = "xyes";
 610     then
 611       AC_CHECK_LIB(cdda_paranoia,
 612                    paranoia_cachemodel_size,
 613                    : ,
 614                    HAVE_CDPARANOIA=no,
 615                  [-lcdda_interface])
 616     fi
 617
 618     AC_SUBST(CDPARANOIA_LIBS)
 619   ])
 620 ])
 621 dnl FIXME : add second check somehow if that is necessary
 622 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 623 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 624
 625 dnl *** ivorbis ***
 626 dnl AM_PATH_IVORBIS only takes two options
 627 translit(dnm, m, l) AM_CONDITIONAL(USE_IVORBIS, true)
 628 AG_GST_CHECK_FEATURE(IVORBIS, [integer vorbis plug-in], ivorbisdec, [
 629   AG_GST_PKG_CHECK_MODULES(IVORBIS, vorbisidec)
 630   if test $HAVE_IVORBIS = no
 631   then
 632     IVORBIS_LIBS=
 633     IVORBIS_CFLAGS=
 634     AC_CHECK_LIB(vorbisidec, vorbis_block_init,
 635       [IVORBIS_LIBS=-lvorbisidec
 636       HAVE_IVORBIS=yes
 637       case $host in
 638       arm-*-*)
 639         IVORBIS_CFLAGS="-D_ARM_ASSEM_ $IVORBIS_CFLAGS"
 640       esac
 641       ],
 642       HAVE_IVORBIS=no)
 643     AC_SUBST(IVORBIS_LIBS)
 644     AC_SUBST(IVORBIS_CFLAGS)
 645   else
 646     AC_CHECK_LIB(vorbisidec, vorbis_dsp_pcmout,
 647       AC_DEFINE([USE_TREMOLO],1, "Define if building for android"),
 648       USE_TREMOLO=no)
 649   fi
 650 ])
 651
 652 dnl *** libvisual ***
 653 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 654 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 655   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 656   if test $HAVE_LIBVISUAL = no
 657   then
 658     AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0)
 659     if test x$HAVE_LIBVISUAL = xyes; then
 660       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.2`"
 661     fi
 662   else
 663     if test x$HAVE_LIBVISUAL = xyes; then
 664       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.4`"
 665     fi
 666   fi
 667   AC_MSG_NOTICE([libvisual pluginsdir: $LIBVIS_PLUGINSDIR])
 668   if test x$LIBVIS_PLUGINSDIR != x; then
 669     AC_DEFINE_UNQUOTED(LIBVISUAL_PLUGINSBASEDIR,
 670         "$LIBVIS_PLUGINSDIR",
 671         [directory in which the detected libvisual's plugins are located])
 672   fi
 673 ])
 674
 675 dnl *** ogg ***
 676 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 677 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 678   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 679   if test $HAVE_OGG = no
 680   then
 681     XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
 682     AS_SCRUB_INCLUDE(OGG_CFLAGS)
 683   fi
 684 ])
 685
 686 dnl *** pango ***
 687 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 688 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 689   AG_GST_PKG_CHECK_MODULES(PANGO, pango >= 1.22.0  pangocairo >= 1.22.0)
 690 ])
 691
 692 dnl *** theora ***
 693 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 694 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 695   AG_GST_PKG_CHECK_MODULES(THEORA, theoradec >= 1.1 theoraenc >= 1.1)
 696 ])
 697
 698 dnl *** vorbis ***
 699 dnl AM_PATH_VORBIS only takes two options
 700 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 701 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 702   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 703   if test $HAVE_VORBIS = no
 704   then
 705     XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
 706     AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
 707   fi
 708 ])
 709
 710 if test "x$HAVE_VORBIS" = "xyes"; then
 711   ac_cflags_save="$CFLAGS"
 712   AC_COMPILE_IFELSE([
 713     AC_LANG_PROGRAM([[
 714 #include <vorbis/codec.h>
 715                      ]],[[
 716 vorbis_dsp_state *v;
 717
 718 vorbis_synthesis_restart (v);
 719                      ]])], HAVE_VSR=yes, HAVE_VSR=no)
 720   if test "x$HAVE_VSR" = "xyes"; then
 721     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 722                        [defined if vorbis_synthesis_restart is present])
 723   fi
 724   CFLAGS="$ac_cflags_save"
 725 fi
 726
 727 else
 728
 729 dnl not building plugins with external dependencies,
 730 dnl but we still need to set the conditionals
 731 AM_CONDITIONAL(USE_ALSA, false)
 732 AM_CONDITIONAL(USE_CDPARANOIA, false)
 733 AM_CONDITIONAL(USE_IVORBIS, false)
 734 AM_CONDITIONAL(USE_LIBVISUAL, false)
 735 AM_CONDITIONAL(USE_OGG, false)
 736 AM_CONDITIONAL(USE_PANGO, false)
 737 AM_CONDITIONAL(USE_THEORA, false)
 738 AM_CONDITIONAL(USE_VORBIS, false)
 739
 740 fi dnl of EXT plugins
 741
 742 dnl seeking needs freetype, so check for it here
 743 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 744   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 745 ])
 746 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 747 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 748 AC_SUBST(FT2_CFLAGS)
 749 AC_SUBST(FT2_LIBS)
 750
 751 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 752
 753 dnl Overview:
 754 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 755 dnl GST_*:              flags shared by built objects to link against GStreamer
 756 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 757 dnl                          (compare to other modules) or for i18n
 758 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 759 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 760 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 761 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 762
 763 dnl GST_OPTION_CFLAGS
 764 if test "x$USE_DEBUG" = xyes; then
 765    PROFILE_CFLAGS="-g"
 766 fi
 767 AC_SUBST(PROFILE_CFLAGS)
 768
 769 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 770   dnl Define _only_ when compiling a git version (not pre-releases or releases)
 771   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 772 else
 773   DEPRECATED_CFLAGS=""
 774 fi
 775 AC_SUBST(DEPRECATED_CFLAGS)
 776
 777 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 778 dnl at make time with e.g. make ERROR_CFLAGS=""
 779 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 780 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 781 AC_SUBST(GST_OPTION_CFLAGS)
 782 AC_SUBST(GST_OPTION_CXXFLAGS)
 783
 784 dnl our libraries need to be versioned correctly
 785 AC_SUBST(GST_LT_LDFLAGS)
 786
 787 dnl GST_PLUGINS_BASE_CFLAGS
 788 dnl prefer internal headers to already installed ones
 789 dnl also add builddir include for enumtypes and marshal
 790 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 791 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 792
 793 dnl FIXME: do we want to rename to GST_ALL_* ?
 794 dnl add GST_OPTION_CFLAGS, but overridable
 795 GST_CFLAGS="$GST_CFLAGS"
 796 GST_CXXFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CXXFLAGS)"
 797 GST_CFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CFLAGS)"
 798 AC_SUBST(GST_CFLAGS)
 799 AC_SUBST(GST_CXXFLAGS)
 800 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 801 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 802 AC_SUBST(GST_LIBS)
 803
 804 dnl LDFLAGS really should only contain flags, not libs - they get added before
 805 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 806 GST_ALL_LDFLAGS="-no-undefined"
 807 if test "x${enable_Bsymbolic}" = "xyes"; then
 808   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 809 fi
 810 AC_SUBST(GST_ALL_LDFLAGS)
 811
 812 dnl GST_LIB_LDFLAGS
 813 dnl linker flags shared by all libraries
 814 dnl LDFLAGS modifier defining exported symbols from built libraries
 815 dnl (export _gst_foo but not __gst_foo)
 816 GST_LIB_LDFLAGS="-export-symbols-regex ^_?\(gst_\|Gst\|GST_\).*"
 817 AC_SUBST(GST_LIB_LDFLAGS)
 818
 819 dnl this really should only contain flags, not libs - they get added before
 820 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 821 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
 822 AC_SUBST(GST_PLUGIN_LDFLAGS)
 823
 824 dnl *** output files ***
 825
 826 AC_CONFIG_FILES(
 827 Makefile
 828 gst-plugins-base.spec
 829 gst/Makefile
 830 gst/adder/Makefile
 831 gst/app/Makefile
 832 gst/audioconvert/Makefile
 833 gst/audiorate/Makefile
 834 gst/audiotestsrc/Makefile
 835 gst/encoding/Makefile
 836 gst/videoconvert/Makefile
 837 gst/gio/Makefile
 838 gst/playback/Makefile
 839 gst/audioresample/Makefile
 840 gst/subparse/Makefile
 841 gst/tcp/Makefile
 842 gst/typefind/Makefile
 843 gst/videotestsrc/Makefile
 844 gst/videorate/Makefile
 845 gst/videoscale/Makefile
 846 gst/volume/Makefile
 847 sys/Makefile
 848 sys/ximage/Makefile
 849 sys/xvimage/Makefile
 850 ext/Makefile
 851 ext/alsa/Makefile
 852 ext/cdparanoia/Makefile
 853 ext/libvisual/Makefile
 854 ext/ogg/Makefile
 855 ext/pango/Makefile
 856 ext/theora/Makefile
 857 ext/vorbis/Makefile
 858 gst-libs/Makefile
 859 gst-libs/gst/Makefile
 860 gst-libs/gst/audio/Makefile
 861 gst-libs/gst/app/Makefile
 862 gst-libs/gst/fft/Makefile
 863 gst-libs/gst/riff/Makefile
 864 gst-libs/gst/rtp/Makefile
 865 gst-libs/gst/rtsp/Makefile
 866 gst-libs/gst/sdp/Makefile
 867 gst-libs/gst/tag/Makefile
 868 gst-libs/gst/pbutils/Makefile
 869 gst-libs/gst/pbutils/gstpluginsbaseversion.h
 870 gst-libs/gst/video/Makefile
 871 tools/Makefile
 872 pkgconfig/Makefile
 873 pkgconfig/gstreamer-audio.pc
 874 pkgconfig/gstreamer-audio-uninstalled.pc
 875 pkgconfig/gstreamer-app.pc
 876 pkgconfig/gstreamer-app-uninstalled.pc
 877 pkgconfig/gstreamer-fft.pc
 878 pkgconfig/gstreamer-fft-uninstalled.pc
 879 pkgconfig/gstreamer-pbutils.pc
 880 pkgconfig/gstreamer-pbutils-uninstalled.pc
 881 pkgconfig/gstreamer-riff.pc
 882 pkgconfig/gstreamer-riff-uninstalled.pc
 883 pkgconfig/gstreamer-rtp.pc
 884 pkgconfig/gstreamer-rtp-uninstalled.pc
 885 pkgconfig/gstreamer-rtsp.pc
 886 pkgconfig/gstreamer-rtsp-uninstalled.pc
 887 pkgconfig/gstreamer-sdp.pc
 888 pkgconfig/gstreamer-sdp-uninstalled.pc
 889 pkgconfig/gstreamer-tag.pc
 890 pkgconfig/gstreamer-tag-uninstalled.pc
 891 pkgconfig/gstreamer-video.pc
 892 pkgconfig/gstreamer-video-uninstalled.pc
 893 pkgconfig/gstreamer-plugins-base.pc
 894 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 895 tests/Makefile
 896 tests/check/Makefile
 897 tests/examples/Makefile
 898 tests/examples/app/Makefile
 899 tests/examples/audio/Makefile
 900 tests/examples/dynamic/Makefile
 901 tests/examples/encoding/Makefile
 902 tests/examples/fft/Makefile
 903 tests/examples/gio/Makefile
 904 tests/examples/overlay/Makefile
 905 tests/examples/seek/Makefile
 906 tests/examples/snapshot/Makefile
 907 tests/examples/playback/Makefile
 908 tests/examples/playrec/Makefile
 909 tests/files/Makefile
 910 tests/icles/Makefile
 911 tests/icles/playback/Makefile
 912 docs/Makefile
 913 docs/design/Makefile
 914 docs/libs/Makefile
 915 docs/plugins/Makefile
 916 docs/version.entities
 917 po/Makefile.in
 918 common/Makefile
 919 common/m4/Makefile
 920 m4/Makefile
 921 )
 922
 923 dnl Create the config.h file for Visual Studio builds
 924 dnl Beware of spaces and /'s in some of the shell variable contents.
 925 sed \
 926     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 927     -e 's/.* GST_INSTALL_PLUGINS_HELPER/#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
 928     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 929     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 930     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 931     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 932     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
 933     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 934     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 935     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
 936     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 937     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 938     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 939     -e 's/.* HAVE_ISO_CODES$/#undef HAVE_ISO_CODES/' \
 940     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
 941     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 942     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 943     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 944     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 945     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 946     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 947     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 948     -e 's/.* ISO_CODES_PREFIX$/#undef ISO_CODES_PREFIX/' \
 949     -e 's/.* ISO_CODES_VERSION$/#undef ISO_CODES_VERSION/' \
 950     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 951     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 952     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
 953     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 954     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
 955     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 956     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 957     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 958     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
 959     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
 960     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 961     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
 962     -e "s/.* DEFAULT_VIDEOSINK$/#define DEFAULT_VIDEOSINK \"directdrawsink\"/" \
 963     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
 964     config.h.in >win32/common/config.h-new
 965
 966
 967
 968 AC_OUTPUT
 969
 970 AG_GST_OUTPUT_PLUGINS
 971 ORC_OUTPUT
 972