configure.ac

   1 AC_PREREQ(2.60)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/prerelease
   8 AC_INIT(GStreamer Base Plug-ins, 0.11.90,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-base)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability 1.10])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use GST_API_VERSION in the filename
  41 dnl to allow side-by-side installation of different API versions
  42 GST_API_VERSION=1.0
  43 AC_SUBST(GST_API_VERSION)
  44 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  45   [GStreamer API Version])
  46
  47 dnl CURRENT, REVISION, AGE
  48 dnl - library source changed -> increment REVISION
  49 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  50 dnl - interfaces added -> increment AGE
  51 dnl - interfaces removed -> AGE = 0
  52 dnl sets GST_LT_LDFLAGS
  53 AS_LIBTOOL(GST, 0, 0, 0)
  54
  55 dnl FIXME: this macro doesn't actually work;
  56 dnl the generated libtool script has no support for the listed tags.
  57 dnl So this needs to be fixed first if we want to use this
  58 dnl AS_LIBTOOL_TAGS
  59
  60 AC_LIBTOOL_WIN32_DLL
  61 AM_PROG_LIBTOOL
  62
  63 dnl *** required versions of GStreamer stuff ***
  64 GST_REQ=0.11.90
  65
  66 dnl *** autotools stuff ****
  67
  68 dnl allow for different autotools
  69 AS_AUTOTOOLS_ALTERNATE
  70
  71 dnl Add parameters for aclocal
  72 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  73
  74 dnl set up gettext
  75 dnl the version check needs to stay here because autopoint greps for it
  76 AM_GNU_GETTEXT_VERSION([0.17])
  77 AM_GNU_GETTEXT([external])
  78 AG_GST_GETTEXT([gst-plugins-base-$GST_API_VERSION])
  79
  80 dnl *** check for arguments to configure ***
  81
  82 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  83
  84 AG_GST_ARG_DEBUG
  85 AG_GST_ARG_PROFILING
  86 AG_GST_ARG_VALGRIND
  87 AG_GST_ARG_GCOV
  88
  89 AG_GST_ARG_EXAMPLES
  90
  91 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  92 AG_GST_ARG_WITH_PACKAGE_NAME
  93 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  94
  95 AG_GST_PKG_CONFIG_PATH
  96
  97 dnl let distro override plugin install helper path
  98 AC_ARG_WITH(install-plugins-helper,
  99   AC_HELP_STRING([--with-install-plugins-helper],
 100     [specify path of helper script to call to install plugins]),
 101   [
 102     case "${withval}" in
 103       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 104       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 105       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
 106     esac
 107   ],
 108   [
 109     dnl Default value
 110     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 111   ]
 112 )
 113 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 114 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 115     [plugin install helper script])
 116 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 117
 118 AG_GST_ARG_WITH_PLUGINS
 119
 120 AG_GST_ARG_ENABLE_EXTERNAL
 121
 122 AG_GST_ARG_ENABLE_EXPERIMENTAL
 123
 124 dnl *** checks for platform ***
 125 AG_GST_PLATFORM
 126
 127 dnl * hardware/architecture *
 128
 129 dnl common/m4/gst-arch.m4
 130 dnl check CPU type
 131 AG_GST_ARCH
 132
 133 dnl check for large file support
 134 dnl affected plugins must include config.h
 135 AC_SYS_LARGEFILE
 136
 137 dnl *** checks for programs ***
 138
 139 dnl find a compiler
 140 AC_PROG_CC
 141 AC_PROG_CC_STDC
 142
 143 dnl check if the compiler supports '-c' and '-o' options
 144 AM_PROG_CC_C_O
 145
 146 dnl determine if c++ is available on this system
 147 AC_PROG_CXX
 148 dnl CXX may be set to some default even if no c++ compiler is available
 149 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 150 AC_LANG_PUSH([C++])
 151 AC_TRY_COMPILE([ class Foo { int bar; };], , working_cxx=yes, working_cxx=no)
 152 AC_LANG_POP([C++])
 153 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 154 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 155
 156 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 157 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 158
 159 dnl check for gobject-introspection
 160 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 161
 162 dnl check for documentation tools
 163 GTK_DOC_CHECK([1.3])
 164 AS_PATH_PYTHON([2.1])
 165 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 166
 167 dnl *** checks for libraries ***
 168
 169 dnl libm, for sin() etc.
 170 AC_CHECK_LIBM
 171 AC_SUBST(LIBM)
 172
 173 dnl *** checks for header files ***
 174
 175 dnl check if we have ANSI C header files
 176 AC_HEADER_STDC
 177
 178 ac_cppflags_save="$CPPFLAGS"
 179 CPPFLAGS="`$PKG_CONFIG --cflags libxml-2.0`"
 180 AC_COMPILE_IFELSE([
 181   AC_LANG_PROGRAM([[
 182 #include <libxml/HTMLparser.h>
 183 ]],[[
 184 #ifndef LIBXML_HTML_ENABLED
 185 #error libxml2 has no HTML support
 186 #endif /* LIBXML_HTML_ENABLED */
 187 ]])], [
 188   HAVE_LIBXML_HTML="yes"
 189 ], [
 190   HAVE_LIBXML_HTML="no"
 191 ])
 192 CPPFLAGS="$ac_cppflags_save"
 193 AM_CONDITIONAL(HAVE_LIBXML_HTML, test "x$HAVE_LIBXML_HTML" = "xyes")
 194
 195 dnl used in gst/tcp
 196 AC_CHECK_HEADERS([sys/socket.h],
 197   HAVE_SYS_SOCKET_H="yes", HAVE_SYS_SOCKET_H="no")
 198 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 199
 200 dnl used in gst-libs/gst/pbutils and associated unit test
 201 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h])
 202
 203 dnl also, Windows does not have long long
 204 AX_CREATE_STDINT_H
 205
 206 dnl *** checks for functions ***
 207 AC_CHECK_FUNCS([localtime_r gmtime_r])
 208
 209 dnl *** checks for math functions ***
 210 LIBS_SAVE=$LIBS
 211 LIBS="$LIBS $LIBM"
 212 AC_CHECK_FUNCS(log2)
 213 LIBS=$LIBS_SAVE
 214
 215 dnl *** checks for types/defines ***
 216
 217 dnl *** checks for structures ***
 218
 219 dnl *** checks for compiler characteristics ***
 220
 221 dnl *** checks for library functions ***
 222
 223 dnl check for fseeko()
 224 AC_FUNC_FSEEKO
 225
 226 dnl Check for fast float to int casting as defined in C99
 227 dnl used to be used in gst-libs/gst/floatcast/floatcast.h (FIXME: still needed?)
 228 save_libs=$LIBS
 229 LIBS="$LIBS $LIBM"
 230 AC_C99_FUNC_LRINT
 231 AC_C99_FUNC_LRINTF
 232 LIBS=$save_libs
 233
 234 dnl Check for a way to display the function name in debug output
 235 AG_GST_CHECK_FUNCTION
 236
 237 dnl *** checks for dependency libraries ***
 238
 239 dnl GLib
 240 GLIB_REQ=2.31.14
 241 AG_GST_GLIB_CHECK([$GLIB_REQ])
 242
 243 ORC_CHECK([0.4.11])
 244
 245 dnl checks for gstreamer
 246 dnl uninstalled is selected preferentially -- see pkg-config(1)
 247 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 248 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 249 AG_GST_CHECK_GST_CONTROLLER($GST_API_VERSION, [$GST_REQ], yes)
 250 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 251 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 252
 253 dnl Check for documentation xrefs
 254 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 255 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 256 AC_SUBST(GLIB_PREFIX)
 257 AC_SUBST(GST_PREFIX)
 258
 259 dnl GTK is optional and only used in examples
 260 HAVE_GTK=no
 261 HAVE_GTK_X11=no
 262 GTK_REQ=3.0.0
 263 if test "x$BUILD_EXAMPLES" = "xyes"; then
 264   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 265   dnl some examples need gtk+-x11
 266   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 267   AC_SUBST(GTK_LIBS)
 268   AC_SUBST(GTK_CFLAGS)
 269 fi
 270 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 271 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 272
 273 dnl QT is optional and only used in examples
 274 PKG_CHECK_MODULES(QT, QtGui >= 4.6, [
 275   HAVE_QT_GV=yes
 276   HAVE_QT=yes
 277 ], [
 278   HAVE_QT_GV=no
 279   PKG_CHECK_MODULES(QT, QtGui >= 4.0, HAVE_QT=yes, HAVE_QT=no)
 280 ])
 281 if test "x$HAVE_QT" = "xyes"; then
 282   AC_MSG_CHECKING([Qt moc])
 283   QT4_MOC=`$PKG_CONFIG --variable=moc_location QtGui`
 284   AC_MSG_RESULT($QT4_MOC)
 285   AC_SUBST(QT4_MOC)
 286 fi
 287 AM_CONDITIONAL(HAVE_QT, test "x$HAVE_QT" = "xyes")
 288 AM_CONDITIONAL(HAVE_QT_GV, test "x$HAVE_QT_GV" = "xyes")
 289
 290 dnl chck for linux headers needed by the joystick seek example
 291 AC_COMPILE_IFELSE(
 292 [
 293   AC_LANG_PROGRAM([
 294     #include <linux/input.h>
 295     #include <linux/joystick.h>
 296   ],[
 297     struct js_event js;
 298     js.type = JS_EVENT_AXIS;
 299   ])
 300 ], [
 301   HAVE_LINUX_JOYSTICK_HEADERS="yes"
 302 ], [
 303   HAVE_LINUX_JOYSTICK_HEADERS="no"
 304 ])
 305 AM_CONDITIONAL(HAVE_LINUX_JOYSTICK_HEADERS, test "x$HAVE_LINUX_JOYSTICK_HEADERS" = "xyes")
 306
 307 dnl Check for -Bsymbolic-functions linker flag used to avoid
 308 dnl intra-library PLT jumps, if available.
 309 AC_ARG_ENABLE(Bsymbolic,
 310               [AC_HELP_STRING([--disable-Bsymbolic],
 311                               [avoid linking with -Bsymbolic])],,
 312               [SAVED_LDFLAGS="${LDFLAGS}"
 313                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 314                LDFLAGS=-Wl,-Bsymbolic-functions
 315                AC_TRY_LINK([], [int main (void) { return 0; }],
 316                            AC_MSG_RESULT(yes)
 317                            enable_Bsymbolic=yes,
 318                            AC_MSG_RESULT(no)
 319                            enable_Bsymbolic=no)
 320                LDFLAGS="${SAVED_LDFLAGS}"])
 321
 322
 323 dnl *** set variables based on configure arguments ***
 324
 325 dnl set license and copyright notice
 326 GST_LICENSE="LGPL"
 327 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 328 AC_SUBST(GST_LICENSE)
 329
 330 dnl set location of plugin directory
 331 AG_GST_SET_PLUGINDIR
 332
 333 dnl set release date/time
 334 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 335   ["${srcdir}/gst-plugins-base.doap"],
 336   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 337
 338 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 339 dnl make sure it doesn't complain about unused variables if debugging is disabled
 340 NO_WARNINGS=""
 341 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 342
 343 dnl define an ERROR_CFLAGS Makefile variable
 344 dnl -Wformat-nonliteral - see ext/pango/gstclockoverlay.c and http://gcc.gnu.org/bugzilla/show_bug.cgi?id=39438
 345 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 346     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef
 347     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 348     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 349     -Wno-multichar -Wnested-externs $NO_WARNINGS])
 350
 351 dnl define an ERROR_CXXFLAGS Makefile variable
 352 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 353     -Wmissing-declarations -Wredundant-decls -Wundef
 354     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 355     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 356     -Wno-multichar $NO_WARNINGS])
 357
 358 dnl define correct level for debugging messages
 359 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 360
 361 dnl used in examples
 362 AG_GST_DEFAULT_ELEMENTS
 363
 364 dnl needed for encoding-target
 365 GST_DATADIR="$GST_PREFIX/share"
 366 AC_DEFINE_UNQUOTED(GST_DATADIR, "$GST_DATADIR", [system wide data directory])
 367 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION", [major/minor version])
 368
 369 dnl behaviour of speex based audio resampler
 370 AC_MSG_CHECKING(which audio resample format to use for integer)
 371 AC_ARG_WITH([audioresample_format],
 372         AS_HELP_STRING([--with-audioresample-format],[Which implementation should be used for integer audio resampling, int/float/auto, (default is auto)]),
 373         [ac_cv_audioresample_format=$withval], [ac_cv_audioresample_format=auto])dnl
 374 AC_MSG_RESULT($ac_cv_audioresample_format)
 375 case $ac_cv_audioresample_format in
 376   int)
 377     AC_DEFINE(AUDIORESAMPLE_FORMAT_INT,1,[The int implementation should be used for integer audio resampling])
 378     AC_SUBST(AUDIORESAMPLE_FORMAT_INT)
 379   ;;
 380   float)
 381     AC_DEFINE(AUDIORESAMPLE_FORMAT_FLOAT,1,[The float implementation should be used for integer audio resampling])
 382     AC_SUBST(AUDIORESAMPLE_FORMAT_FLOAT)
 383   ;;
 384   auto)
 385     AC_DEFINE(AUDIORESAMPLE_FORMAT_AUTO,1,[The implementation that should be used for integer audio resampling witll be benchmarked at runtime])
 386     AC_SUBST(AUDIORESAMPLE_FORMAT_AUTO)
 387 esac
 388
 389 dnl *** plug-ins to include ***
 390
 391 dnl these are all the gst plug-ins, compilable without additional libs
 392 AG_GST_CHECK_PLUGIN(adder)
 393 AG_GST_CHECK_PLUGIN(app)
 394 AG_GST_CHECK_PLUGIN(audioconvert)
 395 AG_GST_CHECK_PLUGIN(audiorate)
 396 AG_GST_CHECK_PLUGIN(audiotestsrc)
 397 AG_GST_CHECK_PLUGIN(encoding)
 398 AG_GST_CHECK_PLUGIN(videoconvert)
 399 AG_GST_CHECK_PLUGIN(gdp)
 400 AG_GST_CHECK_PLUGIN(gio)
 401 AG_GST_CHECK_PLUGIN(playback)
 402 AG_GST_CHECK_PLUGIN(audioresample)
 403 AG_GST_CHECK_PLUGIN(subparse)
 404 AG_GST_CHECK_PLUGIN(tcp)
 405 AG_GST_CHECK_PLUGIN(typefind)
 406 AG_GST_CHECK_PLUGIN(videotestsrc)
 407 AG_GST_CHECK_PLUGIN(videorate)
 408 AG_GST_CHECK_PLUGIN(videoscale)
 409 AG_GST_CHECK_PLUGIN(volume)
 410
 411 dnl FIXME 0.11: check for libxml, split subparse and move libxml parts to ext/
 412 AM_CONDITIONAL(USE_XML, false)
 413 AC_DEFINE([GST_DISABLE_XML], [1], [set to disable libxml2-dependent code in subparse])
 414
 415 dnl disable plug-ins that require libxml2's HTML support if it is not available
 416 if test "x$HAVE_LIBXML_HTML" != "xyes"; then
 417   AG_GST_DISABLE_PLUGIN(subparse)
 418 fi
 419
 420 dnl iso-codes is optional, used by libgsttag
 421 AC_ARG_ENABLE(iso-codes,
 422 AC_HELP_STRING([--enable-iso-codes],[use iso-codes if installed]),
 423 [case "${enableval}" in
 424   yes) enable_iso_codes=yes ;;
 425   no)  enable_iso_codes=no ;;
 426   *) AC_MSG_ERROR(bad value ${enableval} for --enable-iso-codes) ;;
 427 esac
 428 ],
 429 [enable_iso_codes=yes]) dnl Default value
 430
 431 AC_MSG_CHECKING([whether to use iso-codes if they are available])
 432 if test "x$enable_iso_codes" = "xyes"; then
 433   AC_MSG_RESULT([yes])
 434   have_iso_codes=no
 435   AC_MSG_CHECKING([whether iso-codes are available on this system])
 436   if $PKG_CONFIG iso-codes; then
 437     AC_MSG_RESULT([yes])
 438     AC_MSG_CHECKING([whether iso-codes has iso-639 domain])
 439     if $PKG_CONFIG --variable=domains iso-codes | $GREP -q 639 ; then
 440       AC_MSG_RESULT([yes])
 441       AC_MSG_CHECKING([for iso-codes prefix])
 442       ISO_CODES_PREFIX=`$PKG_CONFIG --variable=prefix iso-codes`
 443       if test -d "$ISO_CODES_PREFIX"; then
 444         AC_MSG_RESULT([yes])
 445         AC_MSG_CHECKING([ISO_CODES_PREFIX])
 446         AC_MSG_RESULT([$ISO_CODES_PREFIX])
 447         ISO_639_DOMAIN="iso_639"
 448         AC_MSG_CHECKING([ISO_639_DOMAIN])
 449         AC_MSG_RESULT([$ISO_639_DOMAIN])
 450         have_iso_codes=yes
 451         AC_DEFINE([HAVE_ISO_CODES], [1], [make use of iso-codes for ISO-639])
 452         AC_DEFINE_UNQUOTED([ISO_CODES_PREFIX], ["$ISO_CODES_PREFIX"], [prefix])
 453         ISO_CODES_VERSION=`$PKG_CONFIG --modversion iso-codes`
 454         AC_DEFINE_UNQUOTED([ISO_CODES_VERSION], ["$ISO_CODES_VERSION"], [ ])
 455       else
 456         AC_MSG_RESULT([no])
 457       fi
 458     else
 459       AC_MSG_RESULT([no])
 460     fi
 461   else
 462     AC_MSG_RESULT([no])
 463   fi
 464   AM_CONDITIONAL(USE_ISO_CODES, test "x$have_iso_codes" = "xyes")
 465 else
 466   AC_MSG_RESULT([no (disabled via --disable-iso-codes)])
 467   AM_CONDITIONAL(USE_ISO_CODES, false)
 468 fi
 469
 470 dnl *** zlib is optionally used by id3 tag parsing in libgsttag ***
 471 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 472 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for ID3 parsing in libgsttag],, [
 473   PKG_CHECK_MODULES(ZLIB, [ zlib ], [
 474       HAVE_ZLIB="yes"
 475     ], [
 476       AG_GST_CHECK_LIBHEADER(ZLIB, z, uncompress,, zlib.h, [
 477         HAVE_ZLIB="yes"
 478         ZLIB_LIBS="-lz"
 479         AC_SUBST(ZLIB_LIBS)
 480       ])
 481     ])
 482 ])
 483
 484 dnl *** sys plug-ins ***
 485
 486 echo
 487 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 488 echo
 489
 490 dnl *** X11 ***
 491 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 492 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 493                   [ximagesink], [
 494   AC_PATH_XTRA
 495   ac_cflags_save="$CFLAGS"
 496   ac_cppflags_save="$CPPFLAGS"
 497   CFLAGS="$CFLAGS $X_CFLAGS"
 498   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 499
 500   dnl now try to find the HEADER
 501   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 502
 503   if test "x$HAVE_X" = "xno"
 504   then
 505     AC_MSG_NOTICE([cannot find X11 development files])
 506   else
 507     dnl this is much more than we want
 508     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 509     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 510     dnl it does not add the libs; therefore we add them here
 511     X_LIBS="$X_LIBS -lX11"
 512     AC_SUBST(X_CFLAGS)
 513     AC_SUBST(X_LIBS)
 514   fi
 515   AC_SUBST(HAVE_X)
 516   CFLAGS="$ac_cflags_save"
 517   CPPFLAGS="$ac_cppflags_save"
 518 ])
 519
 520 dnl Check for Xv extension
 521 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 522 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 523                   [xvimagesink], [
 524   AG_GST_CHECK_XV
 525 ])
 526
 527 dnl check for X Shm
 528 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 529 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 530   if test x$HAVE_X = xyes; then
 531     AC_CHECK_LIB(Xext, XShmAttach,
 532                  HAVE_XSHM="yes", HAVE_XSHM="no",
 533                  $X_LIBS)
 534     if test "x$HAVE_XSHM" = "xyes"; then
 535       XSHM_LIBS="-lXext"
 536     else
 537       dnl On AIX, it is in XextSam instead, but we still need -lXext
 538       AC_CHECK_LIB(XextSam, XShmAttach,
 539                    HAVE_XSHM="yes", HAVE_XSHM="no",
 540                    $X_LIBS)
 541       if test "x$HAVE_XSHM" = "xyes"; then
 542         XSHM_LIBS="-lXext -lXextSam"
 543       fi
 544     fi
 545   fi
 546 ], , [
 547   AC_SUBST(HAVE_XSHM)
 548   AC_SUBST(XSHM_LIBS)
 549 ])
 550
 551 dnl *** ext plug-ins ***
 552 dnl keep this list sorted alphabetically !
 553
 554 if test "x$BUILD_EXTERNAL" = "xyes"; then
 555
 556 echo
 557 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 558 echo
 559
 560 dnl *** alsa ***
 561 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 562 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 563   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 564     HAVE_ALSA="yes"
 565     AC_SUBST(ALSA_CFLAGS)
 566     AC_SUBST(ALSA_LIBS)
 567   ], [
 568     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 569   ])
 570 ])
 571
 572 dnl *** CDParanoia ***
 573 dnl Note: upstream has a pkg-config file only in post-10.2 SVN so far
 574 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 575 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 576   PKG_CHECK_MODULES(CDPARANOIA, cdparanoia-3 >= 10.2, [
 577     HAVE_CDPARANOIA="yes"
 578   ], [
 579     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 580                         cdda_open, -lm,
 581                         cdda_interface.h,
 582                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 583                         HEADER_DIR="no"
 584                         FOUND_CDPARANOIA="yes")
 585     if test "x$FOUND_CDPARANOIA" != "xyes";
 586     then
 587       AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 588                           cdda_open, -lm,
 589                           cdda/cdda_interface.h,
 590                           CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 591                           HEADER_DIR="yes"
 592                           FOUND_CDPARANOIA="yes")
 593     fi
 594     if test "x$HEADER_DIR" = "xyes";
 595     then
 596       AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 597                          defined if cdda headers are in a cdda/ directory)
 598     fi
 599     if test "x$FOUND_CDPARANOIA" = "xyes";
 600     then
 601       AC_CHECK_LIB(cdda_paranoia,
 602                    paranoia_cachemodel_size,
 603                    : ,
 604                    HAVE_CDPARANOIA=no,
 605                  [-lcdda_interface])
 606     fi
 607
 608     AC_SUBST(CDPARANOIA_LIBS)
 609   ])
 610 ])
 611 dnl FIXME : add second check somehow if that is necessary
 612 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 613 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 614
 615 dnl *** ivorbis ***
 616 dnl AM_PATH_IVORBIS only takes two options
 617 translit(dnm, m, l) AM_CONDITIONAL(USE_IVORBIS, true)
 618 AG_GST_CHECK_FEATURE(IVORBIS, [integer vorbis plug-in], ivorbisdec, [
 619   AG_GST_PKG_CHECK_MODULES(IVORBIS, vorbisidec)
 620   if test $HAVE_IVORBIS = no
 621   then
 622     IVORBIS_LIBS=
 623     IVORBIS_CFLAGS=
 624     AC_CHECK_LIB(vorbisidec, vorbis_block_init,
 625       [IVORBIS_LIBS=-lvorbisidec
 626       HAVE_IVORBIS=yes
 627       case $host in
 628       arm-*-*)
 629         IVORBIS_CFLAGS="-D_ARM_ASSEM_ $IVORBIS_CFLAGS"
 630       esac
 631       ],
 632       HAVE_IVORBIS=no)
 633     AC_SUBST(IVORBIS_LIBS)
 634     AC_SUBST(IVORBIS_CFLAGS)
 635   else
 636     AC_CHECK_LIB(vorbisidec, vorbis_dsp_pcmout,
 637       AC_DEFINE([USE_TREMOLO],1, "Define if building for android"),
 638       USE_TREMOLO=no)
 639   fi
 640 ])
 641
 642 dnl *** libvisual ***
 643 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 644 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 645   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 646   if test $HAVE_LIBVISUAL = no
 647   then
 648     AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0)
 649     if test x$HAVE_LIBVISUAL = xyes; then
 650       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.2`"
 651     fi
 652   else
 653     if test x$HAVE_LIBVISUAL = xyes; then
 654       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.4`"
 655     fi
 656   fi
 657   AC_MSG_NOTICE([libvisual pluginsdir: $LIBVIS_PLUGINSDIR])
 658   if test x$LIBVIS_PLUGINSDIR != x; then
 659     AC_DEFINE_UNQUOTED(LIBVISUAL_PLUGINSBASEDIR,
 660         "$LIBVIS_PLUGINSDIR",
 661         [directory in which the detected libvisual's plugins are located])
 662   fi
 663 ])
 664
 665 dnl *** ogg ***
 666 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 667 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 668   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 669   if test $HAVE_OGG = no
 670   then
 671     XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
 672     AS_SCRUB_INCLUDE(OGG_CFLAGS)
 673   fi
 674 ])
 675
 676 dnl *** pango ***
 677 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 678 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 679   AG_GST_PKG_CHECK_MODULES(PANGO, pango >= 1.22.0  pangocairo >= 1.22.0)
 680 ])
 681
 682 dnl *** theora ***
 683 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 684 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 685   AG_GST_PKG_CHECK_MODULES(THEORA, theoradec >= 1.1 theoraenc >= 1.1)
 686 ])
 687
 688 dnl *** vorbis ***
 689 dnl AM_PATH_VORBIS only takes two options
 690 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 691 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 692   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 693   if test $HAVE_VORBIS = no
 694   then
 695     XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
 696     AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
 697   fi
 698 ])
 699
 700 if test "x$HAVE_VORBIS" = "xyes"; then
 701   ac_cflags_save="$CFLAGS"
 702   AC_COMPILE_IFELSE([
 703     AC_LANG_PROGRAM([[
 704 #include <vorbis/codec.h>
 705                      ]],[[
 706 vorbis_dsp_state *v;
 707
 708 vorbis_synthesis_restart (v);
 709                      ]])], HAVE_VSR=yes, HAVE_VSR=no)
 710   if test "x$HAVE_VSR" = "xyes"; then
 711     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 712                        [defined if vorbis_synthesis_restart is present])
 713   fi
 714   CFLAGS="$ac_cflags_save"
 715 fi
 716
 717 else
 718
 719 dnl not building plugins with external dependencies,
 720 dnl but we still need to set the conditionals
 721 AM_CONDITIONAL(USE_ALSA, false)
 722 AM_CONDITIONAL(USE_CDPARANOIA, false)
 723 AM_CONDITIONAL(USE_IVORBIS, false)
 724 AM_CONDITIONAL(USE_LIBVISUAL, false)
 725 AM_CONDITIONAL(USE_OGG, false)
 726 AM_CONDITIONAL(USE_PANGO, false)
 727 AM_CONDITIONAL(USE_THEORA, false)
 728 AM_CONDITIONAL(USE_VORBIS, false)
 729
 730 fi dnl of EXT plugins
 731
 732 dnl seeking needs freetype, so check for it here
 733 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 734   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 735 ])
 736 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 737 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 738 AC_SUBST(FT2_CFLAGS)
 739 AC_SUBST(FT2_LIBS)
 740
 741 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 742
 743 dnl Overview:
 744 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 745 dnl GST_*:              flags shared by built objects to link against GStreamer
 746 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 747 dnl                          (compare to other modules) or for i18n
 748 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 749 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 750 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 751 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 752
 753 dnl GST_OPTION_CFLAGS
 754 if test "x$USE_DEBUG" = xyes; then
 755    PROFILE_CFLAGS="-g"
 756 fi
 757 AC_SUBST(PROFILE_CFLAGS)
 758
 759 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 760   dnl Define _only_ when compiling a git version (not pre-releases or releases)
 761   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 762 else
 763   DEPRECATED_CFLAGS=""
 764 fi
 765 AC_SUBST(DEPRECATED_CFLAGS)
 766
 767 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 768 dnl at make time with e.g. make ERROR_CFLAGS=""
 769 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 770 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 771 AC_SUBST(GST_OPTION_CFLAGS)
 772 AC_SUBST(GST_OPTION_CXXFLAGS)
 773
 774 dnl our libraries need to be versioned correctly
 775 AC_SUBST(GST_LT_LDFLAGS)
 776
 777 dnl GST_PLUGINS_BASE_CFLAGS
 778 dnl prefer internal headers to already installed ones
 779 dnl also add builddir include for enumtypes and marshal
 780 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 781 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 782
 783 dnl FIXME: do we want to rename to GST_ALL_* ?
 784 dnl add GST_OPTION_CFLAGS, but overridable
 785 GST_CFLAGS="$GST_CFLAGS -DGST_USE_UNSTABLE_API"
 786 GST_CXXFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CXXFLAGS)"
 787 GST_CFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CFLAGS)"
 788 AC_SUBST(GST_CFLAGS)
 789 AC_SUBST(GST_CXXFLAGS)
 790 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 791 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 792 AC_SUBST(GST_LIBS)
 793
 794 dnl LDFLAGS really should only contain flags, not libs - they get added before
 795 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 796 GST_ALL_LDFLAGS="-no-undefined"
 797 if test "x${enable_Bsymbolic}" = "xyes"; then
 798   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 799 fi
 800 AC_SUBST(GST_ALL_LDFLAGS)
 801
 802 dnl GST_LIB_LDFLAGS
 803 dnl linker flags shared by all libraries
 804 dnl LDFLAGS modifier defining exported symbols from built libraries
 805 dnl (export _gst_foo but not __gst_foo)
 806 GST_LIB_LDFLAGS="-export-symbols-regex ^_?\(gst_\|Gst\|GST_\).*"
 807 AC_SUBST(GST_LIB_LDFLAGS)
 808
 809 dnl this really should only contain flags, not libs - they get added before
 810 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 811 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
 812 AC_SUBST(GST_PLUGIN_LDFLAGS)
 813
 814 dnl *** output files ***
 815
 816 AC_CONFIG_FILES(
 817 Makefile
 818 gst-plugins-base.spec
 819 gst/Makefile
 820 gst/adder/Makefile
 821 gst/app/Makefile
 822 gst/audioconvert/Makefile
 823 gst/audiorate/Makefile
 824 gst/audiotestsrc/Makefile
 825 gst/encoding/Makefile
 826 gst/videoconvert/Makefile
 827 gst/gdp/Makefile
 828 gst/gio/Makefile
 829 gst/playback/Makefile
 830 gst/audioresample/Makefile
 831 gst/subparse/Makefile
 832 gst/tcp/Makefile
 833 gst/typefind/Makefile
 834 gst/videotestsrc/Makefile
 835 gst/videorate/Makefile
 836 gst/videoscale/Makefile
 837 gst/volume/Makefile
 838 sys/Makefile
 839 sys/ximage/Makefile
 840 sys/xvimage/Makefile
 841 ext/Makefile
 842 ext/alsa/Makefile
 843 ext/cdparanoia/Makefile
 844 ext/libvisual/Makefile
 845 ext/ogg/Makefile
 846 ext/pango/Makefile
 847 ext/theora/Makefile
 848 ext/vorbis/Makefile
 849 gst-libs/Makefile
 850 gst-libs/gst/Makefile
 851 gst-libs/gst/audio/Makefile
 852 gst-libs/gst/app/Makefile
 853 gst-libs/gst/fft/Makefile
 854 gst-libs/gst/interfaces/Makefile
 855 gst-libs/gst/riff/Makefile
 856 gst-libs/gst/rtp/Makefile
 857 gst-libs/gst/rtsp/Makefile
 858 gst-libs/gst/sdp/Makefile
 859 gst-libs/gst/tag/Makefile
 860 gst-libs/gst/pbutils/Makefile
 861 gst-libs/gst/pbutils/gstpluginsbaseversion.h
 862 gst-libs/gst/video/Makefile
 863 tools/Makefile
 864 pkgconfig/Makefile
 865 pkgconfig/gstreamer-audio.pc
 866 pkgconfig/gstreamer-audio-uninstalled.pc
 867 pkgconfig/gstreamer-app.pc
 868 pkgconfig/gstreamer-app-uninstalled.pc
 869 pkgconfig/gstreamer-fft.pc
 870 pkgconfig/gstreamer-fft-uninstalled.pc
 871 pkgconfig/gstreamer-interfaces.pc
 872 pkgconfig/gstreamer-interfaces-uninstalled.pc
 873 pkgconfig/gstreamer-pbutils.pc
 874 pkgconfig/gstreamer-pbutils-uninstalled.pc
 875 pkgconfig/gstreamer-riff.pc
 876 pkgconfig/gstreamer-riff-uninstalled.pc
 877 pkgconfig/gstreamer-rtp.pc
 878 pkgconfig/gstreamer-rtp-uninstalled.pc
 879 pkgconfig/gstreamer-rtsp.pc
 880 pkgconfig/gstreamer-rtsp-uninstalled.pc
 881 pkgconfig/gstreamer-sdp.pc
 882 pkgconfig/gstreamer-sdp-uninstalled.pc
 883 pkgconfig/gstreamer-tag.pc
 884 pkgconfig/gstreamer-tag-uninstalled.pc
 885 pkgconfig/gstreamer-video.pc
 886 pkgconfig/gstreamer-video-uninstalled.pc
 887 pkgconfig/gstreamer-plugins-base.pc
 888 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 889 tests/Makefile
 890 tests/check/Makefile
 891 tests/examples/Makefile
 892 tests/examples/app/Makefile
 893 tests/examples/audio/Makefile
 894 tests/examples/dynamic/Makefile
 895 tests/examples/encoding/Makefile
 896 tests/examples/fft/Makefile
 897 tests/examples/gio/Makefile
 898 tests/examples/overlay/Makefile
 899 tests/examples/seek/Makefile
 900 tests/examples/snapshot/Makefile
 901 tests/examples/playback/Makefile
 902 tests/examples/playrec/Makefile
 903 tests/files/Makefile
 904 tests/icles/Makefile
 905 tests/icles/playback/Makefile
 906 docs/Makefile
 907 docs/design/Makefile
 908 docs/libs/Makefile
 909 docs/plugins/Makefile
 910 docs/version.entities
 911 po/Makefile.in
 912 common/Makefile
 913 common/m4/Makefile
 914 m4/Makefile
 915 )
 916
 917 dnl Create the config.h file for Visual Studio builds
 918 dnl Beware of spaces and /'s in some of the shell variable contents.
 919 sed \
 920     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 921     -e 's/.* GST_INSTALL_PLUGINS_HELPER/#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
 922     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 923     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 924     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 925     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 926     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
 927     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 928     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 929     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
 930     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 931     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 932     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 933     -e 's/.* HAVE_ISO_CODES$/#undef HAVE_ISO_CODES/' \
 934     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
 935     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 936     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 937     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 938     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 939     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 940     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 941     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 942     -e 's/.* ISO_CODES_PREFIX$/#undef ISO_CODES_PREFIX/' \
 943     -e 's/.* ISO_CODES_VERSION$/#undef ISO_CODES_VERSION/' \
 944     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 945     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 946     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
 947     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 948     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
 949     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 950     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 951     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 952     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
 953     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
 954     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 955     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
 956     -e "s/.* DEFAULT_VIDEOSINK$/#define DEFAULT_VIDEOSINK \"directdrawsink\"/" \
 957     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
 958     config.h.in >win32/common/config.h-new
 959
 960
 961
 962 AC_OUTPUT
 963
 964 AG_GST_OUTPUT_PLUGINS
 965 ORC_OUTPUT
 966