configure.ac

   1 AC_PREREQ(2.69)
   2 dnl initialize autoconf
   3 dnl when going to/from release please set the nano (fourth number) right !
   4 dnl releases only do Wall, cvs and prerelease does Werror too
   5 AC_INIT([GStreamer RTSP Server Library], [1.15.0.1],
   6     [http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],
   7     [gst-rtsp-server])
   8 AG_GST_INIT
   9
  10 dnl initialize automake
  11 AM_INIT_AUTOMAKE([-Wno-portability 1.14 no-dist-gzip dist-xz tar-ustar subdir-objects])
  12
  13 dnl define PACKAGE_VERSION_* variables
  14 AS_VERSION
  15
  16 dnl check if this is a release version
  17 AS_NANO(GST_GIT="no", GST_GIT="yes")
  18
  19 dnl can autoconf find the source ?
  20 AC_CONFIG_SRCDIR([gst/rtsp-server/rtsp-server.c])
  21
  22 dnl define the output header for config
  23 AC_CONFIG_HEADERS([config.h])
  24
  25 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  26 AM_MAINTAINER_MODE([enable])
  27
  28 dnl sets host_* variables
  29 AC_CANONICAL_HOST
  30
  31 dnl use pretty build output with automake >= 1.11
  32 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  33   [AM_DEFAULT_VERBOSITY=1
  34    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  35
  36 dnl our libraries and install dirs use major.minor as a version
  37 dnl GST_API_VERSION=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  38 dnl we override it here if we need to for the release candidate of new series
  39 GST_API_VERSION=1.0
  40 AC_SUBST(GST_API_VERSION)
  41
  42 dnl CURRENT, REVISION, AGE
  43 dnl - library source changed -> increment REVISION
  44 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  45 dnl - interfaces added -> increment AGE
  46 dnl - interfaces removed -> AGE = 0
  47 dnl
  48 dnl Keep CURRENT as MINOR * 100 + MICRO
  49 dnl Ex : 1.0.0 => 0
  50 dnl      1.0.3 => 3
  51 dnl      1.1.0 => 100
  52 dnl      1.2.5 => 205
  53 dnl      1.10.9 (who knows) => 1009
  54 dnl
  55 dnl sets GST_LT_LDFLAGS
  56 AS_LIBTOOL(GST, 1500, 0, 1500)
  57
  58 dnl *** required versions of GStreamer stuff ***
  59 GST_REQ=1.15.0.1
  60 GSTPB_REQ=1.15.0.1
  61 GSTPG_REQ=1.15.0.1
  62 GSTPD_REQ=1.15.0.1
  63
  64 dnl *** autotools stuff ****
  65
  66 dnl allow for different autotools
  67 AS_AUTOTOOLS_ALTERNATE
  68
  69 dnl Add parameters for aclocal
  70 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  71 AC_CONFIG_MACRO_DIR([m4])
  72
  73 dnl set up gettext
  74 dnl the version check needs to stay here because autopoint greps for it
  75 #AM_GNU_GETTEXT_VERSION([0.17])
  76 #AM_GNU_GETTEXT([external])
  77 #AG_GST_GETTEXT([gst-rtsp-server-$GST_API_VERSION])
  78
  79 dnl *** check for arguments to configure ***
  80
  81 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  82 AG_GST_ARG_ENABLE_EXTRA_CHECKS
  83
  84 AG_GST_ARG_DEBUG
  85 AG_GST_ARG_VALGRIND
  86 AG_GST_ARG_GCOV
  87 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  88 AG_GST_ARG_WITH_PACKAGE_NAME
  89 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  90
  91 AG_GST_ARG_EXAMPLES
  92
  93 AG_GST_PKG_CONFIG_PATH
  94
  95 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
  96   ["${srcdir}/gst-rtsp-server.doap"],
  97   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
  98
  99 dnl building of tests
 100 AC_ARG_ENABLE(tests,
 101   AS_HELP_STRING([--disable-tests],[disable building test apps]),
 102   [
 103     case "${enableval}" in
 104       yes) BUILD_TESTS=yes ;;
 105       no)  BUILD_TESTS=no ;;
 106       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 107     esac
 108   ],
 109 [BUILD_TESTS=yes]) dnl Default value
 110 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 111
 112 dnl *** checks for platform ***
 113
 114 dnl * hardware/architecture *
 115
 116 dnl *** checks for programs ***
 117
 118 dnl find a compiler
 119 AC_PROG_CC
 120 AC_PROG_CC_STDC
 121
 122 dnl check if the compiler supports '-c' and '-o' options
 123 AM_PROG_CC_C_O
 124
 125 dnl find an assembler
 126 AM_PROG_AS
 127
 128 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 129 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 130
 131 dnl check for gobject-introspection
 132 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 133
 134 dnl check for documentation tools
 135 AG_GST_DOCBOOK_CHECK
 136 GTK_DOC_CHECK([1.12])
 137
 138 dnl *** checks for libraries ***
 139
 140 dnl check for pthreads
 141 AX_PTHREAD
 142
 143 dnl *** checks for header files ***
 144
 145 dnl *** checks for types/defines ***
 146
 147 dnl *** checks for structures ***
 148
 149 dnl *** checks for compiler characteristics ***
 150
 151 dnl *** checks for library functions ***
 152
 153 dnl *** checks for dependancy libraries ***
 154
 155 dnl GLib is required
 156 GLIB_REQ=2.40.0
 157 AC_SUBST([GLIB_REQ])
 158 AG_GST_GLIB_CHECK([$GLIB_REQ])
 159
 160 dnl checks for gstreamer
 161 dnl uninstalled is selected preferentially -- see pkg-config(1)
 162 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], [yes])
 163
 164 GST_TOOLS_DIR=`$PKG_CONFIG --variable=toolsdir gstreamer-$GST_API_VERSION`
 165 if test -z $GST_TOOLS_DIR; then
 166   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 167 fi
 168 AC_SUBST(GST_TOOLS_DIR)
 169
 170 GST_PLUGINS_DIR=`$PKG_CONFIG gstreamer-$GST_API_VERSION --variable pluginsdir`
 171 AC_SUBST(GST_PLUGINS_DIR)
 172 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 173
 174 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], [yes])
 175
 176 AG_GST_CHECK_GST_NET($GST_API_VERSION, [$GST_REQ], yes)
 177
 178 AG_GST_CHECK_GST_PLUGINS_BASE($GST_API_VERSION, [$GSTPB_REQ], [yes])
 179 GSTPB_PLUGINS_DIR=`$PKG_CONFIG gstreamer-plugins-base-$GST_API_VERSION --variable pluginsdir`
 180 AC_SUBST(GSTPB_PLUGINS_DIR)
 181 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 182
 183 AG_GST_CHECK_GST_PLUGINS_GOOD($GST_API_VERSION, [$GSTPG_REQ], [yes])
 184 GSTPG_PLUGINS_DIR=`$PKG_CONFIG gstreamer-plugins-good-$GST_API_VERSION --variable pluginsdir`
 185 AC_SUBST(GSTPG_PLUGINS_DIR)
 186 AC_MSG_NOTICE(Using GStreamer Good Plugins in $GSTPG_PLUGINS_DIR)
 187
 188 AG_GST_CHECK_GST_PLUGINS_BAD($GST_API_VERSION, [$GSTPD_REQ], [yes])
 189 GSTPD_PLUGINS_DIR=`$PKG_CONFIG gstreamer-plugins-bad-$GST_API_VERSION --variable pluginsdir`
 190 AC_SUBST(GSTPD_PLUGINS_DIR)
 191 AC_MSG_NOTICE(Using GStreamer Bad Plugins in $GSTPD_PLUGINS_DIR)
 192
 193 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 194 AM_CONDITIONAL(HAVE_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 195
 196 dnl Check for -Bsymbolic-functions linker flag used to avoid
 197 dnl intra-library PLT jumps, if available.
 198 AC_ARG_ENABLE(Bsymbolic,
 199               [AS_HELP_STRING([--disable-Bsymbolic],[avoid linking with -Bsymbolic])],,
 200               [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
 201                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 202                LDFLAGS=-Wl,-Bsymbolic-functions
 203                LIBS=
 204                AC_TRY_LINK([], [return 0],
 205                            AC_MSG_RESULT(yes)
 206                            enable_Bsymbolic=yes,
 207                            AC_MSG_RESULT(no)
 208                            enable_Bsymbolic=no)
 209                LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
 210
 211 dnl *** set variables based on configure arguments ***
 212
 213 dnl set license and copyright notice
 214 GST_LICENSE="LGPL"
 215 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 216 AC_SUBST(GST_LICENSE)
 217
 218 dnl set location of plugin directory
 219 AG_GST_SET_PLUGINDIR
 220
 221 dnl set release date/time (and check that release version is in doap file)
 222 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 223   ["${srcdir}/gst-rtsp-server.doap"],
 224   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 225
 226 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 227 dnl make sure it doesn't complain about unused variables if debugging is disabled
 228 NO_WARNINGS=""
 229 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 230
 231 dnl define an ERROR_CFLAGS Makefile variable
 232 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [-Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef -Wwrite-strings -Wformat-nonliteral -Wformat-security -Wold-style-definition -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return -Wno-multichar -Wnested-externs $NO_WARNINGS])
 233
 234 dnl define correct level for debugging messages
 235 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 236
 237 dnl used in examples
 238 AG_GST_DEFAULT_ELEMENTS
 239
 240 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 241
 242 dnl Overview:
 243 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 244 dnl GST_*:              flags shared by built objects to link against GStreamer
 245 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 246 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 247 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 248 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 249
 250 dnl GST_OPTION_CFLAGS
 251 if test "x$USE_DEBUG" = xyes; then
 252    PROFILE_CFLAGS="-g"
 253 fi
 254 AC_SUBST(PROFILE_CFLAGS)
 255
 256 # GST_DISABLE_DEPRECATED: hide the visibility of deprecated
 257 # functionality from the API that gstreamer uses
 258 # GST_REMOVE_DEPRECATED: don't compile deprecated functionality (breaks ABI)
 259 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 260   dnl Define _only_ when compiling from git (not for pre-releases or releases)
 261   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 262 else
 263   DEPRECATED_CFLAGS=""
 264 fi
 265 AC_SUBST(DEPRECATED_CFLAGS)
 266
 267 VISIBILITY_CFLAGS=""
 268 AS_COMPILER_FLAG([-fvisibility=hidden], [VISIBILITY_CFLAGS="-fvisibility=hidden"])
 269 AC_SUBST(VISIBILITY_CFLAGS)
 270
 271 dnl disable strict aliasing
 272 AS_COMPILER_FLAG([-fno-strict-aliasing], [EXTRA_CFLAGS="-fno-strict-aliasing"])
 273 AC_SUBST(EXTRA_CFLAGS)
 274
 275 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 276 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 277 AC_SUBST(GST_OPTION_CFLAGS)
 278
 279 dnl FIXME: do we want to rename to GST_ALL_* ?
 280 dnl prefer internal headers to already installed ones
 281 dnl add GST_OPTION_CFLAGS, but overridable
 282 GST_CFLAGS="$GST_CFLAGS $EXTRA_CFLAGS \$(GST_STATIC_CFLAGS) \$(GST_OPTION_CFLAGS) \$(VISIBILITY_CFLAGS)"
 283 AC_SUBST(GST_CFLAGS)
 284 AC_SUBST(GST_LIBS)
 285
 286 dnl GST_ALL_*
 287 dnl vars common to for all internal objects (core libs, elements, applications)
 288 dnl CFLAGS:
 289 dnl - src and build dirs need to be added because every piece that gets built
 290 dnl   will need the GStreamer source and generated headers
 291 GST_ALL_CFLAGS="-I\$(top_srcdir) -I\$(top_builddir) $GST_PLUGINS_BASE_CFLAGS $GST_CFLAGS \$(GST_OPTION_CFLAGS)"
 292 AC_SUBST([GST_ALL_CFLAGS])
 293
 294 dnl FIXME: check if LTLIBINTL is needed everywhere
 295 dnl I presume it is given that it contains the symbols that _() stuff maps to
 296 GST_ALL_LIBS="$GST_LIBS $LTLIBINTL \$(GCOV_LIBS)"
 297 AC_SUBST([GST_ALL_LIBS])
 298
 299 dnl LDFLAGS really should only contain flags, not libs - they get added before
 300 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 301 GST_ALL_LDFLAGS="-no-undefined"
 302 if test "x${enable_Bsymbolic}" = "xyes"; then
 303   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 304 fi
 305
 306 AC_SUBST(GST_ALL_LDFLAGS)
 307
 308 dnl GST_LIB_LDFLAGS
 309 dnl linker flags shared by all libraries
 310 dnl LDFLAGS modifier defining exported symbols from built libraries
 311 GST_LIB_LDFLAGS=""
 312 AC_SUBST(GST_LIB_LDFLAGS)
 313
 314 dnl GST_OBJ_*
 315 dnl default vars for all internal objects built on libgstrtspserver
 316 dnl includes GST_ALL_*
 317 GST_OBJ_CFLAGS="\$(GST_ALL_CFLAGS)"
 318 AC_SUBST([GST_OBJ_CFLAGS])
 319 GST_OBJ_LIBS="\$(top_builddir)/gst/rtsp-server/libgstrtspserver-$GST_API_VERSION.la \$(GST_ALL_LIBS)"
 320 AC_SUBST([GST_OBJ_LIBS])
 321
 322 dnl If only building static libraries, define GST_STATIC_COMPILATION. This is
 323 dnl needed only on Windows, but it doesn't hurt to have it everywhere.
 324 if test x$enable_static = xyes -a x$enable_shared = xno; then
 325   GST_STATIC_CFLAGS="-DGST_STATIC_COMPILATION"
 326 fi
 327 AC_SUBST(GST_STATIC_CFLAGS)
 328
 329 GST_PLUGIN_LDFLAGS="-module -avoid-version $GST_ALL_LDFLAGS"
 330 AC_SUBST(GST_PLUGIN_LDFLAGS)
 331
 332 PKG_CHECK_MODULES(LIBCGROUP, libcgroup >= 0.26, HAVE_LIBCGROUP="yes", HAVE_LIBCGROUP="no")
 333 AC_SUBST(LIBCGROUP_CFLAGS)
 334 AC_SUBST(LIBCGROUP_LIBS)
 335 AM_CONDITIONAL(HAVE_LIBCGROUP, test "x$HAVE_LIBCGROUP" = "xyes")
 336
 337 dnl this really should only contain flags, not libs - they get added before
 338 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 339
 340 dnl *** output files ***
 341
 342 dnl keep this alphabetic per directory, please
 343 AC_CONFIG_FILES([
 344 Makefile
 345 common/Makefile
 346 common/m4/Makefile
 347 gst/Makefile
 348 gst/rtsp-server/Makefile
 349 gst/rtsp-sink/Makefile
 350 examples/Makefile
 351 tests/Makefile
 352 tests/check/Makefile
 353 pkgconfig/Makefile
 354 pkgconfig/gstreamer-rtsp-server.pc
 355 pkgconfig/gstreamer-rtsp-server-uninstalled.pc
 356 docs/Makefile
 357 docs/version.entities
 358 docs/libs/Makefile
 359 ])
 360 AC_OUTPUT
 361
 362 echo "
 363
 364 Configuration
 365         Version                    : ${VERSION}
 366         Source code location       : ${srcdir}
 367         Prefix                     : ${prefix}
 368         Compiler                   : ${CC}
 369         CGroups example            : ${HAVE_LIBCGROUP}
 370
 371 gst-rtsp-server configured. Type 'make' to build.
 372 "