configure.ac

   1 AC_PREREQ(2.60)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/prerelease
   8 AC_INIT(GStreamer Base Plug-ins, 0.11.2.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-base)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability 1.10])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use major.minor as a version
  41 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  42 dnl we override it here if we need to for the release candidate of new series
  43 GST_MAJORMINOR=0.11
  44 AC_SUBST(GST_MAJORMINOR)
  45
  46 dnl CURRENT, REVISION, AGE
  47 dnl - library source changed -> increment REVISION
  48 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  49 dnl - interfaces added -> increment AGE
  50 dnl - interfaces removed -> AGE = 0
  51 dnl sets GST_LT_LDFLAGS
  52 AS_LIBTOOL(GST, 27, 0, 0)
  53
  54 dnl FIXME: this macro doesn't actually work;
  55 dnl the generated libtool script has no support for the listed tags.
  56 dnl So this needs to be fixed first if we want to use this
  57 dnl AS_LIBTOOL_TAGS
  58
  59 AC_LIBTOOL_WIN32_DLL
  60 AM_PROG_LIBTOOL
  61
  62 dnl *** required versions of GStreamer stuff ***
  63 GST_REQ=0.11.2
  64
  65 dnl *** autotools stuff ****
  66
  67 dnl allow for different autotools
  68 AS_AUTOTOOLS_ALTERNATE
  69
  70 dnl Add parameters for aclocal
  71 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  72
  73 dnl set up gettext
  74 dnl the version check needs to stay here because autopoint greps for it
  75 AM_GNU_GETTEXT_VERSION([0.17])
  76 AM_GNU_GETTEXT([external])
  77 AG_GST_GETTEXT([gst-plugins-base-$GST_MAJORMINOR])
  78
  79 dnl *** check for arguments to configure ***
  80
  81 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  82
  83 AG_GST_ARG_DEBUG
  84 AG_GST_ARG_PROFILING
  85 AG_GST_ARG_VALGRIND
  86 AG_GST_ARG_GCOV
  87
  88 AG_GST_ARG_EXAMPLES
  89
  90 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  91 AG_GST_ARG_WITH_PACKAGE_NAME
  92 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  93
  94 AG_GST_PKG_CONFIG_PATH
  95
  96 dnl let distro override plugin install helper path
  97 AC_ARG_WITH(install-plugins-helper,
  98   AC_HELP_STRING([--with-install-plugins-helper],
  99     [specify path of helper script to call to install plugins]),
 100   [
 101     case "${withval}" in
 102       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 103       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 104       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
 105     esac
 106   ],
 107   [
 108     dnl Default value
 109     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 110   ]
 111 )
 112 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 113 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 114     [plugin install helper script])
 115 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 116
 117 AG_GST_ARG_WITH_PLUGINS
 118
 119 AG_GST_ARG_ENABLE_EXTERNAL
 120
 121 AG_GST_ARG_ENABLE_EXPERIMENTAL
 122
 123 dnl *** checks for platform ***
 124 AG_GST_PLATFORM
 125
 126 dnl * hardware/architecture *
 127
 128 dnl common/m4/gst-arch.m4
 129 dnl check CPU type
 130 AG_GST_ARCH
 131
 132 dnl check for large file support
 133 dnl affected plugins must include config.h
 134 AC_SYS_LARGEFILE
 135
 136 dnl *** checks for programs ***
 137
 138 dnl find a compiler
 139 AC_PROG_CC
 140 AC_PROG_CC_STDC
 141
 142 dnl check if the compiler supports '-c' and '-o' options
 143 AM_PROG_CC_C_O
 144
 145 dnl determine if c++ is available on this system
 146 AC_PROG_CXX
 147 dnl CXX may be set to some default even if no c++ compiler is available
 148 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 149 AC_LANG_PUSH([C++])
 150 AC_TRY_COMPILE([ class Foo { int bar; };], , working_cxx=yes, working_cxx=no)
 151 AC_LANG_POP([C++])
 152 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 153 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 154
 155 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 156 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 157
 158 dnl check for gobject-introspection
 159 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 160
 161 dnl check for documentation tools
 162 GTK_DOC_CHECK([1.3])
 163 AS_PATH_PYTHON([2.1])
 164 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 165
 166 dnl *** checks for libraries ***
 167
 168 dnl libm, for sin() etc.
 169 AC_CHECK_LIBM
 170 AC_SUBST(LIBM)
 171
 172 dnl *** checks for header files ***
 173
 174 dnl check if we have ANSI C header files
 175 AC_HEADER_STDC
 176
 177 ac_cppflags_save="$CPPFLAGS"
 178 CPPFLAGS="`$PKG_CONFIG --cflags libxml-2.0`"
 179 AC_COMPILE_IFELSE(
 180   AC_LANG_PROGRAM([
 181 #include <libxml/HTMLparser.h>
 182                      ],[
 183 #ifndef LIBXML_HTML_ENABLED
 184 #error libxml2 has no HTML support
 185 #endif /* LIBXML_HTML_ENABLED */
 186                    ]), HAVE_LIBXML_HTML="yes", HAVE_LIBXML_HTML="no")
 187 CPPFLAGS="$ac_cppflags_save"
 188 AM_CONDITIONAL(HAVE_LIBXML_HTML, test "x$HAVE_LIBXML_HTML" = "xyes")
 189
 190 dnl used in gst/tcp
 191 AC_CHECK_HEADERS([sys/socket.h],
 192   HAVE_SYS_SOCKET_H="yes", HAVE_SYS_SOCKET_H="no")
 193 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 194
 195 dnl used in gst-libs/gst/pbutils and associated unit test
 196 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h])
 197
 198 dnl also, Windows does not have long long
 199 AX_CREATE_STDINT_H
 200
 201 dnl *** checks for functions ***
 202 AC_CHECK_FUNCS([localtime_r gmtime_r])
 203
 204 dnl *** checks for math functions ***
 205 LIBS_SAVE=$LIBS
 206 LIBS="$LIBS $LIBM"
 207 AC_CHECK_FUNCS(log2)
 208 LIBS=$LIBS_SAVE
 209
 210 dnl *** checks for types/defines ***
 211
 212 dnl *** checks for structures ***
 213
 214 dnl *** checks for compiler characteristics ***
 215
 216 dnl *** checks for library functions ***
 217
 218 dnl check for fseeko()
 219 AC_FUNC_FSEEKO
 220
 221 dnl Check for fast float to int casting as defined in C99
 222 dnl used to be used in gst-libs/gst/floatcast/floatcast.h (FIXME: still needed?)
 223 save_libs=$LIBS
 224 LIBS="$LIBS $LIBM"
 225 AC_C99_FUNC_LRINT
 226 AC_C99_FUNC_LRINTF
 227 LIBS=$save_libs
 228
 229 dnl Check for a way to display the function name in debug output
 230 AG_GST_CHECK_FUNCTION
 231
 232 dnl *** checks for dependency libraries ***
 233
 234 dnl GLib
 235 GLIB_REQ=2.31.10
 236 AG_GST_GLIB_CHECK([$GLIB_REQ])
 237
 238 ORC_CHECK([0.4.11])
 239
 240 dnl checks for gstreamer
 241 dnl uninstalled is selected preferentially -- see pkg-config(1)
 242 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 243 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 244 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 245 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 246 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 247
 248 dnl Check for documentation xrefs
 249 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 250 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 251 AC_SUBST(GLIB_PREFIX)
 252 AC_SUBST(GST_PREFIX)
 253
 254 dnl GTK is optional and only used in examples
 255 HAVE_GTK=no
 256 HAVE_GTK_X11=no
 257 GTK_REQ=3.0.0
 258 if test "x$BUILD_EXAMPLES" = "xyes"; then
 259   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 260   dnl some examples need gtk+-x11
 261   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 262   AC_SUBST(GTK_LIBS)
 263   AC_SUBST(GTK_CFLAGS)
 264 fi
 265 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 266 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 267
 268 dnl QT is optional and only used in examples
 269 PKG_CHECK_MODULES(QT, QtGui >= 4.6, [
 270   HAVE_QT_GV=yes
 271   HAVE_QT=yes
 272 ], [
 273   HAVE_QT_GV=no
 274   PKG_CHECK_MODULES(QT, QtGui >= 4.0, HAVE_QT=yes, HAVE_QT=no)
 275 ])
 276 if test "x$HAVE_QT" = "xyes"; then
 277   AC_MSG_CHECKING([Qt moc])
 278   QT4_MOC=`$PKG_CONFIG --variable=moc_location QtGui`
 279   AC_MSG_RESULT($QT4_MOC)
 280   AC_SUBST(QT4_MOC)
 281 fi
 282 AM_CONDITIONAL(HAVE_QT, test "x$HAVE_QT" = "xyes")
 283 AM_CONDITIONAL(HAVE_QT_GV, test "x$HAVE_QT_GV" = "xyes")
 284
 285 dnl chck for linux headers needed by the joystick seek example
 286 AC_COMPILE_IFELSE(
 287 [
 288   AC_LANG_PROGRAM([
 289     #include <linux/input.h>
 290     #include <linux/joystick.h>
 291   ],[
 292     struct js_event js;
 293     js.type = JS_EVENT_AXIS;
 294   ])
 295 ], [
 296   HAVE_LINUX_JOYSTICK_HEADERS="yes"
 297 ], [
 298   HAVE_LINUX_JOYSTICK_HEADERS="no"
 299 ])
 300 AM_CONDITIONAL(HAVE_LINUX_JOYSTICK_HEADERS, test "x$HAVE_LINUX_JOYSTICK_HEADERS" = "xyes")
 301
 302 dnl Check for -Bsymbolic-functions linker flag used to avoid
 303 dnl intra-library PLT jumps, if available.
 304 AC_ARG_ENABLE(Bsymbolic,
 305               [AC_HELP_STRING([--disable-Bsymbolic],
 306                               [avoid linking with -Bsymbolic])],,
 307               [SAVED_LDFLAGS="${LDFLAGS}"
 308                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 309                LDFLAGS=-Wl,-Bsymbolic-functions
 310                AC_TRY_LINK([], [int main (void) { return 0; }],
 311                            AC_MSG_RESULT(yes)
 312                            enable_Bsymbolic=yes,
 313                            AC_MSG_RESULT(no)
 314                            enable_Bsymbolic=no)
 315                LDFLAGS="${SAVED_LDFLAGS}"])
 316
 317
 318 dnl *** set variables based on configure arguments ***
 319
 320 dnl set license and copyright notice
 321 GST_LICENSE="LGPL"
 322 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 323 AC_SUBST(GST_LICENSE)
 324
 325 dnl set location of plugin directory
 326 AG_GST_SET_PLUGINDIR
 327
 328 dnl set release date/time
 329 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 330   ["${srcdir}/gst-plugins-base.doap"],
 331   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 332
 333 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 334 dnl make sure it doesn't complain about unused variables if debugging is disabled
 335 NO_WARNINGS=""
 336 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 337
 338 dnl define an ERROR_CFLAGS Makefile variable
 339 dnl -Wformat-nonliteral - see ext/pango/gstclockoverlay.c and http://gcc.gnu.org/bugzilla/show_bug.cgi?id=39438
 340 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 341     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef
 342     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 343     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 344     -Wno-multichar -Wnested-externs $NO_WARNINGS])
 345
 346 dnl define an ERROR_CXXFLAGS Makefile variable
 347 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 348     -Wmissing-declarations -Wredundant-decls -Wundef
 349     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 350     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 351     -Wno-multichar $NO_WARNINGS])
 352
 353 dnl define correct level for debugging messages
 354 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 355
 356 dnl used in examples
 357 AG_GST_DEFAULT_ELEMENTS
 358
 359 dnl needed for encoding-target
 360 GST_DATADIR="$GST_PREFIX/share"
 361 AC_DEFINE_UNQUOTED(GST_DATADIR, "$GST_DATADIR", [system wide data directory])
 362 AC_DEFINE_UNQUOTED(GST_MAJORMINOR, "$GST_MAJORMINOR", [major/minor version])
 363
 364 dnl behaviour of speex based audio resampler
 365 AC_MSG_CHECKING(which audio resample format to use for integer)
 366 AC_ARG_WITH([audioresample_format],
 367         AS_HELP_STRING([--with-audioresample-format],[Which implementation should be used for integer audio resampling, int/float/auto, (default is auto)]),
 368         [ac_cv_audioresample_format=$withval], [ac_cv_audioresample_format=auto])dnl
 369 AC_MSG_RESULT($ac_cv_audioresample_format)
 370 case $ac_cv_audioresample_format in
 371   int)
 372     AC_DEFINE(AUDIORESAMPLE_FORMAT_INT,1,[The int implementation should be used for integer audio resampling])
 373     AC_SUBST(AUDIORESAMPLE_FORMAT_INT)
 374   ;;
 375   float)
 376     AC_DEFINE(AUDIORESAMPLE_FORMAT_FLOAT,1,[The float implementation should be used for integer audio resampling])
 377     AC_SUBST(AUDIORESAMPLE_FORMAT_FLOAT)
 378   ;;
 379   auto)
 380     AC_DEFINE(AUDIORESAMPLE_FORMAT_AUTO,1,[The implementation that should be used for integer audio resampling witll be benchmarked at runtime])
 381     AC_SUBST(AUDIORESAMPLE_FORMAT_AUTO)
 382 esac
 383
 384 dnl *** plug-ins to include ***
 385
 386 dnl these are all the gst plug-ins, compilable without additional libs
 387 AG_GST_CHECK_PLUGIN(adder)
 388 AG_GST_CHECK_PLUGIN(app)
 389 AG_GST_CHECK_PLUGIN(audioconvert)
 390 AG_GST_CHECK_PLUGIN(audiorate)
 391 AG_GST_CHECK_PLUGIN(audiotestsrc)
 392 AG_GST_CHECK_PLUGIN(encoding)
 393 AG_GST_CHECK_PLUGIN(videoconvert)
 394 AG_GST_CHECK_PLUGIN(gdp)
 395 AG_GST_CHECK_PLUGIN(gio)
 396 AG_GST_CHECK_PLUGIN(playback)
 397 AG_GST_CHECK_PLUGIN(audioresample)
 398 AG_GST_CHECK_PLUGIN(subparse)
 399 AG_GST_CHECK_PLUGIN(tcp)
 400 AG_GST_CHECK_PLUGIN(typefind)
 401 AG_GST_CHECK_PLUGIN(videotestsrc)
 402 AG_GST_CHECK_PLUGIN(videorate)
 403 AG_GST_CHECK_PLUGIN(videoscale)
 404 AG_GST_CHECK_PLUGIN(volume)
 405
 406 dnl FIXME 0.11: check for libxml, split subparse and move libxml parts to ext/
 407 AM_CONDITIONAL(USE_XML, false)
 408 AC_DEFINE([GST_DISABLE_XML], [1], [set to disable libxml2-dependent code in subparse])
 409
 410 dnl disable plug-ins that require libxml2's HTML support if it is not available
 411 if test "x$HAVE_LIBXML_HTML" != "xyes"; then
 412   AG_GST_DISABLE_PLUGIN(subparse)
 413 fi
 414
 415 dnl iso-codes is optional, used by libgsttag
 416 AC_ARG_ENABLE(iso-codes,
 417 AC_HELP_STRING([--enable-iso-codes],[use iso-codes if installed]),
 418 [case "${enableval}" in
 419   yes) enable_iso_codes=yes ;;
 420   no)  enable_iso_codes=no ;;
 421   *) AC_MSG_ERROR(bad value ${enableval} for --enable-iso-codes) ;;
 422 esac
 423 ],
 424 [enable_iso_codes=yes]) dnl Default value
 425
 426 AC_MSG_CHECKING([whether to use iso-codes if they are available])
 427 if test "x$enable_iso_codes" = "xyes"; then
 428   AC_MSG_RESULT([yes])
 429   have_iso_codes=no
 430   AC_MSG_CHECKING([whether iso-codes are available on this system])
 431   if $PKG_CONFIG iso-codes; then
 432     AC_MSG_RESULT([yes])
 433     AC_MSG_CHECKING([whether iso-codes has iso-639 domain])
 434     if $PKG_CONFIG --variable=domains iso-codes | $GREP -q 639 ; then
 435       AC_MSG_RESULT([yes])
 436       AC_MSG_CHECKING([for iso-codes prefix])
 437       ISO_CODES_PREFIX=`$PKG_CONFIG --variable=prefix iso-codes`
 438       if test -d "$ISO_CODES_PREFIX"; then
 439         AC_MSG_RESULT([yes])
 440         AC_MSG_CHECKING([ISO_CODES_PREFIX])
 441         AC_MSG_RESULT([$ISO_CODES_PREFIX])
 442         ISO_639_DOMAIN="iso_639"
 443         AC_MSG_CHECKING([ISO_639_DOMAIN])
 444         AC_MSG_RESULT([$ISO_639_DOMAIN])
 445         have_iso_codes=yes
 446         AC_DEFINE([HAVE_ISO_CODES], [1], [make use of iso-codes for ISO-639])
 447         AC_DEFINE_UNQUOTED([ISO_CODES_PREFIX], ["$ISO_CODES_PREFIX"], [prefix])
 448         ISO_CODES_VERSION=`$PKG_CONFIG --modversion iso-codes`
 449         AC_DEFINE_UNQUOTED([ISO_CODES_VERSION], ["$ISO_CODES_VERSION"], [ ])
 450       else
 451         AC_MSG_RESULT([no])
 452       fi
 453     else
 454       AC_MSG_RESULT([no])
 455     fi
 456   else
 457     AC_MSG_RESULT([no])
 458   fi
 459   AM_CONDITIONAL(USE_ISO_CODES, test "x$have_iso_codes" = "xyes")
 460 else
 461   AC_MSG_RESULT([no (disabled via --disable-iso-codes)])
 462   AM_CONDITIONAL(USE_ISO_CODES, false)
 463 fi
 464
 465 dnl *** zlib is optionally used by id3 tag parsing in libgsttag ***
 466 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 467 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for ID3 parsing in libgsttag],, [
 468   PKG_CHECK_MODULES(ZLIB, [ zlib ], [
 469       HAVE_ZLIB="yes"
 470     ], [
 471       AG_GST_CHECK_LIBHEADER(ZLIB, z, uncompress,, zlib.h, [
 472         HAVE_ZLIB="yes"
 473         ZLIB_LIBS="-lz"
 474         AC_SUBST(ZLIB_LIBS)
 475       ])
 476     ])
 477 ])
 478
 479 dnl *** sys plug-ins ***
 480
 481 echo
 482 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 483 echo
 484
 485 dnl *** X11 ***
 486 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 487 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 488                   [ximagesink], [
 489   AC_PATH_XTRA
 490   ac_cflags_save="$CFLAGS"
 491   ac_cppflags_save="$CPPFLAGS"
 492   CFLAGS="$CFLAGS $X_CFLAGS"
 493   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 494
 495   dnl now try to find the HEADER
 496   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 497
 498   if test "x$HAVE_X" = "xno"
 499   then
 500     AC_MSG_NOTICE([cannot find X11 development files])
 501   else
 502     dnl this is much more than we want
 503     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 504     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 505     dnl it does not add the libs; therefore we add them here
 506     X_LIBS="$X_LIBS -lX11"
 507     AC_SUBST(X_CFLAGS)
 508     AC_SUBST(X_LIBS)
 509   fi
 510   AC_SUBST(HAVE_X)
 511   CFLAGS="$ac_cflags_save"
 512   CPPFLAGS="$ac_cppflags_save"
 513 ])
 514
 515 dnl Check for Xv extension
 516 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 517 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 518                   [xvimagesink], [
 519   AG_GST_CHECK_XV
 520 ])
 521
 522 dnl check for X Shm
 523 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 524 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 525   if test x$HAVE_X = xyes; then
 526     AC_CHECK_LIB(Xext, XShmAttach,
 527                  HAVE_XSHM="yes", HAVE_XSHM="no",
 528                  $X_LIBS)
 529     if test "x$HAVE_XSHM" = "xyes"; then
 530       XSHM_LIBS="-lXext"
 531     else
 532       dnl On AIX, it is in XextSam instead, but we still need -lXext
 533       AC_CHECK_LIB(XextSam, XShmAttach,
 534                    HAVE_XSHM="yes", HAVE_XSHM="no",
 535                    $X_LIBS)
 536       if test "x$HAVE_XSHM" = "xyes"; then
 537         XSHM_LIBS="-lXext -lXextSam"
 538       fi
 539     fi
 540   fi
 541 ], , [
 542   AC_SUBST(HAVE_XSHM)
 543   AC_SUBST(XSHM_LIBS)
 544 ])
 545
 546 dnl *** ext plug-ins ***
 547 dnl keep this list sorted alphabetically !
 548
 549 if test "x$BUILD_EXTERNAL" = "xyes"; then
 550
 551 echo
 552 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 553 echo
 554
 555 dnl *** alsa ***
 556 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 557 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 558   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 559     HAVE_ALSA="yes"
 560     AC_SUBST(ALSA_CFLAGS)
 561     AC_SUBST(ALSA_LIBS)
 562   ], [
 563     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 564   ])
 565 ])
 566
 567 dnl *** CDParanoia ***
 568 dnl Note: upstream has a pkg-config file only in post-10.2 SVN so far
 569 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 570 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 571   PKG_CHECK_MODULES(CDPARANOIA, cdparanoia-3 >= 10.2, [
 572     HAVE_CDPARANOIA="yes"
 573   ], [
 574     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 575                         cdda_open, -lm,
 576                         cdda_interface.h,
 577                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 578                         HEADER_DIR="no"
 579                         FOUND_CDPARANOIA="yes")
 580     if test "x$FOUND_CDPARANOIA" != "xyes";
 581     then
 582       AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 583                           cdda_open, -lm,
 584                           cdda/cdda_interface.h,
 585                           CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 586                           HEADER_DIR="yes"
 587                           FOUND_CDPARANOIA="yes")
 588     fi
 589     if test "x$HEADER_DIR" = "xyes";
 590     then
 591       AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 592                          defined if cdda headers are in a cdda/ directory)
 593     fi
 594     if test "x$FOUND_CDPARANOIA" = "xyes";
 595     then
 596       AC_CHECK_LIB(cdda_paranoia,
 597                    paranoia_cachemodel_size,
 598                    : ,
 599                    HAVE_CDPARANOIA=no,
 600                  [-lcdda_interface])
 601     fi
 602
 603     AC_SUBST(CDPARANOIA_LIBS)
 604   ])
 605 ])
 606 dnl FIXME : add second check somehow if that is necessary
 607 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 608 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 609
 610 dnl *** ivorbis ***
 611 dnl AM_PATH_IVORBIS only takes two options
 612 translit(dnm, m, l) AM_CONDITIONAL(USE_IVORBIS, true)
 613 AG_GST_CHECK_FEATURE(IVORBIS, [integer vorbis plug-in], ivorbisdec, [
 614   AG_GST_PKG_CHECK_MODULES(IVORBIS, vorbisidec)
 615   if test $HAVE_IVORBIS = no
 616   then
 617     IVORBIS_LIBS=
 618     IVORBIS_CFLAGS=
 619     AC_CHECK_LIB(vorbisidec, vorbis_block_init,
 620       [IVORBIS_LIBS=-lvorbisidec
 621       HAVE_IVORBIS=yes
 622       case $host in
 623       arm-*-*)
 624         IVORBIS_CFLAGS="-D_ARM_ASSEM_ $IVORBIS_CFLAGS"
 625       esac
 626       ],
 627       HAVE_IVORBIS=no)
 628     AC_SUBST(IVORBIS_LIBS)
 629     AC_SUBST(IVORBIS_CFLAGS)
 630   else
 631     AC_CHECK_LIB(vorbisidec, vorbis_dsp_pcmout,
 632       AC_DEFINE([USE_TREMOLO],1, "Define if building for android"),
 633       USE_TREMOLO=no)
 634   fi
 635 ])
 636
 637 dnl *** libvisual ***
 638 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 639 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 640   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 641   if test $HAVE_LIBVISUAL = no
 642   then
 643     AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0)
 644     if test x$HAVE_LIBVISUAL = xyes; then
 645       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.2`"
 646     fi
 647   else
 648     if test x$HAVE_LIBVISUAL = xyes; then
 649       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.4`"
 650     fi
 651   fi
 652   AC_MSG_NOTICE([libvisual pluginsdir: $LIBVIS_PLUGINSDIR])
 653   if test x$LIBVIS_PLUGINSDIR != x; then
 654     AC_DEFINE_UNQUOTED(LIBVISUAL_PLUGINSBASEDIR,
 655         "$LIBVIS_PLUGINSDIR",
 656         [directory in which the detected libvisual's plugins are located])
 657   fi
 658 ])
 659
 660 dnl *** ogg ***
 661 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 662 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 663   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 664   if test $HAVE_OGG = no
 665   then
 666     XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
 667     AS_SCRUB_INCLUDE(OGG_CFLAGS)
 668   fi
 669 ])
 670
 671 dnl *** pango ***
 672 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 673 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 674   AG_GST_PKG_CHECK_MODULES(PANGO, pango >= 1.16.0  pangocairo >= 1.16.0)
 675 ])
 676
 677 dnl *** theora ***
 678 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 679 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 680   AG_GST_PKG_CHECK_MODULES(THEORA, theoradec >= 1.1 theoraenc >= 1.1)
 681 ])
 682
 683 dnl *** vorbis ***
 684 dnl AM_PATH_VORBIS only takes two options
 685 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 686 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 687   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 688   if test $HAVE_VORBIS = no
 689   then
 690     XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
 691     AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
 692   fi
 693 ])
 694
 695 if test "x$HAVE_VORBIS" = "xyes"; then
 696   ac_cflags_save="$CFLAGS"
 697   AC_COMPILE_IFELSE(
 698     AC_LANG_PROGRAM([
 699 #include <vorbis/codec.h>
 700                      ],[
 701 vorbis_dsp_state *v;
 702
 703 vorbis_synthesis_restart (v);
 704                      ]), HAVE_VSR=yes, HAVE_VSR=no)
 705   if test "x$HAVE_VSR" = "xyes"; then
 706     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 707                        [defined if vorbis_synthesis_restart is present])
 708   fi
 709   CFLAGS="$ac_cflags_save"
 710 fi
 711
 712 else
 713
 714 dnl not building plugins with external dependencies,
 715 dnl but we still need to set the conditionals
 716 AM_CONDITIONAL(USE_ALSA, false)
 717 AM_CONDITIONAL(USE_CDPARANOIA, false)
 718 AM_CONDITIONAL(USE_IVORBIS, false)
 719 AM_CONDITIONAL(USE_LIBVISUAL, false)
 720 AM_CONDITIONAL(USE_OGG, false)
 721 AM_CONDITIONAL(USE_PANGO, false)
 722 AM_CONDITIONAL(USE_THEORA, false)
 723 AM_CONDITIONAL(USE_VORBIS, false)
 724
 725 fi dnl of EXT plugins
 726
 727 dnl seeking needs freetype, so check for it here
 728 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 729   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 730 ])
 731 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 732 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 733 AC_SUBST(FT2_CFLAGS)
 734 AC_SUBST(FT2_LIBS)
 735
 736 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 737
 738 dnl Overview:
 739 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 740 dnl GST_*:              flags shared by built objects to link against GStreamer
 741 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 742 dnl                          (compare to other modules) or for i18n
 743 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 744 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 745 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 746 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 747
 748 dnl GST_OPTION_CFLAGS
 749 if test "x$USE_DEBUG" = xyes; then
 750    PROFILE_CFLAGS="-g"
 751 fi
 752 AC_SUBST(PROFILE_CFLAGS)
 753
 754 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 755   dnl Define _only_ when compiling a git version (not pre-releases or releases)
 756   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 757 else
 758   DEPRECATED_CFLAGS=""
 759 fi
 760 AC_SUBST(DEPRECATED_CFLAGS)
 761
 762 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 763 dnl at make time with e.g. make ERROR_CFLAGS=""
 764 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 765 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 766 AC_SUBST(GST_OPTION_CFLAGS)
 767 AC_SUBST(GST_OPTION_CXXFLAGS)
 768
 769 dnl our libraries need to be versioned correctly
 770 AC_SUBST(GST_LT_LDFLAGS)
 771
 772 dnl GST_PLUGINS_BASE_CFLAGS
 773 dnl prefer internal headers to already installed ones
 774 dnl also add builddir include for enumtypes and marshal
 775 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 776 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 777
 778 dnl FIXME: do we want to rename to GST_ALL_* ?
 779 dnl add GST_OPTION_CFLAGS, but overridable
 780 GST_CFLAGS="$GST_CFLAGS -DGST_USE_UNSTABLE_API"
 781 GST_CXXFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CXXFLAGS)"
 782 GST_CFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CFLAGS)"
 783 AC_SUBST(GST_CFLAGS)
 784 AC_SUBST(GST_CXXFLAGS)
 785 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 786 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 787 AC_SUBST(GST_LIBS)
 788
 789 dnl LDFLAGS really should only contain flags, not libs - they get added before
 790 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 791 GST_ALL_LDFLAGS="-no-undefined"
 792 if test "x${enable_Bsymbolic}" = "xyes"; then
 793   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 794 fi
 795 AC_SUBST(GST_ALL_LDFLAGS)
 796
 797 dnl GST_LIB_LDFLAGS
 798 dnl linker flags shared by all libraries
 799 dnl LDFLAGS modifier defining exported symbols from built libraries
 800 dnl (export _gst_foo but not __gst_foo)
 801 GST_LIB_LDFLAGS="-export-symbols-regex ^_?\(gst_\|Gst\|GST_\).*"
 802 AC_SUBST(GST_LIB_LDFLAGS)
 803
 804 dnl this really should only contain flags, not libs - they get added before
 805 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 806 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
 807 AC_SUBST(GST_PLUGIN_LDFLAGS)
 808
 809 dnl *** output files ***
 810
 811 AC_CONFIG_FILES(
 812 Makefile
 813 gst-plugins-base.spec
 814 gst/Makefile
 815 gst/adder/Makefile
 816 gst/app/Makefile
 817 gst/audioconvert/Makefile
 818 gst/audiorate/Makefile
 819 gst/audiotestsrc/Makefile
 820 gst/encoding/Makefile
 821 gst/videoconvert/Makefile
 822 gst/gdp/Makefile
 823 gst/gio/Makefile
 824 gst/playback/Makefile
 825 gst/audioresample/Makefile
 826 gst/subparse/Makefile
 827 gst/tcp/Makefile
 828 gst/typefind/Makefile
 829 gst/videotestsrc/Makefile
 830 gst/videorate/Makefile
 831 gst/videoscale/Makefile
 832 gst/volume/Makefile
 833 sys/Makefile
 834 sys/ximage/Makefile
 835 sys/xvimage/Makefile
 836 ext/Makefile
 837 ext/alsa/Makefile
 838 ext/cdparanoia/Makefile
 839 ext/libvisual/Makefile
 840 ext/ogg/Makefile
 841 ext/pango/Makefile
 842 ext/theora/Makefile
 843 ext/vorbis/Makefile
 844 gst-libs/Makefile
 845 gst-libs/gst/Makefile
 846 gst-libs/gst/audio/Makefile
 847 gst-libs/gst/app/Makefile
 848 gst-libs/gst/fft/Makefile
 849 gst-libs/gst/interfaces/Makefile
 850 gst-libs/gst/riff/Makefile
 851 gst-libs/gst/rtp/Makefile
 852 gst-libs/gst/rtsp/Makefile
 853 gst-libs/gst/sdp/Makefile
 854 gst-libs/gst/tag/Makefile
 855 gst-libs/gst/pbutils/Makefile
 856 gst-libs/gst/pbutils/gstpluginsbaseversion.h
 857 gst-libs/gst/video/Makefile
 858 tools/Makefile
 859 pkgconfig/Makefile
 860 pkgconfig/gstreamer-audio.pc
 861 pkgconfig/gstreamer-audio-uninstalled.pc
 862 pkgconfig/gstreamer-app.pc
 863 pkgconfig/gstreamer-app-uninstalled.pc
 864 pkgconfig/gstreamer-fft.pc
 865 pkgconfig/gstreamer-fft-uninstalled.pc
 866 pkgconfig/gstreamer-interfaces.pc
 867 pkgconfig/gstreamer-interfaces-uninstalled.pc
 868 pkgconfig/gstreamer-pbutils.pc
 869 pkgconfig/gstreamer-pbutils-uninstalled.pc
 870 pkgconfig/gstreamer-riff.pc
 871 pkgconfig/gstreamer-riff-uninstalled.pc
 872 pkgconfig/gstreamer-rtp.pc
 873 pkgconfig/gstreamer-rtp-uninstalled.pc
 874 pkgconfig/gstreamer-rtsp.pc
 875 pkgconfig/gstreamer-rtsp-uninstalled.pc
 876 pkgconfig/gstreamer-sdp.pc
 877 pkgconfig/gstreamer-sdp-uninstalled.pc
 878 pkgconfig/gstreamer-tag.pc
 879 pkgconfig/gstreamer-tag-uninstalled.pc
 880 pkgconfig/gstreamer-video.pc
 881 pkgconfig/gstreamer-video-uninstalled.pc
 882 pkgconfig/gstreamer-plugins-base.pc
 883 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 884 tests/Makefile
 885 tests/check/Makefile
 886 tests/examples/Makefile
 887 tests/examples/app/Makefile
 888 tests/examples/audio/Makefile
 889 tests/examples/dynamic/Makefile
 890 tests/examples/encoding/Makefile
 891 tests/examples/fft/Makefile
 892 tests/examples/gio/Makefile
 893 tests/examples/overlay/Makefile
 894 tests/examples/seek/Makefile
 895 tests/examples/snapshot/Makefile
 896 tests/examples/playback/Makefile
 897 tests/examples/playrec/Makefile
 898 tests/files/Makefile
 899 tests/icles/Makefile
 900 tests/icles/playback/Makefile
 901 docs/Makefile
 902 docs/design/Makefile
 903 docs/libs/Makefile
 904 docs/plugins/Makefile
 905 docs/version.entities
 906 po/Makefile.in
 907 common/Makefile
 908 common/m4/Makefile
 909 m4/Makefile
 910 )
 911
 912 dnl Create the config.h file for Visual Studio builds
 913 dnl Beware of spaces and /'s in some of the shell variable contents.
 914 sed \
 915     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 916     -e 's/.* GST_INSTALL_PLUGINS_HELPER/#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
 917     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 918     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 919     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 920     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 921     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
 922     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 923     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 924     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
 925     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 926     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 927     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 928     -e 's/.* HAVE_ISO_CODES$/#undef HAVE_ISO_CODES/' \
 929     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
 930     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 931     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 932     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 933     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 934     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 935     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 936     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 937     -e 's/.* ISO_CODES_PREFIX$/#undef ISO_CODES_PREFIX/' \
 938     -e 's/.* ISO_CODES_VERSION$/#undef ISO_CODES_VERSION/' \
 939     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 940     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 941     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
 942     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 943     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
 944     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 945     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 946     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 947     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
 948     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
 949     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 950     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
 951     -e "s/.* DEFAULT_VIDEOSINK$/#define DEFAULT_VIDEOSINK \"directdrawsink\"/" \
 952     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
 953     config.h.in >win32/common/config.h-new
 954
 955
 956
 957 AC_OUTPUT
 958
 959 AG_GST_OUTPUT_PLUGINS
 960 ORC_OUTPUT
 961