configure.ac

   1 AC_INIT
   2 AC_CANONICAL_TARGET([])
   3
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, cvs and prerelease does Werror too
   6 AS_VERSION(gstreamer, GST_VERSION, 0, 7, 0, 1, GST_CVS="no", GST_CVS="yes")
   7
   8 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
   9 AM_MAINTAINER_MODE
  10 AM_INIT_AUTOMAKE($PACKAGE,$VERSION)
  11
  12 dnl our libraries and install dirs use major.minor as a version
  13 GST_MAJORMINOR=$GST_VERSION_MAJOR.$GST_VERSION_MINOR
  14 AC_SUBST(GST_MAJORMINOR)
  15
  16 AC_PROG_CC
  17 dnl For interactive UNIX (a Sun thing)
  18 AC_ISC_POSIX
  19
  20 dnl CURRENT, REVISION, AGE
  21 dnl - library source changed -> increment REVISION
  22 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  23 dnl - interfaces added -> increment AGE
  24 dnl - interfaces removed -> AGE = 0
  25 AS_LIBTOOL(GST, 3, 0, 0)
  26
  27 AC_CONFIG_SRCDIR([gst/gst.c])
  28 AM_CONFIG_HEADER(config.h)
  29
  30 dnl Add parameters for aclocal
  31 dnl (This must come after AM_INIT_AUTOMAKE, since it modifies ACLOCAL)
  32 ACLOCAL="$ACLOCAL -I common/m4 $ACLOCAL_FLAGS"
  33
  34 AM_PROG_CC_STDC
  35 AM_PROG_AS
  36 AS="${CC}"
  37
  38 dnl decide on error flags
  39 AS_COMPILER(COMPILER)
  40 if test "x$COMPILER" = "xforte"; then
  41   GST_ERROR=
  42 else
  43   if test "x$GST_CVS"="xyes"; then
  44     GST_ERROR="-Wall -Werror"
  45   else
  46     GST_ERROR="-Wall"
  47   fi
  48 fi
  49
  50 dnl We disable static building for development, for time savings
  51 dnl *NOTE*: dnl this line before release, so release does static too
  52 dnl AM_DISABLE_STATIC
  53
  54 AC_HEADER_STDC([])
  55
  56
  57 dnl ##############################
  58 dnl # Do automated configuration #
  59 dnl ##############################
  60
  61 dnl Check for tools:
  62 dnl ================
  63
  64 dnl allow for different autotools
  65 AS_AUTOTOOLS_ALTERNATE()
  66
  67 dnl modify pkg-config path
  68 AC_ARG_WITH(pkg-config-path,
  69    AC_HELP_STRING([--with-pkg-config-path],
  70                   [colon-separated list of pkg-config(1) dirs]),
  71    [export PKG_CONFIG_PATH=${withval}])
  72
  73 GST_DOC()
  74 GST_ARCH()
  75
  76 dnl we require bison for building of some of the marshal files
  77 dnl FIXME: check if AC_PROG_YACC is suitable here
  78 AC_PATH_PROG(BISON_PATH, bison, no)
  79 if test x$BISON_PATH = xno; then
  80   AC_MSG_ERROR(Could not find bison)
  81 fi
  82
  83 dnl we require flex for building the parser
  84 dnl FIXME: check if AC_PROG_LEX is suitable here
  85 AC_PATH_PROG(FLEX_PATH, flex, no)
  86 if test x$FLEX_PATH = xno; then
  87   AC_MSG_ERROR(Could not find flex)
  88 fi
  89
  90 dnl
  91 dnl We should really use AC_SYS_LARGEFILE, but the problem is
  92 dnl many of the plugins don't include "config.h".  To assure
  93 dnl binary compatibility, it is necessary that all gstreamer
  94 dnl code be compiled with the same sizeof(off_t), so we use
  95 dnl the following crude hack.
  96 dnl
  97
  98 dnl
  99 dnl GST_CFLAGS are split up as GST_EXT_CFLAGS and GST_INT_CFLAGS
 100 dnl same for libs
 101 dnl this is so we can make GST_CFLAGS for external modules available
 102 dnl without mixing in internal (uninstalled) CFLAGS
 103 dnl
 104
 105 dnl disable deprecated functions internally
 106 GST_INT_CFLAGS="-DGST_DISABLE_DEPRECATED"
 107
 108 AC_MSG_CHECKING(for large file support)
 109 AC_TRY_RUN([
 110 #define _LARGEFILE_SOURCE
 111 #define _FILE_OFFSET_BITS 64
 112 #include <sys/types.h>
 113 int main () { return !(sizeof(off_t) == 8); }
 114 ],
 115 [
 116 AC_MSG_RESULT(yes)
 117 GST_EXT_CFLAGS="-D_LARGEFILE_SOURCE -D_FILE_OFFSET_BITS=64"
 118 ],
 119 [
 120 AC_MSG_RESULT(no)
 121 ],
 122 [
 123 AC_MSG_RESULT(no)
 124 ])
 125
 126 dnl check for makecontext and define HAVE_MAKECONTEXT if we have it
 127 AC_CHECK_MCSC()
 128 if test "$ac_cv_check_mcsc" == "yes"; then
 129   AC_DEFINE_UNQUOTED(HAVE_MAKECONTEXT, $HAVE_MAKECONTEXT,
 130                      [defined if we have makecontext ()])
 131 fi
 132
 133 dnl Check for a way to display the function name in debug output
 134 GST_CHECK_FUNCTION()
 135
 136 dnl Check for essential libraries first:
 137 dnl ====================================
 138
 139 dnl === GLib 2 ===
 140 dnl Minimum required version of GLib2
 141 dnl required for compilation without warnings
 142 GLIB2_REQ="2.0.1"
 143 AC_SUBST(GLIB2_REQ)
 144
 145 dnl Check for glib2
 146 PKG_CHECK_MODULES(GLIB2, glib-2.0 >= $GLIB2_REQ gobject-2.0 gthread-2.0 gmodule-2.0,HAVE_GLIB2=yes,HAVE_GLIB2=no)
 147 GLIB_LIBS=$GLIB2_LIBS
 148 GLIB_CFLAGS=$GLIB2_CFLAGS
 149 AC_SUBST(GLIB_LIBS)
 150 AC_SUBST(GLIB_CFLAGS)
 151
 152 if test "x$HAVE_GLIB2" = "xno"; then
 153   AC_MSG_ERROR([GStreamer requires GLib 2.0 to compile.])
 154 fi
 155
 156 GST_PKG_DEPS="glib-2.0, gobject-2.0, gmodule-2.0, gthread-2.0"
 157 AC_SUBST(GST_PKG_DEPS)
 158
 159 dnl === libxml 2 ===
 160 dnl Minimum required version of libxml2
 161 LIBXML2_REQ="2.4.9"
 162 AC_SUBST(LIBXML2_REQ)
 163
 164 dnl check for libxml2
 165 GST_LIBXML2_CHECK()
 166
 167 dnl popt checks
 168 dnl FIXME: This test passes on popt 1.6.2, maybe earlier, but popt 1.6.2
 169 dnl        causes segfaults on gst_init. Write a working test if possible.
 170 GST_CHECK_LIBHEADER(POPT, popt, poptStrippedArgv,, popt.h, POPT_LIBS="-lpopt",
 171   AC_MSG_ERROR([popt 1.6.3 or newer is required to build gstreamer. You can
 172                 download the latest version from
 173                 ftp://ftp.rpm.org/pub/rpm/dist/])
 174 )
 175 AC_MSG_NOTICE(Checking for POPT_TABLEEND)
 176 AC_COMPILE_IFELSE([
 177 #include <popt.h>
 178 int main ()
 179 {
 180 #ifndef POPT_TABLEEND
 181 #error
 182 #else
 183   return 0;
 184 #endif
 185 }
 186 ],, [
 187   dnl it failed
 188   AC_MSG_ERROR([popt 1.6.3 or newer is required to build gstreamer. You can
 189                 download the latest version from
 190                 ftp://ftp.rpm.org/pub/rpm/dist/])
 191 ])
 192
 193 dnl Check for atomic.h
 194 dnl Note: use AC_CHECK_HEADER not AC_CHECK_HEADERS, because the latter
 195 dnl defines the wrong default symbol as well (HAVE_ASM_ATOMIC_H)
 196 AC_CHECK_HEADER(asm/atomic.h, HAVE_ATOMIC_H=yes, HAVE_ATOMIC_H=no)
 197 dnl Do a compile to check that it has atomic_set (eg, linux 2.0 didn't)
 198 if test x$HAVE_ATOMIC_H = xyes; then
 199   AC_LINK_IFELSE([
 200 #include "asm/atomic.h"
 201 main() {atomic_t t; atomic_set(&t,0); atomic_inc(&t); atomic_add(1,&t);return 0;}
 202   ],, [
 203     # Not successful
 204     if test x$HAVE_ATOMIC_H = xyes; then
 205       AC_MSG_WARN(Atomic reference counting is out of date: doing without.)
 206     fi
 207     HAVE_ATOMIC_H=no
 208   ])
 209 fi
 210
 211 dnl Check for ucontext.h
 212 AC_CHECK_HEADER(ucontext.h, AC_DEFINE(HAVE_UCONTEXT_H, 1, [defined if we have ucontext.h]))
 213
 214 dnl ######################################################################
 215 dnl # Check command line parameters, and set shell variables accordingly #
 216 dnl ######################################################################
 217
 218 dnl FIXME: simplify all this down using a few m4 macros
 219
 220 AC_ARG_ENABLE(libmmx,
 221 AC_HELP_STRING([--enable-libmmx],[use libmmx, if available]),
 222 [case "${enableval}" in
 223   yes) USE_LIBMMX=$HAVE_LIBMMX ;;
 224   no)  USE_LIBMMX=no ;;
 225   *) AC_MSG_ERROR(bad value ${enableval} for --enable-libmmx) ;;
 226 esac],
 227 [USE_LIBMMX=$HAVE_LIBMMX]) dnl Default value
 228
 229 AC_ARG_ENABLE(atomic,
 230 AC_HELP_STRING([--enable-atomic],[use atomic reference counting header]),
 231 [case "${enableval}" in
 232   yes) USE_ATOMIC_H=$HAVE_ATOMIC_H;;
 233   noset) USE_ATOMIC_H=$HAVE_ATOMIC_H;;
 234   no)  USE_ATOMIC_H=no;;
 235   *) AC_MSG_ERROR(bad value ${enableval} for --enable-atomic) ;;
 236 esac],
 237 [USE_ATOMIC_H=$HAVE_ATOMIC_H]) dnl Default value
 238
 239 AC_ARG_ENABLE(plugin-builddir,
 240 AC_HELP_STRING([--enable-plugin-builddir],[allow tests/demos to use non-installed plugins]),
 241 [case "${enableval}" in
 242   yes) PLUGINS_USE_BUILDDIR=yes ;;
 243   no)  PLUGINS_USE_BUILDDIR=no ;;
 244   *) AC_MSG_ERROR(bad value ${enableval} for --enable-plugin-builddir) ;;
 245 esac],
 246 [PLUGINS_USE_BUILDDIR=no]) dnl Default value
 247
 248 GST_DEBUGINFO
 249
 250 AC_ARG_ENABLE(profiling,
 251 AC_HELP_STRING([--enable-profiling],[adds -pg to compiler commandline, for profiling]),
 252 [case "${enableval}" in
 253   yes) USE_PROFILING=yes ;;
 254   no)  UES_PROFILING=no ;;
 255   *) AC_MSG_ERROR(bad value ${enableval} for --enable-profiling) ;;
 256 esac],
 257 [USE_PROFILING=no]) dnl Default value
 258
 259 dnl use a cache dir for storing element registry info.
 260 dnl default to building registry in the source tree if we are enabling plugin build dir
 261 if test "x$PLUGINS_USE_BUILDDIR" = "xyes"; then
 262   GST_CACHE_DIR=`pwd`
 263 else
 264   dnl ${localstatedir} points to PREFIX/var
 265   GST_CACHE_DIR=${localstatedir}/cache/gstreamer-$GST_MAJORMINOR
 266 fi
 267 AC_ARG_WITH(cachedir,
 268 AC_HELP_STRING([--with-cachedir],[specify path to use for plugin and command completion registries]),
 269 [case "${withval}" in
 270   yes) AC_MSG_ERROR(bad value ${withval} for --with-cachedir) ;;
 271   no) AC_MSG_ERROR(bad value ${withval} for --with-cachedir) ;;
 272   *) GST_CACHE_DIR="${withval}" ;;
 273 esac],
 274 [:]) dnl Default value
 275
 276 AS_AC_EXPAND(GST_CACHE_DIR, $GST_CACHE_DIR)
 277 AC_MSG_NOTICE(Using $GST_CACHE_DIR as registry cache dir)
 278
 279
 280 dnl building of tests
 281 AC_ARG_ENABLE(tests,
 282 AC_HELP_STRING([--disable-tests],[disable building test apps]),
 283 [case "${enableval}" in
 284   yes) BUILD_TESTS=yes ;;
 285   no)  BUILD_TESTS=no ;;
 286   *) AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 287 esac],
 288 [BUILD_TESTS=yes]) dnl Default value
 289 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 290
 291 dnl tests known to fail
 292 AC_ARG_ENABLE(failing-tests,
 293 AC_HELP_STRING([--disable-failing-tests],[disable building tests known to fail]),
 294 [case "${enableval}" in
 295   yes) BUILD_FAILING_TESTS=yes ;;
 296   no)  BUILD_FAILING_TESTS=no ;;
 297   *) AC_MSG_ERROR(bad value ${enableval} for --disable-failing-tests) ;;
 298 esac],
 299 [BUILD_FAILING_TESTS=no]) dnl Default value
 300 AM_CONDITIONAL(BUILD_FAILING_TESTS, test "x$BUILD_FAILING_TESTS" = "xyes")
 301 if test x$BUILD_FAILING_TESTS = xyes; then
 302   AC_MSG_WARN([building tests known to fail, use --disable-failing-tests to disable])
 303 else
 304   AC_MSG_WARN([Sissy ! By asking to not build the tests known to fail, you hereby waive your right to customer support.  If you do not agree with this EULA, please press Ctrl-C before the next line is printed.  By allowing the next line to be printed, you expressly acknowledge your acceptance of this EULA.])
 305 fi
 306
 307 AC_ARG_ENABLE(examples,
 308 AC_HELP_STRING([--disable-examples],[disable building examples]),
 309 [case "${enableval}" in
 310   yes) BUILD_EXAMPLES=yes ;;
 311   no)  BUILD_EXAMPLES=no ;;
 312   *) AC_MSG_ERROR(bad value ${enableval} for --disable-examples) ;;
 313 esac],
 314 [BUILD_EXAMPLES=yes]) dnl Default value
 315 AM_CONDITIONAL(BUILD_EXAMPLES,      test "x$BUILD_EXAMPLES" = "xyes")
 316
 317 dnl Next, check for the optional components:
 318 dnl ========================================
 319
 320 translit(dnm, m, l) AM_CONDITIONAL(GST_DISABLE_LOADSAVE, true)
 321 GST_SUBSYSTEM_DISABLE(LOADSAVE,[pipeline XML load/save])
 322 translit(dnm, m, l) AM_CONDITIONAL(GST_DISABLE_TYPEFIND, true)
 323 GST_SUBSYSTEM_DISABLE(TYPEFIND,[typefind plugin],)
 324 translit(dnm, m, l) AM_CONDITIONAL(GST_DISABLE_AUTOPLUG, true)
 325 GST_SUBSYSTEM_DISABLE(AUTOPLUG,[autoplugger subsystem])
 326 translit(dnm, m, l) AM_CONDITIONAL(GST_DISABLE_PARSE, true)
 327 GST_SUBSYSTEM_DISABLE(PARSE,[command-line parser])
 328 translit(dnm, m, l) AM_CONDITIONAL(GST_DISABLE_TRACE, true)
 329 GST_SUBSYSTEM_DISABLE(TRACE,[tracing subsystem])
 330 translit(dnm, m, l) AM_CONDITIONAL(GST_DISABLE_ALLOC_TRACE, true)
 331 GST_SUBSYSTEM_DISABLE(ALLOC_TRACE,[allocation tracing])
 332
 333 translit(dnm, m, l) AM_CONDITIONAL(GST_DISABLE_REGISTRY, true)
 334 GST_SUBSYSTEM_DISABLE(REGISTRY,[plugin registry])
 335 translit(dnm, m, l) AM_CONDITIONAL(GST_DISABLE_ENUMTYPES, true)
 336 GST_SUBSYSTEM_DISABLE(ENUMTYPES,[enum types])
 337 translit(dnm, m, l) AM_CONDITIONAL(GST_DISABLE_INDEX, true)
 338 GST_SUBSYSTEM_DISABLE(INDEX,[index])
 339 translit(dnm, m, l) AM_CONDITIONAL(GST_DISABLE_PLUGIN, true)
 340 GST_SUBSYSTEM_DISABLE(PLUGIN,[plugin])
 341 translit(dnm, m, l) AM_CONDITIONAL(GST_DISABLE_URI, true)
 342 GST_SUBSYSTEM_DISABLE(URI,[uri handlers])
 343
 344 GST_EXT_CFLAGS="$GST_EXT_CFLAGS $GST_SUBSYSTEM_DISABLE_DEFINES"
 345
 346 dnl ################################################
 347 dnl # Set defines according to variables set above #
 348 dnl ################################################
 349
 350
 351 dnl These should be "USE_*" instead of "HAVE_*", but some packages expect
 352 dnl HAVE_ and it is likely to be easier to stick with the old name
 353 if test "x$USE_LIBMMX" = xyes; then
 354   AC_DEFINE(HAVE_LIBMMX, 1, [Define if libmmx is available])
 355 fi
 356
 357 if test "x$USE_ATOMIC_H" = xyes; then
 358   AC_DEFINE(HAVE_ATOMIC_H, 1, [Define if atomic.h header file is available])
 359 fi
 360
 361 dnl test if we have pthread_attr_setstack; if not use the older calls
 362 AC_CHECK_LIB(pthread, pthread_attr_setstack,
 363    AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACK, 1,
 364              [Defined if libpthread has pthread_attr_setstack ()]))
 365
 366 dnl test if we have posix_memalign; FreeBSD doesn't
 367 AC_CHECK_FUNC(posix_memalign,
 368    AC_DEFINE(HAVE_POSIX_MEMALIGN, 1,
 369              [Defined if we have posix_memalign ()]))
 370
 371 if test "x$PLUGINS_USE_BUILDDIR" = xyes; then
 372   AC_DEFINE(PLUGINS_USE_BUILDDIR, 1, [Define if plugins should be loaded from the build tree - only developers should use this])
 373 fi
 374
 375 if test "x$USE_DEBUG" = xyes; then
 376    GST_INT_CFLAGS="$GST_INT_CFLAGS -g"
 377 fi
 378
 379 if test "x$USE_PROFILING" = xyes; then
 380 dnl  CFLAGS="$CFLAGS -pg -fprofile-arcs"
 381   FOMIT_FRAME_POINTER=""
 382 else
 383   FOMIT_FRAME_POINTER="-fomit-frame-pointer"
 384 fi
 385
 386 dnl
 387 dnl AC_SUBST(FOMIT_FRAME_POINTER)
 388 dnl
 389
 390 dnl #############################
 391 dnl # Set automake conditionals #
 392 dnl #############################
 393
 394 dnl These should be "USE_*" instead of "HAVE_*", but some packages expect
 395 dnl HAVE_ and it is likely to be easier to stick with the old name
 396 AM_CONDITIONAL(HAVE_ATOMIC_H,       test "x$USE_ATOMIC_H" = "xyes")
 397
 398 AM_CONDITIONAL(EXPERIMENTAL,        test "$EXPERIMENTAL" = "$xyes")
 399 AM_CONDITIONAL(BROKEN,              test "$BROKEN" = "$xyes")
 400
 401 AM_CONDITIONAL(PLUGINS_USE_BUILDDIR,  test "x$PLUGINS_USE_BUILDDIR" = "xyes")
 402
 403
 404 dnl ############################
 405 dnl # Set up some more defines #
 406 dnl ############################
 407
 408 dnl Set location of registry dir.
 409 AC_DEFINE_UNQUOTED(GST_CACHE_DIR, "$GST_CACHE_DIR", [Define the registry directory])
 410 AC_SUBST(GST_CACHE_DIR)
 411
 412 dnl Set location of plugin directory
 413 if test "x${prefix}" = "xNONE"; then
 414   PLUGINS_DIR=${ac_default_prefix}/lib/gstreamer-$GST_MAJORMINOR
 415 else
 416   PLUGINS_DIR=${prefix}/lib/gstreamer-$GST_MAJORMINOR
 417 fi
 418 AC_DEFINE_UNQUOTED(PLUGINS_DIR, "$PLUGINS_DIR", [Define the plugin directory])
 419 AC_SUBST(PLUGINS_DIR)
 420
 421 dnl Set location of uninstalled plugin directory
 422 PLUGINS_BUILDDIR=`pwd`
 423 AC_DEFINE_UNQUOTED(PLUGINS_BUILDDIR, "$PLUGINS_BUILDDIR", [Define the uninstalled plugin directory])
 424 AC_SUBST(PLUGINS_BUILDDIR)
 425
 426 dnl since glib and xml are package deps, there's no need to include their cflags
 427 dnl in the pkg-config file
 428
 429 dnl for pkg-config
 430 GST_PKG_CFLAGS=$GST_EXT_CFLAGS
 431 GST_PKG_LIBS=$GST_EXT_LIBS
 432 AC_SUBST(GST_PKG_CFLAGS)
 433 AC_SUBST(GST_PKG_LIBS)
 434
 435 dnl finalize _CFLAGS and _LIBS
 436 dnl add GLIB and XML if necessary to EXT_*
 437 GST_CFLAGS="$GST_EXT_CFLAGS $XML_CFLAGS $GLIB_CFLAGS"
 438 GST_LIBS="$GST_EXT_LIBS $XML_LIBS $GLIB_LIBS -lpopt"
 439
 440 dnl Private vars for libgst only
 441 LIBGST_LIBS="$GST_LIBS"
 442 LIBGST_CFLAGS="$GST_CFLAGS -I\$(top_srcdir) $GST_ERROR"
 443 AC_SUBST(LIBGST_LIBS)
 444 AC_SUBST(LIBGST_CFLAGS)
 445
 446 dnl Vars for everyone else
 447 GST_INT_LIBS="\$(top_builddir)/gst/libgstreamer-$GST_MAJORMINOR.la"
 448 GST_INT_CFLAGS="$GST_INT_CFLAGS -I\$(top_srcdir)/libs -I\$(top_srcdir)/include"
 449
 450 AC_SUBST(GST_CFLAGS, "$LIBGST_CFLAGS $GST_INT_CFLAGS")
 451 AC_SUBST(GST_LIBS, "$LIBGST_LIBS $GST_INT_LIBS")
 452
 453 GST_PLUGIN_LDFLAGS="-module -avoid-version"
 454 AC_SUBST(GST_PLUGIN_LDFLAGS, "$GST_PLUGIN_LDFLAGS")
 455
 456 AC_CONFIG_SUBDIRS(libs/ext/cothreads)
 457
 458 dnl ##################################################
 459 dnl # deps for examples from manual                  #
 460 dnl ##################################################
 461
 462 PKG_CHECK_MODULES(LIBGNOMEUI, libgnomeui-2.0,
 463                   HAVE_LIBGNOMEUI="yes", HAVE_LIBGNOMEUI="no")
 464 AC_SUBST(LIBGNOMEUI_CFLAGS)
 465 AC_SUBST(LIBGNOMEUI_LIBS)
 466 AM_CONDITIONAL(HAVE_LIBGNOMEUI, test "x$HAVE_LIBGNOMEUI" = "xyes")
 467
 468 dnl ##################################################
 469 dnl # Prepare informative messages to display at end #
 470 dnl ##################################################
 471
 472 infomessages=
 473
 474 if test "x$PLUGINS_USE_BUILDDIR" = xyes; then
 475   infomessages="$infomessages
 476 *** Warning: You have configured using the --enable-plugin-builddir option.
 477
 478 This option is for development purposes only: binaries built with
 479 it should be used with code in the build tree only.  To build an
 480 installable version, use ./configure without the --enable-plugin-builddir
 481 option.  Note that the autogen.sh script supplies the plugin builddir
 482 option automatically -- run ./autogen.sh -- --disable-plugin-builddir to make
 483 an installable build.
 484
 485 "
 486 fi
 487
 488 dnl #########################
 489 dnl # Make the output files #
 490 dnl #########################
 491
 492 dnl libs/ext/Makefile
 493 dnl nothing there yet !
 494 AC_OUTPUT(
 495 Makefile
 496 include/Makefile
 497 gst/Makefile
 498 gst/gstversion.h
 499 gst/autoplug/Makefile
 500 gst/indexers/Makefile
 501 gst/elements/Makefile
 502 gst/parse/Makefile
 503 gst/schedulers/Makefile
 504 gst/types/Makefile
 505 gst/registries/Makefile
 506 libs/Makefile
 507 libs/gst/Makefile
 508 libs/gst/bytestream/Makefile
 509 libs/gst/getbits/Makefile
 510 libs/gst/putbits/Makefile
 511 libs/gst/control/Makefile
 512 libs/ext/Makefile
 513 tests/Makefile
 514 tests/bufspeed/Makefile
 515 tests/memchunk/Makefile
 516 tests/muxing/Makefile
 517 tests/seeking/Makefile
 518 tests/sched/Makefile
 519 tests/threadstate/Makefile
 520 testsuite/Makefile
 521 testsuite/bytestream/Makefile
 522 testsuite/caps/Makefile
 523 testsuite/cleanup/Makefile
 524 testsuite/clock/Makefile
 525 testsuite/dynparams/Makefile
 526 testsuite/elements/Makefile
 527 testsuite/indexers/Makefile
 528 testsuite/parse/Makefile
 529 testsuite/plugin/Makefile
 530 testsuite/refcounting/Makefile
 531 testsuite/threads/Makefile
 532 examples/Makefile
 533 examples/autoplug/Makefile
 534 examples/cutter/Makefile
 535 examples/helloworld/Makefile
 536 examples/helloworld2/Makefile
 537 examples/launch/Makefile
 538 examples/manual/Makefile
 539 examples/mixer/Makefile
 540 examples/pingpong/Makefile
 541 examples/plugins/Makefile
 542 examples/queue/Makefile
 543 examples/queue2/Makefile
 544 examples/queue3/Makefile
 545 examples/queue4/Makefile
 546 examples/thread/Makefile
 547 examples/typefind/Makefile
 548 examples/xml/Makefile
 549 tools/Makefile
 550 docs/Makefile
 551 docs/devhelp/Makefile
 552 docs/faq/Makefile
 553 docs/gst/Makefile
 554 docs/gst/gstreamer.types
 555 docs/libs/Makefile
 556 docs/manual/Makefile
 557 docs/pwg/Makefile
 558 docs/plugins/Makefile
 559 docs/plugins/gstreamer-plugins.types
 560 docs/xsl/Makefile
 561 pkgconfig/Makefile
 562 stamp.h
 563 pkgconfig/gstreamer.pc
 564 pkgconfig/gstreamer-uninstalled.pc
 565 pkgconfig/gstreamer-control.pc
 566 pkgconfig/gstreamer-control-uninstalled.pc
 567 gstreamer.spec,
 568 echo "$infomessages", infomessages="$infomessages"
 569 )