configure.ac

   1 dnl autoconf configuration file for gst-plugins
   2 AC_INIT
   3 AC_CANONICAL_TARGET
   4
   5 dnl We disable static building for development, for time savings
   6 dnl this goes before AS_LIBTOOL to appease autoconf
   7 dnl *NOTE*: dnl this line before release, so release does static too
   8 AM_DISABLE_STATIC
   9
  10 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  11 AM_MAINTAINER_MODE
  12
  13 dnl when going to/from release please set the nano (fourth number) right !
  14 dnl releases only do Wall, cvs and prerelease does Werror too
  15 AS_VERSION(gst-plugins-base, GST_PLUGINS_VERSION, 0, 9, 0, 1, GST_CVS="no", GST_CVS="yes")
  16
  17 AM_INIT_AUTOMAKE($PACKAGE,$VERSION)
  18
  19 dnl our libraries and install dirs use major.minor as a version
  20 GST_MAJORMINOR=$GST_PLUGINS_VERSION_MAJOR.$GST_PLUGINS_VERSION_MINOR
  21 dnl we override it here if we need to for the release candidate of new series
  22 GST_MAJORMINOR=0.9
  23 AC_SUBST(GST_MAJORMINOR)
  24
  25 dnl CURRENT, REVISION, AGE
  26 dnl - library source changed -> increment REVISION
  27 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  28 dnl - interfaces added -> increment AGE
  29 dnl - interfaces removed -> AGE = 0
  30 dnl for 0.8.3 release, gst_play_get_all_by_interface was added, so update
  31 AS_LIBTOOL(GST_PLUGINS, 1, 0, 1)
  32 AM_PROG_LIBTOOL
  33
  34 dnl FIXME take something else ?
  35 AC_CONFIG_SRCDIR([gst/sine/gstsinesrc.c])
  36 AM_CONFIG_HEADER(config.h)
  37
  38 dnl Add parameters for aclocal
  39 dnl (This must come after AM_INIT_AUTOMAKE, since it modifies ACLOCAL)
  40 ACLOCAL_FLAGS="-I m4 -I common/m4"
  41 AC_SUBST(ACLOCAL_AMFLAGS, $ACLOCAL_FLAGS)
  42
  43 AC_PROG_CC
  44 AM_PROG_CC_STDC
  45 AM_PROG_AS
  46 AS="${CC}"
  47 AS_PROG_OBJC
  48
  49 dnl the gettext stuff needed
  50 AM_GNU_GETTEXT_VERSION(0.11.5)
  51 AM_GNU_GETTEXT([external])
  52
  53 GETTEXT_PACKAGE=gst-plugins-base-$GST_MAJORMINOR
  54 AC_SUBST(GETTEXT_PACKAGE)
  55 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE], "$GETTEXT_PACKAGE",
  56                    [gettext package name])
  57
  58 dnl define LOCALEDIR in config.h
  59 AS_AC_EXPAND(LOCALEDIR, $datadir/locale)
  60 AC_DEFINE_UNQUOTED([LOCALEDIR], "$LOCALEDIR",
  61                    [gettext locale dir])
  62
  63 dnl decide on error flags
  64 AS_COMPILER_FLAG(-Wall, GST_WALL="yes", GST_WALL="no")
  65
  66 if test "x$GST_WALL" = "xyes"; then
  67    GST_ERROR="$GST_ERROR -Wall"
  68
  69 dnl   if test "x$GST_CVS" = "xyes"; then
  70 dnl     AS_COMPILER_FLAG(-Werror,GST_ERROR="$GST_ERROR -Werror",GST_ERROR="$GST_ERROR")
  71 dnl   fi
  72 fi
  73
  74 dnl determine c++ compiler
  75 AC_PROG_CXX
  76 dnl determine if c++ is available on this system
  77 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
  78 dnl determine c++ preprocessor
  79 AC_PROG_CXXCPP
  80 AC_ISC_POSIX
  81
  82 AC_HEADER_STDC([])
  83 AC_C_INLINE
  84 AX_CREATE_STDINT_H
  85
  86 dnl Check for malloc.h
  87 AC_CHECK_HEADER(malloc.h,[
  88   AC_DEFINE(HAVE_MALLOC_H, 1, [whether malloc.h available])
  89 ])
  90
  91 dnl Check for a way to display the function name in debug output
  92 GST_CHECK_FUNCTION()
  93
  94 dnl define correct errorlevel for debugging messages. We want to have GST_ERROR
  95 dnl messages printed when running cvs builds
  96 if test "x$GST_CVS" = "xyes"; then
  97   AC_DEFINE(GST_LEVEL_DEFAULT, GST_LEVEL_ERROR, [Default errorlevel to use])
  98 fi
  99
 100 dnl Check for FIONREAD ioctl declaration :
 101 GST_CHECK_FIONREAD()
 102
 103 DEFAULT_AUDIOSINK="osssink"
 104 DEFAULT_VIDEOSINK="xvimagesink"
 105 DEFAULT_AUDIOSRC="osssrc"
 106 DEFAULT_VIDEOSRC="v4lsrc"
 107 DEFAULT_VISUALIZER="goom"
 108 case "$host" in
 109   *-sun-* | *pc-solaris* )
 110     DEFAULT_AUDIOSINK="sunaudiosink"
 111     DEFAULT_VIDEOSINK="ximagesink"
 112     DEFAULT_AUDIOSRC="sunaudiosrc"
 113     ;;
 114   *-darwin* )
 115     DEFAULT_AUDIOSINK="osxaudiosink"
 116     DEFAULT_AUDIOSRC="osxaudiosrc"
 117     DEFAULT_VIDEOSINK="osxvideosink"
 118     ;;
 119 esac
 120
 121 AC_SUBST(DEFAULT_AUDIOSINK)
 122 AC_DEFINE_UNQUOTED(DEFAULT_AUDIOSINK,"$DEFAULT_AUDIOSINK",[Default audio sink])
 123 AC_SUBST(DEFAULT_AUDIOSRC)
 124 AC_DEFINE_UNQUOTED(DEFAULT_AUDIOSRC,"$DEFAULT_AUDIOSRC",[Default audio source])
 125 AC_SUBST(DEFAULT_VIDEOSINK)
 126 AC_DEFINE_UNQUOTED(DEFAULT_VIDEOSINK,"$DEFAULT_VIDEOSINK",[Default video sink])
 127 AC_SUBST(DEFAULT_VIDEOSRC)
 128 AC_DEFINE_UNQUOTED(DEFAULT_VIDEOSRC,"$DEFAULT_VIDEOSRC",[Default video source])
 129 AC_SUBST(DEFAULT_VISUALIZER)
 130 AC_DEFINE_UNQUOTED(DEFAULT_VISUALIZER,"$DEFAULT_VISUALIZER",[Default visualizer])
 131
 132 dnl ############################################
 133 dnl # Super Duper options for plug-in building #
 134 dnl ############################################
 135
 136 dnl ext plug-ins; plug-ins that have external dependencies
 137 GST_CHECK_FEATURE(EXTERNAL, [enable building of plug-ins with external deps],,
 138 [HAVE_EXTERNAL=yes],enabled,
 139 [
 140   AC_MSG_WARN(building external plug-ins)
 141   BUILD_EXTERNAL="yes"
 142 ],[
 143   AC_MSG_WARN(all plug-ins with external dependencies will not be built)
 144   BUILD_EXTERNAL="no"
 145 ])
 146 # make BUILD_EXTERNAL available to Makefile.am
 147 AM_CONDITIONAL(BUILD_EXTERNAL, test "x$BUILD_EXTERNAL" = "xyes")
 148
 149 dnl experimental plug-ins; stuff that hasn't had the dust settle yet
 150 dnl read 'builds, but might not work'UTO
 151 GST_CHECK_FEATURE(EXPERIMENTAL, [enable building of experimental plug-ins],,
 152 [HAVE_EXPERIMENTAL=yes],disabled,
 153 [
 154   AC_MSG_WARN(building experimental plug-ins)
 155   USE_TARKIN="yes"
 156 ],[
 157   AC_MSG_NOTICE(not building experimental plug-ins)
 158   USE_TARKIN="no"
 159 ])
 160
 161 dnl broken plug-ins; stuff that doesn't seem to build at the moment
 162 GST_CHECK_FEATURE(BROKEN, [enable building of broken plug-ins],,
 163 HAVE_BROKEN=yes,disabled,
 164 [
 165   AC_MSG_WARN([building broken plug-ins -- no bug reports on these, only patches :)])
 166 ],[
 167   AC_MSG_NOTICE([not building broken plug-ins])
 168 ])
 169
 170 dnl ##############################
 171 dnl # Do automated configuration #
 172 dnl ##############################
 173
 174 dnl Check for tools:
 175 dnl ================
 176
 177 dnl allow for different autotools
 178 AS_AUTOTOOLS_ALTERNATE()
 179
 180 dnl modify pkg-config path
 181 AC_ARG_WITH(pkg-config-path,
 182    AC_HELP_STRING([--with-pkg-config-path],[colon-separated list of pkg-config(1) dirs]),
 183    [export PKG_CONFIG_PATH=${withval}])
 184
 185 GST_DOC()
 186 dnl check architecture
 187 GST_ARCH()
 188
 189 dnl check for gconftool-2
 190
 191 dnl this macro defines an am conditional, so it needs to be run always
 192 AM_GCONF_SOURCE_2
 193
 194 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONFTOOL, true)
 195 GST_CHECK_FEATURE(GCONFTOOL, [GConf schemas], , [
 196   AC_PATH_PROG(GCONFTOOL, gconftool-2, no)
 197   if test x$GCONFTOOL = xno; then
 198     AC_MSG_WARN(Not installing GConf schemas)
 199     HAVE_GCONFTOOL="no"
 200   else
 201     HAVE_GCONFTOOL="yes"
 202   fi
 203   AC_SUBST(HAVE_GCONFTOOL)
 204 ])
 205
 206 dnl check for GConf libraries
 207 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONF, true)
 208 GST_CHECK_FEATURE(GCONF, [GConf libraries], , [
 209   PKG_CHECK_MODULES(GCONF, gconf-2.0, HAVE_GCONF="yes", HAVE_GCONF="no")
 210   AC_SUBST(GCONF_CFLAGS)
 211   AC_SUBST(GCONF_LIBS)
 212 ])
 213
 214 dnl check for gstreamer
 215 dnl uninstalled is selected preferentially -- see pkg-config(1)
 216 GST_REQ=0.9.0
 217 PKG_CHECK_MODULES(GST, gstreamer-$GST_MAJORMINOR >= $GST_REQ,
 218   HAVE_GST="yes", HAVE_GST="no")
 219
 220 if test "x$HAVE_GST" = "xno"; then
 221   AC_MSG_ERROR(no GStreamer found)
 222 fi
 223
 224 GST_TOOLS_DIR=`pkg-config --variable=toolsdir gstreamer-$GST_MAJORMINOR`
 225 if test -z $GST_TOOLS_DIR; then
 226   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 227 fi
 228 AC_SUBST(GST_TOOLS_DIR)
 229
 230 dnl check for gstreamer-control; uninstalled is selected preferentially
 231 PKG_CHECK_MODULES(GST_CONTROL, gstreamer-control-$GST_MAJORMINOR >= $GST_REQ,
 232   HAVE_GST_CONTROL="yes", HAVE_GST_CONTROL="no")
 233
 234 if test "x$HAVE_GST_CONTROL" = "xno"; then
 235   AC_MSG_ERROR(no GStreamer Control Libs found)
 236 fi
 237
 238 AC_SUBST(GST_CONTROL_LIBS)
 239
 240 PKG_CHECK_MODULES(GST_BASE, gstreamer-base-$GST_MAJORMINOR >= $GST_REQ,
 241   HAVE_GST_BASE="yes", HAVE_GST_BASE="no")
 242
 243 if test "x$HAVE_GST_BASE" = "xno"; then
 244   AC_MSG_ERROR(no libgstbase found)
 245 fi
 246
 247 AC_SUBST(GST_BASE_LIBS)
 248
 249 dnl Determine endianness
 250 AC_C_BIGENDIAN
 251
 252 dnl Check for fast float to int casting as defined in C99
 253 AC_C99_FUNC_LRINT()
 254 AC_C99_FUNC_LRINTF()
 255
 256 dnl Check for essential libraries first:
 257 dnl ====================================
 258
 259 GST_GLIB2_CHECK()
 260
 261 dnl Check for additional libraries that we might use:
 262 dnl =================================================
 263 dnl GTK
 264 HAVE_GTK=NO
 265 PKG_CHECK_MODULES(GTK2, gtk+-2.0 >= 2.2.0, HAVE_GTK_22=yes, HAVE_GTK_22=no)
 266 if test "x$HAVE_GTK_22" = "xyes"; then
 267   HAVE_GTK=yes
 268   GTK_VERSION=`$PKG_CONFIG --variable=gtk_binary_version gtk+-2.0`
 269   AC_SUBST(GTK_VERSION)
 270   GTK_PREFIX=`$PKG_CONFIG --variable=prefix gdk-pixbuf-2.0`
 271   GDK_PIXBUF_LIBDIR=`$PKG_CONFIG --variable=libdir gdk-pixbuf-2.0`
 272   GDK_PIXBUF_PREFIXDIR=`$PKG_CONFIG --variable=prefix gdk-pixbuf-2.0`
 273   AC_SUBST(GTK_BASE_DIR)
 274 else
 275   PKG_CHECK_MODULES(GTK2, gtk+-2.0, HAVE_GTK_20=yes, HAVE_GTK_20=no)
 276 fi
 277 if test "x$HAVE_GTK_20" = "xyes"; then
 278   HAVE_GTK=yes
 279 fi
 280 GTK_CFLAGS=$GTK2_CFLAGS
 281 GTK_LIBS=$GTK2_LIBS
 282 AC_SUBST(GTK_LIBS)
 283 AC_SUBST(GTK_CFLAGS)
 284 AC_SUBST(HAVE_GTK)
 285
 286 # gdk_pixbuf gstreamer loader is considered experimental, so disable
 287 # by default
 288 if test "x$HAVE_GTK_22" = "xyes"; then
 289   HAVE_GDK_LOADERS=yes
 290 else
 291   HAVE_GDK_LOADERS=no
 292 fi
 293
 294 # we set the defaults always to make sure we have non-empty variables
 295 # for the Makefile
 296
 297 # by default, stick to prefix
 298 GDK_PIXBUF_LOADER_DIR=${libdir}/gtk-2.0/\${GTK_VERSION}/loaders
 299 GDK_PIXBUF_CONF_DIR=${sysconfdir}/gtk-2.0
 300
 301
 302 AC_ARG_ENABLE(gdk-pixbuf-loader,
 303   AC_HELP_STRING([--enable-gdk-pixbuf-loader],
 304               [whether to enable building of gdk_pixbuf loader]),
 305               :, HAVE_GDK_LOADERS="no")
 306
 307 if test "x$HAVE_GDK_LOADERS" = "xyes"; then
 308   AC_PATH_PROG(QUERYLOADERS, gdk-pixbuf-query-loaders, no)
 309   # allow customization of pixbuf loader install location
 310   # when nothing specified, adhere to prefix settings
 311   # when called without any option with this argument, autodetect
 312   # when called with a path, set to the given path
 313
 314   AC_ARG_WITH(gdk-pixbuf-loader-dir,
 315      AC_HELP_STRING([--with-gdk-pixbuf-loader-dir],
 316         [directory to install the gdk_pixbuf loader (none for pkg-config default)]),
 317      [
 318       if test "x${withval}" != xyes ; then
 319         GDK_PIXBUF_LOADER_DIR="${withval}"
 320       else
 321         GDK_PIXBUF_LOADER_DIR="$GDK_PIXBUF_LIBDIR/gtk-2.0/\$GTK_VERSION/loaders"
 322       fi
 323      ]
 324   )
 325   AS_AC_EXPAND(GDK_PIXBUF_LOADER_DIR, $GDK_PIXBUF_LOADER_DIR)
 326   AC_SUBST(GDK_PIXBUF_LOADER_DIR)
 327   AC_MSG_NOTICE([Putting GTK+-2 pixbuf loaders in $GDK_PIXBUF_LOADER_DIR])
 328
 329   # allow customization of pixbuf loader configuration file
 330   # when nothing specified, adhere to prefix settings
 331   # when called without any option with this argument, autodetect
 332   # when called with a path, set to the given path
 333
 334   AC_ARG_WITH(gdk-pixbuf-conf-dir,
 335      AC_HELP_STRING([--with-gdk-pixbuf-conf-dir],
 336         [directory to install the gdk_pixbuf config (none for pkg-config default)]),
 337      [
 338       if test "x${withval}" != xyes ; then
 339         GDK_PIXBUF_CONF_DIR="${withval}"
 340       else
 341         GDK_PIXBUF_CONF_DIR="$GDK_PIXBUF_PREFIXDIR/etc/gtk-2.0/"
 342       fi
 343      ]
 344   )
 345   AS_AC_EXPAND(GDK_PIXBUF_CONF_DIR, $GDK_PIXBUF_CONF_DIR)
 346   AC_SUBST(GDK_PIXBUF_CONF_DIR)
 347   AC_MSG_NOTICE([Putting GTK+-2 pixbuf loader config in $GDK_PIXBUF_CONF_DIR])
 348 fi
 349 AM_CONDITIONAL(HAVE_GDK_LOADERS, test "x$HAVE_GDK_LOADERS" = "xyes")
 350
 351 PKG_CHECK_MODULES(LIBOIL, liboil-0.2, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 352 #PKG_CHECK_MODULES(LIBOIL, liboil-0.3 >= 0.3.0, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 353 AC_SUBST(LIBOIL_CFLAGS)
 354 AC_SUBST(LIBOIL_LIBS)
 355 if test "x${HAVE_LIBOIL}" = xyes ; then
 356   #AC_DEFINE_UNQUOTED(HAVE_LIBOIL, 1, [Define if liboil is being used])
 357   true
 358 fi
 359
 360 dnl ===========================================================================
 361 dnl ============================= gst plug-ins ================================
 362 dnl ===========================================================================
 363
 364 plugindir="\$(libdir)/gstreamer-$GST_MAJORMINOR"
 365 AC_SUBST(plugindir)
 366
 367 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '[_]*(gst_|Gst|GST_).*' $GST_LIBS"
 368 AC_SUBST(GST_PLUGIN_LDFLAGS)
 369
 370 dnl these are all the gst plug-ins, compilable without additional libs
 371 GST_PLUGINS_ALL="\
 372         adder \
 373         audioconvert \
 374         audioscale \
 375         ffmpegcolorspace \
 376         playback \
 377         sine \
 378         tags \
 379         tcp \
 380         typefind \
 381         videotestsrc \
 382         "
 383
 384 dnl see if we can build C++ plug-ins
 385 if test "x$HAVE_CXX" = "xyes"; then
 386   GST_PLUGINS_ALL="$GST_PLUGINS_ALL"
 387 else
 388   AC_MSG_WARN([Not compiling plug-ins requiring C++ compiler])
 389 fi
 390
 391 AC_SUBST(GST_PLUGINS_ALL)
 392
 393 GST_PLUGINS_SELECTED=""
 394
 395 AC_ARG_WITH(plugins,
 396     AC_HELP_STRING([--with-plugins],[comma-separated list of plug-ins to compile]),
 397     [for i in `echo $withval | tr , ' '`; do
 398         if echo $GST_PLUGINS_ALL | grep $i > /dev/null
 399         then
 400             GST_PLUGINS_SELECTED="$GST_PLUGINS_SELECTED $i"
 401         else
 402             echo "plug-in $i not recognized, ignoring..."
 403         fi
 404     done],
 405     [GST_PLUGINS_SELECTED=$GST_PLUGINS_ALL])
 406
 407 AC_SUBST(GST_PLUGINS_SELECTED)
 408
 409 dnl ==========================================================================
 410 dnl ============================= sys plug-ins ================================
 411 dnl ==========================================================================
 412
 413 dnl Check for X11
 414 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 415 GST_CHECK_FEATURE(X, [X libraries and plugins],
 416                   [ximagesink], [
 417   AC_PATH_XTRA
 418   dnl now try to find the HEADER
 419   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 420
 421   if test "x$HAVE_X" = "xno"
 422   then
 423     AC_MSG_NOTICE([cannot find X11 development files])
 424   else
 425     dnl this is much more than we want
 426     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 427     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 428     dnl it does not add the libs; therefore we add them here
 429     X_LIBS="$X_LIBS -lX11"
 430     AC_SUBST(X_CFLAGS)
 431     AC_SUBST(X_LIBS)
 432   fi
 433   AC_SUBST(HAVE_X)
 434 ])
 435
 436 dnl *** XVideo ***
 437 dnl Look for the PIC library first, Debian requires it.
 438 dnl Check debian-devel archives for gory details.
 439 dnl 20020110:
 440 dnl At the moment XFree86 doesn't distribute shared libXv due
 441 dnl to unstable API.  On many platforms you CAN NOT link a shared
 442 dnl lib to a static non-PIC lib.  This is what the xvideo GStreamer
 443 dnl plug-in wants to do.  So Debian distributes a PIC compiled
 444 dnl version of the static lib for plug-ins to link to when it is
 445 dnl inappropriate to link the main application to libXv directly.
 446 dnl FIXME: add check if this platform can support linking to a
 447 dnl        non-PIC libXv, if not then don not use Xv.
 448 dnl FIXME: perhaps warn user if they have a shared libXv since
 449 dnl        this is an error until XFree86 starts shipping one
 450
 451 dnl Check for Xv extension
 452 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 453 GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 454                   [xvimagesink], [
 455   if test x$HAVE_X = xyes; then
 456     AC_CHECK_LIB(Xv_pic, XvQueryExtension,
 457                  HAVE_XVIDEO="yes", HAVE_XVIDEO="no",
 458                  $X_LIBS -lXext)
 459
 460     if test x$HAVE_XVIDEO = xyes; then
 461       XVIDEO_LIBS="-lXv_pic -lXext"
 462       AC_SUBST(XVIDEO_LIBS)
 463     else
 464       dnl try again using something else if we didn't find it first
 465       if test x$HAVE_XVIDEO = xno; then
 466         AC_CHECK_LIB(Xv, XvQueryExtension,
 467                    HAVE_XVIDEO="yes", HAVE_XVIDEO="no",
 468                    $X_LIBS -lXext)
 469
 470         if test x$HAVE_XVIDEO = xyes; then
 471           XVIDEO_LIBS="-lXv -lXext"
 472           AC_SUBST(XVIDEO_LIBS)
 473         fi
 474       fi
 475     fi
 476   fi
 477 ])
 478
 479 dnl check for X Shm
 480 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 481 GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], xshm, [
 482   if test x$HAVE_X = xyes; then
 483     AC_CHECK_LIB(Xext, XShmAttach,
 484                  HAVE_XSHM="yes", HAVE_XSHM="no",
 485                  $X_LIBS)
 486     if test "x$HAVE_XSHM" = "xyes"; then
 487       XSHM_LIBS="-lXext"
 488     else
 489       dnl On AIX, it is in XextSam instead, but we still need -lXext
 490       AC_CHECK_LIB(XextSam, XShmAttach,
 491                    HAVE_XSHM="yes", HAVE_XSHM="no",
 492                    $X_LIBS)
 493       if test "x$HAVE_XSHM" = "xyes"; then
 494         XSHM_LIBS="-lXext -lXextSam"
 495       fi
 496     fi
 497   fi
 498 ], , [
 499   AC_SUBST(HAVE_XSHM)
 500   AC_SUBST(XSHM_LIBS)
 501 ] )
 502
 503 dnl v4l/v4l2 checks have been moved down because they require X
 504
 505 dnl *** Video 4 Linux ***
 506 dnl for information about the header/define, see sys/v4l/gstv4lelement.h
 507 dnl renamed to GST_V4L in accordance with V4L2 below
 508 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L, true)
 509 GST_CHECK_FEATURE(GST_V4L, [Video 4 Linux], v4lsrc v4lmjpegsrc v4lmjpegsink, [
 510   # first check X
 511   HAVE_GST_V4L="no"
 512   if test "$HAVE_X" = "yes"
 513   then
 514     AC_CHECK_DECL(VID_TYPE_MPEG_ENCODER, HAVE_GST_V4L="yes", HAVE_GST_V4L="no", [
 515 #include <sys/types.h>
 516 #define _LINUX_TIME_H
 517 #define __user
 518 #include <linux/videodev.h>
 519     ])
 520   fi
 521 ])
 522
 523 dnl *** Video 4 Linux 2 ***
 524 dnl for information about the header/define, see sys/v4l2/gstv4l2element.h
 525 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 526 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 527 GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], v4l2src, [
 528   HAVE_GST_V4L2="no"
 529   if test "$HAVE_X" = "yes"
 530   then
 531     AC_MSG_CHECKING([Checking for uptodate v4l2 installation])
 532     AC_TRY_COMPILE([
 533 #include <sys/types.h>
 534 #include <linux/types.h>
 535 #define _LINUX_TIME_H
 536 #define __user
 537 #include <linux/videodev2.h>
 538 #if defined(V4L2_MAJOR_VERSION) || defined(V4L2_MINOR_VERSION)
 539 #error too early v4l2 version or no v4l2 at all
 540 #endif
 541     ], [
 542 return 0;
 543     ], [ HAVE_GST_V4L2="yes" && AC_MSG_RESULT(yes)],
 544        [ HAVE_GST_V4L2="no"  && AC_MSG_RESULT(no) &&
 545          AC_CHECK_HEADER(linux/videodev2.h,
 546                          [ AC_MSG_WARN([video4linux2 headers were found, but they're old. Please update v4l2 to compile the v4l2 plugins])],
 547                          [ AC_MSG_WARN([video4linux2 was not found])])
 548        ])
 549   fi
 550   dnl check for missing v4l2_buffer declaration (see #135919)
 551   if [ test x$HAVE_GST_V4L2 = xyes ]; then
 552     MISSING_DECL=0
 553     AC_MSG_CHECKING(struct v4l2_buffer declaration)
 554     AC_TRY_COMPILE([
 555 #include <sys/types.h>
 556 #include <linux/types.h>
 557 #define _LINUX_TIME_H
 558 #define __user
 559 #include <linux/videodev2.h>
 560     ],[
 561 struct v4l2_buffer buf;
 562 buf.index = 0;
 563 return 0;
 564     ], [ AC_MSG_RESULT(yes) ], [ MISSING_DECL=1 && AC_MSG_RESULT(no) ])
 565     if [ test x$MISSING_DECL = x1 ]; then
 566       AC_DEFINE(GST_V4L2_MISSING_BUFDECL, 1, [struct v4l2_buffer missing])
 567     fi
 568   fi
 569 ])
 570
 571 dnl Next, check for the optional libraries:
 572 dnl These are all libraries used in building plug-ins
 573 dnl ================================================
 574 dnl let's try and sort them alphabetically, shall we ?
 575
 576 if test "x$BUILD_EXTERNAL" = "xyes"; then
 577
 578 AC_MSG_NOTICE(Checking for plug-in dependency libraries)
 579
 580 dnl *** alsa ***
 581 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 582 GST_CHECK_FEATURE(ALSA, [alsa plug-ins], gstalsa, [
 583   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 584     HAVE_ALSA="yes"
 585     AC_SUBST(ALSA_CFLAGS)
 586     AC_SUBST(ALSA_LIBS)
 587   ], [
 588     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 589   ])
 590 ])
 591
 592 dnl *** CDParanoia ***
 593 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 594 GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 595   GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 596                       cdda_open, -lm,
 597                       cdda_interface.h,
 598                       CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 599                       HEADER_DIR="no"
 600                       FOUND_CDPARANOIA="yes")
 601   if test "x$FOUND_CDPARANOIA" != "xyes";
 602   then
 603     GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 604                         cdda_open, -lm,
 605                         cdda/cdda_interface.h,
 606                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 607                         HEADER_DIR="yes"
 608                         FOUND_CDPARANOIA="yes")
 609   fi
 610   if test "x$HEADER_DIR" = "xyes";
 611   then
 612     AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 613                        defined if cdda headers are in a cdda/ directory)
 614   fi
 615   AC_SUBST(CDPARANOIA_LIBS)
 616 ])
 617 dnl FIXME : add second check somehow if that is necessary
 618 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 619 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 620
 621 dnl *** Gnome VFS ***
 622 translit(dnm, m, l) AM_CONDITIONAL(USE_GNOME_VFS, true)
 623 GST_CHECK_FEATURE(GNOME_VFS, [Gnome VFS], gnomevfssrc, [
 624   PKG_CHECK_MODULES(GNOME_VFS, gnome-vfs-2.0, HAVE_GNOME_VFS="yes", HAVE_GNOME_VFS="no")
 625   AC_SUBST(GNOME_VFS_CFLAGS)
 626   AC_SUBST(GNOME_VFS_LIBS)
 627 ])
 628
 629 dnl *** libvisual ***
 630 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 631 GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization plugins], libvisual, [
 632   PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0, HAVE_LIBVISUAL="yes", HAVE_LIBVISUAL="no")
 633   AC_SUBST(LIBVISUAL_CFLAGS)
 634   AC_SUBST(LIBVISUAL_LIBS)
 635 ])
 636
 637 dnl *** ogg ***
 638 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 639 GST_CHECK_FEATURE(OGG, [ogg de/encoder], oggdemux oggmux, [
 640   PKG_CHECK_MODULES(OGG, ogg >= 1.0, [
 641     HAVE_OGG="yes"
 642     AC_SUBST(OGG_CFLAGS)
 643     AC_SUBST(OGG_LIBS)
 644   ], [
 645     XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
 646     AS_SCRUB_INCLUDE(OGG_CFLAGS)
 647   ])
 648 ])
 649
 650 dnl *** theora ***
 651 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 652 GST_CHECK_FEATURE(THEORA, [ogg theora codec], theoradec theoraenc, [
 653   PKG_CHECK_MODULES(THEORA, theora, [
 654     HAVE_THEORA="yes"
 655     AC_SUBST(THEORA_LIBS)
 656     AC_SUBST(THEORA_CFLAGS)
 657   ], [
 658     GST_CHECK_LIBHEADER(THEORA, theora, theora_version_string, "-logg", theora/theora.h, THEORA_LIBS="-ltheora -logg")
 659     AC_SUBST(THEORA_LIBS)
 660   ])
 661 ])
 662
 663 dnl *** vorbis ***
 664 dnl AM_PATH_VORBIS only takes two options
 665 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 666 GST_CHECK_FEATURE(VORBIS, [vorbis plug-in], vorbisenc vorbisdec, [
 667   PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0, [
 668     HAVE_VORBIS="yes"
 669   ], [
 670     XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
 671     AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
 672   ])
 673 ])
 674 if test "x$HAVE_VORBIS" = "xyes"; then
 675   ac_cflags_save="$CFLAGS"
 676   dnl FIXME: does this work on non-gcc? -- Company
 677   CFLAGS="-Wall -Werror"
 678   AC_COMPILE_IFELSE(
 679     AC_LANG_PROGRAM([
 680 #include <vorbis/codec.h>
 681                      ],[
 682 vorbis_dsp_state *v;
 683
 684 vorbis_synthesis_restart (v);
 685                      ]), HAVE_VSR=yes, HAVE_VSR=no)
 686   if test "x$HAVE_VSR" = "xyes"; then
 687     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 688                        [defined if vorbis_synthesis_restart is present])
 689   fi
 690   CFLAGS="$ac_cflags_save"
 691 fi
 692
 693 fi dnl of EXT plugins
 694
 695 dnl Check for atomic.h
 696 dnl Note: use AC_CHECK_HEADER not AC_CHECK_HEADERS, because the latter
 697 dnl defines the wrong default symbol as well (HAVE_ASM_ATOMIC_H)
 698 AC_CHECK_HEADER(asm/atomic.h, HAVE_ATOMIC_H=yes, HAVE_ATOMIC_H=no)
 699 dnl Do a compile to check that it has atomic_set (eg, linux 2.0 didn't)
 700 if test x$HAVE_ATOMIC_H = xyes; then
 701   AC_TRY_RUN([
 702 #include "asm/atomic.h"
 703 main() { atomic_t t; atomic_set(&t,0); atomic_inc(&t); atomic_add(1,&t);return 0;}
 704   ],, [
 705     # Not successful
 706     if test x$HAVE_ATOMIC_H = xyes; then
 707       AC_MSG_WARN(Atomic reference counting is out of date: doing without.)
 708     fi
 709     HAVE_ATOMIC_H=no
 710   ], [
 711     # Cross compiling
 712     AC_MSG_RESULT(yes)
 713     AC_MSG_WARN(Can't check properly for atomic reference counting.  Assuming OK.)
 714   ])
 715 fi
 716
 717
 718 dnl ######################################################################
 719 dnl # Check command line parameters, and set shell variables accordingly #
 720 dnl ######################################################################
 721
 722 AC_ARG_ENABLE(atomic,
 723   AC_HELP_STRING([--enable-atomic],[use atomic reference counting header]),
 724 [case "${enableval}" in
 725   yes) USE_ATOMIC_H=$HAVE_ATOMIC_H;;
 726   noset) USE_ATOMIC_H=$HAVE_ATOMIC_H;;
 727   no)  USE_ATOMIC_H=no;;
 728   *) AC_MSG_ERROR(bad value ${enableval} for --enable-atomic) ;;
 729 esac],
 730 [USE_ATOMIC_H=$HAVE_ATOMIC_H]) dnl Default value
 731
 732 AC_ARG_ENABLE(profiling,
 733   AC_HELP_STRING([--enable-profiling],
 734                  [-pg to compiler commandline, for profiling]),
 735 [case "${enableval}" in
 736   yes) USE_PROFILING=yes ;;
 737   no)  UES_PROFILING=no ;;
 738   *) AC_MSG_ERROR(bad value ${enableval} for --enable-profiling) ;;
 739 esac],
 740 [USE_PROFILING=no]) dnl Default value
 741
 742 AC_ARG_ENABLE(tests,
 743   AC_HELP_STRING([--disable-tests],[disable building test apps]),
 744 [case "${enableval}" in
 745   yes) BUILD_TESTS=yes ;;
 746   no)  BUILD_TESTS=no ;;
 747   *) AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 748 esac],
 749 [BUILD_TESTS=yes]) dnl Default value
 750
 751 AC_ARG_ENABLE(examples,
 752   AC_HELP_STRING([--disable-examples],[disable building examples]),
 753 [case "${enableval}" in
 754   yes) BUILD_EXAMPLES=yes ;;
 755   no)  BUILD_EXAMPLES=no ;;
 756   *) AC_MSG_ERROR(bad value ${enableval} for --disable-examples) ;;
 757 esac],
 758 [BUILD_EXAMPLES=yes]) dnl Default value
 759
 760 dnl seeking needs freetype, so check for it here
 761 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 762   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 763 ])
 764 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 765 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 766 AC_SUBST(FT2_CFLAGS)
 767 AC_SUBST(FT2_LIBS)
 768
 769 dnl ################################################
 770 dnl # Set defines according to variables set above #
 771 dnl ################################################
 772
 773
 774 if test "x$USE_ATOMIC_H" = xyes; then
 775   AC_DEFINE(HAVE_ATOMIC_H, 1, [Define if atomic.h header file is available])
 776 fi
 777
 778 # do not use deprecated stuff
 779 GST_CFLAGS="$GST_CFLAGS -DGST_DISABLE_DEPRECATED"
 780
 781 if test "x$USE_DEBUG" = xyes; then
 782   GST_CFLAGS="$GST_CFLAGS -g"
 783 fi
 784
 785 dnl #############################
 786 dnl # Set automake conditionals #
 787 dnl #############################
 788
 789 dnl These should be "USE_*" instead of "HAVE_*", but some packages expect
 790 dnl HAVE_ and it is likely to be easier to stick with the old name
 791 AM_CONDITIONAL(HAVE_ATOMIC_H,       test "x$USE_ATOMIC_H" = "xyes")
 792
 793 AM_CONDITIONAL(EXPERIMENTAL,        test "$EXPERIMENTAL" = "$xyes")
 794 AM_CONDITIONAL(BROKEN,              test "$BROKEN" = "$xyes")
 795
 796 AM_CONDITIONAL(HAVE_NASM,           test "x$HAVE_NASM" = "xyes")
 797 AM_CONDITIONAL(HAVE_GTK,            test "x$HAVE_GTK" = "xyes")
 798 AM_CONDITIONAL(HAVE_GTK_DOC,        $HAVE_GTK_DOC)
 799 AM_CONDITIONAL(BUILD_DOCS,          test "x$BUILD_DOCS" = "xyes")
 800 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 801 AM_CONDITIONAL(BUILD_EXAMPLES,      test "x$BUILD_EXAMPLES" = "xyes")
 802 AM_CONDITIONAL(BUILD_PLUGIN_DOCS,   test "x$BUILD_PLUGIN_DOCS" = "xyes")
 803 AM_CONDITIONAL(HAVE_FIG2DEV_PNG,    $HAVE_FIG2DEV_PNG)
 804 AM_CONDITIONAL(HAVE_FIG2DEV_PDF,    $HAVE_FIG2DEV_PDF)
 805 AM_CONDITIONAL(HAVE_RAW1394,        test "x$HAVE_RAW1394" = "xyes")
 806
 807 dnl prefer internal headers to already installed ones
 808 dnl also add builddir include for enumtypes and marshal
 809 GST_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS $GST_ERROR"
 810
 811 AC_SUBST(GST_LIBS)
 812 AC_SUBST(GST_CFLAGS)
 813
 814 dnl ###########################
 815 dnl # Configure external libs #
 816 dnl ###########################
 817
 818 dnl ############################
 819 dnl # Set up some more defines #
 820 dnl ############################
 821
 822 dnl set license and copyright notice
 823 AC_DEFINE(GST_LICENSE, "LGPL", [GStreamer license])
 824
 825 dnl package name in plugins
 826 AC_ARG_WITH(package-name,
 827 AC_HELP_STRING([--with-package-name],[specify package name to use in plugins]),
 828 [case "${withval}" in
 829   yes) AC_MSG_ERROR(bad value ${withval} for --with-package-name) ;;
 830   no) AC_MSG_ERROR(bad value ${withval} for --with-package-name) ;;
 831   *) GST_PACKAGE="${withval}" ;;
 832 esac],
 833 [
 834 dnl default value
 835 if test "x$GST_CVS" = "xyes"
 836 then
 837   dnl nano >= 1
 838   GST_PACKAGE="GStreamer CVS/prerelease"
 839 else
 840   GST_PACKAGE="GStreamer source release"
 841 fi
 842 ]
 843 )
 844 AC_MSG_NOTICE(Using $GST_PACKAGE as package name)
 845 AC_DEFINE_UNQUOTED(GST_PACKAGE, "$GST_PACKAGE", [package name in plugins])
 846
 847 dnl package origin URL
 848 AC_ARG_WITH(package-origin,
 849 AC_HELP_STRING([--with-package-origin],[specify package origin URL to use in plugins]),
 850 [case "${withval}" in
 851   yes) AC_MSG_ERROR(bad value ${withval} for --with-package-origin) ;;
 852   no) AC_MSG_ERROR(bad value ${withval} for --with-package-origin) ;;
 853   *) GST_ORIGIN="${withval}" ;;
 854 esac],
 855 [GST_ORIGIN="http://gstreamer.freedesktop.org/"]) dnl Default value
 856 AC_MSG_NOTICE(Using $GST_ORIGIN as package origin)
 857 AC_DEFINE_UNQUOTED(GST_ORIGIN, "$GST_ORIGIN", [package origin])
 858
 859 dnl #########################
 860 dnl # Make the output files #
 861 dnl #########################
 862
 863 AC_CONFIG_FILES(
 864 Makefile
 865 gst-plugins-base.spec
 866 gst/Makefile
 867 gst/adder/Makefile
 868 gst/audioconvert/Makefile
 869 gst/audioscale/Makefile
 870 gst/ffmpegcolorspace/Makefile
 871 gst/playback/Makefile
 872 gst/sine/Makefile
 873 gst/tags/Makefile
 874 gst/tcp/Makefile
 875 gst/typefind/Makefile
 876 gst/videotestsrc/Makefile
 877 sys/Makefile
 878 sys/ximage/Makefile
 879 sys/xvimage/Makefile
 880 ext/Makefile
 881 ext/alsa/Makefile
 882 ext/cdparanoia/Makefile
 883 ext/gnomevfs/Makefile
 884 ext/libvisual/Makefile
 885 ext/ogg/Makefile
 886 ext/theora/Makefile
 887 ext/vorbis/Makefile
 888 gst-libs/Makefile
 889 gst-libs/gst/Makefile
 890 gst-libs/gst/audio/Makefile
 891 gst-libs/gst/colorbalance/Makefile
 892 gst-libs/gst/floatcast/Makefile
 893 gst-libs/gst/gconf/Makefile
 894 gst-libs/gst/mixer/Makefile
 895 gst-libs/gst/navigation/Makefile
 896 gst-libs/gst/propertyprobe/Makefile
 897 gst-libs/gst/riff/Makefile
 898 gst-libs/gst/tag/Makefile
 899 gst-libs/gst/tuner/Makefile
 900 gst-libs/gst/video/Makefile
 901 gst-libs/gst/xoverlay/Makefile
 902 gst-libs/ext/Makefile
 903 examples/seeking/Makefile
 904 examples/Makefile
 905 tools/Makefile
 906 gconf/Makefile
 907 gconf/gstreamer.schemas
 908 pkgconfig/Makefile
 909 pkgconfig/gstreamer-gconf.pc
 910 pkgconfig/gstreamer-gconf-uninstalled.pc
 911 pkgconfig/gstreamer-interfaces.pc
 912 pkgconfig/gstreamer-interfaces-uninstalled.pc
 913 pkgconfig/gstreamer-libs.pc
 914 pkgconfig/gstreamer-libs-uninstalled.pc
 915 pkgconfig/gstreamer-plugins.pc
 916 pkgconfig/gstreamer-plugins-uninstalled.pc
 917 po/Makefile.in
 918 common/Makefile
 919 common/m4/Makefile
 920 m4/Makefile
 921 )
 922 dnl disabled until it actually passes make distcheck
 923 dnl docs/Makefile
 924 dnl docs/libs/Makefile
 925 dnl docs/version.entities
 926 AC_OUTPUT
 927
 928 echo -n "configure: *** Plug-ins that will be built :"
 929 echo -e "$GST_PLUGINS_YES" | sort
 930 echo
 931 echo -n "configure: *** Plug-ins that will not be built :"
 932 echo -e "$GST_PLUGINS_NO" | sort
 933 echo
 934 if test "x$BUILD_EXTERNAL" = "xno"; then
 935   echo "configure: *** No external plug-ins will be built"
 936 fi