configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl initialize autoconf
   4 dnl we don't specify PACKAGE and VERSION because AS_VERSION puts it together
   5 AC_INIT
   6
   7 dnl when going to/from release please set the nano (fourth number) right !
   8 dnl releases only do Wall, cvs and prerelease does Werror too
   9 AS_VERSION(gstreamer, GST_VERSION, 0, 9, 5, 1,
  10     GST_CVS="no", GST_CVS="yes")
  11
  12 dnl can autoconf find the source ?
  13 AC_CONFIG_SRCDIR([gst/gst.c])
  14
  15 dnl define the output header for config
  16 AM_CONFIG_HEADER([config.h])
  17
  18 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  19 AM_MAINTAINER_MODE
  20
  21 dnl sets host_* variables
  22 AC_CANONICAL_HOST
  23
  24 dnl initialize automake
  25 dnl FIXME: this is deprecated use, we should move PACKAGE and VERSION to
  26 dnl AC_INIT, but then we need to parse the version to pass to AS_VERSION
  27 AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
  28
  29 dnl our libraries and install dirs use major.minor as a version
  30 GST_MAJORMINOR=$GST_VERSION_MAJOR.$GST_VERSION_MINOR
  31 dnl we override it here for release candidates for a new series
  32 # GST_MAJORMINOR=0.9
  33 AC_SUBST(GST_MAJORMINOR)
  34
  35 dnl CURRENT, REVISION, AGE
  36 dnl - library source changed -> increment REVISION
  37 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  38 dnl - interfaces added -> increment AGE
  39 dnl - interfaces removed -> AGE = 0
  40 dnl sets GST_LT_LDFLAGS
  41 AS_LIBTOOL(GST, 7, 0, 0)
  42 AS_LIBTOOL_TAGS
  43 AM_PROG_LIBTOOL
  44
  45 dnl *** autotools stuff ****
  46
  47 dnl allow for different autotools
  48 AS_AUTOTOOLS_ALTERNATE
  49
  50 dnl Add parameters for aclocal
  51 AC_SUBST(ACLOCAL_AMFLAGS, "-I common/m4")
  52
  53 dnl set up gettext
  54 dnl the version check needs to stay here because autopoint greps for it
  55 AM_GNU_GETTEXT_VERSION([0.11.5])
  56 AM_GNU_GETTEXT([external])
  57 GST_GETTEXT([gstreamer-$GST_MAJORMINOR])
  58
  59 dnl *** check for arguments to configure ***
  60
  61 dnl subsystems - can influence other decisions so needs to be high up
  62 dnl we need to AM_CONDITIONAL them here for automake 1.6.x compatibility
  63 GST_CHECK_SUBSYSTEM_DISABLE(GST_DEBUG,[debugging subsystem])
  64 AM_CONDITIONAL(GST_DISABLE_GST_DEBUG, test "x$GST_GST_DISABLE_DEBUG" = "xyes")
  65 GST_CHECK_SUBSYSTEM_DISABLE(LOADSAVE,[pipeline XML load/save])
  66 AM_CONDITIONAL(GST_DISABLE_LOADSAVE, test "x$GST_DISABLE_LOADSAVE" = "xyes")
  67 GST_CHECK_SUBSYSTEM_DISABLE(PARSE,[command-line parser])
  68 AM_CONDITIONAL(GST_DISABLE_PARSE, test "x$GST_DISABLE_PARSE" = "xyes")
  69 GST_CHECK_SUBSYSTEM_DISABLE(TRACE,[tracing subsystem])
  70 AM_CONDITIONAL(GST_DISABLE_TRACE, test "x$GST_DISABLE_TRACE" = "xyes")
  71 GST_CHECK_SUBSYSTEM_DISABLE(ALLOC_TRACE,[allocation tracing])
  72 AM_CONDITIONAL(GST_DISABLE_ALLOC_TRACE, test "x$GST_DISABLE_ALLOC_TRACE" = "xyes")
  73 GST_CHECK_SUBSYSTEM_DISABLE(REGISTRY,[plugin registry])
  74 AM_CONDITIONAL(GST_DISABLE_REGISTRY, test "x$GST_DISABLE_REGISTRY" = "xyes")
  75 GST_CHECK_SUBSYSTEM_DISABLE(ENUMTYPES,[enum types])
  76 AM_CONDITIONAL(GST_DISABLE_ENUMTYPES, test "x$GST_DISABLE_ENUMTYPES" = "xyes")
  77 GST_CHECK_SUBSYSTEM_DISABLE(INDEX,[index])
  78 AM_CONDITIONAL(GST_DISABLE_INDEX, test "x$GST_DISABLE_INDEX" = "xyes")
  79 GST_CHECK_SUBSYSTEM_DISABLE(PLUGIN,[plugin])
  80 AM_CONDITIONAL(GST_DISABLE_PLUGIN, test "x$GST_DISABLE_PLUGIN" = "xyes")
  81 GST_CHECK_SUBSYSTEM_DISABLE(URI,[uri handlers])
  82 AM_CONDITIONAL(GST_DISABLE_URI, test "x$GST_DISABLE_URI" = "xyes")
  83
  84 GST_ARG_DEBUG
  85 GST_ARG_PROFILING
  86 GST_ARG_VALGRIND
  87 GST_ARG_GCOV
  88
  89 GST_ARG_EXAMPLES
  90
  91 GST_ARG_WITH_PKG_CONFIG_PATH
  92 GST_ARG_WITH_PACKAGE_NAME([GStreamer])
  93 GST_ARG_WITH_PACKAGE_ORIGIN
  94
  95 dnl use a cache dir for storing element registry info.
  96 GST_CACHE_DIR=${localstatedir}/cache/gstreamer-$GST_MAJORMINOR
  97
  98 AC_ARG_WITH(cachedir,
  99   AC_HELP_STRING([--with-cachedir],
 100     [specify path to use for plugin and command completion registries]),
 101   [
 102     case "${withval}" in
 103       yes) AC_MSG_ERROR(bad value ${withval} for --with-cachedir) ;;
 104       no)  AC_MSG_ERROR(bad value ${withval} for --with-cachedir) ;;
 105       *)   GST_CACHE_DIR="${withval}" ;;
 106     esac
 107   ],
 108   [:]) dnl Default value
 109
 110 AS_AC_EXPAND(GST_CACHE_DIR, $GST_CACHE_DIR)
 111 AC_DEFINE_UNQUOTED(GST_CACHE_DIR, "$GST_CACHE_DIR", [Location of registry])
 112 AC_MSG_NOTICE(Using $GST_CACHE_DIR as registry cache dir)
 113
 114 dnl building of tests
 115 AC_ARG_ENABLE(tests,
 116   AC_HELP_STRING([--disable-tests], [disable building test apps]),
 117   [
 118     case "${enableval}" in
 119       yes) BUILD_TESTS=yes ;;
 120       no)  BUILD_TESTS=no ;;
 121       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 122     esac
 123   ],
 124 [BUILD_TESTS=yes]) dnl Default value
 125 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 126
 127 dnl tests known to fail
 128 AC_ARG_ENABLE(failing-tests,
 129   AC_HELP_STRING([--disable-failing-tests],
 130     [disable building tests known to fail]),
 131   [
 132     case "${enableval}" in
 133       yes) BUILD_FAILING_TESTS=yes ;;
 134       no)  BUILD_FAILING_TESTS=no ;;
 135       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-failing-tests) ;;
 136     esac
 137   ],
 138   [BUILD_FAILING_TESTS=no]) dnl Default value
 139 AM_CONDITIONAL(BUILD_FAILING_TESTS, test "x$BUILD_FAILING_TESTS" = "xyes")
 140 if test x$BUILD_FAILING_TESTS = xyes; then
 141   AC_MSG_WARN([building tests known to fail, use --disable-failing-tests to disable])
 142 else
 143   AC_MSG_WARN([Sissy ! By asking to not build the tests known to fail, you hereby waive your right to customer support.  If you do not agree with this EULA, please press Ctrl-C before the next line is printed.  By allowing the next line to be printed, you expressly acknowledge your acceptance of this EULA.])
 144 fi
 145
 146 dnl poison destroyed objects
 147 AC_ARG_ENABLE(poisoning,
 148   AC_HELP_STRING([--enable-poisoning],
 149     [enable poisoning of deallocated objects]),
 150   [
 151     case "${enableval}" in
 152       yes) USE_POISONING=yes ;;
 153       no)  USE_POISONING=no ;;
 154       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-poisoning) ;;
 155     esac
 156   ],
 157   [USE_POISONING=no]) dnl Default value
 158 if test "x$USE_POISONING" = xyes; then
 159   AC_DEFINE(USE_POISONING, 1,
 160     [Define if we should poison deallocated memory])
 161 fi
 162
 163 dnl *** checks for platform ***
 164
 165 dnl * hardware/architecture *
 166
 167 dnl common/m4/gst-arch.m4
 168 dnl check CPU type
 169 GST_ARCH
 170
 171 dnl common/m4/gst-arch.m4
 172 dnl check for unaligned access
 173 GST_UNALIGNED_ACCESS
 174 dnl create a configure variable for gst/gstconfig.h
 175 if test x${as_cv_unaligned_access} = xyes ; then
 176   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 1"
 177 else
 178   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 0"
 179 fi
 180 AC_SUBST(GST_HAVE_UNALIGNED_ACCESS_DEFINE)
 181
 182 dnl * software *
 183
 184 dnl check for large file support
 185 dnl affected plugins must include config.h
 186 AC_SYS_LARGEFILE
 187
 188 dnl HAVE_WIN32 currently means "disable POSIXisms".
 189 case "$host" in
 190   *-*-mingw*)
 191     AC_DEFINE_UNQUOTED(HAVE_WIN32, 1, [Defined if compiling for Windows])
 192     ;;
 193   *)
 194     ;;
 195 esac
 196
 197 dnl *** checks for programs ***
 198
 199 dnl find a compiler
 200 AC_PROG_CC
 201
 202 dnl find an assembler
 203 AM_PROG_AS
 204
 205 dnl we use awk in the bison version check
 206 AC_PROG_AWK
 207
 208 dnl we require bison for building the parser
 209 dnl FIXME: check if AC_PROG_YACC is suitable here
 210 dnl FIXME: make precious
 211 AC_PATH_PROG(BISON_PATH, bison, no)
 212 if test x$BISON_PATH = xno; then
 213   AC_MSG_ERROR(Could not find bison)
 214 fi
 215
 216 dnl check bison version
 217 AC_MSG_CHECKING([bison version])
 218
 219 if $BISON_PATH --version | head -n 1 | $AWK '{ if ($4 < 1.35) exit 1; else exit 0;}';
 220 then
 221   AC_MSG_RESULT([ok])
 222 else
 223   AC_MSG_RESULT([too old.])
 224   AC_MSG_ERROR([Your bison version is too old, v1.35 or later is required.])
 225 fi
 226
 227 dnl we require flex for building the parser
 228 dnl FIXME: check if AC_PROG_LEX is suitable here
 229 AC_PATH_PROG(FLEX_PATH, flex, no)
 230 if test x$FLEX_PATH = xno; then
 231   AC_MSG_ERROR(Could not find flex)
 232 fi
 233
 234 dnl Perl is used in building documentation
 235 AC_PATH_PROG(PERL_PATH, perl, no)
 236 if test x$PERL_PATH = xno; then
 237   AC_MSG_ERROR(Could not find perl)
 238 fi
 239
 240 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 241 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 242
 243 dnl check for documentation tools
 244 GST_DOCBOOK_CHECK
 245 GTK_DOC_CHECK([1.3])
 246
 247 dnl *** checks for libraries ***
 248
 249 dnl For interactive UNIX (a Sun thing)
 250 dnl FIXME: this adds -lcposix to LIBS, but I doubt we use LIBS
 251 AC_ISC_POSIX
 252
 253 dnl *** checks for header files ***
 254
 255 dnl check if we have ANSI C header files
 256 AC_HEADER_STDC
 257
 258 dnl Check for ucontext.h
 259 AC_CHECK_HEADERS([ucontext.h])
 260 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 261 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 262 AC_CHECK_HEADERS([process.h])
 263
 264 dnl *** checks for types/defines ***
 265
 266 dnl *** checks for structures ***
 267
 268 dnl *** checks for compiler characteristics ***
 269
 270 dnl make sure we can use "inline" from C code
 271 AC_C_INLINE
 272
 273 OPT_CFLAGS=
 274 dnl Check for some compiler flags that optimize our code.
 275 if test "x$GCC" = xyes; then
 276   AS_COMPILER_FLAG(-fno-common, OPT_CFLAGS="$OPT_CFLAGS -fno-common")
 277 fi
 278
 279 dnl FIXME: decide what kind of flag this is, maybe it's not an optimization
 280 dnl flag
 281 dnl check if we should use -Wa,-mregnames on PowerPC, so we can use
 282 dnl symbolic register names in inline asm
 283 if test x$HAVE_CPU_PPC = xyes ; then
 284   AS_COMPILER_FLAG(["-Wa,-mregnames"],
 285     [OPT_CFLAGS="$OPT_CFLAGS -Wa,-mregnames"])
 286 fi
 287
 288 dnl *** checks for library functions ***
 289
 290 AC_CHECK_FUNCS([sigaction])
 291
 292 dnl check for fseeko()
 293 AC_FUNC_FSEEKO
 294 dnl check for ftello()
 295 AC_CHECK_FUNCS([ftello])
 296
 297 AC_CHECK_FUNCS([fgetpos])
 298 AC_CHECK_FUNCS([fsetpos])
 299
 300 dnl check for mmap()
 301 AC_FUNC_MMAP
 302 AM_CONDITIONAL(HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 303
 304 dnl common/m4/gst-mcsc.m4
 305 dnl check for makecontext and define HAVE_MAKECONTEXT if we have it
 306 AC_CHECK_MCSC
 307 if test "$ac_cv_check_mcsc" = "yes"; then
 308   AC_DEFINE_UNQUOTED(HAVE_MAKECONTEXT, 1,
 309                      [defined if we have makecontext ()])
 310 fi
 311
 312 dnl Check for a way to display the function name in debug output
 313 GST_CHECK_FUNCTION
 314
 315 dnl test for register_printf_function
 316 AC_CHECK_FUNC(register_printf_function,
 317   [
 318     GST_PRINTF_EXTENSION_FORMAT_DEFINE="#define GST_PTR_FORMAT \"P\""
 319     AC_DEFINE(HAVE_PRINTF_EXTENSION, 1,
 320       [Defined if we have register_printf_function ()])
 321   ],
 322   GST_PRINTF_EXTENSION_FORMAT_DEFINE="#define GST_PTR_FORMAT \"p\""
 323 )
 324 AC_SUBST(GST_PRINTF_EXTENSION_FORMAT_DEFINE)
 325
 326 dnl test if we have dladdr(); we use it for debugging; see gst/gstinfo.c
 327 save_cflags="$CFLAGS"
 328 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 329 AC_CHECK_LIB(dl, dladdr,
 330    AC_DEFINE(HAVE_DLADDR, 1,
 331              [Defined if we have dladdr ()]))
 332 CFLAGS="$save_cflags"
 333
 334 dnl *** checks for dependancy libraries ***
 335
 336 dnl GLib
 337
 338 GST_GLIB_CHECK([2.6])
 339
 340 dnl GLib 2.8 has some bug fixes that we like, so make sure our code knows
 341 AC_MSG_CHECKING([glib version >= 2.8])
 342 if pkg-config --atleast-version=2.8 glib-2.0; then
 343   AC_MSG_RESULT(yes)
 344   GST_HAVE_GLIB_2_8_DEFINE="#define GST_HAVE_GLIB_2_8 1"
 345 else
 346   AC_MSG_RESULT(no)
 347   GST_HAVE_GLIB_2_8_DEFINE="/* #undef GST_HAVE_GLIB_2_8 */"
 348 fi
 349 AC_SUBST(GST_HAVE_GLIB_2_8_DEFINE)
 350
 351 dnl Check for glib2 without extra fat, useful for the unversioned tool frontends
 352 PKG_CHECK_MODULES(GLIB_ONLY, glib-2.0 >= $GLIB_REQ)
 353
 354 dnl libxml 2, which is/should be optional (FIXME)
 355 if test "x$GST_DISABLE_LOADSAVE" = "xyes" && \
 356    test "x$GST_DISABLE_REGISTRY" = "xyes"
 357 then
 358   AC_MSG_NOTICE([Registry and load/save are disabled, not checking for libxml2])
 359 else
 360   dnl check for libxml2 with minimum req version
 361   GST_LIBXML2_CHECK(2.4.9)
 362 fi
 363
 364 dnl check for "check", unit testing library/header
 365 AM_PATH_CHECK(0.9.2,
 366     [
 367         HAVE_CHECK=yes
 368         AC_MSG_NOTICE(CHECK_CFLAGS: $CHECK_CFLAGS)
 369         AC_MSG_NOTICE(CHECK_LIBS: $CHECK_LIBS)
 370     ],
 371     HAVE_CHECK=no)
 372 AM_CONDITIONAL(HAVE_CHECK, test "x$HAVE_CHECK" = "xyes")
 373
 374 dnl *** set variables based on configure arguments
 375
 376 dnl set license and copyright notice
 377 GST_LICENSE="LGPL"
 378 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 379 AC_SUBST(GST_LICENSE)
 380
 381 dnl define LIBDIR so we can inform people where we live
 382 AS_AC_EXPAND(LIBDIR, $libdir)
 383 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [library dir])
 384
 385 dnl set location of plugin directory
 386 GST_SET_PLUGINDIR
 387
 388 dnl FIXME: add LIBXML_PKG here
 389 GST_PKG_DEPS="glib-2.0, gobject-2.0, gmodule-2.0, gthread-2.0"
 390 AC_SUBST(GST_PKG_DEPS)
 391
 392 dnl define an ERROR_CFLAGS Makefile variable
 393 GST_SET_ERROR_CFLAGS($GST_CVS)
 394
 395 dnl define correct level for debugging messages
 396 GST_SET_LEVEL_DEFAULT($GST_CVS)
 397
 398 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 399
 400 dnl Overview:
 401 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 402 dnl GST_ALL_*:          flags shared by all built objects
 403 dnl GST_OBJ_*:          additional flags to link to the core library
 404 dnl                     include GST_ALL_*
 405 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 406 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 407
 408 dnl GST_OPTION_CFLAGS
 409 if test "x$USE_DEBUG" = xyes; then
 410    PROFILE_CFLAGS="-g"
 411 fi
 412 AC_SUBST(PROFILE_CFLAGS)
 413
 414 DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 415 AC_SUBST(DEPRECATED_CFLAGS)
 416
 417 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 418 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 419 AC_SUBST(GST_OPTION_CFLAGS)
 420
 421 dnl GST_ALL_*
 422 dnl vars common to for all internal objects (core libs, elements, applications)
 423 dnl CFLAGS:
 424 dnl - XML needs to be added because xmlPtr is used in core
 425 dnl - src and build dirs need to be added because every piece that gets built
 426 dnl   will need the GStreamer source and generated headers
 427 dnl LIBS: XML doesn't need to be added because we don't explicitly use symbols
 428 dnl       from LibXML
 429 GST_ALL_CFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir) $GLIB_CFLAGS $XML_CFLAGS \$(GST_OPTION_CFLAGS)"
 430 dnl FIXME: check if LTLIBINTL is needed everywhere
 431 dnl I presume it is given that it contains the symbols that _() stuff maps to
 432 GST_ALL_LIBS="$GLIB_LIBS $LTLIBINTL"
 433 dnl LDFLAGS modifier defining exported symbols from built shared objects
 434 EXPORT_LDFLAGS="-export-symbols-regex [_]*\(gst_\|Gst\|GST_\).*"
 435 dnl LDFLAGS really should only contain flags, not libs - they get added before
 436 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 437 GST_ALL_LDFLAGS="$EXPORT_LDFLAGS -no-undefined"
 438 AC_SUBST(GST_ALL_CFLAGS)
 439 AC_SUBST(GST_ALL_LIBS)
 440 AC_SUBST(GST_ALL_LDFLAGS)
 441
 442 dnl GST_OBJ_*
 443 dnl default vars for all internal objects built on libgstreamer
 444 GST_OBJ_CFLAGS="\$(GST_ALL_CFLAGS)"
 445 GST_OBJ_LIBS="\$(top_builddir)/gst/libgstreamer-$GST_MAJORMINOR.la \$(GST_ALL_LIBS)"
 446 GST_OBJ_LDFLAGS="$GST_LT_LDFLAGS $GST_ALL_LDFLAGS"
 447 AC_SUBST(GST_OBJ_CFLAGS)
 448 AC_SUBST(GST_OBJ_LIBS)
 449 AC_SUBST(GST_OBJ_LDFLAGS)
 450
 451 dnl GST_PLUGIN_LDFLAGS
 452 dnl LDFLAGS for plugins; include GST_ALL_LDFLAGS
 453 GST_PLUGIN_LDFLAGS="-module -avoid-version $GST_ALL_LDFLAGS"
 454 AC_SUBST(GST_PLUGIN_LDFLAGS, "$GST_PLUGIN_LDFLAGS")
 455
 456 dnl ##################################################
 457 dnl # deps for examples from manual                  #
 458 dnl ##################################################
 459
 460 PKG_CHECK_MODULES(LIBGNOMEUI, libgnomeui-2.0,
 461                   HAVE_LIBGNOMEUI="yes", HAVE_LIBGNOMEUI="no")
 462 AM_CONDITIONAL(HAVE_LIBGNOMEUI, test "x$HAVE_LIBGNOMEUI" = "xyes")
 463
 464 AC_CONFIG_FILES(
 465 Makefile
 466 gst/Makefile
 467 gst/gstconfig.h
 468 gst/gstversion.h
 469 gst/base/Makefile
 470 gst/check/Makefile
 471 gst/indexers/Makefile
 472 gst/elements/Makefile
 473 gst/parse/Makefile
 474 libs/Makefile
 475 libs/gst/Makefile
 476 libs/gst/controller/Makefile
 477 libs/gst/dataprotocol/Makefile
 478 po/Makefile.in
 479 check/Makefile
 480 tests/Makefile
 481 tests/instantiate/Makefile
 482 tests/muxing/Makefile
 483 tests/seeking/Makefile
 484 tests/sched/Makefile
 485 tests/threadstate/Makefile
 486 testsuite/Makefile
 487 testsuite/caps/Makefile
 488 testsuite/debug/Makefile
 489 testsuite/dlopen/Makefile
 490 testsuite/elements/Makefile
 491 testsuite/indexers/Makefile
 492 testsuite/parse/Makefile
 493 testsuite/plugin/Makefile
 494 testsuite/refcounting/Makefile
 495 testsuite/states/Makefile
 496 testsuite/threads/Makefile
 497 testsuite/trigger/Makefile
 498 examples/Makefile
 499 examples/controller/Makefile
 500 examples/cutter/Makefile
 501 examples/helloworld/Makefile
 502 examples/launch/Makefile
 503 examples/manual/Makefile
 504 examples/mixer/Makefile
 505 examples/metadata/Makefile
 506 examples/pingpong/Makefile
 507 examples/plugins/Makefile
 508 examples/pwg/Makefile
 509 examples/queue/Makefile
 510 examples/retag/Makefile
 511 examples/thread/Makefile
 512 examples/typefind/Makefile
 513 examples/xml/Makefile
 514 tools/Makefile
 515 common/Makefile
 516 common/m4/Makefile
 517 docs/Makefile
 518 docs/faq/Makefile
 519 docs/gst/Makefile
 520 docs/libs/Makefile
 521 docs/manual/Makefile
 522 docs/pwg/Makefile
 523 docs/xsl/Makefile
 524 docs/version.entities
 525 win32/common/config.h
 526 pkgconfig/Makefile
 527 stamp.h
 528 pkgconfig/gstreamer.pc
 529 pkgconfig/gstreamer-uninstalled.pc
 530 pkgconfig/gstreamer-base.pc
 531 pkgconfig/gstreamer-base-uninstalled.pc
 532 pkgconfig/gstreamer-check.pc
 533 pkgconfig/gstreamer-check-uninstalled.pc
 534 pkgconfig/gstreamer-controller.pc
 535 pkgconfig/gstreamer-controller-uninstalled.pc
 536 pkgconfig/gstreamer-dataprotocol.pc
 537 pkgconfig/gstreamer-dataprotocol-uninstalled.pc
 538 gstreamer.spec
 539 )
 540 AC_OUTPUT