configure.ac

   1 AC_PREREQ([2.69])
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, git and prerelease does Werror too
   6 dnl
   7 AC_INIT([GStreamer],[1.9.0.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gstreamer])
   8 AG_GST_INIT
   9
  10 dnl initialize automake (we require GNU make)
  11 AM_INIT_AUTOMAKE([-Wno-portability 1.14 no-dist-gzip dist-xz tar-ustar subdir-objects])
  12
  13 dnl define PACKAGE_VERSION_* variables
  14 AS_VERSION
  15
  16 dnl check if this is a release version
  17 AS_NANO(GST_GIT="no", GST_GIT="yes")
  18
  19 dnl can autoconf find the source ?
  20 AC_CONFIG_SRCDIR([gst/gst.c])
  21
  22 dnl define the output header for config
  23 AC_CONFIG_HEADERS([config.h])
  24
  25 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  26 AM_MAINTAINER_MODE([enable])
  27
  28 dnl sets host_* variables
  29 AC_CANONICAL_HOST
  30
  31 dnl use pretty build output by default
  32 AM_SILENT_RULES([yes])
  33
  34 dnl GStreamer versioning, this is mostly informational
  35 GST_VERSION_MAJOR=$PACKAGE_VERSION_MAJOR
  36 GST_VERSION_MINOR=$PACKAGE_VERSION_MINOR
  37 GST_VERSION_MICRO=$PACKAGE_VERSION_MICRO
  38 GST_VERSION_NANO=$PACKAGE_VERSION_NANO
  39 AC_SUBST(GST_VERSION_MAJOR)
  40 AC_SUBST(GST_VERSION_MINOR)
  41 AC_SUBST(GST_VERSION_MICRO)
  42 AC_SUBST(GST_VERSION_NANO)
  43
  44 dnl our libraries and install dirs use GST_API_VERSION in the filename
  45 dnl to allow side-by-side installation of different API versions
  46 GST_API_VERSION=1.0
  47 AC_SUBST(GST_API_VERSION)
  48 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  49   [GStreamer API Version])
  50
  51 dnl CURRENT, REVISION, AGE
  52 dnl - library source changed -> increment REVISION
  53 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  54 dnl - interfaces added -> increment AGE
  55 dnl - interfaces removed -> AGE = 0
  56 dnl
  57 dnl Keep CURRENT as MINOR * 100 + MICRO
  58 dnl Ex : 1.0.0 => 0
  59 dnl      1.0.3 => 3
  60 dnl      1.1.0 => 100
  61 dnl      1.2.5 => 205
  62 dnl      1.10.9 (who knows) => 1009
  63 dnl
  64 dnl sets GST_LT_LDFLAGS
  65 AS_LIBTOOL(GST, 900, 0, 900)
  66
  67 dnl *** autotools stuff ****
  68
  69 dnl allow for different autotools
  70 AS_AUTOTOOLS_ALTERNATE
  71
  72 dnl Add parameters for aclocal (keep in sync with Makefile.am)
  73 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  74
  75 dnl set up gettext
  76 dnl the version check needs to stay here because autopoint greps for it
  77 AM_GNU_GETTEXT_VERSION([0.17])
  78 AM_GNU_GETTEXT([external])
  79 AG_GST_GETTEXT([gstreamer-$GST_API_VERSION])
  80
  81 dnl *** check for arguments to configure ***
  82
  83 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  84 AG_GST_ARG_ENABLE_EXTRA_CHECKS
  85
  86 dnl subsystems - can influence other decisions so needs to be high up
  87 dnl we need to AM_CONDITIONAL them here for automake 1.6.x compatibility
  88 AG_GST_CHECK_SUBSYSTEM_DISABLE(GST_DEBUG,[debugging subsystem])
  89 AM_CONDITIONAL(GST_DISABLE_GST_DEBUG, test "x$GST_DISABLE_GST_DEBUG" = "xyes")
  90 AG_GST_CHECK_SUBSYSTEM_DISABLE(GST_TRACER_HOOKS,[tracing subsystem hooks])
  91 AM_CONDITIONAL(GST_DISABLE_GST_TRACER_HOOKS, test "x$GST_DISABLE_GST_TRACER_HOOKS" = "xyes")
  92 AG_GST_CHECK_SUBSYSTEM_DISABLE(PARSE,[command-line parser])
  93 AM_CONDITIONAL(GST_DISABLE_PARSE, test "x$GST_DISABLE_PARSE" = "xyes")
  94 if test "x$GST_DISABLE_PARSE" = xyes; then
  95   AC_DEFINE(GST_DISABLE_PARSE, 1,
  96     [Define if pipeline parsing code is disabled])
  97 fi
  98 AG_GST_CHECK_SUBSYSTEM_DISABLE(OPTION_PARSING,[option parsing when gst_init])
  99 AM_CONDITIONAL(GST_DISABLE_OPTION_PARSING, test "x$GST_DISABLE_OPTION_PARSING" = "xyes")
 100 if test "x$GST_DISABLE_OPTION_PARSING" = xyes; then
 101   AC_DEFINE(GST_DISABLE_OPTION_PARSING, 1,
 102     [Define if option parsing is disabled])
 103 fi
 104 AG_GST_CHECK_SUBSYSTEM_DISABLE(TRACE,[historic tracing subsystem])
 105 AM_CONDITIONAL(GST_DISABLE_TRACE, test "x$GST_DISABLE_TRACE" = "xyes")
 106 AG_GST_CHECK_SUBSYSTEM_DISABLE(ALLOC_TRACE,[allocation tracing])
 107 AM_CONDITIONAL(GST_DISABLE_ALLOC_TRACE, test "x$GST_DISABLE_ALLOC_TRACE" = "xyes")
 108 AG_GST_CHECK_SUBSYSTEM_DISABLE(REGISTRY,[plugin registry])
 109 AM_CONDITIONAL(GST_DISABLE_REGISTRY, test "x$GST_DISABLE_REGISTRY" = "xyes")
 110 dnl define a substitution to use in docs/gst/gstreamer.types
 111 if test "x$GST_DISABLE_REGISTRY" = "xyes"
 112 then
 113   GST_REGISTRY_DOC_TYPES="%"
 114 else
 115   GST_REGISTRY_DOC_TYPES=
 116 fi
 117 AC_SUBST(GST_REGISTRY_DOC_TYPES)
 118 AG_GST_CHECK_SUBSYSTEM_DISABLE(PLUGIN,[plugin])
 119 AM_CONDITIONAL(GST_DISABLE_PLUGIN, test "x$GST_DISABLE_PLUGIN" = "xyes")
 120
 121 AG_GST_ARG_DEBUG
 122 AG_GST_ARG_PROFILING
 123 AG_GST_ARG_VALGRIND
 124 AG_GST_ARG_GCOV
 125
 126 AG_GST_ARG_EXAMPLES
 127
 128 AG_GST_ARG_WITH_PKG_CONFIG_PATH
 129 AG_GST_ARG_WITH_PACKAGE_NAME
 130 AG_GST_ARG_WITH_PACKAGE_ORIGIN
 131
 132 AG_GST_PKG_CONFIG_PATH
 133
 134 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 135   ["${srcdir}/gstreamer.doap"],
 136   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 137
 138 dnl check for bash completion
 139 AC_ARG_WITH([bash-completion-dir],
 140     AS_HELP_STRING([--with-bash-completion-dir[=PATH]],
 141         [Install the bash auto-completion script in this directory. @<:@default=yes@:>@]),
 142     [],
 143     [with_bash_completion_dir=yes])
 144
 145 if test "x$with_bash_completion_dir" = "xyes"
 146 then
 147     extra_args=
 148
 149     if test "x$prefix" != "xNONE"
 150     then
 151         extra_args="--define-variable=prefix=\"$prefix\""
 152     fi
 153
 154     PKG_CHECK_MODULES([BASH_COMPLETION], [bash-completion >= 2.0],
 155         [BASH_COMPLETION_DIR="`eval pkg-config $extra_args --variable=completionsdir bash-completion`"],
 156         [BASH_COMPLETION_DIR="$datadir/bash-completion/completions"])
 157     PKG_CHECK_MODULES([BASH_COMPLETION], [bash-completion >= 2.0],
 158         [BASH_HELPERS_DIR="`eval pkg-config $extra_args --variable=helpersdir bash-completion`"],
 159         [BASH_HELPERS_DIR="$datadir/bash-completion/helpers"])
 160 else
 161     BASH_COMPLETION_DIR="$with_bash_completion_dir/completions"
 162     BASH_HELPERS_DIR="$with_bash_completion_dir/helpers"
 163 fi
 164
 165 AC_SUBST([BASH_COMPLETION_DIR])
 166 AC_SUBST([BASH_HELPERS_DIR])
 167 AM_CONDITIONAL([ENABLE_BASH_COMPLETION],[test "x$with_bash_completion_dir" != "xno"])
 168
 169 dnl build static plugins or not
 170 AC_MSG_CHECKING([whether to build static plugins or not])
 171 AC_ARG_ENABLE(
 172   static-plugins,
 173   AC_HELP_STRING(
 174     [--enable-static-plugins],
 175     [build static plugins @<:@default=no@:>@]),
 176   [AS_CASE(
 177     [$enableval], [no], [], [yes], [],
 178     [AC_MSG_ERROR([bad value "$enableval" for --enable-static-plugins])])],
 179   [enable_static_plugins=no])
 180 AC_MSG_RESULT([$enable_static_plugins])
 181 if test "x$enable_static_plugins" = xyes; then
 182   AC_DEFINE(GST_PLUGIN_BUILD_STATIC, 1,
 183     [Define if static plugins should be built])
 184   GST_PLUGIN_LIBTOOLFLAGS=""
 185 else
 186   GST_PLUGIN_LIBTOOLFLAGS="--tag=disable-static"
 187 fi
 188 AC_SUBST(GST_PLUGIN_LIBTOOLFLAGS)
 189 AM_CONDITIONAL(GST_PLUGIN_BUILD_STATIC, test "x$enable_static_plugins" = "xyes")
 190
 191 dnl building of tests
 192 AC_ARG_ENABLE(tests,
 193   AS_HELP_STRING([--disable-tests],[disable building test apps]),
 194   [
 195     case "${enableval}" in
 196       yes) BUILD_TESTS=yes ;;
 197       no)  BUILD_TESTS=no ;;
 198       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 199     esac
 200   ],
 201 [BUILD_TESTS=yes]) dnl Default value
 202 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 203
 204 dnl tests known to fail
 205 AC_ARG_ENABLE(failing-tests,
 206   AS_HELP_STRING([--disable-failing-tests],[disable building tests known to fail]),
 207   [
 208     case "${enableval}" in
 209       yes) BUILD_FAILING_TESTS=yes ;;
 210       no)  BUILD_FAILING_TESTS=no ;;
 211       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-failing-tests) ;;
 212     esac
 213   ],
 214   [BUILD_FAILING_TESTS=no]) dnl Default value
 215 AM_CONDITIONAL(BUILD_FAILING_TESTS, test "x$BUILD_FAILING_TESTS" = "xyes")
 216 if test x$BUILD_FAILING_TESTS = xyes; then
 217   AC_MSG_WARN([building tests known to fail, use --disable-failing-tests to disable])
 218 else
 219   AC_MSG_WARN([Sissy ! By asking to not build the tests known to fail, you hereby waive your right to customer support.  If you do not agree with this EULA, please press Ctrl-C before the next line is printed.  By allowing the next line to be printed, you expressly acknowledge your acceptance of this EULA.])
 220 fi
 221
 222 dnl building of benchmarks
 223 AC_ARG_ENABLE(benchmarks,
 224   AS_HELP_STRING([--disable-benchmarks],[disable building benchmarks apps]),
 225   [
 226     case "${enableval}" in
 227       yes) BUILD_BENCHMARKS=yes ;;
 228       no)  BUILD_BENCHMARKS=no ;;
 229       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-benchmarks) ;;
 230     esac
 231   ],
 232 [BUILD_BENCHMARKS=yes]) dnl Default value
 233 AM_CONDITIONAL(BUILD_BENCHMARKS, test "x$BUILD_BENCHMARKS" = "xyes")
 234
 235 dnl building of tools
 236 AC_ARG_ENABLE(tools,
 237   AS_HELP_STRING([--disable-tools],[disable building tools]),
 238   [
 239     case "${enableval}" in
 240       yes) BUILD_TOOLS=yes ;;
 241       no)  BUILD_TOOLS=no ;;
 242       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tools) ;;
 243     esac
 244   ],
 245 [BUILD_TOOLS=yes]) dnl Default value
 246 AM_CONDITIONAL(BUILD_TOOLS, test "x$BUILD_TOOLS" = "xyes")
 247
 248 dnl poison destroyed objects
 249 AC_ARG_ENABLE(poisoning,
 250   AS_HELP_STRING([--enable-poisoning],[enable poisoning of deallocated objects]),
 251   [
 252     case "${enableval}" in
 253       yes) USE_POISONING=yes ;;
 254       no)  USE_POISONING=no ;;
 255       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-poisoning) ;;
 256     esac
 257   ],
 258   [USE_POISONING=no]) dnl Default value
 259 if test "x$USE_POISONING" = xyes; then
 260   AC_DEFINE(USE_POISONING, 1,
 261     [Define if we should poison deallocated memory])
 262 fi
 263
 264 dnl PTP support parts
 265 AC_MSG_CHECKING([whether PTP support can be enabled])
 266 case "$host_os" in
 267   *android*)
 268     dnl Can't run on Android because of permissions
 269     HAVE_PTP=no
 270     ;;
 271   mingw*|pw32*|cygwin*)
 272     dnl Not ported to Windows yet
 273     HAVE_PTP=no
 274     ;;
 275   darwin*)
 276     dnl Can't run on iOS because of permissions
 277     AC_CHECK_HEADER(MobileCoreServices/MobileCoreServices.h, HAVE_PTP="no", HAVE_PTP="yes", [-])
 278     ;;
 279   linux*|darwin*|solaris*|netbsd*|freebsd*|openbsd*|kfreebsd*|dragonfly*|gnu*)
 280     HAVE_PTP=yes
 281     ;;
 282   *)
 283     HAVE_PTP=no
 284     ;;
 285 esac
 286 AC_MSG_RESULT([$HAVE_PTP])
 287
 288 dnl user/group to change to in gst-ptp-helper
 289 AC_ARG_WITH([ptp-helper-setuid-user],
 290   AS_HELP_STRING([--with-ptp-helper-setuid-user],[User to switch to when installing gst-ptp-helper setuid root]),
 291   [
 292     if test "x$withval" != "x"
 293     then
 294       AC_DEFINE_UNQUOTED(HAVE_PTP_HELPER_SETUID_USER, "$withval", [PTP helper setuid user])
 295     fi
 296   ], []
 297 )
 298
 299 dnl group/group to change to in gst-ptp-helper
 300 AC_ARG_WITH([ptp-helper-setuid-group],
 301   AS_HELP_STRING([--with-ptp-helper-setuid-group],[Group to switch to when installing gst-ptp-helper setuid root]),
 302   [
 303     if test "x$withval" != "x"
 304     then
 305       AC_DEFINE_UNQUOTED(HAVE_PTP_HELPER_SETUID_GROUP, "$withval", [PTP helper setuid group])
 306     fi
 307   ], []
 308 )
 309
 310 AC_ARG_WITH(
 311   ptp-helper-permissions,
 312   AC_HELP_STRING(
 313     [--with-ptp-helper-permissions],
 314     [how to gain PTP permissions (none, setuid-root, capabilities, auto)]),
 315     [],
 316     [with_ptp_helper_permissions=auto])
 317
 318 gst_ptp_have_cap=no
 319 AG_GST_CHECK_LIBHEADER(CAP, cap,
 320                        cap_init, ,
 321                        sys/capability.h,
 322                        CAP_LIBS="-lcap"
 323                        AC_SUBST(CAP_LIBS)
 324                        gst_ptp_have_cap=yes)
 325
 326 AC_PATH_PROG([SETCAP], [setcap], [no], [$PATH:/usr/bin:/bin:/usr/sbin:/sbin])
 327
 328 if test "x$HAVE_PTP" = "xyes"; then
 329 AC_DEFINE(HAVE_PTP, 1, [PTP support available])
 330
 331 AC_MSG_CHECKING([for SIOCGIFCONF, SIOCGIFFLAGS and SIOCGIFHWADDR])
 332 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 333     [[
 334         #include <sys/ioctl.h>
 335         #include <net/if.h>
 336     ]],
 337     [[
 338         struct ifreq ifr;
 339         struct ifconf ifc;
 340         ioctl(0, SIOCGIFCONF, &ifc);
 341         ioctl(0, SIOCGIFFLAGS, &ifr);
 342         ioctl(0, SIOCGIFHWADDR, &ifr);
 343         int dummy = ifr.ifr_hwaddr.sa_data[0];
 344     ]])], [
 345         AC_MSG_RESULT(yes)
 346         AC_DEFINE(HAVE_SIOCGIFCONF_SIOCGIFFLAGS_SIOCGIFHWADDR, 1, [SIOCGIFCONF, SIOCGIFFLAGS and SIOCGIFHWADDR is available])
 347     ], [
 348         AC_MSG_RESULT(no)
 349 ])
 350
 351 AC_MSG_CHECKING([for getifaddrs() and AF_LINK])
 352 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 353     [[
 354         #include <ifaddrs.h>
 355         #include <net/if.h>
 356         #include <net/if_dl.h>
 357     ]],
 358     [[
 359         struct ifaddrs *ifaddr;
 360         getifaddrs(&ifaddr);
 361         int dummy = (ifaddr->ifa_flags & IFF_LOOPBACK) && ifaddr->ifa_addr->sa_family != AF_LINK;
 362     ]])], [
 363         AC_MSG_RESULT(yes)
 364         AC_DEFINE(HAVE_GETIFADDRS_AF_LINK, 1, [getifaddrs() and AF_LINK is available])
 365     ], [
 366         AC_MSG_RESULT(no)
 367     ])
 368
 369 AC_MSG_CHECKING([how to install gst-ptp-helper])
 370 if test "x$with_ptp_helper_permissions" = "xauto"; then
 371     if test "x$gst_ptp_have_cap" = "xyes" -a "x$SETCAP" != "xno"; then
 372         with_ptp_helper_permissions="capabilities"
 373     else
 374         with_ptp_helper_permissions="setuid-root"
 375     fi
 376 fi
 377 AC_MSG_RESULT([$with_ptp_helper_permissions])
 378
 379 case "$with_ptp_helper_permissions" in
 380   none)
 381     ;;
 382   setuid-root)
 383      AC_DEFINE(HAVE_PTP_HELPER_SETUID, 1,
 384         [Use setuid-root for permissions in PTP helper])
 385     ;;
 386   capabilities)
 387      AC_DEFINE(HAVE_PTP_HELPER_CAPABILITIES, 1,
 388         [Use capabilities for permissions in PTP helper])
 389     ;;
 390   *)
 391     AC_MSG_ERROR(Invalid parameter [$with_ptp_helper_permissions])
 392     ;;
 393 esac
 394
 395 fi
 396
 397 AM_CONDITIONAL(HAVE_PTP, test "x$HAVE_PTP" = "xyes")
 398 AM_CONDITIONAL(HAVE_PTP_HELPER_SETUID, test "x$with_ptp_helper_permissions" = "xsetuid-root")
 399 AM_CONDITIONAL(HAVE_PTP_HELPER_CAPABILITIES, test "x$with_ptp_helper_permissions" = "xcapabilities")
 400
 401 dnl *** checks for platform ***
 402
 403 dnl * hardware/architecture *
 404
 405 dnl common/m4/gst-arch.m4
 406 dnl check CPU type
 407 AG_GST_ARCH
 408 dnl substitution for win32/common/config.h
 409 HOST_CPU=$host_cpu
 410 AC_SUBST(HOST_CPU)
 411
 412 dnl common/m4/gst-arch.m4
 413 dnl check for unaligned access
 414 AG_GST_UNALIGNED_ACCESS
 415 dnl create a configure variable for gst/gstconfig.h
 416 if test x${as_cv_unaligned_access} = xyes ; then
 417   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 1"
 418 else
 419   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 0"
 420 fi
 421 AC_SUBST(GST_HAVE_UNALIGNED_ACCESS_DEFINE)
 422
 423 dnl check for platform specific settings
 424 AG_GST_PLATFORM
 425
 426 dnl * software *
 427
 428 dnl check for large file support
 429 dnl affected plugins must include config.h
 430 AC_SYS_LARGEFILE
 431
 432 dnl *** checks for programs ***
 433
 434 dnl find a compiler
 435 AC_PROG_CC
 436 AC_PROG_CC_STDC
 437
 438 dnl check if the compiler supports '-c' and '-o' options
 439 AM_PROG_CC_C_O
 440
 441 dnl find an assembler
 442 AM_PROG_AS
 443
 444 dnl determine if c++ is available on this system
 445 AC_PROG_CXX
 446 dnl CXX may be set to some default even if no c++ compiler is available
 447 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 448 AC_LANG_PUSH([C++])
 449 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ class Foo { int bar; };]], [[]])],[working_cxx=yes],[working_cxx=no])
 450 AC_LANG_POP([C++])
 451 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 452 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 453
 454 dnl Perl is used in building documentation and in the version checks
 455 AC_PATH_PROG(PERL_PATH, perl, no)
 456 if test x$PERL_PATH = xno; then
 457   AC_MSG_ERROR(Could not find perl)
 458 fi
 459
 460 dnl we require flex and bison for building the parser
 461 if test "x$GST_DISABLE_PARSE" != xyes; then
 462   AG_GST_BISON_CHECK
 463   AG_GST_FLEX_CHECK
 464 fi
 465
 466 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 467 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 468
 469 dnl check for gobject-introspection
 470 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 471
 472 dnl check for documentation tools
 473 AG_GST_DOCBOOK_CHECK
 474 GTK_DOC_CHECK([1.12])
 475 AG_GST_PLUGIN_DOCS([1.12])
 476
 477 dnl *** checks for libraries ***
 478
 479 dnl check for libm, for sin()
 480 LT_LIB_M
 481 AC_SUBST(LIBM)
 482
 483 dnl *** checks for header files ***
 484
 485 dnl check if we have ANSI C header files
 486 AC_HEADER_STDC
 487
 488 dnl Check for ucontext.h
 489 AC_CHECK_HEADERS([ucontext.h], [], [], [AC_INCLUDES_DEFAULT])
 490
 491 dnl Check for sys/socket.h
 492 AC_CHECK_HEADERS([sys/socket.h], [HAVE_SYS_SOCKET_H=yes], [HAVE_SYS_SOCKET_H=no], [AC_INCLUDES_DEFAULT])
 493 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 494
 495 dnl check for sys/times.h for tests/examples/adapter/
 496 AC_CHECK_HEADERS([sys/times.h], [HAVE_SYS_TIMES_H=yes], [HAVE_SYS_TIME_H=no], [AC_INCLUDES_DEFAULT])
 497 AC_CHECK_HEADERS([unistd.h], [HAVE_UNISTD_H=yes], [HAVE_UNISTD_H=no], [AC_INCLUDES_DEFAULT])
 498 AM_CONDITIONAL(HAVE_SYS_TIMES_H_AND_UNISTD_H, test "x$HAVE_SYS_TIMES_H" = "xyes" -a "x$HAVE_UNISTD_H" = "xyes")
 499
 500 dnl Check for process.h for getpid() on win32
 501 AC_CHECK_HEADERS([process.h], [], [], [AC_INCLUDES_DEFAULT])
 502
 503 dnl Check for sys/utsname.h for uname
 504 AC_CHECK_HEADERS([sys/utsname.h], [], [], [AC_INCLUDES_DEFAULT])
 505
 506 dnl Check for stdio_ext.f for __fbufsize
 507 AC_CHECK_HEADERS([stdio_ext.h], [], [], [AC_INCLUDES_DEFAULT])
 508
 509 dnl check for pthreads
 510 dnl without arguments AX_PTHREAD() will do AC_DEFINE(HAVE_PTHREAD)
 511 dnl which later checks use in their test code
 512 AX_PTHREAD()
 513 AM_CONDITIONAL(HAVE_PTHREAD, test "x$ax_pthread_ok" = "xyes")
 514
 515 dnl check for sys/prctl for setting thread name on Linux
 516 AC_CHECK_HEADERS([sys/prctl.h], [], [], [AC_INCLUDES_DEFAULT])
 517
 518 dnl check for pthread_setname_np(const char*)
 519 dnl which is present on OS X 10.6, iOS 3.2 and above
 520 AC_MSG_CHECKING(for pthread_setname_np(const char*))
 521 AC_LINK_IFELSE(
 522     [AC_LANG_PROGRAM(
 523         [#include <pthread.h>],
 524         [pthread_setname_np("example")])],
 525     [AC_MSG_RESULT(yes)
 526      AC_DEFINE(HAVE_PTHREAD_SETNAME_NP_WITHOUT_TID,1,
 527         [Have function pthread_setname_np(const char*)])],
 528     [AC_MSG_RESULT(no)])
 529
 530 dnl check for sys/uio.h for writev()
 531 AC_CHECK_HEADERS([sys/uio.h], [], [], [AC_INCLUDES_DEFAULT])
 532
 533 dnl Check for valgrind.h
 534 dnl separate from HAVE_VALGRIND because you can have the program, but not
 535 dnl the dev package
 536 AC_CHECK_HEADERS([valgrind/valgrind.h], [], [], [AC_INCLUDES_DEFAULT])
 537
 538 dnl used in gst/gstpoll.c
 539 AC_CHECK_HEADERS([winsock2.h], [HAVE_WINSOCK2_H=yes], [HAVE_WINSOCK2_H=no], [AC_INCLUDES_DEFAULT])
 540 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 541 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 542   WIN32_LIBS="-lws2_32"
 543   AC_SUBST(WIN32_LIBS)
 544 fi
 545
 546 dnl check for GMP/GSL, used by the gst_util_uint64_scale unit test only
 547 if test "x$BUILD_TESTS" = "xyes"; then
 548   AG_GST_CHECK_LIBHEADER(GMP, gmp,
 549                          __gmpz_init_set_d, ,
 550                          gmp.h,
 551                          GMP_LIBS="-lgmp"
 552                          AC_SUBST(GMP_LIBS)
 553                          AC_DEFINE(HAVE_GMP, [1],[Have GMP library]))
 554   AG_GST_CHECK_LIBHEADER(GSL, gsl,
 555                          gsl_rng_uniform_int, -lgslcblas,
 556                          gsl/gsl_rng.h,
 557                          GSL_LIBS="-lgsl -lgslcblas"
 558                          AC_SUBST(GSL_LIBS)
 559                          AC_DEFINE(HAVE_GSL, [1],[Have GSL library]))
 560 fi
 561
 562 dnl *** checks for types/defines ***
 563
 564 dnl *** checks for structures ***
 565
 566 dnl *** checks for compiler characteristics ***
 567
 568 dnl check if the compiler supports __uint128_t (gcc)
 569 dnl Actually check for 128-bit division, since that's what we use
 570 dnl uint128_t for.
 571 AC_CACHE_CHECK(for __uint128_t, gst_cv_uint128_t,
 572     AC_LINK_IFELSE([AC_LANG_PROGRAM([[ ]], [[
 573       static __uint128_t v1 = 100;
 574       static __uint128_t v2 = 10;
 575       static __uint128_t u;
 576       u = v1 / v2;
 577     ]])],[
 578       gst_cv_uint128_t=yes
 579     ],[
 580       gst_cv_uint128_t=no
 581     ])
 582 )
 583 if test x$gst_cv_uint128_t = xyes; then
 584   AC_DEFINE(HAVE_UINT128_T, 1, [Have __uint128_t type])
 585 fi
 586
 587 dnl *** checking for tm_gmtoff ***
 588 AC_MSG_CHECKING([for tm_gmtoff])
 589 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 590         #include <time.h>
 591         int main(void) {
 592           struct tm t;
 593           t.tm_gmtoff = 0;
 594           exit(0);
 595         }]])],
 596   [have_tm_gmtoff=yes
 597    AC_DEFINE(HAVE_TM_GMTOFF,1,[Have tm_gmtoff field in struct tm])],
 598   [have_tm_gmtoff=no],
 599   [have_tm_gmtoff="no (cross compiling)"])
 600 AC_MSG_RESULT($have_tm_gmtoff)
 601
 602
 603 dnl *** checks for library functions ***
 604
 605 AC_CHECK_FUNCS([strcasestr])
 606
 607 AC_CHECK_FUNCS([gmtime_r])
 608 AC_CHECK_FUNCS([localtime_r])
 609 AC_CHECK_FUNCS([sigaction])
 610 AC_CHECK_FUNCS([getrusage])
 611 AM_CONDITIONAL(HAVE_GETRUSAGE, test "x$ac_cv_func_getrusage" = "xyes")
 612 AC_CHECK_HEADERS([sys/resource.h])
 613
 614 dnl check for fseeko()
 615 AC_FUNC_FSEEKO
 616 dnl check for ftello()
 617 AC_CHECK_FUNCS([ftello])
 618
 619 AC_CHECK_FUNCS([fgetpos])
 620 AC_CHECK_FUNCS([fsetpos])
 621
 622 dnl check for poll(), ppoll() and pselect()
 623 AC_CHECK_HEADERS([sys/poll.h], [], [], [AC_INCLUDES_DEFAULT])
 624 AC_CHECK_HEADERS([poll.h], [], [], [AC_INCLUDES_DEFAULT])
 625 AC_CHECK_FUNCS([poll])
 626 AC_CHECK_FUNCS([ppoll])
 627 AC_CHECK_FUNCS([pselect])
 628
 629 dnl check for socketpair()
 630 AC_CHECK_FUNC(socketpair, [], [
 631   AC_CHECK_LIB(socket, socketpair, [
 632     SOCKET_LIBS="-lsocket"
 633     AC_SUBST(SOCKET_LIBS)
 634   ])
 635 ])
 636
 637 dnl ****************************************
 638 dnl *** GLib POLL* compatibility defines ***
 639 dnl ****************************************
 640
 641 AC_MSG_CHECKING([for broken poll])
 642 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 643         #include <stdlib.h>
 644         #include <fcntl.h>
 645         #ifdef HAVE_SYS_POLL_H
 646         #include <sys/poll.h>
 647         #endif
 648         #ifdef HAVE_POLL_H
 649         #include <poll.h>
 650         #endif
 651         int main(void) {
 652           struct pollfd fds[1];
 653           int fd;
 654           fd = open("/dev/null", 1);
 655           fds[0].fd = fd;
 656           fds[0].events = POLLIN;
 657           fds[0].revents = 0;
 658           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
 659                 exit(1);  /* Does not work for devices -- fail */
 660           }
 661           exit(0);
 662         }]])],
 663   [broken_poll=no],
 664   [broken_poll=yes
 665    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
 666   [broken_poll="no (cross compiling)"])
 667 AC_MSG_RESULT($broken_poll)
 668
 669 dnl check for mmap()
 670 AC_FUNC_MMAP
 671 AM_CONDITIONAL(HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 672
 673 dnl check for posix_memalign(), getpagesize()
 674 AC_CHECK_FUNCS([posix_memalign])
 675 AC_CHECK_FUNCS([getpagesize])
 676
 677 dnl Check for POSIX timers
 678 AC_CHECK_FUNCS(clock_gettime, [], [
 679   AC_CHECK_LIB(rt, clock_gettime, [
 680     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 681     LIBS="$LIBS -lrt"
 682   ], [
 683     AC_CHECK_LIB(pthread, clock_gettime, [
 684       AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 685       LIBS="$LIBS -lpthread"
 686     ])
 687   ])
 688 ])
 689
 690 AC_CACHE_CHECK(for posix timers, gst_cv_posix_timers,
 691     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 692 #include <time.h>
 693 #ifdef HAVE_UNISTD_H
 694 #include <unistd.h>
 695 #endif
 696     ]], [[
 697 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 698 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 699 #endif
 700     ]])],[
 701       gst_cv_posix_timers=yes
 702     ],[
 703       gst_cv_posix_timers=no
 704     ])
 705 )
 706
 707 if test "$gst_cv_posix_timers" = "yes"; then
 708   AC_DEFINE(HAVE_POSIX_TIMERS,1,[Have posix timers])
 709   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 1"
 710 else
 711   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 0"
 712 fi
 713 AC_SUBST(GST_HAVE_POSIX_TIMERS_DEFINE)
 714 AM_CONDITIONAL(GST_HAVE_POSIX_TIMERS, test "$gst_cv_posix_timers" = "yes")
 715
 716 AC_CACHE_CHECK(for monotonic clock, gst_cv_monotonic_clock,
 717     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 718 #include <time.h>
 719 #ifdef HAVE_UNISTD_H
 720 #include <unistd.h>
 721 #endif
 722     ]], [[
 723 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 724 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 725 #endif
 726     ]])],[
 727       gst_cv_monotonic_clock=yes
 728     ],[
 729       gst_cv_monotonic_clock=no
 730     ])
 731 )
 732
 733 if test "$gst_cv_monotonic_clock" = "yes"; then
 734   AC_DEFINE(HAVE_MONOTONIC_CLOCK,1,[Have a monotonic clock])
 735   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 1"
 736 else
 737   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 0"
 738 fi
 739 AC_SUBST(GST_HAVE_MONOTONIC_CLOCK_DEFINE)
 740 AM_CONDITIONAL(GST_HAVE_MONOTONIC_CLOCK, test "$gst_cv_monotonic_clock" = "yes")
 741
 742 dnl Check for a way to display the function name in debug output
 743 AG_GST_CHECK_FUNCTION
 744
 745 dnl test if we have dladdr(); we use it for debugging; see gst/gstinfo.c
 746 save_cflags="$CFLAGS"
 747 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 748 AC_CHECK_LIB(dl, dladdr,
 749    AC_DEFINE(HAVE_DLADDR, 1, [Defined if we have dladdr ()])
 750    LIBS="$LIBS -ldl")
 751 CFLAGS="$save_cflags"
 752
 753 dnl Check printf stuff
 754 if test "x${GST_DISABLE_GST_DEBUG}" != "xyes"; then
 755   AC_TYPE_LONG_LONG_INT
 756   AC_TYPE_UNSIGNED_LONG_LONG_INT
 757
 758   if test x$ac_cv_type_long_long_int$ac_cv_type_unsigned_long_long_int = xyesyes; then
 759     AC_DEFINE([HAVE_LONG_LONG], [1], [Define to 1 if the system has the type long long])
 760   fi
 761
 762   dnl /usr/share/aclocal/inttypes_h.m4 - ships with gettext apparently
 763   gl_AC_HEADER_INTTYPES_H
 764
 765   dnl /usr/share/aclocal/stdint_h.m4 - ships with gettext apparently
 766   gl_AC_HEADER_STDINT_H
 767
 768   AC_CHECK_TYPES(ptrdiff_t)
 769
 770   AC_TYPE_INTMAX_T
 771   AC_TYPE_SIZE_T
 772 fi
 773
 774 dnl *** checks for dependency libraries ***
 775
 776 dnl GLib
 777 GLIB_REQ=2.40.0
 778 AG_GST_GLIB_CHECK([$GLIB_REQ])
 779
 780 dnl Check for documentation xrefs
 781 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 782 AC_SUBST(GLIB_PREFIX)
 783
 784 dnl GTK is optional and only used in examples
 785 HAVE_GTK=no
 786 GTK_REQ=3.10
 787 if test "x$BUILD_EXAMPLES" = "xyes"; then
 788   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 789   AC_SUBST(GTK_LIBS)
 790   AC_SUBST(GTK_CFLAGS)
 791 fi
 792 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 793
 794 dnl building of unit test libraries
 795 AC_ARG_ENABLE(check,
 796   AS_HELP_STRING([--disable-check],[disable building unit test libraries]),
 797   [
 798     case "${enableval}" in
 799       yes) BUILD_CHECK=yes ;;
 800       no)  BUILD_CHECK=no ;;
 801       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-check) ;;
 802     esac
 803   ], [
 804     dnl Default value
 805     case $host_os in
 806       mingw* | msvc* | mks*) BUILD_CHECK=no ;;
 807       *) BUILD_CHECK=yes ;;
 808     esac
 809 ])
 810 dnl bit of a misnomer, but keep the conditional named like this so we don't
 811 dnl have to change too much elsewhere
 812 AM_CONDITIONAL(HAVE_CHECK, test "x$BUILD_CHECK" = "xyes")
 813
 814 dnl configure the desired memory alignment
 815 AC_ARG_WITH([memory-alignment],
 816   AS_HELP_STRING([--with-memory-alignment],[8,N,malloc,pagesize (default is 32)]),
 817   [
 818     if test "x$withval" = "xyes"
 819     then
 820       AC_DEFINE(MEMORY_ALIGNMENT, 32, [Memory alignment to use])
 821     else
 822       case "${withval}" in
 823         malloc) AC_DEFINE(MEMORY_ALIGNMENT_MALLOC, 1, [Memory alignment by malloc default]) ;;
 824         pagesize)  AC_DEFINE(MEMORY_ALIGNMENT_PAGESIZE, 1, [Memory alignment by pagesize]) ;;
 825         *)   AC_DEFINE_UNQUOTED(MEMORY_ALIGNMENT, ${withval}, [Memory alignment to use]) ;;
 826       esac
 827     fi
 828   ], [
 829     AC_DEFINE(MEMORY_ALIGNMENT_MALLOC, 1, [Memory alignment by malloc default])
 830   ]
 831 )
 832
 833 dnl Check for -Bsymbolic-functions linker flag used to avoid
 834 dnl intra-library PLT jumps, if available.
 835 AC_ARG_ENABLE(Bsymbolic,
 836               [AS_HELP_STRING([--disable-Bsymbolic],[avoid linking with -Bsymbolic])],,
 837               [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
 838                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 839                LDFLAGS=-Wl,-Bsymbolic-functions
 840                LIBS=
 841                AC_TRY_LINK([], [return 0],
 842                            AC_MSG_RESULT(yes)
 843                            enable_Bsymbolic=yes,
 844                            AC_MSG_RESULT(no)
 845                            enable_Bsymbolic=no)
 846                LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
 847
 848
 849 dnl *** set variables based on configure arguments
 850
 851 dnl set license and copyright notice
 852 GST_LICENSE="LGPL"
 853 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 854 AC_SUBST(GST_LICENSE)
 855
 856 dnl define LIBDIR, GST_DATADIR so we can inform people where we live
 857 AS_AC_EXPAND(LIBDIR, $libdir)
 858 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [library dir])
 859 AS_AC_EXPAND(DATADIR, $datadir)
 860 AC_DEFINE_UNQUOTED(GST_DATADIR, "$DATADIR", [data dir])
 861
 862 dnl set location of plugin directory
 863 AG_GST_SET_PLUGINDIR
 864
 865 dnl make sure it doesn't complain about unused variables if debugging is disabled
 866 NO_WARNINGS=""
 867 if test "x${GST_DISABLE_GST_DEBUG}" = "xyes"; then
 868   NO_WARNINGS="-Wno-unused"
 869 fi
 870
 871 dnl define an ERROR_CFLAGS Makefile variable
 872 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [-Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef -Wwrite-strings -Wformat-nonliteral -Wformat-security -Wold-style-definition -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return -Wno-multichar -Wnested-externs $NO_WARNINGS])
 873
 874 dnl special warning flags for gst/printf
 875 AS_COMPILER_FLAG([-Wno-format-nonliteral], [PRINTF_CFLAGS="-Wno-format-nonliteral"])
 876 AC_SUBST(PRINTF_CFLAGS)
 877
 878 dnl define correct level for debugging messages
 879 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 880
 881 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 882
 883 dnl Overview:
 884 dnl GST_OPTION_CFLAGS:  common cflags for profiling, debugging, errors, ...
 885 dnl GST_ALL_*:          vars shared by all built objects
 886 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 887 dnl GST_OBJ_*:          additional vars to link to the core library
 888 dnl                     include GST_ALL_*
 889 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 890 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 891
 892 dnl GST_OPTION_CFLAGS
 893 if test "x$USE_DEBUG" = xyes; then
 894    PROFILE_CFLAGS="-g"
 895 fi
 896 AC_SUBST(PROFILE_CFLAGS)
 897
 898 # GST_DISABLE_DEPRECATED: hide the visibility of deprecated
 899 # functionality from the API that gstreamer uses
 900 # GST_REMOVE_DEPRECATED: don't compile deprecated functionality (breaks ABI)
 901 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 902   dnl Define _only_ when compiling from git (not for pre-releases or releases)
 903   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 904 else
 905   DEPRECATED_CFLAGS=""
 906 fi
 907 AC_SUBST(DEPRECATED_CFLAGS)
 908
 909 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time via e.g.
 910 dnl make DEPRECATED_CFLAGS=''
 911 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 912 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 913 GST_OPTION_CFLAGS="$GST_OPTION_CFLAGS"
 914 GST_OPTION_CXXFLAGS="$GST_OPTION_CXXFLAGS"
 915 AC_SUBST(GST_OPTION_CFLAGS)
 916 AC_SUBST(GST_OPTION_CXXFLAGS)
 917
 918 dnl GST_ALL_*
 919 dnl vars common to for all internal objects (core libs, elements, applications)
 920 dnl CFLAGS:
 921 dnl - src and build dirs need to be added because every piece that gets built
 922 dnl   will need the GStreamer source and generated headers
 923 dnl LIBS: XML doesn't need to be added because we don't explicitly use symbols
 924 dnl       from LibXML except for in the core library
 925 GST_ALL_CXXFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir)/libs -I\$(top_builddir) $GLIB_CFLAGS \$(GLIB_EXTRA_CFLAGS) $XML_CFLAGS \$(GST_OPTION_CXXFLAGS) \$(ERROR_CXXFLAGS)"
 926 GST_ALL_CFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir)/libs -I\$(top_builddir) $GLIB_CFLAGS \$(GLIB_EXTRA_CFLAGS) $XML_CFLAGS \$(GST_OPTION_CFLAGS) \$(ERROR_CFLAGS)"
 927
 928 dnl FIXME: check if LTLIBINTL is needed everywhere
 929 dnl I presume it is given that it contains the symbols that _() stuff maps to
 930 GST_ALL_LIBS="$GLIB_LIBS $LTLIBINTL \$(GCOV_LIBS)"
 931
 932 dnl LDFLAGS really should only contain flags, not libs - they get added before
 933 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 934 GST_ALL_LDFLAGS="-no-undefined"
 935 if test "x${enable_Bsymbolic}" = "xyes"; then
 936   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 937 fi
 938
 939 AC_SUBST(GST_ALL_CFLAGS)
 940 AC_SUBST(GST_ALL_CXXFLAGS)
 941 AC_SUBST(GST_ALL_LIBS)
 942 AC_SUBST(GST_ALL_LDFLAGS)
 943
 944 dnl GST_LIB_LDFLAGS
 945 dnl linker flags shared by all libraries
 946 dnl LDFLAGS modifier defining exported symbols from built libraries
 947 GST_LIB_LDFLAGS="-export-symbols-regex \^[_]?\(gst_\|Gst\|GST_\).*"
 948 AC_SUBST(GST_LIB_LDFLAGS)
 949
 950 dnl GST_OBJ_*
 951 dnl default vars for all internal objects built on libgstreamer
 952 dnl includes GST_ALL_*
 953 GST_OBJ_CFLAGS="\$(GST_ALL_CFLAGS)"
 954 GST_OBJ_CXXFLAGS="\$(GST_ALL_CXXFLAGS)"
 955 GST_OBJ_LIBS="\$(top_builddir)/gst/libgstreamer-$GST_API_VERSION.la \$(GST_ALL_LIBS)"
 956 AC_SUBST(GST_OBJ_CFLAGS)
 957 AC_SUBST(GST_OBJ_CXXFLAGS)
 958 AC_SUBST(GST_OBJ_LIBS)
 959
 960 dnl GST_PLUGIN_LDFLAGS
 961 dnl LDFLAGS for plugins; includes GST_ALL_LDFLAGS
 962 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_.*' $GST_ALL_LDFLAGS"
 963 AC_SUBST(GST_PLUGIN_LDFLAGS, "$GST_PLUGIN_LDFLAGS")
 964
 965 dnl plugin scanner locations
 966 AS_AC_EXPAND(GST_PLUGIN_SCANNER_INSTALLED,${libexecdir}/gstreamer-$GST_API_VERSION/gst-plugin-scanner)
 967 AC_DEFINE_UNQUOTED(GST_PLUGIN_SCANNER_INSTALLED,
 968     "$GST_PLUGIN_SCANNER_INSTALLED", [location of the installed gst-plugin-scanner])
 969 AC_SUBST(GST_PLUGIN_SCANNER_INSTALLED)
 970
 971 dnl ptp helper locations
 972 AS_AC_EXPAND(GST_PTP_HELPER_INSTALLED,${libexecdir}/gstreamer-$GST_API_VERSION/gst-ptp-helper)
 973 AC_DEFINE_UNQUOTED(GST_PTP_HELPER_INSTALLED,
 974     "$GST_PTP_HELPER_INSTALLED", [location of the installed gst-ptp-helper])
 975 AC_SUBST(GST_PTP_HELPER_INSTALLED)
 976
 977 dnl things for our internal libcheck (must be called even if building
 978 dnl libcheck is disabled because it defines conditionals)
 979 AG_GST_CHECK_CHECKS
 980
 981 AC_CONFIG_FILES(
 982 Makefile
 983 data/Makefile
 984 gst/Makefile
 985 gst/gstconfig.h
 986 gst/gstversion.h
 987 gst/parse/Makefile
 988 gst/printf/Makefile
 989 libs/Makefile
 990 libs/gst/Makefile
 991 libs/gst/base/Makefile
 992 libs/gst/check/Makefile
 993 libs/gst/check/libcheck/Makefile
 994 libs/gst/check/internal-check.h:libs/gst/check/libcheck/check.h.in
 995 libs/gst/controller/Makefile
 996 libs/gst/helpers/Makefile
 997 libs/gst/net/Makefile
 998 plugins/Makefile
 999 plugins/elements/Makefile
1000 plugins/tracers/Makefile
1001 po/Makefile.in
1002 tests/Makefile
1003 tests/benchmarks/Makefile
1004 tests/check/Makefile
1005 tests/misc/Makefile
1006 tests/examples/Makefile
1007 tests/examples/adapter/Makefile
1008 tests/examples/controller/Makefile
1009 tests/examples/stepping/Makefile
1010 tests/examples/helloworld/Makefile
1011 tests/examples/manual/Makefile
1012 tests/examples/memory/Makefile
1013 tests/examples/netclock/Makefile
1014 tests/examples/ptp/Makefile
1015 tests/examples/streamiddemux/Makefile
1016 tests/examples/streams/Makefile
1017 tools/Makefile
1018 common/Makefile
1019 common/m4/Makefile
1020 docs/Makefile
1021 docs/design/Makefile
1022 docs/faq/Makefile
1023 docs/gst/Makefile
1024 docs/gst/gstreamer.types
1025 docs/libs/Makefile
1026 docs/plugins/Makefile
1027 docs/manual/Makefile
1028 docs/pwg/Makefile
1029 docs/slides/Makefile
1030 docs/xsl/Makefile
1031 docs/version.entities
1032 m4/Makefile
1033 pkgconfig/Makefile
1034 stamp.h
1035 pkgconfig/gstreamer.pc
1036 pkgconfig/gstreamer-uninstalled.pc
1037 pkgconfig/gstreamer-base.pc
1038 pkgconfig/gstreamer-base-uninstalled.pc
1039 pkgconfig/gstreamer-check.pc
1040 pkgconfig/gstreamer-check-uninstalled.pc
1041 pkgconfig/gstreamer-controller.pc
1042 pkgconfig/gstreamer-controller-uninstalled.pc
1043 pkgconfig/gstreamer-net.pc
1044 pkgconfig/gstreamer-net-uninstalled.pc
1045 gstreamer.spec
1046 )
1047
1048 dnl Create the config.h file for Visual Studio builds
1049 dnl Beware of spaces and /'s in some of the shell variable contents.
1050 sed \
1051     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
1052     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
1053     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
1054     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
1055     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
1056     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
1057     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
1058     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
1059     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
1060     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
1061     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
1062     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
1063     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
1064     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
1065     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
1066     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
1067     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
1068     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
1069     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
1070     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1071     -e 's/.* MEMORY_ALIGNMENT_MALLOC/#define MEMORY_ALIGNMENT_MALLOC 1/' \
1072     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1073     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1074     -e 's/.* PACKAGE$/#define PACKAGE "gstreamer"/' \
1075     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1076     -e 's/.* PACKAGE_NAME$/#define PACKAGE_NAME "'$PACKAGE_NAME'"/' \
1077     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1078     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1079     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1080     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-1.0"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-1.0"\n#endif/' \
1081     -e 's/.* GST_PLUGIN_SCANNER_INSTALLED$/#define GST_PLUGIN_SCANNER_INSTALLED LIBDIR "\\\\gst-plugin-scanner"/' \
1082     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1083     config.h.in >win32/common/config.h-new
1084
1085 AC_OUTPUT
1086
1087 dnl negate for output
1088 if test "x${GST_DISABLE_GST_DEBUG}" = "xno"; then enable_gst_debug="yes"; fi
1089 if test "x${GST_DISABLE_GST_TRACER_HOOKS}" = "xno"; then enable_gst_tracer_hooks="yes"; fi
1090 if test "x${GST_DISABLE_PARSE}" = "xno"; then enable_parse="yes"; fi
1091 if test "x${GST_DISABLE_OPTION_PARSING}" = "xno"; then enable_option_parsing="yes"; fi
1092 if test "x${GST_DISABLE_TRACE}" = "xno"; then enable_trace="yes"; fi
1093 if test "x${GST_DISABLE_ALLOC_TRACE}" = "xno"; then enable_alloc_trace="yes"; fi
1094 if test "x${GST_DISABLE_PLUGIN}" = "xno"; then enable_plugin="yes"; fi
1095 if test "x${GST_DISABLE_REGISTRY}" = "xno"; then enable_registry="yes"; fi
1096
1097 echo "
1098
1099 Configuration
1100         Version                    : ${VERSION}
1101         Source code location       : ${srcdir}
1102         Prefix                     : ${prefix}
1103         Compiler                   : ${CC}
1104         Package name               : ${GST_PACKAGE_NAME}
1105         Package origin             : ${GST_PACKAGE_ORIGIN}
1106
1107         Documentation (manuals)    : ${enable_docbook}
1108         Documentation (API)        : ${enable_gtk_doc}
1109
1110         Debug logging              : ${enable_gst_debug}
1111         Tracing subsystem hooks    : ${enable_gst_tracer_hooks}
1112         Command-line parser        : ${enable_parse}
1113         Option parsing in gst_init : ${enable_option_parsing}
1114         Historic tracing subsystem : ${enable_trace}
1115         Allocation tracing         : ${enable_alloc_trace}
1116         Plugin registry            : ${enable_registry}
1117         Plugin support             : ${enable_plugin}
1118         Static plugins             : ${enable_static_plugins}
1119         Unit testing support       : ${BUILD_CHECK}
1120         PTP clock support          : ${HAVE_PTP}
1121
1122         Debug                      : ${USE_DEBUG}
1123         Profiling                  : ${USE_PROFILING}
1124
1125         Building benchmarks        : ${BUILD_BENCHMARKS}
1126         Building examples          : ${BUILD_EXAMPLES}
1127         Building test apps         : ${BUILD_TESTS}
1128         Building tests that fail   : ${BUILD_FAILING_TESTS}
1129         Building tools             : ${BUILD_TOOLS}
1130 "