configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl initialize autoconf
   4 dnl we don't specify PACKAGE and VERSION because AS_VERSION puts it together
   5 AC_INIT
   6
   7 dnl when going to/from release please set the nano (fourth number) right !
   8 dnl releases only do Wall, cvs and prerelease does Werror too
   9 AS_VERSION(gst-plugins-base, GST_PLUGINS_BASE_VERSION, 0, 9, 6, 1,
  10     GST_CVS="no", GST_CVS="yes")
  11
  12 dnl can autoconf find the source ?
  13 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  14
  15 dnl define the output header for config
  16 AM_CONFIG_HEADER([config.h])
  17
  18 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  19 AM_MAINTAINER_MODE
  20
  21 dnl sets host_* variables
  22 AC_CANONICAL_HOST
  23
  24 dnl initialize automake
  25 dnl FIXME: this is deprecated use, we should move PACKAGE and VERSION to
  26 dnl AC_INIT, but then we need to parse the version to pass to AS_VERSION
  27 AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
  28
  29 dnl our libraries and install dirs use major.minor as a version
  30 GST_MAJORMINOR=$GST_PLUGINS_BASE_VERSION_MAJOR.$GST_PLUGINS_BASE_VERSION_MINOR
  31 dnl we override it here if we need to for the release candidate of new series
  32 # GST_MAJORMINOR=0.9
  33 AC_SUBST(GST_MAJORMINOR)
  34
  35 dnl CURRENT, REVISION, AGE
  36 dnl - library source changed -> increment REVISION
  37 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  38 dnl - interfaces added -> increment AGE
  39 dnl - interfaces removed -> AGE = 0
  40 dnl sets GST_LT_LDFLAGS
  41 AS_LIBTOOL(GST, 3, 0, 0)
  42 AS_LIBTOOL_TAGS
  43 AM_PROG_LIBTOOL
  44
  45 dnl *** autotools stuff ****
  46
  47 dnl allow for different autotools
  48 AS_AUTOTOOLS_ALTERNATE
  49
  50 dnl Add parameters for aclocal
  51 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  52
  53 dnl set up gettext
  54 dnl the version check needs to stay here because autopoint greps for it
  55 AM_GNU_GETTEXT_VERSION([0.11.5])
  56 AM_GNU_GETTEXT([external])
  57 GST_GETTEXT([gst-plugins-base-$GST_MAJORMINOR])
  58
  59 dnl *** check for arguments to configure ***
  60
  61 GST_ARG_DEBUG
  62 GST_ARG_PROFILING
  63 GST_ARG_VALGRIND
  64 GST_ARG_GCOV
  65
  66 GST_ARG_EXAMPLES
  67
  68 GST_ARG_WITH_PKG_CONFIG_PATH
  69 GST_ARG_WITH_PACKAGE_NAME([GStreamer Base Plug-ins])
  70 GST_ARG_WITH_PACKAGE_ORIGIN
  71
  72 dnl these are all the gst plug-ins, compilable without additional libs
  73 GST_PLUGINS_ALL="\
  74         adder \
  75         audioconvert \
  76         audiorate \
  77         audioresample \
  78         audiotestsrc \
  79         ffmpegcolorspace \
  80         playback \
  81         typefind \
  82         videotestsrc \
  83         videorate \
  84         videoscale \
  85         volume \
  86         "
  87 AC_SUBST(GST_PLUGINS_ALL)
  88
  89 GST_PLUGINS_SELECTED=""
  90
  91 AC_ARG_WITH(plugins,
  92     AC_HELP_STRING([--with-plugins],
  93       [comma-separated list of plug-ins to compile]),
  94     [for i in `echo $withval | tr , ' '`; do
  95         if echo $GST_PLUGINS_ALL | grep $i > /dev/null
  96         then
  97             GST_PLUGINS_SELECTED="$GST_PLUGINS_SELECTED $i"
  98         else
  99             echo "plug-in $i not recognized, ignoring..."
 100         fi
 101     done],
 102     [GST_PLUGINS_SELECTED=$GST_PLUGINS_ALL])
 103
 104 AC_SUBST(GST_PLUGINS_SELECTED)
 105
 106 dnl ext plug-ins; plug-ins that have external dependencies
 107 GST_CHECK_FEATURE(EXTERNAL, [enable building of plug-ins with external deps],,
 108   [HAVE_EXTERNAL=yes], enabled,
 109   [
 110     AC_MSG_NOTICE(building external plug-ins)
 111     BUILD_EXTERNAL="yes"
 112   ],[
 113     AC_MSG_NOTICE(all plug-ins with external dependencies will not be built)
 114     BUILD_EXTERNAL="no"
 115   ])
 116 AM_CONDITIONAL(BUILD_EXTERNAL, test "x$BUILD_EXTERNAL" = "xyes")
 117
 118 dnl *** checks for platform ***
 119
 120 dnl * hardware/architecture *
 121
 122 dnl common/m4/gst-arch.m4
 123 dnl check CPU type
 124 GST_ARCH
 125
 126 dnl *** checks for programs ***
 127
 128 dnl find a compiler
 129 AC_PROG_CC
 130
 131 dnl determine c++ compiler
 132 AC_PROG_CXX
 133 dnl determine if c++ is available on this system
 134 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 135
 136 dnl determine c++ preprocessor
 137 dnl FIXME: do we need this ?
 138 AC_PROG_CXXCPP
 139
 140 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 141 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 142
 143 dnl check for documentation tools
 144 GTK_DOC_CHECK([1.3])
 145 AS_PATH_PYTHON([2.1])
 146
 147 dnl *** checks for libraries ***
 148
 149 dnl For interactive UNIX (a Sun thing)
 150 dnl FIXME: this adds -lcposix to LIBS, but I doubt we use LIBS
 151 AC_ISC_POSIX
 152
 153 dnl *** checks for header files ***
 154
 155 dnl check if we have ANSI C header files
 156 AC_HEADER_STDC
 157
 158 dnl used in gst/ffmpegcolorspace/mem.c
 159 dnl FIXME: could be fixed by redefining av_malloc and av_free to GLib's
 160 AC_CHECK_HEADERS([malloc.h])
 161
 162 dnl used in gst/subparse/gstsubparse.c
 163 AC_CHECK_HEADERS([regex.h], HAVE_REGEX_H="yes", HAVE_REGEX_H="no")
 164 AM_CONDITIONAL(HAVE_REGEX_H, test "x$HAVE_REGEX_H" = "xyes")
 165
 166 dnl used in gst/tcp
 167 AC_CHECK_HEADERS([sys/socket.h],
 168   HAVE_SYS_SOCKET_H="yes", HAVE_SYS_SOCKET_H="no")
 169 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 170
 171 dnl ffmpegcolorspace includes _stdint.h
 172 AX_CREATE_STDINT_H
 173
 174 dnl *** checks for types/defines ***
 175
 176 dnl Check for FIONREAD ioctl declaration
 177 dnl used in gst/tcp
 178 GST_CHECK_FIONREAD
 179
 180 dnl *** checks for structures ***
 181
 182 dnl *** checks for compiler characteristics ***
 183
 184 dnl make sure we can use "inline" from C code
 185 AC_C_INLINE
 186
 187 dnl *** checks for library functions ***
 188
 189 dnl Check for fast float to int casting as defined in C99
 190 dnl used in gst-libs/gst/floatcast/floatcast.h
 191 AC_C99_FUNC_LRINT
 192 AC_C99_FUNC_LRINTF
 193
 194 dnl Check for a way to display the function name in debug output
 195 GST_CHECK_FUNCTION
 196
 197 dnl *** checks for dependancy libraries ***
 198
 199 dnl GLib is required
 200 GST_GLIB_CHECK([2.6])
 201
 202 dnl liboil is required
 203 PKG_CHECK_MODULES(LIBOIL, liboil-0.3 >= 0.3.2, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 204 if test "x${HAVE_LIBOIL}" != xyes ; then
 205   AC_ERROR([liboil-0.3 is required])
 206 fi
 207
 208 dnl checks for gstreamer
 209 dnl uninstalled is selected preferentially -- see pkg-config(1)
 210 GST_REQ=0.9.3
 211 GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ])
 212 GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ])
 213 GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ])
 214 GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ])
 215 GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 216
 217 dnl FIXME: get rid of this by making sure gstreamer-check brings it in
 218 dnl check for "check", unit testing library/header
 219 AM_PATH_CHECK(0.9.2, HAVE_CHECK=yes, HAVE_CHECK=no)
 220 AM_CONDITIONAL(HAVE_CHECK, test "x$HAVE_CHECK" = "xyes")
 221
 222 dnl GTK is optional and used in examples
 223 HAVE_GTK=NO
 224 PKG_CHECK_MODULES(GTK2, gtk+-2.0 >= 2.2.0, HAVE_GTK_22=yes, HAVE_GTK_22=no)
 225 if test "x$HAVE_GTK_22" = "xyes"; then
 226   HAVE_GTK=yes
 227   GTK_VERSION=`$PKG_CONFIG --variable=gtk_binary_version gtk+-2.0`
 228   AC_SUBST(GTK_VERSION)
 229   GTK_PREFIX=`$PKG_CONFIG --variable=prefix gdk-pixbuf-2.0`
 230   AC_SUBST(GTK_BASE_DIR)
 231 else
 232   PKG_CHECK_MODULES(GTK2, gtk+-2.0, HAVE_GTK_20=yes, HAVE_GTK_20=no)
 233 fi
 234 if test "x$HAVE_GTK_20" = "xyes"; then
 235   HAVE_GTK=yes
 236 fi
 237 GTK_CFLAGS=$GTK2_CFLAGS
 238 GTK_LIBS=$GTK2_LIBS
 239 AC_SUBST(GTK_LIBS)
 240 AC_SUBST(GTK_CFLAGS)
 241 AC_SUBST(HAVE_GTK)
 242 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 243
 244 dnl *** set variables based on configure arguments ***
 245
 246 dnl set license and copyright notice
 247 GST_LICENSE="LGPL"
 248 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 249 AC_SUBST(GST_LICENSE)
 250
 251 dnl set location of plugin directory
 252 GST_SET_PLUGINDIR
 253
 254 dnl define an ERROR_CFLAGS Makefile variable
 255 GST_SET_ERROR_CFLAGS($GST_CVS)
 256
 257 dnl define correct level for debugging messages
 258 GST_SET_LEVEL_DEFAULT($GST_CVS)
 259
 260 dnl used in examples
 261 GST_DEFAULT_ELEMENTS
 262
 263 dnl *** sys plug-ins ***
 264
 265 echo
 266 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 267 echo
 268
 269 dnl *** X11 ***
 270 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 271 GST_CHECK_FEATURE(X, [X libraries and plugins],
 272                   [ximagesink], [
 273   AC_PATH_XTRA
 274   ac_cflags_save="$CFLAGS"
 275   ac_cppflags_save="$CPPFLAGS"
 276   CFLAGS="$CFLAGS $X_CFLAGS"
 277   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 278
 279   dnl now try to find the HEADER
 280   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 281
 282   if test "x$HAVE_X" = "xno"
 283   then
 284     AC_MSG_NOTICE([cannot find X11 development files])
 285   else
 286     dnl this is much more than we want
 287     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 288     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 289     dnl it does not add the libs; therefore we add them here
 290     X_LIBS="$X_LIBS -lX11"
 291     AC_SUBST(X_CFLAGS)
 292     AC_SUBST(X_LIBS)
 293   fi
 294   AC_SUBST(HAVE_X)
 295   CFLAGS="$ac_cflags_save"
 296   CPPFLAGS="$ac_cppflags_save"
 297 ])
 298
 299 dnl *** XVideo ***
 300 dnl Look for the PIC library first, Debian requires it.
 301 dnl Check debian-devel archives for gory details.
 302 dnl 20020110:
 303 dnl At the moment XFree86 doesn't distribute shared libXv due
 304 dnl to unstable API.  On many platforms you CAN NOT link a shared
 305 dnl lib to a static non-PIC lib.  This is what the xvideo GStreamer
 306 dnl plug-in wants to do.  So Debian distributes a PIC compiled
 307 dnl version of the static lib for plug-ins to link to when it is
 308 dnl inappropriate to link the main application to libXv directly.
 309 dnl FIXME: add check if this platform can support linking to a
 310 dnl        non-PIC libXv, if not then don not use Xv.
 311 dnl FIXME: perhaps warn user if they have a shared libXv since
 312 dnl        this is an error until XFree86 starts shipping one
 313
 314 dnl Check for Xv extension
 315 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 316 GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 317                   [xvimagesink], [
 318   if test x$HAVE_X = xyes; then
 319     AC_CHECK_LIB(Xv_pic, XvQueryExtension,
 320                  HAVE_XVIDEO="yes", HAVE_XVIDEO="no",
 321                  $X_LIBS -lXext)
 322
 323     if test x$HAVE_XVIDEO = xyes; then
 324       XVIDEO_LIBS="-lXv_pic -lXext"
 325       AC_SUBST(XVIDEO_LIBS)
 326     else
 327       dnl try again using something else if we didn't find it first
 328       if test x$HAVE_XVIDEO = xno; then
 329         AC_CHECK_LIB(Xv, XvQueryExtension,
 330                    HAVE_XVIDEO="yes", HAVE_XVIDEO="no",
 331                    $X_LIBS -lXext)
 332
 333         if test x$HAVE_XVIDEO = xyes; then
 334           XVIDEO_LIBS="-lXv -lXext"
 335           AC_SUBST(XVIDEO_LIBS)
 336         fi
 337       fi
 338     fi
 339   fi
 340 ])
 341
 342 dnl check for X Shm
 343 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 344 GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], xshm, [
 345   if test x$HAVE_X = xyes; then
 346     AC_CHECK_LIB(Xext, XShmAttach,
 347                  HAVE_XSHM="yes", HAVE_XSHM="no",
 348                  $X_LIBS)
 349     if test "x$HAVE_XSHM" = "xyes"; then
 350       XSHM_LIBS="-lXext"
 351     else
 352       dnl On AIX, it is in XextSam instead, but we still need -lXext
 353       AC_CHECK_LIB(XextSam, XShmAttach,
 354                    HAVE_XSHM="yes", HAVE_XSHM="no",
 355                    $X_LIBS)
 356       if test "x$HAVE_XSHM" = "xyes"; then
 357         XSHM_LIBS="-lXext -lXextSam"
 358       fi
 359     fi
 360   fi
 361 ], , [
 362   AC_SUBST(HAVE_XSHM)
 363   AC_SUBST(XSHM_LIBS)
 364 ] )
 365
 366 dnl v4l/v4l2 checks have been moved down because they require X
 367
 368 dnl *** Video 4 Linux ***
 369 dnl for information about the header/define, see sys/v4l/gstv4lelement.h
 370 dnl renamed to GST_V4L in accordance with V4L2 below
 371 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L, true)
 372 GST_CHECK_FEATURE(GST_V4L, [Video 4 Linux], v4lsrc v4lmjpegsrc v4lmjpegsink, [
 373   # first check X
 374   HAVE_GST_V4L="no"
 375   if test "$HAVE_X" = "yes"
 376   then
 377     AC_CHECK_DECL(VID_TYPE_MPEG_ENCODER, HAVE_GST_V4L="yes", HAVE_GST_V4L="no", [
 378 #include <sys/types.h>
 379 #define _LINUX_TIME_H
 380 #define __user
 381 #include <linux/videodev.h>
 382     ])
 383   fi
 384 ])
 385
 386 dnl *** ext plug-ins ***
 387 dnl keep this list sorted alphabetically !
 388
 389 if test "x$BUILD_EXTERNAL" = "xyes"; then
 390
 391 echo
 392 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 393 echo
 394
 395 dnl *** alsa ***
 396 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 397 GST_CHECK_FEATURE(ALSA, [alsa plug-ins], gstalsa, [
 398   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 399     HAVE_ALSA="yes"
 400     AC_SUBST(ALSA_CFLAGS)
 401     AC_SUBST(ALSA_LIBS)
 402   ], [
 403     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 404   ])
 405 ])
 406
 407 dnl *** CDParanoia ***
 408 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 409 GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 410   GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 411                       cdda_open, -lm,
 412                       cdda_interface.h,
 413                       CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 414                       HEADER_DIR="no"
 415                       FOUND_CDPARANOIA="yes")
 416   if test "x$FOUND_CDPARANOIA" != "xyes";
 417   then
 418     GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 419                         cdda_open, -lm,
 420                         cdda/cdda_interface.h,
 421                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 422                         HEADER_DIR="yes"
 423                         FOUND_CDPARANOIA="yes")
 424   fi
 425   if test "x$HEADER_DIR" = "xyes";
 426   then
 427     AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 428                        defined if cdda headers are in a cdda/ directory)
 429   fi
 430   AC_SUBST(CDPARANOIA_LIBS)
 431 ])
 432 dnl FIXME : add second check somehow if that is necessary
 433 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 434 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 435
 436 dnl *** Gnome VFS ***
 437 translit(dnm, m, l) AM_CONDITIONAL(USE_GNOME_VFS, true)
 438 GST_CHECK_FEATURE(GNOME_VFS, [Gnome VFS], gnomevfssrc, [
 439   PKG_CHECK_MODULES(GNOME_VFS, gnome-vfs-2.0, HAVE_GNOME_VFS="yes", HAVE_GNOME_VFS="no")
 440   AC_SUBST(GNOME_VFS_CFLAGS)
 441   AC_SUBST(GNOME_VFS_LIBS)
 442 ])
 443
 444 dnl *** libvisual ***
 445 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 446 GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization plugins], libvisual, [
 447   PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0, HAVE_LIBVISUAL="yes", HAVE_LIBVISUAL="no")
 448   AC_SUBST(LIBVISUAL_CFLAGS)
 449   AC_SUBST(LIBVISUAL_LIBS)
 450 ])
 451
 452 dnl *** ogg ***
 453 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 454 GST_CHECK_FEATURE(OGG, [ogg de/encoder], oggdemux oggmux, [
 455   PKG_CHECK_MODULES(OGG, ogg >= 1.0, [
 456     HAVE_OGG="yes"
 457     AC_SUBST(OGG_CFLAGS)
 458     AC_SUBST(OGG_LIBS)
 459   ], [
 460     XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
 461     AS_SCRUB_INCLUDE(OGG_CFLAGS)
 462   ])
 463 ])
 464
 465 dnl *** theora ***
 466 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 467 GST_CHECK_FEATURE(THEORA, [ogg theora codec], theoradec theoraenc, [
 468   PKG_CHECK_MODULES(THEORA, theora, [
 469     HAVE_THEORA="yes"
 470     AC_SUBST(THEORA_LIBS)
 471     AC_SUBST(THEORA_CFLAGS)
 472   ], [
 473     GST_CHECK_LIBHEADER(THEORA, theora, theora_version_string, "-logg", theora/theora.h, THEORA_LIBS="-ltheora -logg")
 474     AC_SUBST(THEORA_LIBS)
 475   ])
 476 ])
 477
 478 dnl *** vorbis ***
 479 dnl AM_PATH_VORBIS only takes two options
 480 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 481 GST_CHECK_FEATURE(VORBIS, [vorbis plug-in], vorbisenc vorbisdec, [
 482   PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0, [
 483     HAVE_VORBIS="yes"
 484   ], [
 485     XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
 486     AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
 487   ])
 488 ])
 489 if test "x$HAVE_VORBIS" = "xyes"; then
 490   ac_cflags_save="$CFLAGS"
 491   dnl FIXME: does this work on non-gcc? -- Company
 492   dnl FIXME: no, it doesn't.  Why is this here in the first place ? -- thomasvs
 493   CFLAGS="-Wall -Werror"
 494   AC_COMPILE_IFELSE(
 495     AC_LANG_PROGRAM([
 496 #include <vorbis/codec.h>
 497                      ],[
 498 vorbis_dsp_state *v;
 499
 500 vorbis_synthesis_restart (v);
 501                      ]), HAVE_VSR=yes, HAVE_VSR=no)
 502   if test "x$HAVE_VSR" = "xyes"; then
 503     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 504                        [defined if vorbis_synthesis_restart is present])
 505   fi
 506   CFLAGS="$ac_cflags_save"
 507 fi
 508
 509 fi dnl of EXT plugins
 510
 511 dnl seeking needs freetype, so check for it here
 512 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 513   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 514 ])
 515 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 516 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 517 AC_SUBST(FT2_CFLAGS)
 518 AC_SUBST(FT2_LIBS)
 519
 520 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 521
 522 dnl Overview:
 523 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 524 dnl GST_*:              flags shared by built objects to link against GStreamer
 525 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 526 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 527 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 528 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 529
 530 dnl GST_OPTION_CFLAGS
 531 if test "x$USE_DEBUG" = xyes; then
 532    PROFILE_CFLAGS="-g"
 533 fi
 534 AC_SUBST(PROFILE_CFLAGS)
 535
 536 DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 537 AC_SUBST(DEPRECATED_CFLAGS)
 538
 539 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 540 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 541 AC_SUBST(GST_OPTION_CFLAGS)
 542
 543 dnl our libraries need to be versioned correctly
 544 AC_SUBST(GST_LT_LDFLAGS)
 545
 546 dnl FIXME: do we want to rename to GST_ALL_* ?
 547 dnl prefer internal headers to already installed ones
 548 dnl also add builddir include for enumtypes and marshal
 549 dnl add GST_OPTION_CFLAGS, but overridable
 550 GST_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS \$(GST_OPTION_CFLAGS)"
 551 AC_SUBST(GST_CFLAGS)
 552 AC_SUBST(GST_LIBS)
 553
 554 dnl LDFLAGS really should only contain flags, not libs - they get added before
 555 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 556 GST_ALL_LDFLAGS="-no-undefined"
 557 AC_SUBST(GST_ALL_LDFLAGS)
 558
 559 dnl GST_LIB_LDFLAGS
 560 dnl linker flags shared by all libraries
 561 dnl LDFLAGS modifier defining exported symbols from built libraries
 562 GST_LIB_LDFLAGS="-export-symbols-regex [_]*\(gst_\|Gst\|GST_\).*"
 563 AC_SUBST(GST_LIB_LDFLAGS)
 564
 565 dnl this really should only contain flags, not libs - they get added before
 566 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 567 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 568 AC_SUBST(GST_PLUGIN_LDFLAGS)
 569
 570 dnl *** output files ***
 571
 572 AC_CONFIG_FILES(
 573 Makefile
 574 gst-plugins-base.spec
 575 gst/Makefile
 576 gst/adder/Makefile
 577 gst/audioconvert/Makefile
 578 gst/audiorate/Makefile
 579 gst/audioresample/Makefile
 580 gst/audiotestsrc/Makefile
 581 gst/ffmpegcolorspace/Makefile
 582 gst/playback/Makefile
 583 gst/subparse/Makefile
 584 gst/tcp/Makefile
 585 gst/typefind/Makefile
 586 gst/videotestsrc/Makefile
 587 gst/videorate/Makefile
 588 gst/videoscale/Makefile
 589 gst/volume/Makefile
 590 sys/Makefile
 591 sys/ximage/Makefile
 592 sys/xvimage/Makefile
 593 sys/v4l/Makefile
 594 ext/Makefile
 595 ext/alsa/Makefile
 596 ext/cdparanoia/Makefile
 597 ext/gnomevfs/Makefile
 598 ext/libvisual/Makefile
 599 ext/ogg/Makefile
 600 ext/theora/Makefile
 601 ext/vorbis/Makefile
 602 gst-libs/Makefile
 603 gst-libs/gst/Makefile
 604 gst-libs/gst/audio/Makefile
 605 gst-libs/gst/floatcast/Makefile
 606 gst-libs/gst/interfaces/Makefile
 607 gst-libs/gst/netbuffer/Makefile
 608 gst-libs/gst/riff/Makefile
 609 gst-libs/gst/rtp/Makefile
 610 gst-libs/gst/tag/Makefile
 611 gst-libs/gst/video/Makefile
 612 tools/Makefile
 613 pkgconfig/Makefile
 614 pkgconfig/gstreamer-plugins-base.pc
 615 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 616 tests/Makefile
 617 tests/check/Makefile
 618 tests/examples/Makefile
 619 tests/examples/seek/Makefile
 620 docs/Makefile
 621 docs/libs/Makefile
 622 docs/plugins/Makefile
 623 docs/version.entities
 624 po/Makefile.in
 625 common/Makefile
 626 common/m4/Makefile
 627 m4/Makefile
 628 )
 629 AC_OUTPUT
 630
 631 echo "configure: *** Core plug-ins, always built:"
 632 ( for i in $GST_PLUGINS_ALL; do echo -e '\t'$i; done ) | sort
 633 echo
 634 echo -n "configure: *** Plug-ins relying on libraries that will be built:"
 635 echo -e "$GST_PLUGINS_YES" | sort
 636 echo
 637 echo -n "configure: *** Plug-ins relying on libraries that will NOT be built:"
 638 echo -e "$GST_PLUGINS_NO" | sort
 639 echo
 640 if test "x$BUILD_EXTERNAL" = "xno"; then
 641   echo "configure: *** No external plug-ins will be built"
 642 fi