configure.ac

   1 AC_PREREQ(2.60)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/prerelease
   8 AC_INIT(GStreamer Base Plug-ins, 0.10.35.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-base)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability 1.10])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use major.minor as a version
  41 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  42 dnl we override it here if we need to for the release candidate of new series
  43 GST_MAJORMINOR=0.10
  44 AC_SUBST(GST_MAJORMINOR)
  45
  46 dnl CURRENT, REVISION, AGE
  47 dnl - library source changed -> increment REVISION
  48 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  49 dnl - interfaces added -> increment AGE
  50 dnl - interfaces removed -> AGE = 0
  51 dnl sets GST_LT_LDFLAGS
  52 AS_LIBTOOL(GST, 24, 0, 24)
  53
  54 dnl FIXME: this macro doesn't actually work;
  55 dnl the generated libtool script has no support for the listed tags.
  56 dnl So this needs to be fixed first if we want to use this
  57 dnl AS_LIBTOOL_TAGS
  58
  59 AC_LIBTOOL_WIN32_DLL
  60 AM_PROG_LIBTOOL
  61
  62 dnl *** required versions of GStreamer stuff ***
  63 GST_REQ=0.10.35.1
  64
  65 dnl *** autotools stuff ****
  66
  67 dnl allow for different autotools
  68 AS_AUTOTOOLS_ALTERNATE
  69
  70 dnl Add parameters for aclocal
  71 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  72
  73 dnl set up gettext
  74 dnl the version check needs to stay here because autopoint greps for it
  75 AM_GNU_GETTEXT_VERSION([0.17])
  76 AM_GNU_GETTEXT([external])
  77 AG_GST_GETTEXT([gst-plugins-base-$GST_MAJORMINOR])
  78
  79 dnl *** check for arguments to configure ***
  80
  81 AG_GST_ARG_DEBUG
  82 AG_GST_ARG_PROFILING
  83 AG_GST_ARG_VALGRIND
  84 AG_GST_ARG_GCOV
  85
  86 AG_GST_ARG_EXAMPLES
  87
  88 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  89 AG_GST_ARG_WITH_PACKAGE_NAME
  90 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  91
  92 AG_GST_PKG_CONFIG_PATH
  93
  94 dnl let distro override plugin install helper path
  95 AC_ARG_WITH(install-plugins-helper,
  96   AC_HELP_STRING([--with-install-plugins-helper],
  97     [specify path of helper script to call to install plugins]),
  98   [
  99     case "${withval}" in
 100       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 101       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 102       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
 103     esac
 104   ],
 105   [
 106     dnl Default value
 107     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 108   ]
 109 )
 110 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 111 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 112     [plugin install helper script])
 113 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 114
 115 AG_GST_ARG_WITH_PLUGINS
 116
 117 AG_GST_ARG_ENABLE_EXTERNAL
 118
 119 AG_GST_ARG_ENABLE_EXPERIMENTAL
 120
 121 dnl *** checks for platform ***
 122
 123 dnl * hardware/architecture *
 124
 125 dnl common/m4/gst-arch.m4
 126 dnl check CPU type
 127 AG_GST_ARCH
 128
 129 dnl check for large file support
 130 dnl affected plugins must include config.h
 131 AC_SYS_LARGEFILE
 132
 133 dnl *** checks for programs ***
 134
 135 dnl find a compiler
 136 AC_PROG_CC
 137 AC_PROG_CC_STDC
 138
 139 dnl check if the compiler supports '-c' and '-o' options
 140 AM_PROG_CC_C_O
 141
 142 dnl determine if c++ is available on this system
 143 AC_PROG_CXX
 144 dnl CXX may be set to some default even if no c++ compiler is available
 145 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 146 AC_LANG_PUSH([C++])
 147 AC_TRY_COMPILE([ class Foo { int bar; };], , working_cxx=yes, working_cxx=no)
 148 AC_LANG_POP([C++])
 149 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 150 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 151
 152 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 153 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 154
 155 dnl check for gobject-introspection
 156 GOBJECT_INTROSPECTION_CHECK([0.9.12])
 157
 158 dnl check for documentation tools
 159 GTK_DOC_CHECK([1.3])
 160 AS_PATH_PYTHON([2.1])
 161 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 162
 163 dnl *** checks for libraries ***
 164
 165 dnl libm, for sin() etc.
 166 AC_CHECK_LIBM
 167 AC_SUBST(LIBM)
 168
 169 dnl *** checks for header files ***
 170
 171 dnl check if we have ANSI C header files
 172 AC_HEADER_STDC
 173
 174 dnl used in gst/ffmpegcolorspace/mem.c
 175 dnl FIXME: could be fixed by redefining av_malloc and av_free to GLib's
 176 AC_CHECK_HEADERS([malloc.h])
 177
 178 ac_cppflags_save="$CPPFLAGS"
 179 CPPFLAGS="`$PKG_CONFIG --cflags libxml-2.0`"
 180 AC_COMPILE_IFELSE(
 181   AC_LANG_PROGRAM([
 182 #include <libxml/HTMLparser.h>
 183                      ],[
 184 #ifndef LIBXML_HTML_ENABLED
 185 #error libxml2 has no HTML support
 186 #endif /* LIBXML_HTML_ENABLED */
 187                    ]), HAVE_LIBXML_HTML="yes", HAVE_LIBXML_HTML="no")
 188 CPPFLAGS="$ac_cppflags_save"
 189 AM_CONDITIONAL(HAVE_LIBXML_HTML, test "x$HAVE_LIBXML_HTML" = "xyes")
 190
 191 dnl used in gst/tcp
 192 AC_CHECK_HEADERS([sys/socket.h],
 193   HAVE_SYS_SOCKET_H="yes", HAVE_SYS_SOCKET_H="no")
 194 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 195
 196 dnl used in gst-libs/gst/rtsp
 197 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 198 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 199   WIN32_LIBS="-lws2_32"
 200   AC_SUBST(WIN32_LIBS)
 201 fi
 202
 203 dnl check for hstrerror, for gst-libs/gst/rtsp
 204 save_libs="$LIBS"
 205 AC_CHECK_FUNC(hstrerror, ,
 206     AC_CHECK_LIB(resolv, hstrerror, ,
 207         [AC_DEFINE(NO_HSTRERROR, 1,
 208              [Define if you have no native hstrerror() function.])]))
 209 HSTRERROR_LIBS=$LIBS
 210 AC_SUBST(HSTRERROR_LIBS)
 211 LIBS="$save_libs"
 212
 213 dnl used in gst-libs/gst/pbutils and associated unit test
 214 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h])
 215
 216 AC_CHECK_HEADERS([xmmintrin.h emmintrin.h])
 217
 218 dnl ffmpegcolorspace includes _stdint.h
 219 dnl also, Windows does not have long long
 220 AX_CREATE_STDINT_H
 221
 222 dnl *** checks for functions ***
 223 AC_CHECK_FUNCS([localtime_r gmtime_r])
 224
 225 dnl *** checks for math functions ***
 226 LIBS_SAVE=$LIBS
 227 LIBS="$LIBS $LIBM"
 228 AC_CHECK_FUNCS(log2)
 229 LIBS=$LIBS_SAVE
 230
 231 dnl *** checks for types/defines ***
 232
 233 dnl Check for FIONREAD ioctl declaration
 234 dnl used in gst/tcp
 235 GST_CHECK_FIONREAD
 236
 237 dnl *** checks for structures ***
 238
 239 dnl *** checks for compiler characteristics ***
 240
 241 dnl *** checks for library functions ***
 242
 243 dnl check for fseeko()
 244 AC_FUNC_FSEEKO
 245
 246 dnl Check for fast float to int casting as defined in C99
 247 dnl used in gst-libs/gst/floatcast/floatcast.h
 248 save_libs=$LIBS
 249 LIBS="$LIBS $LIBM"
 250 AC_C99_FUNC_LRINT
 251 AC_C99_FUNC_LRINTF
 252 LIBS=$save_libs
 253
 254 dnl Check for a way to display the function name in debug output
 255 AG_GST_CHECK_FUNCTION
 256
 257 dnl *** checks for socket and nsl libraries ***
 258 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 259 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
 260
 261 dnl *** checks for dependency libraries ***
 262
 263 dnl GLib is required
 264 AG_GST_GLIB_CHECK([2.24])
 265
 266 ORC_CHECK([0.4.11])
 267
 268 dnl checks for gstreamer
 269 dnl uninstalled is selected preferentially -- see pkg-config(1)
 270 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 271 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 272 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ], yes)
 273 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 274 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 275 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 276
 277 dnl Check for documentation xrefs
 278 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 279 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 280 AC_SUBST(GLIB_PREFIX)
 281 AC_SUBST(GST_PREFIX)
 282
 283 dnl GTK is optional and only used in examples
 284 HAVE_GTK=no
 285 HAVE_GTK_X11=no
 286 GTK_REQ=3.0.0
 287 if test "x$BUILD_EXAMPLES" = "xyes"; then
 288   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 289   dnl some examples need gtk+-x11
 290   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 291   AC_SUBST(GTK_LIBS)
 292   AC_SUBST(GTK_CFLAGS)
 293 fi
 294 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 295 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 296
 297 dnl QT is optional and only used in examples
 298 PKG_CHECK_MODULES(QT, QtGui >= 4.6, [
 299   HAVE_QT_GV=yes
 300   HAVE_QT=yes
 301 ], [
 302   HAVE_QT_GV=no
 303   PKG_CHECK_MODULES(QT, QtGui >= 4.0, HAVE_QT=yes, HAVE_QT=no)
 304 ])
 305 if test "x$HAVE_QT" = "xyes"; then
 306   AC_MSG_CHECKING([Qt moc])
 307   QT4_MOC=`$PKG_CONFIG --variable=moc_location QtGui`
 308   AC_MSG_RESULT($QT4_MOC)
 309   AC_SUBST(QT4_MOC)
 310 fi
 311 AM_CONDITIONAL(HAVE_QT, test "x$HAVE_QT" = "xyes")
 312 AM_CONDITIONAL(HAVE_QT_GV, test "x$HAVE_QT_GV" = "xyes")
 313
 314 dnl chck for linux headers needed by the joystick seek example
 315 AC_COMPILE_IFELSE(
 316 [
 317   AC_LANG_PROGRAM([
 318     #include <linux/input.h>
 319     #include <linux/joystick.h>
 320   ],[
 321     struct js_event js;
 322     js.type = JS_EVENT_AXIS;
 323   ])
 324 ], [
 325   HAVE_LINUX_JOYSTICK_HEADERS="yes"
 326 ], [
 327   HAVE_LINUX_JOYSTICK_HEADERS="no"
 328 ])
 329 AM_CONDITIONAL(HAVE_LINUX_JOYSTICK_HEADERS, test "x$HAVE_LINUX_JOYSTICK_HEADERS" = "xyes")
 330
 331 dnl Check for -Bsymbolic-functions linker flag used to avoid
 332 dnl intra-library PLT jumps, if available.
 333 AC_ARG_ENABLE(Bsymbolic,
 334               [AC_HELP_STRING([--disable-Bsymbolic],
 335                               [avoid linking with -Bsymbolic])],,
 336               [SAVED_LDFLAGS="${LDFLAGS}"
 337                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 338                LDFLAGS=-Wl,-Bsymbolic-functions
 339                AC_TRY_LINK([], [int main (void) { return 0; }],
 340                            AC_MSG_RESULT(yes)
 341                            enable_Bsymbolic=yes,
 342                            AC_MSG_RESULT(no)
 343                            enable_Bsymbolic=no)
 344                LDFLAGS="${SAVED_LDFLAGS}"])
 345
 346
 347 dnl *** set variables based on configure arguments ***
 348
 349 dnl set license and copyright notice
 350 GST_LICENSE="LGPL"
 351 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 352 AC_SUBST(GST_LICENSE)
 353
 354 dnl set location of plugin directory
 355 AG_GST_SET_PLUGINDIR
 356
 357 dnl set release date/time
 358 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 359   ["${srcdir}/gst-plugins-base.doap"],
 360   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 361
 362 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 363 dnl make sure it doesn't complain about unused variables if debugging is disabled
 364 NO_WARNINGS=""
 365 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 366
 367 dnl define an ERROR_CFLAGS Makefile variable
 368 dnl -Wformat-nonliteral - see ext/pango/gstclockoverlay.c and http://gcc.gnu.org/bugzilla/show_bug.cgi?id=39438
 369 AG_GST_SET_ERROR_CFLAGS($GST_GIT, [
 370     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef
 371     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 372     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 373     -Wno-multichar -Wnested-externs $NO_WARNINGS])
 374
 375 dnl define an ERROR_CXXFLAGS Makefile variable
 376 AG_GST_SET_ERROR_CXXFLAGS($GST_GIT, [
 377     -Wmissing-declarations -Wredundant-decls -Wundef
 378     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 379     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 380     -Wno-multichar $NO_WARNINGS])
 381
 382 dnl define correct level for debugging messages
 383 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 384
 385 dnl used in examples
 386 AG_GST_DEFAULT_ELEMENTS
 387
 388 dnl needed for encoding-target
 389 GST_DATADIR="$GST_PREFIX/share"
 390 AC_DEFINE_UNQUOTED(GST_DATADIR, "$GST_DATADIR", [system wide data directory])
 391 AC_DEFINE_UNQUOTED(GST_MAJORMINOR, "$GST_MAJORMINOR", [major/minor version])
 392
 393 dnl behaviour of speex based audio resampler
 394 AC_MSG_CHECKING(which audio resample format to use for integer)
 395 AC_ARG_WITH([audioresample_format],
 396         AS_HELP_STRING([--with-audioresample-format],[Which implementation should be used for integer audio resampling, int/float/auto, (default is auto)]),
 397         [ac_cv_audioresample_format=$withval], [ac_cv_audioresample_format=auto])dnl
 398 AC_MSG_RESULT($ac_cv_audioresample_format)
 399 case $ac_cv_audioresample_format in
 400   int)
 401     AC_DEFINE(AUDIORESAMPLE_FORMAT_INT,1,[The int implementation should be used for integer audio resampling])
 402     AC_SUBST(AUDIORESAMPLE_FORMAT_INT)
 403   ;;
 404   float)
 405     AC_DEFINE(AUDIORESAMPLE_FORMAT_FLOAT,1,[The float implementation should be used for integer audio resampling])
 406     AC_SUBST(AUDIORESAMPLE_FORMAT_FLOAT)
 407   ;;
 408   auto)
 409     AC_DEFINE(AUDIORESAMPLE_FORMAT_AUTO,1,[The implementation that should be used for integer audio resampling witll be benchmarked at runtime])
 410     AC_SUBST(AUDIORESAMPLE_FORMAT_AUTO)
 411 esac
 412
 413 dnl *** plug-ins to include ***
 414
 415 dnl these are all the gst plug-ins, compilable without additional libs
 416 AG_GST_CHECK_PLUGIN(adder)
 417 AG_GST_CHECK_PLUGIN(app)
 418 AG_GST_CHECK_PLUGIN(audioconvert)
 419 AG_GST_CHECK_PLUGIN(audiorate)
 420 AG_GST_CHECK_PLUGIN(audiotestsrc)
 421 AG_GST_CHECK_PLUGIN(encoding)
 422 AG_GST_CHECK_PLUGIN(ffmpegcolorspace)
 423 AG_GST_CHECK_PLUGIN(gdp)
 424 AG_GST_CHECK_PLUGIN(playback)
 425 AG_GST_CHECK_PLUGIN(audioresample)
 426 AG_GST_CHECK_PLUGIN(subparse)
 427 AG_GST_CHECK_PLUGIN(tcp)
 428 AG_GST_CHECK_PLUGIN(typefind)
 429 AG_GST_CHECK_PLUGIN(videotestsrc)
 430 AG_GST_CHECK_PLUGIN(videorate)
 431 AG_GST_CHECK_PLUGIN(videoscale)
 432 AG_GST_CHECK_PLUGIN(volume)
 433
 434 dnl check for gstreamer core features (subsystems)
 435 dnl FIXME: this assumes srcdir == builddir for uninstalled setups
 436 GST_CONFIGPATH=`$PKG_CONFIG --variable=includedir gstreamer-0.10`"/gst/gstconfig.h"
 437 AG_GST_PARSE_SUBSYSTEM_DISABLES($GST_CONFIGPATH)
 438 AM_CONDITIONAL(USE_XML, test $GST_DISABLE_XML != "1")
 439
 440 dnl disable plug-ins that require libxml2's HTML support if it is not available
 441 if test "x$HAVE_LIBXML_HTML" != "xyes"; then
 442   AG_GST_DISABLE_PLUGIN(subparse)
 443 fi
 444
 445 dnl disable plug-ins that require sys/socket.h if it is not available
 446 if test "x$HAVE_SYS_SOCKET_H" != "xyes"; then
 447   AG_GST_DISABLE_PLUGIN(tcp)
 448 fi
 449
 450 dnl iso-codes is optional, used by libgsttag
 451 AC_ARG_ENABLE(iso-codes,
 452 AC_HELP_STRING([--enable-iso-codes],[use iso-codes if installed]),
 453 [case "${enableval}" in
 454   yes) enable_iso_codes=yes ;;
 455   no)  enable_iso_codes=no ;;
 456   *) AC_MSG_ERROR(bad value ${enableval} for --enable-iso-codes) ;;
 457 esac
 458 ],
 459 [enable_iso_codes=yes]) dnl Default value
 460
 461 AC_MSG_CHECKING([whether to use iso-codes if they are available])
 462 if test "x$enable_iso_codes" = "xyes"; then
 463   AC_MSG_RESULT([yes])
 464   have_iso_codes=no
 465   AC_MSG_CHECKING([whether iso-codes are available on this system])
 466   if $PKG_CONFIG iso-codes; then
 467     AC_MSG_RESULT([yes])
 468     AC_MSG_CHECKING([whether iso-codes has iso-639 domain])
 469     if $PKG_CONFIG --variable=domains iso-codes | $GREP -q 639 ; then
 470       AC_MSG_RESULT([yes])
 471       AC_MSG_CHECKING([for iso-codes prefix])
 472       ISO_CODES_PREFIX=`$PKG_CONFIG --variable=prefix iso-codes`
 473       if test -d "$ISO_CODES_PREFIX"; then
 474         AC_MSG_RESULT([yes])
 475         AC_MSG_CHECKING([ISO_CODES_PREFIX])
 476         AC_MSG_RESULT([$ISO_CODES_PREFIX])
 477         ISO_639_DOMAIN="iso_639"
 478         AC_MSG_CHECKING([ISO_639_DOMAIN])
 479         AC_MSG_RESULT([$ISO_639_DOMAIN])
 480         have_iso_codes=yes
 481         AC_DEFINE([HAVE_ISO_CODES], [1], [make use of iso-codes for ISO-639])
 482         AC_DEFINE_UNQUOTED([ISO_CODES_PREFIX], ["$ISO_CODES_PREFIX"], [prefix])
 483         ISO_CODES_VERSION=`$PKG_CONFIG --modversion iso-codes`
 484         AC_DEFINE_UNQUOTED([ISO_CODES_VERSION], ["$ISO_CODES_VERSION"], [ ])
 485       else
 486         AC_MSG_RESULT([no])
 487       fi
 488     else
 489       AC_MSG_RESULT([no])
 490     fi
 491   else
 492     AC_MSG_RESULT([no])
 493   fi
 494   AM_CONDITIONAL(USE_ISO_CODES, test "x$have_iso_codes" = "xyes")
 495 else
 496   AC_MSG_RESULT([no (disabled via --disable-iso-codes)])
 497   AM_CONDITIONAL(USE_ISO_CODES, false)
 498 fi
 499
 500 dnl *** zlib is optionally used by id3 tag parsing in libgsttag ***
 501 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 502 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for ID3 parsing in libgsttag],, [
 503   PKG_CHECK_MODULES(ZLIB, [ zlib ], [
 504       HAVE_ZLIB="yes"
 505     ], [
 506       AG_GST_CHECK_LIBHEADER(ZLIB, z, uncompress,, zlib.h, [
 507         HAVE_ZLIB="yes"
 508         ZLIB_LIBS="-lz"
 509         AC_SUBST(ZLIB_LIBS)
 510       ])
 511     ])
 512 ])
 513
 514 dnl *** sys plug-ins ***
 515
 516 echo
 517 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 518 echo
 519
 520 dnl *** X11 ***
 521 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 522 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 523                   [ximagesink], [
 524   AC_PATH_XTRA
 525   ac_cflags_save="$CFLAGS"
 526   ac_cppflags_save="$CPPFLAGS"
 527   CFLAGS="$CFLAGS $X_CFLAGS"
 528   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 529
 530   dnl now try to find the HEADER
 531   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 532
 533   if test "x$HAVE_X" = "xno"
 534   then
 535     AC_MSG_NOTICE([cannot find X11 development files])
 536   else
 537     dnl this is much more than we want
 538     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 539     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 540     dnl it does not add the libs; therefore we add them here
 541     X_LIBS="$X_LIBS -lX11"
 542     AC_SUBST(X_CFLAGS)
 543     AC_SUBST(X_LIBS)
 544   fi
 545   AC_SUBST(HAVE_X)
 546   CFLAGS="$ac_cflags_save"
 547   CPPFLAGS="$ac_cppflags_save"
 548 ])
 549
 550 dnl Check for Xv extension
 551 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 552 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 553                   [xvimagesink], [
 554   AG_GST_CHECK_XV
 555 ])
 556
 557 dnl check for X Shm
 558 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 559 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 560   if test x$HAVE_X = xyes; then
 561     AC_CHECK_LIB(Xext, XShmAttach,
 562                  HAVE_XSHM="yes", HAVE_XSHM="no",
 563                  $X_LIBS)
 564     if test "x$HAVE_XSHM" = "xyes"; then
 565       XSHM_LIBS="-lXext"
 566     else
 567       dnl On AIX, it is in XextSam instead, but we still need -lXext
 568       AC_CHECK_LIB(XextSam, XShmAttach,
 569                    HAVE_XSHM="yes", HAVE_XSHM="no",
 570                    $X_LIBS)
 571       if test "x$HAVE_XSHM" = "xyes"; then
 572         XSHM_LIBS="-lXext -lXextSam"
 573       fi
 574     fi
 575   fi
 576 ], , [
 577   AC_SUBST(HAVE_XSHM)
 578   AC_SUBST(XSHM_LIBS)
 579 ])
 580
 581 dnl v4l/v4l2 checks have been moved down because they require X
 582
 583 dnl *** Video 4 Linux ***
 584 dnl for information about the header/define, see sys/v4l/gstv4lelement.h
 585 dnl renamed to GST_V4L in accordance with V4L2 below
 586 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L, true)
 587 AG_GST_CHECK_FEATURE(GST_V4L, [Video 4 Linux], video4linux, [
 588   AC_CHECK_DECL(VID_TYPE_MPEG_ENCODER, HAVE_GST_V4L="yes", HAVE_GST_V4L="no", [
 589 #include <sys/types.h>
 590 #define _LINUX_TIME_H
 591 #define __user
 592 #include <linux/videodev.h>
 593   ])
 594
 595   dnl we can build v4l without Xv, but then we won't have XOverlay support
 596   if test "x$HAVE_GST_V4L" = "xyes" -a "x$HAVE_XVIDEO" != "xyes"
 597   then
 598     AC_MSG_NOTICE([NO XVIDEO FOUND, VIDEO4LINUX WILL BE BUILT])
 599     AC_MSG_NOTICE([WITHOUT XOVERLAY SUPPORT])
 600   fi
 601 ])
 602
 603 # Optional gudev for device probing
 604 AC_ARG_WITH([gudev],
 605   AC_HELP_STRING([--with-gudev],
 606     [device detection with gudev]),
 607   [],
 608   [with_gudev=check])
 609 if test x$HAVE_GST_V4L = xyes; then
 610   if test x$with_gudev != xno; then
 611       PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 143 ],
 612           [ have_gudev=yes
 613             AC_DEFINE(HAVE_GUDEV, 1,
 614                [Whether gudev is available for device detection])
 615             AC_DEFINE([G_UDEV_API_IS_SUBJECT_TO_CHANGE], 1, [I know the API is subject to change.])
 616           ], [
 617           have_gudev=no
 618           ])
 619   else
 620     have_gudev=no
 621   fi
 622 fi
 623 AC_SUBST(GUDEV_CFLAGS)
 624 AC_SUBST(GUDEV_LIBS)
 625
 626 dnl *** ext plug-ins ***
 627 dnl keep this list sorted alphabetically !
 628
 629 if test "x$BUILD_EXTERNAL" = "xyes"; then
 630
 631 echo
 632 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 633 echo
 634
 635 dnl *** alsa ***
 636 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 637 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 638   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 639     HAVE_ALSA="yes"
 640     AC_SUBST(ALSA_CFLAGS)
 641     AC_SUBST(ALSA_LIBS)
 642   ], [
 643     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 644   ])
 645 ])
 646
 647 dnl *** CDParanoia ***
 648 dnl Note: upstream has a pkg-config file only in post-10.2 SVN so far
 649 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 650 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 651   PKG_CHECK_MODULES(CDPARANOIA, cdparanoia-3 >= 10.2, [
 652     HAVE_CDPARANOIA="yes"
 653   ], [
 654     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 655                         cdda_open, -lm,
 656                         cdda_interface.h,
 657                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 658                         HEADER_DIR="no"
 659                         FOUND_CDPARANOIA="yes")
 660     if test "x$FOUND_CDPARANOIA" != "xyes";
 661     then
 662       AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 663                           cdda_open, -lm,
 664                           cdda/cdda_interface.h,
 665                           CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 666                           HEADER_DIR="yes"
 667                           FOUND_CDPARANOIA="yes")
 668     fi
 669     if test "x$HEADER_DIR" = "xyes";
 670     then
 671       AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 672                          defined if cdda headers are in a cdda/ directory)
 673     fi
 674     if test "x$FOUND_CDPARANOIA" = "xyes";
 675     then
 676       AC_CHECK_LIB(cdda_paranoia,
 677                    paranoia_cachemodel_size,
 678                    : ,
 679                    HAVE_CDPARANOIA=no,
 680                  [-lcdda_interface])
 681     fi
 682
 683     AC_SUBST(CDPARANOIA_LIBS)
 684   ])
 685 ])
 686 dnl FIXME : add second check somehow if that is necessary
 687 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 688 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 689
 690 dnl *** GNOME VFS ***
 691 translit(dnm, m, l) AM_CONDITIONAL(USE_GNOME_VFS, true)
 692 AG_GST_CHECK_FEATURE(GNOME_VFS, [GNOME VFS], gnomevfs, [
 693   PKG_CHECK_MODULES(GNOME_VFS, gnome-vfs-2.0, [
 694       HAVE_GNOME_VFS="yes"
 695       AC_SUBST(GNOME_VFS_CFLAGS)
 696       AC_SUBST(GNOME_VFS_LIBS)
 697       GNOME_VFS_MODULES_DIR="`$PKG_CONFIG --variable=modulesdir gnome-vfs-2.0`"
 698       AC_DEFINE_UNQUOTED(GNOME_VFS_MODULES_DIR, "$GNOME_VFS_MODULES_DIR",
 699              [The GnomeVFS modules directory.])
 700     ],[
 701       HAVE_GNOME_VFS="no"
 702     ]
 703     )
 704 ])
 705
 706 dnl *** ivorbis ***
 707 dnl AM_PATH_IVORBIS only takes two options
 708 translit(dnm, m, l) AM_CONDITIONAL(USE_IVORBIS, true)
 709 AG_GST_CHECK_FEATURE(IVORBIS, [integer vorbis plug-in], ivorbisdec, [
 710   AG_GST_PKG_CHECK_MODULES(IVORBIS, vorbisidec)
 711   if test $HAVE_IVORBIS = no
 712   then
 713     IVORBIS_LIBS=
 714     IVORBIS_CFLAGS=
 715     AC_CHECK_LIB(vorbisidec, vorbis_block_init,
 716       [IVORBIS_LIBS=-lvorbisidec
 717       HAVE_IVORBIS=yes
 718       case $host in
 719       arm-*-*)
 720         IVORBIS_CFLAGS="-D_ARM_ASSEM_ $IVORBIS_CFLAGS"
 721       esac
 722       ],
 723       HAVE_IVORBIS=no)
 724     AC_SUBST(IVORBIS_LIBS)
 725     AC_SUBST(IVORBIS_CFLAGS)
 726   else
 727     AC_CHECK_LIB(vorbisidec, vorbis_dsp_pcmout,
 728       AC_DEFINE([USE_TREMOLO],1, "Define if building for android"),
 729       USE_TREMOLO=no)
 730   fi
 731 ])
 732
 733 dnl *** libgio ***
 734 translit(dnm, m, l) AM_CONDITIONAL(USE_GIO, true)
 735 AG_GST_CHECK_FEATURE(GIO, [GIO library], gio, [
 736   PKG_CHECK_MODULES(GIO, gio-2.0 >= 2.16, [
 737     HAVE_GIO="yes"
 738     GIO_MODULE_DIR="`$PKG_CONFIG --variable=giomoduledir gio-2.0`"
 739     AC_DEFINE_UNQUOTED(GIO_MODULE_DIR, "$GIO_MODULE_DIR",
 740            [The GIO modules directory.])
 741     GIO_LIBDIR="`$PKG_CONFIG --variable=libdir gio-2.0`"
 742     AC_DEFINE_UNQUOTED(GIO_LIBDIR, "$GIO_LIBDIR",
 743            [The GIO library directory.])
 744   ], [
 745     HAVE_GIO="no"
 746   ])
 747   AC_SUBST(GIO_CFLAGS)
 748   AC_SUBST(GIO_LIBS)
 749   AC_SUBST(GIO_LDFLAGS)
 750 ])
 751
 752 dnl *** libvisual ***
 753 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 754 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 755   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 756   if test $HAVE_LIBVISUAL = no
 757   then
 758     AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0)
 759     if test x$HAVE_LIBVISUAL = xyes; then
 760       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.2`"
 761     fi
 762   else
 763     if test x$HAVE_LIBVISUAL = xyes; then
 764       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.4`"
 765     fi
 766   fi
 767   AC_MSG_NOTICE([libvisual pluginsdir: $LIBVIS_PLUGINSDIR])
 768   if test x$LIBVIS_PLUGINSDIR != x; then
 769     AC_DEFINE_UNQUOTED(LIBVISUAL_PLUGINSBASEDIR,
 770         "$LIBVIS_PLUGINSDIR",
 771         [directory in which the detected libvisual's plugins are located])
 772   fi
 773 ])
 774
 775 dnl *** ogg ***
 776 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 777 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 778   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 779   if test $HAVE_OGG = no
 780   then
 781     XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
 782     AS_SCRUB_INCLUDE(OGG_CFLAGS)
 783   fi
 784 ])
 785
 786 dnl *** pango ***
 787 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 788 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 789   AG_GST_PKG_CHECK_MODULES(PANGO, pango >= 1.16.0  pangocairo >= 1.16.0)
 790 ])
 791
 792 dnl *** theora ***
 793 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 794 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 795   AG_GST_PKG_CHECK_MODULES(THEORA, theoradec >= 1.1 theoraenc >= 1.1)
 796 ])
 797
 798 dnl *** vorbis ***
 799 dnl AM_PATH_VORBIS only takes two options
 800 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 801 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 802   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 803   if test $HAVE_VORBIS = no
 804   then
 805     XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
 806     AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
 807   fi
 808 ])
 809
 810 if test "x$HAVE_VORBIS" = "xyes"; then
 811   ac_cflags_save="$CFLAGS"
 812   AC_COMPILE_IFELSE(
 813     AC_LANG_PROGRAM([
 814 #include <vorbis/codec.h>
 815                      ],[
 816 vorbis_dsp_state *v;
 817
 818 vorbis_synthesis_restart (v);
 819                      ]), HAVE_VSR=yes, HAVE_VSR=no)
 820   if test "x$HAVE_VSR" = "xyes"; then
 821     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 822                        [defined if vorbis_synthesis_restart is present])
 823   fi
 824   CFLAGS="$ac_cflags_save"
 825 fi
 826
 827 else
 828
 829 dnl not building plugins with external dependencies,
 830 dnl but we still need to set the conditionals
 831 AM_CONDITIONAL(USE_ALSA, false)
 832 AM_CONDITIONAL(USE_CDPARANOIA, false)
 833 AM_CONDITIONAL(USE_GIO, false)
 834 AM_CONDITIONAL(USE_GNOME_VFS, false)
 835 AM_CONDITIONAL(USE_IVORBIS, false)
 836 AM_CONDITIONAL(USE_LIBVISUAL, false)
 837 AM_CONDITIONAL(USE_OGG, false)
 838 AM_CONDITIONAL(USE_PANGO, false)
 839 AM_CONDITIONAL(USE_THEORA, false)
 840 AM_CONDITIONAL(USE_VORBIS, false)
 841
 842 fi dnl of EXT plugins
 843
 844 dnl seeking needs freetype, so check for it here
 845 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 846   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 847 ])
 848 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 849 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 850 AC_SUBST(FT2_CFLAGS)
 851 AC_SUBST(FT2_LIBS)
 852
 853 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 854
 855 dnl Overview:
 856 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 857 dnl GST_*:              flags shared by built objects to link against GStreamer
 858 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 859 dnl                          (compare to other modules) or for i18n
 860 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 861 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 862 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 863 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 864
 865 dnl GST_OPTION_CFLAGS
 866 if test "x$USE_DEBUG" = xyes; then
 867    PROFILE_CFLAGS="-g"
 868 fi
 869 AC_SUBST(PROFILE_CFLAGS)
 870
 871 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 872   dnl Define _only_ when compiling a git version (not pre-releases or releases)
 873   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 874 else
 875   DEPRECATED_CFLAGS=""
 876 fi
 877 AC_SUBST(DEPRECATED_CFLAGS)
 878
 879 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 880 dnl at make time with e.g. make ERROR_CFLAGS=""
 881 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 882 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 883 AC_SUBST(GST_OPTION_CFLAGS)
 884 AC_SUBST(GST_OPTION_CXXFLAGS)
 885
 886 dnl our libraries need to be versioned correctly
 887 AC_SUBST(GST_LT_LDFLAGS)
 888
 889 dnl GST_PLUGINS_BASE_CFLAGS
 890 dnl prefer internal headers to already installed ones
 891 dnl also add builddir include for enumtypes and marshal
 892 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 893 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 894
 895 dnl FIXME: do we want to rename to GST_ALL_* ?
 896 dnl add GST_OPTION_CFLAGS, but overridable
 897 GST_CXXFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CXXFLAGS)"
 898 GST_CFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CFLAGS)"
 899 AC_SUBST(GST_CFLAGS)
 900 AC_SUBST(GST_CXXFLAGS)
 901 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 902 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 903 AC_SUBST(GST_LIBS)
 904
 905 dnl LDFLAGS really should only contain flags, not libs - they get added before
 906 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 907 GST_ALL_LDFLAGS="-no-undefined"
 908 if test "x${enable_Bsymbolic}" = "xyes"; then
 909   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 910 fi
 911 AC_SUBST(GST_ALL_LDFLAGS)
 912
 913 dnl GST_LIB_LDFLAGS
 914 dnl linker flags shared by all libraries
 915 dnl LDFLAGS modifier defining exported symbols from built libraries
 916 dnl (export _gst_foo but not __gst_foo)
 917 GST_LIB_LDFLAGS="-export-symbols-regex ^_?\(gst_\|Gst\|GST_\).*"
 918 AC_SUBST(GST_LIB_LDFLAGS)
 919
 920 dnl this really should only contain flags, not libs - they get added before
 921 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 922 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
 923 AC_SUBST(GST_PLUGIN_LDFLAGS)
 924
 925 dnl *** output files ***
 926
 927 AC_CONFIG_FILES(
 928 Makefile
 929 gst-plugins-base.spec
 930 gst/Makefile
 931 gst/adder/Makefile
 932 gst/app/Makefile
 933 gst/audioconvert/Makefile
 934 gst/audiorate/Makefile
 935 gst/audiotestsrc/Makefile
 936 gst/encoding/Makefile
 937 gst/ffmpegcolorspace/Makefile
 938 gst/gdp/Makefile
 939 gst/playback/Makefile
 940 gst/audioresample/Makefile
 941 gst/subparse/Makefile
 942 gst/tcp/Makefile
 943 gst/typefind/Makefile
 944 gst/videotestsrc/Makefile
 945 gst/videorate/Makefile
 946 gst/videoscale/Makefile
 947 gst/volume/Makefile
 948 sys/Makefile
 949 sys/ximage/Makefile
 950 sys/xvimage/Makefile
 951 sys/v4l/Makefile
 952 ext/Makefile
 953 ext/alsa/Makefile
 954 ext/cdparanoia/Makefile
 955 ext/gnomevfs/Makefile
 956 ext/gio/Makefile
 957 ext/libvisual/Makefile
 958 ext/ogg/Makefile
 959 ext/pango/Makefile
 960 ext/theora/Makefile
 961 ext/vorbis/Makefile
 962 gst-libs/Makefile
 963 gst-libs/gst/Makefile
 964 gst-libs/gst/audio/Makefile
 965 gst-libs/gst/app/Makefile
 966 gst-libs/gst/cdda/Makefile
 967 gst-libs/gst/fft/Makefile
 968 gst-libs/gst/floatcast/Makefile
 969 gst-libs/gst/interfaces/Makefile
 970 gst-libs/gst/netbuffer/Makefile
 971 gst-libs/gst/riff/Makefile
 972 gst-libs/gst/rtp/Makefile
 973 gst-libs/gst/rtsp/Makefile
 974 gst-libs/gst/sdp/Makefile
 975 gst-libs/gst/tag/Makefile
 976 gst-libs/gst/pbutils/Makefile
 977 gst-libs/gst/pbutils/gstpluginsbaseversion.h
 978 gst-libs/gst/video/Makefile
 979 tools/Makefile
 980 pkgconfig/Makefile
 981 pkgconfig/gstreamer-audio.pc
 982 pkgconfig/gstreamer-audio-uninstalled.pc
 983 pkgconfig/gstreamer-app.pc
 984 pkgconfig/gstreamer-app-uninstalled.pc
 985 pkgconfig/gstreamer-cdda.pc
 986 pkgconfig/gstreamer-cdda-uninstalled.pc
 987 pkgconfig/gstreamer-fft.pc
 988 pkgconfig/gstreamer-fft-uninstalled.pc
 989 pkgconfig/gstreamer-floatcast.pc
 990 pkgconfig/gstreamer-floatcast-uninstalled.pc
 991 pkgconfig/gstreamer-interfaces.pc
 992 pkgconfig/gstreamer-interfaces-uninstalled.pc
 993 pkgconfig/gstreamer-netbuffer.pc
 994 pkgconfig/gstreamer-netbuffer-uninstalled.pc
 995 pkgconfig/gstreamer-pbutils.pc
 996 pkgconfig/gstreamer-pbutils-uninstalled.pc
 997 pkgconfig/gstreamer-riff.pc
 998 pkgconfig/gstreamer-riff-uninstalled.pc
 999 pkgconfig/gstreamer-rtp.pc
1000 pkgconfig/gstreamer-rtp-uninstalled.pc
1001 pkgconfig/gstreamer-rtsp.pc
1002 pkgconfig/gstreamer-rtsp-uninstalled.pc
1003 pkgconfig/gstreamer-sdp.pc
1004 pkgconfig/gstreamer-sdp-uninstalled.pc
1005 pkgconfig/gstreamer-tag.pc
1006 pkgconfig/gstreamer-tag-uninstalled.pc
1007 pkgconfig/gstreamer-video.pc
1008 pkgconfig/gstreamer-video-uninstalled.pc
1009 pkgconfig/gstreamer-plugins-base.pc
1010 pkgconfig/gstreamer-plugins-base-uninstalled.pc
1011 tests/Makefile
1012 tests/check/Makefile
1013 tests/examples/Makefile
1014 tests/examples/app/Makefile
1015 tests/examples/audio/Makefile
1016 tests/examples/dynamic/Makefile
1017 tests/examples/encoding/Makefile
1018 tests/examples/gio/Makefile
1019 tests/examples/overlay/Makefile
1020 tests/examples/seek/Makefile
1021 tests/examples/snapshot/Makefile
1022 tests/examples/playrec/Makefile
1023 tests/examples/v4l/Makefile
1024 tests/files/Makefile
1025 tests/icles/Makefile
1026 tests/icles/playback/Makefile
1027 docs/Makefile
1028 docs/design/Makefile
1029 docs/libs/Makefile
1030 docs/plugins/Makefile
1031 docs/version.entities
1032 po/Makefile.in
1033 common/Makefile
1034 common/m4/Makefile
1035 m4/Makefile
1036 )
1037
1038 dnl Create the config.h file for Visual Studio builds
1039 dnl Beware of spaces and /'s in some of the shell variable contents.
1040 sed \
1041     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
1042     -e 's/.* GST_INSTALL_PLUGINS_HELPER/#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
1043     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
1044     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
1045     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
1046     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
1047     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
1048     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
1049     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
1050     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
1051     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
1052     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
1053     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
1054     -e 's/.* HAVE_ISO_CODES$/#undef HAVE_ISO_CODES/' \
1055     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
1056     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
1057     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
1058     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
1059     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
1060     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
1061     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
1062     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
1063     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1064     -e 's/.* ISO_CODES_PREFIX$/#undef ISO_CODES_PREFIX/' \
1065     -e 's/.* ISO_CODES_VERSION$/#undef ISO_CODES_VERSION/' \
1066     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1067     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1068     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
1069     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1070     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
1071     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1072     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1073     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1074     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.10"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.10"\n#endif/' \
1075     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
1076     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1077     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
1078     -e "s/.* DEFAULT_VIDEOSINK$/#define DEFAULT_VIDEOSINK \"directdrawsink\"/" \
1079     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1080     config.h.in >win32/common/config.h-new
1081
1082
1083
1084 AC_OUTPUT
1085
1086 AG_GST_OUTPUT_PLUGINS
1087 ORC_OUTPUT
1088