configure.ac

   1 AC_PREREQ([2.68])
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/pre
   8 AC_INIT([GStreamer Good Plug-ins],[1.5.0.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gst-plugins-good])
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.11 no-dist-gzip dist-xz tar-ustar subdir-objects])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  23
  24 dnl define the output header for config
  25 AC_CONFIG_HEADERS([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output with automake >= 1.11
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  35   [AM_DEFAULT_VERBOSITY=1
  36    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  37
  38 dnl our libraries and install dirs use GST_API_VERSION in the filename
  39 dnl to allow side-by-side installation of different API versions
  40 GST_API_VERSION=1.0
  41 AC_SUBST(GST_API_VERSION)
  42 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  43   [GStreamer API Version])
  44
  45 AG_GST_LIBTOOL_PREPARE
  46 AS_LIBTOOL(GST, 501, 0, 501)
  47
  48 dnl *** required versions of GStreamer stuff ***
  49 GST_REQ=1.5.0.1
  50 GSTPB_REQ=1.5.0.1
  51
  52 dnl *** autotools stuff ****
  53
  54 dnl allow for different autotools
  55 AS_AUTOTOOLS_ALTERNATE
  56
  57 dnl Add parameters for aclocal
  58 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  59
  60 dnl set up gettext
  61 dnl the version check needs to stay here because autopoint greps for it
  62 AM_GNU_GETTEXT_VERSION([0.17])
  63 AM_GNU_GETTEXT([external])
  64 AG_GST_GETTEXT([gst-plugins-good-$GST_API_VERSION])
  65
  66 dnl *** check for arguments to configure ***
  67
  68 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  69
  70 AG_GST_ARG_DEBUG
  71 AG_GST_ARG_PROFILING
  72 AG_GST_ARG_VALGRIND
  73 AG_GST_ARG_GCOV
  74
  75 AG_GST_ARG_EXAMPLES
  76
  77 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  78 AG_GST_ARG_WITH_PACKAGE_NAME
  79 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  80
  81 AG_GST_ARG_WITH_PLUGINS
  82
  83 AG_GST_ARG_ENABLE_EXTERNAL
  84
  85 AG_GST_ARG_ENABLE_EXPERIMENTAL
  86
  87 dnl *** checks for platform ***
  88
  89 dnl * hardware/architecture *
  90
  91 dnl common/m4/gst-arch.m4
  92 dnl check CPU type
  93 AG_GST_ARCH
  94
  95 dnl Determine endianness
  96 AC_C_BIGENDIAN
  97
  98 dnl *** checks for programs ***
  99
 100 dnl find a compiler
 101 AC_PROG_CC
 102 AC_PROG_CC_STDC
 103
 104 dnl determine c++ compiler
 105 AC_PROG_CXX
 106 dnl determine if c++ is available on this system
 107 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 108
 109 dnl determine c++ preprocessor
 110 dnl FIXME: do we need this ?
 111 AC_PROG_CXXCPP
 112
 113 AC_PROG_OBJC
 114
 115 dnl check if the compiler supports '-c' and '-o' options
 116 AM_PROG_CC_C_O
 117
 118 dnl find an assembler
 119 AM_PROG_AS
 120
 121 dnl check if the compiler supports do while(0) macros
 122 AG_GST_CHECK_DOWHILE_MACROS
 123
 124 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 125 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 126
 127 dnl check for documentation tools
 128 GTK_DOC_CHECK([1.12])
 129 AG_GST_PLUGIN_DOCS([1.12])
 130
 131 dnl *** checks for libraries ***
 132
 133 dnl check for libm, for sin()
 134 LT_LIB_M
 135 AC_SUBST(LIBM)
 136
 137 AC_CHECK_FUNCS(clock_gettime, [], [
 138   AC_CHECK_LIB(rt, clock_gettime, [
 139     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 140     LIBRT="-lrt"
 141     AC_SUBST([LIBRT])
 142   ])
 143 ])
 144
 145 dnl *** checks for header files ***
 146
 147 dnl check if we have ANSI C header files
 148 AC_HEADER_STDC
 149
 150 dnl used by ext/wavpack
 151 AX_CREATE_STDINT_H
 152
 153 dnl used in gst/udp
 154 AC_CHECK_HEADERS([sys/time.h])
 155
 156 dnl used in gst/udp
 157 AC_CHECK_HEADERS([sys/socket.h])
 158
 159 dnl *** checks for types/defines ***
 160
 161 dnl Check for FIONREAD ioctl declaration.  This check is needed
 162 dnl for the UDP plugin to build on Solaris
 163 GST_CHECK_FIONREAD
 164
 165 dnl *** checks for structures ***
 166
 167 dnl *** checks for compiler characteristics ***
 168
 169 dnl check if we have GCC inline-asm
 170 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 171 if test x$HAVE_GCC_ASM = xyes ; then
 172   AC_DEFINE(HAVE_GCC_ASM, 1,
 173     [Define if compiler supports gcc inline assembly])
 174 fi
 175 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 176
 177 dnl *** checks for library functions ***
 178
 179 LIBS_SAVE=$LIBS
 180 LIBS="$LIBS $LIBM"
 181 AC_CHECK_FUNCS(rint sinh cosh asinh fpclass)
 182 LIBS=$LIBS_SAVE
 183
 184 dnl Check whether isinf() is defined by math.h
 185 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
 186     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; int i=isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
 187 if test "$ac_cv_have_isinf" = "yes"
 188 then
 189     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
 190 fi
 191
 192 dnl Check for mmap (needed by electricfence plugin)
 193 AC_FUNC_MMAP
 194 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 195
 196 dnl Check for mmap (needed by electricfence plugin)
 197
 198 AC_CHECK_TYPE([struct ip_mreqn], [
 199               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
 200               [#include <netinet/in.h>])
 201
 202 dnl *** checks for dependency libraries ***
 203
 204
 205 dnl GLib
 206 GLIB_REQ=2.32.0
 207 AG_GST_GLIB_CHECK([$GLIB_REQ])
 208
 209 dnl Orc
 210 ORC_CHECK([0.4.17])
 211
 212 dnl checks for gstreamer
 213 dnl uninstalled is selected preferentially -- see pkg-config(1)
 214 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 215 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 216 AG_GST_CHECK_GST_CONTROLLER($GST_API_VERSION, [$GST_REQ], yes)
 217 AG_GST_CHECK_GST_NET($GST_API_VERSION, [$GST_REQ], yes)
 218 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 219 AG_GST_CHECK_GST_PLUGINS_BASE($GST_API_VERSION, [$GSTPB_REQ], yes)
 220
 221 GST_TOOLS_DIR=`$PKG_CONFIG --variable=toolsdir gstreamer-$GST_API_VERSION`
 222 if test -z $GST_TOOLS_DIR; then
 223   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 224 fi
 225 AC_SUBST(GST_TOOLS_DIR)
 226
 227 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 228 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 229
 230 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 231
 232 dnl Check for documentation xrefs
 233 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 234 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 235 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_API_VERSION`"
 236 AC_SUBST(GLIB_PREFIX)
 237 AC_SUBST(GST_PREFIX)
 238 AC_SUBST(GSTPB_PREFIX)
 239
 240 dnl GTK is optional and used in examples
 241 HAVE_GTK=no
 242 GTK_REQ=3.0.0
 243 if test "x$BUILD_EXAMPLES" = "xyes"; then
 244   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 245   dnl some examples need gtk+-x11
 246   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 247   AC_SUBST(GTK_LIBS)
 248   AC_SUBST(GTK_CFLAGS)
 249 fi
 250 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 251 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 252
 253 dnl *** set variables based on configure arguments ***
 254
 255 dnl set license and copyright notice
 256 GST_LICENSE="LGPL"
 257 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 258 AC_SUBST(GST_LICENSE)
 259
 260 dnl set location of plugin directory
 261 AG_GST_SET_PLUGINDIR
 262
 263 dnl set release date/time
 264 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 265   ["${srcdir}/gst-plugins-good.doap"],
 266   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 267
 268 dnl build static plugins or not
 269 AC_MSG_CHECKING([whether to build static plugins or not])
 270 AC_ARG_ENABLE(
 271   static-plugins,
 272   AC_HELP_STRING(
 273     [--enable-static-plugins],
 274     [build static plugins @<:@default=no@:>@]),
 275   [AS_CASE(
 276     [$enableval], [no], [], [yes], [],
 277     [AC_MSG_ERROR([bad value "$enableval" for --enable-static-plugins])])],
 278   [enable_static_plugins=no])
 279 AC_MSG_RESULT([$enable_static_plugins])
 280 if test "x$enable_static_plugins" = xyes; then
 281   AC_DEFINE(GST_PLUGIN_BUILD_STATIC, 1,
 282     [Define if static plugins should be built])
 283   GST_PLUGIN_LIBTOOLFLAGS=""
 284 else
 285   GST_PLUGIN_LIBTOOLFLAGS="--tag=disable-static"
 286 fi
 287 AC_SUBST(GST_PLUGIN_LIBTOOLFLAGS)
 288 AM_CONDITIONAL(GST_PLUGIN_BUILD_STATIC, test "x$enable_static_plugins" = "xyes")
 289
 290 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 291 dnl make sure it doesn't complain about unused variables if debugging is disabled
 292 NO_WARNINGS=""
 293 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 294
 295 dnl define an ERROR_CFLAGS Makefile variable
 296 dnl -Wundef: too many broken headers
 297 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 298       -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 299       -Wwrite-strings -Wold-style-definition -Waggregate-return
 300       -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 301       -Wnested-externs $NO_WARNINGS])
 302
 303 dnl define an ERROR_CXXFLAGS Makefile variable
 304 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 305         -Wmissing-declarations -Wredundant-decls
 306         -Wwrite-strings
 307         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 308         $NO_WARNINGS])
 309
 310 dnl define an ERROR_OBJCFLAGS Makefile variable
 311 AG_GST_SET_ERROR_OBJCFLAGS($FATAL_WARNINGS, [
 312       -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 313       -Wwrite-strings -Wold-style-definition
 314       -Winit-self -Wmissing-include-dirs -Wno-multichar
 315       -Wnested-externs $NO_WARNINGS])
 316
 317 dnl define correct level for debugging messages
 318 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 319
 320 dnl used in examples
 321 AG_GST_DEFAULT_ELEMENTS
 322
 323 dnl *** plug-ins to include ***
 324
 325 dnl these are all the gst plug-ins, compilable without additional libs
 326 dnl videofilter is at the top because others depend on it
 327 AG_GST_CHECK_PLUGIN(alpha)
 328 AG_GST_CHECK_PLUGIN(apetag)
 329 AG_GST_CHECK_PLUGIN(audiofx)
 330 AG_GST_CHECK_PLUGIN(audioparsers)
 331 AG_GST_CHECK_PLUGIN(auparse)
 332 AG_GST_CHECK_PLUGIN(autodetect)
 333 AG_GST_CHECK_PLUGIN(avi)
 334 AG_GST_CHECK_PLUGIN(cutter)
 335 AG_GST_CHECK_PLUGIN(debugutils)
 336 AG_GST_CHECK_PLUGIN(deinterlace)
 337 AG_GST_CHECK_PLUGIN(dtmf)
 338 AG_GST_CHECK_PLUGIN(effectv)
 339 AG_GST_CHECK_PLUGIN(equalizer)
 340 AG_GST_CHECK_PLUGIN(flv)
 341 AG_GST_CHECK_PLUGIN(flx)
 342 AG_GST_CHECK_PLUGIN(goom)
 343 AG_GST_CHECK_PLUGIN(goom2k1)
 344 AG_GST_CHECK_PLUGIN(icydemux)
 345 AG_GST_CHECK_PLUGIN(id3demux)
 346 AG_GST_CHECK_PLUGIN(imagefreeze)
 347 AG_GST_CHECK_PLUGIN(interleave)
 348 AG_GST_CHECK_PLUGIN(isomp4)
 349 AG_GST_CHECK_PLUGIN(law)
 350 AG_GST_CHECK_PLUGIN(level)
 351 AG_GST_CHECK_PLUGIN(matroska)
 352 AG_GST_CHECK_PLUGIN(monoscope)
 353 AG_GST_CHECK_PLUGIN(multifile)
 354 AG_GST_CHECK_PLUGIN(multipart)
 355 AG_GST_CHECK_PLUGIN(replaygain)
 356 AG_GST_CHECK_PLUGIN(rtp)
 357 AG_GST_CHECK_PLUGIN(rtpmanager)
 358 AG_GST_CHECK_PLUGIN(rtsp)
 359 AG_GST_CHECK_PLUGIN(shapewipe)
 360 AG_GST_CHECK_PLUGIN(smpte)
 361 AG_GST_CHECK_PLUGIN(spectrum)
 362 AG_GST_CHECK_PLUGIN(udp)
 363 AG_GST_CHECK_PLUGIN(videobox)
 364 AG_GST_CHECK_PLUGIN(videocrop)
 365 AG_GST_CHECK_PLUGIN(videofilter)
 366 AG_GST_CHECK_PLUGIN(videomixer)
 367 AG_GST_CHECK_PLUGIN(wavenc)
 368 AG_GST_CHECK_PLUGIN(wavparse)
 369 AG_GST_CHECK_PLUGIN(y4m)
 370
 371 dnl disable experimental plug-ins
 372 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 373   AG_GST_DISABLE_PLUGIN(monoscope)
 374 fi
 375
 376 dnl *** sys plug-ins ***
 377
 378 echo
 379 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 380 echo
 381
 382 dnl DirectSound
 383 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 384 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 385   HAVE_DIRECTSOUND="no"
 386   save_CFLAGS="$CFLAGS"
 387   save_LDFLAGS="$LDFLAGS"
 388   save_LIBS="$LIBS"
 389   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 390   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 391   LIBS="$LIBS -ldsound -ldxerr9 -luser32"
 392   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 393   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 394 #include <windows.h>
 395 #include <dxerr9.h>
 396 #include <dsound.h>
 397 ]], [[
 398   DXGetErrorString9 (0);
 399   DirectSoundCreate(NULL, NULL, NULL);
 400 ]])
 401 ],
 402     [HAVE_DIRECTSOUND="yes"],
 403     [HAVE_DIRECTSOUND="no"])
 404   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 405   CFLAGS=$save_CFLAGS
 406   LDFLAGS=$save_LDFLAGS
 407   LIBS=$save_LIBS
 408
 409   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 410     dnl this is much more than we want
 411     DIRECTSOUND_LIBS="-ldsound -ldxerr9 -luser32"
 412     AC_SUBST(DIRECTSOUND_CFLAGS)
 413     AC_SUBST(DIRECTSOUND_LDFLAGS)
 414     AC_SUBST(DIRECTSOUND_LIBS)
 415   fi
 416   AC_SUBST(HAVE_DIRECTSOUND)
 417 ])
 418
 419 dnl *** Win32 WaveOut ***
 420 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVEFORM, true)
 421 AG_GST_CHECK_FEATURE(WAVEFORM, [Win32 WaveForm], waveformsink, [
 422   AC_CHECK_HEADER(mmsystem.h, HAVE_WAVEFORM="yes", HAVE_WAVEFORM="no", [#include <windows.h>])
 423 ])
 424
 425 dnl *** OSS audio *** (Linux, *BSD)
 426 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 427 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 428  HAVE_OSS="yes"
 429 dnl Linux and newer BSD versions :
 430  AC_CHECK_HEADER(sys/soundcard.h, [
 431    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 432    ] , [
 433 dnl Some old BSD versions and also newer OpenBSD versions :
 434    AC_CHECK_HEADER(soundcard.h, [
 435      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 436      ], [
 437   dnl Some old BSD versions :
 438      AC_CHECK_HEADER(machine/soundcard.h, [
 439        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 440          [Define if OSS includes are in /machine/])
 441        ], [
 442        HAVE_OSS="no"
 443      ])
 444    ])
 445  ])
 446 ])
 447
 448 dnl *** oss4 ***
 449 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS4, true)
 450 AG_GST_CHECK_FEATURE(OSS4, [Open Sound System 4], oss4, [
 451   AC_MSG_CHECKING([Checking if we can build the OSS4 elements])
 452   AC_CHECK_HEADERS([fcntl.h sys/ioctl.h sys/stat.h sys/types.h],
 453       [test -z "$OSS4_MISSING_HEADER" && HAVE_OSS4="yes"],
 454       [OSS4_MISSING_HEADER="yes";HAVE_OSS4="no"])
 455 ])
 456
 457 dnl *** Sun Audio ***
 458 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 459 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 460   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 461 ])
 462
 463 dnl *** OSX Audio ***
 464 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 465 HAVE_IOS="no"
 466 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 467   AC_CHECK_HEADER(CoreAudio/CoreAudio.h,
 468     [HAVE_OSX_AUDIO="yes"],
 469     [AC_CHECK_HEADER(CoreAudio/CoreAudioTypes.h,
 470     [
 471       HAVE_OSX_AUDIO="yes"
 472       HAVE_IOS="yes"
 473     ], [
 474       HAVE_OSX_AUDIO="no"
 475       HAVE_IOS="no"
 476     ])]
 477   )
 478 ])
 479 if test "x$HAVE_IOS" = "xyes"; then
 480   AC_DEFINE(HAVE_IOS, 1, [building for iOS platofrm])
 481 fi
 482 AM_CONDITIONAL(HAVE_IOS, test "x$HAVE_IOS" = "xyes")
 483
 484 dnl *** OS X video ***
 485 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 486 HAVE_OSX_VIDEO="no"
 487 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 488   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 489
 490   dnl in case header OpenGL/gl.h is found on other platforms (or older, unsupported OS X)
 491   dnl also require Snow Leopard or newer
 492
 493   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 494         #include <AvailabilityMacros.h>
 495         #if MAC_OS_X_VERSION_MIN_REQUIRED < 1060
 496         #error Too old OSX version
 497         #endif
 498       ]], [[return 0;]])],[HAVE_OSX_VIDEO="yes"],[HAVE_OSX_VIDEO="no"])
 499 ])
 500
 501 dnl *** Video 4 Linux 2 ***
 502 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 503 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 504 HAVE_GST_V4L2=no
 505 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], video4linux2, [
 506   AC_MSG_CHECKING([Checking for video4linux2 header ...])
 507   AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_GST_V4L2=yes ],
 508   [
 509     AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_GST_V4L2=yes ],
 510     [
 511       AC_CHECK_HEADER(sys/videoio.h, [ HAVE_GST_V4L2=yes ])
 512     ])
 513   ])
 514   if test "x$HAVE_VIDEODEV" = "xno"; then
 515      AC_MSG_WARN([video4linux2 was not found])
 516   fi
 517 ])
 518
 519 # Optional gudev for device probing
 520 AC_ARG_WITH([gudev],
 521   AS_HELP_STRING([--with-gudev],[device detection with gudev]),
 522   [],
 523   [with_gudev=check])
 524 if test x$HAVE_GST_V4L2 = xyes; then
 525   if test x$with_gudev != xno; then
 526     PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 147 ],
 527       [ AC_DEFINE(HAVE_GUDEV, 1,
 528           [Whether gudev is available for device detection])
 529       ],
 530       [true])
 531   fi
 532 fi
 533
 534 AC_SUBST(GUDEV_CFLAGS)
 535 AC_SUBST(GUDEV_LIBS)
 536
 537 # Make libv4l2 non-automagic
 538 AC_ARG_WITH([libv4l2],
 539   AS_HELP_STRING([--with-libv4l2],[support video buffer conversion using libv4l2]),
 540   [],
 541   [with_libv4l2=check])
 542 if test x$HAVE_GST_V4L2 = xyes; then
 543   if test x$with_libv4l2 != xno; then
 544       PKG_CHECK_MODULES(LIBV4L2, libv4l2,
 545           [ have_libv4l2=yes
 546             AC_DEFINE(HAVE_LIBV4L2, 1,
 547                 [Whether libv4l2 is available for video buffer conversion])
 548           ], [
 549           have_libv4l2=no
 550           ])
 551   else
 552     have_libv4l2=no
 553   fi
 554 fi
 555
 556 dnl Check for X11
 557 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 558 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 559                   [ximagesrc], [
 560   PKG_CHECK_MODULES([X], [x11], [
 561     HAVE_X="yes"
 562     dnl check for Xfixes
 563     PKG_CHECK_MODULES([XFIXES], [ xfixes ], [
 564       AC_DEFINE(HAVE_XFIXES, 1, [Defined if Xfixes is available])
 565     ], [ HAVE_XFIXES="no" ])
 566
 567     dnl check for Xdamage
 568     PKG_CHECK_MODULES([XDAMAGE], [ xdamage ], [
 569       AC_DEFINE(HAVE_XDAMAGE, 1, [Defined if Xdamage is available])
 570     ], [ HAVE_XDAMAGE="no" ])
 571
 572     dnl check for X Shm
 573     PKG_CHECK_MODULES([XEXT], [ xext ], [
 574       AC_CHECK_LIB([Xext], [ XShmAttach ], [
 575         AC_DEFINE(HAVE_XSHM, 1, [Defined if XShm is available])
 576         XSHM_LIBS="$XEXT_LIBS"
 577         XSHM_CFLAGS="$XEXT_CFLAGS"
 578       ], [ HAVE_XEXT="no" ] , [ $X_LIBS ])
 579     ])
 580     AC_SUBST(XSHM_LIBS)
 581     AC_SUBST(XSHM_CFLAGS)
 582   ], [ HAVE_X="no" ])
 583 ])
 584
 585 dnl *** ext plug-ins ***
 586 dnl keep this list sorted alphabetically !
 587
 588 if test "x$BUILD_EXTERNAL" = "xyes"; then
 589
 590 echo
 591 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 592 echo
 593
 594 dnl *** aalib ***
 595 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 596 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 597   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 598 ])
 599
 600 dnl *** cairo ***
 601 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 602 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering and gobject bindings], cairo, [
 603   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.10.0 cairo-gobject >= 1.10.0)
 604 ])
 605
 606 dnl *** FLAC ***
 607 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 608 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 609   AG_GST_PKG_CHECK_MODULES(FLAC, flac >= 1.1.4)
 610 ])
 611
 612 dnl *** GDK pixbuf ***
 613 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 614 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 615   AG_GST_PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0 >= 2.8.0)
 616 ])
 617
 618 dnl *** Jack ***
 619 translit(dnm, m, l) AM_CONDITIONAL(USE_JACK, true)
 620 AG_GST_CHECK_FEATURE(JACK, Jack, jack, [
 621   PKG_CHECK_MODULES(JACK, jack >= 0.99.10, HAVE_JACK="yes", HAVE_JACK="no")
 622   AC_SUBST(JACK_CFLAGS)
 623   AC_SUBST(JACK_LIBS)
 624
 625   AG_GST_PKG_CHECK_MODULES(JACK_0_120_1, jack >= 0.120.1 jack < 1.0)
 626   if test x$HAVE_JACK_0_120_1 = xyes; then
 627     AC_DEFINE(HAVE_JACK_0_120_1, 1, [defined if jack >= 0.120.1 is available])
 628   fi
 629   AG_GST_PKG_CHECK_MODULES(JACK_1_9_7, jack >= 1.9.7)
 630   if test x$HAVE_JACK_1_9_7 = xyes; then
 631     AC_DEFINE(HAVE_JACK_1_9_7, 1, [defined if jack >= 1.9.7 is available])
 632   fi
 633
 634 ])
 635
 636 dnl *** jpeg ***
 637 dnl FIXME: we could use header checks here as well IMO
 638 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 639 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 640   AC_ARG_WITH(jpeg-mmx,
 641     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 642   OLD_LIBS="$LIBS"
 643   if test x$with_jpeg_mmx != x; then
 644     LIBS="$LIBS -L$with_jpeg_mmx"
 645   fi
 646   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 647   JPEG_LIBS="$LIBS -ljpeg-mmx"
 648   LIBS="$OLD_LIBS"
 649   if test x$HAVE_JPEG != xyes; then
 650     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 651     JPEG_LIBS="-ljpeg"
 652   fi
 653   AC_SUBST(JPEG_LIBS)
 654 ])
 655
 656 dnl *** libcaca ***
 657 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 658 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 659   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 660 ])
 661
 662 dnl *** libdv ***
 663 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 664 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 665   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 666 ])
 667
 668 dnl *** libpng ***
 669 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 670 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 671   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng >= 1.2)
 672 ])
 673
 674 dnl *** pulseaudio ***
 675 translit(dnm, m, l) AM_CONDITIONAL(USE_PULSE, true)
 676 AG_GST_CHECK_FEATURE(PULSE, [pulseaudio plug-in], pulseaudio, [
 677
 678   dnl used in ext/pulse/pulseutil.c
 679   AC_CHECK_HEADERS([process.h])
 680
 681   AG_GST_PKG_CHECK_MODULES(PULSE, libpulse >= 2.0)
 682 ])
 683
 684 dnl *** dv1394 ***
 685 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 686 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 687   dnl first test for libraw1394 >= 2.0.0
 688   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 2.0.0)
 689   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 690   dnl now see how far we got
 691   if test x$HAVE_RAW1394 = xyes && \
 692      test x$HAVE_LIBIEC61883 = xyes; then
 693        AG_GST_CHECK_LIBHEADER(AVC1394,
 694         avc1394, avc1394_send_command, $RAW1394_LIBS,
 695         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 696        AG_GST_CHECK_LIBHEADER(ROM1394,
 697         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 698         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 699        if test x$HAVE_AVC1394 = xyes && \
 700           test x$HAVE_AVC1394 = xyes && \
 701           test x$HAVE_ROM1394 = xyes; then
 702           HAVE_DV1394=yes
 703           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 704           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 705           AC_SUBST(DV1394_CFLAGS)
 706           AC_SUBST(DV1394_LIBS)
 707         fi
 708   else
 709        if test x$HAVE_RAW1394 = xno; then
 710           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 711           AG_GST_CHECK_LIBHEADER(AVC1394,
 712            avc1394, avc1394_send_command, $RAW1394_LIBS,
 713            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 714           AG_GST_CHECK_LIBHEADER(ROM1394,
 715            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 716            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 717           if test x$HAVE_RAW1394 = xyes && \
 718              test x$HAVE_AVC1394 = xyes && \
 719              test x$HAVE_ROM1394 = xyes; then
 720              HAVE_DV1394=yes
 721              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 722              DV1394_CFLAGS="$RAW1394_CFLAGS"
 723              if test x$HAVE_LIBIEC61883 = xyes; then
 724                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 725                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 726              fi
 727              AC_SUBST(DV1394_CFLAGS)
 728              AC_SUBST(DV1394_LIBS)
 729            fi
 730          fi
 731   fi
 732 ])
 733 AM_CONDITIONAL(USE_LIBIEC61883, [ test "x${HAVE_LIBIEC61883}" = xyes ] )
 734
 735 dnl *** shout2 ***
 736 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 737 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 738   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 739 ])
 740
 741 dnl *** soup ***
 742 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUP, true)
 743 AG_GST_CHECK_FEATURE(SOUP, [soup http client plugin (2.4)], souphttpsrc, [
 744   PKG_CHECK_MODULES(SOUP, libsoup-2.4 >= 2.40, [HAVE_SOUP="yes"], [HAVE_SOUP="no"])
 745   AC_SUBST(SOUP_CFLAGS)
 746   AC_SUBST(SOUP_LIBS)
 747 ])
 748
 749 dnl *** speex ***
 750 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 751 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 752   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 753 ])
 754
 755 dnl *** taglib ***
 756 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 757 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 758   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.5)
 759   if test "x$HAVE_CXX" != "xyes"; then
 760     USE_TAGLIB=false
 761     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 762   else
 763     dnl work around bug in taglib 1.5 headers, remove once there is a 1.6
 764     AS_CXX_COMPILER_FLAG([-Wno-attributes], [
 765         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS -Wno-attributes"
 766       ], [
 767         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS"
 768     ])
 769     AC_SUBST(TAGLIB_CXXFLAGS)
 770   fi
 771 ])
 772
 773 dnl *** vpx ***
 774 translit(dnm, m, l) AM_CONDITIONAL(USE_VPX, vpx)
 775 AG_GST_CHECK_FEATURE(VPX, [VPX decoder], vpx, [
 776   PKG_CHECK_MODULES(VPX, vpx >= 1.1.0, [HAVE_VPX="yes"], [HAVE_VPX="no"])
 777   HAVE_VP8=no
 778   HAVE_VP9=no
 779
 780   if test $HAVE_VPX = "yes"; then
 781     OLD_LIBS="$LIBS"
 782     OLD_CFLAGS="$CFLAGS"
 783     CFLAGS="$CFLAGS $VPX_CFLAGS"
 784     LIBS="$LIBS $VPX_LIBS"
 785     AC_CHECK_LIB(vpx, vpx_codec_vp8_cx_algo, [
 786       HAVE_VP8=yes
 787       AC_DEFINE(HAVE_VP8_ENCODER, 1, [Defined if the VP8 encoder is available])
 788     ])
 789     AC_CHECK_LIB(vpx, vpx_codec_vp8_dx_algo, [
 790       HAVE_VP8=yes
 791       AC_DEFINE(HAVE_VP8_DECODER, 1, [Defined if the VP8 decoder is available])
 792     ])
 793
 794     PKG_CHECK_MODULES(VPX_130, vpx >= 1.3.0, [
 795       AC_CHECK_LIB(vpx, vpx_codec_vp9_cx_algo, [
 796         HAVE_VP9=yes
 797         AC_DEFINE(HAVE_VP9_ENCODER, 1, [Defined if the VP9 encoder is available])
 798       ])
 799       AC_CHECK_LIB(vpx, vpx_codec_vp9_dx_algo, [
 800         HAVE_VP9=yes
 801         AC_DEFINE(HAVE_VP9_DECODER, 1, [Defined if the VP9 decoder is available])
 802       ])
 803     ], [true])
 804     LIBS="$OLD_LIBS"
 805     CFLAGS="$OLD_CFLAGS"
 806   fi
 807   AC_SUBST(VPX_LIBS)
 808   AC_SUBST(VPX_CFLAGS)
 809 ])
 810
 811 dnl *** wavpack ***
 812 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 813 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 814   AG_GST_PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.60.0)
 815 ])
 816
 817 dnl *** qtdemux & matroska prefer to have zlib ***
 818 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 819 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for qtdemux/matroska],, [
 820   AG_GST_CHECK_LIBHEADER(ZLIB,
 821     z, uncompress,, zlib.h, [
 822     HAVE_ZLIB="yes"
 823     ZLIB_LIBS="-lz"
 824     AC_SUBST(ZLIB_LIBS)
 825   ])
 826 ])
 827
 828 dnl *** matroska prefers to have bz2 ***
 829 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
 830 AG_GST_CHECK_FEATURE(BZ2, [bz2 library for matroska ],, [
 831   save_LIBS=$LIBS
 832   LIBS="$LIBS -lbz2"
 833   AC_MSG_CHECKING([for BZ2_bzlibVersion in -lbz2])
 834   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <bzlib.h>]], [[const char *version = BZ2_bzlibVersion ();]])],[HAVE_BZ2=yes],[HAVE_BZ2=no])
 835   AC_MSG_RESULT($HAVE_BZ2)
 836   LIBS=$save_LIBS
 837   if test "x$HAVE_BZ2" = "xyes"; then
 838     BZ2_LIBS="-lbz2"
 839   fi
 840   AC_SUBST(BZ2_LIBS)
 841 ])
 842
 843 else
 844
 845 dnl not building plugins with external dependencies,
 846 dnl but we still need to set the conditionals
 847 AM_CONDITIONAL(USE_AALIB, false)
 848 AM_CONDITIONAL(USE_BZ2, false)
 849 AM_CONDITIONAL(USE_CAIRO, false)
 850 AM_CONDITIONAL(USE_DIRECTSOUND, false)
 851 AM_CONDITIONAL(USE_DV1394, false)
 852 AM_CONDITIONAL(USE_FLAC, false)
 853 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
 854 AM_CONDITIONAL(USE_JACK, false)
 855 AM_CONDITIONAL(USE_JPEG, false)
 856 AM_CONDITIONAL(USE_LIBCACA, false)
 857 AM_CONDITIONAL(USE_LIBDV, false)
 858 AM_CONDITIONAL(USE_LIBIEC61883, false)
 859 AM_CONDITIONAL(USE_LIBPNG, false)
 860 AM_CONDITIONAL(USE_OSS, false)
 861 AM_CONDITIONAL(USE_OSS4, false)
 862 AM_CONDITIONAL(USE_OSX_AUDIO, false)
 863 AM_CONDITIONAL(USE_OSX_VIDEO, false)
 864 AM_CONDITIONAL(USE_PULSE, false)
 865 AM_CONDITIONAL(USE_SHOUT2, false)
 866 AM_CONDITIONAL(USE_SOUP, false)
 867 AM_CONDITIONAL(USE_SPEEX, false)
 868 AM_CONDITIONAL(USE_SUNAUDIO, false)
 869 AM_CONDITIONAL(USE_TAGLIB, false)
 870 AM_CONDITIONAL(USE_VPX, false)
 871 AM_CONDITIONAL(USE_WAVEFORM, false)
 872 AM_CONDITIONAL(USE_WAVPACK, false)
 873 AM_CONDITIONAL(USE_X, false)
 874 AM_CONDITIONAL(USE_ZLIB, false)
 875
 876 fi dnl of EXT plugins
 877
 878 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 879
 880 dnl Overview:
 881 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 882 dnl GST_*:              flags shared by all built objects
 883 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 884 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
 885 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 886 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 887
 888 dnl GST_OPTION_CFLAGS
 889 if test "x$USE_DEBUG" = xyes; then
 890    PROFILE_CFLAGS="-g"
 891 fi
 892 AC_SUBST(PROFILE_CFLAGS)
 893
 894 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 895   dnl Define _only_ for git (not pre-releases or releases)
 896   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 897 else
 898   DEPRECATED_CFLAGS=""
 899 fi
 900 AC_SUBST(DEPRECATED_CFLAGS)
 901
 902 dnl every flag in GST_OPTION_CFLAGS, GST_OPTION_CXXFLAGS and GST_OPTION_OBJCFLAGS can be overridden
 903 dnl at make time with e.g. make ERROR_CFLAGS=""
 904 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 905 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 906 GST_OPTION_OBJCFLAGS="\$(WARNING_OBJCFLAGS) \$(ERROR_OBJCFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 907 AC_SUBST(GST_OPTION_CFLAGS)
 908 AC_SUBST(GST_OPTION_CXXFLAGS)
 909 AC_SUBST(GST_OPTION_OBJCFLAGS)
 910
 911 dnl our libraries need to be versioned correctly
 912 AC_SUBST(GST_LT_LDFLAGS)
 913
 914 dnl FIXME: do we want to rename to GST_ALL_* ?
 915 dnl prefer internal headers to already installed ones
 916 dnl also add builddir include for enumtypes and marshal
 917 dnl add ERROR_CFLAGS, but overridable
 918 GST_CFLAGS="$GST_CFLAGS -DGST_USE_UNSTABLE_API"
 919 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS)"
 920 GST_OBJCFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_OBJCFLAGS)"
 921 GST_CFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
 922 AC_SUBST(GST_CFLAGS)
 923 AC_SUBST(GST_CXXFLAGS)
 924 AC_SUBST(GST_OBJCFLAGS)
 925 AC_SUBST(GST_LIBS)
 926
 927 dnl LDFLAGS really should only contain flags, not libs - they get added before
 928 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 929 GST_ALL_LDFLAGS="-no-undefined"
 930 AC_SUBST(GST_ALL_LDFLAGS)
 931
 932 dnl this really should only contain flags, not libs - they get added before
 933 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 934 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_.*' $GST_ALL_LDFLAGS"
 935 AC_SUBST(GST_PLUGIN_LDFLAGS)
 936
 937 dnl *** output files ***
 938
 939 $MKDIR_P tests/check/orc
 940
 941 dnl keep this alphabetic per directory, please
 942 AC_CONFIG_FILES(
 943 Makefile
 944 gst/Makefile
 945 gst/alpha/Makefile
 946 gst/apetag/Makefile
 947 gst/audiofx/Makefile
 948 gst/audioparsers/Makefile
 949 gst/auparse/Makefile
 950 gst/autodetect/Makefile
 951 gst/avi/Makefile
 952 gst/cutter/Makefile
 953 gst/deinterlace/Makefile
 954 gst/dtmf/Makefile
 955 gst/debugutils/Makefile
 956 gst/effectv/Makefile
 957 gst/equalizer/Makefile
 958 gst/flv/Makefile
 959 gst/goom/Makefile
 960 gst/goom2k1/Makefile
 961 gst/id3demux/Makefile
 962 gst/icydemux/Makefile
 963 gst/imagefreeze/Makefile
 964 gst/interleave/Makefile
 965 gst/isomp4/Makefile
 966 gst/law/Makefile
 967 gst/level/Makefile
 968 gst/matroska/Makefile
 969 gst/monoscope/Makefile
 970 gst/multifile/Makefile
 971 gst/multipart/Makefile
 972 gst/replaygain/Makefile
 973 gst/rtp/Makefile
 974 gst/rtpmanager/Makefile
 975 gst/rtsp/Makefile
 976 gst/shapewipe/Makefile
 977 gst/smpte/Makefile
 978 gst/spectrum/Makefile
 979 gst/udp/Makefile
 980 gst/videobox/Makefile
 981 gst/videocrop/Makefile
 982 gst/videofilter/Makefile
 983 gst/videomixer/Makefile
 984 gst/wavenc/Makefile
 985 gst/wavparse/Makefile
 986 gst/flx/Makefile
 987 gst/y4m/Makefile
 988 ext/Makefile
 989 ext/aalib/Makefile
 990 ext/cairo/Makefile
 991 ext/dv/Makefile
 992 ext/flac/Makefile
 993 ext/gdk_pixbuf/Makefile
 994 ext/jack/Makefile
 995 ext/jpeg/Makefile
 996 ext/libcaca/Makefile
 997 ext/libpng/Makefile
 998 ext/pulse/Makefile
 999 ext/raw1394/Makefile
1000 ext/shout2/Makefile
1001 ext/soup/Makefile
1002 ext/speex/Makefile
1003 ext/taglib/Makefile
1004 ext/vpx/Makefile
1005 ext/wavpack/Makefile
1006 sys/Makefile
1007 sys/directsound/Makefile
1008 sys/oss/Makefile
1009 sys/oss4/Makefile
1010 sys/osxaudio/Makefile
1011 sys/osxvideo/Makefile
1012 sys/sunaudio/Makefile
1013 sys/v4l2/Makefile
1014 sys/waveform/Makefile
1015 sys/ximage/Makefile
1016 po/Makefile.in
1017 tests/Makefile
1018 tests/check/Makefile
1019 tests/examples/Makefile
1020 tests/examples/audiofx/Makefile
1021 tests/examples/cairo/Makefile
1022 tests/examples/equalizer/Makefile
1023 tests/examples/jack/Makefile
1024 tests/examples/level/Makefile
1025 tests/examples/pulse/Makefile
1026 tests/examples/rtp/Makefile
1027 tests/examples/shapewipe/Makefile
1028 tests/examples/spectrum/Makefile
1029 tests/examples/v4l2/Makefile
1030 tests/files/Makefile
1031 tests/icles/Makefile
1032 common/Makefile
1033 common/m4/Makefile
1034 m4/Makefile
1035 docs/Makefile
1036 docs/plugins/Makefile
1037 docs/version.entities
1038 pkgconfig/Makefile
1039 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1040 gst-plugins-good.spec
1041 )
1042
1043 dnl Create the config.h file for Visual Studio builds
1044 dnl Beware of spaces and /'s in some of the shell variable contents.
1045 sed \
1046     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"\n\n#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
1047     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
1048     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
1049     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
1050     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
1051     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
1052     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
1053     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
1054     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
1055     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
1056     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
1057     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
1058     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
1059     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
1060     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
1061     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
1062     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
1063     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
1064     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
1065     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1066     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1067     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1068     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
1069     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1070     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
1071     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1072     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1073     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1074     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
1075     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
1076     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1077     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
1078     -e "s/.* DEFAULT_AUDIOSRC$/#define DEFAULT_AUDIOSRC \"audiotestsrc\"/" \
1079     -e "s/.* DEFAULT_VIDEOSRC$/#define DEFAULT_VIDEOSRC \"videotestsrc\"/" \
1080     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1081     config.h.in >win32/common/config.h-new
1082
1083 AC_OUTPUT
1084
1085 AG_GST_OUTPUT_PLUGINS
1086 ORC_OUTPUT
1087