configure.ac

   1 AC_PREREQ(2.62)
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, cvs and prerelease does Werror too
   6 AC_INIT(GStreamer Editing Services, 1.17.0.1,
   7     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
   8     gstreamer-editing-services)
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.11 no-dist-gzip dist-xz tar-ustar subdir-objects])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([ges/ges-timeline.c])
  23
  24 dnl define the output header for config
  25 AC_CONFIG_HEADERS([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output with automake >= 1.11
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  35  [AM_DEFAULT_VERBOSITY=1
  36  AC_SUBST(AM_DEFAULT_VERBOSITY)])
  37
  38 dnl GES versioning, this is mostly informational
  39 GES_VERSION_MAJOR=$PACKAGE_VERSION_MAJOR
  40 GES_VERSION_MINOR=$PACKAGE_VERSION_MINOR
  41 GES_VERSION_MICRO=$PACKAGE_VERSION_MICRO
  42 GES_VERSION_NANO=$PACKAGE_VERSION_NANO
  43 AC_SUBST(GES_VERSION_MAJOR)
  44 AC_SUBST(GES_VERSION_MINOR)
  45 AC_SUBST(GES_VERSION_MICRO)
  46 AC_SUBST(GES_VERSION_NANO)
  47
  48 dnl our libraries and install dirs use major.minor as a version
  49 GST_API_VERSION=$GST_EDITING_SERVICES_VERSION_MAJOR.$GST_EDITING_SERVICES_VERSION_MINOR
  50 dnl we override it here if we need to for the release candidate of new series
  51 GST_API_VERSION=1.0
  52 AC_SUBST(GST_API_VERSION)
  53
  54 AS_LIBTOOL(GST, 1700, 0, 1700)
  55
  56 dnl *** required versions of GStreamer stuff ***
  57 GST_REQ=1.17.0.1
  58 GSTPB_REQ=1.17.0.1
  59
  60 dnl *** autotools stuff ****
  61
  62 dnl allow for different autotools
  63 AS_AUTOTOOLS_ALTERNATE
  64
  65 dnl Add parameters for aclocal
  66 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  67 AC_CONFIG_MACRO_DIR([m4])
  68
  69 dnl *** check for arguments to configure ***
  70
  71 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  72 AG_GST_ARG_ENABLE_EXTRA_CHECKS
  73
  74 AG_GST_ARG_DEBUG
  75 AG_GST_ARG_PROFILING
  76 AG_GST_ARG_VALGRIND
  77 AG_GST_ARG_GCOV
  78
  79 AG_GST_ARG_EXAMPLES
  80
  81 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  82 AG_GST_ARG_WITH_PACKAGE_NAME
  83 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  84
  85 AG_GST_PKG_CONFIG_PATH
  86
  87 AG_GST_FLEX_CHECK
  88
  89 dnl *** checks for platform ***
  90
  91 dnl * hardware/architecture *
  92
  93 dnl common/m4/gst-arch.m4
  94 dnl check CPU type
  95 AG_GST_ARCH
  96
  97 dnl Determine endianness
  98 AC_C_BIGENDIAN
  99
 100 dnl *** checks for programs ***
 101
 102 dnl find a compiler
 103 AC_PROG_CC
 104
 105 dnl check if the compiler supports '-c' and '-o' options
 106 AM_PROG_CC_C_O
 107
 108 dnl check if the compiler supports do while(0) macros
 109 AG_GST_CHECK_DOWHILE_MACROS
 110
 111 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 112 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 113
 114 dnl check for gobject-introspection
 115 GOBJECT_INTROSPECTION_CHECK([0.9.6])
 116
 117 dnl check for pygobject
 118 AC_SUBST(PYGOBJECT_REQ, 3.0)
 119 PKG_CHECK_MODULES(PYGOBJECT, pygobject-3.0 >= $PYGOBJECT_REQ,
 120   [
 121     HAVE_PYGOBJECT=yes
 122   ], HAVE_PYGOBJECT=no)
 123
 124 AM_CONDITIONAL(WITH_PYTHON, [test "x$HAVE_PYGOBJECT" = "xyes"])
 125
 126 dnl check for gst-validate
 127 PKG_CHECK_MODULES(GST_VALIDATE, gst-validate-1.0 >= 1.12.1,
 128   [
 129     HAVE_GST_VALIDATE=yes
 130     AC_DEFINE(HAVE_GST_VALIDATE, 1, [Define if build with gst-validate support])
 131   ], HAVE_GST_VALIDATE=no)
 132
 133 AC_SUBST(GST_VALIDATE_CFLAGS)
 134 AC_SUBST(GST_VALIDATE_LIBS)
 135 AM_CONDITIONAL(HAVE_GST_VALIDATE, [test "x$HAVE_GST_VALIDATE" = "xyes"])
 136
 137 dnl needed for scenarios definition files
 138 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 139 AC_SUBST(GST_PREFIX)
 140 GST_DATADIR="$GST_PREFIX/share"
 141 AC_DEFINE_UNQUOTED(GST_DATADIR, "$GST_DATADIR", [system wide data directory])
 142
 143 dnl check for bash completion
 144 AC_ARG_WITH([bash-completion-dir],
 145     AS_HELP_STRING([--with-bash-completion-dir[=PATH]],
 146         [Install the bash auto-completion script in this directory. @<:@default=yes@:>@]),
 147     [],
 148     [with_bash_completion_dir=yes])
 149
 150 if test "x$with_bash_completion_dir" = "xyes"; then
 151     PKG_CHECK_MODULES([BASH_COMPLETION], [bash-completion >= 2.0],
 152         [BASH_COMPLETION_DIR="`pkg-config --variable=completionsdir bash-completion`"],
 153         [BASH_COMPLETION_DIR="$datadir/bash-completion/completions"])
 154 else
 155     BASH_COMPLETION_DIR="$with_bash_completion_dir"
 156 fi
 157
 158 AC_SUBST([BASH_COMPLETION_DIR])
 159 AM_CONDITIONAL([ENABLE_BASH_COMPLETION],[test "x$with_bash_completion_dir" != "xno"])
 160
 161 dnl *** checks for libraries ***
 162
 163 dnl check for libm, for sin() etc.
 164 # LT_LIB_M
 165 # AC_SUBST(LIBM)
 166
 167 dnl *** checks for header files ***
 168
 169 AC_CHECK_HEADERS([unistd.h], HAVE_UNISTD_H=yes)
 170 AM_CONDITIONAL(HAVE_UNISTD_H, test "x$HAVE_UNISTD_H" = "xyes")
 171
 172 if test "x$HAVE_UNISTD_H" != "xyes"; then
 173   GST_PLUGINS_SELECTED=`echo $GST_PLUGINS_SELECTED | $SED -e s/festival//`
 174 fi
 175
 176 dnl *** checks for gst-validate-launcher ***
 177
 178 AC_CHECK_PROG(GST_VALIDATE_LAUNCHER, gst-validate-launcher, yes)
 179 AM_CONDITIONAL(HAVE_GST_VALIDATE_LAUNCHER, [test "x$GST_VALIDATE_LAUNCHER" = "xyes"])
 180
 181 dnl *** checks for types/defines ***
 182
 183 dnl *** checks for structures ***
 184
 185 dnl *** checks for compiler characteristics ***
 186
 187 dnl *** checks for library functions ***
 188
 189 dnl *** checks for headers ***
 190
 191 dnl *** checks for dependency libraries ***
 192
 193 dnl GLib is required
 194 AG_GST_GLIB_CHECK([2.40.0])
 195
 196 PKG_CHECK_MODULES(GIO, gio-2.0 >= 2.16, HAVE_GIO=yes, HAVE_GIO=no)
 197 AC_SUBST(GIO_CFLAGS)
 198 AC_SUBST(GIO_LIBS)
 199
 200 dnl checks for gstreamer
 201 dnl uninstalled is selected preferentially -- see pkg-config(1)
 202 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 203 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 204 #AG_GST_CHECK_GST_GDP($GST_API_VERSION, [$GST_REQ], yes)
 205 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 206 AG_GST_CHECK_GST_CONTROLLER($GST_API_VERSION, [$GST_REQ], yes)
 207 AG_GST_CHECK_GST_PLUGINS_BASE($GST_API_VERSION, [$GSTPB_REQ], yes)
 208 AG_GST_CHECK_GST_PLUGINS_BAD($GST_API_VERSION, [$GST_REQ], yes)
 209 AG_GST_CHECK_GST_PLUGINS_GOOD($GST_API_VERSION, [$GST_REQ], yes)
 210 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 211
 212 AG_GST_ARG_WITH_PLUGINS
 213 AG_GST_CHECK_PLUGIN(plugins)
 214
 215 dnl set location of plugin directory
 216 AG_GST_SET_PLUGINDIR
 217
 218 GSTPB_PLUGINS_DIR=`$PKG_CONFIG gstreamer-plugins-base-$GST_API_VERSION --variable pluginsdir`
 219 AC_SUBST(GSTPB_PLUGINS_DIR)
 220 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 221
 222 dnl check for gstreamer-pbutils
 223 PKG_CHECK_MODULES(GST_PBUTILS, gstreamer-pbutils-$GST_API_VERSION, HAVE_GST_PBUTILS="yes", HAVE_GST_PBUTILS="no")
 224 if test "x$HAVE_GST_PBUTILS" != "xyes"; then
 225   AC_ERROR([gst-pbutils is required for rendering support])
 226 fi
 227 AC_SUBST(GST_PBUTILS_LIBS)
 228 AC_SUBST(GST_PBUTILS_CFLAGS)
 229
 230 dnl check for gst-controller
 231 PKG_CHECK_MODULES(GST_CONTROLLER, gstreamer-controller-$GST_API_VERSION, HAVE_GST_CONTROLLER="yes", HAVE_GST_CONROLLER="no")
 232 if test "x$HAVE_GST_CONTROLLER" != "xyes"; then
 233   AC_ERROR([gst-controller is required for transition support])
 234 fi
 235 AC_SUBST(GST_CONTROLLER_LIBS)
 236 AC_SUBST(GST_CONTROLLER_CFLAGS)
 237
 238 dnl check for gstvideo
 239 PKG_CHECK_MODULES(GST_VIDEO, gstreamer-video-$GST_API_VERSION, HAVE_GST_VIDEO="yes", HAVE_GST_CONROLLER="no")
 240 if test "x$HAVE_GST_VIDEO" != "xyes"; then
 241   AC_ERROR([gst-video is required for transition support])
 242 fi
 243 AC_SUBST(GST_VIDEO_LIBS)
 244 AC_SUBST(GST_VIDEO_CFLAGS)
 245
 246 dnl Check for documentation xrefs
 247 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 248 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 249 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_API_VERSION`"
 250 AC_SUBST(GLIB_PREFIX)
 251 AC_SUBST(GST_PREFIX)
 252 AC_SUBST(GSTPB_PREFIX)
 253
 254 dnl pitivi formatter needs libxml
 255 PKG_CHECK_MODULES(XML, libxml-2.0, HAVE_LIBXML="yes", HAVE_LIBXML="no")
 256 if test "x$HAVE_LIBXML" != "xyes"; then
 257   AC_ERROR([libxml2 is required])
 258 fi
 259 AC_SUBST(XML_LIBS)
 260 AC_SUBST(XML_CFLAGS)
 261
 262 dnl GTK is optional and only used in examples
 263 HAVE_GTK=no
 264 HAVE_GTK_X11=no
 265 GTK_REQ=3.0.0
 266 if test "x$BUILD_EXAMPLES" = "xyes"; then
 267   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 268   dnl some examples need gtk+-x11
 269   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 270   AC_SUBST(GTK_LIBS)
 271   AC_SUBST(GTK_CFLAGS)
 272 fi
 273 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 274 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 275
 276 dnl Check for -Bsymbolic-functions linker flag used to avoid
 277 dnl intra-library PLT jumps, if available.
 278 AC_ARG_ENABLE(Bsymbolic,
 279               [AS_HELP_STRING([--disable-Bsymbolic],[avoid linking with -Bsymbolic])],,
 280               [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
 281                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 282                LDFLAGS=-Wl,-Bsymbolic-functions
 283                LIBS=
 284                AC_TRY_LINK([], [return 0],
 285                            AC_MSG_RESULT(yes)
 286                            enable_Bsymbolic=yes,
 287                            AC_MSG_RESULT(no)
 288                            enable_Bsymbolic=no)
 289                LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
 290
 291 dnl building of benchmarks
 292 AC_ARG_ENABLE(benchmarks,
 293   AS_HELP_STRING([--disable-benchmarks],[disable building benchmarks apps]),
 294   [
 295     case "${enableval}" in
 296       yes) BUILD_BENCHMARKS=yes ;;
 297       no)  BUILD_BENCHMARKS=no ;;
 298       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-benchmarks) ;;
 299     esac
 300   ],
 301 [BUILD_BENCHMARKS=yes]) dnl Default value
 302 AM_CONDITIONAL(BUILD_BENCHMARKS, test "x$BUILD_BENCHMARKS" = "xyes")
 303
 304 dnl set license and copyright notice
 305 GST_LICENSE="LGPL"
 306 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 307 AC_SUBST(GST_LICENSE)
 308
 309 dnl define LIBDIR so we can inform people where we live
 310 AS_AC_EXPAND(LIBDIR, $libdir)
 311 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [library dir])
 312
 313 dnl set location of plugin directory
 314 AG_GST_SET_PLUGINDIR
 315
 316 dnl define an ERROR_CFLAGS Makefile variable
 317 AG_GST_SET_ERROR_CFLAGS($GST_GIT, [-Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef \
 318                                    -Wwrite-strings -Wformat-security -Wold-style-definition \
 319                                    -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return -Wno-multichar \
 320                                    -Wnested-externs])
 321
 322 dnl define correct level for debugging messages
 323 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 324
 325 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 326
 327 dnl Overview:
 328 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 329 dnl GST_*:              flags shared by built objects to link against GStreamer
 330 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 331 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 332 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 333 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 334
 335 dnl GST_OPTION_CFLAGS
 336 if test "x$USE_DEBUG" = xyes; then
 337    PROFILE_CFLAGS="-g"
 338 fi
 339 AC_SUBST(PROFILE_CFLAGS)
 340
 341 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 342   dnl Define _only_ during CVS (not pre-releases or releases)
 343   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 344 else
 345   DEPRECATED_CFLAGS=""
 346 fi
 347 AC_SUBST(DEPRECATED_CFLAGS)
 348
 349 VISIBILITY_CFLAGS=""
 350 AS_COMPILER_FLAG([-fvisibility=hidden], [
 351   VISIBILITY_CFLAGS="-fvisibility=hidden"
 352   AC_DEFINE(GST_API_EXPORT, [extern __attribute__ ((visibility ("default")))], [public symbol export define])
 353 ], [
 354   VISIBILITY_CFLAGS=""
 355   AC_DEFINE(GST_API_EXPORT, [extern], [public symbol export define])
 356 ])
 357 AC_SUBST(VISIBILITY_CFLAGS)
 358
 359 dnl disable strict aliasing
 360 AS_COMPILER_FLAG([-fno-strict-aliasing], [EXTRA_CFLAGS="-fno-strict-aliasing"])
 361 AC_SUBST(EXTRA_CFLAGS)
 362
 363 dnl every flag in GST_OPTION_CFLAGS can be overridden
 364 dnl at make time with e.g. make ERROR_CFLAGS=""
 365 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 366 AC_SUBST(GST_OPTION_CFLAGS)
 367
 368 dnl FIXME: do we want to rename to GST_ALL_* ?
 369 dnl prefer internal headers to already installed ones
 370 dnl also add builddir include for enumtypes and marshal
 371 dnl add GST_OPTION_CFLAGS, but overridable
 372 GST_CFLAGS="$GST_CFLAGS $EXTRA_CFLAGS \$(GST_OPTION_CFLAGS) \$(ERROR_CFLAGS) \$(VISIBILITY_CFLAGS) -DGST_USE_UNSTABLE_API"
 373 AC_SUBST(GST_CFLAGS)
 374 AC_SUBST(GST_LIBS)
 375
 376 dnl LDFLAGS really should only contain flags, not libs - they get added before
 377 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 378 GST_ALL_LDFLAGS="-no-undefined"
 379 if test "x${enable_Bsymbolic}" = "xyes"; then
 380   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 381 fi
 382 AC_SUBST(GST_ALL_LDFLAGS)
 383
 384 dnl GST_LIB_LDFLAGS
 385 dnl linker flags shared by all libraries
 386 dnl LDFLAGS modifier defining exported symbols from built libraries
 387 GST_LIB_LDFLAGS=""
 388 AC_SUBST(GST_LIB_LDFLAGS)
 389
 390 dnl GST_PLUGIN_LDFLAGS must only contain flags, not libs - they get added before
 391 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 392 GST_PLUGIN_LDFLAGS="-module -avoid-version $GST_ALL_LDFLAGS"
 393 AC_SUBST(GST_PLUGIN_LDFLAGS)
 394
 395 dnl *** output files ***
 396
 397 dnl po/Makefile.in
 398
 399 AC_CONFIG_FILES(
 400 Makefile
 401 ges/ges-version.h
 402 common/Makefile
 403 common/m4/Makefile
 404 m4/Makefile
 405 ges/Makefile
 406 tests/Makefile
 407 tests/check/Makefile
 408 tests/benchmarks/Makefile
 409 examples/Makefile
 410 examples/c/Makefile
 411 tests/validate/Makefile
 412 tests/validate/scenarios/Makefile
 413 tools/Makefile
 414 pkgconfig/Makefile
 415 pkgconfig/gst-editing-services.pc
 416 pkgconfig/gst-editing-services-uninstalled.pc
 417 plugins/Makefile
 418 plugins/ges/Makefile
 419 plugins/nle/Makefile
 420 bindings/Makefile
 421 bindings/python/Makefile
 422 bindings/python/gi/Makefile
 423 bindings/python/gi/overrides/Makefile
 424 )
 425 AC_OUTPUT