configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, cvs and prerelease does Werror too
   6 AC_INIT(GStreamer, 0.10.19.1,
   7     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
   8     gstreamer)
   9 AG_GST_INIT
  10
  11 dnl initialize automake
  12 AM_INIT_AUTOMAKE
  13
  14 dnl define PACKAGE_VERSION_* variables
  15 AS_VERSION
  16
  17 dnl check if this is a release version
  18 AS_NANO(GST_CVS="no", GST_CVS="yes")
  19
  20 dnl can autoconf find the source ?
  21 AC_CONFIG_SRCDIR([gst/gst.c])
  22
  23 dnl define the output header for config
  24 AM_CONFIG_HEADER([config.h])
  25
  26 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  27 AM_MAINTAINER_MODE
  28
  29 dnl sets host_* variables
  30 AC_CANONICAL_HOST
  31
  32 dnl our libraries and install dirs use major.minor as a version
  33 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  34 dnl we override it here for release candidates for a new series
  35 GST_MAJORMINOR=0.10
  36 AC_SUBST(GST_MAJORMINOR)
  37 AC_DEFINE_UNQUOTED(GST_MAJORMINOR, "$GST_MAJORMINOR",
  38   [library major.minor version])
  39
  40 dnl CURRENT, REVISION, AGE
  41 dnl - library source changed -> increment REVISION
  42 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  43 dnl - interfaces added -> increment AGE
  44 dnl - interfaces removed -> AGE = 0
  45 dnl sets GST_LT_LDFLAGS
  46 AS_LIBTOOL(GST, 16, 0, 16)
  47
  48 dnl FIXME: this macro doesn't actually work;
  49 dnl the generated libtool script has no support for the listed tags.
  50 dnl So this needs to be fixed first if we want to use this
  51 dnl AS_LIBTOOL_TAGS
  52
  53 AC_LIBTOOL_WIN32_DLL
  54 AM_PROG_LIBTOOL
  55
  56 dnl *** autotools stuff ****
  57
  58 dnl allow for different autotools
  59 AS_AUTOTOOLS_ALTERNATE
  60
  61 dnl Add parameters for aclocal
  62 AC_SUBST(ACLOCAL_AMFLAGS, "-I common/m4")
  63
  64 dnl set up gettext
  65 dnl the version check needs to stay here because autopoint greps for it
  66 AM_GNU_GETTEXT_VERSION([0.11.5])
  67 AM_GNU_GETTEXT([external])
  68 AG_GST_GETTEXT([gstreamer-$GST_MAJORMINOR])
  69
  70 dnl *** check for arguments to configure ***
  71
  72 dnl subsystems - can influence other decisions so needs to be high up
  73 dnl we need to AM_CONDITIONAL them here for automake 1.6.x compatibility
  74 AG_GST_CHECK_SUBSYSTEM_DISABLE(GST_DEBUG,[debugging subsystem])
  75 AM_CONDITIONAL(GST_DISABLE_GST_DEBUG, test "x$GST_DISABLE_GST_DEBUG" = "xyes")
  76 AG_GST_CHECK_SUBSYSTEM_DISABLE(LOADSAVE,[pipeline XML load/save])
  77 AM_CONDITIONAL(GST_DISABLE_LOADSAVE, test "x$GST_DISABLE_LOADSAVE" = "xyes")
  78 dnl define a substitution to use in docs/gst/gstreamer.types
  79 if test "x$GST_DISABLE_LOADSAVE" = "xyes"
  80 then
  81   GST_LOADSAVE_DOC_TYPES="%"
  82 else
  83   GST_LOADSAVE_DOC_TYPES=
  84 fi
  85 AC_SUBST(GST_LOADSAVE_DOC_TYPES)
  86 AG_GST_CHECK_SUBSYSTEM_DISABLE(PARSE,[command-line parser])
  87 AM_CONDITIONAL(GST_DISABLE_PARSE, test "x$GST_DISABLE_PARSE" = "xyes")
  88 if test "x$GST_DISABLE_PARSE" = xyes; then
  89   AC_DEFINE(GST_DISABLE_PARSE, 1,
  90     [Define if pipeline parsing code is disabled])
  91 fi
  92 AG_GST_CHECK_SUBSYSTEM_DISABLE(OPTION_PARSING,[option parsing when gst_init])
  93 AM_CONDITIONAL(GST_DISABLE_OPTION_PARSING, test "x$GST_DISABLE_OPTION_PARSING" = "xyes")
  94 if test "x$GST_DISABLE_OPTION_PARSING" = xyes; then
  95   AC_DEFINE(GST_DISABLE_OPTION_PARSING, 1,
  96     [Define if option parsing is disabled])
  97 fi
  98 AG_GST_CHECK_SUBSYSTEM_DISABLE(TRACE,[tracing subsystem])
  99 AM_CONDITIONAL(GST_DISABLE_TRACE, test "x$GST_DISABLE_TRACE" = "xyes")
 100 AG_GST_CHECK_SUBSYSTEM_DISABLE(ALLOC_TRACE,[allocation tracing])
 101 AM_CONDITIONAL(GST_DISABLE_ALLOC_TRACE, test "x$GST_DISABLE_ALLOC_TRACE" = "xyes")
 102 AG_GST_CHECK_SUBSYSTEM_DISABLE(REGISTRY,[plugin registry])
 103 AM_CONDITIONAL(GST_DISABLE_REGISTRY, test "x$GST_DISABLE_REGISTRY" = "xyes")
 104 dnl define a substitution to use in docs/gst/gstreamer.types
 105 if test "x$GST_DISABLE_REGISTRY" = "xyes"
 106 then
 107   GST_REGISTRY_DOC_TYPES="%"
 108 else
 109   GST_REGISTRY_DOC_TYPES=
 110 fi
 111 AC_SUBST(GST_REGISTRY_DOC_TYPES)
 112 AG_GST_CHECK_SUBSYSTEM_DISABLE(ENUMTYPES,[enum types])
 113 AM_CONDITIONAL(GST_DISABLE_ENUMTYPES, test "x$GST_DISABLE_ENUMTYPES" = "xyes")
 114 AG_GST_CHECK_SUBSYSTEM_DISABLE(INDEX,[index])
 115 AM_CONDITIONAL(GST_DISABLE_INDEX, test "x$GST_DISABLE_INDEX" = "xyes")
 116 dnl define a substitution to use in docs/gst/gstreamer.types
 117 if test "x$GST_DISABLE_INDEX" = "xyes"
 118 then
 119   GST_INDEX_DOC_TYPES="%"
 120 else
 121   GST_INDEX_DOC_TYPES=
 122 fi
 123 AC_SUBST(GST_INDEX_DOC_TYPES)
 124 AG_GST_CHECK_SUBSYSTEM_DISABLE(NET,[network distribution])
 125 AM_CONDITIONAL(GST_DISABLE_NET, test "x$GST_DISABLE_NET" = "xyes")
 126 AG_GST_CHECK_SUBSYSTEM_DISABLE(PLUGIN,[plugin])
 127 AM_CONDITIONAL(GST_DISABLE_PLUGIN, test "x$GST_DISABLE_PLUGIN" = "xyes")
 128 AG_GST_CHECK_SUBSYSTEM_DISABLE(URI,[uri handlers])
 129 AM_CONDITIONAL(GST_DISABLE_URI, test "x$GST_DISABLE_URI" = "xyes")
 130
 131 AG_GST_ARG_DEBUG
 132 AG_GST_ARG_PROFILING
 133 AG_GST_ARG_VALGRIND
 134 AG_GST_ARG_GCOV
 135
 136 AG_GST_ARG_EXAMPLES
 137
 138 AG_GST_ARG_WITH_PKG_CONFIG_PATH
 139 AG_GST_ARG_WITH_PACKAGE_NAME
 140 AG_GST_ARG_WITH_PACKAGE_ORIGIN
 141
 142 dnl building of tests
 143 AC_ARG_ENABLE(tests,
 144   AC_HELP_STRING([--disable-tests], [disable building test apps]),
 145   [
 146     case "${enableval}" in
 147       yes) BUILD_TESTS=yes ;;
 148       no)  BUILD_TESTS=no ;;
 149       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 150     esac
 151   ],
 152 [BUILD_TESTS=yes]) dnl Default value
 153 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 154
 155 dnl tests known to fail
 156 AC_ARG_ENABLE(failing-tests,
 157   AC_HELP_STRING([--disable-failing-tests],
 158     [disable building tests known to fail]),
 159   [
 160     case "${enableval}" in
 161       yes) BUILD_FAILING_TESTS=yes ;;
 162       no)  BUILD_FAILING_TESTS=no ;;
 163       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-failing-tests) ;;
 164     esac
 165   ],
 166   [BUILD_FAILING_TESTS=no]) dnl Default value
 167 AM_CONDITIONAL(BUILD_FAILING_TESTS, test "x$BUILD_FAILING_TESTS" = "xyes")
 168 if test x$BUILD_FAILING_TESTS = xyes; then
 169   AC_MSG_WARN([building tests known to fail, use --disable-failing-tests to disable])
 170 else
 171   AC_MSG_WARN([Sissy ! By asking to not build the tests known to fail, you hereby waive your right to customer support.  If you do not agree with this EULA, please press Ctrl-C before the next line is printed.  By allowing the next line to be printed, you expressly acknowledge your acceptance of this EULA.])
 172 fi
 173
 174 dnl poison destroyed objects
 175 AC_ARG_ENABLE(poisoning,
 176   AC_HELP_STRING([--enable-poisoning],
 177     [enable poisoning of deallocated objects]),
 178   [
 179     case "${enableval}" in
 180       yes) USE_POISONING=yes ;;
 181       no)  USE_POISONING=no ;;
 182       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-poisoning) ;;
 183     esac
 184   ],
 185   [USE_POISONING=no]) dnl Default value
 186 if test "x$USE_POISONING" = xyes; then
 187   AC_DEFINE(USE_POISONING, 1,
 188     [Define if we should poison deallocated memory])
 189 fi
 190
 191 dnl Use binary registry
 192 AC_ARG_ENABLE(binary-registry,
 193   AC_HELP_STRING([--enable-binary-registry],
 194     [enable experimental binary registry]),
 195   [
 196     case "${enableval}" in
 197       yes) USE_BINARY_REGISTRY=yes ;;
 198       no)  USE_BINARY_REGISTRY=no ;;
 199       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-binary-registry) ;;
 200     esac
 201   ],
 202   [USE_BINARY_REGISTRY=no]) dnl Default value
 203
 204 if test "x$USE_BINARY_REGISTRY" = xyes; then
 205   dnl for config.h:
 206   AC_DEFINE(USE_BINARY_REGISTRY, 1,
 207     [Define if we should use binary registry instead xml registry])
 208 fi
 209 AM_CONDITIONAL(USE_BINARY_REGISTRY, test "x$USE_BINARY_REGISTRY" = "xyes")
 210
 211 dnl *** checks for platform ***
 212
 213 dnl * hardware/architecture *
 214
 215 dnl common/m4/gst-arch.m4
 216 dnl check CPU type
 217 AG_GST_ARCH
 218 dnl substitution for win32/common/config.h
 219 HOST_CPU=$host_cpu
 220 AC_SUBST(HOST_CPU)
 221
 222 dnl common/m4/gst-arch.m4
 223 dnl check for unaligned access
 224 AG_GST_UNALIGNED_ACCESS
 225 dnl create a configure variable for gst/gstconfig.h
 226 if test x${as_cv_unaligned_access} = xyes ; then
 227   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 1"
 228 else
 229   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 0"
 230 fi
 231 AC_SUBST(GST_HAVE_UNALIGNED_ACCESS_DEFINE)
 232
 233 dnl check for platform specific settings
 234 case $host_os in
 235      rhapsody*)
 236         AC_DEFINE_UNQUOTED(GST_EXTRA_MODULE_SUFFIX, [".dylib"], [Extra platform specific plugin suffix])
 237         ;;
 238      darwin*)
 239         AC_DEFINE_UNQUOTED(GST_EXTRA_MODULE_SUFFIX, [".dylib"], [Extra platform specific plugin suffix])
 240         AC_DEFINE_UNQUOTED(GST_HAVE_UNSAFE_FORK, 1, [Defined when registry scanning through fork is unsafe])
 241         ;;
 242      cygwin* | mingw* | msvc* | mks*)
 243         dnl HAVE_WIN32 currently means "disable POSIXisms".
 244         AC_DEFINE_UNQUOTED(HAVE_WIN32, 1, [Defined if compiling for Windows])
 245         ;;
 246      *)
 247         ;;
 248 esac
 249
 250 dnl * software *
 251
 252 dnl check for large file support
 253 dnl affected plugins must include config.h
 254 AC_SYS_LARGEFILE
 255
 256 dnl *** checks for programs ***
 257
 258 dnl find a compiler
 259 AC_PROG_CC
 260
 261 dnl check if the compiler supports '-c' and '-o' options
 262 AM_PROG_CC_C_O
 263
 264 dnl find an assembler
 265 AM_PROG_AS
 266
 267 dnl Perl is used in building documentation and in the version checks
 268 AC_PATH_PROG(PERL_PATH, perl, no)
 269 if test x$PERL_PATH = xno; then
 270   AC_MSG_ERROR(Could not find perl)
 271 fi
 272
 273 dnl we require flex and bison for building the parser
 274 AG_GST_BISON_CHECK
 275 AG_GST_FLEX_CHECK
 276
 277 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 278 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 279
 280 dnl check for documentation tools
 281 AG_GST_DOCBOOK_CHECK
 282 GTK_DOC_CHECK([1.3])
 283 AS_PATH_PYTHON([2.1])
 284 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 285
 286 dnl *** checks for libraries ***
 287
 288 dnl For interactive UNIX (a Sun thing)
 289 dnl FIXME: this adds -lcposix to LIBS, but I doubt we use LIBS
 290 AC_ISC_POSIX
 291
 292 dnl check for libm, for sin()
 293 AC_CHECK_LIBM
 294 AC_SUBST(LIBM)
 295
 296 dnl *** checks for header files ***
 297
 298 dnl check if we have ANSI C header files
 299 AC_HEADER_STDC
 300
 301 dnl Check for ucontext.h
 302 AC_CHECK_HEADERS([ucontext.h])
 303
 304 dnl Check for sys/socket.h
 305 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 306 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 307
 308 dnl check for sys/times.h for tests/examples/adapter/
 309 AC_CHECK_HEADERS([sys/times.h], HAVE_SYS_TIMES_H=yes)
 310 AC_CHECK_HEADERS([unistd.h], HAVE_UNISTD_H=yes)
 311 AM_CONDITIONAL(HAVE_SYS_TIMES_H_AND_UNISTD_H, test "x$HAVE_SYS_TIMES_H" = "xyes" -a "x$HAVE_UNISTD_H" = "xyes")
 312
 313 dnl Check for process.h for getpid() on win32
 314 AC_CHECK_HEADERS([process.h])
 315
 316 dnl Check for sys/utsname.h for uname
 317 AC_CHECK_HEADERS([sys/utsname.h])
 318
 319 dnl Check for stdio_ext.f for __fbufsize
 320 AC_CHECK_HEADERS([stdio_ext.h])
 321
 322 dnl *** checks for types/defines ***
 323
 324 dnl *** checks for structures ***
 325
 326 dnl *** checks for compiler characteristics ***
 327
 328 dnl make sure we can use "inline" from C code
 329 AC_C_INLINE
 330
 331 OPT_CFLAGS=
 332 dnl Check for some compiler flags that optimize our code.
 333 if test "x$GCC" = xyes; then
 334   AS_COMPILER_FLAG(-fno-common, OPT_CFLAGS="$OPT_CFLAGS -fno-common")
 335 fi
 336
 337 dnl FIXME: decide what kind of flag this is, maybe it's not an optimization
 338 dnl flag
 339 dnl check if we should use -Wa,-mregnames on PowerPC, so we can use
 340 dnl symbolic register names in inline asm
 341 if test x$HAVE_CPU_PPC = xyes ; then
 342   AS_COMPILER_FLAG(["-Wa,-mregnames"],
 343     [OPT_CFLAGS="$OPT_CFLAGS -Wa,-mregnames"])
 344 fi
 345
 346 dnl *** checks for library functions ***
 347
 348 AC_CHECK_FUNCS([sigaction])
 349
 350 dnl we use fork in the registry code
 351 AC_CHECK_FUNCS([fork])
 352
 353 dnl check for fseeko()
 354 AC_FUNC_FSEEKO
 355 dnl check for ftello()
 356 AC_CHECK_FUNCS([ftello])
 357
 358 AC_CHECK_FUNCS([fgetpos])
 359 AC_CHECK_FUNCS([fsetpos])
 360
 361 dnl check for poll(), ppoll() and pselect()
 362 AC_CHECK_FUNCS([poll])
 363 AC_CHECK_FUNCS([ppoll])
 364 AC_CHECK_FUNCS([pselect])
 365
 366 dnl check for mmap()
 367 AC_FUNC_MMAP
 368 AM_CONDITIONAL(HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 369
 370 dnl Check for POSIX timers
 371 AC_CHECK_FUNCS(clock_gettime, [], [
 372   AC_CHECK_LIB(rt, clock_gettime, [
 373     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 374     LIBS="$LIBS -lrt"
 375   ])
 376 ])
 377
 378 AC_CACHE_CHECK(for posix timers, gst_cv_posix_timers,
 379     AC_TRY_COMPILE([
 380 #include <time.h>
 381 #ifdef HAVE_UNISTD_H
 382 #include <unistd.h>
 383 #endif
 384     ], [
 385 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 386 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 387 #endif
 388       return 0;
 389     ], [
 390       gst_cv_posix_timers=yes
 391     ], [
 392       gst_cv_posix_timers=no
 393     ])
 394 )
 395
 396 if test "$gst_cv_posix_timers" = "yes"; then
 397   AC_DEFINE(HAVE_POSIX_TIMERS,1,[Have posix timers])
 398   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 1"
 399 else
 400   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 0"
 401 fi
 402 AC_SUBST(GST_HAVE_POSIX_TIMERS_DEFINE)
 403 AM_CONDITIONAL(GST_HAVE_POSIX_TIMERS, test "$gst_cv_posix_timers" = "yes")
 404
 405 AC_CACHE_CHECK(for monotonic clock, gst_cv_monotonic_clock,
 406     AC_TRY_COMPILE([
 407 #include <time.h>
 408 #ifdef HAVE_UNISTD_H
 409 #include <unistd.h>
 410 #endif
 411     ], [
 412 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 413 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 414 #endif
 415       return 0;
 416     ], [
 417       gst_cv_monotonic_clock=yes
 418     ], [
 419       gst_cv_monotonic_clock=no
 420     ])
 421 )
 422
 423 if test "$gst_cv_monotonic_clock" = "yes"; then
 424   AC_DEFINE(HAVE_MONOTONIC_CLOCK,1,[Have a monotonic clock])
 425   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 1"
 426 else
 427   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 0"
 428 fi
 429 AC_SUBST(GST_HAVE_MONOTONIC_CLOCK_DEFINE)
 430 AM_CONDITIONAL(GST_HAVE_MONOTONIC_CLOCK, test "$gst_cv_monotonic_clock" = "yes")
 431
 432 dnl Check for a way to display the function name in debug output
 433 AG_GST_CHECK_FUNCTION
 434
 435 dnl test for register_printf_function
 436 AC_CHECK_FUNC(register_printf_function,
 437   [
 438     GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE="#define GST_PTR_FORMAT \"P\""
 439     GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE="#define GST_SEGMENT_FORMAT \"Q\""
 440     GST_USING_PRINTF_EXTENSION_DEFINE="#define GST_USING_PRINTF_EXTENSION"
 441     AC_DEFINE(HAVE_PRINTF_EXTENSION, 1,
 442       [Defined if we have register_printf_function ()])
 443   ], [
 444     GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE="#define GST_PTR_FORMAT \"p\""
 445     GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE="#define GST_SEGMENT_FORMAT \"p\""
 446     GST_USING_PRINTF_EXTENSION_DEFINE="#undef GST_USING_PRINTF_EXTENSION"
 447   ]
 448 )
 449 AC_SUBST(GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE)
 450 AC_SUBST(GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE)
 451 AC_SUBST(GST_USING_PRINTF_EXTENSION_DEFINE)
 452
 453 dnl test if we have dladdr(); we use it for debugging; see gst/gstinfo.c
 454 save_cflags="$CFLAGS"
 455 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 456 AC_CHECK_LIB(dl, dladdr,
 457    AC_DEFINE(HAVE_DLADDR, 1,
 458              [Defined if we have dladdr ()]))
 459 CFLAGS="$save_cflags"
 460
 461 dnl check for inet_aton()
 462 save_libs="$LIBS"
 463 AC_CHECK_FUNC(inet_aton, ,
 464    AC_CHECK_LIB(nsl, inet_aton, ,
 465       AC_CHECK_LIB(socket, inet_aton, ,
 466          AC_CHECK_LIB(resolv, inet_aton, ,[AC_DEFINE(NO_INET_ATON, 1, [Define if you have no native inet_aton() function.])]))))
 467 INET_ATON_LIBS=$LIBS
 468 AC_SUBST(INET_ATON_LIBS)
 469 LIBS="$save_libs"
 470
 471 dnl *** checks for dependency libraries ***
 472
 473 dnl GLib
 474 GLIB_REQ=2.12
 475
 476 AG_GST_GLIB_CHECK([$GLIB_REQ])
 477
 478 dnl FIXME: 0.11: Guess we need to keep this around until 0.11
 479 GST_HAVE_GLIB_2_8_DEFINE="#define GST_HAVE_GLIB_2_8 1"
 480 AC_SUBST(GST_HAVE_GLIB_2_8_DEFINE)
 481
 482 dnl Check for glib2 without extra fat, useful for the unversioned tool frontends
 483 PKG_CHECK_MODULES(GLIB_ONLY, glib-2.0 >= $GLIB_REQ)
 484
 485 dnl Check for documentation xrefs
 486 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 487 AC_SUBST(GLIB_PREFIX)
 488
 489 dnl libxml 2 is optional in some cases
 490 if test "x$GST_DISABLE_LOADSAVE" = "xyes" && \
 491    ( test "x$GST_DISABLE_REGISTRY" = "xyes" || \
 492    test "x$USE_BINARY_REGISTRY" = "xyes" )
 493 then
 494   AC_MSG_NOTICE([XML registry and load/save are disabled, not checking for libxml2])
 495   GST_DISABLE_XML_DEFINE="#define GST_DISABLE_XML 1"
 496 else
 497   dnl check for libxml2 with minimum req version
 498   AG_GST_LIBXML2_CHECK(2.4.9)
 499   GST_DISABLE_XML_DEFINE="/* #undef GST_DISABLE_XML */"
 500 fi
 501 AC_SUBST(GST_DISABLE_XML_DEFINE)
 502
 503 dnl check for "check", unit testing library/header
 504 AM_PATH_CHECK(0.9.2,
 505     [
 506         HAVE_CHECK=yes
 507         AC_MSG_NOTICE(CHECK_CFLAGS: $CHECK_CFLAGS)
 508         AC_MSG_NOTICE(CHECK_LIBS: $CHECK_LIBS)
 509     ],
 510     HAVE_CHECK=no)
 511 AM_CONDITIONAL(HAVE_CHECK, test "x$HAVE_CHECK" = "xyes")
 512
 513 dnl pkg-config check that for libcheck that works for cross-compiling
 514 dnl but not normal compilation on Fedora & Ubuntu:
 515 dnl PKG_CHECK_MODULES(CHECK, check >= 0.9.2,
 516 dnl   AM_CONDITIONAL(HAVE_CHECK, true),
 517 dnl   AM_CONDITIONAL(HAVE_CHECK, false)
 518 dnl )
 519
 520 dnl *** set variables based on configure arguments
 521
 522 dnl set license and copyright notice
 523 GST_LICENSE="LGPL"
 524 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 525 AC_SUBST(GST_LICENSE)
 526
 527 dnl define LIBDIR so we can inform people where we live
 528 AS_AC_EXPAND(LIBDIR, $libdir)
 529 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [library dir])
 530
 531 dnl set location of plugin directory
 532 AG_GST_SET_PLUGINDIR
 533
 534 dnl FIXME: add LIBXML_PKG here if we use it
 535 GST_PKG_DEPS="glib-2.0, gobject-2.0, gmodule-no-export-2.0, gthread-2.0"
 536 AC_SUBST(GST_PKG_DEPS)
 537
 538 dnl define an ERROR_CFLAGS Makefile variable
 539 AG_GST_SET_ERROR_CFLAGS($GST_CVS)
 540
 541 dnl define correct level for debugging messages
 542 AG_GST_SET_LEVEL_DEFAULT($GST_CVS)
 543
 544 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 545
 546 dnl Overview:
 547 dnl GST_OPTION_CFLAGS:  common cflags for profiling, debugging, errors, ...
 548 dnl GST_ALL_*:          vars shared by all built objects
 549 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 550 dnl GST_OBJ_*:          additional vars to link to the core library
 551 dnl                     include GST_ALL_*
 552 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 553 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 554
 555 dnl GST_OPTION_CFLAGS
 556 if test "x$USE_DEBUG" = xyes; then
 557    PROFILE_CFLAGS="-g"
 558 fi
 559 AC_SUBST(PROFILE_CFLAGS)
 560
 561 # GST_DISABLE_DEPRECATED: hide the visibility of deprecated
 562 # functionality from the API that gstreamer uses
 563 # GST_REMOVE_DEPRECATED: don't compile deprecated functionality (breaks ABI)
 564 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 565   dnl Define _only_ during CVS (not pre-releases or releases)
 566   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 567 else
 568   DEPRECATED_CFLAGS=""
 569 fi
 570 AC_SUBST(DEPRECATED_CFLAGS)
 571
 572 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time via e.g.
 573 dnl make DEPRECATED_CFLAGS=''
 574 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 575 AC_SUBST(GST_OPTION_CFLAGS)
 576
 577 dnl GST_ALL_*
 578 dnl vars common to for all internal objects (core libs, elements, applications)
 579 dnl CFLAGS:
 580 dnl - XML needs to be added because xmlPtr is used in core
 581 dnl - src and build dirs need to be added because every piece that gets built
 582 dnl   will need the GStreamer source and generated headers
 583 dnl LIBS: XML doesn't need to be added because we don't explicitly use symbols
 584 dnl       from LibXML except for in the core library
 585 GST_ALL_CFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir) $GLIB_CFLAGS $XML_CFLAGS \$(GST_OPTION_CFLAGS)"
 586
 587 dnl FIXME: check if LTLIBINTL is needed everywhere
 588 dnl I presume it is given that it contains the symbols that _() stuff maps to
 589 GST_ALL_LIBS="$GLIB_LIBS $LTLIBINTL \$(GCOV_LIBS)"
 590
 591 dnl LDFLAGS really should only contain flags, not libs - they get added before
 592 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 593 GST_ALL_LDFLAGS="-no-undefined"
 594
 595 AC_SUBST(GST_ALL_CFLAGS)
 596 AC_SUBST(GST_ALL_LIBS)
 597 AC_SUBST(GST_ALL_LDFLAGS)
 598
 599 dnl GST_LIB_LDFLAGS
 600 dnl linker flags shared by all libraries
 601 dnl LDFLAGS modifier defining exported symbols from built libraries
 602 GST_LIB_LDFLAGS="-export-symbols-regex \^[_]*\(gst_\|Gst\|GST_\).*"
 603 AC_SUBST(GST_LIB_LDFLAGS)
 604 dnl Version of the linker flags specifically for libgstcheck to support the boonky extra symbols it exports.
 605 GST_CHECK_LIB_LDFLAGS="-export-symbols-regex \^\([_]*\(gst_\|Gst\|GST_\).*\|check_\(debug\|mutex\|cond\)\|buffers\|mutex\|start_cond\|sync_cond\|thread_list\)$"
 606 dnl HACK: add non-portable --export-dynamic if we have GNU ld (needed on my debian stable, tpm)
 607 if test "x$ac_cv_prog_gnu_ld" = "xyes" -o "x$acl_cv_prog_gnu_ld" = "xyes" ; then
 608   GST_CHECK_LIB_LDFLAGS="-Wl,--export-dynamic $GST_CHECK_LIB_LDFLAGS"
 609 fi
 610 AC_SUBST(GST_CHECK_LIB_LDFLAGS)
 611
 612 dnl GST_OBJ_*
 613 dnl default vars for all internal objects built on libgstreamer
 614 dnl includes GST_ALL_*
 615 GST_OBJ_CFLAGS="\$(GST_ALL_CFLAGS)"
 616 GST_OBJ_LIBS="\$(top_builddir)/gst/libgstreamer-$GST_MAJORMINOR.la \$(GST_ALL_LIBS)"
 617 AC_SUBST(GST_OBJ_CFLAGS)
 618 AC_SUBST(GST_OBJ_LIBS)
 619
 620 dnl GST_PLUGIN_LDFLAGS
 621 dnl LDFLAGS for plugins; includes GST_ALL_LDFLAGS
 622 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 623 AC_SUBST(GST_PLUGIN_LDFLAGS, "$GST_PLUGIN_LDFLAGS")
 624
 625 AC_CONFIG_FILES(
 626 Makefile
 627 gst/Makefile
 628 gst/gstconfig.h
 629 gst/gstversion.h
 630 gst/parse/Makefile
 631 libs/Makefile
 632 libs/gst/Makefile
 633 libs/gst/base/Makefile
 634 libs/gst/check/Makefile
 635 libs/gst/controller/Makefile
 636 libs/gst/dataprotocol/Makefile
 637 libs/gst/net/Makefile
 638 plugins/Makefile
 639 plugins/indexers/Makefile
 640 plugins/elements/Makefile
 641 po/Makefile.in
 642 tests/Makefile
 643 tests/benchmarks/Makefile
 644 tests/check/Makefile
 645 tests/misc/Makefile
 646 tests/examples/Makefile
 647 tests/examples/adapter/Makefile
 648 tests/examples/controller/Makefile
 649 tests/examples/helloworld/Makefile
 650 tests/examples/launch/Makefile
 651 tests/examples/manual/Makefile
 652 tests/examples/metadata/Makefile
 653 tests/examples/queue/Makefile
 654 tests/examples/typefind/Makefile
 655 tests/examples/xml/Makefile
 656 tools/Makefile
 657 common/Makefile
 658 common/m4/Makefile
 659 docs/Makefile
 660 docs/design/Makefile
 661 docs/faq/Makefile
 662 docs/gst/Makefile
 663 docs/gst/gstreamer.types
 664 docs/libs/Makefile
 665 docs/plugins/Makefile
 666 docs/manual/Makefile
 667 docs/pwg/Makefile
 668 docs/slides/Makefile
 669 docs/xsl/Makefile
 670 docs/version.entities
 671 win32/common/config.h
 672 pkgconfig/Makefile
 673 stamp.h
 674 pkgconfig/gstreamer.pc
 675 pkgconfig/gstreamer-uninstalled.pc
 676 pkgconfig/gstreamer-base.pc
 677 pkgconfig/gstreamer-base-uninstalled.pc
 678 pkgconfig/gstreamer-check.pc
 679 pkgconfig/gstreamer-check-uninstalled.pc
 680 pkgconfig/gstreamer-controller.pc
 681 pkgconfig/gstreamer-controller-uninstalled.pc
 682 pkgconfig/gstreamer-dataprotocol.pc
 683 pkgconfig/gstreamer-dataprotocol-uninstalled.pc
 684 pkgconfig/gstreamer-net.pc
 685 pkgconfig/gstreamer-net-uninstalled.pc
 686 gst-element-check.m4
 687 gstreamer.spec
 688 )
 689
 690 AC_OUTPUT