configure.ac

   1 AC_PREREQ([2.68])
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/pre
   8 AC_INIT([GStreamer Good Plug-ins],[1.1.0.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gst-plugins-good])
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.11 no-dist-gzip dist-xz tar-ustar])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  23
  24 dnl define the output header for config
  25 AC_CONFIG_HEADERS([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output with automake >= 1.11
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  35   [AM_DEFAULT_VERBOSITY=1
  36    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  37
  38 dnl our libraries and install dirs use GST_API_VERSION in the filename
  39 dnl to allow side-by-side installation of different API versions
  40 GST_API_VERSION=1.0
  41 AC_SUBST(GST_API_VERSION)
  42 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  43   [GStreamer API Version])
  44
  45 AG_GST_LIBTOOL_PREPARE
  46 AS_LIBTOOL(GST, 2, 0, 2)
  47
  48 dnl *** required versions of GStreamer stuff ***
  49 GST_REQ=1.1.0
  50 GSTPB_REQ=1.1.0
  51
  52 dnl *** autotools stuff ****
  53
  54 dnl allow for different autotools
  55 AS_AUTOTOOLS_ALTERNATE
  56
  57 dnl Add parameters for aclocal
  58 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  59
  60 dnl set up gettext
  61 dnl the version check needs to stay here because autopoint greps for it
  62 AM_GNU_GETTEXT_VERSION([0.17])
  63 AM_GNU_GETTEXT([external])
  64 AG_GST_GETTEXT([gst-plugins-good-$GST_API_VERSION])
  65
  66 dnl *** check for arguments to configure ***
  67
  68 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  69
  70 AG_GST_ARG_DEBUG
  71 AG_GST_ARG_PROFILING
  72 AG_GST_ARG_VALGRIND
  73 AG_GST_ARG_GCOV
  74
  75 AG_GST_ARG_EXAMPLES
  76
  77 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  78 AG_GST_ARG_WITH_PACKAGE_NAME
  79 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  80
  81 AG_GST_ARG_WITH_PLUGINS
  82
  83 AG_GST_ARG_ENABLE_EXTERNAL
  84
  85 AG_GST_ARG_ENABLE_EXPERIMENTAL
  86
  87 dnl *** checks for platform ***
  88
  89 dnl * hardware/architecture *
  90
  91 dnl common/m4/gst-arch.m4
  92 dnl check CPU type
  93 AG_GST_ARCH
  94
  95 dnl Determine endianness
  96 AC_C_BIGENDIAN
  97
  98 dnl *** checks for programs ***
  99
 100 dnl find a compiler
 101 AC_PROG_CC
 102 AC_PROG_CC_STDC
 103
 104 dnl determine c++ compiler
 105 AC_PROG_CXX
 106 dnl determine if c++ is available on this system
 107 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 108
 109 dnl determine c++ preprocessor
 110 dnl FIXME: do we need this ?
 111 AC_PROG_CXXCPP
 112
 113 AC_PROG_OBJC
 114
 115 dnl check if the compiler supports '-c' and '-o' options
 116 AM_PROG_CC_C_O
 117
 118 dnl find an assembler
 119 AM_PROG_AS
 120
 121 dnl check if the compiler supports do while(0) macros
 122 AG_GST_CHECK_DOWHILE_MACROS
 123
 124 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 125 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 126
 127 dnl check for documentation tools
 128 GTK_DOC_CHECK([1.12])
 129 AG_GST_PLUGIN_DOCS([1.12])
 130
 131 dnl *** checks for libraries ***
 132
 133 dnl check for libm, for sin()
 134 LT_LIB_M
 135 AC_SUBST(LIBM)
 136
 137 AC_CHECK_FUNCS(clock_gettime, [], [
 138   AC_CHECK_LIB(rt, clock_gettime, [
 139     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 140     LIBRT="-lrt"
 141     AC_SUBST([LIBRT])
 142   ])
 143 ])
 144
 145 dnl *** checks for header files ***
 146
 147 dnl check if we have ANSI C header files
 148 AC_HEADER_STDC
 149
 150 dnl used by ext/wavpack
 151 AX_CREATE_STDINT_H
 152
 153 dnl used in gst/udp
 154 AC_CHECK_HEADERS([sys/time.h])
 155
 156 dnl used in gst/udp
 157 AC_CHECK_HEADERS([sys/socket.h])
 158
 159 dnl *** checks for types/defines ***
 160
 161 dnl Check for FIONREAD ioctl declaration.  This check is needed
 162 dnl for the UDP plugin to build on Solaris
 163 GST_CHECK_FIONREAD
 164
 165 dnl *** checks for structures ***
 166
 167 dnl *** checks for compiler characteristics ***
 168
 169 dnl check if we have GCC inline-asm
 170 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 171 if test x$HAVE_GCC_ASM = xyes ; then
 172   AC_DEFINE(HAVE_GCC_ASM, 1,
 173     [Define if compiler supports gcc inline assembly])
 174 fi
 175 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 176
 177 dnl *** checks for library functions ***
 178
 179 LIBS_SAVE=$LIBS
 180 LIBS="$LIBS $LIBM"
 181 AC_CHECK_FUNCS(rint sinh cosh asinh fpclass)
 182 LIBS=$LIBS_SAVE
 183
 184 dnl Check whether isinf() is defined by math.h
 185 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
 186     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; int i=isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
 187 if test "$ac_cv_have_isinf" = "yes"
 188 then
 189     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
 190 fi
 191
 192 dnl Check for mmap (needed by electricfence plugin)
 193 AC_FUNC_MMAP
 194 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 195
 196 dnl Check for mmap (needed by electricfence plugin)
 197
 198 AC_CHECK_TYPE([struct ip_mreqn], [
 199               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
 200               [#include <netinet/in.h>])
 201
 202 dnl *** checks for dependency libraries ***
 203
 204
 205 dnl GLib
 206 GLIB_REQ=2.32.0
 207 AG_GST_GLIB_CHECK([$GLIB_REQ])
 208
 209 dnl Orc
 210 ORC_CHECK([0.4.16])
 211
 212 dnl checks for gstreamer
 213 dnl uninstalled is selected preferentially -- see pkg-config(1)
 214 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 215 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 216 AG_GST_CHECK_GST_CONTROLLER($GST_API_VERSION, [$GST_REQ], yes)
 217 AG_GST_CHECK_GST_NET($GST_API_VERSION, [$GST_REQ], yes)
 218 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 219 AG_GST_CHECK_GST_PLUGINS_BASE($GST_API_VERSION, [$GSTPB_REQ], yes)
 220
 221 GST_TOOLS_DIR=`$PKG_CONFIG --variable=toolsdir gstreamer-$GST_API_VERSION`
 222 if test -z $GST_TOOLS_DIR; then
 223   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 224 fi
 225 AC_SUBST(GST_TOOLS_DIR)
 226
 227 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 228 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 229
 230 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 231
 232 dnl Check for documentation xrefs
 233 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 234 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 235 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_API_VERSION`"
 236 AC_SUBST(GLIB_PREFIX)
 237 AC_SUBST(GST_PREFIX)
 238 AC_SUBST(GSTPB_PREFIX)
 239
 240 dnl GTK is optional and used in examples
 241 HAVE_GTK=no
 242 GTK_REQ=3.0.0
 243 if test "x$BUILD_EXAMPLES" = "xyes"; then
 244   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 245   dnl some examples need gtk+-x11
 246   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 247   AC_SUBST(GTK_LIBS)
 248   AC_SUBST(GTK_CFLAGS)
 249 fi
 250 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 251 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 252
 253 dnl *** set variables based on configure arguments ***
 254
 255 dnl set license and copyright notice
 256 GST_LICENSE="LGPL"
 257 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 258 AC_SUBST(GST_LICENSE)
 259
 260 dnl set location of plugin directory
 261 AG_GST_SET_PLUGINDIR
 262
 263 dnl set release date/time
 264 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 265   ["${srcdir}/gst-plugins-good.doap"],
 266   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 267
 268 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 269 dnl make sure it doesn't complain about unused variables if debugging is disabled
 270 NO_WARNINGS=""
 271 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 272
 273 dnl define an ERROR_CFLAGS Makefile variable
 274 dnl -Wundef: too many broken headers
 275 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 276       -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 277       -Wwrite-strings -Wold-style-definition -Waggregate-return
 278       -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 279       -Wnested-externs $NO_WARNINGS])
 280
 281 dnl define an ERROR_CXXFLAGS Makefile variable
 282 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 283         -Wmissing-declarations -Wredundant-decls
 284         -Wwrite-strings
 285         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 286         $NO_WARNINGS])
 287
 288 dnl define an ERROR_OBJCFLAGS Makefile variable
 289 AG_GST_SET_ERROR_OBJCFLAGS($FATAL_WARNINGS, [
 290       -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 291       -Wwrite-strings -Wold-style-definition
 292       -Winit-self -Wmissing-include-dirs -Wno-multichar
 293       -Wnested-externs $NO_WARNINGS])
 294
 295 dnl define correct level for debugging messages
 296 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 297
 298 dnl used in examples
 299 AG_GST_DEFAULT_ELEMENTS
 300
 301 dnl *** plug-ins to include ***
 302
 303 dnl Non ported plugins (non-dependant, then dependant)
 304 dnl Make sure you have a space before and after all plugins
 305 GST_PLUGINS_NONPORTED="osx_audio "
 306 AC_SUBST(GST_PLUGINS_NONPORTED)
 307
 308 dnl these are all the gst plug-ins, compilable without additional libs
 309 dnl videofilter is at the top because others depend on it
 310 AG_GST_CHECK_PLUGIN(alpha)
 311 AG_GST_CHECK_PLUGIN(apetag)
 312 AG_GST_CHECK_PLUGIN(audiofx)
 313 AG_GST_CHECK_PLUGIN(audioparsers)
 314 AG_GST_CHECK_PLUGIN(auparse)
 315 AG_GST_CHECK_PLUGIN(autodetect)
 316 AG_GST_CHECK_PLUGIN(avi)
 317 AG_GST_CHECK_PLUGIN(cutter)
 318 AG_GST_CHECK_PLUGIN(debugutils)
 319 AG_GST_CHECK_PLUGIN(deinterlace)
 320 AG_GST_CHECK_PLUGIN(effectv)
 321 AG_GST_CHECK_PLUGIN(equalizer)
 322 AG_GST_CHECK_PLUGIN(flv)
 323 AG_GST_CHECK_PLUGIN(flx)
 324 AG_GST_CHECK_PLUGIN(goom)
 325 AG_GST_CHECK_PLUGIN(goom2k1)
 326 AG_GST_CHECK_PLUGIN(icydemux)
 327 AG_GST_CHECK_PLUGIN(id3demux)
 328 AG_GST_CHECK_PLUGIN(imagefreeze)
 329 AG_GST_CHECK_PLUGIN(interleave)
 330 AG_GST_CHECK_PLUGIN(isomp4)
 331 AG_GST_CHECK_PLUGIN(law)
 332 AG_GST_CHECK_PLUGIN(level)
 333 AG_GST_CHECK_PLUGIN(matroska)
 334 AG_GST_CHECK_PLUGIN(monoscope)
 335 AG_GST_CHECK_PLUGIN(multifile)
 336 AG_GST_CHECK_PLUGIN(multipart)
 337 AG_GST_CHECK_PLUGIN(replaygain)
 338 AG_GST_CHECK_PLUGIN(rtp)
 339 AG_GST_CHECK_PLUGIN(rtpmanager)
 340 AG_GST_CHECK_PLUGIN(rtsp)
 341 AG_GST_CHECK_PLUGIN(shapewipe)
 342 AG_GST_CHECK_PLUGIN(smpte)
 343 AG_GST_CHECK_PLUGIN(spectrum)
 344 AG_GST_CHECK_PLUGIN(udp)
 345 AG_GST_CHECK_PLUGIN(videobox)
 346 AG_GST_CHECK_PLUGIN(videocrop)
 347 AG_GST_CHECK_PLUGIN(videofilter)
 348 AG_GST_CHECK_PLUGIN(videomixer)
 349 AG_GST_CHECK_PLUGIN(wavenc)
 350 AG_GST_CHECK_PLUGIN(wavparse)
 351 AG_GST_CHECK_PLUGIN(y4m)
 352
 353 dnl disable experimental plug-ins
 354 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 355   AG_GST_DISABLE_PLUGIN(monoscope)
 356 fi
 357
 358 dnl *** sys plug-ins ***
 359
 360 echo
 361 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 362 echo
 363
 364 dnl DirectSound
 365 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 366 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 367   HAVE_DIRECTSOUND="no"
 368   save_CFLAGS="$CFLAGS"
 369   save_LDFLAGS="$LDFLAGS"
 370   save_LIBS="$LIBS"
 371   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 372   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 373   LIBS="$LIBS -ldsound -ldxerr9 -luser32"
 374   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 375   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 376 #include <windows.h>
 377 #include <dxerr9.h>
 378 #include <dsound.h>
 379 ]], [[
 380   DXGetErrorString9 (0);
 381   DirectSoundCreate(NULL, NULL, NULL);
 382 ]])
 383 ],
 384     [HAVE_DIRECTSOUND="yes"],
 385     [HAVE_DIRECTSOUND="no"])
 386   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 387   CFLAGS=$save_CFLAGS
 388   LDFLAGS=$save_LDFLAGS
 389   LIBS=$save_LIBS
 390
 391   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 392     dnl this is much more than we want
 393     DIRECTSOUND_LIBS="-ldsound -ldxerr9 -luser32"
 394     AC_SUBST(DIRECTSOUND_CFLAGS)
 395     AC_SUBST(DIRECTSOUND_LDFLAGS)
 396     AC_SUBST(DIRECTSOUND_LIBS)
 397   fi
 398   AC_SUBST(HAVE_DIRECTSOUND)
 399 ])
 400
 401 dnl *** Win32 WaveOut ***
 402 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVEFORM, true)
 403 AG_GST_CHECK_FEATURE(WAVEFORM, [Win32 WaveForm], waveformsink, [
 404   AC_CHECK_HEADER(mmsystem.h, HAVE_WAVEFORM="yes", HAVE_WAVEFORM="no", [#include <windows.h>])
 405 ])
 406
 407 dnl *** OSS audio *** (Linux, *BSD)
 408 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 409 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 410  HAVE_OSS="yes"
 411 dnl Linux and newer BSD versions :
 412  AC_CHECK_HEADER(sys/soundcard.h, [
 413    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 414    ] , [
 415 dnl Some old BSD versions and also newer OpenBSD versions :
 416    AC_CHECK_HEADER(soundcard.h, [
 417      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 418      ], [
 419   dnl Some old BSD versions :
 420      AC_CHECK_HEADER(machine/soundcard.h, [
 421        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 422          [Define if OSS includes are in /machine/])
 423        ], [
 424        HAVE_OSS="no"
 425      ])
 426    ])
 427  ])
 428 ])
 429
 430 dnl *** oss4 ***
 431 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS4, true)
 432 AG_GST_CHECK_FEATURE(OSS4, [Open Sound System 4], oss4, [
 433   AC_MSG_CHECKING([Checking if we can build the OSS4 elements])
 434   AC_CHECK_HEADERS([fcntl.h sys/ioctl.h sys/stat.h sys/types.h],
 435       [test -z "$OSS4_MISSING_HEADER" && HAVE_OSS4="yes"],
 436       [OSS4_MISSING_HEADER="yes";HAVE_OSS4="no"])
 437 ])
 438
 439 dnl *** Sun Audio ***
 440 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 441 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 442   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 443 ])
 444
 445 dnl *** OSX Audio ***
 446 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 447 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 448   AC_CHECK_HEADER(CoreAudio/CoreAudio.h, HAVE_OSX_AUDIO="yes", HAVE_OSX_AUDIO="no")
 449 ])
 450
 451 dnl *** OS X video ***
 452 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 453 HAVE_OSX_VIDEO="no"
 454 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 455   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 456 ])
 457 dnl in case header OpenGL/gl.h is found on other platforms
 458 case "$host" in
 459   *-*darwin*)
 460     dnl do nothing
 461     ;;
 462   *)
 463     HAVE_OSX_VIDEO="no"
 464     ;;
 465 esac
 466
 467
 468 dnl *** Video 4 Linux 2 ***
 469 dnl for information about the header/define, see sys/v4l2/gstv4l2element.h
 470 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 471 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 472 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], v4l2src, [
 473   AC_MSG_CHECKING([Checking for up to date v4l2 installation])
 474   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 475 #include <sys/types.h>
 476 #ifdef __sun /* Solaris */
 477 #include <sys/types.h>
 478 #include <sys/videodev2.h>
 479 #elif __FreeBSD__
 480 #include <linux/videodev2.h>
 481 #else /* Linux */
 482 #include <linux/types.h>
 483 #define _LINUX_TIME_H
 484 #define __user
 485 #include <linux/videodev2.h>
 486 #endif
 487 #if defined(V4L2_MAJOR_VERSION) || defined(V4L2_MINOR_VERSION)
 488 #error too early v4l2 version or no v4l2 at all
 489 #endif
 490     ]], [[
 491 return 0;
 492     ]])],[
 493       HAVE_GST_V4L2="yes"
 494       AC_MSG_RESULT(yes)
 495     ],[
 496       HAVE_GST_V4L2="no"
 497       AC_MSG_RESULT(no)
 498
 499       HAVE_VIDEODEV=no
 500       AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_VIDEODEV=yes ],
 501       [
 502         AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_VIDEODEV=yes ])
 503       ])
 504
 505       if test "x$HAVE_VIDEODEV" = "xyes"; then
 506         AC_MSG_WARN([video4linux2 headers were found, but they're old.])
 507         AC_MSG_WARN([Please update v4l2 to compile the v4l2 plugins])
 508       else
 509         AC_MSG_WARN([video4linux2 was not found])
 510       fi
 511     ])
 512
 513   if [ test x$HAVE_GST_V4L2 = xyes ]; then
 514     dnl check for missing v4l2_buffer declaration (see #135919)
 515     MISSING_DECL=0
 516     AC_MSG_CHECKING(struct v4l2_buffer declaration)
 517     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 518 #include <sys/types.h>
 519 #ifdef __sun /* Solaris */
 520 #include <sys/types.h>
 521 #include <sys/videodev2.h>
 522 #elif __FreeBSD__
 523 #include <linux/videodev2.h>
 524 #else /* Linux */
 525 #include <linux/types.h>
 526 #define _LINUX_TIME_H
 527 #define __user
 528 #include <linux/videodev2.h>
 529 #endif
 530     ]], [[
 531 struct v4l2_buffer buf;
 532 buf.index = 0;
 533 return 0;
 534     ]])],[ AC_MSG_RESULT(yes) ],[ MISSING_DECL=1 && AC_MSG_RESULT(no) ])
 535     if [ test x$MISSING_DECL = x1 ]; then
 536       AC_DEFINE(GST_V4L2_MISSING_BUFDECL, 1, [struct v4l2_buffer missing])
 537     fi
 538
 539     dnl check for XOverlay libraries
 540     AG_GST_CHECK_XV
 541   fi
 542 ])
 543
 544 # Optional gudev for device probing
 545 AC_ARG_WITH([gudev],
 546   AS_HELP_STRING([--with-gudev],[device detection with gudev]),
 547   [],
 548   [with_gudev=check])
 549 if test x$HAVE_GST_V4L2 = xyes; then
 550   if test x$with_gudev != xno; then
 551       PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 143 ],
 552           [ have_gudev=yes
 553             AC_DEFINE(HAVE_GUDEV, 1,
 554                [Whether gudev is available for device detection])
 555             AC_DEFINE([G_UDEV_API_IS_SUBJECT_TO_CHANGE], 1, [I know the API is subject to change.])
 556           ], [
 557           have_gudev=no
 558           ])
 559   else
 560     have_gudev=no
 561   fi
 562 fi
 563 AC_SUBST(GUDEV_CFLAGS)
 564 AC_SUBST(GUDEV_LIBS)
 565
 566 # Make libv4l2 non-automagic
 567 AC_ARG_WITH([libv4l2],
 568   AS_HELP_STRING([--with-libv4l2],[support video buffer conversion using libv4l2]),
 569   [],
 570   [with_libv4l2=check])
 571 if test x$HAVE_GST_V4L2 = xyes; then
 572   if test x$with_libv4l2 != xno; then
 573       PKG_CHECK_MODULES(LIBV4L2, libv4l2,
 574           [ have_libv4l2=yes
 575             AC_DEFINE(HAVE_LIBV4L2, 1,
 576                 [Whether libv4l2 is available for video buffer conversion])
 577           ], [
 578           have_libv4l2=no
 579           ])
 580   else
 581     have_libv4l2=no
 582   fi
 583 fi
 584
 585 dnl Check for X11
 586 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 587 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 588                   [ximagesrc], [
 589   AC_PATH_XTRA
 590
 591   dnl now try to find the HEADER
 592   ac_cflags_save="$CFLAGS"
 593   ac_cppflags_save="$CPPFLAGS"
 594   CFLAGS="$CFLAGS $X_CFLAGS"
 595   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 596   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 597
 598   if test "x$HAVE_X" = "xno"
 599   then
 600     AC_MSG_NOTICE([cannot find X11 development files])
 601   else
 602     dnl this is much more than we want
 603     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 604     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 605     dnl it does not add the libs; therefore we add them here
 606     X_LIBS="$X_LIBS -lX11"
 607     AC_SUBST(X_CFLAGS)
 608     AC_SUBST(X_LIBS)
 609
 610     dnl check for Xfixes
 611     PKG_CHECK_MODULES(XFIXES, xfixes, HAVE_XFIXES="yes", HAVE_XFIXES="no")
 612     if test "x$HAVE_XFIXES" = "xyes"
 613     then
 614         XFIXES_CFLAGS="-DHAVE_XFIXES $XFIXES_CFLAGS"
 615     fi
 616     AC_SUBST(XFIXES_LIBS)
 617     AC_SUBST(XFIXES_CFLAGS)
 618
 619     dnl check for Xdamage
 620     PKG_CHECK_MODULES(XDAMAGE, xdamage, HAVE_XDAMAGE="yes", HAVE_XDAMAGE="no")
 621     if test "x$HAVE_XDAMAGE" = "xyes"
 622     then
 623         XDAMAGE_CFLAGS="-DHAVE_XDAMAGE $XDAMAGE_CFLAGS"
 624     fi
 625     AC_SUBST(XDAMAGE_LIBS)
 626     AC_SUBST(XDAMAGE_CFLAGS)
 627   fi
 628   AC_SUBST(HAVE_X)
 629   CFLAGS="$ac_cflags_save"
 630   CPPFLAGS="$ac_cppflags_save"
 631 ])
 632
 633 dnl FIXME: this should be rolled into the test above, it's just an additional
 634 dnl feature of the ximagesrc plug-in
 635 dnl This is the same as in gst-plugins-base
 636 dnl check for X Shm
 637 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 638 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 639   if test x$HAVE_X = xyes; then
 640     AC_CHECK_LIB(Xext, XShmAttach,
 641                  HAVE_XSHM="yes", HAVE_XSHM="no",
 642                  $X_LIBS)
 643     if test "x$HAVE_XSHM" = "xyes"; then
 644       XSHM_LIBS="-lXext"
 645     else
 646       dnl On AIX, it is in XextSam instead, but we still need -lXext
 647       AC_CHECK_LIB(XextSam, XShmAttach,
 648                    HAVE_XSHM="yes", HAVE_XSHM="no",
 649                    $X_LIBS)
 650       if test "x$HAVE_XSHM" = "xyes"; then
 651         XSHM_LIBS="-lXext -lXextSam"
 652       fi
 653     fi
 654   fi
 655 ], ,[
 656   AC_SUBST(HAVE_XSHM)
 657   AC_SUBST(XSHM_LIBS)
 658 ])
 659
 660 dnl for V4L2, we also need to know if we have XVIDEO
 661 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 662 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 663                   [], [
 664   AG_GST_CHECK_XV
 665 ])
 666
 667 dnl *** ext plug-ins ***
 668 dnl keep this list sorted alphabetically !
 669
 670 if test "x$BUILD_EXTERNAL" = "xyes"; then
 671
 672 echo
 673 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 674 echo
 675
 676 dnl *** aalib ***
 677 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 678 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 679   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 680   AS_SCRUB_INCLUDE(AALIB_CFLAGS)
 681 ])
 682
 683 dnl *** cairo ***
 684 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 685 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering and gobject bindings], cairo, [
 686   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.10.0 cairo-gobject >= 1.10.0)
 687 ])
 688
 689 dnl *** FLAC ***
 690 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 691 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 692   AG_GST_PKG_CHECK_MODULES(FLAC, flac >= 1.1.4)
 693 ])
 694
 695 dnl *** GDK pixbuf ***
 696 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 697 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 698   AG_GST_PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0 >= 2.8.0)
 699 ])
 700
 701 dnl *** Jack ***
 702 translit(dnm, m, l) AM_CONDITIONAL(USE_JACK, true)
 703 AG_GST_CHECK_FEATURE(JACK, Jack, jack, [
 704   PKG_CHECK_MODULES(JACK, jack >= 0.99.10, HAVE_JACK="yes", HAVE_JACK="no")
 705   AC_SUBST(JACK_CFLAGS)
 706   AC_SUBST(JACK_LIBS)
 707
 708   AG_GST_PKG_CHECK_MODULES(JACK_0_120_1, jack >= 0.120.1 jack < 1.0)
 709   if test x$HAVE_JACK_0_120_1 = xyes; then
 710     AC_DEFINE(HAVE_JACK_0_120_1, 1, [defined if jack >= 0.120.1 is available])
 711   fi
 712   AG_GST_PKG_CHECK_MODULES(JACK_1_9_7, jack >= 1.9.7)
 713   if test x$HAVE_JACK_1_9_7 = xyes; then
 714     AC_DEFINE(HAVE_JACK_1_9_7, 1, [defined if jack >= 1.9.7 is available])
 715   fi
 716
 717 ])
 718
 719 dnl *** jpeg ***
 720 dnl FIXME: we could use header checks here as well IMO
 721 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 722 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 723   AC_ARG_WITH(jpeg-mmx,
 724     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 725   OLD_LIBS="$LIBS"
 726   if test x$with_jpeg_mmx != x; then
 727     LIBS="$LIBS -L$with_jpeg_mmx"
 728   fi
 729   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 730   JPEG_LIBS="$LIBS -ljpeg-mmx"
 731   LIBS="$OLD_LIBS"
 732   if test x$HAVE_JPEG != xyes; then
 733     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 734     JPEG_LIBS="-ljpeg"
 735   fi
 736   AC_SUBST(JPEG_LIBS)
 737 ])
 738
 739 dnl *** libcaca ***
 740 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 741 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 742   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 743 ])
 744
 745 dnl *** libdv ***
 746 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 747 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 748   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 749 ])
 750
 751 dnl *** libpng ***
 752 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 753 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 754   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng >= 1.2)
 755 ])
 756
 757 dnl *** pulseaudio ***
 758 translit(dnm, m, l) AM_CONDITIONAL(USE_PULSE, true)
 759 AG_GST_CHECK_FEATURE(PULSE, [pulseaudio plug-in], pulseaudio, [
 760
 761   dnl used in ext/pulse/pulseutil.c
 762   AC_CHECK_HEADERS([process.h])
 763
 764   AG_GST_PKG_CHECK_MODULES(PULSE, libpulse >= 1.0)
 765 ])
 766
 767 dnl *** dv1394 ***
 768 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 769 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 770   dnl first test for libraw1394 >= 2.0.0
 771   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 2.0.0)
 772   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 773   dnl now see how far we got
 774   if test x$HAVE_RAW1394 = xyes && \
 775      test x$HAVE_LIBIEC61883 = xyes; then
 776        AG_GST_CHECK_LIBHEADER(AVC1394,
 777         avc1394, avc1394_send_command, $RAW1394_LIBS,
 778         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 779        AG_GST_CHECK_LIBHEADER(ROM1394,
 780         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 781         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 782        if test x$HAVE_AVC1394 = xyes && \
 783           test x$HAVE_AVC1394 = xyes && \
 784           test x$HAVE_ROM1394 = xyes; then
 785           HAVE_DV1394=yes
 786           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 787           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 788           AC_SUBST(DV1394_CFLAGS)
 789           AC_SUBST(DV1394_LIBS)
 790         fi
 791   else
 792        if test x$HAVE_RAW1394 = xno; then
 793           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 794           AG_GST_CHECK_LIBHEADER(AVC1394,
 795            avc1394, avc1394_send_command, $RAW1394_LIBS,
 796            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 797           AG_GST_CHECK_LIBHEADER(ROM1394,
 798            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 799            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 800           if test x$HAVE_RAW1394 = xyes && \
 801              test x$HAVE_AVC1394 = xyes && \
 802              test x$HAVE_ROM1394 = xyes; then
 803              HAVE_DV1394=yes
 804              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 805              DV1394_CFLAGS="$RAW1394_CFLAGS"
 806              if test x$HAVE_LIBIEC61883 = xyes; then
 807                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 808                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 809              fi
 810              AC_SUBST(DV1394_CFLAGS)
 811              AC_SUBST(DV1394_LIBS)
 812            fi
 813          fi
 814   fi
 815 ])
 816 AM_CONDITIONAL(USE_LIBIEC61883, [ test "x${HAVE_LIBIEC61883}" = xyes ] )
 817
 818 dnl *** shout2 ***
 819 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 820 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 821   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 822 ])
 823
 824 dnl *** soup ***
 825 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUP, true)
 826 AG_GST_CHECK_FEATURE(SOUP, [soup http client plugin (2.4)], souphttpsrc, [
 827   PKG_CHECK_MODULES(SOUP, libsoup-gnome-2.4 >= 2.3.2, [
 828     HAVE_SOUP="yes"
 829     AC_DEFINE(HAVE_LIBSOUP_GNOME, 1, [soup gnome integration])
 830   ],[
 831     PKG_CHECK_MODULES(SOUP, libsoup-2.4 >= 2.26.1, HAVE_SOUP="yes", [
 832       HAVE_SOUP="no"
 833     ])
 834   ])
 835   AC_SUBST(SOUP_CFLAGS)
 836   AC_SUBST(SOUP_LIBS)
 837 ])
 838
 839 dnl *** speex >= 1.0.4 or >= 1.1.5 ***
 840 dnl   1.1.4 and earlier were not API/ABI compatible with 1.0
 841 dnl   1.1.6 is the first to use a .pc/pkg-config file ***
 842 dnl   speex_jitter.h is 1.1.x only
 843 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 844 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 845   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 846   if test $HAVE_SPEEX = no
 847   then
 848     AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_bits_init, , speex/speex.h, [
 849       AC_CHECK_HEADER(speex/speex_jitter.h, [
 850         dnl speex 1.1.x :
 851         AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_encode_int, , speex/speex.h, [
 852           dnl speex 1.1.5 or + :
 853           HAVE_SPEEX="yes"
 854           SPEEX_LIBS="-lspeex"
 855           AC_SUBST(SPEEX_CFLAGS)
 856           AC_SUBST(SPEEX_LIBS)
 857         ],[
 858           HAVE_SPEEX="no"
 859         ])
 860       ],[
 861         dnl speex 1.0.x :
 862           AC_CHECK_DECL(SPEEX_GET_LOOKAHEAD, [
 863             dnl speex 1.0.4
 864             HAVE_SPEEX="yes"
 865             SPEEX_LIBS="-lspeex"
 866             AC_SUBST(SPEEX_CFLAGS)
 867             AC_SUBST(SPEEX_LIBS)
 868
 869             AC_DEFINE_UNQUOTED(SPEEX_1_0, 1,
 870               [defined if speex 1.0.x API detected])
 871         ],[
 872             HAVE_SPEEX="no"
 873             AC_MSG_NOTICE(You need at least 1.0.4 to compile the speex plugin)
 874         ], [
 875 #include <speex/speex.h>
 876         ])
 877       ])
 878     ])
 879   fi
 880 ])
 881
 882 dnl *** taglib ***
 883 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 884 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 885   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.5)
 886   if test "x$HAVE_CXX" != "xyes"; then
 887     USE_TAGLIB=false
 888     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 889   else
 890     dnl work around bug in taglib 1.5 headers, remove once there is a 1.6
 891     AS_CXX_COMPILER_FLAG([-Wno-attributes], [
 892         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS -Wno-attributes"
 893       ], [
 894         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS"
 895     ])
 896     AC_SUBST(TAGLIB_CXXFLAGS)
 897   fi
 898 ])
 899
 900 dnl *** vpx ***
 901 translit(dnm, m, l) AM_CONDITIONAL(USE_VPX, vpx)
 902 AG_GST_CHECK_FEATURE(VPX, [VPX decoder], vpx, [
 903   PKG_CHECK_MODULES(VPX, vpx >= 1.1.0, [HAVE_VPX="yes"], [HAVE_VPX="no"])
 904
 905   if test $HAVE_VPX = "yes"; then
 906     OLD_LIBS="$LIBS"
 907     OLD_CFLAGS="$CFLAGS"
 908     CFLAGS="$CFLAGS $VPX_CFLAGS"
 909     LIBS="$LIBS $VPX_LIBS"
 910     AC_CHECK_LIB(vpx, vpx_codec_vp8_cx_algo, [
 911       HAVE_VP8=yes
 912       AC_DEFINE(HAVE_VP8_ENCODER, 1, [Defined if the VP8 encoder is available])
 913     ])
 914     AC_CHECK_LIB(vpx, vpx_codec_vp8_dx_algo, [
 915       HAVE_VP8=yes
 916       AC_DEFINE(HAVE_VP8_DECODER, 1, [Defined if the VP8 decoder is available])
 917     ])
 918     LIBS="$OLD_LIBS"
 919     CFLAGS="$OLD_CFLAGS"
 920   fi
 921   AC_SUBST(VPX_LIBS)
 922   AC_SUBST(VPX_CFLAGS)
 923 ])
 924
 925 dnl *** wavpack ***
 926 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 927 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 928   PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.40.0, HAVE_WAVPACK=yes, [
 929     PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.20, [
 930       HAVE_WAVPACK=yes
 931       AC_DEFINE(WAVPACK_OLD_API, 1, [old wavpack API])
 932     ],[
 933       HAVE_WAVPACK=no
 934     ])
 935   ])
 936   AC_SUBST(WAVPACK_CFLAGS)
 937   AC_SUBST(WAVPACK_LIBS)
 938 ])
 939
 940 dnl *** qtdemux & matroska prefer to have zlib ***
 941 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 942 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for qtdemux/matroska],, [
 943   AG_GST_CHECK_LIBHEADER(ZLIB,
 944     z, uncompress,, zlib.h, [
 945     HAVE_ZLIB="yes"
 946     ZLIB_LIBS="-lz"
 947     AC_SUBST(ZLIB_LIBS)
 948   ])
 949 ])
 950
 951 dnl *** matroska prefers to have bz2 ***
 952 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
 953 AG_GST_CHECK_FEATURE(BZ2, [bz2 library for matroska ],, [
 954   AG_GST_CHECK_LIBHEADER(BZ2, bz2, BZ2_bzCompress, ,bzlib.h, BZ2_LIBS="-lbz2")
 955   AC_SUBST(BZ2_LIBS)
 956 ])
 957
 958 else
 959
 960 dnl not building plugins with external dependencies,
 961 dnl but we still need to set the conditionals
 962 AM_CONDITIONAL(USE_AALIB, false)
 963 AM_CONDITIONAL(USE_BZ2, false)
 964 AM_CONDITIONAL(USE_CAIRO, false)
 965 AM_CONDITIONAL(USE_DIRECTSOUND, false)
 966 AM_CONDITIONAL(USE_DV1394, false)
 967 AM_CONDITIONAL(USE_FLAC, false)
 968 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
 969 AM_CONDITIONAL(USE_GST_V4L2, false)
 970 AM_CONDITIONAL(USE_JACK, false)
 971 AM_CONDITIONAL(USE_JPEG, false)
 972 AM_CONDITIONAL(USE_LIBCACA, false)
 973 AM_CONDITIONAL(USE_LIBDV, false)
 974 AM_CONDITIONAL(USE_LIBIEC61883, false)
 975 AM_CONDITIONAL(USE_LIBPNG, false)
 976 AM_CONDITIONAL(USE_OSS, false)
 977 AM_CONDITIONAL(USE_OSS4, false)
 978 AM_CONDITIONAL(USE_OSX_AUDIO, false)
 979 AM_CONDITIONAL(USE_OSX_VIDEO, false)
 980 AM_CONDITIONAL(USE_PULSE, false)
 981 AM_CONDITIONAL(USE_SHOUT2, false)
 982 AM_CONDITIONAL(USE_SOUP, false)
 983 AM_CONDITIONAL(USE_SPEEX, false)
 984 AM_CONDITIONAL(USE_SUNAUDIO, false)
 985 AM_CONDITIONAL(USE_TAGLIB, false)
 986 AM_CONDITIONAL(USE_VPX, false)
 987 AM_CONDITIONAL(USE_WAVEFORM, false)
 988 AM_CONDITIONAL(USE_WAVPACK, false)
 989 AM_CONDITIONAL(USE_X, false)
 990 AM_CONDITIONAL(USE_XSHM, false)
 991 AM_CONDITIONAL(USE_XVIDEO, false)
 992 AM_CONDITIONAL(USE_ZLIB, false)
 993
 994 fi dnl of EXT plugins
 995
 996 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 997
 998 dnl Overview:
 999 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
1000 dnl GST_*:              flags shared by all built objects
1001 dnl GST_ALL_LDFLAGS:    linker flags shared by all
1002 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
1003 dnl GST_LT_LDFLAGS:     library versioning of our libraries
1004 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
1005
1006 dnl GST_OPTION_CFLAGS
1007 if test "x$USE_DEBUG" = xyes; then
1008    PROFILE_CFLAGS="-g"
1009 fi
1010 AC_SUBST(PROFILE_CFLAGS)
1011
1012 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
1013   dnl Define _only_ for git (not pre-releases or releases)
1014   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
1015 else
1016   DEPRECATED_CFLAGS=""
1017 fi
1018 AC_SUBST(DEPRECATED_CFLAGS)
1019
1020 dnl every flag in GST_OPTION_CFLAGS, GST_OPTION_CXXFLAGS and GST_OPTION_OBJCFLAGS can be overridden
1021 dnl at make time with e.g. make ERROR_CFLAGS=""
1022 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1023 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1024 GST_OPTION_OBJCFLAGS="\$(WARNING_OBJCFLAGS) \$(ERROR_OBJCFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1025 AC_SUBST(GST_OPTION_CFLAGS)
1026 AC_SUBST(GST_OPTION_CXXFLAGS)
1027 AC_SUBST(GST_OPTION_OBJCFLAGS)
1028
1029 dnl our libraries need to be versioned correctly
1030 AC_SUBST(GST_LT_LDFLAGS)
1031
1032 dnl FIXME: do we want to rename to GST_ALL_* ?
1033 dnl prefer internal headers to already installed ones
1034 dnl also add builddir include for enumtypes and marshal
1035 dnl add ERROR_CFLAGS, but overridable
1036 GST_CFLAGS="$GST_CFLAGS -DGST_USE_UNSTABLE_API"
1037 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS)"
1038 GST_OBJCFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_OBJCFLAGS)"
1039 GST_CFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
1040 AC_SUBST(GST_CFLAGS)
1041 AC_SUBST(GST_CXXFLAGS)
1042 AC_SUBST(GST_OBJCFLAGS)
1043 AC_SUBST(GST_LIBS)
1044
1045 dnl LDFLAGS really should only contain flags, not libs - they get added before
1046 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1047 GST_ALL_LDFLAGS="-no-undefined"
1048 AC_SUBST(GST_ALL_LDFLAGS)
1049
1050 dnl this really should only contain flags, not libs - they get added before
1051 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1052 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
1053 AC_SUBST(GST_PLUGIN_LDFLAGS)
1054
1055 dnl *** output files ***
1056
1057 dnl keep this alphabetic per directory, please
1058 AC_CONFIG_FILES(
1059 Makefile
1060 gst/Makefile
1061 gst/alpha/Makefile
1062 gst/apetag/Makefile
1063 gst/audiofx/Makefile
1064 gst/audioparsers/Makefile
1065 gst/auparse/Makefile
1066 gst/autodetect/Makefile
1067 gst/avi/Makefile
1068 gst/cutter/Makefile
1069 gst/deinterlace/Makefile
1070 gst/debugutils/Makefile
1071 gst/effectv/Makefile
1072 gst/equalizer/Makefile
1073 gst/flv/Makefile
1074 gst/goom/Makefile
1075 gst/goom2k1/Makefile
1076 gst/id3demux/Makefile
1077 gst/icydemux/Makefile
1078 gst/imagefreeze/Makefile
1079 gst/interleave/Makefile
1080 gst/isomp4/Makefile
1081 gst/law/Makefile
1082 gst/level/Makefile
1083 gst/matroska/Makefile
1084 gst/monoscope/Makefile
1085 gst/multifile/Makefile
1086 gst/multipart/Makefile
1087 gst/replaygain/Makefile
1088 gst/rtp/Makefile
1089 gst/rtpmanager/Makefile
1090 gst/rtsp/Makefile
1091 gst/shapewipe/Makefile
1092 gst/smpte/Makefile
1093 gst/spectrum/Makefile
1094 gst/udp/Makefile
1095 gst/videobox/Makefile
1096 gst/videocrop/Makefile
1097 gst/videofilter/Makefile
1098 gst/videomixer/Makefile
1099 gst/wavenc/Makefile
1100 gst/wavparse/Makefile
1101 gst/flx/Makefile
1102 gst/y4m/Makefile
1103 ext/Makefile
1104 ext/aalib/Makefile
1105 ext/cairo/Makefile
1106 ext/dv/Makefile
1107 ext/flac/Makefile
1108 ext/gdk_pixbuf/Makefile
1109 ext/jack/Makefile
1110 ext/jpeg/Makefile
1111 ext/libcaca/Makefile
1112 ext/libpng/Makefile
1113 ext/pulse/Makefile
1114 ext/raw1394/Makefile
1115 ext/shout2/Makefile
1116 ext/soup/Makefile
1117 ext/speex/Makefile
1118 ext/taglib/Makefile
1119 ext/vpx/Makefile
1120 ext/wavpack/Makefile
1121 sys/Makefile
1122 sys/directsound/Makefile
1123 sys/oss/Makefile
1124 sys/oss4/Makefile
1125 sys/osxaudio/Makefile
1126 sys/osxvideo/Makefile
1127 sys/sunaudio/Makefile
1128 sys/v4l2/Makefile
1129 sys/waveform/Makefile
1130 sys/ximage/Makefile
1131 po/Makefile.in
1132 tests/Makefile
1133 tests/check/Makefile
1134 tests/examples/Makefile
1135 tests/examples/audiofx/Makefile
1136 tests/examples/cairo/Makefile
1137 tests/examples/equalizer/Makefile
1138 tests/examples/jack/Makefile
1139 tests/examples/level/Makefile
1140 tests/examples/pulse/Makefile
1141 tests/examples/rtp/Makefile
1142 tests/examples/shapewipe/Makefile
1143 tests/examples/spectrum/Makefile
1144 tests/examples/v4l2/Makefile
1145 tests/files/Makefile
1146 tests/icles/Makefile
1147 common/Makefile
1148 common/m4/Makefile
1149 m4/Makefile
1150 docs/Makefile
1151 docs/plugins/Makefile
1152 docs/version.entities
1153 pkgconfig/Makefile
1154 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1155 gst-plugins-good.spec
1156 )
1157
1158 dnl Create the config.h file for Visual Studio builds
1159 dnl Beware of spaces and /'s in some of the shell variable contents.
1160 sed \
1161     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"\n\n#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
1162     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
1163     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
1164     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
1165     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
1166     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
1167     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
1168     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
1169     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
1170     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
1171     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
1172     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
1173     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
1174     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
1175     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
1176     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
1177     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
1178     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
1179     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
1180     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1181     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1182     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1183     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
1184     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1185     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
1186     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1187     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1188     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1189     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
1190     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
1191     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1192     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
1193     -e "s/.* DEFAULT_AUDIOSRC$/#define DEFAULT_AUDIOSRC \"audiotestsrc\"/" \
1194     -e "s/.* DEFAULT_VIDEOSRC$/#define DEFAULT_VIDEOSRC \"videotestsrc\"/" \
1195     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1196     config.h.in >win32/common/config.h-new
1197
1198 AC_OUTPUT
1199
1200 AG_GST_OUTPUT_PLUGINS
1201 ORC_OUTPUT
1202