configure.ac

   1 AC_PREREQ(2.60)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/pre
   8 AC_INIT(GStreamer Good Plug-ins, 0.10.28.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-good)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability 1.10])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use major.minor as a version
  41 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  42 dnl we override it here if we need to for the release candidate of new series
  43 GST_MAJORMINOR=0.10
  44 AC_SUBST(GST_MAJORMINOR)
  45
  46 AG_GST_LIBTOOL_PREPARE
  47
  48 dnl FIXME: this macro doesn't actually work;
  49 dnl the generated libtool script has no support for the listed tags.
  50 dnl So this needs to be fixed first if we want to use this
  51 dnl AS_LIBTOOL_TAGS
  52
  53 AC_LIBTOOL_WIN32_DLL
  54 AM_PROG_LIBTOOL
  55
  56 dnl *** required versions of GStreamer stuff ***
  57 GST_REQ=0.10.32.1
  58 GSTPB_REQ=0.10.32.1
  59
  60 dnl *** autotools stuff ****
  61
  62 dnl allow for different autotools
  63 AS_AUTOTOOLS_ALTERNATE
  64
  65 dnl Add parameters for aclocal
  66 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  67
  68 dnl set up gettext
  69 dnl the version check needs to stay here because autopoint greps for it
  70 AM_GNU_GETTEXT_VERSION([0.17])
  71 AM_GNU_GETTEXT([external])
  72 AG_GST_GETTEXT([gst-plugins-good-$GST_MAJORMINOR])
  73
  74 dnl *** check for arguments to configure ***
  75
  76 AG_GST_ARG_DEBUG
  77 AG_GST_ARG_PROFILING
  78 AG_GST_ARG_VALGRIND
  79 AG_GST_ARG_GCOV
  80
  81 AG_GST_ARG_EXAMPLES
  82
  83 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  84 AG_GST_ARG_WITH_PACKAGE_NAME
  85 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  86
  87 AG_GST_ARG_WITH_PLUGINS
  88
  89 AG_GST_ARG_ENABLE_EXTERNAL
  90
  91 AG_GST_ARG_ENABLE_EXPERIMENTAL
  92
  93 dnl *** checks for platform ***
  94
  95 dnl * hardware/architecture *
  96
  97 dnl common/m4/gst-arch.m4
  98 dnl check CPU type
  99 AG_GST_ARCH
 100
 101 dnl Determine endianness
 102 AC_C_BIGENDIAN
 103
 104 dnl *** checks for programs ***
 105
 106 dnl find a compiler
 107 AC_PROG_CC
 108 AC_PROG_CC_STDC
 109
 110 dnl determine c++ compiler
 111 AC_PROG_CXX
 112 dnl determine if c++ is available on this system
 113 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 114
 115 dnl determine c++ preprocessor
 116 dnl FIXME: do we need this ?
 117 AC_PROG_CXXCPP
 118
 119 AS_PROG_OBJC
 120
 121 dnl check if the compiler supports '-c' and '-o' options
 122 AM_PROG_CC_C_O
 123
 124 dnl find an assembler
 125 AM_PROG_AS
 126
 127 dnl check if the compiler supports do while(0) macros
 128 AG_GST_CHECK_DOWHILE_MACROS
 129
 130 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 131 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 132
 133 dnl check for gconftool-2
 134 dnl this macro defines an am conditional, so it needs to be run always
 135 AM_GCONF_SOURCE_2
 136
 137 dnl check for documentation tools
 138 GTK_DOC_CHECK([1.3])
 139 AS_PATH_PYTHON([2.1])
 140 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 141
 142 dnl *** checks for libraries ***
 143
 144 dnl check for libm, for sin()
 145 AC_CHECK_LIBM
 146 AC_SUBST(LIBM)
 147
 148 dnl *** checks for header files ***
 149
 150 dnl check if we have ANSI C header files
 151 AC_HEADER_STDC
 152
 153 dnl used by ext/wavpack
 154 AX_CREATE_STDINT_H
 155
 156 dnl used in gst/rtp/gstasteriskh263.c
 157 AC_CHECK_HEADERS([netinet/in.h])
 158 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 159 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 160
 161 dnl used in gst/udp
 162 AC_CHECK_HEADERS([sys/time.h])
 163
 164 dnl *** checks for types/defines ***
 165
 166 dnl Check for FIONREAD ioctl declaration.  This check is needed
 167 dnl for the UDP plugin to build on Solaris
 168 GST_CHECK_FIONREAD
 169
 170 dnl *** checks for structures ***
 171
 172 dnl *** checks for compiler characteristics ***
 173
 174 dnl check if we have GCC inline-asm
 175 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 176 if test x$HAVE_GCC_ASM = xyes ; then
 177   AC_DEFINE(HAVE_GCC_ASM, 1,
 178     [Define if compiler supports gcc inline assembly])
 179 fi
 180 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 181
 182 dnl *** checks for library functions ***
 183
 184 LIBS_SAVE=$LIBS
 185 LIBS="$LIBS $LIBM"
 186 AC_CHECK_FUNCS(rint sinh cosh asinh fpclass)
 187 LIBS=$LIBS_SAVE
 188
 189 dnl Check whether isinf() is defined by math.h
 190 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
 191     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; int i=isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
 192 if test "$ac_cv_have_isinf" = "yes"
 193 then
 194     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
 195 fi
 196
 197 dnl Check for mmap (needed by electricfence plugin)
 198 AC_FUNC_MMAP
 199 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 200
 201 dnl Check for mmap (needed by electricfence plugin)
 202
 203 AC_CHECK_TYPE([struct ip_mreqn], [
 204               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
 205               [#include <netinet/in.h>])
 206
 207 dnl *** checks for dependency libraries ***
 208
 209 dnl GLib is required
 210 AG_GST_GLIB_CHECK([2.20])
 211
 212 dnl Orc
 213 ORC_CHECK([0.4.11])
 214
 215 dnl checks for gstreamer
 216 dnl uninstalled is selected preferentially -- see pkg-config(1)
 217 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 218 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 219 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ], yes)
 220 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 221 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 222 AG_GST_CHECK_GST_PLUGINS_BASE($GST_MAJORMINOR, [$GSTPB_REQ], yes)
 223
 224 GST_TOOLS_DIR=`$PKG_CONFIG --variable=toolsdir gstreamer-$GST_MAJORMINOR`
 225 if test -z $GST_TOOLS_DIR; then
 226   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 227 fi
 228 AC_SUBST(GST_TOOLS_DIR)
 229
 230 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 231 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 232
 233 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 234
 235 dnl Check for documentation xrefs
 236 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 237 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 238 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_MAJORMINOR`"
 239 AC_SUBST(GLIB_PREFIX)
 240 AC_SUBST(GST_PREFIX)
 241 AC_SUBST(GSTPB_PREFIX)
 242
 243 dnl GTK is optional and used in examples
 244 HAVE_GTK=no
 245 GTK2_REQ=2.14.0
 246 GTK3_REQ=2.91.3
 247 if test "x$BUILD_EXAMPLES" = "xyes"; then
 248   AC_MSG_CHECKING([which gtk+ version to compile examples against (optional)])
 249   AC_ARG_WITH([gtk],
 250     AC_HELP_STRING([--with-gtk=3.0|2.0],
 251                    [which gtk+ version to compile against (default: 2.0)]),
 252     [case "$with_gtk" in
 253         2.0) GTK_REQ=$GTK2_REQ ;;
 254         3.0) GTK_REQ=$GTK3_REQ ;;
 255         *) AC_MSG_ERROR([invalid gtk+ version specified]);;
 256     esac],
 257     [with_gtk=2.0
 258      GTK_REQ=$GTK2_REQ])
 259   AC_MSG_RESULT([$with_gtk (>= $GTK_REQ)])
 260   PKG_CHECK_MODULES(GTK, gtk+-$with_gtk >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 261   dnl some examples need gtk+-x11
 262   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-$with_gtk >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 263   AC_SUBST(GTK_LIBS)
 264   AC_SUBST(GTK_CFLAGS)
 265 fi
 266 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 267 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 268
 269 dnl should we install schemas ?
 270 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONFTOOL, true)
 271 AG_GST_CHECK_FEATURE(GCONFTOOL, [GConf schemas], , [
 272   AC_PATH_PROG(GCONFTOOL, gconftool-2, no)
 273   if test x$GCONFTOOL = xno; then
 274     AC_MSG_WARN(Not installing GConf schemas)
 275     HAVE_GCONFTOOL="no"
 276   else
 277     HAVE_GCONFTOOL="yes"
 278   fi
 279   AC_SUBST(HAVE_GCONFTOOL)
 280 ])
 281
 282 dnl *** set variables based on configure arguments ***
 283
 284 dnl set license and copyright notice
 285 GST_LICENSE="LGPL"
 286 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 287 AC_SUBST(GST_LICENSE)
 288
 289 dnl set location of plugin directory
 290 AG_GST_SET_PLUGINDIR
 291
 292 dnl set release date/time
 293 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 294   ["${srcdir}/gst-plugins-good.doap"],
 295   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 296
 297 dnl define an ERROR_CFLAGS Makefile variable
 298 dnl -Wundef: too many broken headers
 299 dnl -Waggregate-return: causes problems with ObjC code like in osxvideosink
 300 AG_GST_SET_ERROR_CFLAGS($GST_GIT, [
 301         -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 302         -Wwrite-strings -Wold-style-definition
 303         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 304         -Wnested-externs ])
 305
 306 dnl define an ERROR_CXXFLAGS Makefile variable
 307 AG_GST_SET_ERROR_CXXFLAGS($GST_GIT, [
 308         -Wmissing-declarations -Wredundant-decls
 309         -Wwrite-strings
 310         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar ])
 311
 312 dnl define correct level for debugging messages
 313 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 314
 315 dnl used in examples
 316 AG_GST_DEFAULT_ELEMENTS
 317
 318 dnl *** plug-ins to include ***
 319
 320 dnl these are all the gst plug-ins, compilable without additional libs
 321 dnl videofilter is at the top because others depend on it
 322 AG_GST_CHECK_PLUGIN(videofilter)
 323 AG_GST_CHECK_PLUGIN(alpha)
 324 AG_GST_CHECK_PLUGIN(apetag)
 325 AG_GST_CHECK_PLUGIN(audiofx)
 326 AG_GST_CHECK_PLUGIN(audioparsers)
 327 AG_GST_CHECK_PLUGIN(auparse)
 328 AG_GST_CHECK_PLUGIN(autodetect)
 329 AG_GST_CHECK_PLUGIN(avi)
 330 AG_GST_CHECK_PLUGIN(cutter)
 331 AG_GST_CHECK_PLUGIN(debugutils)
 332 AG_GST_CHECK_PLUGIN(deinterlace)
 333 AG_GST_CHECK_PLUGIN(effectv)
 334 AG_GST_CHECK_PLUGIN(equalizer)
 335 AG_GST_CHECK_PLUGIN(flv)
 336 AG_GST_CHECK_PLUGIN(id3demux)
 337 AG_GST_CHECK_PLUGIN(icydemux)
 338 AG_GST_CHECK_PLUGIN(interleave)
 339 AG_GST_CHECK_PLUGIN(flx)
 340 AG_GST_CHECK_PLUGIN(goom)
 341 AG_GST_CHECK_PLUGIN(goom2k1)
 342 AG_GST_CHECK_PLUGIN(imagefreeze)
 343 AG_GST_CHECK_PLUGIN(law)
 344 AG_GST_CHECK_PLUGIN(level)
 345 AG_GST_CHECK_PLUGIN(matroska)
 346 AG_GST_CHECK_PLUGIN(monoscope)
 347 AG_GST_CHECK_PLUGIN(multifile)
 348 AG_GST_CHECK_PLUGIN(multipart)
 349 AG_GST_CHECK_PLUGIN(quicktime)
 350 AG_GST_CHECK_PLUGIN(replaygain)
 351 AG_GST_CHECK_PLUGIN(rtp)
 352 AG_GST_CHECK_PLUGIN(rtpmanager)
 353 AG_GST_CHECK_PLUGIN(rtsp)
 354 AG_GST_CHECK_PLUGIN(shapewipe)
 355 AG_GST_CHECK_PLUGIN(smpte)
 356 AG_GST_CHECK_PLUGIN(spectrum)
 357 AG_GST_CHECK_PLUGIN(udp)
 358 AG_GST_CHECK_PLUGIN(videobox)
 359 AG_GST_CHECK_PLUGIN(videocrop)
 360 AG_GST_CHECK_PLUGIN(videomixer)
 361 AG_GST_CHECK_PLUGIN(wavenc)
 362 AG_GST_CHECK_PLUGIN(wavparse)
 363 AG_GST_CHECK_PLUGIN(y4m)
 364
 365 dnl *** checks for socket and nsl libraries ***
 366 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 367
 368 dnl disable gst plugins we might not be able to build on this
 369 dnl platform: udp and rtsp (ugly but minimally invasive)
 370 dnl FIXME: maybe move to sys
 371 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 372 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 373
 374 if test "x$HAVE_SYS_SOCKET_H" != "xyes" -a "x$HAVE_WINSOCK2_H" != "xyes"; then
 375   AG_GST_DISABLE_PLUGIN(udp)
 376   AG_GST_DISABLE_PLUGIN(rtsp)
 377 fi
 378
 379 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 380   WIN32_LIBS="-lws2_32"
 381   AC_SUBST(WIN32_LIBS)
 382 fi
 383
 384 dnl disable experimental plug-ins
 385 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 386   AG_GST_DISABLE_PLUGIN(monoscope)
 387 fi
 388
 389 dnl *** sys plug-ins ***
 390
 391 echo
 392 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 393 echo
 394
 395 dnl DirectSound
 396 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 397 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 398   HAVE_DIRECTSOUND="no"
 399   save_CFLAGS="$CFLAGS"
 400   save_LDFLAGS="$LDFLAGS"
 401   save_LIBS="$LIBS"
 402   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 403   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 404   LIBS="$LIBS -ldsound -ldxerr9 -luser32"
 405   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 406   AC_LINK_IFELSE([
 407 #include <windows.h>
 408 #include <dxerr9.h>
 409 #include <dsound.h>
 410
 411 int main ()
 412 {
 413   DXGetErrorString9 (0);
 414   DirectSoundCreate(NULL, NULL, NULL);
 415
 416   return 0;
 417 }
 418 ],
 419     [HAVE_DIRECTSOUND="yes"],
 420     [HAVE_DIRECTSOUND="no"])
 421   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 422   CFLAGS=$save_CFLAGS
 423   LDFLAGS=$save_LDFLAGS
 424   LIBS=$save_LIBS
 425
 426   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 427     dnl this is much more than we want
 428     DIRECTSOUND_LIBS="-ldsound -ldxerr9 -luser32"
 429     AC_SUBST(DIRECTSOUND_CFLAGS)
 430     AC_SUBST(DIRECTSOUND_LDFLAGS)
 431     AC_SUBST(DIRECTSOUND_LIBS)
 432   fi
 433   AC_SUBST(HAVE_DIRECTSOUND)
 434 ])
 435
 436 dnl *** OSS audio *** (Linux, *BSD)
 437 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 438 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 439  HAVE_OSS="yes"
 440 dnl Linux and newer BSD versions :
 441  AC_CHECK_HEADER(sys/soundcard.h, [
 442    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 443    ] , [
 444 dnl Some old BSD versions and also newer OpenBSD versions :
 445    AC_CHECK_HEADER(soundcard.h, [
 446      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 447      ], [
 448   dnl Some old BSD versions :
 449      AC_CHECK_HEADER(machine/soundcard.h, [
 450        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 451          [Define if OSS includes are in /machine/])
 452        ], [
 453        HAVE_OSS="no"
 454      ])
 455    ])
 456  ])
 457 ])
 458
 459 dnl *** oss4 ***
 460 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS4, true)
 461 AG_GST_CHECK_FEATURE(OSS4, [Open Sound System 4], oss4, [
 462   AC_MSG_CHECKING([Checking if we can build the OSS4 elements])
 463   AC_CHECK_HEADERS([fcntl.h sys/ioctl.h sys/stat.h sys/types.h],
 464       [test -z "$OSS4_MISSING_HEADER" && HAVE_OSS4="yes"],
 465       [OSS4_MISSING_HEADER="yes";HAVE_OSS4="no"])
 466 ])
 467
 468 dnl *** Sun Audio ***
 469 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 470 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 471   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 472 ])
 473
 474 dnl *** OSX Audio ***
 475 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 476 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 477   AC_CHECK_HEADER(CoreAudio/CoreAudio.h, HAVE_OSX_AUDIO="yes", HAVE_OSX_AUDIO="no")
 478 ])
 479
 480 dnl *** OS X video ***
 481 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 482 HAVE_OSX_VIDEO="no"
 483 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 484   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 485 ])
 486 dnl in case header OpenGL/gl.h is found on other platforms
 487 case "$host" in
 488   *-*darwin*)
 489     dnl do nothing
 490     ;;
 491   *)
 492     HAVE_OSX_VIDEO="no"
 493     ;;
 494 esac
 495
 496
 497 dnl *** Video 4 Linux 2 ***
 498 dnl for information about the header/define, see sys/v4l2/gstv4l2element.h
 499 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 500 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 501 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], v4l2src, [
 502   AC_MSG_CHECKING([Checking for up to date v4l2 installation])
 503   AC_TRY_COMPILE([
 504 #include <sys/types.h>
 505 #ifdef __sun /* Solaris */
 506 #include <sys/types.h>
 507 #include <sys/videodev2.h>
 508 #else /* Linux */
 509 #include <linux/types.h>
 510 #define _LINUX_TIME_H
 511 #define __user
 512 #include <linux/videodev2.h>
 513 #endif
 514 #if defined(V4L2_MAJOR_VERSION) || defined(V4L2_MINOR_VERSION)
 515 #error too early v4l2 version or no v4l2 at all
 516 #endif
 517     ], [
 518 return 0;
 519     ], [
 520       HAVE_GST_V4L2="yes"
 521       AC_MSG_RESULT(yes)
 522     ], [
 523       HAVE_GST_V4L2="no"
 524       AC_MSG_RESULT(no)
 525
 526       HAVE_VIDEODEV=no
 527       AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_VIDEODEV=yes ],
 528       [
 529         AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_VIDEODEV=yes ])
 530       ])
 531
 532       if test "x$HAVE_VIDEODEV" = "xyes"; then
 533         AC_MSG_WARN([video4linux2 headers were found, but they're old.])
 534         AC_MSG_WARN([Please update v4l2 to compile the v4l2 plugins])
 535       else
 536         AC_MSG_WARN([video4linux2 was not found])
 537       fi
 538     ])
 539
 540   if [ test x$HAVE_GST_V4L2 = xyes ]; then
 541     dnl check for missing v4l2_buffer declaration (see #135919)
 542     MISSING_DECL=0
 543     AC_MSG_CHECKING(struct v4l2_buffer declaration)
 544     AC_TRY_COMPILE([
 545 #include <sys/types.h>
 546 #ifdef __sun /* Solaris */
 547 #include <sys/types.h>
 548 #include <sys/videodev2.h>
 549 #else /* Linux */
 550 #include <linux/types.h>
 551 #define _LINUX_TIME_H
 552 #define __user
 553 #include <linux/videodev2.h>
 554 #endif
 555     ],[
 556 struct v4l2_buffer buf;
 557 buf.index = 0;
 558 return 0;
 559     ], [ AC_MSG_RESULT(yes) ], [ MISSING_DECL=1 && AC_MSG_RESULT(no) ])
 560     if [ test x$MISSING_DECL = x1 ]; then
 561       AC_DEFINE(GST_V4L2_MISSING_BUFDECL, 1, [struct v4l2_buffer missing])
 562     fi
 563
 564     dnl check for XOverlay libraries
 565     AG_GST_CHECK_XV
 566   fi
 567 ])
 568
 569 # Optional gudev for device probing
 570 AC_ARG_WITH([gudev],
 571   AC_HELP_STRING([--with-gudev],
 572     [device detection with gudev]),
 573   [],
 574   [with_gudev=check])
 575 if test x$HAVE_GST_V4L2 = xyes; then
 576   if test x$with_gudev != xno; then
 577       PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 143 ],
 578           [ have_gudev=yes
 579             AC_DEFINE(HAVE_GUDEV, 1,
 580                [Whether gudev is available for device detection])
 581             AC_DEFINE([G_UDEV_API_IS_SUBJECT_TO_CHANGE], 1, [I know the API is subject to change.])
 582           ], [
 583           have_gudev=no
 584           ])
 585   else
 586     have_gudev=no
 587   fi
 588 fi
 589 AC_SUBST(GUDEV_CFLAGS)
 590 AC_SUBST(GUDEV_LIBS)
 591
 592 # Make libv4l2 non-automagic
 593 AC_ARG_WITH([libv4l2],
 594   AC_HELP_STRING([--with-libv4l2],
 595     [support video buffer conversion using libv4l2]),
 596   [],
 597   [with_libv4l2=check])
 598 if test x$HAVE_GST_V4L2 = xyes; then
 599   if test x$with_libv4l2 != xno; then
 600       PKG_CHECK_MODULES(LIBV4L2, libv4l2,
 601           [ have_libv4l2=yes
 602             AC_DEFINE(HAVE_LIBV4L2, 1,
 603                 [Whether libv4l2 is available for video buffer conversion])
 604           ], [
 605           have_libv4l2=no
 606           ])
 607   else
 608     have_libv4l2=no
 609   fi
 610 fi
 611
 612 dnl Check for X11
 613 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 614 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 615                   [ximagesrc], [
 616   AC_PATH_XTRA
 617
 618   dnl now try to find the HEADER
 619   ac_cflags_save="$CFLAGS"
 620   ac_cppflags_save="$CPPFLAGS"
 621   CFLAGS="$CFLAGS $X_CFLAGS"
 622   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 623   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 624
 625   if test "x$HAVE_X" = "xno"
 626   then
 627     AC_MSG_NOTICE([cannot find X11 development files])
 628   else
 629     dnl this is much more than we want
 630     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 631     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 632     dnl it does not add the libs; therefore we add them here
 633     X_LIBS="$X_LIBS -lX11"
 634     AC_SUBST(X_CFLAGS)
 635     AC_SUBST(X_LIBS)
 636
 637     dnl check for Xfixes
 638     PKG_CHECK_MODULES(XFIXES, xfixes, HAVE_XFIXES="yes", HAVE_XFIXES="no")
 639     if test "x$HAVE_XFIXES" = "xyes"
 640     then
 641         XFIXES_CFLAGS="-DHAVE_XFIXES $XFIXES_CFLAGS"
 642     fi
 643     AC_SUBST(XFIXES_LIBS)
 644     AC_SUBST(XFIXES_CFLAGS)
 645
 646     dnl check for Xdamage
 647     PKG_CHECK_MODULES(XDAMAGE, xdamage, HAVE_XDAMAGE="yes", HAVE_XDAMAGE="no")
 648     if test "x$HAVE_XDAMAGE" = "xyes"
 649     then
 650         XDAMAGE_CFLAGS="-DHAVE_XDAMAGE $XDAMAGE_CFLAGS"
 651     fi
 652     AC_SUBST(XDAMAGE_LIBS)
 653     AC_SUBST(XDAMAGE_CFLAGS)
 654   fi
 655   AC_SUBST(HAVE_X)
 656   CFLAGS="$ac_cflags_save"
 657   CPPFLAGS="$ac_cppflags_save"
 658 ])
 659
 660 dnl FIXME: this should be rolled into the test above, it's just an additional
 661 dnl feature of the ximagesrc plug-in
 662 dnl This is the same as in gst-plugins-base
 663 dnl check for X Shm
 664 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 665 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 666   if test x$HAVE_X = xyes; then
 667     AC_CHECK_LIB(Xext, XShmAttach,
 668                  HAVE_XSHM="yes", HAVE_XSHM="no",
 669                  $X_LIBS)
 670     if test "x$HAVE_XSHM" = "xyes"; then
 671       XSHM_LIBS="-lXext"
 672     else
 673       dnl On AIX, it is in XextSam instead, but we still need -lXext
 674       AC_CHECK_LIB(XextSam, XShmAttach,
 675                    HAVE_XSHM="yes", HAVE_XSHM="no",
 676                    $X_LIBS)
 677       if test "x$HAVE_XSHM" = "xyes"; then
 678         XSHM_LIBS="-lXext -lXextSam"
 679       fi
 680     fi
 681   fi
 682 ], ,[
 683   AC_SUBST(HAVE_XSHM)
 684   AC_SUBST(XSHM_LIBS)
 685 ])
 686
 687 dnl for V4L2, we also need to know if we have XVIDEO
 688 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 689 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 690                   [], [
 691   AG_GST_CHECK_XV
 692 ])
 693
 694 dnl *** ext plug-ins ***
 695 dnl keep this list sorted alphabetically !
 696
 697 if test "x$BUILD_EXTERNAL" = "xyes"; then
 698
 699 echo
 700 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 701 echo
 702
 703 dnl *** aalib ***
 704 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 705 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 706   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 707   AS_SCRUB_INCLUDE(AALIB_CFLAGS)
 708 ])
 709
 710 dnl *** annodex ***
 711 translit(dnm, m, l) AM_CONDITIONAL(USE_ANNODEX, true)
 712 AG_GST_CHECK_FEATURE(ANNODEX, [XML library], annodex, [
 713   AG_GST_PKG_CHECK_MODULES(ANNODEX, libxml-2.0 >= 2.4.9)
 714 ])
 715
 716 dnl *** cairo ***
 717 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 718 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering], cairo, [
 719   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.0.0)
 720 ])
 721
 722 dnl *** cairo-gobject ***
 723 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO_GOBJECT, true)
 724 AG_GST_CHECK_FEATURE(CAIRO_GOBJECT,
 725   [Cairo graphics rendering gobject bindings], cairooverlay, [
 726   AG_GST_PKG_CHECK_MODULES(CAIRO_GOBJECT, cairo-gobject >= 1.10.0)
 727 ])
 728
 729 dnl **** ESound ****
 730 translit(dnm, m, l) AM_CONDITIONAL(USE_ESD, true)
 731 AG_GST_CHECK_FEATURE(ESD, [ESounD sound daemon], esdsink, [
 732   AG_GST_PKG_CHECK_MODULES(ESD, esound >= 0.2.12)
 733   if test $HAVE_ESD = no
 734   then
 735     AM_PATH_ESD(0.2.12, HAVE_ESD="yes")
 736     AS_SCRUB_INCLUDE(ESD_CFLAGS)
 737   fi
 738 ])
 739
 740 dnl *** FLAC ***
 741 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 742 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 743   AG_GST_PKG_CHECK_MODULES(FLAC, flac >= 1.1.4)
 744 ])
 745
 746 dnl *** GConf ***
 747 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONF, true)
 748 AG_GST_CHECK_FEATURE(GCONF, [GConf libraries], gconfelements, [
 749   AG_GST_PKG_CHECK_MODULES(GCONF, gconf-2.0)
 750 ])
 751
 752 dnl *** GDK pixbuf ***
 753 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 754 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 755   AG_GST_PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0 >= 2.8.0)
 756 ])
 757
 758 dnl *** HAL ***
 759 translit(dnm, m, l) AM_CONDITIONAL(USE_HAL, true)
 760 AG_GST_CHECK_FEATURE(HAL, [HAL libraries], halelements, [
 761   AG_GST_PKG_CHECK_MODULES(HAL, [hal >= 0.5.6, dbus-1 >= 0.32])
 762 ])
 763
 764 dnl *** Jack ***
 765 translit(dnm, m, l) AM_CONDITIONAL(USE_JACK, true)
 766 AG_GST_CHECK_FEATURE(JACK, Jack, jack, [
 767   PKG_CHECK_MODULES(JACK, jack >= 0.99.10, HAVE_JACK="yes", HAVE_JACK="no")
 768   AC_SUBST(JACK_CFLAGS)
 769   AC_SUBST(JACK_LIBS)
 770
 771   AG_GST_PKG_CHECK_MODULES(JACK_0_120_1, jack >= 0.120.1 jack < 1.0)
 772   if test x$HAVE_JACK_0_120_1 = xyes; then
 773     AC_DEFINE(HAVE_JACK_0_120_1, 1, [defined if jack >= 0.120.1 is available])
 774   fi
 775   AG_GST_PKG_CHECK_MODULES(JACK_1_9_7, jack >= 1.9.7)
 776   if test x$HAVE_JACK_1_9_7 = xyes; then
 777     AC_DEFINE(HAVE_JACK_1_9_7, 1, [defined if jack >= 1.9.7 is available])
 778   fi
 779
 780 ])
 781
 782 dnl *** jpeg ***
 783 dnl FIXME: we could use header checks here as well IMO
 784 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 785 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 786   AC_ARG_WITH(jpeg-mmx,
 787     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 788   OLD_LIBS="$LIBS"
 789   if test x$with_jpeg_mmx != x; then
 790     LIBS="$LIBS -L$with_jpeg_mmx"
 791   fi
 792   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 793   JPEG_LIBS="$LIBS -ljpeg-mmx"
 794   LIBS="$OLD_LIBS"
 795   if test x$HAVE_JPEG != xyes; then
 796     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 797     JPEG_LIBS="-ljpeg"
 798   fi
 799   AC_SUBST(JPEG_LIBS)
 800 ])
 801
 802 dnl *** libcaca ***
 803 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 804 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 805   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 806   dnl only newer versions of libcaca ship caca.pc, so try caca-config as well
 807   if test "x$HAVE_LIBCACA" != "xyes"; then
 808     AG_GST_CHECK_CONFIGPROG(LIBCACA, caca-config)
 809     dnl see if it compilation works too, might not if we are cross-compiling
 810     if test "x$HAVE_LIBCACA" = "xyes"; then
 811       AC_CHECK_LIB([caca], [caca_init], [HAVE_LIBCACA=yes],
 812                    [HAVE_LIBCACA=no], [$LIBCACA_LIBS])
 813     fi
 814   fi
 815 ])
 816
 817 dnl *** libdv ***
 818 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 819 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 820   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 821 ])
 822
 823 dnl *** libpng ***
 824 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 825 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 826   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng >= 1.2)
 827 ])
 828
 829 dnl *** pulseaudio ***
 830 translit(dnm, m, l) AM_CONDITIONAL(USE_PULSE, true)
 831 AG_GST_CHECK_FEATURE(PULSE, [pulseaudio plug-in], pulseaudio, [
 832
 833   dnl used in ext/pulse/pulseutil.c
 834   AC_CHECK_HEADERS([process.h])
 835
 836   AG_GST_PKG_CHECK_MODULES(PULSE, libpulse >= 0.9.10)
 837   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_11, libpulse >= 0.9.11)
 838   if test x$HAVE_PULSE_0_9_11 = xyes; then
 839     AC_DEFINE(HAVE_PULSE_0_9_11, 1, [defined if pulseaudio >= 0.9.11 is available])
 840   fi
 841   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_12, libpulse >= 0.9.12)
 842   if test x$HAVE_PULSE_0_9_12 = xyes; then
 843     AC_DEFINE(HAVE_PULSE_0_9_12, 1, [defined if pulseaudio >= 0.9.12 is available])
 844   fi
 845   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_13, libpulse >= 0.9.13)
 846   if test x$HAVE_PULSE_0_9_13 = xyes; then
 847     AC_DEFINE(HAVE_PULSE_0_9_13, 1, [defined if pulseaudio >= 0.9.13 is available])
 848   fi
 849   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_15, libpulse >= 0.9.15)
 850   if test x$HAVE_PULSE_0_9_15 = xyes; then
 851     AC_DEFINE(HAVE_PULSE_0_9_15, 1, [defined if pulseaudio >= 0.9.15 is available])
 852   fi
 853   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_16, libpulse >= 0.9.16)
 854   if test x$HAVE_PULSE_0_9_16 = xyes; then
 855     AC_DEFINE(HAVE_PULSE_0_9_16, 1, [defined if pulseaudio >= 0.9.16 is available])
 856   fi
 857   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_20, libpulse >= 0.9.20)
 858   if test x$HAVE_PULSE_0_9_20 = xyes; then
 859     AC_DEFINE(HAVE_PULSE_0_9_20, 1, [defined if pulseaudio >= 0.9.20 is available])
 860   fi
 861 ])
 862
 863 dnl *** dv1394 ***
 864 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 865 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 866   dnl first test for libraw1394 >= 2.0.0
 867   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 2.0.0)
 868   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 869   dnl now see how far we got
 870   if test x$HAVE_RAW1394 = xyes && \
 871      test x$HAVE_LIBIEC61883 = xyes; then
 872        AG_GST_CHECK_LIBHEADER(AVC1394,
 873         avc1394, avc1394_send_command, $RAW1394_LIBS,
 874         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 875        AG_GST_CHECK_LIBHEADER(ROM1394,
 876         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 877         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 878        if test x$HAVE_AVC1394 = xyes && \
 879           test x$HAVE_AVC1394 = xyes && \
 880           test x$HAVE_ROM1394 = xyes; then
 881           HAVE_DV1394=yes
 882           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 883           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 884           AC_SUBST(DV1394_CFLAGS)
 885           AC_SUBST(DV1394_LIBS)
 886         fi
 887   else
 888        if test x$HAVE_RAW1394 = xno; then
 889           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 890           AG_GST_CHECK_LIBHEADER(AVC1394,
 891            avc1394, avc1394_send_command, $RAW1394_LIBS,
 892            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 893           AG_GST_CHECK_LIBHEADER(ROM1394,
 894            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 895            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 896           if test x$HAVE_RAW1394 = xyes && \
 897              test x$HAVE_AVC1394 = xyes && \
 898              test x$HAVE_ROM1394 = xyes; then
 899              HAVE_DV1394=yes
 900              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 901              DV1394_CFLAGS="$RAW1394_CFLAGS"
 902              if test x$HAVE_LIBIEC61883 = xyes; then
 903                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 904                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 905              fi
 906              AC_SUBST(DV1394_CFLAGS)
 907              AC_SUBST(DV1394_LIBS)
 908            fi
 909          fi
 910   fi
 911 ])
 912 AM_CONDITIONAL(USE_LIBIEC61883, [ test "x${HAVE_LIBIEC61883}" = xyes ] )
 913
 914 dnl *** shout2 ***
 915 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 916 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 917   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 918   if test $HAVE_SHOUT2 = no
 919   then
 920     AM_PATH_SHOUT2(HAVE_SHOUT2="yes")
 921     AC_SUBST(SHOUT2_CFLAGS)
 922     AC_SUBST(SHOUT2_LIBS)
 923   fi
 924 ])
 925
 926 dnl *** soup ***
 927 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUP, true)
 928 AG_GST_CHECK_FEATURE(SOUP, [soup http client plugin (2.4)], souphttpsrc, [
 929   PKG_CHECK_MODULES(SOUP, libsoup-gnome-2.4 >= 2.3.2, [
 930     HAVE_SOUP="yes"
 931     AC_DEFINE(HAVE_LIBSOUP_GNOME, 1, [soup gnome integration])
 932   ],[
 933     PKG_CHECK_MODULES(SOUP, libsoup-2.4 >= 2.26, HAVE_SOUP="yes", [
 934       HAVE_SOUP="no"
 935     ])
 936   ])
 937   AC_SUBST(SOUP_CFLAGS)
 938   AC_SUBST(SOUP_LIBS)
 939 ])
 940
 941 dnl *** speex >= 1.0.4 or >= 1.1.5 ***
 942 dnl   1.1.4 and earlier were not API/ABI compatible with 1.0
 943 dnl   1.1.6 is the first to use a .pc/pkg-config file ***
 944 dnl   speex_jitter.h is 1.1.x only
 945 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 946 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 947   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 948   if test $HAVE_SPEEX = no
 949   then
 950     AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_bits_init, , speex/speex.h, [
 951       AC_CHECK_HEADER(speex/speex_jitter.h, [
 952         dnl speex 1.1.x :
 953         AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_encode_int, , speex/speex.h, [
 954           dnl speex 1.1.5 or + :
 955           HAVE_SPEEX="yes"
 956           SPEEX_LIBS="-lspeex"
 957           AC_SUBST(SPEEX_CFLAGS)
 958           AC_SUBST(SPEEX_LIBS)
 959         ],[
 960           HAVE_SPEEX="no"
 961         ])
 962       ],[
 963         dnl speex 1.0.x :
 964           AC_CHECK_DECL(SPEEX_GET_LOOKAHEAD, [
 965             dnl speex 1.0.4
 966             HAVE_SPEEX="yes"
 967             SPEEX_LIBS="-lspeex"
 968             AC_SUBST(SPEEX_CFLAGS)
 969             AC_SUBST(SPEEX_LIBS)
 970
 971             AC_DEFINE_UNQUOTED(SPEEX_1_0, 1,
 972               [defined if speex 1.0.x API detected])
 973         ],[
 974             HAVE_SPEEX="no"
 975             AC_MSG_NOTICE(You need at least 1.0.4 to compile the speex plugin)
 976         ], [
 977 #include <speex/speex.h>
 978         ])
 979       ])
 980     ])
 981   fi
 982 ])
 983
 984 dnl *** taglib ***
 985 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 986 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 987   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.5)
 988   if test "x$HAVE_CXX" != "xyes"; then
 989     USE_TAGLIB=false
 990     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 991   else
 992     dnl work around bug in taglib 1.5 headers, remove once there is a 1.6
 993     AS_CXX_COMPILER_FLAG([-Wno-attributes], [
 994         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS -Wno-attributes"
 995       ], [
 996         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS"
 997     ])
 998     AC_SUBST(TAGLIB_CXXFLAGS)
 999   fi
1000 ])
1001
1002 dnl *** wavpack ***
1003 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
1004 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
1005   PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.40.0, HAVE_WAVPACK=yes, [
1006     PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.20, [
1007       HAVE_WAVPACK=yes
1008       AC_DEFINE(WAVPACK_OLD_API, 1, [old wavpack API])
1009     ],[
1010       HAVE_WAVPACK=no
1011     ])
1012   ])
1013   AC_SUBST(WAVPACK_CFLAGS)
1014   AC_SUBST(WAVPACK_LIBS)
1015 ])
1016
1017 dnl *** qtdemux & id3demux & matroska prefer to have zlib ***
1018 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
1019 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for id3demux/qtdemux/matroska],, [
1020   AG_GST_CHECK_LIBHEADER(ZLIB,
1021     z, uncompress,, zlib.h, [
1022     HAVE_ZLIB="yes"
1023     ZLIB_LIBS="-lz"
1024     AC_SUBST(ZLIB_LIBS)
1025   ])
1026 ])
1027
1028 dnl *** matroska prefers to have bz2 ***
1029 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
1030 AG_GST_CHECK_FEATURE(BZ2, [bz2 library for matroska ],, [
1031   AG_GST_CHECK_LIBHEADER(BZ2, bz2, BZ2_bzCompress, ,bzlib.h, BZ2_LIBS="-lbz2")
1032   AC_SUBST(BZ2_LIBS)
1033 ])
1034
1035 else
1036
1037 dnl not building plugins with external dependencies,
1038 dnl but we still need to set the conditionals
1039 AM_CONDITIONAL(USE_AALIB, false)
1040 AM_CONDITIONAL(USE_ANNODEX, false)
1041 AM_CONDITIONAL(USE_BZ2, false)
1042 AM_CONDITIONAL(USE_CAIRO, false)
1043 AM_CONDITIONAL(USE_CAIRO_GOBJECT, false)
1044 AM_CONDITIONAL(USE_DIRECTSOUND, false)
1045 AM_CONDITIONAL(USE_DV1394, false)
1046 AM_CONDITIONAL(USE_ESD, false)
1047 AM_CONDITIONAL(USE_FLAC, false)
1048 AM_CONDITIONAL(USE_GCONF, false)
1049 AM_CONDITIONAL(USE_GCONFTOOL, false)
1050 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
1051 AM_CONDITIONAL(USE_GST_V4L2, false)
1052 AM_CONDITIONAL(USE_HAL, false)
1053 AM_CONDITIONAL(USE_JACK, false)
1054 AM_CONDITIONAL(USE_JPEG, false)
1055 AM_CONDITIONAL(USE_LIBCACA, false)
1056 AM_CONDITIONAL(USE_LIBDV, false)
1057 AM_CONDITIONAL(USE_LIBIEC61883, false)
1058 AM_CONDITIONAL(USE_LIBPNG, false)
1059 AM_CONDITIONAL(USE_OSS, false)
1060 AM_CONDITIONAL(USE_OSS4, false)
1061 AM_CONDITIONAL(USE_OSX_AUDIO, false)
1062 AM_CONDITIONAL(USE_OSX_VIDEO, false)
1063 AM_CONDITIONAL(USE_PULSE, false)
1064 AM_CONDITIONAL(USE_SHOUT2, false)
1065 AM_CONDITIONAL(USE_SOUP, false)
1066 AM_CONDITIONAL(USE_SPEEX, false)
1067 AM_CONDITIONAL(USE_SUNAUDIO, false)
1068 AM_CONDITIONAL(USE_TAGLIB, false)
1069 AM_CONDITIONAL(USE_WAVPACK, false)
1070 AM_CONDITIONAL(USE_X, false)
1071 AM_CONDITIONAL(USE_XSHM, false)
1072 AM_CONDITIONAL(USE_XVIDEO, false)
1073 AM_CONDITIONAL(USE_ZLIB, false)
1074
1075 fi dnl of EXT plugins
1076
1077 dnl *** finalize CFLAGS, LDFLAGS, LIBS
1078
1079 dnl Overview:
1080 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
1081 dnl GST_*:              flags shared by all built objects
1082 dnl GST_ALL_LDFLAGS:    linker flags shared by all
1083 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
1084 dnl GST_LT_LDFLAGS:     library versioning of our libraries
1085 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
1086
1087 dnl GST_OPTION_CFLAGS
1088 if test "x$USE_DEBUG" = xyes; then
1089    PROFILE_CFLAGS="-g"
1090 fi
1091 AC_SUBST(PROFILE_CFLAGS)
1092
1093 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
1094   dnl Define _only_ for git (not pre-releases or releases)
1095   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
1096 else
1097   DEPRECATED_CFLAGS=""
1098 fi
1099 AC_SUBST(DEPRECATED_CFLAGS)
1100
1101 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
1102 dnl at make time with e.g. make ERROR_CFLAGS=""
1103 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1104 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1105 AC_SUBST(GST_OPTION_CFLAGS)
1106 AC_SUBST(GST_OPTION_CXXFLAGS)
1107
1108 dnl our libraries need to be versioned correctly
1109 AC_SUBST(GST_LT_LDFLAGS)
1110
1111 dnl FIXME: do we want to rename to GST_ALL_* ?
1112 dnl prefer internal headers to already installed ones
1113 dnl also add builddir include for enumtypes and marshal
1114 dnl add ERROR_CFLAGS, but overridable
1115 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS)"
1116 GST_CFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
1117 AC_SUBST(GST_CFLAGS)
1118 AC_SUBST(GST_CXXFLAGS)
1119 AC_SUBST(GST_LIBS)
1120
1121 dnl LDFLAGS really should only contain flags, not libs - they get added before
1122 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1123 GST_ALL_LDFLAGS="-no-undefined"
1124 AC_SUBST(GST_ALL_LDFLAGS)
1125
1126 dnl this really should only contain flags, not libs - they get added before
1127 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1128 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
1129 AC_SUBST(GST_PLUGIN_LDFLAGS)
1130
1131 dnl *** output files ***
1132
1133 dnl keep this alphabetic per directory, please
1134 AC_CONFIG_FILES(
1135 Makefile
1136 gst/Makefile
1137 gst/alpha/Makefile
1138 gst/apetag/Makefile
1139 gst/audiofx/Makefile
1140 gst/audioparsers/Makefile
1141 gst/auparse/Makefile
1142 gst/autodetect/Makefile
1143 gst/avi/Makefile
1144 gst/cutter/Makefile
1145 gst/deinterlace/Makefile
1146 gst/debugutils/Makefile
1147 gst/effectv/Makefile
1148 gst/equalizer/Makefile
1149 gst/flv/Makefile
1150 gst/id3demux/Makefile
1151 gst/icydemux/Makefile
1152 gst/imagefreeze/Makefile
1153 gst/interleave/Makefile
1154 gst/goom/Makefile
1155 gst/goom2k1/Makefile
1156 gst/law/Makefile
1157 gst/level/Makefile
1158 gst/matroska/Makefile
1159 gst/monoscope/Makefile
1160 gst/multifile/Makefile
1161 gst/multipart/Makefile
1162 gst/quicktime/Makefile
1163 gst/replaygain/Makefile
1164 gst/rtp/Makefile
1165 gst/rtpmanager/Makefile
1166 gst/rtsp/Makefile
1167 gst/shapewipe/Makefile
1168 gst/smpte/Makefile
1169 gst/spectrum/Makefile
1170 gst/udp/Makefile
1171 gst/videobox/Makefile
1172 gst/videocrop/Makefile
1173 gst/videofilter/Makefile
1174 gst/videomixer/Makefile
1175 gst/wavenc/Makefile
1176 gst/wavparse/Makefile
1177 gst/flx/Makefile
1178 gst/y4m/Makefile
1179 ext/Makefile
1180 ext/aalib/Makefile
1181 ext/annodex/Makefile
1182 ext/cairo/Makefile
1183 ext/dv/Makefile
1184 ext/esd/Makefile
1185 ext/flac/Makefile
1186 ext/gconf/Makefile
1187 ext/gdk_pixbuf/Makefile
1188 ext/hal/Makefile
1189 ext/jack/Makefile
1190 ext/jpeg/Makefile
1191 ext/libcaca/Makefile
1192 ext/libpng/Makefile
1193 ext/pulse/Makefile
1194 ext/raw1394/Makefile
1195 ext/shout2/Makefile
1196 ext/soup/Makefile
1197 ext/speex/Makefile
1198 ext/taglib/Makefile
1199 ext/wavpack/Makefile
1200 sys/Makefile
1201 sys/directsound/Makefile
1202 sys/oss/Makefile
1203 sys/oss4/Makefile
1204 sys/osxaudio/Makefile
1205 sys/osxvideo/Makefile
1206 sys/sunaudio/Makefile
1207 sys/v4l2/Makefile
1208 sys/waveform/Makefile
1209 sys/ximage/Makefile
1210 po/Makefile.in
1211 tests/Makefile
1212 tests/check/Makefile
1213 tests/examples/Makefile
1214 tests/examples/audiofx/Makefile
1215 tests/examples/cairo/Makefile
1216 tests/examples/equalizer/Makefile
1217 tests/examples/jack/Makefile
1218 tests/examples/level/Makefile
1219 tests/examples/pulse/Makefile
1220 tests/examples/rtp/Makefile
1221 tests/examples/shapewipe/Makefile
1222 tests/examples/spectrum/Makefile
1223 tests/examples/v4l2/Makefile
1224 tests/files/Makefile
1225 tests/icles/Makefile
1226 gconf/Makefile
1227 gconf/gstreamer.schemas
1228 common/Makefile
1229 common/m4/Makefile
1230 m4/Makefile
1231 docs/Makefile
1232 docs/plugins/Makefile
1233 docs/version.entities
1234 pkgconfig/Makefile
1235 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1236 gst-plugins-good.spec
1237 )
1238
1239 dnl Create the config.h file for Visual Studio builds
1240 dnl Beware of spaces and /'s in some of the shell variable contents.
1241 sed \
1242     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"\n\n#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
1243     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
1244     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
1245     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
1246     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
1247     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
1248     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
1249     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
1250     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
1251     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
1252     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
1253     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
1254     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
1255     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
1256     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
1257     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
1258     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
1259     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
1260     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
1261     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
1262     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1263     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1264     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1265     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
1266     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1267     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
1268     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1269     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1270     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1271     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.10"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.10"\n#endif/' \
1272     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
1273     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1274     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
1275     -e "s/.* DEFAULT_AUDIOSRC$/#define DEFAULT_AUDIOSRC \"audiotestsrc\"/" \
1276     -e "s/.* DEFAULT_VIDEOSRC$/#define DEFAULT_VIDEOSRC \"videotestsrc\"/" \
1277     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1278     config.h.in >win32/common/config.h-new
1279
1280 AC_OUTPUT
1281
1282 AG_GST_OUTPUT_PLUGINS
1283 ORC_OUTPUT
1284