configure.ac

   1 AC_PREREQ([2.69])
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, git and prerelease does Werror too
   6 dnl
   7 AC_INIT([GStreamer],[1.13.0.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gstreamer])
   8 AG_GST_INIT
   9
  10 dnl initialize automake (we require GNU make)
  11 AM_INIT_AUTOMAKE([-Wno-portability 1.14 no-dist-gzip dist-xz tar-ustar subdir-objects])
  12
  13 dnl define PACKAGE_VERSION_* variables
  14 AS_VERSION
  15
  16 dnl check if this is a release version
  17 AS_NANO(GST_GIT="no", GST_GIT="yes")
  18
  19 dnl can autoconf find the source ?
  20 AC_CONFIG_SRCDIR([gst/gst.c])
  21
  22 dnl define the output header for config
  23 AC_CONFIG_HEADERS([config.h])
  24
  25 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  26 AM_MAINTAINER_MODE([enable])
  27
  28 dnl sets host_* variables
  29 AC_CANONICAL_HOST
  30
  31 dnl use pretty build output by default
  32 AM_SILENT_RULES([yes])
  33
  34 dnl GStreamer versioning, this is mostly informational
  35 GST_VERSION_MAJOR=$PACKAGE_VERSION_MAJOR
  36 GST_VERSION_MINOR=$PACKAGE_VERSION_MINOR
  37 GST_VERSION_MICRO=$PACKAGE_VERSION_MICRO
  38 GST_VERSION_NANO=$PACKAGE_VERSION_NANO
  39 AC_SUBST(GST_VERSION_MAJOR)
  40 AC_SUBST(GST_VERSION_MINOR)
  41 AC_SUBST(GST_VERSION_MICRO)
  42 AC_SUBST(GST_VERSION_NANO)
  43
  44 dnl our libraries and install dirs use GST_API_VERSION in the filename
  45 dnl to allow side-by-side installation of different API versions
  46 GST_API_VERSION=1.0
  47 AC_SUBST(GST_API_VERSION)
  48 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  49   [GStreamer API Version])
  50
  51 dnl CURRENT, REVISION, AGE
  52 dnl - library source changed -> increment REVISION
  53 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  54 dnl - interfaces added -> increment AGE
  55 dnl - interfaces removed -> AGE = 0
  56 dnl
  57 dnl Keep CURRENT as MINOR * 100 + MICRO
  58 dnl Ex : 1.0.0 => 0
  59 dnl      1.0.3 => 3
  60 dnl      1.1.0 => 100
  61 dnl      1.2.5 => 205
  62 dnl      1.10.9 (who knows) => 1009
  63 dnl
  64 dnl sets GST_LT_LDFLAGS
  65 AS_LIBTOOL(GST, 1300, 0, 1300)
  66
  67 dnl *** autotools stuff ****
  68
  69 dnl allow for different autotools
  70 AS_AUTOTOOLS_ALTERNATE
  71
  72 dnl Add parameters for aclocal (keep in sync with Makefile.am)
  73 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  74
  75 dnl set up gettext
  76 dnl the version check needs to stay here because autopoint greps for it
  77 AM_GNU_GETTEXT_VERSION([0.17])
  78 AM_GNU_GETTEXT([external])
  79 AG_GST_GETTEXT([gstreamer-$GST_API_VERSION])
  80
  81 dnl *** check for arguments to configure ***
  82
  83 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  84 AG_GST_ARG_ENABLE_EXTRA_CHECKS
  85
  86 dnl subsystems - can influence other decisions so needs to be high up
  87 dnl we need to AM_CONDITIONAL them here for automake 1.6.x compatibility
  88 AG_GST_CHECK_SUBSYSTEM_DISABLE(GST_DEBUG,[debugging subsystem])
  89 AM_CONDITIONAL(GST_DISABLE_GST_DEBUG, test "x$GST_DISABLE_GST_DEBUG" = "xyes")
  90 AG_GST_CHECK_SUBSYSTEM_DISABLE(GST_TRACER_HOOKS,[tracing subsystem hooks])
  91 AM_CONDITIONAL(GST_DISABLE_GST_TRACER_HOOKS, test "x$GST_DISABLE_GST_TRACER_HOOKS" = "xyes")
  92 AG_GST_CHECK_SUBSYSTEM_DISABLE(PARSE,[command-line parser])
  93 AM_CONDITIONAL(GST_DISABLE_PARSE, test "x$GST_DISABLE_PARSE" = "xyes")
  94 if test "x$GST_DISABLE_PARSE" = xyes; then
  95   AC_DEFINE(GST_DISABLE_PARSE, 1,
  96     [Define if pipeline parsing code is disabled])
  97 fi
  98 AG_GST_CHECK_SUBSYSTEM_DISABLE(OPTION_PARSING,[option parsing when gst_init])
  99 AM_CONDITIONAL(GST_DISABLE_OPTION_PARSING, test "x$GST_DISABLE_OPTION_PARSING" = "xyes")
 100 if test "x$GST_DISABLE_OPTION_PARSING" = xyes; then
 101   AC_DEFINE(GST_DISABLE_OPTION_PARSING, 1,
 102     [Define if option parsing is disabled])
 103 fi
 104 AG_GST_CHECK_SUBSYSTEM_DISABLE(REGISTRY,[plugin registry])
 105 AM_CONDITIONAL(GST_DISABLE_REGISTRY, test "x$GST_DISABLE_REGISTRY" = "xyes")
 106 dnl define a substitution to use in docs/gst/gstreamer.types
 107 if test "x$GST_DISABLE_REGISTRY" = "xyes"
 108 then
 109   GST_REGISTRY_DOC_TYPES="%"
 110 else
 111   GST_REGISTRY_DOC_TYPES=
 112 fi
 113 AC_SUBST(GST_REGISTRY_DOC_TYPES)
 114 AG_GST_CHECK_SUBSYSTEM_DISABLE(PLUGIN,[plugin])
 115 AM_CONDITIONAL(GST_DISABLE_PLUGIN, test "x$GST_DISABLE_PLUGIN" = "xyes")
 116
 117 AG_GST_ARG_DEBUG
 118 AG_GST_ARG_PROFILING
 119 AG_GST_ARG_VALGRIND
 120 AG_GST_ARG_GCOV
 121
 122 AG_GST_ARG_EXAMPLES
 123
 124 AG_GST_ARG_WITH_PKG_CONFIG_PATH
 125 AG_GST_ARG_WITH_PACKAGE_NAME
 126 AG_GST_ARG_WITH_PACKAGE_ORIGIN
 127
 128 AG_GST_PKG_CONFIG_PATH
 129
 130 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 131   ["${srcdir}/gstreamer.doap"],
 132   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 133
 134 # We only use this when building with MSVC, which is only done with the
 135 # alternate Meson build system files
 136 GSTCONFIG_BUILT_WITH_MSVC=0
 137 AC_SUBST(GSTCONFIG_BUILT_WITH_MSVC)
 138
 139 dnl check for bash completion
 140 AC_ARG_WITH([bash-completion-dir],
 141     AS_HELP_STRING([--with-bash-completion-dir[=PATH]],
 142         [Install the bash auto-completion script in this directory. @<:@default=yes@:>@]),
 143     [],
 144     [with_bash_completion_dir=yes])
 145
 146 if test "x$with_bash_completion_dir" = "xyes"
 147 then
 148     extra_args=
 149
 150     if test "x$prefix" != "xNONE"
 151     then
 152         extra_args="--define-variable=prefix=\"$prefix\""
 153     fi
 154
 155     PKG_CHECK_MODULES([BASH_COMPLETION], [bash-completion >= 2.0],
 156         [
 157           BASH_COMPLETION_DIR="`eval pkg-config $extra_args --variable=completionsdir bash-completion`"
 158           BASH_HELPERS_DIR="`eval pkg-config $extra_args --variable=helpersdir bash-completion`"
 159         ],
 160         [
 161           BASH_COMPLETION_DIR="$datadir/bash-completion/completions"
 162           BASH_HELPERS_DIR="$datadir/bash-completion/helpers"
 163         ])
 164 else
 165     BASH_COMPLETION_DIR="$with_bash_completion_dir/completions"
 166     BASH_HELPERS_DIR="$with_bash_completion_dir/helpers"
 167 fi
 168
 169 AC_SUBST([BASH_COMPLETION_DIR])
 170 AC_SUBST([BASH_HELPERS_DIR])
 171 AM_CONDITIONAL([ENABLE_BASH_COMPLETION],[test "x$with_bash_completion_dir" != "xno"])
 172
 173 dnl build static plugins or not
 174 AC_MSG_CHECKING([whether to build static plugins or not])
 175 AC_ARG_ENABLE(
 176   static-plugins,
 177   AC_HELP_STRING(
 178     [--enable-static-plugins],
 179     [build static plugins @<:@default=no@:>@]),
 180   [AS_CASE(
 181     [$enableval], [no], [], [yes], [],
 182     [AC_MSG_ERROR([bad value "$enableval" for --enable-static-plugins])])],
 183   [enable_static_plugins=no])
 184 AC_MSG_RESULT([$enable_static_plugins])
 185 if test "x$enable_static_plugins" = xyes; then
 186   AC_DEFINE(GST_PLUGIN_BUILD_STATIC, 1,
 187     [Define if static plugins should be built])
 188   GST_PLUGIN_LIBTOOLFLAGS=""
 189 else
 190   GST_PLUGIN_LIBTOOLFLAGS="--tag=disable-static"
 191 fi
 192 AC_SUBST(GST_PLUGIN_LIBTOOLFLAGS)
 193 AM_CONDITIONAL(GST_PLUGIN_BUILD_STATIC, test "x$enable_static_plugins" = "xyes")
 194
 195 dnl If only building static libraries, define GST_STATIC_COMPILATION. This is
 196 dnl needed only on Windows, but it doesn't hurt to have it everywhere.
 197 if test x$enable_static = xyes -a x$enable_shared = xno; then
 198   GST_OBJ_STATIC_CFLAGS="-DGST_STATIC_COMPILATION"
 199 fi
 200
 201 dnl building of tests
 202 AC_ARG_ENABLE(tests,
 203   AS_HELP_STRING([--disable-tests],[disable building test apps]),
 204   [
 205     case "${enableval}" in
 206       yes) BUILD_TESTS=yes ;;
 207       no)  BUILD_TESTS=no ;;
 208       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 209     esac
 210   ],
 211 [BUILD_TESTS=yes]) dnl Default value
 212 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 213
 214 dnl tests known to fail
 215 AC_ARG_ENABLE(failing-tests,
 216   AS_HELP_STRING([--disable-failing-tests],[disable building tests known to fail]),
 217   [
 218     case "${enableval}" in
 219       yes) BUILD_FAILING_TESTS=yes ;;
 220       no)  BUILD_FAILING_TESTS=no ;;
 221       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-failing-tests) ;;
 222     esac
 223   ],
 224   [BUILD_FAILING_TESTS=no]) dnl Default value
 225 AM_CONDITIONAL(BUILD_FAILING_TESTS, test "x$BUILD_FAILING_TESTS" = "xyes")
 226 if test x$BUILD_FAILING_TESTS = xyes; then
 227   AC_MSG_WARN([building tests known to fail, use --disable-failing-tests to disable])
 228 else
 229   AC_MSG_WARN([Sissy ! By asking to not build the tests known to fail, you hereby waive your right to customer support.  If you do not agree with this EULA, please press Ctrl-C before the next line is printed.  By allowing the next line to be printed, you expressly acknowledge your acceptance of this EULA.])
 230 fi
 231
 232 dnl building of benchmarks
 233 AC_ARG_ENABLE(benchmarks,
 234   AS_HELP_STRING([--disable-benchmarks],[disable building benchmarks apps]),
 235   [
 236     case "${enableval}" in
 237       yes) BUILD_BENCHMARKS=yes ;;
 238       no)  BUILD_BENCHMARKS=no ;;
 239       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-benchmarks) ;;
 240     esac
 241   ],
 242 [BUILD_BENCHMARKS=yes]) dnl Default value
 243 AM_CONDITIONAL(BUILD_BENCHMARKS, test "x$BUILD_BENCHMARKS" = "xyes")
 244
 245 dnl building of tools
 246 AC_ARG_ENABLE(tools,
 247   AS_HELP_STRING([--disable-tools],[disable building tools]),
 248   [
 249     case "${enableval}" in
 250       yes) BUILD_TOOLS=yes ;;
 251       no)  BUILD_TOOLS=no ;;
 252       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tools) ;;
 253     esac
 254   ],
 255 [BUILD_TOOLS=yes]) dnl Default value
 256 AM_CONDITIONAL(BUILD_TOOLS, test "x$BUILD_TOOLS" = "xyes")
 257
 258 dnl poison destroyed objects
 259 AC_ARG_ENABLE(poisoning,
 260   AS_HELP_STRING([--enable-poisoning],[enable poisoning of deallocated objects]),
 261   [
 262     case "${enableval}" in
 263       yes) USE_POISONING=yes ;;
 264       no)  USE_POISONING=no ;;
 265       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-poisoning) ;;
 266     esac
 267   ],
 268   [USE_POISONING=no]) dnl Default value
 269 if test "x$USE_POISONING" = xyes; then
 270   AC_DEFINE(USE_POISONING, 1,
 271     [Define if we should poison deallocated memory])
 272 fi
 273
 274 dnl PTP support parts
 275 AC_MSG_CHECKING([whether PTP support can be enabled])
 276 case "$host_os" in
 277   *android*)
 278     dnl Can't run on Android because of permissions
 279     HAVE_PTP=no
 280     ;;
 281   mingw*|pw32*|cygwin*)
 282     dnl Not ported to Windows yet
 283     HAVE_PTP=no
 284     ;;
 285   darwin*)
 286     dnl Can't run on iOS because of permissions
 287     AC_CHECK_HEADER(MobileCoreServices/MobileCoreServices.h, HAVE_PTP="no", HAVE_PTP="yes", [-])
 288     ;;
 289   linux*|darwin*|solaris*|netbsd*|freebsd*|openbsd*|kfreebsd*|dragonfly*|gnu*)
 290     HAVE_PTP=yes
 291     ;;
 292   *)
 293     HAVE_PTP=no
 294     ;;
 295 esac
 296 AC_MSG_RESULT([$HAVE_PTP])
 297
 298 dnl user/group to change to in gst-ptp-helper
 299 AC_ARG_WITH([ptp-helper-setuid-user],
 300   AS_HELP_STRING([--with-ptp-helper-setuid-user],[User to switch to when installing gst-ptp-helper setuid root]),
 301   [
 302     if test "x$withval" != "x"
 303     then
 304       AC_DEFINE_UNQUOTED(HAVE_PTP_HELPER_SETUID_USER, "$withval", [PTP helper setuid user])
 305     fi
 306   ], []
 307 )
 308
 309 dnl group/group to change to in gst-ptp-helper
 310 AC_ARG_WITH([ptp-helper-setuid-group],
 311   AS_HELP_STRING([--with-ptp-helper-setuid-group],[Group to switch to when installing gst-ptp-helper setuid root]),
 312   [
 313     if test "x$withval" != "x"
 314     then
 315       AC_DEFINE_UNQUOTED(HAVE_PTP_HELPER_SETUID_GROUP, "$withval", [PTP helper setuid group])
 316     fi
 317   ], []
 318 )
 319
 320 AC_ARG_WITH(
 321   ptp-helper-permissions,
 322   AC_HELP_STRING(
 323     [--with-ptp-helper-permissions],
 324     [how to gain PTP permissions (none, setuid-root, capabilities, auto)]),
 325     [],
 326     [with_ptp_helper_permissions=auto])
 327
 328 gst_ptp_have_cap=no
 329 AG_GST_CHECK_LIBHEADER(CAP, cap,
 330                        cap_init, ,
 331                        sys/capability.h,
 332                        CAP_LIBS="-lcap"
 333                        AC_SUBST(CAP_LIBS)
 334                        gst_ptp_have_cap=yes)
 335
 336 AC_PATH_PROG([SETCAP], [setcap], [no], [$PATH:/usr/bin:/bin:/usr/sbin:/sbin])
 337
 338 if test "x$HAVE_PTP" = "xyes"; then
 339 AC_DEFINE(HAVE_PTP, 1, [PTP support available])
 340
 341 AC_MSG_CHECKING([for SIOCGIFCONF, SIOCGIFFLAGS and SIOCGIFHWADDR])
 342 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 343     [[
 344         #include <sys/ioctl.h>
 345         #include <net/if.h>
 346     ]],
 347     [[
 348         struct ifreq ifr;
 349         struct ifconf ifc;
 350         ioctl(0, SIOCGIFCONF, &ifc);
 351         ioctl(0, SIOCGIFFLAGS, &ifr);
 352         ioctl(0, SIOCGIFHWADDR, &ifr);
 353         int dummy = ifr.ifr_hwaddr.sa_data[0];
 354     ]])], [
 355         AC_MSG_RESULT(yes)
 356         AC_DEFINE(HAVE_SIOCGIFCONF_SIOCGIFFLAGS_SIOCGIFHWADDR, 1, [SIOCGIFCONF, SIOCGIFFLAGS and SIOCGIFHWADDR is available])
 357     ], [
 358         AC_MSG_RESULT(no)
 359 ])
 360
 361 AC_MSG_CHECKING([for getifaddrs() and AF_LINK])
 362 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 363     [[
 364         #include <ifaddrs.h>
 365         #include <net/if.h>
 366         #include <net/if_dl.h>
 367     ]],
 368     [[
 369         struct ifaddrs *ifaddr;
 370         getifaddrs(&ifaddr);
 371         int dummy = (ifaddr->ifa_flags & IFF_LOOPBACK) && ifaddr->ifa_addr->sa_family != AF_LINK;
 372     ]])], [
 373         AC_MSG_RESULT(yes)
 374         AC_DEFINE(HAVE_GETIFADDRS_AF_LINK, 1, [getifaddrs() and AF_LINK is available])
 375     ], [
 376         AC_MSG_RESULT(no)
 377     ])
 378
 379 AC_MSG_CHECKING([how to install gst-ptp-helper])
 380 if test "x$with_ptp_helper_permissions" = "xauto"; then
 381     if test "x$gst_ptp_have_cap" = "xyes" -a "x$SETCAP" != "xno"; then
 382         with_ptp_helper_permissions="capabilities"
 383     else
 384         with_ptp_helper_permissions="setuid-root"
 385     fi
 386 fi
 387 AC_MSG_RESULT([$with_ptp_helper_permissions])
 388
 389 case "$with_ptp_helper_permissions" in
 390   none)
 391     ;;
 392   setuid-root)
 393      AC_DEFINE(HAVE_PTP_HELPER_SETUID, 1,
 394         [Use setuid-root for permissions in PTP helper])
 395     ;;
 396   capabilities)
 397      AC_DEFINE(HAVE_PTP_HELPER_CAPABILITIES, 1,
 398         [Use capabilities for permissions in PTP helper])
 399     ;;
 400   *)
 401     AC_MSG_ERROR(Invalid parameter [$with_ptp_helper_permissions])
 402     ;;
 403 esac
 404
 405 fi
 406
 407 AM_CONDITIONAL(HAVE_PTP, test "x$HAVE_PTP" = "xyes")
 408 AM_CONDITIONAL(HAVE_PTP_HELPER_SETUID, test "x$with_ptp_helper_permissions" = "xsetuid-root")
 409 AM_CONDITIONAL(HAVE_PTP_HELPER_CAPABILITIES, test "x$with_ptp_helper_permissions" = "xcapabilities")
 410
 411 dnl *** checks for platform ***
 412
 413 dnl * hardware/architecture *
 414
 415 dnl common/m4/gst-arch.m4
 416 dnl check CPU type
 417 AG_GST_ARCH
 418
 419 dnl check for platform specific settings
 420 AG_GST_PLATFORM
 421
 422 dnl * software *
 423
 424 dnl check for large file support
 425 dnl affected plugins must include config.h
 426 AC_SYS_LARGEFILE
 427
 428 dnl *** checks for programs ***
 429
 430 dnl find a compiler
 431 AC_PROG_CC
 432 AC_PROG_CC_STDC
 433
 434 dnl check if the compiler supports '-c' and '-o' options
 435 AM_PROG_CC_C_O
 436
 437 dnl find an assembler
 438 AM_PROG_AS
 439
 440 dnl determine if c++ is available on this system
 441 AC_PROG_CXX
 442 dnl CXX may be set to some default even if no c++ compiler is available
 443 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 444 AC_LANG_PUSH([C++])
 445 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ class Foo { int bar; };]], [[]])],[working_cxx=yes],[working_cxx=no])
 446 AC_LANG_POP([C++])
 447 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 448 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 449
 450 dnl Perl is used in building documentation and in the version checks
 451 AC_PATH_PROG(PERL_PATH, perl, no)
 452 if test x$PERL_PATH = xno; then
 453   AC_MSG_ERROR(Could not find perl)
 454 fi
 455
 456 dnl we require flex and bison for building the parser
 457 if test "x$GST_DISABLE_PARSE" != xyes; then
 458   AG_GST_BISON_CHECK
 459   AG_GST_FLEX_CHECK
 460 fi
 461
 462 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 463 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 464
 465 dnl check for gobject-introspection
 466 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 467
 468 dnl check for documentation tools
 469 GTK_DOC_CHECK([1.12])
 470 AG_GST_PLUGIN_DOCS([1.12])
 471
 472 dnl *** checks for libraries ***
 473
 474 dnl check for libm, for sin()
 475 LT_LIB_M
 476 AC_SUBST(LIBM)
 477
 478 dnl *** checks for header files ***
 479
 480 dnl check if we have ANSI C header files
 481 AC_HEADER_STDC
 482
 483 dnl Check for ucontext.h
 484 AC_CHECK_HEADERS([ucontext.h], [], [], [AC_INCLUDES_DEFAULT])
 485
 486 dnl Check for sys/socket.h
 487 AC_CHECK_HEADERS([sys/socket.h], [HAVE_SYS_SOCKET_H=yes], [HAVE_SYS_SOCKET_H=no], [AC_INCLUDES_DEFAULT])
 488 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 489
 490 dnl check for sys/times.h for tests/examples/adapter/
 491 AC_CHECK_HEADERS([sys/times.h], [HAVE_SYS_TIMES_H=yes], [HAVE_SYS_TIME_H=no], [AC_INCLUDES_DEFAULT])
 492 AC_CHECK_HEADERS([unistd.h], [HAVE_UNISTD_H=yes], [HAVE_UNISTD_H=no], [AC_INCLUDES_DEFAULT])
 493 AM_CONDITIONAL(HAVE_SYS_TIMES_H_AND_UNISTD_H, test "x$HAVE_SYS_TIMES_H" = "xyes" -a "x$HAVE_UNISTD_H" = "xyes")
 494
 495 dnl Check for process.h for getpid() on win32
 496 AC_CHECK_HEADERS([process.h], [], [], [AC_INCLUDES_DEFAULT])
 497
 498 dnl Check for sys/utsname.h for uname
 499 AC_CHECK_HEADERS([sys/utsname.h], [], [], [AC_INCLUDES_DEFAULT])
 500
 501 dnl Check for stdio_ext.f for __fbufsize
 502 AC_CHECK_HEADERS([stdio_ext.h], [], [], [AC_INCLUDES_DEFAULT])
 503
 504 dnl check for pthreads
 505 dnl without arguments AX_PTHREAD() will do AC_DEFINE(HAVE_PTHREAD)
 506 dnl which later checks use in their test code
 507 AX_PTHREAD()
 508 AM_CONDITIONAL(HAVE_PTHREAD, test "x$ax_pthread_ok" = "xyes")
 509
 510 dnl check for sys/prctl for setting thread name on Linux
 511 AC_CHECK_HEADERS([sys/prctl.h], [], [], [AC_INCLUDES_DEFAULT])
 512
 513 dnl check for pthread_setname_np(const char*)
 514 dnl which is present on OS X 10.6, iOS 3.2 and above
 515 AC_MSG_CHECKING(for pthread_setname_np(const char*))
 516 AC_LINK_IFELSE(
 517     [AC_LANG_PROGRAM(
 518         [#include <pthread.h>],
 519         [pthread_setname_np("example")])],
 520     [AC_MSG_RESULT(yes)
 521      AC_DEFINE(HAVE_PTHREAD_SETNAME_NP_WITHOUT_TID,1,
 522         [Have function pthread_setname_np(const char*)])],
 523     [AC_MSG_RESULT(no)])
 524
 525 dnl check for sys/uio.h for writev()
 526 AC_CHECK_HEADERS([sys/uio.h], [], [], [AC_INCLUDES_DEFAULT])
 527
 528 dnl Check for valgrind.h
 529 dnl separate from HAVE_VALGRIND because you can have the program, but not
 530 dnl the dev package
 531 AC_CHECK_HEADERS([valgrind/valgrind.h], [], [], [AC_INCLUDES_DEFAULT])
 532
 533 dnl used in gst/gstpoll.c
 534 AC_CHECK_HEADERS([winsock2.h], [HAVE_WINSOCK2_H=yes], [HAVE_WINSOCK2_H=no], [AC_INCLUDES_DEFAULT])
 535 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 536 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 537   WIN32_LIBS="-lws2_32"
 538   AC_SUBST(WIN32_LIBS)
 539 fi
 540
 541 dnl check for GMP/GSL, used by the gst_util_uint64_scale unit test only
 542 if test "x$BUILD_TESTS" = "xyes"; then
 543   AG_GST_CHECK_LIBHEADER(GMP, gmp,
 544                          __gmpz_init_set_d, ,
 545                          gmp.h,
 546                          GMP_LIBS="-lgmp"
 547                          AC_SUBST(GMP_LIBS)
 548                          AC_DEFINE(HAVE_GMP, [1],[Have GMP library]))
 549   AG_GST_CHECK_LIBHEADER(GSL, gsl,
 550                          gsl_rng_uniform_int, -lgslcblas,
 551                          gsl/gsl_rng.h,
 552                          GSL_LIBS="-lgsl -lgslcblas"
 553                          AC_SUBST(GSL_LIBS)
 554                          AC_DEFINE(HAVE_GSL, [1],[Have GSL library]))
 555 fi
 556
 557 dnl *** checks for types/defines ***
 558
 559 dnl *** checks for structures ***
 560
 561 dnl *** checks for compiler characteristics ***
 562
 563 dnl check if the compiler supports __uint128_t (gcc)
 564 dnl Actually check for 128-bit division, since that's what we use
 565 dnl uint128_t for.
 566 AC_CACHE_CHECK(for __uint128_t, gst_cv_uint128_t,
 567     AC_LINK_IFELSE([AC_LANG_PROGRAM([[ ]], [[
 568       static __uint128_t v1 = 100;
 569       static __uint128_t v2 = 10;
 570       static __uint128_t u;
 571       u = v1 / v2;
 572     ]])],[
 573       gst_cv_uint128_t=yes
 574     ],[
 575       gst_cv_uint128_t=no
 576     ])
 577 )
 578 if test x$gst_cv_uint128_t = xyes; then
 579   AC_DEFINE(HAVE_UINT128_T, 1, [Have __uint128_t type])
 580 fi
 581
 582 dnl *** checking for tm_gmtoff ***
 583 AC_MSG_CHECKING([for tm_gmtoff])
 584 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 585         #include <time.h>
 586         int main(void) {
 587           struct tm t;
 588           t.tm_gmtoff = 0;
 589           exit(0);
 590         }]])],
 591   [have_tm_gmtoff=yes
 592    AC_DEFINE(HAVE_TM_GMTOFF,1,[Have tm_gmtoff field in struct tm])],
 593   [have_tm_gmtoff=no],
 594   [have_tm_gmtoff="no (cross compiling)"])
 595 AC_MSG_RESULT($have_tm_gmtoff)
 596
 597
 598 dnl *** checks for library functions ***
 599
 600 AC_CHECK_FUNCS([strcasestr])
 601
 602 AC_CHECK_FUNCS([gmtime_r])
 603 AC_CHECK_FUNCS([localtime_r])
 604 AC_CHECK_FUNCS([sigaction])
 605 AC_CHECK_FUNCS([getrusage])
 606 AM_CONDITIONAL(HAVE_GETRUSAGE, test "x$ac_cv_func_getrusage" = "xyes")
 607 AC_CHECK_HEADERS([sys/resource.h])
 608
 609 dnl check for fseeko()
 610 AC_FUNC_FSEEKO
 611 dnl check for ftello()
 612 AC_CHECK_FUNCS([ftello])
 613
 614 AC_CHECK_FUNCS([fgetpos])
 615 AC_CHECK_FUNCS([fsetpos])
 616
 617 dnl check for poll(), ppoll() and pselect()
 618 AC_CHECK_HEADERS([sys/poll.h], [], [], [AC_INCLUDES_DEFAULT])
 619 AC_CHECK_HEADERS([poll.h], [], [], [AC_INCLUDES_DEFAULT])
 620 AC_CHECK_FUNCS([poll])
 621 AC_CHECK_FUNCS([ppoll])
 622 AC_CHECK_FUNCS([pselect])
 623
 624 dnl check for socketpair()
 625 AC_CHECK_FUNC(socketpair, [], [
 626   AC_CHECK_LIB(socket, socketpair, [
 627     SOCKET_LIBS="-lsocket"
 628     AC_SUBST(SOCKET_LIBS)
 629   ])
 630 ])
 631
 632 dnl ****************************************
 633 dnl *** GLib POLL* compatibility defines ***
 634 dnl ****************************************
 635
 636 AC_MSG_CHECKING([for broken poll])
 637 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 638         #include <stdlib.h>
 639         #include <fcntl.h>
 640         #ifdef HAVE_SYS_POLL_H
 641         #include <sys/poll.h>
 642         #endif
 643         #ifdef HAVE_POLL_H
 644         #include <poll.h>
 645         #endif
 646         int main(void) {
 647           struct pollfd fds[1];
 648           int fd;
 649           fd = open("/dev/null", 1);
 650           fds[0].fd = fd;
 651           fds[0].events = POLLIN;
 652           fds[0].revents = 0;
 653           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
 654                 exit(1);  /* Does not work for devices -- fail */
 655           }
 656           exit(0);
 657         }]])],
 658   [broken_poll=no],
 659   [broken_poll=yes
 660    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
 661   [broken_poll="no (cross compiling)"])
 662 AC_MSG_RESULT($broken_poll)
 663
 664 dnl check for getpagesize()
 665 AC_CHECK_FUNCS([getpagesize])
 666
 667 dnl Check for POSIX timers
 668 CLOCK_GETTIME_FOUND="no"
 669 AC_CHECK_FUNC(clock_gettime, [CLOCK_GETTIME_FOUND="yes"], [
 670   AC_CHECK_LIB(rt, clock_gettime, [
 671     CLOCK_GETTIME_FOUND="yes"
 672     LIBS="$LIBS -lrt"
 673   ], [
 674     AC_CHECK_LIB(pthread, clock_gettime, [
 675       CLOCK_GETTIME_FOUND="yes"
 676       LIBS="$LIBS -lpthread"
 677     ])
 678   ])
 679 ])
 680
 681 # With XCode 8, clock_gettime will be incorrectly detected as being available
 682 # regardless of what version of OS X you target because the symbol is available
 683 # in the .tbd file as a weak symbol.
 684 # See: https://bugzilla.gnome.org/show_bug.cgi?id=772451
 685 #
 686 # We cannot simply do AC_CHECK_FUNCS with -Wl,-no_weak_imports because the
 687 # autoconf check does its own prototype declaration that doesn't trigger that
 688 # compiler flag.
 689 #
 690 # It's only starting from macOS 10.12 and iOS 10.0 that clock_gettime is
 691 # actually available, so we can unconditionally disable it for older versions.
 692 case "$host_os" in
 693   darwin*)
 694     AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 695 #include <AvailabilityMacros.h>
 696 #include <TargetConditionals.h>
 697 #if defined(TARGET_OS_MAC)
 698 #  if MAC_OS_X_VERSION_MIN_REQUIRED < MAC_OS_X_VERSION_10_12
 699 #    error "Not compiling for OS X 10.12 or later"
 700 #  endif
 701 #else
 702 #  if __IPHONE_OS_VERSION_MIN_REQUIRED < __IPHONE_10_0
 703 #    error "Not compiling for iOS 10.0 or later"
 704 #  endif
 705 #endif
 706     ]])], [], [
 707     if test "$CLOCK_GETTIME_FOUND" = "yes"; then
 708       AC_MSG_NOTICE([Disabling incorrectly detected clock_gettime on OS X])
 709     fi
 710     CLOCK_GETTIME_FOUND="no"
 711     ])
 712     ;;
 713 esac
 714
 715 if test "$CLOCK_GETTIME_FOUND" = "yes"; then
 716   AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [Have clock_gettime])
 717 fi
 718
 719 AC_CACHE_CHECK(for posix timers, gst_cv_posix_timers,
 720     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 721 #include <time.h>
 722 #ifdef HAVE_UNISTD_H
 723 #include <unistd.h>
 724 #endif
 725     ]], [[
 726 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 727 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 728 #endif
 729     ]])],[
 730       gst_cv_posix_timers=yes
 731     ],[
 732       gst_cv_posix_timers=no
 733     ])
 734 )
 735
 736 if test "$gst_cv_posix_timers" = "yes"; then
 737   AC_DEFINE(HAVE_POSIX_TIMERS,1,[Have posix timers])
 738   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 1"
 739 else
 740   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 0"
 741 fi
 742 AC_SUBST(GST_HAVE_POSIX_TIMERS_DEFINE)
 743 AM_CONDITIONAL(GST_HAVE_POSIX_TIMERS, test "$gst_cv_posix_timers" = "yes")
 744
 745 AC_CACHE_CHECK(for monotonic clock, gst_cv_monotonic_clock,
 746     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 747 #include <time.h>
 748 #ifdef HAVE_UNISTD_H
 749 #include <unistd.h>
 750 #endif
 751     ]], [[
 752 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 753 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 754 #endif
 755     ]])],[
 756       gst_cv_monotonic_clock=yes
 757     ],[
 758       gst_cv_monotonic_clock=no
 759     ])
 760 )
 761
 762 if test "$gst_cv_monotonic_clock" = "yes"; then
 763   AC_DEFINE(HAVE_MONOTONIC_CLOCK,1,[Have a monotonic clock])
 764   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 1"
 765 else
 766   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 0"
 767 fi
 768 AC_SUBST(GST_HAVE_MONOTONIC_CLOCK_DEFINE)
 769 AM_CONDITIONAL(GST_HAVE_MONOTONIC_CLOCK, test "$gst_cv_monotonic_clock" = "yes")
 770
 771 dnl Check for a way to display the function name in debug output
 772 AG_GST_CHECK_FUNCTION
 773
 774 dnl test if we have dladdr(); we use it for debugging; see gst/gstinfo.c
 775 save_cflags="$CFLAGS"
 776 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 777 AC_CHECK_LIB(dl, dladdr,
 778    AC_DEFINE(HAVE_DLADDR, 1, [Defined if we have dladdr ()])
 779    LIBS="$LIBS -ldl")
 780 CFLAGS="$save_cflags"
 781
 782 dnl Check printf stuff
 783 if test "x${GST_DISABLE_GST_DEBUG}" != "xyes"; then
 784   AC_TYPE_LONG_LONG_INT
 785   AC_TYPE_UNSIGNED_LONG_LONG_INT
 786
 787   if test x$ac_cv_type_long_long_int$ac_cv_type_unsigned_long_long_int = xyesyes; then
 788     AC_DEFINE([HAVE_LONG_LONG], [1], [Define to 1 if the system has the type long long])
 789   fi
 790
 791   dnl /usr/share/aclocal/inttypes_h.m4 - ships with gettext apparently
 792   gl_AC_HEADER_INTTYPES_H
 793
 794   dnl /usr/share/aclocal/stdint_h.m4 - ships with gettext apparently
 795   gl_AC_HEADER_STDINT_H
 796
 797   AC_CHECK_TYPES(ptrdiff_t)
 798
 799   AC_TYPE_INTMAX_T
 800   AC_TYPE_SIZE_T
 801 fi
 802
 803 dnl *** checks for dependency libraries ***
 804
 805 dnl GLib
 806 GLIB_REQ=2.40.0
 807 AG_GST_GLIB_CHECK([$GLIB_REQ])
 808
 809 dnl Check for documentation xrefs
 810 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 811 AC_SUBST(GLIB_PREFIX)
 812
 813 dnl GTK is optional and only used in examples
 814 HAVE_GTK=no
 815 GTK_REQ=3.10
 816 if test "x$BUILD_EXAMPLES" = "xyes"; then
 817   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 818   AC_SUBST(GTK_LIBS)
 819   AC_SUBST(GTK_CFLAGS)
 820 fi
 821 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 822
 823 dnl libunwind is optionally used by the leaks tracer
 824 PKG_CHECK_MODULES(UNWIND, libunwind, HAVE_UNWIND=yes, HAVE_UNWIND=no)
 825 if test "x$HAVE_UNWIND" = "xyes"; then
 826   AC_DEFINE(HAVE_UNWIND, 1, [libunwind available])
 827 fi
 828
 829 dnl libdw is optionally used to add source lines and numbers to backtraces
 830 PKG_CHECK_MODULES(DW, libdw, HAVE_DW=yes, HAVE_DW=no)
 831 if test "x$HAVE_DW" = "xyes"; then
 832   AC_DEFINE(HAVE_DW, 1, [libdw available])
 833 fi
 834
 835 dnl Check for backtrace() from libc
 836 AC_CHECK_FUNC(backtrace, [
 837   AC_CHECK_HEADERS([execinfo.h], [
 838     AC_DEFINE(HAVE_BACKTRACE,1,[Have backtrace])
 839   ], [], [])
 840 ])
 841
 842 dnl building of unit test libraries
 843 AC_ARG_ENABLE(check,
 844   AS_HELP_STRING([--disable-check],[disable building unit test libraries]),
 845   [
 846     case "${enableval}" in
 847       yes) BUILD_CHECK=yes ;;
 848       no)  BUILD_CHECK=no ;;
 849       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-check) ;;
 850     esac
 851   ], [
 852     dnl Default value
 853     case $host_os in
 854       mingw* | msvc* | mks*) BUILD_CHECK=no ;;
 855       *) BUILD_CHECK=yes ;;
 856     esac
 857 ])
 858 dnl bit of a misnomer, but keep the conditional named like this so we don't
 859 dnl have to change too much elsewhere
 860 AM_CONDITIONAL(HAVE_CHECK, test "x$BUILD_CHECK" = "xyes")
 861
 862 dnl configure the desired memory alignment
 863 AC_ARG_WITH([memory-alignment],
 864   AS_HELP_STRING([--with-memory-alignment],[8,N,malloc,pagesize (default is 32)]),
 865   [
 866     if test "x$withval" = "xyes"
 867     then
 868       AC_DEFINE(MEMORY_ALIGNMENT, 32, [Memory alignment to use])
 869     else
 870       case "${withval}" in
 871         malloc) AC_DEFINE(MEMORY_ALIGNMENT_MALLOC, 1, [Memory alignment by malloc default]) ;;
 872         pagesize)  AC_DEFINE(MEMORY_ALIGNMENT_PAGESIZE, 1, [Memory alignment by pagesize]) ;;
 873         *)   AC_DEFINE_UNQUOTED(MEMORY_ALIGNMENT, ${withval}, [Memory alignment to use]) ;;
 874       esac
 875     fi
 876   ], [
 877     AC_DEFINE(MEMORY_ALIGNMENT_MALLOC, 1, [Memory alignment by malloc default])
 878   ]
 879 )
 880
 881 dnl Check for -Bsymbolic-functions linker flag used to avoid
 882 dnl intra-library PLT jumps, if available.
 883 AC_ARG_ENABLE(Bsymbolic,
 884               [AS_HELP_STRING([--disable-Bsymbolic],[avoid linking with -Bsymbolic])],,
 885               [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
 886                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 887                LDFLAGS=-Wl,-Bsymbolic-functions
 888                LIBS=
 889                AC_TRY_LINK([], [return 0],
 890                            AC_MSG_RESULT(yes)
 891                            enable_Bsymbolic=yes,
 892                            AC_MSG_RESULT(no)
 893                            enable_Bsymbolic=no)
 894                LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
 895
 896
 897 dnl *** set variables based on configure arguments
 898
 899 dnl set license and copyright notice
 900 GST_LICENSE="LGPL"
 901 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 902 AC_SUBST(GST_LICENSE)
 903
 904 dnl define LIBDIR, GST_DATADIR so we can inform people where we live
 905 AS_AC_EXPAND(LIBDIR, $libdir)
 906 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [library dir])
 907 AS_AC_EXPAND(DATADIR, $datadir)
 908 AC_DEFINE_UNQUOTED(GST_DATADIR, "$DATADIR", [data dir])
 909
 910 dnl set location of plugin directory
 911 AG_GST_SET_PLUGINDIR
 912
 913 dnl make sure it doesn't complain about unused variables if debugging is disabled
 914 NO_WARNINGS=""
 915 if test "x${GST_DISABLE_GST_DEBUG}" = "xyes"; then
 916   NO_WARNINGS="-Wno-unused"
 917 fi
 918
 919 dnl define an ERROR_CFLAGS Makefile variable
 920 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [-Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef -Wwrite-strings -Wformat-nonliteral -Wformat-security -Wold-style-definition -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return -Wno-multichar -Wnested-externs $NO_WARNINGS])
 921
 922 dnl special warning flags for gst/printf
 923 AS_COMPILER_FLAG([-Wno-format-nonliteral], [PRINTF_CFLAGS="-Wno-format-nonliteral"])
 924 AC_SUBST(PRINTF_CFLAGS)
 925
 926 dnl define correct level for debugging messages
 927 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 928
 929 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 930
 931 dnl Overview:
 932 dnl GST_OPTION_CFLAGS:  common cflags for profiling, debugging, errors, ...
 933 dnl GST_ALL_*:          vars shared by all built objects
 934 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 935 dnl GST_OBJ_*:          additional vars to link to the core library
 936 dnl                     include GST_ALL_*
 937 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 938 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 939
 940 dnl GST_OPTION_CFLAGS
 941 if test "x$USE_DEBUG" = xyes; then
 942    PROFILE_CFLAGS="-g"
 943 fi
 944 AC_SUBST(PROFILE_CFLAGS)
 945
 946 # GST_DISABLE_DEPRECATED: hide the visibility of deprecated
 947 # functionality from the API that gstreamer uses
 948 # GST_REMOVE_DEPRECATED: don't compile deprecated functionality (breaks ABI)
 949 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 950   dnl Define _only_ when compiling from git (not for pre-releases or releases)
 951   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 952 else
 953   DEPRECATED_CFLAGS=""
 954 fi
 955 AC_SUBST(DEPRECATED_CFLAGS)
 956
 957 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time via e.g.
 958 dnl make DEPRECATED_CFLAGS=''
 959 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 960 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 961 GST_OPTION_CFLAGS="$GST_OPTION_CFLAGS"
 962 GST_OPTION_CXXFLAGS="$GST_OPTION_CXXFLAGS"
 963 AC_SUBST(GST_OPTION_CFLAGS)
 964 AC_SUBST(GST_OPTION_CXXFLAGS)
 965
 966 dnl GST_ALL_*
 967 dnl vars common to for all internal objects (core libs, elements, applications)
 968 dnl CFLAGS:
 969 dnl - src and build dirs need to be added because every piece that gets built
 970 dnl   will need the GStreamer source and generated headers
 971 dnl LIBS: XML doesn't need to be added because we don't explicitly use symbols
 972 dnl       from LibXML except for in the core library
 973 GST_ALL_CXXFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir)/libs -I\$(top_builddir) $GLIB_CFLAGS \$(GLIB_EXTRA_CFLAGS) $XML_CFLAGS \$(GST_OPTION_CXXFLAGS) \$(ERROR_CXXFLAGS)"
 974 GST_ALL_CFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir)/libs -I\$(top_builddir) $GLIB_CFLAGS \$(GLIB_EXTRA_CFLAGS) $XML_CFLAGS \$(GST_OPTION_CFLAGS) \$(ERROR_CFLAGS)"
 975
 976 dnl FIXME: check if LTLIBINTL is needed everywhere
 977 dnl I presume it is given that it contains the symbols that _() stuff maps to
 978 GST_ALL_LIBS="$GLIB_LIBS $LTLIBINTL \$(GCOV_LIBS)"
 979
 980 dnl LDFLAGS really should only contain flags, not libs - they get added before
 981 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 982 GST_ALL_LDFLAGS="-no-undefined"
 983 if test "x${enable_Bsymbolic}" = "xyes"; then
 984   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 985 fi
 986
 987 AC_SUBST(GST_ALL_CFLAGS)
 988 AC_SUBST(GST_ALL_CXXFLAGS)
 989 AC_SUBST(GST_ALL_LIBS)
 990 AC_SUBST(GST_ALL_LDFLAGS)
 991
 992 dnl GST_LIB_LDFLAGS
 993 dnl linker flags shared by all libraries
 994 dnl LDFLAGS modifier defining exported symbols from built libraries
 995 GST_LIB_LDFLAGS="-export-symbols-regex \^[_]?\(gst_\|Gst\|GST_\).*"
 996 AC_SUBST(GST_LIB_LDFLAGS)
 997
 998 dnl GST_OBJ_*
 999 dnl default vars for all internal objects built on libgstreamer
1000 dnl includes GST_ALL_*
1001 GST_OBJ_CFLAGS="\$(GST_ALL_CFLAGS) $GST_OBJ_STATIC_CFLAGS"
1002 GST_OBJ_CXXFLAGS="\$(GST_ALL_CXXFLAGS) $GST_OBJ_STATIC_CFLAGS"
1003 GST_OBJ_LIBS="\$(top_builddir)/gst/libgstreamer-$GST_API_VERSION.la \$(GST_ALL_LIBS)"
1004 AC_SUBST(GST_OBJ_CFLAGS)
1005 AC_SUBST(GST_OBJ_CXXFLAGS)
1006 AC_SUBST(GST_OBJ_LIBS)
1007
1008 dnl GST_PLUGIN_LDFLAGS
1009 dnl LDFLAGS for plugins; includes GST_ALL_LDFLAGS
1010 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_.*' $GST_ALL_LDFLAGS"
1011 AC_SUBST(GST_PLUGIN_LDFLAGS, "$GST_PLUGIN_LDFLAGS")
1012
1013 dnl plugin scanner locations
1014 AS_AC_EXPAND(GST_PLUGIN_SCANNER_INSTALLED,${libexecdir}/gstreamer-$GST_API_VERSION/gst-plugin-scanner)
1015 AC_DEFINE_UNQUOTED(GST_PLUGIN_SCANNER_INSTALLED,
1016     "$GST_PLUGIN_SCANNER_INSTALLED", [location of the installed gst-plugin-scanner])
1017 AC_SUBST(GST_PLUGIN_SCANNER_INSTALLED)
1018
1019 dnl completion helper locations
1020 AS_AC_EXPAND(GST_COMPLETION_HELPER_INSTALLED,${libexecdir}/gstreamer-$GST_API_VERSION/gst-completion-helper)
1021 AC_DEFINE_UNQUOTED(GST_COMPLETION_HELPER_INSTALLED,
1022     "$GST_COMPLETION_HELPER_INSTALLED", [location of the installed gst-completion-helper])
1023 AC_SUBST(GST_COMPLETION_HELPER_INSTALLED)
1024
1025 dnl ptp helper locations
1026 AS_AC_EXPAND(GST_PTP_HELPER_INSTALLED,${libexecdir}/gstreamer-$GST_API_VERSION/gst-ptp-helper)
1027 AC_DEFINE_UNQUOTED(GST_PTP_HELPER_INSTALLED,
1028     "$GST_PTP_HELPER_INSTALLED", [location of the installed gst-ptp-helper])
1029 AC_SUBST(GST_PTP_HELPER_INSTALLED)
1030
1031 dnl things for our internal libcheck (must be called even if building
1032 dnl libcheck is disabled because it defines conditionals)
1033 AG_GST_CHECK_CHECKS
1034
1035 AC_CONFIG_FILES(
1036 Makefile
1037 data/Makefile
1038 data/bash-completion/helpers/gst
1039 gst/Makefile
1040 gst/gstconfig.h
1041 gst/gstversion.h
1042 gst/parse/Makefile
1043 gst/printf/Makefile
1044 libs/Makefile
1045 libs/gst/Makefile
1046 libs/gst/base/Makefile
1047 libs/gst/check/Makefile
1048 libs/gst/check/libcheck/Makefile
1049 libs/gst/check/internal-check.h:libs/gst/check/libcheck/check.h.in
1050 libs/gst/controller/Makefile
1051 libs/gst/helpers/Makefile
1052 libs/gst/net/Makefile
1053 plugins/Makefile
1054 plugins/elements/Makefile
1055 plugins/tracers/Makefile
1056 po/Makefile.in
1057 tests/Makefile
1058 tests/benchmarks/Makefile
1059 tests/check/Makefile
1060 tests/misc/Makefile
1061 tests/examples/Makefile
1062 tests/examples/adapter/Makefile
1063 tests/examples/controller/Makefile
1064 tests/examples/stepping/Makefile
1065 tests/examples/helloworld/Makefile
1066 tests/examples/memory/Makefile
1067 tests/examples/netclock/Makefile
1068 tests/examples/ptp/Makefile
1069 tests/examples/streamiddemux/Makefile
1070 tests/examples/streams/Makefile
1071 tools/Makefile
1072 common/Makefile
1073 common/m4/Makefile
1074 docs/Makefile
1075 docs/gst/Makefile
1076 docs/gst/gstreamer.types
1077 docs/libs/Makefile
1078 docs/plugins/Makefile
1079 docs/version.entities
1080 m4/Makefile
1081 pkgconfig/Makefile
1082 stamp.h
1083 pkgconfig/gstreamer.pc
1084 pkgconfig/gstreamer-uninstalled.pc
1085 pkgconfig/gstreamer-base.pc
1086 pkgconfig/gstreamer-base-uninstalled.pc
1087 pkgconfig/gstreamer-check.pc
1088 pkgconfig/gstreamer-check-uninstalled.pc
1089 pkgconfig/gstreamer-controller.pc
1090 pkgconfig/gstreamer-controller-uninstalled.pc
1091 pkgconfig/gstreamer-net.pc
1092 pkgconfig/gstreamer-net-uninstalled.pc
1093 )
1094
1095 AC_OUTPUT
1096
1097 dnl negate for output
1098 if test "x${GST_DISABLE_GST_DEBUG}" = "xno"; then enable_gst_debug="yes"; fi
1099 if test "x${GST_DISABLE_GST_TRACER_HOOKS}" = "xno"; then enable_gst_tracer_hooks="yes"; fi
1100 if test "x${GST_DISABLE_PARSE}" = "xno"; then enable_parse="yes"; fi
1101 if test "x${GST_DISABLE_OPTION_PARSING}" = "xno"; then enable_option_parsing="yes"; fi
1102 if test "x${GST_DISABLE_PLUGIN}" = "xno"; then enable_plugin="yes"; fi
1103 if test "x${GST_DISABLE_REGISTRY}" = "xno"; then enable_registry="yes"; fi
1104
1105 echo "
1106
1107 Configuration
1108         Version                    : ${VERSION}
1109         Source code location       : ${srcdir}
1110         Prefix                     : ${prefix}
1111         Compiler                   : ${CC}
1112         Package name               : ${GST_PACKAGE_NAME}
1113         Package origin             : ${GST_PACKAGE_ORIGIN}
1114
1115         API Documentation          : ${enable_gtk_doc}
1116
1117         Debug logging              : ${enable_gst_debug}
1118         Tracing subsystem hooks    : ${enable_gst_tracer_hooks}
1119         Command-line parser        : ${enable_parse}
1120         Option parsing in gst_init : ${enable_option_parsing}
1121         Plugin registry            : ${enable_registry}
1122         Plugin support             : ${enable_plugin}
1123         Static plugins             : ${enable_static_plugins}
1124         Unit testing support       : ${BUILD_CHECK}
1125         PTP clock support          : ${HAVE_PTP}
1126         libunwind support          : ${HAVE_UNWIND}
1127         libdw support              : ${HAVE_DW}
1128
1129         Debug                      : ${USE_DEBUG}
1130         Profiling                  : ${USE_PROFILING}
1131
1132         Building benchmarks        : ${BUILD_BENCHMARKS}
1133         Building examples          : ${BUILD_EXAMPLES}
1134         Building test apps         : ${BUILD_TESTS}
1135         Building tests that fail   : ${BUILD_FAILING_TESTS}
1136         Building tools             : ${BUILD_TOOLS}
1137 "