configure.ac

   1 AC_PREREQ([2.69])
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, git and prerelease does Werror too
   6 dnl
   7 AC_INIT([GStreamer],[1.13.90],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gstreamer])
   8 AG_GST_INIT
   9
  10 dnl initialize automake (we require GNU make)
  11 AM_INIT_AUTOMAKE([-Wno-portability 1.14 no-dist-gzip dist-xz tar-ustar subdir-objects])
  12
  13 dnl define PACKAGE_VERSION_* variables
  14 AS_VERSION
  15
  16 dnl check if this is a release version
  17 AS_NANO(GST_GIT="no", GST_GIT="yes")
  18
  19 dnl can autoconf find the source ?
  20 AC_CONFIG_SRCDIR([gst/gst.c])
  21
  22 dnl define the output header for config
  23 AC_CONFIG_HEADERS([config.h])
  24
  25 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  26 AM_MAINTAINER_MODE([enable])
  27
  28 dnl sets host_* variables
  29 AC_CANONICAL_HOST
  30
  31 dnl use pretty build output by default
  32 AM_SILENT_RULES([yes])
  33
  34 dnl GStreamer versioning, this is mostly informational
  35 GST_VERSION_MAJOR=$PACKAGE_VERSION_MAJOR
  36 GST_VERSION_MINOR=$PACKAGE_VERSION_MINOR
  37 GST_VERSION_MICRO=$PACKAGE_VERSION_MICRO
  38 GST_VERSION_NANO=$PACKAGE_VERSION_NANO
  39 AC_SUBST(GST_VERSION_MAJOR)
  40 AC_SUBST(GST_VERSION_MINOR)
  41 AC_SUBST(GST_VERSION_MICRO)
  42 AC_SUBST(GST_VERSION_NANO)
  43
  44 dnl our libraries and install dirs use GST_API_VERSION in the filename
  45 dnl to allow side-by-side installation of different API versions
  46 GST_API_VERSION=1.0
  47 AC_SUBST(GST_API_VERSION)
  48 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  49   [GStreamer API Version])
  50
  51 dnl CURRENT, REVISION, AGE
  52 dnl - library source changed -> increment REVISION
  53 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  54 dnl - interfaces added -> increment AGE
  55 dnl - interfaces removed -> AGE = 0
  56 dnl
  57 dnl Keep CURRENT as MINOR * 100 + MICRO
  58 dnl Ex : 1.0.0 => 0
  59 dnl      1.0.3 => 3
  60 dnl      1.1.0 => 100
  61 dnl      1.2.5 => 205
  62 dnl      1.10.9 (who knows) => 1009
  63 dnl
  64 dnl sets GST_LT_LDFLAGS
  65 AS_LIBTOOL(GST, 1390, 0, 1390)
  66
  67 dnl *** autotools stuff ****
  68
  69 dnl allow for different autotools
  70 AS_AUTOTOOLS_ALTERNATE
  71
  72 dnl Add parameters for aclocal (keep in sync with Makefile.am)
  73 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  74
  75 dnl set up gettext
  76 dnl the version check needs to stay here because autopoint greps for it
  77 AM_GNU_GETTEXT_VERSION([0.17])
  78 AM_GNU_GETTEXT([external])
  79 AG_GST_GETTEXT([gstreamer-$GST_API_VERSION])
  80
  81 dnl *** check for arguments to configure ***
  82
  83 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  84 AG_GST_ARG_ENABLE_EXTRA_CHECKS
  85
  86 dnl subsystems - can influence other decisions so needs to be high up
  87 dnl we need to AM_CONDITIONAL them here for automake 1.6.x compatibility
  88 AG_GST_CHECK_SUBSYSTEM_DISABLE(GST_DEBUG,[debugging subsystem])
  89 AM_CONDITIONAL(GST_DISABLE_GST_DEBUG, test "x$GST_DISABLE_GST_DEBUG" = "xyes")
  90 AG_GST_CHECK_SUBSYSTEM_DISABLE(GST_TRACER_HOOKS,[tracing subsystem hooks])
  91 AM_CONDITIONAL(GST_DISABLE_GST_TRACER_HOOKS, test "x$GST_DISABLE_GST_TRACER_HOOKS" = "xyes")
  92 if test "x$GST_DISABLE_GST_TRACER_HOOKS" = xyes; then
  93   AC_DEFINE(GST_DISABLE_GST_TRACER_HOOKS, 1,
  94     [Define if tracing subsystem hooks is disabled])
  95 fi
  96 AG_GST_CHECK_SUBSYSTEM_DISABLE(PARSE,[command-line parser])
  97 AM_CONDITIONAL(GST_DISABLE_PARSE, test "x$GST_DISABLE_PARSE" = "xyes")
  98 if test "x$GST_DISABLE_PARSE" = xyes; then
  99   AC_DEFINE(GST_DISABLE_PARSE, 1,
 100     [Define if pipeline parsing code is disabled])
 101 fi
 102 AG_GST_CHECK_SUBSYSTEM_DISABLE(OPTION_PARSING,[option parsing when gst_init])
 103 AM_CONDITIONAL(GST_DISABLE_OPTION_PARSING, test "x$GST_DISABLE_OPTION_PARSING" = "xyes")
 104 if test "x$GST_DISABLE_OPTION_PARSING" = xyes; then
 105   AC_DEFINE(GST_DISABLE_OPTION_PARSING, 1,
 106     [Define if option parsing is disabled])
 107 fi
 108 AG_GST_CHECK_SUBSYSTEM_DISABLE(REGISTRY,[plugin registry])
 109 AM_CONDITIONAL(GST_DISABLE_REGISTRY, test "x$GST_DISABLE_REGISTRY" = "xyes")
 110 dnl define a substitution to use in docs/gst/gstreamer.types
 111 if test "x$GST_DISABLE_REGISTRY" = "xyes"
 112 then
 113   GST_REGISTRY_DOC_TYPES="%"
 114 else
 115   GST_REGISTRY_DOC_TYPES=
 116 fi
 117 AC_SUBST(GST_REGISTRY_DOC_TYPES)
 118 AG_GST_CHECK_SUBSYSTEM_DISABLE(PLUGIN,[plugin])
 119 AM_CONDITIONAL(GST_DISABLE_PLUGIN, test "x$GST_DISABLE_PLUGIN" = "xyes")
 120
 121 AG_GST_ARG_DEBUG
 122 AG_GST_ARG_PROFILING
 123 AG_GST_ARG_VALGRIND
 124 AG_GST_ARG_GCOV
 125
 126 AG_GST_ARG_EXAMPLES
 127
 128 AG_GST_ARG_WITH_PKG_CONFIG_PATH
 129 AG_GST_ARG_WITH_PACKAGE_NAME
 130 AG_GST_ARG_WITH_PACKAGE_ORIGIN
 131
 132 AG_GST_PKG_CONFIG_PATH
 133
 134 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 135   ["${srcdir}/gstreamer.doap"],
 136   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 137
 138 # We only use this when building with MSVC, which is only done with the
 139 # alternate Meson build system files
 140 GSTCONFIG_BUILT_WITH_MSVC=0
 141 AC_SUBST(GSTCONFIG_BUILT_WITH_MSVC)
 142
 143 dnl check for bash completion
 144 AC_ARG_WITH([bash-completion-dir],
 145     AS_HELP_STRING([--with-bash-completion-dir[=PATH]],
 146         [Install the bash auto-completion script in this directory. @<:@default=yes@:>@]),
 147     [],
 148     [with_bash_completion_dir=yes])
 149
 150 if test "x$with_bash_completion_dir" = "xyes"
 151 then
 152     extra_args=
 153
 154     if test "x$prefix" != "xNONE"
 155     then
 156         extra_args="--define-variable=prefix=\"$prefix\""
 157     fi
 158
 159     PKG_CHECK_MODULES([BASH_COMPLETION], [bash-completion >= 2.0],
 160         [
 161           BASH_COMPLETION_DIR="`eval pkg-config $extra_args --variable=completionsdir bash-completion`"
 162           BASH_HELPERS_DIR="`eval pkg-config $extra_args --variable=helpersdir bash-completion`"
 163         ],
 164         [
 165           BASH_COMPLETION_DIR="$datadir/bash-completion/completions"
 166           BASH_HELPERS_DIR="$datadir/bash-completion/helpers"
 167         ])
 168 else
 169     BASH_COMPLETION_DIR="$with_bash_completion_dir/completions"
 170     BASH_HELPERS_DIR="$with_bash_completion_dir/helpers"
 171 fi
 172
 173 AC_SUBST([BASH_COMPLETION_DIR])
 174 AC_SUBST([BASH_HELPERS_DIR])
 175 AM_CONDITIONAL([ENABLE_BASH_COMPLETION],[test "x$with_bash_completion_dir" != "xno"])
 176
 177 dnl If only building static libraries, define GST_STATIC_COMPILATION. This is
 178 dnl needed only on Windows, but it doesn't hurt to have it everywhere.
 179 if test x$enable_static = xyes -a x$enable_shared = xno; then
 180   GST_OBJ_STATIC_CFLAGS="-DGST_STATIC_COMPILATION"
 181 fi
 182
 183 dnl building of tests
 184 AC_ARG_ENABLE(tests,
 185   AS_HELP_STRING([--disable-tests],[disable building test apps]),
 186   [
 187     case "${enableval}" in
 188       yes) BUILD_TESTS=yes ;;
 189       no)  BUILD_TESTS=no ;;
 190       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 191     esac
 192   ],
 193 [BUILD_TESTS=yes]) dnl Default value
 194 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 195
 196 dnl tests known to fail
 197 AC_ARG_ENABLE(failing-tests,
 198   AS_HELP_STRING([--disable-failing-tests],[disable building tests known to fail]),
 199   [
 200     case "${enableval}" in
 201       yes) BUILD_FAILING_TESTS=yes ;;
 202       no)  BUILD_FAILING_TESTS=no ;;
 203       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-failing-tests) ;;
 204     esac
 205   ],
 206   [BUILD_FAILING_TESTS=no]) dnl Default value
 207 AM_CONDITIONAL(BUILD_FAILING_TESTS, test "x$BUILD_FAILING_TESTS" = "xyes")
 208 if test x$BUILD_FAILING_TESTS = xyes; then
 209   AC_MSG_WARN([building tests known to fail, use --disable-failing-tests to disable])
 210 else
 211   AC_MSG_WARN([Sissy ! By asking to not build the tests known to fail, you hereby waive your right to customer support.  If you do not agree with this EULA, please press Ctrl-C before the next line is printed.  By allowing the next line to be printed, you expressly acknowledge your acceptance of this EULA.])
 212 fi
 213
 214 dnl building of benchmarks
 215 AC_ARG_ENABLE(benchmarks,
 216   AS_HELP_STRING([--disable-benchmarks],[disable building benchmarks apps]),
 217   [
 218     case "${enableval}" in
 219       yes) BUILD_BENCHMARKS=yes ;;
 220       no)  BUILD_BENCHMARKS=no ;;
 221       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-benchmarks) ;;
 222     esac
 223   ],
 224 [BUILD_BENCHMARKS=yes]) dnl Default value
 225 AM_CONDITIONAL(BUILD_BENCHMARKS, test "x$BUILD_BENCHMARKS" = "xyes")
 226
 227 dnl building of tools
 228 AC_ARG_ENABLE(tools,
 229   AS_HELP_STRING([--disable-tools],[disable building tools]),
 230   [
 231     case "${enableval}" in
 232       yes) BUILD_TOOLS=yes ;;
 233       no)  BUILD_TOOLS=no ;;
 234       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tools) ;;
 235     esac
 236   ],
 237 [BUILD_TOOLS=yes]) dnl Default value
 238 AM_CONDITIONAL(BUILD_TOOLS, test "x$BUILD_TOOLS" = "xyes")
 239
 240 dnl poison destroyed objects
 241 AC_ARG_ENABLE(poisoning,
 242   AS_HELP_STRING([--enable-poisoning],[enable poisoning of deallocated objects]),
 243   [
 244     case "${enableval}" in
 245       yes) USE_POISONING=yes ;;
 246       no)  USE_POISONING=no ;;
 247       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-poisoning) ;;
 248     esac
 249   ],
 250   [USE_POISONING=no]) dnl Default value
 251 if test "x$USE_POISONING" = xyes; then
 252   AC_DEFINE(USE_POISONING, 1,
 253     [Define if we should poison deallocated memory])
 254 fi
 255
 256 dnl PTP support parts
 257 AC_MSG_CHECKING([whether PTP support can be enabled])
 258 case "$host_os" in
 259   *android*)
 260     dnl Can't run on Android because of permissions
 261     HAVE_PTP=no
 262     ;;
 263   mingw*|pw32*|cygwin*)
 264     dnl Not ported to Windows yet
 265     HAVE_PTP=no
 266     ;;
 267   darwin*)
 268     dnl Can't run on iOS because of permissions
 269     AC_CHECK_HEADER(MobileCoreServices/MobileCoreServices.h, HAVE_PTP="no", HAVE_PTP="yes", [-])
 270     ;;
 271   linux*|darwin*|solaris*|netbsd*|freebsd*|openbsd*|kfreebsd*|dragonfly*|gnu*)
 272     HAVE_PTP=yes
 273     ;;
 274   *)
 275     HAVE_PTP=no
 276     ;;
 277 esac
 278 AC_MSG_RESULT([$HAVE_PTP])
 279
 280 dnl user/group to change to in gst-ptp-helper
 281 AC_ARG_WITH([ptp-helper-setuid-user],
 282   AS_HELP_STRING([--with-ptp-helper-setuid-user],[User to switch to when installing gst-ptp-helper setuid root]),
 283   [
 284     if test "x$withval" != "x"
 285     then
 286       AC_DEFINE_UNQUOTED(HAVE_PTP_HELPER_SETUID_USER, "$withval", [PTP helper setuid user])
 287     fi
 288   ], []
 289 )
 290
 291 dnl group/group to change to in gst-ptp-helper
 292 AC_ARG_WITH([ptp-helper-setuid-group],
 293   AS_HELP_STRING([--with-ptp-helper-setuid-group],[Group to switch to when installing gst-ptp-helper setuid root]),
 294   [
 295     if test "x$withval" != "x"
 296     then
 297       AC_DEFINE_UNQUOTED(HAVE_PTP_HELPER_SETUID_GROUP, "$withval", [PTP helper setuid group])
 298     fi
 299   ], []
 300 )
 301
 302 AC_ARG_WITH(
 303   ptp-helper-permissions,
 304   AC_HELP_STRING(
 305     [--with-ptp-helper-permissions],
 306     [how to gain PTP permissions (none, setuid-root, capabilities, auto)]),
 307     [],
 308     [with_ptp_helper_permissions=auto])
 309
 310 gst_ptp_have_cap=no
 311 AG_GST_CHECK_LIBHEADER(CAP, cap,
 312                        cap_init, ,
 313                        sys/capability.h,
 314                        CAP_LIBS="-lcap"
 315                        AC_SUBST(CAP_LIBS)
 316                        gst_ptp_have_cap=yes)
 317
 318 AC_PATH_PROG([SETCAP], [setcap], [no], [$PATH:/usr/bin:/bin:/usr/sbin:/sbin])
 319
 320 if test "x$HAVE_PTP" = "xyes"; then
 321 AC_DEFINE(HAVE_PTP, 1, [PTP support available])
 322
 323 AC_MSG_CHECKING([for SIOCGIFCONF, SIOCGIFFLAGS and SIOCGIFHWADDR])
 324 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 325     [[
 326         #include <sys/ioctl.h>
 327         #include <net/if.h>
 328     ]],
 329     [[
 330         struct ifreq ifr;
 331         struct ifconf ifc;
 332         ioctl(0, SIOCGIFCONF, &ifc);
 333         ioctl(0, SIOCGIFFLAGS, &ifr);
 334         ioctl(0, SIOCGIFHWADDR, &ifr);
 335         int dummy = ifr.ifr_hwaddr.sa_data[0];
 336     ]])], [
 337         AC_MSG_RESULT(yes)
 338         AC_DEFINE(HAVE_SIOCGIFCONF_SIOCGIFFLAGS_SIOCGIFHWADDR, 1, [SIOCGIFCONF, SIOCGIFFLAGS and SIOCGIFHWADDR is available])
 339     ], [
 340         AC_MSG_RESULT(no)
 341 ])
 342
 343 AC_MSG_CHECKING([for getifaddrs() and AF_LINK])
 344 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 345     [[
 346         #include <ifaddrs.h>
 347         #include <net/if.h>
 348         #include <net/if_dl.h>
 349     ]],
 350     [[
 351         struct ifaddrs *ifaddr;
 352         getifaddrs(&ifaddr);
 353         int dummy = (ifaddr->ifa_flags & IFF_LOOPBACK) && ifaddr->ifa_addr->sa_family != AF_LINK;
 354     ]])], [
 355         AC_MSG_RESULT(yes)
 356         AC_DEFINE(HAVE_GETIFADDRS_AF_LINK, 1, [getifaddrs() and AF_LINK is available])
 357     ], [
 358         AC_MSG_RESULT(no)
 359     ])
 360
 361 AC_MSG_CHECKING([how to install gst-ptp-helper])
 362 if test "x$with_ptp_helper_permissions" = "xauto"; then
 363     if test "x$gst_ptp_have_cap" = "xyes" -a "x$SETCAP" != "xno"; then
 364         with_ptp_helper_permissions="capabilities"
 365     else
 366         with_ptp_helper_permissions="setuid-root"
 367     fi
 368 fi
 369 AC_MSG_RESULT([$with_ptp_helper_permissions])
 370
 371 case "$with_ptp_helper_permissions" in
 372   none)
 373     ;;
 374   setuid-root)
 375      AC_DEFINE(HAVE_PTP_HELPER_SETUID, 1,
 376         [Use setuid-root for permissions in PTP helper])
 377     ;;
 378   capabilities)
 379      AC_DEFINE(HAVE_PTP_HELPER_CAPABILITIES, 1,
 380         [Use capabilities for permissions in PTP helper])
 381     ;;
 382   *)
 383     AC_MSG_ERROR(Invalid parameter [$with_ptp_helper_permissions])
 384     ;;
 385 esac
 386
 387 fi
 388
 389 AM_CONDITIONAL(HAVE_PTP, test "x$HAVE_PTP" = "xyes")
 390 AM_CONDITIONAL(HAVE_PTP_HELPER_SETUID, test "x$with_ptp_helper_permissions" = "xsetuid-root")
 391 AM_CONDITIONAL(HAVE_PTP_HELPER_CAPABILITIES, test "x$with_ptp_helper_permissions" = "xcapabilities")
 392
 393 dnl *** checks for platform ***
 394
 395 dnl * hardware/architecture *
 396
 397 dnl common/m4/gst-arch.m4
 398 dnl check CPU type
 399 AG_GST_ARCH
 400
 401 dnl check for platform specific settings
 402 AG_GST_PLATFORM
 403
 404 dnl * software *
 405
 406 dnl check for large file support
 407 dnl affected plugins must include config.h
 408 AC_SYS_LARGEFILE
 409
 410 dnl *** checks for programs ***
 411
 412 dnl find a compiler
 413 AC_PROG_CC
 414 AC_PROG_CC_STDC
 415
 416 dnl check if the compiler supports '-c' and '-o' options
 417 AM_PROG_CC_C_O
 418
 419 dnl find an assembler
 420 AM_PROG_AS
 421
 422 dnl determine if c++ is available on this system
 423 AC_PROG_CXX
 424 dnl CXX may be set to some default even if no c++ compiler is available
 425 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 426 AC_LANG_PUSH([C++])
 427 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ class Foo { int bar; };]], [[]])],[working_cxx=yes],[working_cxx=no])
 428 AC_LANG_POP([C++])
 429 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 430 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 431
 432 dnl Perl is used in building documentation and in the version checks
 433 AC_PATH_PROG(PERL_PATH, perl, no)
 434 if test x$PERL_PATH = xno; then
 435   AC_MSG_ERROR(Could not find perl)
 436 fi
 437
 438 dnl we require flex and bison for building the parser
 439 if test "x$GST_DISABLE_PARSE" != xyes; then
 440   AG_GST_BISON_CHECK
 441   AG_GST_FLEX_CHECK
 442 fi
 443
 444 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 445 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 446
 447 dnl check for gobject-introspection
 448 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 449
 450 dnl check for documentation tools
 451 GTK_DOC_CHECK([1.12])
 452 AG_GST_PLUGIN_DOCS([1.12])
 453
 454 dnl *** checks for libraries ***
 455
 456 dnl check for libm, for sin()
 457 LT_LIB_M
 458 AC_SUBST(LIBM)
 459
 460 dnl *** checks for header files ***
 461
 462 dnl check if we have ANSI C header files
 463 AC_HEADER_STDC
 464
 465 dnl Check for ucontext.h
 466 AC_CHECK_HEADERS([ucontext.h], [], [], [AC_INCLUDES_DEFAULT])
 467
 468 dnl Check for sys/socket.h
 469 AC_CHECK_HEADERS([sys/socket.h], [HAVE_SYS_SOCKET_H=yes], [HAVE_SYS_SOCKET_H=no], [AC_INCLUDES_DEFAULT])
 470 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 471
 472 dnl check for sys/times.h for tests/examples/adapter/
 473 AC_CHECK_HEADERS([sys/times.h], [HAVE_SYS_TIMES_H=yes], [HAVE_SYS_TIME_H=no], [AC_INCLUDES_DEFAULT])
 474 AC_CHECK_HEADERS([unistd.h], [HAVE_UNISTD_H=yes], [HAVE_UNISTD_H=no], [AC_INCLUDES_DEFAULT])
 475 AM_CONDITIONAL(HAVE_SYS_TIMES_H_AND_UNISTD_H, test "x$HAVE_SYS_TIMES_H" = "xyes" -a "x$HAVE_UNISTD_H" = "xyes")
 476
 477 dnl Check for process.h for getpid() on win32
 478 AC_CHECK_HEADERS([process.h], [], [], [AC_INCLUDES_DEFAULT])
 479
 480 dnl Check for sys/utsname.h for uname
 481 AC_CHECK_HEADERS([sys/utsname.h], [], [], [AC_INCLUDES_DEFAULT])
 482
 483 dnl Check for stdio_ext.f for __fbufsize
 484 AC_CHECK_HEADERS([stdio_ext.h], [], [], [AC_INCLUDES_DEFAULT])
 485
 486 dnl check for pthreads
 487 dnl without arguments AX_PTHREAD() will do AC_DEFINE(HAVE_PTHREAD)
 488 dnl which later checks use in their test code
 489 AX_PTHREAD()
 490 AM_CONDITIONAL(HAVE_PTHREAD, test "x$ax_pthread_ok" = "xyes")
 491
 492 dnl check for sys/prctl for setting thread name on Linux
 493 AC_CHECK_HEADERS([sys/prctl.h], [], [], [AC_INCLUDES_DEFAULT])
 494
 495 dnl check for pthread_setname_np(const char*)
 496 dnl which is present on OS X 10.6, iOS 3.2 and above
 497 AC_MSG_CHECKING(for pthread_setname_np(const char*))
 498 AC_LINK_IFELSE(
 499     [AC_LANG_PROGRAM(
 500         [#include <pthread.h>],
 501         [pthread_setname_np("example")])],
 502     [AC_MSG_RESULT(yes)
 503      AC_DEFINE(HAVE_PTHREAD_SETNAME_NP_WITHOUT_TID,1,
 504         [Have function pthread_setname_np(const char*)])],
 505     [AC_MSG_RESULT(no)])
 506
 507 dnl check for sys/uio.h for writev()
 508 AC_CHECK_HEADERS([sys/uio.h], [], [], [AC_INCLUDES_DEFAULT])
 509
 510 dnl Check for valgrind.h
 511 dnl separate from HAVE_VALGRIND because you can have the program, but not
 512 dnl the dev package
 513 AC_CHECK_HEADERS([valgrind/valgrind.h], [], [], [AC_INCLUDES_DEFAULT])
 514
 515 dnl used in gst/gstpoll.c
 516 AC_CHECK_HEADERS([winsock2.h], [HAVE_WINSOCK2_H=yes], [HAVE_WINSOCK2_H=no], [AC_INCLUDES_DEFAULT])
 517 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 518 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 519   WIN32_LIBS="-lws2_32"
 520   AC_SUBST(WIN32_LIBS)
 521 fi
 522
 523 dnl check for GMP/GSL, used by the gst_util_uint64_scale unit test only
 524 if test "x$BUILD_TESTS" = "xyes"; then
 525   AG_GST_CHECK_LIBHEADER(GMP, gmp,
 526                          __gmpz_init_set_d, ,
 527                          gmp.h,
 528                          GMP_LIBS="-lgmp"
 529                          AC_SUBST(GMP_LIBS)
 530                          AC_DEFINE(HAVE_GMP, [1],[Have GMP library]))
 531   AG_GST_CHECK_LIBHEADER(GSL, gsl,
 532                          gsl_rng_uniform_int, -lgslcblas,
 533                          gsl/gsl_rng.h,
 534                          GSL_LIBS="-lgsl -lgslcblas"
 535                          AC_SUBST(GSL_LIBS)
 536                          AC_DEFINE(HAVE_GSL, [1],[Have GSL library]))
 537 fi
 538
 539 dnl *** checks for types/defines ***
 540
 541 dnl *** checks for structures ***
 542
 543 dnl *** checks for compiler characteristics ***
 544
 545 dnl check if the compiler supports __uint128_t (gcc)
 546 dnl Actually check for 128-bit division, since that's what we use
 547 dnl uint128_t for.
 548 AC_CACHE_CHECK(for __uint128_t, gst_cv_uint128_t,
 549     AC_LINK_IFELSE([AC_LANG_PROGRAM([[ ]], [[
 550       static __uint128_t v1 = 100;
 551       static __uint128_t v2 = 10;
 552       static __uint128_t u;
 553       u = v1 / v2;
 554     ]])],[
 555       gst_cv_uint128_t=yes
 556     ],[
 557       gst_cv_uint128_t=no
 558     ])
 559 )
 560 if test x$gst_cv_uint128_t = xyes; then
 561   AC_DEFINE(HAVE_UINT128_T, 1, [Have __uint128_t type])
 562 fi
 563
 564 dnl *** checking for tm_gmtoff ***
 565 AC_MSG_CHECKING([for tm_gmtoff])
 566 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 567         #include <time.h>
 568         int main(void) {
 569           struct tm t;
 570           t.tm_gmtoff = 0;
 571           exit(0);
 572         }]])],
 573   [have_tm_gmtoff=yes
 574    AC_DEFINE(HAVE_TM_GMTOFF,1,[Have tm_gmtoff field in struct tm])],
 575   [have_tm_gmtoff=no],
 576   [have_tm_gmtoff="no (cross compiling)"])
 577 AC_MSG_RESULT($have_tm_gmtoff)
 578
 579
 580 dnl *** checks for library functions ***
 581
 582 AC_CHECK_FUNCS([strcasestr])
 583
 584 AC_CHECK_FUNCS([gmtime_r])
 585 AC_CHECK_FUNCS([localtime_r])
 586 AC_CHECK_FUNCS([sigaction])
 587 AC_CHECK_FUNCS([getrusage])
 588 AM_CONDITIONAL(HAVE_GETRUSAGE, test "x$ac_cv_func_getrusage" = "xyes")
 589 AC_CHECK_HEADERS([sys/resource.h])
 590
 591 dnl check for fseeko()
 592 AC_FUNC_FSEEKO
 593 dnl check for ftello()
 594 AC_CHECK_FUNCS([ftello])
 595
 596 AC_CHECK_FUNCS([fgetpos])
 597 AC_CHECK_FUNCS([fsetpos])
 598
 599 dnl check for poll(), ppoll() and pselect()
 600 AC_CHECK_HEADERS([sys/poll.h], [], [], [AC_INCLUDES_DEFAULT])
 601 AC_CHECK_HEADERS([poll.h], [], [], [AC_INCLUDES_DEFAULT])
 602 AC_CHECK_FUNCS([poll])
 603 AC_CHECK_FUNCS([ppoll])
 604 AC_CHECK_FUNCS([pselect])
 605
 606 dnl check for socketpair()
 607 AC_CHECK_FUNC(socketpair, [], [
 608   AC_CHECK_LIB(socket, socketpair, [
 609     SOCKET_LIBS="-lsocket"
 610     AC_SUBST(SOCKET_LIBS)
 611   ])
 612 ])
 613
 614 dnl ****************************************
 615 dnl *** GLib POLL* compatibility defines ***
 616 dnl ****************************************
 617
 618 AC_MSG_CHECKING([for broken poll])
 619 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 620         #include <stdlib.h>
 621         #include <fcntl.h>
 622         #ifdef HAVE_SYS_POLL_H
 623         #include <sys/poll.h>
 624         #endif
 625         #ifdef HAVE_POLL_H
 626         #include <poll.h>
 627         #endif
 628         int main(void) {
 629           struct pollfd fds[1];
 630           int fd;
 631           fd = open("/dev/null", 1);
 632           fds[0].fd = fd;
 633           fds[0].events = POLLIN;
 634           fds[0].revents = 0;
 635           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
 636                 exit(1);  /* Does not work for devices -- fail */
 637           }
 638           exit(0);
 639         }]])],
 640   [broken_poll=no],
 641   [broken_poll=yes
 642    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
 643   [broken_poll="no (cross compiling)"])
 644 AC_MSG_RESULT($broken_poll)
 645
 646 dnl check for getpagesize()
 647 AC_CHECK_FUNCS([getpagesize])
 648
 649 dnl Check for POSIX timers
 650 CLOCK_GETTIME_FOUND="no"
 651 AC_CHECK_FUNC(clock_gettime, [CLOCK_GETTIME_FOUND="yes"], [
 652   AC_CHECK_LIB(rt, clock_gettime, [
 653     CLOCK_GETTIME_FOUND="yes"
 654     LIBS="$LIBS -lrt"
 655   ], [
 656     AC_CHECK_LIB(pthread, clock_gettime, [
 657       CLOCK_GETTIME_FOUND="yes"
 658       LIBS="$LIBS -lpthread"
 659     ])
 660   ])
 661 ])
 662
 663 # With XCode 8, clock_gettime will be incorrectly detected as being available
 664 # regardless of what version of OS X you target because the symbol is available
 665 # in the .tbd file as a weak symbol.
 666 # See: https://bugzilla.gnome.org/show_bug.cgi?id=772451
 667 #
 668 # We cannot simply do AC_CHECK_FUNCS with -Wl,-no_weak_imports because the
 669 # autoconf check does its own prototype declaration that doesn't trigger that
 670 # compiler flag.
 671 #
 672 # It's only starting from macOS 10.12 and iOS 10.0 that clock_gettime is
 673 # actually available, so we can unconditionally disable it for older versions.
 674 case "$host_os" in
 675   darwin*)
 676     AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 677 #include <AvailabilityMacros.h>
 678 #include <TargetConditionals.h>
 679 #if defined(TARGET_OS_MAC)
 680 #  if MAC_OS_X_VERSION_MIN_REQUIRED < MAC_OS_X_VERSION_10_12
 681 #    error "Not compiling for OS X 10.12 or later"
 682 #  endif
 683 #else
 684 #  if __IPHONE_OS_VERSION_MIN_REQUIRED < __IPHONE_10_0
 685 #    error "Not compiling for iOS 10.0 or later"
 686 #  endif
 687 #endif
 688     ]])], [], [
 689     if test "$CLOCK_GETTIME_FOUND" = "yes"; then
 690       AC_MSG_NOTICE([Disabling incorrectly detected clock_gettime on OS X])
 691     fi
 692     CLOCK_GETTIME_FOUND="no"
 693     ])
 694     ;;
 695 esac
 696
 697 if test "$CLOCK_GETTIME_FOUND" = "yes"; then
 698   AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [Have clock_gettime])
 699 fi
 700
 701 AC_CACHE_CHECK(for posix timers, gst_cv_posix_timers,
 702     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 703 #include <time.h>
 704 #ifdef HAVE_UNISTD_H
 705 #include <unistd.h>
 706 #endif
 707     ]], [[
 708 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 709 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 710 #endif
 711     ]])],[
 712       gst_cv_posix_timers=yes
 713     ],[
 714       gst_cv_posix_timers=no
 715     ])
 716 )
 717
 718 if test "$gst_cv_posix_timers" = "yes"; then
 719   AC_DEFINE(HAVE_POSIX_TIMERS,1,[Have posix timers])
 720   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 1"
 721 else
 722   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 0"
 723 fi
 724 AC_SUBST(GST_HAVE_POSIX_TIMERS_DEFINE)
 725 AM_CONDITIONAL(GST_HAVE_POSIX_TIMERS, test "$gst_cv_posix_timers" = "yes")
 726
 727 AC_CACHE_CHECK(for monotonic clock, gst_cv_monotonic_clock,
 728     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 729 #include <time.h>
 730 #ifdef HAVE_UNISTD_H
 731 #include <unistd.h>
 732 #endif
 733     ]], [[
 734 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 735 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 736 #endif
 737     ]])],[
 738       gst_cv_monotonic_clock=yes
 739     ],[
 740       gst_cv_monotonic_clock=no
 741     ])
 742 )
 743
 744 if test "$gst_cv_monotonic_clock" = "yes"; then
 745   AC_DEFINE(HAVE_MONOTONIC_CLOCK,1,[Have a monotonic clock])
 746   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 1"
 747 else
 748   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 0"
 749 fi
 750 AC_SUBST(GST_HAVE_MONOTONIC_CLOCK_DEFINE)
 751 AM_CONDITIONAL(GST_HAVE_MONOTONIC_CLOCK, test "$gst_cv_monotonic_clock" = "yes")
 752
 753 dnl Check for a way to display the function name in debug output
 754 AG_GST_CHECK_FUNCTION
 755
 756 dnl test if we have dladdr(); we use it for debugging; see gst/gstinfo.c
 757 save_cflags="$CFLAGS"
 758 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 759 AC_CHECK_LIB(dl, dladdr,
 760    AC_DEFINE(HAVE_DLADDR, 1, [Defined if we have dladdr ()])
 761    LIBS="$LIBS -ldl")
 762 CFLAGS="$save_cflags"
 763
 764 dnl Check printf stuff
 765 if test "x${GST_DISABLE_GST_DEBUG}" != "xyes"; then
 766   AC_TYPE_LONG_LONG_INT
 767   AC_TYPE_UNSIGNED_LONG_LONG_INT
 768
 769   if test x$ac_cv_type_long_long_int$ac_cv_type_unsigned_long_long_int = xyesyes; then
 770     AC_DEFINE([HAVE_LONG_LONG], [1], [Define to 1 if the system has the type long long])
 771   fi
 772
 773   dnl /usr/share/aclocal/inttypes_h.m4 - ships with gettext apparently
 774   gl_AC_HEADER_INTTYPES_H
 775
 776   dnl /usr/share/aclocal/stdint_h.m4 - ships with gettext apparently
 777   gl_AC_HEADER_STDINT_H
 778
 779   AC_CHECK_TYPES(ptrdiff_t)
 780
 781   AC_TYPE_INTMAX_T
 782   AC_TYPE_SIZE_T
 783 fi
 784
 785 dnl *** checks for dependency libraries ***
 786
 787 dnl GLib
 788 GLIB_REQ=2.40.0
 789 AG_GST_GLIB_CHECK([$GLIB_REQ])
 790
 791 dnl Check for documentation xrefs
 792 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 793 AC_SUBST(GLIB_PREFIX)
 794
 795 dnl GTK is optional and only used in examples
 796 HAVE_GTK=no
 797 GTK_REQ=3.10
 798 if test "x$BUILD_EXAMPLES" = "xyes"; then
 799   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 800   AC_SUBST(GTK_LIBS)
 801   AC_SUBST(GTK_CFLAGS)
 802 fi
 803 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 804
 805 dnl libunwind is optionally used by the leaks tracer
 806 AC_ARG_WITH([unwind],[AS_HELP_STRING([--with-unwind=yes|no|auto],[use libunwind])],
 807             [], [with_unwind=auto])
 808 if [ test "x${with_unwind}" != "xno" ]; then
 809   PKG_CHECK_MODULES(UNWIND, [libunwind],
 810       [
 811         HAVE_UNWIND=yes
 812         AC_DEFINE(HAVE_UNWIND, 1, [libunwind available])
 813         UNWIND_REQUIRE=libunwind
 814         AC_SUBST(UNWIND_REQUIRE)
 815       ],
 816       [
 817         HAVE_UNWIND=no
 818         if [ test "x${with_unwind}" = "xyes" ]; then
 819           AC_MSG_ERROR([could not find libunwind])
 820         fi
 821       ])
 822 else
 823   HAVE_UNWIND=no
 824 fi
 825
 826 dnl libdw is optionally used to add source lines and numbers to backtraces
 827 AC_ARG_WITH([dw],[AS_HELP_STRING([--with-dw=yes|no|auto],[use libdw])],
 828             [], [with_dw=auto])
 829 if [ test "x${with_dw}" != "xno" ]; then
 830   PKG_CHECK_MODULES(DW, [libdw],
 831       [
 832         HAVE_DW=yes
 833         AC_DEFINE(HAVE_DW, 1, [libdw available])
 834         DW_REQUIRE=libdw
 835         AC_SUBST(DW_REQUIRE)
 836       ],
 837       [
 838         HAVE_DW=no
 839         if [ test "x${with_dw}" = "xyes" ]; then
 840           AC_MSG_ERROR([could not find libdw])
 841         fi
 842       ])
 843 else
 844   HAVE_DW=no
 845 fi
 846
 847 dnl Check for backtrace() from libc
 848 AC_CHECK_FUNC(backtrace, [
 849   AC_CHECK_HEADERS([execinfo.h], [
 850     AC_DEFINE(HAVE_BACKTRACE,1,[Have backtrace])
 851   ], [], [])
 852 ])
 853
 854 dnl building of unit test libraries
 855 AC_ARG_ENABLE(check,
 856   AS_HELP_STRING([--disable-check],[disable building unit test libraries]),
 857   [
 858     case "${enableval}" in
 859       yes) BUILD_CHECK=yes ;;
 860       no)  BUILD_CHECK=no ;;
 861       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-check) ;;
 862     esac
 863   ], [
 864     dnl Default value
 865     case $host_os in
 866       mingw* | msvc* | mks*) BUILD_CHECK=no ;;
 867       *) BUILD_CHECK=yes ;;
 868     esac
 869 ])
 870 dnl bit of a misnomer, but keep the conditional named like this so we don't
 871 dnl have to change too much elsewhere
 872 AM_CONDITIONAL(HAVE_CHECK, test "x$BUILD_CHECK" = "xyes")
 873
 874 dnl configure the desired memory alignment
 875 AC_ARG_WITH([memory-alignment],
 876   AS_HELP_STRING([--with-memory-alignment],[8,N,malloc,pagesize (default is 32)]),
 877   [
 878     if test "x$withval" = "xyes"
 879     then
 880       AC_DEFINE(MEMORY_ALIGNMENT, 32, [Memory alignment to use])
 881     else
 882       case "${withval}" in
 883         malloc) AC_DEFINE(MEMORY_ALIGNMENT_MALLOC, 1, [Memory alignment by malloc default]) ;;
 884         pagesize)  AC_DEFINE(MEMORY_ALIGNMENT_PAGESIZE, 1, [Memory alignment by pagesize]) ;;
 885         *)   AC_DEFINE_UNQUOTED(MEMORY_ALIGNMENT, ${withval}, [Memory alignment to use]) ;;
 886       esac
 887     fi
 888   ], [
 889     AC_DEFINE(MEMORY_ALIGNMENT_MALLOC, 1, [Memory alignment by malloc default])
 890   ]
 891 )
 892
 893 dnl Check for -Bsymbolic-functions linker flag used to avoid
 894 dnl intra-library PLT jumps, if available.
 895 AC_ARG_ENABLE(Bsymbolic,
 896               [AS_HELP_STRING([--disable-Bsymbolic],[avoid linking with -Bsymbolic])],,
 897               [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
 898                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 899                LDFLAGS=-Wl,-Bsymbolic-functions
 900                LIBS=
 901                AC_TRY_LINK([], [return 0],
 902                            AC_MSG_RESULT(yes)
 903                            enable_Bsymbolic=yes,
 904                            AC_MSG_RESULT(no)
 905                            enable_Bsymbolic=no)
 906                LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
 907
 908
 909 dnl *** set variables based on configure arguments
 910
 911 dnl set license and copyright notice
 912 GST_LICENSE="LGPL"
 913 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 914 AC_SUBST(GST_LICENSE)
 915
 916 dnl define LIBDIR, GST_DATADIR so we can inform people where we live
 917 AS_AC_EXPAND(LIBDIR, $libdir)
 918 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [library dir])
 919 AS_AC_EXPAND(DATADIR, $datadir)
 920 AC_DEFINE_UNQUOTED(GST_DATADIR, "$DATADIR", [data dir])
 921
 922 dnl set location of plugin directory
 923 AG_GST_SET_PLUGINDIR
 924
 925 dnl make sure it doesn't complain about unused variables if debugging is disabled
 926 NO_WARNINGS=""
 927 if test "x${GST_DISABLE_GST_DEBUG}" = "xyes"; then
 928   NO_WARNINGS="-Wno-unused"
 929 fi
 930
 931 dnl define an ERROR_CFLAGS Makefile variable
 932 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [-Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef -Wwrite-strings -Wformat-nonliteral -Wformat-security -Wold-style-definition -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return -Wno-multichar -Wnested-externs $NO_WARNINGS])
 933
 934 dnl special warning flags for gst/printf
 935 AS_COMPILER_FLAG([-Wno-format-nonliteral], [PRINTF_CFLAGS="-Wno-format-nonliteral"])
 936 AC_SUBST(PRINTF_CFLAGS)
 937
 938 dnl disable strict aliasing
 939 AS_COMPILER_FLAG([-fno-strict-aliasing], [EXTRA_CFLAGS="-fno-strict-aliasing"])
 940 AC_SUBST(EXTRA_CFLAGS)
 941
 942 dnl define correct level for debugging messages
 943 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 944
 945 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 946
 947 dnl Overview:
 948 dnl GST_OPTION_CFLAGS:  common cflags for profiling, debugging, errors, ...
 949 dnl GST_ALL_*:          vars shared by all built objects
 950 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 951 dnl GST_OBJ_*:          additional vars to link to the core library
 952 dnl                     include GST_ALL_*
 953 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 954 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 955
 956 dnl GST_OPTION_CFLAGS
 957 if test "x$USE_DEBUG" = xyes; then
 958    PROFILE_CFLAGS="-g"
 959 fi
 960 AC_SUBST(PROFILE_CFLAGS)
 961
 962 # GST_DISABLE_DEPRECATED: hide the visibility of deprecated
 963 # functionality from the API that gstreamer uses
 964 # GST_REMOVE_DEPRECATED: don't compile deprecated functionality (breaks ABI)
 965 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 966   dnl Define _only_ when compiling from git (not for pre-releases or releases)
 967   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 968 else
 969   DEPRECATED_CFLAGS=""
 970 fi
 971 AC_SUBST(DEPRECATED_CFLAGS)
 972
 973 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time via e.g.
 974 dnl make DEPRECATED_CFLAGS=''
 975 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 976 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 977 GST_OPTION_CFLAGS="$GST_OPTION_CFLAGS"
 978 GST_OPTION_CXXFLAGS="$GST_OPTION_CXXFLAGS"
 979 AC_SUBST(GST_OPTION_CFLAGS)
 980 AC_SUBST(GST_OPTION_CXXFLAGS)
 981
 982 dnl GST_ALL_*
 983 dnl vars common to for all internal objects (core libs, elements, applications)
 984 dnl CFLAGS:
 985 dnl - src and build dirs need to be added because every piece that gets built
 986 dnl   will need the GStreamer source and generated headers
 987 dnl LIBS: XML doesn't need to be added because we don't explicitly use symbols
 988 dnl       from LibXML except for in the core library
 989 GST_ALL_CXXFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir)/libs -I\$(top_builddir) $GLIB_CFLAGS \$(GLIB_EXTRA_CFLAGS) $EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS) \$(ERROR_CXXFLAGS)"
 990 GST_ALL_CFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir)/libs -I\$(top_builddir) $GLIB_CFLAGS \$(GLIB_EXTRA_CFLAGS) $EXTRA_CFLAGS \$(GST_OPTION_CFLAGS) \$(ERROR_CFLAGS)"
 991
 992 dnl FIXME: check if LTLIBINTL is needed everywhere
 993 dnl I presume it is given that it contains the symbols that _() stuff maps to
 994 GST_ALL_LIBS="$GLIB_LIBS $LTLIBINTL \$(GCOV_LIBS)"
 995
 996 dnl LDFLAGS really should only contain flags, not libs - they get added before
 997 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 998 GST_ALL_LDFLAGS="-no-undefined"
 999 if test "x${enable_Bsymbolic}" = "xyes"; then
1000   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
1001 fi
1002
1003 AC_SUBST(GST_ALL_CFLAGS)
1004 AC_SUBST(GST_ALL_CXXFLAGS)
1005 AC_SUBST(GST_ALL_LIBS)
1006 AC_SUBST(GST_ALL_LDFLAGS)
1007
1008 dnl GST_LIB_LDFLAGS
1009 dnl linker flags shared by all libraries
1010 dnl LDFLAGS modifier defining exported symbols from built libraries
1011 GST_LIB_LDFLAGS="-export-symbols-regex \^[_]?\(gst_\|Gst\|GST_\).*"
1012 AC_SUBST(GST_LIB_LDFLAGS)
1013
1014 dnl GST_OBJ_*
1015 dnl default vars for all internal objects built on libgstreamer
1016 dnl includes GST_ALL_*
1017 GST_OBJ_CFLAGS="\$(GST_ALL_CFLAGS) $GST_OBJ_STATIC_CFLAGS"
1018 GST_OBJ_CXXFLAGS="\$(GST_ALL_CXXFLAGS) $GST_OBJ_STATIC_CFLAGS"
1019 GST_OBJ_LIBS="\$(top_builddir)/gst/libgstreamer-$GST_API_VERSION.la \$(GST_ALL_LIBS)"
1020 AC_SUBST(GST_OBJ_CFLAGS)
1021 AC_SUBST(GST_OBJ_CXXFLAGS)
1022 AC_SUBST(GST_OBJ_LIBS)
1023
1024 dnl GST_PLUGIN_LDFLAGS
1025 dnl LDFLAGS for plugins; includes GST_ALL_LDFLAGS
1026 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_.*' $GST_ALL_LDFLAGS"
1027 AC_SUBST(GST_PLUGIN_LDFLAGS, "$GST_PLUGIN_LDFLAGS")
1028
1029 dnl plugin scanner locations
1030 AS_AC_EXPAND(GST_PLUGIN_SCANNER_INSTALLED,${libexecdir}/gstreamer-$GST_API_VERSION/gst-plugin-scanner)
1031 AC_DEFINE_UNQUOTED(GST_PLUGIN_SCANNER_INSTALLED,
1032     "$GST_PLUGIN_SCANNER_INSTALLED", [location of the installed gst-plugin-scanner])
1033 AC_SUBST(GST_PLUGIN_SCANNER_INSTALLED)
1034
1035 case "${libexecdir}" in
1036   *libexec)
1037     GST_PLUGIN_SCANNER_SUBDIR="libexec";;
1038   *lib)
1039     GST_PLUGIN_SCANNER_SUBDIR="lib";;
1040   *)
1041     GST_PLUGIN_SCANNER_SUBDIR=`basename ${libexecdir}`;
1042     if test -z "$GST_PLUGIN_SCANNER_SUBDIR"; then
1043       AC_MSG_WARN([Couldn't determined libexecdir suffix, using "lib"])
1044       GST_PLUGIN_SCANNER_SUBDIR="lib";
1045     fi
1046     ;;
1047 esac
1048 AC_DEFINE_UNQUOTED(GST_PLUGIN_SCANNER_SUBDIR,
1049     "$GST_PLUGIN_SCANNER_SUBDIR", [libexecdir path component, used to find plugin-scanner on relocatable builds on windows])
1050
1051
1052 dnl completion helper locations
1053 AS_AC_EXPAND(GST_COMPLETION_HELPER_INSTALLED,${libexecdir}/gstreamer-$GST_API_VERSION/gst-completion-helper)
1054 AC_DEFINE_UNQUOTED(GST_COMPLETION_HELPER_INSTALLED,
1055     "$GST_COMPLETION_HELPER_INSTALLED", [location of the installed gst-completion-helper])
1056 AC_SUBST(GST_COMPLETION_HELPER_INSTALLED)
1057
1058 dnl ptp helper locations
1059 AS_AC_EXPAND(GST_PTP_HELPER_INSTALLED,${libexecdir}/gstreamer-$GST_API_VERSION/gst-ptp-helper)
1060 AC_DEFINE_UNQUOTED(GST_PTP_HELPER_INSTALLED,
1061     "$GST_PTP_HELPER_INSTALLED", [location of the installed gst-ptp-helper])
1062 AC_SUBST(GST_PTP_HELPER_INSTALLED)
1063
1064 dnl things for our internal libcheck (must be called even if building
1065 dnl libcheck is disabled because it defines conditionals)
1066 AG_GST_CHECK_CHECKS
1067
1068 AC_CONFIG_FILES(
1069 Makefile
1070 data/Makefile
1071 data/bash-completion/helpers/gst
1072 gst/Makefile
1073 gst/gstconfig.h
1074 gst/gstversion.h
1075 gst/parse/Makefile
1076 gst/printf/Makefile
1077 libs/Makefile
1078 libs/gst/Makefile
1079 libs/gst/base/Makefile
1080 libs/gst/check/Makefile
1081 libs/gst/check/libcheck/Makefile
1082 libs/gst/check/internal-check.h:libs/gst/check/libcheck/check.h.in
1083 libs/gst/controller/Makefile
1084 libs/gst/helpers/Makefile
1085 libs/gst/net/Makefile
1086 plugins/Makefile
1087 plugins/elements/Makefile
1088 plugins/tracers/Makefile
1089 po/Makefile.in
1090 tests/Makefile
1091 tests/benchmarks/Makefile
1092 tests/check/Makefile
1093 tests/misc/Makefile
1094 tests/examples/Makefile
1095 tests/examples/adapter/Makefile
1096 tests/examples/controller/Makefile
1097 tests/examples/stepping/Makefile
1098 tests/examples/helloworld/Makefile
1099 tests/examples/memory/Makefile
1100 tests/examples/netclock/Makefile
1101 tests/examples/ptp/Makefile
1102 tests/examples/streamiddemux/Makefile
1103 tests/examples/streams/Makefile
1104 tools/Makefile
1105 common/Makefile
1106 common/m4/Makefile
1107 docs/Makefile
1108 docs/gst/Makefile
1109 docs/gst/gstreamer.types
1110 docs/libs/Makefile
1111 docs/plugins/Makefile
1112 docs/version.entities
1113 m4/Makefile
1114 pkgconfig/Makefile
1115 stamp.h
1116 pkgconfig/gstreamer.pc
1117 pkgconfig/gstreamer-uninstalled.pc
1118 pkgconfig/gstreamer-base.pc
1119 pkgconfig/gstreamer-base-uninstalled.pc
1120 pkgconfig/gstreamer-check.pc
1121 pkgconfig/gstreamer-check-uninstalled.pc
1122 pkgconfig/gstreamer-controller.pc
1123 pkgconfig/gstreamer-controller-uninstalled.pc
1124 pkgconfig/gstreamer-net.pc
1125 pkgconfig/gstreamer-net-uninstalled.pc
1126 )
1127
1128 AC_OUTPUT
1129
1130 dnl negate for output
1131 if test "x${GST_DISABLE_GST_DEBUG}" = "xno"; then enable_gst_debug="yes"; fi
1132 if test "x${GST_DISABLE_GST_TRACER_HOOKS}" = "xno"; then enable_gst_tracer_hooks="yes"; fi
1133 if test "x${GST_DISABLE_PARSE}" = "xno"; then enable_parse="yes"; fi
1134 if test "x${GST_DISABLE_OPTION_PARSING}" = "xno"; then enable_option_parsing="yes"; fi
1135 if test "x${GST_DISABLE_PLUGIN}" = "xno"; then enable_plugin="yes"; fi
1136 if test "x${GST_DISABLE_REGISTRY}" = "xno"; then enable_registry="yes"; fi
1137
1138 echo "
1139
1140 Configuration
1141         Version                    : ${VERSION}
1142         Source code location       : ${srcdir}
1143         Prefix                     : ${prefix}
1144         Compiler                   : ${CC}
1145         Package name               : ${GST_PACKAGE_NAME}
1146         Package origin             : ${GST_PACKAGE_ORIGIN}
1147
1148         API Documentation          : ${enable_gtk_doc}
1149
1150         Debug logging              : ${enable_gst_debug}
1151         Tracing subsystem hooks    : ${enable_gst_tracer_hooks}
1152         Command-line parser        : ${enable_parse}
1153         Option parsing in gst_init : ${enable_option_parsing}
1154         Plugin registry            : ${enable_registry}
1155         Plugin support             : ${enable_plugin}
1156         Static plugins             : ${enable_static_plugins}
1157         Unit testing support       : ${BUILD_CHECK}
1158         PTP clock support          : ${HAVE_PTP}
1159         libunwind support          : ${HAVE_UNWIND}
1160         libdw support              : ${HAVE_DW}
1161
1162         Debug                      : ${USE_DEBUG}
1163         Profiling                  : ${USE_PROFILING}
1164
1165         Building benchmarks        : ${BUILD_BENCHMARKS}
1166         Building examples          : ${BUILD_EXAMPLES}
1167         Building test apps         : ${BUILD_TESTS}
1168         Building tests that fail   : ${BUILD_FAILING_TESTS}
1169         Building tools             : ${BUILD_TOOLS}
1170 "