configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, cvs and prerelease does Werror too
   6 AC_INIT(GStreamer, 0.10.14.1,
   7     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
   8     gstreamer)
   9 AG_GST_INIT
  10
  11 dnl initialize automake
  12 AM_INIT_AUTOMAKE
  13
  14 dnl define PACKAGE_VERSION_* variables
  15 AS_VERSION
  16
  17 dnl check if this is a release version
  18 AS_NANO(GST_CVS="no", GST_CVS="yes")
  19
  20 dnl can autoconf find the source ?
  21 AC_CONFIG_SRCDIR([gst/gst.c])
  22
  23 dnl define the output header for config
  24 AM_CONFIG_HEADER([config.h])
  25
  26 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  27 AM_MAINTAINER_MODE
  28
  29 dnl sets host_* variables
  30 AC_CANONICAL_HOST
  31
  32 dnl our libraries and install dirs use major.minor as a version
  33 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  34 dnl we override it here for release candidates for a new series
  35 GST_MAJORMINOR=0.10
  36 AC_SUBST(GST_MAJORMINOR)
  37 AC_DEFINE_UNQUOTED(GST_MAJORMINOR, "$GST_MAJORMINOR",
  38   [library major.minor version])
  39
  40 dnl CURRENT, REVISION, AGE
  41 dnl - library source changed -> increment REVISION
  42 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  43 dnl - interfaces added -> increment AGE
  44 dnl - interfaces removed -> AGE = 0
  45 dnl sets GST_LT_LDFLAGS
  46 AS_LIBTOOL(GST, 13, 0, 13)
  47
  48 dnl FIXME: this macro doesn't actually work;
  49 dnl the generated libtool script has no support for the listed tags.
  50 dnl So this needs to be fixed first if we want to use this
  51 dnl AS_LIBTOOL_TAGS
  52
  53 AM_PROG_LIBTOOL
  54
  55 dnl *** autotools stuff ****
  56
  57 dnl allow for different autotools
  58 AS_AUTOTOOLS_ALTERNATE
  59
  60 dnl Add parameters for aclocal
  61 AC_SUBST(ACLOCAL_AMFLAGS, "-I common/m4")
  62
  63 dnl set up gettext
  64 dnl the version check needs to stay here because autopoint greps for it
  65 AM_GNU_GETTEXT_VERSION([0.11.5])
  66 AM_GNU_GETTEXT([external])
  67 AG_GST_GETTEXT([gstreamer-$GST_MAJORMINOR])
  68
  69 dnl *** check for arguments to configure ***
  70
  71 dnl subsystems - can influence other decisions so needs to be high up
  72 dnl we need to AM_CONDITIONAL them here for automake 1.6.x compatibility
  73 AG_GST_CHECK_SUBSYSTEM_DISABLE(GST_DEBUG,[debugging subsystem])
  74 AM_CONDITIONAL(GST_DISABLE_GST_DEBUG, test "x$GST_DISABLE_GST_DEBUG" = "xyes")
  75 AG_GST_CHECK_SUBSYSTEM_DISABLE(LOADSAVE,[pipeline XML load/save])
  76 AM_CONDITIONAL(GST_DISABLE_LOADSAVE, test "x$GST_DISABLE_LOADSAVE" = "xyes")
  77 dnl define a substitution to use in docs/gst/gstreamer.types
  78 if test "x$GST_DISABLE_LOADSAVE" = "xyes"
  79 then
  80   GST_LOADSAVE_DOC_TYPES="%"
  81 else
  82   GST_LOADSAVE_DOC_TYPES=
  83 fi
  84 AC_SUBST(GST_LOADSAVE_DOC_TYPES)
  85 AG_GST_CHECK_SUBSYSTEM_DISABLE(PARSE,[command-line parser])
  86 AM_CONDITIONAL(GST_DISABLE_PARSE, test "x$GST_DISABLE_PARSE" = "xyes")
  87 if test "x$GST_DISABLE_PARSE" = xyes; then
  88   AC_DEFINE(GST_DISABLE_PARSE, 1,
  89     [Define if pipeline parsing code is disabled])
  90 fi
  91 AG_GST_CHECK_SUBSYSTEM_DISABLE(TRACE,[tracing subsystem])
  92 AM_CONDITIONAL(GST_DISABLE_TRACE, test "x$GST_DISABLE_TRACE" = "xyes")
  93 AG_GST_CHECK_SUBSYSTEM_DISABLE(ALLOC_TRACE,[allocation tracing])
  94 AM_CONDITIONAL(GST_DISABLE_ALLOC_TRACE, test "x$GST_DISABLE_ALLOC_TRACE" = "xyes")
  95 AG_GST_CHECK_SUBSYSTEM_DISABLE(REGISTRY,[plugin registry])
  96 AM_CONDITIONAL(GST_DISABLE_REGISTRY, test "x$GST_DISABLE_REGISTRY" = "xyes")
  97 dnl define a substitution to use in docs/gst/gstreamer.types
  98 if test "x$GST_DISABLE_REGISTRY" = "xyes"
  99 then
 100   GST_REGISTRY_DOC_TYPES="%"
 101 else
 102   GST_REGISTRY_DOC_TYPES=
 103 fi
 104 AC_SUBST(GST_REGISTRY_DOC_TYPES)
 105 AG_GST_CHECK_SUBSYSTEM_DISABLE(ENUMTYPES,[enum types])
 106 AM_CONDITIONAL(GST_DISABLE_ENUMTYPES, test "x$GST_DISABLE_ENUMTYPES" = "xyes")
 107 AG_GST_CHECK_SUBSYSTEM_DISABLE(INDEX,[index])
 108 AM_CONDITIONAL(GST_DISABLE_INDEX, test "x$GST_DISABLE_INDEX" = "xyes")
 109 dnl define a substitution to use in docs/gst/gstreamer.types
 110 if test "x$GST_DISABLE_INDEX" = "xyes"
 111 then
 112   GST_INDEX_DOC_TYPES="%"
 113 else
 114   GST_INDEX_DOC_TYPES=
 115 fi
 116 AC_SUBST(GST_INDEX_DOC_TYPES)
 117 AG_GST_CHECK_SUBSYSTEM_DISABLE(NET,[network distribution])
 118 AM_CONDITIONAL(GST_DISABLE_NET, test "x$GST_DISABLE_NET" = "xyes")
 119 AG_GST_CHECK_SUBSYSTEM_DISABLE(PLUGIN,[plugin])
 120 AM_CONDITIONAL(GST_DISABLE_PLUGIN, test "x$GST_DISABLE_PLUGIN" = "xyes")
 121 AG_GST_CHECK_SUBSYSTEM_DISABLE(URI,[uri handlers])
 122 AM_CONDITIONAL(GST_DISABLE_URI, test "x$GST_DISABLE_URI" = "xyes")
 123
 124 AG_GST_ARG_DEBUG
 125 AG_GST_ARG_PROFILING
 126 AG_GST_ARG_VALGRIND
 127 AG_GST_ARG_GCOV
 128
 129 AG_GST_ARG_EXAMPLES
 130
 131 AG_GST_ARG_WITH_PKG_CONFIG_PATH
 132 AG_GST_ARG_WITH_PACKAGE_NAME
 133 AG_GST_ARG_WITH_PACKAGE_ORIGIN
 134
 135 dnl use a cache dir for storing element registry info.
 136 GST_CACHE_DIR=${localstatedir}/cache/gstreamer-$GST_MAJORMINOR
 137
 138 AC_ARG_WITH(cachedir,
 139   AC_HELP_STRING([--with-cachedir],
 140     [specify path to use for plugin and command completion registries]),
 141   [
 142     case "${withval}" in
 143       yes) AC_MSG_ERROR(bad value ${withval} for --with-cachedir) ;;
 144       no)  AC_MSG_ERROR(bad value ${withval} for --with-cachedir) ;;
 145       *)   GST_CACHE_DIR="${withval}" ;;
 146     esac
 147   ],
 148   [:]) dnl Default value
 149
 150 AS_AC_EXPAND(GST_CACHE_DIR, $GST_CACHE_DIR)
 151 AC_DEFINE_UNQUOTED(GST_CACHE_DIR, "$GST_CACHE_DIR", [Location of registry])
 152 AC_MSG_NOTICE(Using $GST_CACHE_DIR as registry cache dir)
 153
 154 dnl building of tests
 155 AC_ARG_ENABLE(tests,
 156   AC_HELP_STRING([--disable-tests], [disable building test apps]),
 157   [
 158     case "${enableval}" in
 159       yes) BUILD_TESTS=yes ;;
 160       no)  BUILD_TESTS=no ;;
 161       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 162     esac
 163   ],
 164 [BUILD_TESTS=yes]) dnl Default value
 165 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 166
 167 dnl tests known to fail
 168 AC_ARG_ENABLE(failing-tests,
 169   AC_HELP_STRING([--disable-failing-tests],
 170     [disable building tests known to fail]),
 171   [
 172     case "${enableval}" in
 173       yes) BUILD_FAILING_TESTS=yes ;;
 174       no)  BUILD_FAILING_TESTS=no ;;
 175       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-failing-tests) ;;
 176     esac
 177   ],
 178   [BUILD_FAILING_TESTS=no]) dnl Default value
 179 AM_CONDITIONAL(BUILD_FAILING_TESTS, test "x$BUILD_FAILING_TESTS" = "xyes")
 180 if test x$BUILD_FAILING_TESTS = xyes; then
 181   AC_MSG_WARN([building tests known to fail, use --disable-failing-tests to disable])
 182 else
 183   AC_MSG_WARN([Sissy ! By asking to not build the tests known to fail, you hereby waive your right to customer support.  If you do not agree with this EULA, please press Ctrl-C before the next line is printed.  By allowing the next line to be printed, you expressly acknowledge your acceptance of this EULA.])
 184 fi
 185
 186 dnl poison destroyed objects
 187 AC_ARG_ENABLE(poisoning,
 188   AC_HELP_STRING([--enable-poisoning],
 189     [enable poisoning of deallocated objects]),
 190   [
 191     case "${enableval}" in
 192       yes) USE_POISONING=yes ;;
 193       no)  USE_POISONING=no ;;
 194       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-poisoning) ;;
 195     esac
 196   ],
 197   [USE_POISONING=no]) dnl Default value
 198 if test "x$USE_POISONING" = xyes; then
 199   AC_DEFINE(USE_POISONING, 1,
 200     [Define if we should poison deallocated memory])
 201 fi
 202
 203 dnl Use binary registry
 204 AC_ARG_ENABLE(binary-registry,
 205   AC_HELP_STRING([--enable-binary-registry],
 206     [enable experimental binary registry]),
 207   [
 208     case "${enableval}" in
 209       yes) USE_BINARY_REGISTRY=yes ;;
 210       no)  USE_BINARY_REGISTRY=no ;;
 211       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-binary-registry) ;;
 212     esac
 213   ],
 214   [USE_BINARY_REGISTRY=no]) dnl Default value
 215 if test "x$USE_BINARY_REGISTRY" = xyes; then
 216   AC_DEFINE(USE_BINARY_REGISTRY, 1,
 217     [Define if we should use binary registry instead xml registry])
 218 fi
 219 AM_CONDITIONAL(USE_BINARY_REGISTRY, test "x$USE_BINARY_REGISTRY" = "xyes")
 220
 221 dnl *** checks for platform ***
 222
 223 dnl * hardware/architecture *
 224
 225 dnl common/m4/gst-arch.m4
 226 dnl check CPU type
 227 AG_GST_ARCH
 228 dnl substitution for win32/common/config.h
 229 HOST_CPU=$host_cpu
 230 AC_SUBST(HOST_CPU)
 231
 232 dnl common/m4/gst-arch.m4
 233 dnl check for unaligned access
 234 AG_GST_UNALIGNED_ACCESS
 235 dnl create a configure variable for gst/gstconfig.h
 236 if test x${as_cv_unaligned_access} = xyes ; then
 237   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 1"
 238 else
 239   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 0"
 240 fi
 241 AC_SUBST(GST_HAVE_UNALIGNED_ACCESS_DEFINE)
 242
 243 dnl * software *
 244
 245 dnl check for large file support
 246 dnl affected plugins must include config.h
 247 AC_SYS_LARGEFILE
 248
 249 dnl HAVE_WIN32 currently means "disable POSIXisms".
 250 case "$host" in
 251   *-*-mingw*)
 252     AC_DEFINE_UNQUOTED(HAVE_WIN32, 1, [Defined if compiling for Windows])
 253     ;;
 254   *)
 255     ;;
 256 esac
 257
 258 dnl *** checks for programs ***
 259
 260 dnl find a compiler
 261 AC_PROG_CC
 262
 263 dnl find an assembler
 264 AM_PROG_AS
 265
 266 dnl Perl is used in building documentation and in the version checks
 267 AC_PATH_PROG(PERL_PATH, perl, no)
 268 if test x$PERL_PATH = xno; then
 269   AC_MSG_ERROR(Could not find perl)
 270 fi
 271
 272 dnl we require flex and bison for building the parser
 273 AG_GST_BISON_CHECK
 274 AG_GST_FLEX_CHECK
 275
 276 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 277 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 278
 279 dnl check for documentation tools
 280 AG_GST_DOCBOOK_CHECK
 281 GTK_DOC_CHECK([1.3])
 282 AS_PATH_PYTHON([2.1])
 283 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 284
 285 dnl *** checks for libraries ***
 286
 287 dnl For interactive UNIX (a Sun thing)
 288 dnl FIXME: this adds -lcposix to LIBS, but I doubt we use LIBS
 289 AC_ISC_POSIX
 290
 291 dnl check for libm, for sin()
 292 AC_CHECK_LIBM
 293 AC_SUBST(LIBM)
 294
 295 dnl *** checks for header files ***
 296
 297 dnl check if we have ANSI C header files
 298 AC_HEADER_STDC
 299
 300 dnl Check for ucontext.h
 301 AC_CHECK_HEADERS([ucontext.h])
 302
 303 dnl Check for sys/socket.h
 304 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 305 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 306
 307 dnl check for sys/times.h for tests/examples/adapter/
 308 AC_CHECK_HEADERS([sys/times.h], HAVE_SYS_TIMES_H=yes)
 309 AC_CHECK_HEADERS([unistd.h], HAVE_UNISTD_H=yes)
 310 AM_CONDITIONAL(HAVE_SYS_TIMES_H_AND_UNISTD_H, test "x$HAVE_SYS_TIMES_H" = "xyes" -a "x$HAVE_UNISTD_H" = "xyes")
 311
 312 dnl Check for process.h for getpid() on win32
 313 AC_CHECK_HEADERS([process.h])
 314
 315 dnl Check for sys/utsname.h for uname
 316 AC_CHECK_HEADERS([sys/utsname.h])
 317
 318 dnl *** checks for types/defines ***
 319
 320 dnl *** checks for structures ***
 321
 322 dnl *** checks for compiler characteristics ***
 323
 324 dnl make sure we can use "inline" from C code
 325 AC_C_INLINE
 326
 327 OPT_CFLAGS=
 328 dnl Check for some compiler flags that optimize our code.
 329 if test "x$GCC" = xyes; then
 330   AS_COMPILER_FLAG(-fno-common, OPT_CFLAGS="$OPT_CFLAGS -fno-common")
 331 fi
 332
 333 dnl FIXME: decide what kind of flag this is, maybe it's not an optimization
 334 dnl flag
 335 dnl check if we should use -Wa,-mregnames on PowerPC, so we can use
 336 dnl symbolic register names in inline asm
 337 if test x$HAVE_CPU_PPC = xyes ; then
 338   AS_COMPILER_FLAG(["-Wa,-mregnames"],
 339     [OPT_CFLAGS="$OPT_CFLAGS -Wa,-mregnames"])
 340 fi
 341
 342 dnl *** checks for library functions ***
 343
 344 AC_CHECK_FUNCS([sigaction])
 345
 346 dnl we use fork in the registry code
 347 AC_CHECK_FUNCS([fork])
 348
 349 dnl check for fseeko()
 350 AC_FUNC_FSEEKO
 351 dnl check for ftello()
 352 AC_CHECK_FUNCS([ftello])
 353
 354 AC_CHECK_FUNCS([fgetpos])
 355 AC_CHECK_FUNCS([fsetpos])
 356
 357 dnl check for mmap()
 358 AC_FUNC_MMAP
 359 AM_CONDITIONAL(HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 360
 361 dnl Check for a way to display the function name in debug output
 362 AG_GST_CHECK_FUNCTION
 363
 364 dnl test for register_printf_function
 365 AC_CHECK_FUNC(register_printf_function,
 366   [
 367     GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE="#define GST_PTR_FORMAT \"P\""
 368     GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE="#define GST_SEGMENT_FORMAT \"Q\""
 369     GST_USING_PRINTF_EXTENSION_DEFINE="#define GST_USING_PRINTF_EXTENSION"
 370     AC_DEFINE(HAVE_PRINTF_EXTENSION, 1,
 371       [Defined if we have register_printf_function ()])
 372   ], [
 373     GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE="#define GST_PTR_FORMAT \"p\""
 374     GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE="#define GST_SEGMENT_FORMAT \"p\""
 375     GST_USING_PRINTF_EXTENSION_DEFINE="#undef GST_USING_PRINTF_EXTENSION"
 376   ]
 377 )
 378 AC_SUBST(GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE)
 379 AC_SUBST(GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE)
 380 AC_SUBST(GST_USING_PRINTF_EXTENSION_DEFINE)
 381
 382 dnl test if we have dladdr(); we use it for debugging; see gst/gstinfo.c
 383 save_cflags="$CFLAGS"
 384 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 385 AC_CHECK_LIB(dl, dladdr,
 386    AC_DEFINE(HAVE_DLADDR, 1,
 387              [Defined if we have dladdr ()]))
 388 CFLAGS="$save_cflags"
 389
 390 dnl check for inet_aton()
 391 save_libs="$LIBS"
 392 AC_CHECK_FUNC(inet_aton, ,
 393    AC_CHECK_LIB(nsl, inet_aton, ,
 394       AC_CHECK_LIB(socket, inet_aton, ,
 395          AC_CHECK_LIB(resolv, inet_aton, ,[AC_DEFINE(NO_INET_ATON, 1, [Define if you have no native inet_aton() function.])]))))
 396 INET_ATON_LIBS=$LIBS
 397 AC_SUBST(INET_ATON_LIBS)
 398 LIBS="$save_libs"
 399
 400 dnl *** checks for dependency libraries ***
 401
 402 dnl GLib
 403
 404 AG_GST_GLIB_CHECK([2.8])
 405
 406 dnl FIXME: 0.11: Guess we need to keep this around until 0.11
 407 GST_HAVE_GLIB_2_8_DEFINE="#define GST_HAVE_GLIB_2_8 1"
 408 AC_SUBST(GST_HAVE_GLIB_2_8_DEFINE)
 409
 410 dnl Check for glib2 without extra fat, useful for the unversioned tool frontends
 411 PKG_CHECK_MODULES(GLIB_ONLY, glib-2.0 >= $GLIB_REQ)
 412
 413 dnl Check for documentation xrefs
 414 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 415 AC_SUBST(GLIB_PREFIX)
 416
 417 dnl libxml 2 is optional in some cases
 418 if test "x$GST_DISABLE_LOADSAVE" = "xyes" && \
 419    ( test "x$GST_DISABLE_REGISTRY" = "xyes" || \
 420    test "x$USE_BINARY_REGISTRY" = "xyes" )
 421 then
 422   AC_MSG_NOTICE([XML registry and load/save are disabled, not checking for libxml2])
 423   GST_DISABLE_XML_DEFINE="#define GST_DISABLE_XML 1"
 424 else
 425   dnl check for libxml2 with minimum req version
 426   AG_GST_LIBXML2_CHECK(2.4.9)
 427   GST_DISABLE_XML_DEFINE="/* #undef GST_DISABLE_XML */"
 428 fi
 429 AC_SUBST(GST_DISABLE_XML_DEFINE)
 430
 431 dnl check for "check", unit testing library/header
 432 AM_PATH_CHECK(0.9.2,
 433     [
 434         HAVE_CHECK=yes
 435         AC_MSG_NOTICE(CHECK_CFLAGS: $CHECK_CFLAGS)
 436         AC_MSG_NOTICE(CHECK_LIBS: $CHECK_LIBS)
 437     ],
 438     HAVE_CHECK=no)
 439 AM_CONDITIONAL(HAVE_CHECK, test "x$HAVE_CHECK" = "xyes")
 440
 441 dnl pkg-config check that for libcheck that works for cross-compiling
 442 dnl but not normal compilation on Fedora & Ubuntu:
 443 dnl PKG_CHECK_MODULES(CHECK, check >= 0.9.2,
 444 dnl   AM_CONDITIONAL(HAVE_CHECK, true),
 445 dnl   AM_CONDITIONAL(HAVE_CHECK, false)
 446 dnl )
 447
 448 dnl *** set variables based on configure arguments
 449
 450 dnl set license and copyright notice
 451 GST_LICENSE="LGPL"
 452 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 453 AC_SUBST(GST_LICENSE)
 454
 455 dnl define LIBDIR so we can inform people where we live
 456 AS_AC_EXPAND(LIBDIR, $libdir)
 457 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [library dir])
 458
 459 dnl set location of plugin directory
 460 AG_GST_SET_PLUGINDIR
 461
 462 dnl FIXME: add LIBXML_PKG here if we use it
 463 GST_PKG_DEPS="glib-2.0, gobject-2.0, gmodule-no-export-2.0, gthread-2.0"
 464 AC_SUBST(GST_PKG_DEPS)
 465
 466 dnl define an ERROR_CFLAGS Makefile variable
 467 AG_GST_SET_ERROR_CFLAGS($GST_CVS)
 468
 469 dnl define correct level for debugging messages
 470 AG_GST_SET_LEVEL_DEFAULT($GST_CVS)
 471
 472 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 473
 474 dnl Overview:
 475 dnl GST_OPTION_CFLAGS:  common cflags for profiling, debugging, errors, ...
 476 dnl GST_ALL_*:          vars shared by all built objects
 477 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 478 dnl GST_OBJ_*:          additional vars to link to the core library
 479 dnl                     include GST_ALL_*
 480 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 481 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 482
 483 dnl GST_OPTION_CFLAGS
 484 if test "x$USE_DEBUG" = xyes; then
 485    PROFILE_CFLAGS="-g"
 486 fi
 487 AC_SUBST(PROFILE_CFLAGS)
 488
 489 # GST_DISABLE_DEPRECATED: hide the visibility of deprecated
 490 # functionality from the API that gstreamer uses
 491 # GST_REMOVE_DEPRECATED: don't compile deprecated functionality (breaks ABI)
 492 DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 493 AC_SUBST(DEPRECATED_CFLAGS)
 494
 495 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time via e.g.
 496 dnl make DEPRECATED_CFLAGS=''
 497 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 498 AC_SUBST(GST_OPTION_CFLAGS)
 499
 500 dnl GST_ALL_*
 501 dnl vars common to for all internal objects (core libs, elements, applications)
 502 dnl CFLAGS:
 503 dnl - XML needs to be added because xmlPtr is used in core
 504 dnl - src and build dirs need to be added because every piece that gets built
 505 dnl   will need the GStreamer source and generated headers
 506 dnl LIBS: XML doesn't need to be added because we don't explicitly use symbols
 507 dnl       from LibXML except for in the core library
 508 GST_ALL_CFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir) $GLIB_CFLAGS $XML_CFLAGS \$(GST_OPTION_CFLAGS)"
 509
 510 dnl FIXME: check if LTLIBINTL is needed everywhere
 511 dnl I presume it is given that it contains the symbols that _() stuff maps to
 512 GST_ALL_LIBS="$GLIB_LIBS $LTLIBINTL \$(GCOV_LIBS)"
 513
 514 dnl LDFLAGS really should only contain flags, not libs - they get added before
 515 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 516 GST_ALL_LDFLAGS="-no-undefined"
 517
 518 AC_SUBST(GST_ALL_CFLAGS)
 519 AC_SUBST(GST_ALL_LIBS)
 520 AC_SUBST(GST_ALL_LDFLAGS)
 521
 522 dnl GST_LIB_LDFLAGS
 523 dnl linker flags shared by all libraries
 524 dnl LDFLAGS modifier defining exported symbols from built libraries
 525 GST_LIB_LDFLAGS="-export-symbols-regex \^[_]*\(gst_\|Gst\|GST_\).*"
 526 AC_SUBST(GST_LIB_LDFLAGS)
 527
 528 dnl GST_OBJ_*
 529 dnl default vars for all internal objects built on libgstreamer
 530 dnl includes GST_ALL_*
 531 GST_OBJ_CFLAGS="\$(GST_ALL_CFLAGS)"
 532 GST_OBJ_LIBS="\$(top_builddir)/gst/libgstreamer-$GST_MAJORMINOR.la \$(GST_ALL_LIBS)"
 533 AC_SUBST(GST_OBJ_CFLAGS)
 534 AC_SUBST(GST_OBJ_LIBS)
 535
 536 dnl GST_PLUGIN_LDFLAGS
 537 dnl LDFLAGS for plugins; includes GST_ALL_LDFLAGS
 538 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 539 AC_SUBST(GST_PLUGIN_LDFLAGS, "$GST_PLUGIN_LDFLAGS")
 540
 541 AC_CONFIG_FILES(
 542 Makefile
 543 gst/Makefile
 544 gst/gstconfig.h
 545 gst/gstversion.h
 546 gst/parse/Makefile
 547 libs/Makefile
 548 libs/gst/Makefile
 549 libs/gst/base/Makefile
 550 libs/gst/check/Makefile
 551 libs/gst/controller/Makefile
 552 libs/gst/dataprotocol/Makefile
 553 libs/gst/net/Makefile
 554 plugins/Makefile
 555 plugins/indexers/Makefile
 556 plugins/elements/Makefile
 557 po/Makefile.in
 558 tests/Makefile
 559 tests/benchmarks/Makefile
 560 tests/check/Makefile
 561 tests/misc/Makefile
 562 tests/examples/Makefile
 563 tests/examples/adapter/Makefile
 564 tests/examples/controller/Makefile
 565 tests/examples/helloworld/Makefile
 566 tests/examples/launch/Makefile
 567 tests/examples/manual/Makefile
 568 tests/examples/metadata/Makefile
 569 tests/examples/queue/Makefile
 570 tests/examples/typefind/Makefile
 571 tests/examples/xml/Makefile
 572 tools/Makefile
 573 common/Makefile
 574 common/m4/Makefile
 575 docs/Makefile
 576 docs/design/Makefile
 577 docs/faq/Makefile
 578 docs/gst/Makefile
 579 docs/gst/gstreamer.types
 580 docs/libs/Makefile
 581 docs/plugins/Makefile
 582 docs/manual/Makefile
 583 docs/pwg/Makefile
 584 docs/slides/Makefile
 585 docs/xsl/Makefile
 586 docs/version.entities
 587 win32/common/config.h
 588 pkgconfig/Makefile
 589 stamp.h
 590 pkgconfig/gstreamer.pc
 591 pkgconfig/gstreamer-uninstalled.pc
 592 pkgconfig/gstreamer-base.pc
 593 pkgconfig/gstreamer-base-uninstalled.pc
 594 pkgconfig/gstreamer-check.pc
 595 pkgconfig/gstreamer-check-uninstalled.pc
 596 pkgconfig/gstreamer-controller.pc
 597 pkgconfig/gstreamer-controller-uninstalled.pc
 598 pkgconfig/gstreamer-dataprotocol.pc
 599 pkgconfig/gstreamer-dataprotocol-uninstalled.pc
 600 pkgconfig/gstreamer-net.pc
 601 pkgconfig/gstreamer-net-uninstalled.pc
 602 gst-element-check.m4
 603 gstreamer.spec
 604 )
 605
 606 AC_OUTPUT