configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, cvs and prerelease does Werror too
   6 AC_INIT(GStreamer, 0.10.17.4,
   7     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
   8     gstreamer)
   9 AG_GST_INIT
  10
  11 dnl initialize automake
  12 AM_INIT_AUTOMAKE
  13
  14 dnl define PACKAGE_VERSION_* variables
  15 AS_VERSION
  16
  17 dnl check if this is a release version
  18 AS_NANO(GST_CVS="no", GST_CVS="yes")
  19
  20 dnl can autoconf find the source ?
  21 AC_CONFIG_SRCDIR([gst/gst.c])
  22
  23 dnl define the output header for config
  24 AM_CONFIG_HEADER([config.h])
  25
  26 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  27 AM_MAINTAINER_MODE
  28
  29 dnl sets host_* variables
  30 AC_CANONICAL_HOST
  31
  32 dnl our libraries and install dirs use major.minor as a version
  33 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  34 dnl we override it here for release candidates for a new series
  35 GST_MAJORMINOR=0.10
  36 AC_SUBST(GST_MAJORMINOR)
  37 AC_DEFINE_UNQUOTED(GST_MAJORMINOR, "$GST_MAJORMINOR",
  38   [library major.minor version])
  39
  40 dnl CURRENT, REVISION, AGE
  41 dnl - library source changed -> increment REVISION
  42 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  43 dnl - interfaces added -> increment AGE
  44 dnl - interfaces removed -> AGE = 0
  45 dnl sets GST_LT_LDFLAGS
  46 AS_LIBTOOL(GST, 15, 0, 15)
  47
  48 dnl FIXME: this macro doesn't actually work;
  49 dnl the generated libtool script has no support for the listed tags.
  50 dnl So this needs to be fixed first if we want to use this
  51 dnl AS_LIBTOOL_TAGS
  52
  53 AM_PROG_LIBTOOL
  54
  55 dnl *** autotools stuff ****
  56
  57 dnl allow for different autotools
  58 AS_AUTOTOOLS_ALTERNATE
  59
  60 dnl Add parameters for aclocal
  61 AC_SUBST(ACLOCAL_AMFLAGS, "-I common/m4")
  62
  63 dnl set up gettext
  64 dnl the version check needs to stay here because autopoint greps for it
  65 AM_GNU_GETTEXT_VERSION([0.11.5])
  66 AM_GNU_GETTEXT([external])
  67 AG_GST_GETTEXT([gstreamer-$GST_MAJORMINOR])
  68
  69 dnl *** check for arguments to configure ***
  70
  71 dnl subsystems - can influence other decisions so needs to be high up
  72 dnl we need to AM_CONDITIONAL them here for automake 1.6.x compatibility
  73 AG_GST_CHECK_SUBSYSTEM_DISABLE(GST_DEBUG,[debugging subsystem])
  74 AM_CONDITIONAL(GST_DISABLE_GST_DEBUG, test "x$GST_DISABLE_GST_DEBUG" = "xyes")
  75 AG_GST_CHECK_SUBSYSTEM_DISABLE(LOADSAVE,[pipeline XML load/save])
  76 AM_CONDITIONAL(GST_DISABLE_LOADSAVE, test "x$GST_DISABLE_LOADSAVE" = "xyes")
  77 dnl define a substitution to use in docs/gst/gstreamer.types
  78 if test "x$GST_DISABLE_LOADSAVE" = "xyes"
  79 then
  80   GST_LOADSAVE_DOC_TYPES="%"
  81 else
  82   GST_LOADSAVE_DOC_TYPES=
  83 fi
  84 AC_SUBST(GST_LOADSAVE_DOC_TYPES)
  85 AG_GST_CHECK_SUBSYSTEM_DISABLE(PARSE,[command-line parser])
  86 AM_CONDITIONAL(GST_DISABLE_PARSE, test "x$GST_DISABLE_PARSE" = "xyes")
  87 if test "x$GST_DISABLE_PARSE" = xyes; then
  88   AC_DEFINE(GST_DISABLE_PARSE, 1,
  89     [Define if pipeline parsing code is disabled])
  90 fi
  91 AG_GST_CHECK_SUBSYSTEM_DISABLE(TRACE,[tracing subsystem])
  92 AM_CONDITIONAL(GST_DISABLE_TRACE, test "x$GST_DISABLE_TRACE" = "xyes")
  93 AG_GST_CHECK_SUBSYSTEM_DISABLE(ALLOC_TRACE,[allocation tracing])
  94 AM_CONDITIONAL(GST_DISABLE_ALLOC_TRACE, test "x$GST_DISABLE_ALLOC_TRACE" = "xyes")
  95 AG_GST_CHECK_SUBSYSTEM_DISABLE(REGISTRY,[plugin registry])
  96 AM_CONDITIONAL(GST_DISABLE_REGISTRY, test "x$GST_DISABLE_REGISTRY" = "xyes")
  97 dnl define a substitution to use in docs/gst/gstreamer.types
  98 if test "x$GST_DISABLE_REGISTRY" = "xyes"
  99 then
 100   GST_REGISTRY_DOC_TYPES="%"
 101 else
 102   GST_REGISTRY_DOC_TYPES=
 103 fi
 104 AC_SUBST(GST_REGISTRY_DOC_TYPES)
 105 AG_GST_CHECK_SUBSYSTEM_DISABLE(ENUMTYPES,[enum types])
 106 AM_CONDITIONAL(GST_DISABLE_ENUMTYPES, test "x$GST_DISABLE_ENUMTYPES" = "xyes")
 107 AG_GST_CHECK_SUBSYSTEM_DISABLE(INDEX,[index])
 108 AM_CONDITIONAL(GST_DISABLE_INDEX, test "x$GST_DISABLE_INDEX" = "xyes")
 109 dnl define a substitution to use in docs/gst/gstreamer.types
 110 if test "x$GST_DISABLE_INDEX" = "xyes"
 111 then
 112   GST_INDEX_DOC_TYPES="%"
 113 else
 114   GST_INDEX_DOC_TYPES=
 115 fi
 116 AC_SUBST(GST_INDEX_DOC_TYPES)
 117 AG_GST_CHECK_SUBSYSTEM_DISABLE(NET,[network distribution])
 118 AM_CONDITIONAL(GST_DISABLE_NET, test "x$GST_DISABLE_NET" = "xyes")
 119 AG_GST_CHECK_SUBSYSTEM_DISABLE(PLUGIN,[plugin])
 120 AM_CONDITIONAL(GST_DISABLE_PLUGIN, test "x$GST_DISABLE_PLUGIN" = "xyes")
 121 AG_GST_CHECK_SUBSYSTEM_DISABLE(URI,[uri handlers])
 122 AM_CONDITIONAL(GST_DISABLE_URI, test "x$GST_DISABLE_URI" = "xyes")
 123
 124 AG_GST_ARG_DEBUG
 125 AG_GST_ARG_PROFILING
 126 AG_GST_ARG_VALGRIND
 127 AG_GST_ARG_GCOV
 128
 129 AG_GST_ARG_EXAMPLES
 130
 131 AG_GST_ARG_WITH_PKG_CONFIG_PATH
 132 AG_GST_ARG_WITH_PACKAGE_NAME
 133 AG_GST_ARG_WITH_PACKAGE_ORIGIN
 134
 135 dnl building of tests
 136 AC_ARG_ENABLE(tests,
 137   AC_HELP_STRING([--disable-tests], [disable building test apps]),
 138   [
 139     case "${enableval}" in
 140       yes) BUILD_TESTS=yes ;;
 141       no)  BUILD_TESTS=no ;;
 142       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 143     esac
 144   ],
 145 [BUILD_TESTS=yes]) dnl Default value
 146 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 147
 148 dnl tests known to fail
 149 AC_ARG_ENABLE(failing-tests,
 150   AC_HELP_STRING([--disable-failing-tests],
 151     [disable building tests known to fail]),
 152   [
 153     case "${enableval}" in
 154       yes) BUILD_FAILING_TESTS=yes ;;
 155       no)  BUILD_FAILING_TESTS=no ;;
 156       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-failing-tests) ;;
 157     esac
 158   ],
 159   [BUILD_FAILING_TESTS=no]) dnl Default value
 160 AM_CONDITIONAL(BUILD_FAILING_TESTS, test "x$BUILD_FAILING_TESTS" = "xyes")
 161 if test x$BUILD_FAILING_TESTS = xyes; then
 162   AC_MSG_WARN([building tests known to fail, use --disable-failing-tests to disable])
 163 else
 164   AC_MSG_WARN([Sissy ! By asking to not build the tests known to fail, you hereby waive your right to customer support.  If you do not agree with this EULA, please press Ctrl-C before the next line is printed.  By allowing the next line to be printed, you expressly acknowledge your acceptance of this EULA.])
 165 fi
 166
 167 dnl poison destroyed objects
 168 AC_ARG_ENABLE(poisoning,
 169   AC_HELP_STRING([--enable-poisoning],
 170     [enable poisoning of deallocated objects]),
 171   [
 172     case "${enableval}" in
 173       yes) USE_POISONING=yes ;;
 174       no)  USE_POISONING=no ;;
 175       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-poisoning) ;;
 176     esac
 177   ],
 178   [USE_POISONING=no]) dnl Default value
 179 if test "x$USE_POISONING" = xyes; then
 180   AC_DEFINE(USE_POISONING, 1,
 181     [Define if we should poison deallocated memory])
 182 fi
 183
 184 dnl Use binary registry
 185 AC_ARG_ENABLE(binary-registry,
 186   AC_HELP_STRING([--enable-binary-registry],
 187     [enable experimental binary registry]),
 188   [
 189     case "${enableval}" in
 190       yes) USE_BINARY_REGISTRY=yes ;;
 191       no)  USE_BINARY_REGISTRY=no ;;
 192       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-binary-registry) ;;
 193     esac
 194   ],
 195   [USE_BINARY_REGISTRY=no]) dnl Default value
 196
 197 if test "x$USE_BINARY_REGISTRY" = xyes; then
 198   dnl for config.h:
 199   AC_DEFINE(USE_BINARY_REGISTRY, 1,
 200     [Define if we should use binary registry instead xml registry])
 201 fi
 202 AM_CONDITIONAL(USE_BINARY_REGISTRY, test "x$USE_BINARY_REGISTRY" = "xyes")
 203
 204 dnl *** checks for platform ***
 205
 206 dnl * hardware/architecture *
 207
 208 dnl common/m4/gst-arch.m4
 209 dnl check CPU type
 210 AG_GST_ARCH
 211 dnl substitution for win32/common/config.h
 212 HOST_CPU=$host_cpu
 213 AC_SUBST(HOST_CPU)
 214
 215 dnl common/m4/gst-arch.m4
 216 dnl check for unaligned access
 217 AG_GST_UNALIGNED_ACCESS
 218 dnl create a configure variable for gst/gstconfig.h
 219 if test x${as_cv_unaligned_access} = xyes ; then
 220   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 1"
 221 else
 222   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 0"
 223 fi
 224 AC_SUBST(GST_HAVE_UNALIGNED_ACCESS_DEFINE)
 225
 226 dnl * software *
 227
 228 dnl check for large file support
 229 dnl affected plugins must include config.h
 230 AC_SYS_LARGEFILE
 231
 232 dnl HAVE_WIN32 currently means "disable POSIXisms".
 233 case "$host" in
 234   *-*-mingw*)
 235     AC_DEFINE_UNQUOTED(HAVE_WIN32, 1, [Defined if compiling for Windows])
 236     ;;
 237   *)
 238     ;;
 239 esac
 240
 241 dnl *** checks for programs ***
 242
 243 dnl find a compiler
 244 AC_PROG_CC
 245
 246 dnl check if the compiler supports '-c' and '-o' options
 247 AM_PROG_CC_C_O
 248
 249 dnl find an assembler
 250 AM_PROG_AS
 251
 252 dnl Perl is used in building documentation and in the version checks
 253 AC_PATH_PROG(PERL_PATH, perl, no)
 254 if test x$PERL_PATH = xno; then
 255   AC_MSG_ERROR(Could not find perl)
 256 fi
 257
 258 dnl we require flex and bison for building the parser
 259 AG_GST_BISON_CHECK
 260 AG_GST_FLEX_CHECK
 261
 262 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 263 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 264
 265 dnl check for documentation tools
 266 AG_GST_DOCBOOK_CHECK
 267 GTK_DOC_CHECK([1.3])
 268 AS_PATH_PYTHON([2.1])
 269 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 270
 271 dnl *** checks for libraries ***
 272
 273 dnl For interactive UNIX (a Sun thing)
 274 dnl FIXME: this adds -lcposix to LIBS, but I doubt we use LIBS
 275 AC_ISC_POSIX
 276
 277 dnl check for libm, for sin()
 278 AC_CHECK_LIBM
 279 AC_SUBST(LIBM)
 280
 281 dnl *** checks for header files ***
 282
 283 dnl check if we have ANSI C header files
 284 AC_HEADER_STDC
 285
 286 dnl Check for ucontext.h
 287 AC_CHECK_HEADERS([ucontext.h])
 288
 289 dnl Check for sys/socket.h
 290 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 291 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 292
 293 dnl check for sys/times.h for tests/examples/adapter/
 294 AC_CHECK_HEADERS([sys/times.h], HAVE_SYS_TIMES_H=yes)
 295 AC_CHECK_HEADERS([unistd.h], HAVE_UNISTD_H=yes)
 296 AM_CONDITIONAL(HAVE_SYS_TIMES_H_AND_UNISTD_H, test "x$HAVE_SYS_TIMES_H" = "xyes" -a "x$HAVE_UNISTD_H" = "xyes")
 297
 298 dnl Check for process.h for getpid() on win32
 299 AC_CHECK_HEADERS([process.h])
 300
 301 dnl Check for sys/utsname.h for uname
 302 AC_CHECK_HEADERS([sys/utsname.h])
 303
 304 dnl Check for stdio_ext.f for __fbufsize
 305 AC_CHECK_HEADERS([stdio_ext.h])
 306
 307 dnl *** checks for types/defines ***
 308
 309 dnl *** checks for structures ***
 310
 311 dnl *** checks for compiler characteristics ***
 312
 313 dnl make sure we can use "inline" from C code
 314 AC_C_INLINE
 315
 316 OPT_CFLAGS=
 317 dnl Check for some compiler flags that optimize our code.
 318 if test "x$GCC" = xyes; then
 319   AS_COMPILER_FLAG(-fno-common, OPT_CFLAGS="$OPT_CFLAGS -fno-common")
 320 fi
 321
 322 dnl FIXME: decide what kind of flag this is, maybe it's not an optimization
 323 dnl flag
 324 dnl check if we should use -Wa,-mregnames on PowerPC, so we can use
 325 dnl symbolic register names in inline asm
 326 if test x$HAVE_CPU_PPC = xyes ; then
 327   AS_COMPILER_FLAG(["-Wa,-mregnames"],
 328     [OPT_CFLAGS="$OPT_CFLAGS -Wa,-mregnames"])
 329 fi
 330
 331 dnl *** checks for library functions ***
 332
 333 AC_CHECK_FUNCS([sigaction])
 334
 335 dnl we use fork in the registry code
 336 AC_CHECK_FUNCS([fork])
 337
 338 dnl check for fseeko()
 339 AC_FUNC_FSEEKO
 340 dnl check for ftello()
 341 AC_CHECK_FUNCS([ftello])
 342
 343 AC_CHECK_FUNCS([fgetpos])
 344 AC_CHECK_FUNCS([fsetpos])
 345
 346 dnl check for poll(), ppoll() and pselect()
 347 AC_CHECK_FUNCS([poll])
 348 AC_CHECK_FUNCS([ppoll])
 349 AC_CHECK_FUNCS([pselect])
 350
 351 dnl check for mmap()
 352 AC_FUNC_MMAP
 353 AM_CONDITIONAL(HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 354
 355 dnl Check for POSIX timers
 356 AC_CHECK_FUNCS(clock_gettime, [], [
 357   AC_CHECK_LIB(rt, clock_gettime, [
 358     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 359     LIBS="$LIBS -lrt"
 360   ])
 361 ])
 362
 363 AC_CACHE_CHECK(for posix timers, gst_cv_posix_timers,
 364     AC_TRY_COMPILE([
 365 #include <time.h>
 366 #ifdef HAVE_UNISTD_H
 367 #include <unistd.h>
 368 #endif
 369     ], [
 370 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 371 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 372 #endif
 373       return 0;
 374     ], [
 375       gst_cv_posix_timers=yes
 376     ], [
 377       gst_cv_posix_timers=no
 378     ])
 379 )
 380
 381 if test "$gst_cv_posix_timers" = "yes"; then
 382   AC_DEFINE(HAVE_POSIX_TIMERS,1,[Have posix timers])
 383   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 1"
 384 else
 385   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 0"
 386 fi
 387 AC_SUBST(GST_HAVE_POSIX_TIMERS_DEFINE)
 388 AM_CONDITIONAL(GST_HAVE_POSIX_TIMERS, test "$gst_cv_posix_timers" = "yes")
 389
 390 AC_CACHE_CHECK(for monotonic clock, gst_cv_monotonic_clock,
 391     AC_TRY_COMPILE([
 392 #include <time.h>
 393 #ifdef HAVE_UNISTD_H
 394 #include <unistd.h>
 395 #endif
 396     ], [
 397 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 398 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 399 #endif
 400       return 0;
 401     ], [
 402       gst_cv_monotonic_clock=yes
 403     ], [
 404       gst_cv_monotonic_clock=no
 405     ])
 406 )
 407
 408 if test "$gst_cv_monotonic_clock" = "yes"; then
 409   AC_DEFINE(HAVE_MONOTONIC_CLOCK,1,[Have a monotonic clock])
 410   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 1"
 411 else
 412   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 0"
 413 fi
 414 AC_SUBST(GST_HAVE_MONOTONIC_CLOCK_DEFINE)
 415 AM_CONDITIONAL(GST_HAVE_MONOTONIC_CLOCK, test "$gst_cv_monotonic_clock" = "yes")
 416
 417 dnl Check for a way to display the function name in debug output
 418 AG_GST_CHECK_FUNCTION
 419
 420 dnl test for register_printf_function
 421 AC_CHECK_FUNC(register_printf_function,
 422   [
 423     GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE="#define GST_PTR_FORMAT \"P\""
 424     GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE="#define GST_SEGMENT_FORMAT \"Q\""
 425     GST_USING_PRINTF_EXTENSION_DEFINE="#define GST_USING_PRINTF_EXTENSION"
 426     AC_DEFINE(HAVE_PRINTF_EXTENSION, 1,
 427       [Defined if we have register_printf_function ()])
 428   ], [
 429     GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE="#define GST_PTR_FORMAT \"p\""
 430     GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE="#define GST_SEGMENT_FORMAT \"p\""
 431     GST_USING_PRINTF_EXTENSION_DEFINE="#undef GST_USING_PRINTF_EXTENSION"
 432   ]
 433 )
 434 AC_SUBST(GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE)
 435 AC_SUBST(GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE)
 436 AC_SUBST(GST_USING_PRINTF_EXTENSION_DEFINE)
 437
 438 dnl test if we have dladdr(); we use it for debugging; see gst/gstinfo.c
 439 save_cflags="$CFLAGS"
 440 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 441 AC_CHECK_LIB(dl, dladdr,
 442    AC_DEFINE(HAVE_DLADDR, 1,
 443              [Defined if we have dladdr ()]))
 444 CFLAGS="$save_cflags"
 445
 446 dnl check for inet_aton()
 447 save_libs="$LIBS"
 448 AC_CHECK_FUNC(inet_aton, ,
 449    AC_CHECK_LIB(nsl, inet_aton, ,
 450       AC_CHECK_LIB(socket, inet_aton, ,
 451          AC_CHECK_LIB(resolv, inet_aton, ,[AC_DEFINE(NO_INET_ATON, 1, [Define if you have no native inet_aton() function.])]))))
 452 INET_ATON_LIBS=$LIBS
 453 AC_SUBST(INET_ATON_LIBS)
 454 LIBS="$save_libs"
 455
 456 dnl *** checks for dependency libraries ***
 457
 458 dnl GLib
 459
 460 AG_GST_GLIB_CHECK([2.8])
 461
 462 dnl FIXME: 0.11: Guess we need to keep this around until 0.11
 463 GST_HAVE_GLIB_2_8_DEFINE="#define GST_HAVE_GLIB_2_8 1"
 464 AC_SUBST(GST_HAVE_GLIB_2_8_DEFINE)
 465
 466 dnl Check for glib2 without extra fat, useful for the unversioned tool frontends
 467 PKG_CHECK_MODULES(GLIB_ONLY, glib-2.0 >= $GLIB_REQ)
 468
 469 dnl Check for documentation xrefs
 470 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 471 AC_SUBST(GLIB_PREFIX)
 472
 473 dnl libxml 2 is optional in some cases
 474 if test "x$GST_DISABLE_LOADSAVE" = "xyes" && \
 475    ( test "x$GST_DISABLE_REGISTRY" = "xyes" || \
 476    test "x$USE_BINARY_REGISTRY" = "xyes" )
 477 then
 478   AC_MSG_NOTICE([XML registry and load/save are disabled, not checking for libxml2])
 479   GST_DISABLE_XML_DEFINE="#define GST_DISABLE_XML 1"
 480 else
 481   dnl check for libxml2 with minimum req version
 482   AG_GST_LIBXML2_CHECK(2.4.9)
 483   GST_DISABLE_XML_DEFINE="/* #undef GST_DISABLE_XML */"
 484 fi
 485 AC_SUBST(GST_DISABLE_XML_DEFINE)
 486
 487 dnl check for "check", unit testing library/header
 488 AM_PATH_CHECK(0.9.2,
 489     [
 490         HAVE_CHECK=yes
 491         AC_MSG_NOTICE(CHECK_CFLAGS: $CHECK_CFLAGS)
 492         AC_MSG_NOTICE(CHECK_LIBS: $CHECK_LIBS)
 493     ],
 494     HAVE_CHECK=no)
 495 AM_CONDITIONAL(HAVE_CHECK, test "x$HAVE_CHECK" = "xyes")
 496
 497 dnl pkg-config check that for libcheck that works for cross-compiling
 498 dnl but not normal compilation on Fedora & Ubuntu:
 499 dnl PKG_CHECK_MODULES(CHECK, check >= 0.9.2,
 500 dnl   AM_CONDITIONAL(HAVE_CHECK, true),
 501 dnl   AM_CONDITIONAL(HAVE_CHECK, false)
 502 dnl )
 503
 504 dnl *** set variables based on configure arguments
 505
 506 dnl set license and copyright notice
 507 GST_LICENSE="LGPL"
 508 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 509 AC_SUBST(GST_LICENSE)
 510
 511 dnl define LIBDIR so we can inform people where we live
 512 AS_AC_EXPAND(LIBDIR, $libdir)
 513 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [library dir])
 514
 515 dnl set location of plugin directory
 516 AG_GST_SET_PLUGINDIR
 517
 518 dnl FIXME: add LIBXML_PKG here if we use it
 519 GST_PKG_DEPS="glib-2.0, gobject-2.0, gmodule-no-export-2.0, gthread-2.0"
 520 AC_SUBST(GST_PKG_DEPS)
 521
 522 dnl define an ERROR_CFLAGS Makefile variable
 523 AG_GST_SET_ERROR_CFLAGS($GST_CVS)
 524
 525 dnl define correct level for debugging messages
 526 AG_GST_SET_LEVEL_DEFAULT($GST_CVS)
 527
 528 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 529
 530 dnl Overview:
 531 dnl GST_OPTION_CFLAGS:  common cflags for profiling, debugging, errors, ...
 532 dnl GST_ALL_*:          vars shared by all built objects
 533 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 534 dnl GST_OBJ_*:          additional vars to link to the core library
 535 dnl                     include GST_ALL_*
 536 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 537 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 538
 539 dnl GST_OPTION_CFLAGS
 540 if test "x$USE_DEBUG" = xyes; then
 541    PROFILE_CFLAGS="-g"
 542 fi
 543 AC_SUBST(PROFILE_CFLAGS)
 544
 545 # GST_DISABLE_DEPRECATED: hide the visibility of deprecated
 546 # functionality from the API that gstreamer uses
 547 # GST_REMOVE_DEPRECATED: don't compile deprecated functionality (breaks ABI)
 548 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 549   dnl Define _only_ during CVS (not pre-releases or releases)
 550   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 551 else
 552   DEPRECATED_CFLAGS=""
 553 fi
 554 AC_SUBST(DEPRECATED_CFLAGS)
 555
 556 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time via e.g.
 557 dnl make DEPRECATED_CFLAGS=''
 558 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 559 AC_SUBST(GST_OPTION_CFLAGS)
 560
 561 dnl GST_ALL_*
 562 dnl vars common to for all internal objects (core libs, elements, applications)
 563 dnl CFLAGS:
 564 dnl - XML needs to be added because xmlPtr is used in core
 565 dnl - src and build dirs need to be added because every piece that gets built
 566 dnl   will need the GStreamer source and generated headers
 567 dnl LIBS: XML doesn't need to be added because we don't explicitly use symbols
 568 dnl       from LibXML except for in the core library
 569 GST_ALL_CFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir) $GLIB_CFLAGS $XML_CFLAGS \$(GST_OPTION_CFLAGS)"
 570
 571 dnl FIXME: check if LTLIBINTL is needed everywhere
 572 dnl I presume it is given that it contains the symbols that _() stuff maps to
 573 GST_ALL_LIBS="$GLIB_LIBS $LTLIBINTL \$(GCOV_LIBS)"
 574
 575 dnl LDFLAGS really should only contain flags, not libs - they get added before
 576 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 577 GST_ALL_LDFLAGS="-no-undefined"
 578
 579 AC_SUBST(GST_ALL_CFLAGS)
 580 AC_SUBST(GST_ALL_LIBS)
 581 AC_SUBST(GST_ALL_LDFLAGS)
 582
 583 dnl GST_LIB_LDFLAGS
 584 dnl linker flags shared by all libraries
 585 dnl LDFLAGS modifier defining exported symbols from built libraries
 586 GST_LIB_LDFLAGS="-export-symbols-regex \^[_]*\(gst_\|Gst\|GST_\).*"
 587 AC_SUBST(GST_LIB_LDFLAGS)
 588 dnl Version of the linker flags specifically for libgstcheck to support the boonky extra symbols it exports.
 589 GST_CHECK_LIB_LDFLAGS="-export-symbols-regex \^\([_]*\(gst_\|Gst\|GST_\).*\|check_\(debug\|mutex\|cond\)\|buffers\|mutex\|start_cond\|sync_cond\|thread_list\)$"
 590 dnl HACK: add non-portable --export-dynamic if we have GNU ld (needed on my debian stable, tpm)
 591 if test "x$ac_cv_prog_gnu_ld" = "xyes" -o "x$acl_cv_prog_gnu_ld" = "xyes" ; then
 592   GST_CHECK_LIB_LDFLAGS="-Wl,--export-dynamic $GST_CHECK_LIB_LDFLAGS"
 593 fi
 594 AC_SUBST(GST_CHECK_LIB_LDFLAGS)
 595
 596 dnl GST_OBJ_*
 597 dnl default vars for all internal objects built on libgstreamer
 598 dnl includes GST_ALL_*
 599 GST_OBJ_CFLAGS="\$(GST_ALL_CFLAGS)"
 600 GST_OBJ_LIBS="\$(top_builddir)/gst/libgstreamer-$GST_MAJORMINOR.la \$(GST_ALL_LIBS)"
 601 AC_SUBST(GST_OBJ_CFLAGS)
 602 AC_SUBST(GST_OBJ_LIBS)
 603
 604 dnl GST_PLUGIN_LDFLAGS
 605 dnl LDFLAGS for plugins; includes GST_ALL_LDFLAGS
 606 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 607 AC_SUBST(GST_PLUGIN_LDFLAGS, "$GST_PLUGIN_LDFLAGS")
 608
 609 AC_CONFIG_FILES(
 610 Makefile
 611 gst/Makefile
 612 gst/gstconfig.h
 613 gst/gstversion.h
 614 gst/parse/Makefile
 615 libs/Makefile
 616 libs/gst/Makefile
 617 libs/gst/base/Makefile
 618 libs/gst/check/Makefile
 619 libs/gst/controller/Makefile
 620 libs/gst/dataprotocol/Makefile
 621 libs/gst/net/Makefile
 622 plugins/Makefile
 623 plugins/indexers/Makefile
 624 plugins/elements/Makefile
 625 po/Makefile.in
 626 tests/Makefile
 627 tests/benchmarks/Makefile
 628 tests/check/Makefile
 629 tests/misc/Makefile
 630 tests/examples/Makefile
 631 tests/examples/adapter/Makefile
 632 tests/examples/controller/Makefile
 633 tests/examples/helloworld/Makefile
 634 tests/examples/launch/Makefile
 635 tests/examples/manual/Makefile
 636 tests/examples/metadata/Makefile
 637 tests/examples/queue/Makefile
 638 tests/examples/typefind/Makefile
 639 tests/examples/xml/Makefile
 640 tools/Makefile
 641 common/Makefile
 642 common/m4/Makefile
 643 docs/Makefile
 644 docs/design/Makefile
 645 docs/faq/Makefile
 646 docs/gst/Makefile
 647 docs/gst/gstreamer.types
 648 docs/libs/Makefile
 649 docs/plugins/Makefile
 650 docs/manual/Makefile
 651 docs/pwg/Makefile
 652 docs/slides/Makefile
 653 docs/xsl/Makefile
 654 docs/version.entities
 655 win32/common/config.h
 656 pkgconfig/Makefile
 657 stamp.h
 658 pkgconfig/gstreamer.pc
 659 pkgconfig/gstreamer-uninstalled.pc
 660 pkgconfig/gstreamer-base.pc
 661 pkgconfig/gstreamer-base-uninstalled.pc
 662 pkgconfig/gstreamer-check.pc
 663 pkgconfig/gstreamer-check-uninstalled.pc
 664 pkgconfig/gstreamer-controller.pc
 665 pkgconfig/gstreamer-controller-uninstalled.pc
 666 pkgconfig/gstreamer-dataprotocol.pc
 667 pkgconfig/gstreamer-dataprotocol-uninstalled.pc
 668 pkgconfig/gstreamer-net.pc
 669 pkgconfig/gstreamer-net-uninstalled.pc
 670 gst-element-check.m4
 671 gstreamer.spec
 672 )
 673
 674 AC_OUTPUT