configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/prerelease
   8 AC_INIT(GStreamer Base Plug-ins, 0.10.28.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-base)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use major.minor as a version
  41 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  42 dnl we override it here if we need to for the release candidate of new series
  43 GST_MAJORMINOR=0.10
  44 AC_SUBST(GST_MAJORMINOR)
  45
  46 dnl CURRENT, REVISION, AGE
  47 dnl - library source changed -> increment REVISION
  48 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  49 dnl - interfaces added -> increment AGE
  50 dnl - interfaces removed -> AGE = 0
  51 dnl sets GST_LT_LDFLAGS
  52 AS_LIBTOOL(GST, 19, 2, 19)
  53
  54 dnl FIXME: this macro doesn't actually work;
  55 dnl the generated libtool script has no support for the listed tags.
  56 dnl So this needs to be fixed first if we want to use this
  57 dnl AS_LIBTOOL_TAGS
  58
  59 AC_LIBTOOL_WIN32_DLL
  60 AM_PROG_LIBTOOL
  61
  62 dnl *** required versions of GStreamer stuff ***
  63 GST_REQ=0.10.28
  64
  65 dnl *** autotools stuff ****
  66
  67 dnl allow for different autotools
  68 AS_AUTOTOOLS_ALTERNATE
  69
  70 dnl Add parameters for aclocal
  71 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  72
  73 dnl set up gettext
  74 dnl the version check needs to stay here because autopoint greps for it
  75 AM_GNU_GETTEXT_VERSION([0.17])
  76 AM_GNU_GETTEXT([external])
  77 AG_GST_GETTEXT([gst-plugins-base-$GST_MAJORMINOR])
  78
  79 dnl *** check for arguments to configure ***
  80
  81 AG_GST_ARG_DEBUG
  82 AG_GST_ARG_PROFILING
  83 AG_GST_ARG_VALGRIND
  84 AG_GST_ARG_GCOV
  85
  86 AG_GST_ARG_EXAMPLES
  87
  88 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  89 AG_GST_ARG_WITH_PACKAGE_NAME
  90 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  91
  92 dnl let distro override plugin install helper path
  93 AC_ARG_WITH(install-plugins-helper,
  94   AC_HELP_STRING([--with-install-plugins-helper],
  95     [specify path of helper script to call to install plugins]),
  96   [
  97     case "${withval}" in
  98       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
  99       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 100       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
 101     esac
 102   ],
 103   [
 104     dnl Default value
 105     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 106   ]
 107 )
 108 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 109 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 110     [plugin install helper script])
 111 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 112
 113 AG_GST_ARG_WITH_PLUGINS
 114
 115 AG_GST_ARG_ENABLE_EXTERNAL
 116
 117 AG_GST_ARG_ENABLE_EXPERIMENTAL
 118
 119 dnl *** checks for platform ***
 120
 121 dnl * hardware/architecture *
 122
 123 dnl common/m4/gst-arch.m4
 124 dnl check CPU type
 125 AG_GST_ARCH
 126
 127 dnl check for large file support
 128 dnl affected plugins must include config.h
 129 AC_SYS_LARGEFILE
 130
 131 dnl *** checks for programs ***
 132
 133 dnl find a compiler
 134 AC_PROG_CC
 135 AC_PROG_CXX
 136
 137 dnl determine if c++ is available on this system
 138 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 139
 140 dnl determine c++ preprocessor
 141 dnl FIXME: do we need this ?
 142 AC_PROG_CXXCPP
 143
 144 dnl check if the compiler supports '-c' and '-o' options
 145 AM_PROG_CC_C_O
 146
 147 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 148 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 149
 150 dnl check for gobject-introspection
 151 GOBJECT_INTROSPECTION_CHECK([0.6.3])
 152
 153 dnl check for documentation tools
 154 GTK_DOC_CHECK([1.3])
 155 AS_PATH_PYTHON([2.1])
 156 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 157
 158 dnl *** checks for libraries ***
 159
 160 dnl libm, for sin() etc.
 161 AC_CHECK_LIBM
 162 AC_SUBST(LIBM)
 163
 164 dnl *** checks for header files ***
 165
 166 dnl check if we have ANSI C header files
 167 AC_HEADER_STDC
 168
 169 dnl used in gst/ffmpegcolorspace/mem.c
 170 dnl FIXME: could be fixed by redefining av_malloc and av_free to GLib's
 171 AC_CHECK_HEADERS([malloc.h])
 172
 173 ac_cppflags_save="$CPPFLAGS"
 174 CPPFLAGS="`$PKG_CONFIG --cflags libxml-2.0`"
 175 AC_COMPILE_IFELSE(
 176   AC_LANG_PROGRAM([
 177 #include <libxml/HTMLparser.h>
 178                      ],[
 179 #ifndef LIBXML_HTML_ENABLED
 180 #error libxml2 has no HTML support
 181 #endif /* LIBXML_HTML_ENABLED */
 182                    ]), HAVE_LIBXML_HTML="yes", HAVE_LIBXML_HTML="no")
 183 CPPFLAGS="$ac_cppflags_save"
 184 AM_CONDITIONAL(HAVE_LIBXML_HTML, test "x$HAVE_LIBXML_HTML" = "xyes")
 185
 186 dnl used in gst/tcp
 187 AC_CHECK_HEADERS([sys/socket.h],
 188   HAVE_SYS_SOCKET_H="yes", HAVE_SYS_SOCKET_H="no")
 189 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 190
 191 dnl used in gst-libs/gst/rtsp
 192 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 193 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 194   WIN32_LIBS="-lws2_32"
 195   AC_SUBST(WIN32_LIBS)
 196 fi
 197
 198 dnl check for hstrerror, for gst-libs/gst/rtsp
 199 save_libs="$LIBS"
 200 AC_CHECK_FUNC(hstrerror, ,
 201     AC_CHECK_LIB(resolv, hstrerror, ,
 202         [AC_DEFINE(NO_HSTRERROR, 1,
 203              [Define if you have no native hstrerror() function.])]))
 204 HSTRERROR_LIBS=$LIBS
 205 AC_SUBST(HSTRERROR_LIBS)
 206 LIBS="$save_libs"
 207
 208 dnl used in gst-libs/gst/pbutils and associated unit test
 209 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h])
 210
 211 dnl ffmpegcolorspace includes _stdint.h
 212 dnl also, Windows does not have long long
 213 AX_CREATE_STDINT_H
 214
 215 dnl *** checks for functions ***
 216 AC_CHECK_FUNCS([localtime_r gmtime_r])
 217
 218 dnl *** checks for math functions ***
 219 LIBS_SAVE=$LIBS
 220 LIBS="$LIBS $LIBM"
 221 AC_CHECK_FUNCS(cbrt)
 222 LIBS=$LIBS_SAVE
 223
 224 dnl *** checks for types/defines ***
 225
 226 dnl Check for FIONREAD ioctl declaration
 227 dnl used in gst/tcp
 228 GST_CHECK_FIONREAD
 229
 230 dnl *** checks for structures ***
 231
 232 dnl *** checks for compiler characteristics ***
 233
 234 dnl *** checks for library functions ***
 235
 236 dnl check for fseeko()
 237 AC_FUNC_FSEEKO
 238
 239 dnl Check for fast float to int casting as defined in C99
 240 dnl used in gst-libs/gst/floatcast/floatcast.h
 241 save_libs=$LIBS
 242 LIBS="$LIBS $LIBM"
 243 AC_C99_FUNC_LRINT
 244 AC_C99_FUNC_LRINTF
 245 LIBS=$save_libs
 246
 247 dnl Check for a way to display the function name in debug output
 248 AG_GST_CHECK_FUNCTION
 249
 250 dnl *** checks for socket and nsl libraries ***
 251 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 252 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
 253
 254 dnl *** checks for dependency libraries ***
 255
 256 dnl GLib is required
 257 AG_GST_GLIB_CHECK([2.18])
 258
 259 dnl liboil is required
 260 PKG_CHECK_MODULES(LIBOIL, liboil-0.3 >= 0.3.14, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 261 if test "x$HAVE_LIBOIL" != "xyes"; then
 262   AC_ERROR([liboil-0.3.14 or later is required])
 263 fi
 264
 265 dnl checks for gstreamer
 266 dnl uninstalled is selected preferentially -- see pkg-config(1)
 267 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 268 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 269 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ], yes)
 270 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 271 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 272 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 273
 274 dnl Check for documentation xrefs
 275 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 276 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 277 AC_SUBST(GLIB_PREFIX)
 278 AC_SUBST(GST_PREFIX)
 279
 280 dnl GTK is optional and only used in examples
 281 PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.14.0, HAVE_GTK=yes, HAVE_GTK=no)
 282 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 283
 284 dnl some examples need gtk+-x11
 285 PKG_CHECK_MODULES(GTK_X11, gtk+-x11-2.0 >= 2.14.0,
 286     HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 287 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 288
 289 dnl QT is optional and only used in examples
 290 PKG_CHECK_MODULES(QT, QtGui >= 4.6, [
 291   HAVE_QT_GV=yes
 292   HAVE_QT=yes
 293 ], [
 294   HAVE_QT_GV=no
 295   PKG_CHECK_MODULES(QT, QtGui >= 4.0, HAVE_QT=yes, HAVE_QT=no)
 296 ])
 297 AM_CONDITIONAL(HAVE_QT, test "x$HAVE_QT" = "xyes")
 298 AM_CONDITIONAL(HAVE_QT_GV, test "x$HAVE_QT_GV" = "xyes")
 299
 300 dnl *** set variables based on configure arguments ***
 301
 302 dnl set license and copyright notice
 303 GST_LICENSE="LGPL"
 304 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 305 AC_SUBST(GST_LICENSE)
 306
 307 dnl set location of plugin directory
 308 AG_GST_SET_PLUGINDIR
 309
 310 dnl define an ERROR_CFLAGS Makefile variable
 311 AG_GST_SET_ERROR_CFLAGS($GST_GIT, [-Wmissing-declarations -Wmissing-prototypes])
 312
 313 dnl define an ERROR_CXXFLAGS Makefile variable
 314 AG_GST_SET_ERROR_CXXFLAGS($GST_GIT, [-Wmissing-declarations -Wmissing-prototypes])
 315
 316 dnl define correct level for debugging messages
 317 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 318
 319 dnl used in examples
 320 AG_GST_DEFAULT_ELEMENTS
 321
 322 dnl behaviour of speex based audio resampler
 323 AC_MSG_CHECKING(which audio resample format to use for integer)
 324 AC_ARG_WITH([audioresample_format],
 325         AS_HELP_STRING([--with-audioresample-format],[Which implementation should be used for integer audio resampling, int/float/auto, (default is auto)]),
 326         [ac_cv_audioresample_format=$withval], [ac_cv_audioresample_format=auto])dnl
 327 AC_MSG_RESULT($ac_cv_audioresample_format)
 328 case $ac_cv_audioresample_format in
 329   int)
 330     AC_DEFINE(AUDIORESAMPLE_FORMAT_INT,1,[The int implementation should be used for integer audio resampling])
 331     AC_SUBST(AUDIORESAMPLE_FORMAT_INT)
 332   ;;
 333   float)
 334     AC_DEFINE(AUDIORESAMPLE_FORMAT_FLOAT,1,[The float implementation should be used for integer audio resampling])
 335     AC_SUBST(AUDIORESAMPLE_FORMAT_FLOAT)
 336   ;;
 337   auto)
 338     AC_DEFINE(AUDIORESAMPLE_FORMAT_AUTO,1,[The implementation that should be used for integer audio resampling witll be benchmarked at runtime])
 339     AC_SUBST(AUDIORESAMPLE_FORMAT_AUTO)
 340 esac
 341 AM_CONDITIONAL(AUDIORESAMPLE_NEEDS_LIBOIL, test "$ac_cv_audioresample_format" = "auto")
 342
 343 dnl *** plug-ins to include ***
 344
 345 dnl these are all the gst plug-ins, compilable without additional libs
 346 AG_GST_CHECK_PLUGIN(adder)
 347 AG_GST_CHECK_PLUGIN(app)
 348 AG_GST_CHECK_PLUGIN(audioconvert)
 349 AG_GST_CHECK_PLUGIN(audiorate)
 350 AG_GST_CHECK_PLUGIN(audiotestsrc)
 351 AG_GST_CHECK_PLUGIN(ffmpegcolorspace)
 352 AG_GST_CHECK_PLUGIN(gdp)
 353 AG_GST_CHECK_PLUGIN(playback)
 354 AG_GST_CHECK_PLUGIN(audioresample)
 355 AG_GST_CHECK_PLUGIN(subparse)
 356 AG_GST_CHECK_PLUGIN(tcp)
 357 AG_GST_CHECK_PLUGIN(typefind)
 358 AG_GST_CHECK_PLUGIN(videotestsrc)
 359 AG_GST_CHECK_PLUGIN(videorate)
 360 AG_GST_CHECK_PLUGIN(videoscale)
 361 AG_GST_CHECK_PLUGIN(volume)
 362
 363 dnl check for gstreamer core features (subsystems)
 364 GST_CONFIGPATH=`$PKG_CONFIG --variable=includedir gstreamer-0.10`"/gst/gstconfig.h"
 365 AG_GST_PARSE_SUBSYSTEM_DISABLES($GST_CONFIGPATH)
 366 AM_CONDITIONAL(USE_XML, test $GST_DISABLE_XML != "1")
 367
 368 dnl disable plug-ins that require libxml2's HTML support if it is not available
 369 if test "x$HAVE_LIBXML_HTML" != "xyes"; then
 370   AG_GST_DISABLE_PLUGIN(subparse)
 371 fi
 372
 373 dnl disable plug-ins that require sys/socket.h if it is not available
 374 if test "x$HAVE_SYS_SOCKET_H" != "xyes"; then
 375   AG_GST_DISABLE_PLUGIN(tcp)
 376 fi
 377
 378 dnl iso-codes is optional, used by libgsttag
 379 AC_ARG_ENABLE(iso-codes,
 380 AC_HELP_STRING([--enable-iso-codes],[use iso-codes if installed]),
 381 [case "${enableval}" in
 382   yes) enable_iso_codes=yes ;;
 383   no)  enable_iso_codes=no ;;
 384   *) AC_MSG_ERROR(bad value ${enableval} for --enable-iso-codes) ;;
 385 esac
 386 ],
 387 [enable_iso_codes=yes]) dnl Default value
 388
 389 AC_MSG_CHECKING([whether to use iso-codes if they are available])
 390 if test "x$enable_iso_codes" = "xyes"; then
 391   AC_MSG_RESULT([yes])
 392   have_iso_codes=no
 393   AC_MSG_CHECKING([whether iso-codes are available on this system])
 394   if $PKG_CONFIG iso-codes; then
 395     AC_MSG_RESULT([yes])
 396     AC_MSG_CHECKING([whether iso-codes has iso-639 domain])
 397     if $PKG_CONFIG --variable=domains iso-codes | $GREP -q 639 ; then
 398       AC_MSG_RESULT([yes])
 399       AC_MSG_CHECKING([for iso-codes prefix])
 400       ISO_CODES_PREFIX=`$PKG_CONFIG --variable=prefix iso-codes`
 401       if test -d "$ISO_CODES_PREFIX"; then
 402         AC_MSG_RESULT([yes])
 403         AC_MSG_CHECKING([ISO_CODES_PREFIX])
 404         AC_MSG_RESULT([$ISO_CODES_PREFIX])
 405         ISO_639_DOMAIN="iso_639"
 406         AC_MSG_CHECKING([ISO_639_DOMAIN])
 407         AC_MSG_RESULT([$ISO_639_DOMAIN])
 408         have_iso_codes=yes
 409         AC_DEFINE([HAVE_ISO_CODES], [1], [make use of iso-codes for ISO-639])
 410         AC_DEFINE_UNQUOTED([ISO_CODES_PREFIX], ["$ISO_CODES_PREFIX"], [prefix])
 411         ISO_CODES_VERSION=`$PKG_CONFIG --modversion iso-codes`
 412         AC_DEFINE_UNQUOTED([ISO_CODES_VERSION], ["$ISO_CODES_VERSION"], [ ])
 413       else
 414         AC_MSG_RESULT([no])
 415       fi
 416     else
 417       AC_MSG_RESULT([no])
 418     fi
 419   else
 420     AC_MSG_RESULT([no])
 421   fi
 422   AM_CONDITIONAL(USE_ISO_CODES, test "x$have_iso_codes" = "xyes")
 423 else
 424   AC_MSG_RESULT([no (disabled via --disable-iso-codes)])
 425   AM_CONDITIONAL(USE_ISO_CODES, false)
 426 fi
 427
 428 dnl *** sys plug-ins ***
 429
 430 echo
 431 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 432 echo
 433
 434 dnl *** X11 ***
 435 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 436 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 437                   [ximagesink], [
 438   AC_PATH_XTRA
 439   ac_cflags_save="$CFLAGS"
 440   ac_cppflags_save="$CPPFLAGS"
 441   CFLAGS="$CFLAGS $X_CFLAGS"
 442   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 443
 444   dnl now try to find the HEADER
 445   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 446
 447   if test "x$HAVE_X" = "xno"
 448   then
 449     AC_MSG_NOTICE([cannot find X11 development files])
 450   else
 451     dnl this is much more than we want
 452     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 453     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 454     dnl it does not add the libs; therefore we add them here
 455     X_LIBS="$X_LIBS -lX11"
 456     AC_SUBST(X_CFLAGS)
 457     AC_SUBST(X_LIBS)
 458   fi
 459   AC_SUBST(HAVE_X)
 460   CFLAGS="$ac_cflags_save"
 461   CPPFLAGS="$ac_cppflags_save"
 462 ])
 463
 464 dnl Check for Xv extension
 465 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 466 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 467                   [xvimagesink], [
 468   AG_GST_CHECK_XV
 469 ])
 470
 471 dnl check for X Shm
 472 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 473 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 474   if test x$HAVE_X = xyes; then
 475     AC_CHECK_LIB(Xext, XShmAttach,
 476                  HAVE_XSHM="yes", HAVE_XSHM="no",
 477                  $X_LIBS)
 478     if test "x$HAVE_XSHM" = "xyes"; then
 479       XSHM_LIBS="-lXext"
 480     else
 481       dnl On AIX, it is in XextSam instead, but we still need -lXext
 482       AC_CHECK_LIB(XextSam, XShmAttach,
 483                    HAVE_XSHM="yes", HAVE_XSHM="no",
 484                    $X_LIBS)
 485       if test "x$HAVE_XSHM" = "xyes"; then
 486         XSHM_LIBS="-lXext -lXextSam"
 487       fi
 488     fi
 489   fi
 490 ], , [
 491   AC_SUBST(HAVE_XSHM)
 492   AC_SUBST(XSHM_LIBS)
 493 ])
 494
 495 dnl v4l/v4l2 checks have been moved down because they require X
 496
 497 dnl *** Video 4 Linux ***
 498 dnl for information about the header/define, see sys/v4l/gstv4lelement.h
 499 dnl renamed to GST_V4L in accordance with V4L2 below
 500 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L, true)
 501 AG_GST_CHECK_FEATURE(GST_V4L, [Video 4 Linux], video4linux, [
 502   AC_CHECK_DECL(VID_TYPE_MPEG_ENCODER, HAVE_GST_V4L="yes", HAVE_GST_V4L="no", [
 503 #include <sys/types.h>
 504 #define _LINUX_TIME_H
 505 #define __user
 506 #include <linux/videodev.h>
 507   ])
 508
 509   dnl we can build v4l without Xv, but then we won't have XOverlay support
 510   if test "x$HAVE_GST_V4L" = "xyes" -a "x$HAVE_XVIDEO" != "xyes"
 511   then
 512     AC_MSG_NOTICE([NO XVIDEO FOUND, VIDEO4LINUX WILL BE BUILT])
 513     AC_MSG_NOTICE([WITHOUT XOVERLAY SUPPORT])
 514   fi
 515 ])
 516
 517 # Optional gudev for device probing
 518 AC_ARG_WITH([gudev],
 519   AC_HELP_STRING([--with-gudev],
 520     [device detection with gudev]),
 521   [],
 522   [with_gudev=check])
 523 if test x$HAVE_GST_V4L = xyes; then
 524   if test x$with_gudev != xno; then
 525       PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 143 ],
 526           [ have_gudev=yes
 527             AC_DEFINE(HAVE_GUDEV, 1,
 528                [Whether gudev is available for device detection])
 529             AC_DEFINE([G_UDEV_API_IS_SUBJECT_TO_CHANGE], 1, [I know the API is subject to change.])
 530           ], [
 531           have_gudev=no
 532           ])
 533   else
 534     have_gudev=no
 535   fi
 536 fi
 537 AC_SUBST(GUDEV_CFLAGS)
 538 AC_SUBST(GUDEV_LIBS)
 539
 540 dnl *** ext plug-ins ***
 541 dnl keep this list sorted alphabetically !
 542
 543 if test "x$BUILD_EXTERNAL" = "xyes"; then
 544
 545 echo
 546 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 547 echo
 548
 549 dnl *** alsa ***
 550 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 551 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 552   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 553     HAVE_ALSA="yes"
 554     AC_SUBST(ALSA_CFLAGS)
 555     AC_SUBST(ALSA_LIBS)
 556   ], [
 557     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 558   ])
 559 ])
 560
 561 dnl *** CDParanoia ***
 562 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 563 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 564   AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 565                       cdda_open, -lm,
 566                       cdda_interface.h,
 567                       CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 568                       HEADER_DIR="no"
 569                       FOUND_CDPARANOIA="yes")
 570   if test "x$FOUND_CDPARANOIA" != "xyes";
 571   then
 572     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 573                         cdda_open, -lm,
 574                         cdda/cdda_interface.h,
 575                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 576                         HEADER_DIR="yes"
 577                         FOUND_CDPARANOIA="yes")
 578   fi
 579   if test "x$HEADER_DIR" = "xyes";
 580   then
 581     AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 582                        defined if cdda headers are in a cdda/ directory)
 583   fi
 584   if test "x$FOUND_CDPARANOIA" = "xyes";
 585   then
 586     AC_CHECK_LIB(cdda_paranoia,
 587                  paranoia_cachemodel_size,
 588                  : ,
 589                  HAVE_CDPARANOIA=no)
 590   fi
 591
 592   AC_SUBST(CDPARANOIA_LIBS)
 593 ])
 594 dnl FIXME : add second check somehow if that is necessary
 595 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 596 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 597
 598 dnl *** GNOME VFS ***
 599 translit(dnm, m, l) AM_CONDITIONAL(USE_GNOME_VFS, true)
 600 AG_GST_CHECK_FEATURE(GNOME_VFS, [GNOME VFS], gnomevfs, [
 601   PKG_CHECK_MODULES(GNOME_VFS, gnome-vfs-2.0, [
 602       HAVE_GNOME_VFS="yes"
 603       AC_SUBST(GNOME_VFS_CFLAGS)
 604       AC_SUBST(GNOME_VFS_LIBS)
 605       GNOME_VFS_MODULES_DIR="`$PKG_CONFIG --variable=modulesdir gnome-vfs-2.0`"
 606       AC_DEFINE_UNQUOTED(GNOME_VFS_MODULES_DIR, "$GNOME_VFS_MODULES_DIR",
 607              [The GnomeVFS modules directory.])
 608     ],[
 609       HAVE_GNOME_VFS="no"
 610     ]
 611     )
 612 ])
 613
 614 dnl *** ivorbis ***
 615 dnl AM_PATH_IVORBIS only takes two options
 616 translit(dnm, m, l) AM_CONDITIONAL(USE_IVORBIS, true)
 617 AG_GST_CHECK_FEATURE(IVORBIS, [integer vorbis plug-in], ivorbisdec, [
 618   AG_GST_PKG_CHECK_MODULES(IVORBIS, vorbisidec)
 619   if test $HAVE_IVORBIS = no
 620   then
 621     IVORBIS_LIBS=
 622     IVORBIS_CFLAGS=
 623     AC_CHECK_LIB(vorbisidec, vorbis_block_init,
 624       [IVORBIS_LIBS=-lvorbisidec
 625       HAVE_IVORBIS=yes
 626       case $host in
 627       arm-*-*)
 628         IVORBIS_CFLAGS="-D_ARM_ASSEM_ $IVORBIS_CFLAGS"
 629       esac
 630       ],
 631       HAVE_IVORBIS=no)
 632     AC_SUBST(IVORBIS_LIBS)
 633     AC_SUBST(IVORBIS_CFLAGS)
 634   fi
 635 ])
 636
 637 dnl *** libgio ***
 638 translit(dnm, m, l) AM_CONDITIONAL(USE_GIO, true)
 639 AG_GST_CHECK_FEATURE(GIO, [GIO library], gio, [
 640   PKG_CHECK_MODULES(GIO, gio-2.0 >= 2.16, [
 641     HAVE_GIO="yes"
 642     GIO_MODULE_DIR="`$PKG_CONFIG --variable=giomoduledir gio-2.0`"
 643     AC_DEFINE_UNQUOTED(GIO_MODULE_DIR, "$GIO_MODULE_DIR",
 644            [The GIO modules directory.])
 645     GIO_LIBDIR="`$PKG_CONFIG --variable=libdir gio-2.0`"
 646     AC_DEFINE_UNQUOTED(GIO_LIBDIR, "$GIO_LIBDIR",
 647            [The GIO library directory.])
 648   ], [
 649     HAVE_GIO="no"
 650     AC_MSG_RESULT(no)
 651   ])
 652   AC_SUBST(GIO_CFLAGS)
 653   AC_SUBST(GIO_LIBS)
 654   AC_SUBST(GIO_LDFLAGS)
 655 ])
 656
 657 dnl *** libvisual ***
 658 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 659 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 660   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 661   if test $HAVE_LIBVISUAL = no
 662   then
 663     AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0)
 664     if test x$HAVE_LIBVISUAL == xyes; then
 665       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.2`"
 666     fi
 667   else
 668     if test x$HAVE_LIBVISUAL == xyes; then
 669       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.4`"
 670     fi
 671   fi
 672   AC_MSG_NOTICE([libvisual pluginsdir: $LIBVIS_PLUGINSDIR])
 673   if test x$LIBVIS_PLUGINSDIR != x; then
 674     AC_DEFINE_UNQUOTED(LIBVISUAL_PLUGINSBASEDIR,
 675         "$LIBVIS_PLUGINSDIR",
 676         [directory in which the detected libvisual's plugins are located])
 677   fi
 678 ])
 679
 680 dnl *** ogg ***
 681 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 682 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 683   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 684   if test $HAVE_OGG = no
 685   then
 686     XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
 687     AS_SCRUB_INCLUDE(OGG_CFLAGS)
 688   fi
 689 ])
 690
 691 dnl *** pango ***
 692 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 693 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 694   AG_GST_PKG_CHECK_MODULES(PANGO, pango >= 1.16.0  pangocairo >= 1.16.0)
 695 ])
 696
 697 dnl *** theora ***
 698 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 699 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 700   dnl theora uses pkg-config version incorrectly, for pkg-config:
 701   dnl 1.0 < 1.0RCX < 1.0alphaX < 1.0betaX < 1.0.0
 702   dnl theoraenc and theoradec appeared in 1.0beta3
 703
 704   AG_GST_PKG_CHECK_MODULES(THEORA, theoradec theoraenc)
 705 ])
 706
 707 dnl *** vorbis ***
 708 dnl AM_PATH_VORBIS only takes two options
 709 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 710 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 711   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 712   if test $HAVE_VORBIS = no
 713   then
 714     XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
 715     AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
 716   fi
 717 ])
 718
 719 if test "x$HAVE_VORBIS" = "xyes"; then
 720   ac_cflags_save="$CFLAGS"
 721   AC_COMPILE_IFELSE(
 722     AC_LANG_PROGRAM([
 723 #include <vorbis/codec.h>
 724                      ],[
 725 vorbis_dsp_state *v;
 726
 727 vorbis_synthesis_restart (v);
 728                      ]), HAVE_VSR=yes, HAVE_VSR=no)
 729   if test "x$HAVE_VSR" = "xyes"; then
 730     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 731                        [defined if vorbis_synthesis_restart is present])
 732   fi
 733   CFLAGS="$ac_cflags_save"
 734 fi
 735
 736 else
 737
 738 dnl not building plugins with external dependencies,
 739 dnl but we still need to set the conditionals
 740 AM_CONDITIONAL(USE_ALSA, false)
 741 AM_CONDITIONAL(USE_CDPARANOIA, false)
 742 AM_CONDITIONAL(USE_GNOME_VFS, false)
 743 AM_CONDITIONAL(USE_GIO, false)
 744 AM_CONDITIONAL(USE_LIBVISUAL, false)
 745 AM_CONDITIONAL(USE_OGG, false)
 746 AM_CONDITIONAL(USE_PANGO, false)
 747 AM_CONDITIONAL(USE_THEORA, false)
 748 AM_CONDITIONAL(USE_VORBIS, false)
 749
 750 fi dnl of EXT plugins
 751
 752 dnl seeking needs freetype, so check for it here
 753 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 754   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 755 ])
 756 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 757 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 758 AC_SUBST(FT2_CFLAGS)
 759 AC_SUBST(FT2_LIBS)
 760
 761 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 762
 763 dnl Overview:
 764 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 765 dnl GST_*:              flags shared by built objects to link against GStreamer
 766 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 767 dnl                          (compare to other modules) or for i18n
 768 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 769 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 770 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 771 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 772
 773 dnl GST_OPTION_CFLAGS
 774 if test "x$USE_DEBUG" = xyes; then
 775    PROFILE_CFLAGS="-g"
 776 fi
 777 AC_SUBST(PROFILE_CFLAGS)
 778
 779 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 780   dnl Define _only_ when compiling a git version (not pre-releases or releases)
 781   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 782 else
 783   DEPRECATED_CFLAGS=""
 784 fi
 785 AC_SUBST(DEPRECATED_CFLAGS)
 786
 787 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 788 dnl at make time with e.g. make ERROR_CFLAGS=""
 789 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 790 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 791 AC_SUBST(GST_OPTION_CFLAGS)
 792 AC_SUBST(GST_OPTION_CXXFLAGS)
 793
 794 dnl our libraries need to be versioned correctly
 795 AC_SUBST(GST_LT_LDFLAGS)
 796
 797 dnl GST_PLUGINS_BASE_CFLAGS
 798 dnl prefer internal headers to already installed ones
 799 dnl also add builddir include for enumtypes and marshal
 800 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 801 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 802
 803 dnl FIXME: do we want to rename to GST_ALL_* ?
 804 dnl add GST_OPTION_CFLAGS, but overridable
 805 GST_CXXFLAGS="$GST_CFLAGS \$(GST_OPTION_CXXFLAGS)"
 806 GST_CFLAGS="$GST_CFLAGS \$(GST_OPTION_CFLAGS)"
 807 AC_SUBST(GST_CFLAGS)
 808 AC_SUBST(GST_CXXFLAGS)
 809 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 810 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 811 AC_SUBST(GST_LIBS)
 812
 813 dnl LDFLAGS really should only contain flags, not libs - they get added before
 814 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 815 GST_ALL_LDFLAGS="-no-undefined"
 816 AC_SUBST(GST_ALL_LDFLAGS)
 817
 818 dnl GST_LIB_LDFLAGS
 819 dnl linker flags shared by all libraries
 820 dnl LDFLAGS modifier defining exported symbols from built libraries
 821 dnl (export _gst_foo but not __gst_foo)
 822 GST_LIB_LDFLAGS="-export-symbols-regex ^_?\(gst_\|Gst\|GST_\).*"
 823 AC_SUBST(GST_LIB_LDFLAGS)
 824
 825 dnl this really should only contain flags, not libs - they get added before
 826 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 827 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 828 AC_SUBST(GST_PLUGIN_LDFLAGS)
 829
 830 dnl *** output files ***
 831
 832 AC_CONFIG_FILES(
 833 Makefile
 834 gst-plugins-base.spec
 835 gst/Makefile
 836 gst/adder/Makefile
 837 gst/app/Makefile
 838 gst/audioconvert/Makefile
 839 gst/audiorate/Makefile
 840 gst/audiotestsrc/Makefile
 841 gst/ffmpegcolorspace/Makefile
 842 gst/gdp/Makefile
 843 gst/playback/Makefile
 844 gst/audioresample/Makefile
 845 gst/subparse/Makefile
 846 gst/tcp/Makefile
 847 gst/typefind/Makefile
 848 gst/videotestsrc/Makefile
 849 gst/videorate/Makefile
 850 gst/videoscale/Makefile
 851 gst/volume/Makefile
 852 sys/Makefile
 853 sys/ximage/Makefile
 854 sys/xvimage/Makefile
 855 sys/v4l/Makefile
 856 ext/Makefile
 857 ext/alsa/Makefile
 858 ext/cdparanoia/Makefile
 859 ext/gnomevfs/Makefile
 860 ext/gio/Makefile
 861 ext/libvisual/Makefile
 862 ext/ogg/Makefile
 863 ext/pango/Makefile
 864 ext/theora/Makefile
 865 ext/vorbis/Makefile
 866 gst-libs/Makefile
 867 gst-libs/gst/Makefile
 868 gst-libs/gst/audio/Makefile
 869 gst-libs/gst/app/Makefile
 870 gst-libs/gst/cdda/Makefile
 871 gst-libs/gst/fft/Makefile
 872 gst-libs/gst/floatcast/Makefile
 873 gst-libs/gst/interfaces/Makefile
 874 gst-libs/gst/netbuffer/Makefile
 875 gst-libs/gst/riff/Makefile
 876 gst-libs/gst/rtp/Makefile
 877 gst-libs/gst/rtsp/Makefile
 878 gst-libs/gst/sdp/Makefile
 879 gst-libs/gst/tag/Makefile
 880 gst-libs/gst/pbutils/Makefile
 881 gst-libs/gst/video/Makefile
 882 tools/Makefile
 883 pkgconfig/Makefile
 884 pkgconfig/gstreamer-audio.pc
 885 pkgconfig/gstreamer-audio-uninstalled.pc
 886 pkgconfig/gstreamer-app.pc
 887 pkgconfig/gstreamer-app-uninstalled.pc
 888 pkgconfig/gstreamer-cdda.pc
 889 pkgconfig/gstreamer-cdda-uninstalled.pc
 890 pkgconfig/gstreamer-fft.pc
 891 pkgconfig/gstreamer-fft-uninstalled.pc
 892 pkgconfig/gstreamer-floatcast.pc
 893 pkgconfig/gstreamer-floatcast-uninstalled.pc
 894 pkgconfig/gstreamer-interfaces.pc
 895 pkgconfig/gstreamer-interfaces-uninstalled.pc
 896 pkgconfig/gstreamer-netbuffer.pc
 897 pkgconfig/gstreamer-netbuffer-uninstalled.pc
 898 pkgconfig/gstreamer-pbutils.pc
 899 pkgconfig/gstreamer-pbutils-uninstalled.pc
 900 pkgconfig/gstreamer-riff.pc
 901 pkgconfig/gstreamer-riff-uninstalled.pc
 902 pkgconfig/gstreamer-rtp.pc
 903 pkgconfig/gstreamer-rtp-uninstalled.pc
 904 pkgconfig/gstreamer-rtsp.pc
 905 pkgconfig/gstreamer-rtsp-uninstalled.pc
 906 pkgconfig/gstreamer-sdp.pc
 907 pkgconfig/gstreamer-sdp-uninstalled.pc
 908 pkgconfig/gstreamer-tag.pc
 909 pkgconfig/gstreamer-tag-uninstalled.pc
 910 pkgconfig/gstreamer-video.pc
 911 pkgconfig/gstreamer-video-uninstalled.pc
 912 pkgconfig/gstreamer-plugins-base.pc
 913 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 914 tests/Makefile
 915 tests/check/Makefile
 916 tests/examples/Makefile
 917 tests/examples/app/Makefile
 918 tests/examples/dynamic/Makefile
 919 tests/examples/overlay/Makefile
 920 tests/examples/seek/Makefile
 921 tests/examples/volume/Makefile
 922 tests/examples/snapshot/Makefile
 923 tests/examples/gio/Makefile
 924 tests/examples/v4l/Makefile
 925 tests/icles/Makefile
 926 docs/Makefile
 927 docs/design/Makefile
 928 docs/libs/Makefile
 929 docs/plugins/Makefile
 930 docs/version.entities
 931 po/Makefile.in
 932 common/Makefile
 933 common/m4/Makefile
 934 m4/Makefile
 935 )
 936
 937 dnl Create the config.h file for Visual Studio builds
 938 dnl Beware of spaces and /'s in some of the shell variable contents.
 939 sed \
 940     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 941     -e 's/.* GST_INSTALL_PLUGINS_HELPER/#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
 942     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 943     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 944     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 945     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 946     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
 947     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 948     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 949     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 950     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 951     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 952     -e 's/.* HAVE_ISO_CODES$/#undef HAVE_ISO_CODES/' \
 953     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
 954     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 955     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 956     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 957     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 958     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 959     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 960     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
 961     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 962     -e 's/.* ISO_CODES_PREFIX$/#undef ISO_CODES_PREFIX/' \
 963     -e 's/.* ISO_CODES_VERSION$/#undef ISO_CODES_VERSION/' \
 964     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 965     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 966     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
 967     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 968     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
 969     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 970     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 971     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 972     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.10"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.10"\n#endif/' \
 973     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
 974     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 975     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directaudiosink\"/" \
 976     -e "s/.* DEFAULT_VIDEOSINK$/#define DEFAULT_VIDEOSINK \"directdrawsink\"/" \
 977     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
 978     config.h.in >win32/common/config.h-new
 979
 980
 981
 982 AC_OUTPUT
 983
 984 AG_GST_OUTPUT_PLUGINS