configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, cvs and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for cvs/pre
   8 AC_INIT(GStreamer Good Plug-ins, 0.10.9.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-good)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_CVS="no", GST_CVS="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl our libraries and install dirs use major.minor as a version
  36 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  37 dnl we override it here if we need to for the release candidate of new series
  38 GST_MAJORMINOR=0.10
  39 AC_SUBST(GST_MAJORMINOR)
  40
  41 dnl FIXME: this macro doesn't actually work;
  42 dnl the generated libtool script has no support for the listed tags.
  43 dnl So this needs to be fixed first if we want to use this
  44 dnl AS_LIBTOOL_TAGS
  45
  46 AC_LIBTOOL_WIN32_DLL
  47 AM_PROG_LIBTOOL
  48
  49 dnl *** required versions of GStreamer stuff ***
  50 GST_REQ=0.10.20.1
  51 GSTPB_REQ=0.10.20.1
  52
  53 dnl *** autotools stuff ****
  54
  55 dnl allow for different autotools
  56 AS_AUTOTOOLS_ALTERNATE
  57
  58 dnl Add parameters for aclocal
  59 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  60
  61 dnl set up gettext
  62 dnl the version check needs to stay here because autopoint greps for it
  63 AM_GNU_GETTEXT_VERSION([0.11.5])
  64 AM_GNU_GETTEXT([external])
  65 AG_GST_GETTEXT([gst-plugins-good-$GST_MAJORMINOR])
  66
  67 dnl *** check for arguments to configure ***
  68
  69 AG_GST_ARG_DEBUG
  70 AG_GST_ARG_PROFILING
  71 AG_GST_ARG_VALGRIND
  72 AG_GST_ARG_GCOV
  73
  74 AG_GST_ARG_EXAMPLES
  75
  76 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  77 AG_GST_ARG_WITH_PACKAGE_NAME
  78 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  79
  80 AG_GST_ARG_WITH_PLUGINS
  81
  82 AG_GST_ARG_ENABLE_EXTERNAL
  83
  84 AG_GST_ARG_ENABLE_EXPERIMENTAL
  85
  86 dnl *** checks for platform ***
  87
  88 dnl * hardware/architecture *
  89
  90 dnl common/m4/gst-arch.m4
  91 dnl check CPU type
  92 AG_GST_ARCH
  93
  94 dnl Determine endianness
  95 AC_C_BIGENDIAN
  96
  97 dnl *** checks for programs ***
  98
  99 dnl find a compiler
 100 AC_PROG_CC
 101
 102 dnl determine c++ compiler
 103 AC_PROG_CXX
 104 dnl determine if c++ is available on this system
 105 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 106
 107 dnl determine c++ preprocessor
 108 dnl FIXME: do we need this ?
 109 AC_PROG_CXXCPP
 110
 111 AS_PROG_OBJC
 112
 113 dnl check if the compiler supports '-c' and '-o' options
 114 AM_PROG_CC_C_O
 115
 116 dnl find an assembler
 117 AM_PROG_AS
 118
 119 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 120 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 121
 122 dnl check for gconftool-2
 123 dnl this macro defines an am conditional, so it needs to be run always
 124 AM_GCONF_SOURCE_2
 125
 126 dnl check for documentation tools
 127 GTK_DOC_CHECK([1.3])
 128 AS_PATH_PYTHON([2.1])
 129 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 130
 131 dnl *** checks for libraries ***
 132
 133 dnl check for libm, for sin()
 134 AC_CHECK_LIBM
 135 AC_SUBST(LIBM)
 136
 137 dnl *** checks for header files ***
 138
 139 dnl check if we have ANSI C header files
 140 AC_HEADER_STDC
 141
 142 dnl used by ext/wavpack
 143 AX_CREATE_STDINT_H
 144
 145 dnl used in gst/rtp/gstasteriskh263.c
 146 AC_CHECK_HEADERS([netinet/in.h])
 147 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 148 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 149
 150 dnl used in gst/udp
 151 AC_CHECK_HEADERS([sys/time.h])
 152
 153 dnl *** checks for types/defines ***
 154
 155 dnl Check for FIONREAD ioctl declaration.  This check is needed
 156 dnl for the UDP plugin to build on Solaris
 157 GST_CHECK_FIONREAD
 158
 159 dnl *** checks for structures ***
 160
 161 dnl *** checks for compiler characteristics ***
 162
 163 dnl check if we have GCC inline-asm
 164 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 165 if test x$HAVE_GCC_ASM = xyes ; then
 166   AC_DEFINE(HAVE_GCC_ASM, 1,
 167     [Define if compiler supports gcc inline assembly])
 168 fi
 169 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 170
 171 dnl *** checks for library functions ***
 172
 173 LIBS_SAVE=$LIBS
 174 LIBS="$LIBS $LIBM"
 175 AC_CHECK_FUNCS(rint sinh cosh asinh)
 176 LIBS=$LIBS_SAVE
 177
 178 dnl Check for mmap (needed by electricfence plugin)
 179 AC_FUNC_MMAP
 180 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" == "xyes")
 181
 182 dnl *** checks for dependency libraries ***
 183
 184 dnl GLib is required
 185 AG_GST_GLIB_CHECK([2.12])
 186
 187 dnl liboil is required
 188 PKG_CHECK_MODULES(LIBOIL, liboil-0.3 >= 0.3.8, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 189 if test "x$HAVE_LIBOIL" != "xyes"; then
 190   AC_ERROR([liboil-0.3.8 or later is required])
 191 fi
 192
 193 dnl checks for gstreamer
 194 dnl uninstalled is selected preferentially -- see pkg-config(1)
 195 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 196 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 197 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ], yes)
 198 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 199 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 200 AG_GST_CHECK_GST_PLUGINS_BASE($GST_MAJORMINOR, [$GSTPB_REQ], yes)
 201
 202 GST_TOOLS_DIR=`pkg-config --variable=toolsdir gstreamer-$GST_MAJORMINOR`
 203 if test -z $GST_TOOLS_DIR; then
 204   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 205 fi
 206 AC_SUBST(GST_TOOLS_DIR)
 207
 208 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 209 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 210
 211 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 212
 213 dnl Check for documentation xrefs
 214 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 215 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 216 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_MAJORMINOR`"
 217 AC_SUBST(GLIB_PREFIX)
 218 AC_SUBST(GST_PREFIX)
 219 AC_SUBST(GSTPB_PREFIX)
 220
 221 dnl GTK is optional and used in examples
 222 HAVE_GTK=NO
 223 PKG_CHECK_MODULES(GTK2, gtk+-2.0 >= 2.2.0, HAVE_GTK_22=yes, HAVE_GTK_22=no)
 224 if test "x$HAVE_GTK_22" = "xyes"; then
 225   HAVE_GTK=yes
 226   GTK_VERSION=`$PKG_CONFIG --variable=gtk_binary_version gtk+-2.0`
 227   AC_SUBST(GTK_VERSION)
 228   GTK_PREFIX=`$PKG_CONFIG --variable=prefix gdk-pixbuf-2.0`
 229   AC_SUBST(GTK_BASE_DIR)
 230   GDK_PIXBUF_LIBDIR=`$PKG_CONFIG --variable=libdir gdk-pixbuf-2.0`
 231   GDK_PIXBUF_PREFIXDIR=`$PKG_CONFIG --variable=prefix gdk-pixbuf-2.0`
 232   AC_SUBST(GTK_BASE_DIR)
 233 else
 234   PKG_CHECK_MODULES(GTK2, gtk+-2.0, HAVE_GTK_20=yes, HAVE_GTK_20=no)
 235 fi
 236 if test "x$HAVE_GTK_20" = "xyes"; then
 237   HAVE_GTK=yes
 238 fi
 239 GTK_CFLAGS=$GTK2_CFLAGS
 240 GTK_LIBS=$GTK2_LIBS
 241 AC_SUBST(GTK_LIBS)
 242 AC_SUBST(GTK_CFLAGS)
 243 AC_SUBST(HAVE_GTK)
 244 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 245
 246 dnl should we install schemas ?
 247 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONFTOOL, true)
 248 AG_GST_CHECK_FEATURE(GCONFTOOL, [GConf schemas], , [
 249   AC_PATH_PROG(GCONFTOOL, gconftool-2, no)
 250   if test x$GCONFTOOL = xno; then
 251     AC_MSG_WARN(Not installing GConf schemas)
 252     HAVE_GCONFTOOL="no"
 253   else
 254     HAVE_GCONFTOOL="yes"
 255   fi
 256   AC_SUBST(HAVE_GCONFTOOL)
 257 ])
 258
 259 dnl *** set variables based on configure arguments ***
 260
 261 dnl set license and copyright notice
 262 GST_LICENSE="LGPL"
 263 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 264 AC_SUBST(GST_LICENSE)
 265
 266 dnl set location of plugin directory
 267 AG_GST_SET_PLUGINDIR
 268
 269 dnl define an ERROR_CFLAGS Makefile variable
 270 AG_GST_SET_ERROR_CFLAGS($GST_CVS)
 271
 272 dnl define an ERROR_CXXFLAGS Makefile variable
 273 AG_GST_SET_ERROR_CXXFLAGS($GST_CVS)
 274
 275 dnl define correct level for debugging messages
 276 AG_GST_SET_LEVEL_DEFAULT($GST_CVS)
 277
 278 dnl used in examples
 279 AG_GST_DEFAULT_ELEMENTS
 280
 281 dnl *** plug-ins to include ***
 282
 283 dnl these are all the gst plug-ins, compilable without additional libs
 284 dnl videofilter is at the top because others depend on it
 285 AG_GST_CHECK_PLUGIN(videofilter)
 286 AG_GST_CHECK_PLUGIN(alpha)
 287 AG_GST_CHECK_PLUGIN(apetag)
 288 AG_GST_CHECK_PLUGIN(audiofx)
 289 AG_GST_CHECK_PLUGIN(auparse)
 290 AG_GST_CHECK_PLUGIN(autodetect)
 291 AG_GST_CHECK_PLUGIN(avi)
 292 AG_GST_CHECK_PLUGIN(cutter)
 293 AG_GST_CHECK_PLUGIN(debug)
 294 AG_GST_CHECK_PLUGIN(effectv)
 295 AG_GST_CHECK_PLUGIN(equalizer)
 296 AG_GST_CHECK_PLUGIN(id3demux)
 297 AG_GST_CHECK_PLUGIN(icydemux)
 298 AG_GST_CHECK_PLUGIN(interleave)
 299 AG_GST_CHECK_PLUGIN(flx)
 300 AG_GST_CHECK_PLUGIN(goom)
 301 AG_GST_CHECK_PLUGIN(goom2k1)
 302 AG_GST_CHECK_PLUGIN(law)
 303 AG_GST_CHECK_PLUGIN(level)
 304 AG_GST_CHECK_PLUGIN(matroska)
 305 AG_GST_CHECK_PLUGIN(monoscope)
 306 AG_GST_CHECK_PLUGIN(multifile)
 307 AG_GST_CHECK_PLUGIN(multipart)
 308 AG_GST_CHECK_PLUGIN(qtdemux)
 309 AG_GST_CHECK_PLUGIN(replaygain)
 310 AG_GST_CHECK_PLUGIN(rtp)
 311 AG_GST_CHECK_PLUGIN(rtsp)
 312 AG_GST_CHECK_PLUGIN(smpte)
 313 AG_GST_CHECK_PLUGIN(spectrum)
 314 AG_GST_CHECK_PLUGIN(udp)
 315 AG_GST_CHECK_PLUGIN(videobox)
 316 AG_GST_CHECK_PLUGIN(videocrop)
 317 AG_GST_CHECK_PLUGIN(videomixer)
 318 AG_GST_CHECK_PLUGIN(wavenc)
 319 AG_GST_CHECK_PLUGIN(wavparse)
 320
 321 dnl disable gst plugins we might not be able to build on this
 322 dnl platform: udp and rtsp (ugly but minimally invasive)
 323 dnl FIXME: maybe move to sys
 324 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 325 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 326
 327 if test "x$HAVE_SYS_SOCKET_H" != "xyes" -a "x$HAVE_WINSOCK2_H" != "xyes"; then
 328   AG_GST_DISABLE_PLUGIN(udp)
 329   AG_GST_DISABLE_PLUGIN(rtsp)
 330 fi
 331
 332 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 333   WIN32_LIBS="-lws2_32"
 334   AC_SUBST(WIN32_LIBS)
 335 fi
 336
 337 dnl disable experimental plug-ins
 338 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 339   AG_GST_DISABLE_PLUGIN(monoscope)
 340 fi
 341
 342 dnl *** sys plug-ins ***
 343
 344 echo
 345 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 346 echo
 347
 348 dnl DirectDraw
 349 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTDRAW, true)
 350 AG_GST_CHECK_FEATURE(DIRECTDRAW, [DirectDraw plug-in], directdrawsink, [
 351   HAVE_DIRECTDRAW="no"
 352   save_CFLAGS="$CFLAGS"
 353   save_LDFLAGS="$LDFLAGS"
 354   save_LIBS="$LIBS"
 355   CFLAGS="$CFLAGS $DIRECTDRAW_CFLAGS"
 356   LDFLAGS="$LDFLAGS $DIRECTDRAW_LDFLAGS"
 357   LIBS="$LIBS -lddraw -lgdi32"
 358   AC_MSG_CHECKING(for DirectDraw LDFLAGS)
 359   AC_LINK_IFELSE([
 360 #include <windows.h>
 361 #include <ddraw.h>
 362
 363 int main ()
 364 {
 365   GetStockObject(0);
 366   DirectDrawCreate(NULL, NULL, NULL);
 367
 368   return 0;
 369 }
 370 ],
 371     [HAVE_DIRECTDRAW="yes"],
 372     [HAVE_DIRECTDRAW="no"])
 373   AC_MSG_RESULT($HAVE_DIRECTDRAW)
 374   CFLAGS=$save_CFLAGS
 375   LDFLAGS=$save_LDFLAGS
 376   LIBS=$save_LIBS
 377
 378   if test "x$HAVE_DIRECTDRAW" = "xyes";  then
 379     dnl this is much more than we want
 380     DIRECTDRAW_LIBS="-lddraw -ldxguid -lgdi32"
 381     AC_SUBST(DIRECTDRAW_CFLAGS)
 382     AC_SUBST(DIRECTDRAW_LDFLAGS)
 383     AC_SUBST(DIRECTDRAW_LIBS)
 384   fi
 385   AC_SUBST(HAVE_DIRECTDRAW)
 386 ])
 387
 388 dnl DirectSound
 389 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 390 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 391   HAVE_DIRECTSOUND="no"
 392   save_CFLAGS="$CFLAGS"
 393   save_LDFLAGS="$LDFLAGS"
 394   save_LIBS="$LIBS"
 395   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 396   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 397   LIBS="$LIBS -ldsound -ldxerr9"
 398   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 399   AC_LINK_IFELSE([
 400 #include <windows.h>
 401 #include <dxerr9.h>
 402 #include <dsound.h>
 403
 404 int main ()
 405 {
 406   DXGetErrorString9 (0);
 407   DirectSoundCreate(NULL, NULL, NULL);
 408
 409   return 0;
 410 }
 411 ],
 412     [HAVE_DIRECTSOUND="yes"],
 413     [HAVE_DIRECTSOUND="no"])
 414   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 415   CFLAGS=$save_CFLAGS
 416   LDFLAGS=$save_LDFLAGS
 417   LIBS=$save_LIBS
 418
 419   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 420     dnl this is much more than we want
 421     DIRECTSOUND_LIBS="-ldsound -ldxerr9"
 422     AC_SUBST(DIRECTSOUND_CFLAGS)
 423     AC_SUBST(DIRECTSOUND_LDFLAGS)
 424     AC_SUBST(DIRECTSOUND_LIBS)
 425   fi
 426   AC_SUBST(HAVE_DIRECTSOUND)
 427 ])
 428
 429 dnl *** OSS audio *** (Linux, *BSD)
 430 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 431 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 432  HAVE_OSS="yes"
 433 dnl Linux and newer BSD versions :
 434  AC_CHECK_HEADER(sys/soundcard.h, [
 435    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 436    ] , [
 437 dnl Some old BSD versions and also newer OpenBSD versions :
 438    AC_CHECK_HEADER(soundcard.h, [
 439      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 440      ], [
 441   dnl Some old BSD versions :
 442      AC_CHECK_HEADER(machine/soundcard.h, [
 443        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 444          [Define if OSS includes are in /machine/])
 445        ], [
 446        HAVE_OSS="no"
 447      ])
 448    ])
 449  ])
 450 ])
 451
 452 dnl *** Sun Audio ***
 453 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 454 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 455   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 456 ])
 457
 458 dnl *** OSX Audio ***
 459 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 460 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 461   AC_CHECK_HEADER(CoreAudio/CoreAudio.h, HAVE_OSX_AUDIO="yes", HAVE_OSX_AUDIO="no")
 462 ])
 463
 464 dnl *** OS X video ***
 465 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 466 HAVE_OSX_VIDEO="no"
 467 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 468   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 469 ])
 470 dnl in case header OpenGL/gl.h is found on other platforms
 471 case "$host" in
 472   *-*darwin*)
 473     dnl do nothing
 474     ;;
 475   *)
 476     HAVE_OSX_VIDEO="no"
 477     ;;
 478 esac
 479
 480
 481 dnl *** Video 4 Linux 2 ***
 482 dnl for information about the header/define, see sys/v4l2/gstv4l2element.h
 483 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 484 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 485 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], v4l2src, [
 486   AC_MSG_CHECKING([Checking for up to date v4l2 installation])
 487   AC_TRY_COMPILE([
 488 #include <sys/types.h>
 489 #ifdef __sun /* Solaris */
 490 #include <sys/types.h>
 491 #include <sys/videodev2.h>
 492 #else /* Linux */
 493 #include <linux/types.h>
 494 #define _LINUX_TIME_H
 495 #define __user
 496 #include <linux/videodev2.h>
 497 #endif
 498 #if defined(V4L2_MAJOR_VERSION) || defined(V4L2_MINOR_VERSION)
 499 #error too early v4l2 version or no v4l2 at all
 500 #endif
 501     ], [
 502 return 0;
 503     ], [
 504       HAVE_GST_V4L2="yes"
 505       AC_MSG_RESULT(yes)
 506     ], [
 507       HAVE_GST_V4L2="no"
 508       AC_MSG_RESULT(no)
 509
 510       HAVE_VIDEODEV=no
 511       AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_VIDEODEV=yes ],
 512       [
 513         AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_VIDEODEV=yes ])
 514       ])
 515
 516       if test "x$HAVE_VIDEODEV" = "xyes"; then
 517         AC_MSG_WARN([video4linux2 headers were found, but they're old.])
 518         AC_MSG_WARN([Please update v4l2 to compile the v4l2 plugins])
 519       else
 520         AC_MSG_WARN([video4linux2 was not found])
 521       fi
 522     ])
 523
 524   if [ test x$HAVE_GST_V4L2 = xyes ]; then
 525     dnl check for missing v4l2_buffer declaration (see #135919)
 526     MISSING_DECL=0
 527     AC_MSG_CHECKING(struct v4l2_buffer declaration)
 528     AC_TRY_COMPILE([
 529 #include <sys/types.h>
 530 #ifdef __sun /* Solaris */
 531 #include <sys/types.h>
 532 #include <sys/videodev2.h>
 533 #else /* Linux */
 534 #include <linux/types.h>
 535 #define _LINUX_TIME_H
 536 #define __user
 537 #include <linux/videodev2.h>
 538 #endif
 539     ],[
 540 struct v4l2_buffer buf;
 541 buf.index = 0;
 542 return 0;
 543     ], [ AC_MSG_RESULT(yes) ], [ MISSING_DECL=1 && AC_MSG_RESULT(no) ])
 544     if [ test x$MISSING_DECL = x1 ]; then
 545       AC_DEFINE(GST_V4L2_MISSING_BUFDECL, 1, [struct v4l2_buffer missing])
 546     fi
 547
 548     dnl check for XOverlay libraries
 549     AG_GST_CHECK_XV
 550   fi
 551 ])
 552
 553 dnl Check for X11
 554 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 555 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 556                   [ximagesrc], [
 557   AC_PATH_XTRA
 558
 559   dnl now try to find the HEADER
 560   ac_cflags_save="$CFLAGS"
 561   ac_cppflags_save="$CPPFLAGS"
 562   CFLAGS="$CFLAGS $X_CFLAGS"
 563   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 564   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 565
 566   if test "x$HAVE_X" = "xno"
 567   then
 568     AC_MSG_NOTICE([cannot find X11 development files])
 569   else
 570     dnl this is much more than we want
 571     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 572     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 573     dnl it does not add the libs; therefore we add them here
 574     X_LIBS="$X_LIBS -lX11"
 575     AC_SUBST(X_CFLAGS)
 576     AC_SUBST(X_LIBS)
 577
 578     dnl check for Xfixes
 579     PKG_CHECK_MODULES(XFIXES, xfixes, HAVE_XFIXES="yes", HAVE_XFIXES="no")
 580     if test "x$HAVE_XFIXES" = "xyes"
 581     then
 582         XFIXES_CFLAGS="-DHAVE_XFIXES $XFIXES_CFLAGS"
 583     fi
 584     AC_SUBST(XFIXES_LIBS)
 585     AC_SUBST(XFIXES_CFLAGS)
 586
 587     dnl check for Xdamage
 588     PKG_CHECK_MODULES(XDAMAGE, xdamage, HAVE_XDAMAGE="yes", HAVE_XDAMAGE="no")
 589     if test "x$HAVE_XDAMAGE" = "xyes"
 590     then
 591         XDAMAGE_CFLAGS="-DHAVE_XDAMAGE $XDAMAGE_CFLAGS"
 592     fi
 593     AC_SUBST(XDAMAGE_LIBS)
 594     AC_SUBST(XDAMAGE_CFLAGS)
 595   fi
 596   AC_SUBST(HAVE_X)
 597   CFLAGS="$ac_cflags_save"
 598   CPPFLAGS="$ac_cppflags_save"
 599 ])
 600
 601 dnl FIXME: this should be rolled into the test above, it's just an additional
 602 dnl feature of the ximagesrc plug-in
 603 dnl This is the same as in gst-plugins-base
 604 dnl check for X Shm
 605 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 606 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 607   if test x$HAVE_X = xyes; then
 608     AC_CHECK_LIB(Xext, XShmAttach,
 609                  HAVE_XSHM="yes", HAVE_XSHM="no",
 610                  $X_LIBS)
 611     if test "x$HAVE_XSHM" = "xyes"; then
 612       XSHM_LIBS="-lXext"
 613     else
 614       dnl On AIX, it is in XextSam instead, but we still need -lXext
 615       AC_CHECK_LIB(XextSam, XShmAttach,
 616                    HAVE_XSHM="yes", HAVE_XSHM="no",
 617                    $X_LIBS)
 618       if test "x$HAVE_XSHM" = "xyes"; then
 619         XSHM_LIBS="-lXext -lXextSam"
 620       fi
 621     fi
 622   fi
 623 ], ,[
 624   AC_SUBST(HAVE_XSHM)
 625   AC_SUBST(XSHM_LIBS)
 626 ])
 627
 628 dnl for V4L2, we also need to know if we have XVIDEO
 629 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 630 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 631                   [], [
 632   AG_GST_CHECK_XV
 633 ])
 634
 635 dnl *** ext plug-ins ***
 636 dnl keep this list sorted alphabetically !
 637
 638 if test "x$BUILD_EXTERNAL" = "xyes"; then
 639
 640 echo
 641 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 642 echo
 643
 644 dnl *** aalib ***
 645 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 646 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 647   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 648   AS_SCRUB_INCLUDE(AALIB_CFLAGS)
 649 ])
 650
 651 dnl *** annodex ***
 652 translit(dnm, m, l) AM_CONDITIONAL(USE_ANNODEX, true)
 653 AG_GST_CHECK_FEATURE(ANNODEX, [XML library], annodex, [
 654   AG_GST_PKG_CHECK_MODULES(ANNODEX, libxml-2.0 >= 2.4.9)
 655 ])
 656
 657 dnl *** cairo ***
 658 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 659 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering], cairo, [
 660   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.0.0)
 661 ])
 662
 663 dnl **** ESound ****
 664 translit(dnm, m, l) AM_CONDITIONAL(USE_ESD, true)
 665 AG_GST_CHECK_FEATURE(ESD, [ESounD sound daemon], esdsink, [
 666   AG_GST_PKG_CHECK_MODULES(ESD, esound >= 0.2.12)
 667   if test $HAVE_ESD = no
 668   then
 669     AM_PATH_ESD(0.2.12, HAVE_ESD="yes")
 670     AS_SCRUB_INCLUDE(ESD_CFLAGS)
 671   fi
 672 ])
 673
 674 dnl *** FLAC ***
 675 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 676 AC_TRY_COMPILE([#include <FLAC/export.h>], [
 677   #if FLAC_API_VERSION_CURRENT < 8
 678   #error "legacy flac API"
 679   #endif
 680   ], [ legacy_flac=no ], [ legacy_flac=yes ], [ legacy_flac=no ])
 681
 682 if test "x$legacy_flac" = "xyes"; then
 683 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 684   AG_GST_CHECK_LIBHEADER(FLAC, FLAC, FLAC__seekable_stream_encoder_new, -lm, FLAC/all.h, FLAC_LIBS="-lFLAC -lm")
 685   dnl API change in FLAC 1.1.1, so require that...
 686   dnl (this check will also fail with FLAC 1.1.3 which changed API again)
 687   if test x$HAVE_FLAC = xyes; then
 688     AC_CHECK_DECL(FLAC__SEEKABLE_STREAM_ENCODER_TELL_ERROR,
 689                   HAVE_FLAC="yes", HAVE_FLAC="no", [
 690 #include <FLAC/seekable_stream_encoder.h>
 691                   ])
 692   fi
 693   AC_SUBST(FLAC_LIBS)
 694 ])
 695 else
 696 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 697   AG_GST_CHECK_LIBHEADER(FLAC, FLAC, FLAC__stream_encoder_new, -lm, FLAC/all.h, FLAC_LIBS="-lFLAC -lm")
 698   dnl API change in FLAC 1.1.3, so require that...
 699   if test x$HAVE_FLAC = xyes; then
 700     AC_CHECK_DECL(FLAC__STREAM_ENCODER_TELL_STATUS_ERROR,
 701                   HAVE_FLAC="yes", HAVE_FLAC="no", [
 702 #include <FLAC/stream_encoder.h>
 703                   ])
 704   fi
 705   AC_SUBST(FLAC_LIBS)
 706 ])
 707 fi
 708
 709 dnl *** GConf ***
 710 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONF, true)
 711 AG_GST_CHECK_FEATURE(GCONF, [GConf libraries], gconfelements, [
 712   AG_GST_PKG_CHECK_MODULES(GCONF, gconf-2.0)
 713 ])
 714
 715 dnl *** GDK pixbuf ***
 716 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 717 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 718   if test $HAVE_GTK_22 = "yes"; then HAVE_GDK_PIXBUF=yes; fi;
 719 ])
 720
 721 dnl *** HAL ***
 722 translit(dnm, m, l) AM_CONDITIONAL(USE_HAL, true)
 723 AG_GST_CHECK_FEATURE(HAL, [HAL libraries], halelements, [
 724   AG_GST_PKG_CHECK_MODULES(HAL, [hal >= 0.5.6, dbus-1 >= 0.32])
 725 ])
 726
 727 dnl *** jpeg ***
 728 dnl FIXME: we could use header checks here as well IMO
 729 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 730 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 731   AC_ARG_WITH(jpeg-mmx,
 732     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 733   OLD_LIBS="$LIBS"
 734   if test x$with_jpeg_mmx != x; then
 735     LIBS="$LIBS -L$with_jpeg_mmx"
 736   fi
 737   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 738   JPEG_LIBS="$LIBS -ljpeg-mmx"
 739   LIBS="$OLD_LIBS"
 740   if test x$HAVE_JPEG != xyes; then
 741     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 742     JPEG_LIBS="-ljpeg"
 743   fi
 744   AC_SUBST(JPEG_LIBS)
 745 ])
 746
 747 dnl *** libcaca ***
 748 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 749 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 750   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 751   dnl only newer versions of libcaca ship caca.pc, so try caca-config as well
 752   if test "x$HAVE_LIBCACA" != "xyes"; then
 753     AG_GST_CHECK_CONFIGPROG(LIBCACA, caca-config)
 754     dnl see if it compilation works too, might not if we are cross-compiling
 755     if test "x$HAVE_LIBCACA" = "xyes"; then
 756       AC_CHECK_LIB([caca], [caca_init], [HAVE_LIBCACA=yes],
 757                    [HAVE_LIBCACA=no], [$LIBCACA_LIBS])
 758     fi
 759   fi
 760 ])
 761
 762 dnl *** libdv ***
 763 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 764 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 765   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 766 ])
 767
 768 dnl *** libpng ***
 769 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 770 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 771   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng12)
 772 ])
 773
 774 dnl *** pulseaudio ***
 775 translit(dnm, m, l) AM_CONDITIONAL(USE_PULSE, true)
 776 AG_GST_CHECK_FEATURE(PULSE, [pulseaudio plug-in], pulseaudio, [
 777   AG_GST_PKG_CHECK_MODULES(PULSE, libpulse >= 0.9.8)
 778 ])
 779
 780 dnl *** dv1394 ***
 781 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 782 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 783   dnl first test for libraw1394 >= 1.2.1
 784   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.2.1)
 785   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 786   dnl now see how far we got
 787   if test x$HAVE_RAW1394 = xyes && \
 788      test x$HAVE_LIBIEC61883 = xyes; then
 789        AG_GST_CHECK_LIBHEADER(AVC1394,
 790         avc1394, avc1394_send_command, $RAW1394_LIBS,
 791         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 792        AG_GST_CHECK_LIBHEADER(ROM1394,
 793         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 794         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 795        if test x$HAVE_AVC1394 = xyes && \
 796           test x$HAVE_AVC1394 = xyes && \
 797           test x$HAVE_ROM1394 = xyes; then
 798           HAVE_DV1394=yes
 799           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 800           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 801           AC_SUBST(DV1394_CFLAGS)
 802           AC_SUBST(DV1394_LIBS)
 803         fi
 804   else
 805        if test x$HAVE_RAW1394 = xno; then
 806           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 807           AG_GST_CHECK_LIBHEADER(AVC1394,
 808            avc1394, avc1394_send_command, $RAW1394_LIBS,
 809            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 810           AG_GST_CHECK_LIBHEADER(ROM1394,
 811            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 812            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 813           if test x$HAVE_RAW1394 = xyes && \
 814              test x$HAVE_AVC1394 = xyes && \
 815              test x$HAVE_ROM1394 = xyes; then
 816              HAVE_DV1394=yes
 817              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 818              DV1394_CFLAGS="$RAW1394_CFLAGS"
 819              if test x$HAVE_LIBIEC61883 = xyes; then
 820                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 821                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 822              fi
 823              AC_SUBST(DV1394_CFLAGS)
 824              AC_SUBST(DV1394_LIBS)
 825            fi
 826          fi
 827   fi
 828 ])
 829
 830 dnl *** shout2 ***
 831 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 832 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 833   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 834   if test $HAVE_SHOUT2 = no
 835   then
 836     AM_PATH_SHOUT2(HAVE_SHOUT2="yes")
 837     AC_SUBST(SHOUT2_CFLAGS)
 838     AC_SUBST(SHOUT2_LIBS)
 839   fi
 840 ])
 841
 842 dnl *** soup ***
 843 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUP, true)
 844 AG_GST_CHECK_FEATURE(SOUP, [soup http client plugin (2.4)], souphttpsrc, [
 845   PKG_CHECK_MODULES(SOUP, libsoup-2.4 >= 2.3.2, HAVE_SOUP="yes", [
 846     HAVE_SOUP="no"
 847     AC_MSG_RESULT(no)
 848   ])
 849   AC_SUBST(SOUP_CFLAGS)
 850   AC_SUBST(SOUP_LIBS)
 851 ])
 852
 853 dnl *** speex >= 1.0.4 or >= 1.1.5 ***
 854 dnl   1.1.4 and earlier were not API/ABI compatible with 1.0
 855 dnl   1.1.6 is the first to use a .pc/pkg-config file ***
 856 dnl   speex_jitter.h is 1.1.x only
 857 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 858 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 859   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 860   if test $HAVE_SPEEX = no
 861   then
 862     AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_bits_init, , speex/speex.h, [
 863       AC_CHECK_HEADER(speex/speex_jitter.h, [
 864         dnl speex 1.1.x :
 865         AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_encode_int, , speex/speex.h, [
 866           dnl speex 1.1.5 or + :
 867           HAVE_SPEEX="yes"
 868           SPEEX_LIBS="-lspeex"
 869           AC_SUBST(SPEEX_CFLAGS)
 870           AC_SUBST(SPEEX_LIBS)
 871         ],[
 872           HAVE_SPEEX="no"
 873         ])
 874       ],[
 875         dnl speex 1.0.x :
 876           AC_CHECK_DECL(SPEEX_GET_LOOKAHEAD, [
 877             dnl speex 1.0.4
 878             HAVE_SPEEX="yes"
 879             SPEEX_LIBS="-lspeex"
 880             AC_SUBST(SPEEX_CFLAGS)
 881             AC_SUBST(SPEEX_LIBS)
 882
 883             AC_DEFINE_UNQUOTED(SPEEX_1_0, 1,
 884               [defined if speex 1.0.x API detected])
 885         ],[
 886             HAVE_SPEEX="no"
 887             AC_MSG_NOTICE(You need at least 1.0.4 to compile the speex plugin)
 888         ], [
 889 #include <speex/speex.h>
 890         ])
 891       ])
 892     ])
 893   fi
 894 ])
 895
 896 dnl *** taglib ***
 897 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 898 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 899   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.4)
 900   if test "x$HAVE_CXX" != "xyes"; then
 901     USE_TAGLIB=false
 902     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 903   else
 904     dnl work around bug in taglib 1.5 headers, remove once there is a 1.6
 905     AS_CXX_COMPILER_FLAG([-Wno-attributes], [
 906         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS -Wno-attributes"
 907       ], [
 908         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS"
 909     ])
 910     AC_SUBST(TAGLIB_CXXFLAGS)
 911   fi
 912 ])
 913
 914 dnl *** wavpack ***
 915 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 916 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 917   PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.40.0, HAVE_WAVPACK=yes, [
 918     PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.20, [
 919       HAVE_WAVPACK=yes
 920       AC_DEFINE(WAVPACK_OLD_API, 1, [old wavpack API])
 921     ],[
 922       HAVE_WAVPACK=no
 923       AC_MSG_RESULT(no)
 924     ])
 925   ])
 926   AC_SUBST(WAVPACK_CFLAGS)
 927   AC_SUBST(WAVPACK_LIBS)
 928 ])
 929
 930 dnl *** qtdemux & id3demux & matroska prefer to have zlib ***
 931 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 932 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for id3demux/qtdemux/matroska],, [
 933   AG_GST_CHECK_LIBHEADER(ZLIB,
 934     z, uncompress,, zlib.h, [
 935     HAVE_ZLIB="yes"
 936     ZLIB_LIBS="-lz"
 937     AC_SUBST(ZLIB_LIBS)
 938   ])
 939 ])
 940
 941 dnl *** matroska prefers to have bz2 ***
 942 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
 943 AG_GST_CHECK_FEATURE(BZ2, [bz2 library for matroska ],, [
 944   AG_GST_CHECK_LIBHEADER(BZ2, bz2, BZ2_bzCompress, ,bzlib.h, BZ2_LIBS="-lbz2")
 945   AC_SUBST(BZ2_LIBS)
 946 ])
 947
 948 else
 949
 950 dnl not building plugins with external dependencies,
 951 dnl but we still need to set the conditionals
 952 AM_CONDITIONAL(USE_GCONFTOOL, false)
 953 AM_CONDITIONAL(USE_DIRECTDRAW, false)
 954 AM_CONDITIONAL(USE_DIRECTSOUND, false)
 955 AM_CONDITIONAL(USE_OSS, false)
 956 AM_CONDITIONAL(USE_SUNAUDIO, false)
 957 AM_CONDITIONAL(USE_OSX_AUDIO, false)
 958 AM_CONDITIONAL(USE_OSX_VIDEO, false)
 959 AM_CONDITIONAL(USE_X, false)
 960 AM_CONDITIONAL(USE_XSHM, false)
 961 AM_CONDITIONAL(USE_AALIB, false)
 962 AM_CONDITIONAL(USE_ANNODEX, false)
 963 AM_CONDITIONAL(USE_CAIRO, false)
 964 AM_CONDITIONAL(USE_ESD, false)
 965 AM_CONDITIONAL(USE_FLAC, false)
 966 AM_CONDITIONAL(USE_GCONF, false)
 967 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
 968 AM_CONDITIONAL(USE_HAL, false)
 969 AM_CONDITIONAL(USE_JPEG, false)
 970 AM_CONDITIONAL(USE_LIBCACA, false)
 971 AM_CONDITIONAL(USE_LIBDV, false)
 972 AM_CONDITIONAL(USE_LIBPNG, false)
 973 AM_CONDITIONAL(USE_DV1394, false)
 974 AM_CONDITIONAL(USE_SHOUT2, false)
 975 AM_CONDITIONAL(USE_SOUP, false)
 976 AM_CONDITIONAL(USE_SPEEX, false)
 977 AM_CONDITIONAL(USE_TAGLIB, false)
 978 AM_CONDITIONAL(USE_WAVPACK, false)
 979 AM_CONDITIONAL(USE_ZLIB, false)
 980
 981 fi dnl of EXT plugins
 982
 983 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 984
 985 dnl Overview:
 986 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 987 dnl GST_*:              flags shared by all built objects
 988 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 989 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
 990 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 991 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 992
 993 dnl GST_OPTION_CFLAGS
 994 if test "x$USE_DEBUG" = xyes; then
 995    PROFILE_CFLAGS="-g"
 996 fi
 997 AC_SUBST(PROFILE_CFLAGS)
 998
 999 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
1000   dnl Define _only_ during CVS (not pre-releases or releases)
1001   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
1002 else
1003   DEPRECATED_CFLAGS=""
1004 fi
1005 AC_SUBST(DEPRECATED_CFLAGS)
1006
1007 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
1008 dnl at make time with e.g. make ERROR_CFLAGS=""
1009 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1010 GST_OPTION_CXXFLAGS="\$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1011 AC_SUBST(GST_OPTION_CFLAGS)
1012 AC_SUBST(GST_OPTION_CXXFLAGS)
1013
1014 dnl our libraries need to be versioned correctly
1015 AC_SUBST(GST_LT_LDFLAGS)
1016
1017 dnl FIXME: do we want to rename to GST_ALL_* ?
1018 dnl prefer internal headers to already installed ones
1019 dnl also add builddir include for enumtypes and marshal
1020 dnl add ERROR_CFLAGS, but overridable
1021 GST_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS \$(GST_OPTION_CFLAGS)"
1022 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CXXFLAGS \$(GST_OPTION_CXXFLAGS)"
1023 AC_SUBST(GST_CFLAGS)
1024 AC_SUBST(GST_CXXFLAGS)
1025 AC_SUBST(GST_LIBS)
1026
1027 dnl LDFLAGS really should only contain flags, not libs - they get added before
1028 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1029 GST_ALL_LDFLAGS="-no-undefined"
1030 AC_SUBST(GST_ALL_LDFLAGS)
1031
1032 dnl this really should only contain flags, not libs - they get added before
1033 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1034 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
1035 AC_SUBST(GST_PLUGIN_LDFLAGS)
1036
1037 dnl *** output files ***
1038
1039 dnl keep this alphabetic per directory, please
1040 AC_CONFIG_FILES(
1041 Makefile
1042 gst/Makefile
1043 gst/alpha/Makefile
1044 gst/apetag/Makefile
1045 gst/audiofx/Makefile
1046 gst/auparse/Makefile
1047 gst/autodetect/Makefile
1048 gst/avi/Makefile
1049 gst/cutter/Makefile
1050 gst/debug/Makefile
1051 gst/effectv/Makefile
1052 gst/equalizer/Makefile
1053 gst/id3demux/Makefile
1054 gst/icydemux/Makefile
1055 gst/interleave/Makefile
1056 gst/goom/Makefile
1057 gst/goom2k1/Makefile
1058 gst/law/Makefile
1059 gst/level/Makefile
1060 gst/matroska/Makefile
1061 gst/monoscope/Makefile
1062 gst/multifile/Makefile
1063 gst/multipart/Makefile
1064 gst/qtdemux/Makefile
1065 gst/replaygain/Makefile
1066 gst/rtp/Makefile
1067 gst/rtsp/Makefile
1068 gst/smpte/Makefile
1069 gst/spectrum/Makefile
1070 gst/udp/Makefile
1071 gst/videobox/Makefile
1072 gst/videocrop/Makefile
1073 gst/videofilter/Makefile
1074 gst/videomixer/Makefile
1075 gst/wavenc/Makefile
1076 gst/wavparse/Makefile
1077 gst/flx/Makefile
1078 ext/jpeg/Makefile
1079 ext/Makefile
1080 ext/aalib/Makefile
1081 ext/annodex/Makefile
1082 ext/cairo/Makefile
1083 ext/dv/Makefile
1084 ext/esd/Makefile
1085 ext/flac/Makefile
1086 ext/gconf/Makefile
1087 ext/gdk_pixbuf/Makefile
1088 ext/hal/Makefile
1089 ext/ladspa/Makefile
1090 ext/libcaca/Makefile
1091 ext/libpng/Makefile
1092 ext/pulse/Makefile
1093 ext/raw1394/Makefile
1094 ext/shout2/Makefile
1095 ext/soup/Makefile
1096 ext/speex/Makefile
1097 ext/taglib/Makefile
1098 ext/wavpack/Makefile
1099 sys/Makefile
1100 sys/directdraw/Makefile
1101 sys/directsound/Makefile
1102 sys/oss/Makefile
1103 sys/sunaudio/Makefile
1104 sys/osxaudio/Makefile
1105 sys/osxvideo/Makefile
1106 sys/v4l2/Makefile
1107 sys/waveform/Makefile
1108 sys/ximage/Makefile
1109 po/Makefile.in
1110 tests/Makefile
1111 tests/check/Makefile
1112 tests/examples/Makefile
1113 tests/examples/equalizer/Makefile
1114 tests/examples/level/Makefile
1115 tests/examples/rtp/Makefile
1116 tests/examples/spectrum/Makefile
1117 tests/files/Makefile
1118 tests/icles/Makefile
1119 gconf/Makefile
1120 gconf/gstreamer.schemas
1121 common/Makefile
1122 common/m4/Makefile
1123 m4/Makefile
1124 docs/Makefile
1125 docs/plugins/Makefile
1126 docs/version.entities
1127 win32/common/config.h
1128 pkgconfig/Makefile
1129 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1130 gst-plugins-good.spec
1131 )
1132 AC_OUTPUT
1133
1134 AG_GST_OUTPUT_PLUGINS