configure.ac

   1 AC_PREREQ(2.60)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/prerelease
   8 AC_INIT(GStreamer Base Plug-ins, 0.10.31.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-base)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability 1.10])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use major.minor as a version
  41 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  42 dnl we override it here if we need to for the release candidate of new series
  43 GST_MAJORMINOR=0.10
  44 AC_SUBST(GST_MAJORMINOR)
  45
  46 dnl CURRENT, REVISION, AGE
  47 dnl - library source changed -> increment REVISION
  48 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  49 dnl - interfaces added -> increment AGE
  50 dnl - interfaces removed -> AGE = 0
  51 dnl sets GST_LT_LDFLAGS
  52 AS_LIBTOOL(GST, 22, 0, 22)
  53
  54 dnl FIXME: this macro doesn't actually work;
  55 dnl the generated libtool script has no support for the listed tags.
  56 dnl So this needs to be fixed first if we want to use this
  57 dnl AS_LIBTOOL_TAGS
  58
  59 AC_LIBTOOL_WIN32_DLL
  60 AM_PROG_LIBTOOL
  61
  62 dnl *** required versions of GStreamer stuff ***
  63 GST_REQ=0.10.31
  64
  65 dnl *** autotools stuff ****
  66
  67 dnl allow for different autotools
  68 AS_AUTOTOOLS_ALTERNATE
  69
  70 dnl Add parameters for aclocal
  71 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  72
  73 dnl set up gettext
  74 dnl the version check needs to stay here because autopoint greps for it
  75 AM_GNU_GETTEXT_VERSION([0.17])
  76 AM_GNU_GETTEXT([external])
  77 AG_GST_GETTEXT([gst-plugins-base-$GST_MAJORMINOR])
  78
  79 dnl *** check for arguments to configure ***
  80
  81 AG_GST_ARG_DEBUG
  82 AG_GST_ARG_PROFILING
  83 AG_GST_ARG_VALGRIND
  84 AG_GST_ARG_GCOV
  85
  86 AG_GST_ARG_EXAMPLES
  87
  88 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  89 AG_GST_ARG_WITH_PACKAGE_NAME
  90 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  91
  92 AG_GST_PKG_CONFIG_PATH
  93
  94 dnl let distro override plugin install helper path
  95 AC_ARG_WITH(install-plugins-helper,
  96   AC_HELP_STRING([--with-install-plugins-helper],
  97     [specify path of helper script to call to install plugins]),
  98   [
  99     case "${withval}" in
 100       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 101       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 102       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
 103     esac
 104   ],
 105   [
 106     dnl Default value
 107     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 108   ]
 109 )
 110 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 111 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 112     [plugin install helper script])
 113 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 114
 115 AG_GST_ARG_WITH_PLUGINS
 116
 117 AG_GST_ARG_ENABLE_EXTERNAL
 118
 119 AG_GST_ARG_ENABLE_EXPERIMENTAL
 120
 121 dnl *** checks for platform ***
 122
 123 dnl * hardware/architecture *
 124
 125 dnl common/m4/gst-arch.m4
 126 dnl check CPU type
 127 AG_GST_ARCH
 128
 129 dnl check for large file support
 130 dnl affected plugins must include config.h
 131 AC_SYS_LARGEFILE
 132
 133 dnl *** checks for programs ***
 134
 135 dnl find a compiler
 136 AC_PROG_CC
 137 AC_PROG_CC_STDC
 138 AC_PROG_CXX
 139
 140 dnl determine if c++ is available on this system
 141 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 142
 143 dnl determine c++ preprocessor
 144 dnl FIXME: do we need this ?
 145 AC_PROG_CXXCPP
 146
 147 dnl check if the compiler supports '-c' and '-o' options
 148 AM_PROG_CC_C_O
 149
 150 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 151 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 152
 153 dnl check for gobject-introspection
 154 GOBJECT_INTROSPECTION_CHECK([0.6.3])
 155
 156 dnl check for documentation tools
 157 GTK_DOC_CHECK([1.3])
 158 AS_PATH_PYTHON([2.1])
 159 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 160
 161 dnl *** checks for libraries ***
 162
 163 dnl libm, for sin() etc.
 164 AC_CHECK_LIBM
 165 AC_SUBST(LIBM)
 166
 167 dnl *** checks for header files ***
 168
 169 dnl check if we have ANSI C header files
 170 AC_HEADER_STDC
 171
 172 dnl used in gst/ffmpegcolorspace/mem.c
 173 dnl FIXME: could be fixed by redefining av_malloc and av_free to GLib's
 174 AC_CHECK_HEADERS([malloc.h])
 175
 176 ac_cppflags_save="$CPPFLAGS"
 177 CPPFLAGS="`$PKG_CONFIG --cflags libxml-2.0`"
 178 AC_COMPILE_IFELSE(
 179   AC_LANG_PROGRAM([
 180 #include <libxml/HTMLparser.h>
 181                      ],[
 182 #ifndef LIBXML_HTML_ENABLED
 183 #error libxml2 has no HTML support
 184 #endif /* LIBXML_HTML_ENABLED */
 185                    ]), HAVE_LIBXML_HTML="yes", HAVE_LIBXML_HTML="no")
 186 CPPFLAGS="$ac_cppflags_save"
 187 AM_CONDITIONAL(HAVE_LIBXML_HTML, test "x$HAVE_LIBXML_HTML" = "xyes")
 188
 189 dnl used in gst/tcp
 190 AC_CHECK_HEADERS([sys/socket.h],
 191   HAVE_SYS_SOCKET_H="yes", HAVE_SYS_SOCKET_H="no")
 192 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 193
 194 dnl used in gst-libs/gst/rtsp
 195 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 196 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 197   WIN32_LIBS="-lws2_32"
 198   AC_SUBST(WIN32_LIBS)
 199 fi
 200
 201 dnl check for hstrerror, for gst-libs/gst/rtsp
 202 save_libs="$LIBS"
 203 AC_CHECK_FUNC(hstrerror, ,
 204     AC_CHECK_LIB(resolv, hstrerror, ,
 205         [AC_DEFINE(NO_HSTRERROR, 1,
 206              [Define if you have no native hstrerror() function.])]))
 207 HSTRERROR_LIBS=$LIBS
 208 AC_SUBST(HSTRERROR_LIBS)
 209 LIBS="$save_libs"
 210
 211 dnl used in gst-libs/gst/pbutils and associated unit test
 212 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h])
 213
 214 dnl ffmpegcolorspace includes _stdint.h
 215 dnl also, Windows does not have long long
 216 AX_CREATE_STDINT_H
 217
 218 dnl *** checks for functions ***
 219 AC_CHECK_FUNCS([localtime_r gmtime_r])
 220
 221 dnl *** checks for math functions ***
 222 LIBS_SAVE=$LIBS
 223 LIBS="$LIBS $LIBM"
 224 AC_CHECK_FUNCS(log2)
 225 LIBS=$LIBS_SAVE
 226
 227 dnl *** checks for types/defines ***
 228
 229 dnl Check for FIONREAD ioctl declaration
 230 dnl used in gst/tcp
 231 GST_CHECK_FIONREAD
 232
 233 dnl *** checks for structures ***
 234
 235 dnl *** checks for compiler characteristics ***
 236
 237 dnl *** checks for library functions ***
 238
 239 dnl check for fseeko()
 240 AC_FUNC_FSEEKO
 241
 242 dnl Check for fast float to int casting as defined in C99
 243 dnl used in gst-libs/gst/floatcast/floatcast.h
 244 save_libs=$LIBS
 245 LIBS="$LIBS $LIBM"
 246 AC_C99_FUNC_LRINT
 247 AC_C99_FUNC_LRINTF
 248 LIBS=$save_libs
 249
 250 dnl Check for a way to display the function name in debug output
 251 AG_GST_CHECK_FUNCTION
 252
 253 dnl *** checks for socket and nsl libraries ***
 254 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 255 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
 256
 257 dnl *** checks for dependency libraries ***
 258
 259 dnl GLib is required
 260 AG_GST_GLIB_CHECK([2.20])
 261
 262 ORC_CHECK([0.4.11])
 263
 264 dnl checks for gstreamer
 265 dnl uninstalled is selected preferentially -- see pkg-config(1)
 266 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 267 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 268 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ], yes)
 269 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 270 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 271 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 272
 273 dnl Check for documentation xrefs
 274 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 275 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 276 AC_SUBST(GLIB_PREFIX)
 277 AC_SUBST(GST_PREFIX)
 278
 279 dnl GTK is optional and only used in examples
 280 HAVE_GTK=no
 281 HAVE_GTK_X11=no
 282 GTK2_REQ=2.14.0
 283 GTK3_REQ=2.91.3
 284 if test "x$BUILD_EXAMPLES" = "xyes"; then
 285   AC_MSG_CHECKING([which gtk+ version to compile examples against (optional)])
 286   AC_ARG_WITH([gtk],
 287     AC_HELP_STRING([--with-gtk=3.0|2.0],
 288                    [which gtk+ version to compile against (default: 2.0)]),
 289     [case "$with_gtk" in
 290         2.0) GTK_REQ=$GTK2_REQ ;;
 291         3.0) GTK_REQ=$GTK3_REQ ;;
 292         *) AC_MSG_ERROR([invalid gtk+ version specified]);;
 293     esac],
 294     [with_gtk=2.0
 295      GTK_REQ=$GTK2_REQ])
 296   AC_MSG_RESULT([$with_gtk (>= $GTK_REQ)])
 297   PKG_CHECK_MODULES(GTK, gtk+-$with_gtk >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 298   dnl some examples need gtk+-x11
 299   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-$with_gtk >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 300   AC_SUBST(GTK_LIBS)
 301   AC_SUBST(GTK_CFLAGS)
 302 fi
 303 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 304 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 305
 306 dnl QT is optional and only used in examples
 307 PKG_CHECK_MODULES(QT, QtGui >= 4.6, [
 308   HAVE_QT_GV=yes
 309   HAVE_QT=yes
 310 ], [
 311   HAVE_QT_GV=no
 312   PKG_CHECK_MODULES(QT, QtGui >= 4.0, HAVE_QT=yes, HAVE_QT=no)
 313 ])
 314 if test "x$HAVE_QT" = "xyes"; then
 315   AC_MSG_CHECKING([Qt moc])
 316   QT4_MOC=`$PKG_CONFIG --variable=moc_location QtGui`
 317   AC_MSG_RESULT($QT4_MOC)
 318   AC_SUBST(QT4_MOC)
 319 fi
 320 AM_CONDITIONAL(HAVE_QT, test "x$HAVE_QT" = "xyes")
 321 AM_CONDITIONAL(HAVE_QT_GV, test "x$HAVE_QT_GV" = "xyes")
 322
 323 dnl chck for linux headers needed by the joystick seek example
 324 AC_COMPILE_IFELSE(
 325 [
 326   AC_LANG_PROGRAM([
 327     #include <linux/input.h>
 328     #include <linux/joystick.h>
 329   ],[
 330     struct js_event js;
 331     js.type = JS_EVENT_AXIS;
 332   ])
 333 ], [
 334   HAVE_LINUX_JOYSTICK_HEADERS="yes"
 335 ], [
 336   HAVE_LINUX_JOYSTICK_HEADERS="no"
 337 ])
 338 AM_CONDITIONAL(HAVE_LINUX_JOYSTICK_HEADERS, test "x$HAVE_LINUX_JOYSTICK_HEADERS" = "xyes")
 339
 340 dnl *** set variables based on configure arguments ***
 341
 342 dnl set license and copyright notice
 343 GST_LICENSE="LGPL"
 344 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 345 AC_SUBST(GST_LICENSE)
 346
 347 dnl set location of plugin directory
 348 AG_GST_SET_PLUGINDIR
 349
 350 dnl set release date/time
 351 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 352   ["${srcdir}/gst-plugins-base.doap"],
 353   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 354
 355 dnl define an ERROR_CFLAGS Makefile variable
 356 dnl -Wformat-nonliteral - see ext/pango/gstclockoverlay.c and http://gcc.gnu.org/bugzilla/show_bug.cgi?id=39438
 357 AG_GST_SET_ERROR_CFLAGS($GST_GIT, [
 358     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef
 359     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 360     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 361     -Wno-multichar -Wnested-externs ])
 362
 363 dnl define an ERROR_CXXFLAGS Makefile variable
 364 AG_GST_SET_ERROR_CXXFLAGS($GST_GIT, [
 365     -Wmissing-declarations -Wredundant-decls -Wundef
 366     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 367     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 368     -Wno-multichar])
 369
 370 dnl define correct level for debugging messages
 371 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 372
 373 dnl used in examples
 374 AG_GST_DEFAULT_ELEMENTS
 375
 376 dnl behaviour of speex based audio resampler
 377 AC_MSG_CHECKING(which audio resample format to use for integer)
 378 AC_ARG_WITH([audioresample_format],
 379         AS_HELP_STRING([--with-audioresample-format],[Which implementation should be used for integer audio resampling, int/float/auto, (default is auto)]),
 380         [ac_cv_audioresample_format=$withval], [ac_cv_audioresample_format=auto])dnl
 381 AC_MSG_RESULT($ac_cv_audioresample_format)
 382 case $ac_cv_audioresample_format in
 383   int)
 384     AC_DEFINE(AUDIORESAMPLE_FORMAT_INT,1,[The int implementation should be used for integer audio resampling])
 385     AC_SUBST(AUDIORESAMPLE_FORMAT_INT)
 386   ;;
 387   float)
 388     AC_DEFINE(AUDIORESAMPLE_FORMAT_FLOAT,1,[The float implementation should be used for integer audio resampling])
 389     AC_SUBST(AUDIORESAMPLE_FORMAT_FLOAT)
 390   ;;
 391   auto)
 392     AC_DEFINE(AUDIORESAMPLE_FORMAT_AUTO,1,[The implementation that should be used for integer audio resampling witll be benchmarked at runtime])
 393     AC_SUBST(AUDIORESAMPLE_FORMAT_AUTO)
 394 esac
 395
 396 dnl *** plug-ins to include ***
 397
 398 dnl these are all the gst plug-ins, compilable without additional libs
 399 AG_GST_CHECK_PLUGIN(adder)
 400 AG_GST_CHECK_PLUGIN(app)
 401 AG_GST_CHECK_PLUGIN(audioconvert)
 402 AG_GST_CHECK_PLUGIN(audiorate)
 403 AG_GST_CHECK_PLUGIN(audiotestsrc)
 404 AG_GST_CHECK_PLUGIN(ffmpegcolorspace)
 405 AG_GST_CHECK_PLUGIN(gdp)
 406 AG_GST_CHECK_PLUGIN(playback)
 407 AG_GST_CHECK_PLUGIN(audioresample)
 408 AG_GST_CHECK_PLUGIN(subparse)
 409 AG_GST_CHECK_PLUGIN(tcp)
 410 AG_GST_CHECK_PLUGIN(typefind)
 411 AG_GST_CHECK_PLUGIN(videotestsrc)
 412 AG_GST_CHECK_PLUGIN(videorate)
 413 AG_GST_CHECK_PLUGIN(videoscale)
 414 AG_GST_CHECK_PLUGIN(volume)
 415
 416 dnl check for gstreamer core features (subsystems)
 417 dnl FIXME: this assumes srcdir == builddir for uninstalled setups
 418 GST_CONFIGPATH=`$PKG_CONFIG --variable=includedir gstreamer-0.10`"/gst/gstconfig.h"
 419 AG_GST_PARSE_SUBSYSTEM_DISABLES($GST_CONFIGPATH)
 420 AM_CONDITIONAL(USE_XML, test $GST_DISABLE_XML != "1")
 421
 422 dnl disable plug-ins that require libxml2's HTML support if it is not available
 423 if test "x$HAVE_LIBXML_HTML" != "xyes"; then
 424   AG_GST_DISABLE_PLUGIN(subparse)
 425 fi
 426
 427 dnl disable plug-ins that require sys/socket.h if it is not available
 428 if test "x$HAVE_SYS_SOCKET_H" != "xyes"; then
 429   AG_GST_DISABLE_PLUGIN(tcp)
 430 fi
 431
 432 dnl iso-codes is optional, used by libgsttag
 433 AC_ARG_ENABLE(iso-codes,
 434 AC_HELP_STRING([--enable-iso-codes],[use iso-codes if installed]),
 435 [case "${enableval}" in
 436   yes) enable_iso_codes=yes ;;
 437   no)  enable_iso_codes=no ;;
 438   *) AC_MSG_ERROR(bad value ${enableval} for --enable-iso-codes) ;;
 439 esac
 440 ],
 441 [enable_iso_codes=yes]) dnl Default value
 442
 443 AC_MSG_CHECKING([whether to use iso-codes if they are available])
 444 if test "x$enable_iso_codes" = "xyes"; then
 445   AC_MSG_RESULT([yes])
 446   have_iso_codes=no
 447   AC_MSG_CHECKING([whether iso-codes are available on this system])
 448   if $PKG_CONFIG iso-codes; then
 449     AC_MSG_RESULT([yes])
 450     AC_MSG_CHECKING([whether iso-codes has iso-639 domain])
 451     if $PKG_CONFIG --variable=domains iso-codes | $GREP -q 639 ; then
 452       AC_MSG_RESULT([yes])
 453       AC_MSG_CHECKING([for iso-codes prefix])
 454       ISO_CODES_PREFIX=`$PKG_CONFIG --variable=prefix iso-codes`
 455       if test -d "$ISO_CODES_PREFIX"; then
 456         AC_MSG_RESULT([yes])
 457         AC_MSG_CHECKING([ISO_CODES_PREFIX])
 458         AC_MSG_RESULT([$ISO_CODES_PREFIX])
 459         ISO_639_DOMAIN="iso_639"
 460         AC_MSG_CHECKING([ISO_639_DOMAIN])
 461         AC_MSG_RESULT([$ISO_639_DOMAIN])
 462         have_iso_codes=yes
 463         AC_DEFINE([HAVE_ISO_CODES], [1], [make use of iso-codes for ISO-639])
 464         AC_DEFINE_UNQUOTED([ISO_CODES_PREFIX], ["$ISO_CODES_PREFIX"], [prefix])
 465         ISO_CODES_VERSION=`$PKG_CONFIG --modversion iso-codes`
 466         AC_DEFINE_UNQUOTED([ISO_CODES_VERSION], ["$ISO_CODES_VERSION"], [ ])
 467       else
 468         AC_MSG_RESULT([no])
 469       fi
 470     else
 471       AC_MSG_RESULT([no])
 472     fi
 473   else
 474     AC_MSG_RESULT([no])
 475   fi
 476   AM_CONDITIONAL(USE_ISO_CODES, test "x$have_iso_codes" = "xyes")
 477 else
 478   AC_MSG_RESULT([no (disabled via --disable-iso-codes)])
 479   AM_CONDITIONAL(USE_ISO_CODES, false)
 480 fi
 481
 482 dnl *** sys plug-ins ***
 483
 484 echo
 485 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 486 echo
 487
 488 dnl *** X11 ***
 489 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 490 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 491                   [ximagesink], [
 492   AC_PATH_XTRA
 493   ac_cflags_save="$CFLAGS"
 494   ac_cppflags_save="$CPPFLAGS"
 495   CFLAGS="$CFLAGS $X_CFLAGS"
 496   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 497
 498   dnl now try to find the HEADER
 499   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 500
 501   if test "x$HAVE_X" = "xno"
 502   then
 503     AC_MSG_NOTICE([cannot find X11 development files])
 504   else
 505     dnl this is much more than we want
 506     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 507     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 508     dnl it does not add the libs; therefore we add them here
 509     X_LIBS="$X_LIBS -lX11"
 510     AC_SUBST(X_CFLAGS)
 511     AC_SUBST(X_LIBS)
 512   fi
 513   AC_SUBST(HAVE_X)
 514   CFLAGS="$ac_cflags_save"
 515   CPPFLAGS="$ac_cppflags_save"
 516 ])
 517
 518 dnl Check for Xv extension
 519 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 520 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 521                   [xvimagesink], [
 522   AG_GST_CHECK_XV
 523 ])
 524
 525 dnl check for X Shm
 526 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 527 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 528   if test x$HAVE_X = xyes; then
 529     AC_CHECK_LIB(Xext, XShmAttach,
 530                  HAVE_XSHM="yes", HAVE_XSHM="no",
 531                  $X_LIBS)
 532     if test "x$HAVE_XSHM" = "xyes"; then
 533       XSHM_LIBS="-lXext"
 534     else
 535       dnl On AIX, it is in XextSam instead, but we still need -lXext
 536       AC_CHECK_LIB(XextSam, XShmAttach,
 537                    HAVE_XSHM="yes", HAVE_XSHM="no",
 538                    $X_LIBS)
 539       if test "x$HAVE_XSHM" = "xyes"; then
 540         XSHM_LIBS="-lXext -lXextSam"
 541       fi
 542     fi
 543   fi
 544 ], , [
 545   AC_SUBST(HAVE_XSHM)
 546   AC_SUBST(XSHM_LIBS)
 547 ])
 548
 549 dnl v4l/v4l2 checks have been moved down because they require X
 550
 551 dnl *** Video 4 Linux ***
 552 dnl for information about the header/define, see sys/v4l/gstv4lelement.h
 553 dnl renamed to GST_V4L in accordance with V4L2 below
 554 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L, true)
 555 AG_GST_CHECK_FEATURE(GST_V4L, [Video 4 Linux], video4linux, [
 556   AC_CHECK_DECL(VID_TYPE_MPEG_ENCODER, HAVE_GST_V4L="yes", HAVE_GST_V4L="no", [
 557 #include <sys/types.h>
 558 #define _LINUX_TIME_H
 559 #define __user
 560 #include <linux/videodev.h>
 561   ])
 562
 563   dnl we can build v4l without Xv, but then we won't have XOverlay support
 564   if test "x$HAVE_GST_V4L" = "xyes" -a "x$HAVE_XVIDEO" != "xyes"
 565   then
 566     AC_MSG_NOTICE([NO XVIDEO FOUND, VIDEO4LINUX WILL BE BUILT])
 567     AC_MSG_NOTICE([WITHOUT XOVERLAY SUPPORT])
 568   fi
 569 ])
 570
 571 # Optional gudev for device probing
 572 AC_ARG_WITH([gudev],
 573   AC_HELP_STRING([--with-gudev],
 574     [device detection with gudev]),
 575   [],
 576   [with_gudev=check])
 577 if test x$HAVE_GST_V4L = xyes; then
 578   if test x$with_gudev != xno; then
 579       PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 143 ],
 580           [ have_gudev=yes
 581             AC_DEFINE(HAVE_GUDEV, 1,
 582                [Whether gudev is available for device detection])
 583             AC_DEFINE([G_UDEV_API_IS_SUBJECT_TO_CHANGE], 1, [I know the API is subject to change.])
 584           ], [
 585           have_gudev=no
 586           ])
 587   else
 588     have_gudev=no
 589   fi
 590 fi
 591 AC_SUBST(GUDEV_CFLAGS)
 592 AC_SUBST(GUDEV_LIBS)
 593
 594 dnl *** ext plug-ins ***
 595 dnl keep this list sorted alphabetically !
 596
 597 if test "x$BUILD_EXTERNAL" = "xyes"; then
 598
 599 echo
 600 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 601 echo
 602
 603 dnl *** alsa ***
 604 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 605 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 606   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 607     HAVE_ALSA="yes"
 608     AC_SUBST(ALSA_CFLAGS)
 609     AC_SUBST(ALSA_LIBS)
 610   ], [
 611     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 612   ])
 613 ])
 614
 615 dnl *** CDParanoia ***
 616 dnl Note: upstream has a pkg-config file only in post-10.2 SVN so far
 617 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 618 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 619   PKG_CHECK_MODULES(CDPARANOIA, cdparanoia-3 >= 10.2, [
 620     HAVE_CDPARANOIA="yes"
 621   ], [
 622     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 623                         cdda_open, -lm,
 624                         cdda_interface.h,
 625                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 626                         HEADER_DIR="no"
 627                         FOUND_CDPARANOIA="yes")
 628     if test "x$FOUND_CDPARANOIA" != "xyes";
 629     then
 630       AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 631                           cdda_open, -lm,
 632                           cdda/cdda_interface.h,
 633                           CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 634                           HEADER_DIR="yes"
 635                           FOUND_CDPARANOIA="yes")
 636     fi
 637     if test "x$HEADER_DIR" = "xyes";
 638     then
 639       AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 640                          defined if cdda headers are in a cdda/ directory)
 641     fi
 642     if test "x$FOUND_CDPARANOIA" = "xyes";
 643     then
 644       AC_CHECK_LIB(cdda_paranoia,
 645                    paranoia_cachemodel_size,
 646                    : ,
 647                    HAVE_CDPARANOIA=no,
 648                  [-lcdda_interface])
 649     fi
 650
 651     AC_SUBST(CDPARANOIA_LIBS)
 652   ])
 653 ])
 654 dnl FIXME : add second check somehow if that is necessary
 655 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 656 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 657
 658 dnl *** GNOME VFS ***
 659 translit(dnm, m, l) AM_CONDITIONAL(USE_GNOME_VFS, true)
 660 AG_GST_CHECK_FEATURE(GNOME_VFS, [GNOME VFS], gnomevfs, [
 661   PKG_CHECK_MODULES(GNOME_VFS, gnome-vfs-2.0, [
 662       HAVE_GNOME_VFS="yes"
 663       AC_SUBST(GNOME_VFS_CFLAGS)
 664       AC_SUBST(GNOME_VFS_LIBS)
 665       GNOME_VFS_MODULES_DIR="`$PKG_CONFIG --variable=modulesdir gnome-vfs-2.0`"
 666       AC_DEFINE_UNQUOTED(GNOME_VFS_MODULES_DIR, "$GNOME_VFS_MODULES_DIR",
 667              [The GnomeVFS modules directory.])
 668     ],[
 669       HAVE_GNOME_VFS="no"
 670     ]
 671     )
 672 ])
 673
 674 dnl *** ivorbis ***
 675 dnl AM_PATH_IVORBIS only takes two options
 676 translit(dnm, m, l) AM_CONDITIONAL(USE_IVORBIS, true)
 677 AG_GST_CHECK_FEATURE(IVORBIS, [integer vorbis plug-in], ivorbisdec, [
 678   AG_GST_PKG_CHECK_MODULES(IVORBIS, vorbisidec)
 679   if test $HAVE_IVORBIS = no
 680   then
 681     IVORBIS_LIBS=
 682     IVORBIS_CFLAGS=
 683     AC_CHECK_LIB(vorbisidec, vorbis_block_init,
 684       [IVORBIS_LIBS=-lvorbisidec
 685       HAVE_IVORBIS=yes
 686       case $host in
 687       arm-*-*)
 688         IVORBIS_CFLAGS="-D_ARM_ASSEM_ $IVORBIS_CFLAGS"
 689       esac
 690       ],
 691       HAVE_IVORBIS=no)
 692     AC_SUBST(IVORBIS_LIBS)
 693     AC_SUBST(IVORBIS_CFLAGS)
 694   fi
 695 ])
 696
 697 dnl *** libgio ***
 698 translit(dnm, m, l) AM_CONDITIONAL(USE_GIO, true)
 699 AG_GST_CHECK_FEATURE(GIO, [GIO library], gio, [
 700   PKG_CHECK_MODULES(GIO, gio-2.0 >= 2.16, [
 701     HAVE_GIO="yes"
 702     GIO_MODULE_DIR="`$PKG_CONFIG --variable=giomoduledir gio-2.0`"
 703     AC_DEFINE_UNQUOTED(GIO_MODULE_DIR, "$GIO_MODULE_DIR",
 704            [The GIO modules directory.])
 705     GIO_LIBDIR="`$PKG_CONFIG --variable=libdir gio-2.0`"
 706     AC_DEFINE_UNQUOTED(GIO_LIBDIR, "$GIO_LIBDIR",
 707            [The GIO library directory.])
 708   ], [
 709     HAVE_GIO="no"
 710     AC_MSG_RESULT(no)
 711   ])
 712   AC_SUBST(GIO_CFLAGS)
 713   AC_SUBST(GIO_LIBS)
 714   AC_SUBST(GIO_LDFLAGS)
 715 ])
 716
 717 dnl *** libvisual ***
 718 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 719 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 720   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 721   if test $HAVE_LIBVISUAL = no
 722   then
 723     AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0)
 724     if test x$HAVE_LIBVISUAL = xyes; then
 725       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.2`"
 726     fi
 727   else
 728     if test x$HAVE_LIBVISUAL = xyes; then
 729       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.4`"
 730     fi
 731   fi
 732   AC_MSG_NOTICE([libvisual pluginsdir: $LIBVIS_PLUGINSDIR])
 733   if test x$LIBVIS_PLUGINSDIR != x; then
 734     AC_DEFINE_UNQUOTED(LIBVISUAL_PLUGINSBASEDIR,
 735         "$LIBVIS_PLUGINSDIR",
 736         [directory in which the detected libvisual's plugins are located])
 737   fi
 738 ])
 739
 740 dnl *** ogg ***
 741 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 742 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 743   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 744   if test $HAVE_OGG = no
 745   then
 746     XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
 747     AS_SCRUB_INCLUDE(OGG_CFLAGS)
 748   fi
 749 ])
 750
 751 dnl *** pango ***
 752 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 753 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 754   AG_GST_PKG_CHECK_MODULES(PANGO, pango >= 1.16.0  pangocairo >= 1.16.0)
 755 ])
 756
 757 dnl *** theora ***
 758 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 759 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 760   AG_GST_PKG_CHECK_MODULES(THEORA, theoradec >= 1.1 theoraenc >= 1.1)
 761 ])
 762
 763 dnl *** vorbis ***
 764 dnl AM_PATH_VORBIS only takes two options
 765 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 766 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 767   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 768   if test $HAVE_VORBIS = no
 769   then
 770     XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
 771     AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
 772   fi
 773 ])
 774
 775 if test "x$HAVE_VORBIS" = "xyes"; then
 776   ac_cflags_save="$CFLAGS"
 777   AC_COMPILE_IFELSE(
 778     AC_LANG_PROGRAM([
 779 #include <vorbis/codec.h>
 780                      ],[
 781 vorbis_dsp_state *v;
 782
 783 vorbis_synthesis_restart (v);
 784                      ]), HAVE_VSR=yes, HAVE_VSR=no)
 785   if test "x$HAVE_VSR" = "xyes"; then
 786     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 787                        [defined if vorbis_synthesis_restart is present])
 788   fi
 789   CFLAGS="$ac_cflags_save"
 790 fi
 791
 792 else
 793
 794 dnl not building plugins with external dependencies,
 795 dnl but we still need to set the conditionals
 796 AM_CONDITIONAL(USE_ALSA, false)
 797 AM_CONDITIONAL(USE_CDPARANOIA, false)
 798 AM_CONDITIONAL(USE_GIO, false)
 799 AM_CONDITIONAL(USE_GNOME_VFS, false)
 800 AM_CONDITIONAL(USE_IVORBIS, false)
 801 AM_CONDITIONAL(USE_LIBVISUAL, false)
 802 AM_CONDITIONAL(USE_OGG, false)
 803 AM_CONDITIONAL(USE_PANGO, false)
 804 AM_CONDITIONAL(USE_THEORA, false)
 805 AM_CONDITIONAL(USE_VORBIS, false)
 806
 807 fi dnl of EXT plugins
 808
 809 dnl seeking needs freetype, so check for it here
 810 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 811   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 812 ])
 813 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 814 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 815 AC_SUBST(FT2_CFLAGS)
 816 AC_SUBST(FT2_LIBS)
 817
 818 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 819
 820 dnl Overview:
 821 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 822 dnl GST_*:              flags shared by built objects to link against GStreamer
 823 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 824 dnl                          (compare to other modules) or for i18n
 825 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 826 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 827 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 828 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 829
 830 dnl GST_OPTION_CFLAGS
 831 if test "x$USE_DEBUG" = xyes; then
 832    PROFILE_CFLAGS="-g"
 833 fi
 834 AC_SUBST(PROFILE_CFLAGS)
 835
 836 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 837   dnl Define _only_ when compiling a git version (not pre-releases or releases)
 838   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 839 else
 840   DEPRECATED_CFLAGS=""
 841 fi
 842 AC_SUBST(DEPRECATED_CFLAGS)
 843
 844 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 845 dnl at make time with e.g. make ERROR_CFLAGS=""
 846 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 847 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 848 AC_SUBST(GST_OPTION_CFLAGS)
 849 AC_SUBST(GST_OPTION_CXXFLAGS)
 850
 851 dnl our libraries need to be versioned correctly
 852 AC_SUBST(GST_LT_LDFLAGS)
 853
 854 dnl GST_PLUGINS_BASE_CFLAGS
 855 dnl prefer internal headers to already installed ones
 856 dnl also add builddir include for enumtypes and marshal
 857 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 858 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 859
 860 dnl FIXME: do we want to rename to GST_ALL_* ?
 861 dnl add GST_OPTION_CFLAGS, but overridable
 862 GST_CXXFLAGS="$GLIB_CFLAGS $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS)"
 863 GST_CFLAGS="$GLIB_CFLAGS $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
 864 AC_SUBST(GST_CFLAGS)
 865 AC_SUBST(GST_CXXFLAGS)
 866 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 867 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 868 AC_SUBST(GST_LIBS)
 869
 870 dnl LDFLAGS really should only contain flags, not libs - they get added before
 871 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 872 GST_ALL_LDFLAGS="-no-undefined"
 873 AC_SUBST(GST_ALL_LDFLAGS)
 874
 875 dnl GST_LIB_LDFLAGS
 876 dnl linker flags shared by all libraries
 877 dnl LDFLAGS modifier defining exported symbols from built libraries
 878 dnl (export _gst_foo but not __gst_foo)
 879 GST_LIB_LDFLAGS="-export-symbols-regex ^_?\(gst_\|Gst\|GST_\).*"
 880 AC_SUBST(GST_LIB_LDFLAGS)
 881
 882 dnl this really should only contain flags, not libs - they get added before
 883 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 884 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 885 AC_SUBST(GST_PLUGIN_LDFLAGS)
 886
 887 dnl *** output files ***
 888
 889 AC_CONFIG_FILES(
 890 Makefile
 891 gst-plugins-base.spec
 892 gst/Makefile
 893 gst/adder/Makefile
 894 gst/app/Makefile
 895 gst/audioconvert/Makefile
 896 gst/audiorate/Makefile
 897 gst/audiotestsrc/Makefile
 898 gst/ffmpegcolorspace/Makefile
 899 gst/gdp/Makefile
 900 gst/playback/Makefile
 901 gst/audioresample/Makefile
 902 gst/subparse/Makefile
 903 gst/tcp/Makefile
 904 gst/typefind/Makefile
 905 gst/videotestsrc/Makefile
 906 gst/videorate/Makefile
 907 gst/videoscale/Makefile
 908 gst/volume/Makefile
 909 sys/Makefile
 910 sys/ximage/Makefile
 911 sys/xvimage/Makefile
 912 sys/v4l/Makefile
 913 ext/Makefile
 914 ext/alsa/Makefile
 915 ext/cdparanoia/Makefile
 916 ext/gnomevfs/Makefile
 917 ext/gio/Makefile
 918 ext/libvisual/Makefile
 919 ext/ogg/Makefile
 920 ext/pango/Makefile
 921 ext/theora/Makefile
 922 ext/vorbis/Makefile
 923 gst-libs/Makefile
 924 gst-libs/gst/Makefile
 925 gst-libs/gst/audio/Makefile
 926 gst-libs/gst/app/Makefile
 927 gst-libs/gst/cdda/Makefile
 928 gst-libs/gst/fft/Makefile
 929 gst-libs/gst/floatcast/Makefile
 930 gst-libs/gst/interfaces/Makefile
 931 gst-libs/gst/netbuffer/Makefile
 932 gst-libs/gst/riff/Makefile
 933 gst-libs/gst/rtp/Makefile
 934 gst-libs/gst/rtsp/Makefile
 935 gst-libs/gst/sdp/Makefile
 936 gst-libs/gst/tag/Makefile
 937 gst-libs/gst/pbutils/Makefile
 938 gst-libs/gst/pbutils/gstpluginsbaseversion.h
 939 gst-libs/gst/video/Makefile
 940 tools/Makefile
 941 pkgconfig/Makefile
 942 pkgconfig/gstreamer-audio.pc
 943 pkgconfig/gstreamer-audio-uninstalled.pc
 944 pkgconfig/gstreamer-app.pc
 945 pkgconfig/gstreamer-app-uninstalled.pc
 946 pkgconfig/gstreamer-cdda.pc
 947 pkgconfig/gstreamer-cdda-uninstalled.pc
 948 pkgconfig/gstreamer-fft.pc
 949 pkgconfig/gstreamer-fft-uninstalled.pc
 950 pkgconfig/gstreamer-floatcast.pc
 951 pkgconfig/gstreamer-floatcast-uninstalled.pc
 952 pkgconfig/gstreamer-interfaces.pc
 953 pkgconfig/gstreamer-interfaces-uninstalled.pc
 954 pkgconfig/gstreamer-netbuffer.pc
 955 pkgconfig/gstreamer-netbuffer-uninstalled.pc
 956 pkgconfig/gstreamer-pbutils.pc
 957 pkgconfig/gstreamer-pbutils-uninstalled.pc
 958 pkgconfig/gstreamer-riff.pc
 959 pkgconfig/gstreamer-riff-uninstalled.pc
 960 pkgconfig/gstreamer-rtp.pc
 961 pkgconfig/gstreamer-rtp-uninstalled.pc
 962 pkgconfig/gstreamer-rtsp.pc
 963 pkgconfig/gstreamer-rtsp-uninstalled.pc
 964 pkgconfig/gstreamer-sdp.pc
 965 pkgconfig/gstreamer-sdp-uninstalled.pc
 966 pkgconfig/gstreamer-tag.pc
 967 pkgconfig/gstreamer-tag-uninstalled.pc
 968 pkgconfig/gstreamer-video.pc
 969 pkgconfig/gstreamer-video-uninstalled.pc
 970 pkgconfig/gstreamer-plugins-base.pc
 971 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 972 tests/Makefile
 973 tests/check/Makefile
 974 tests/examples/Makefile
 975 tests/examples/app/Makefile
 976 tests/examples/dynamic/Makefile
 977 tests/examples/gio/Makefile
 978 tests/examples/overlay/Makefile
 979 tests/examples/seek/Makefile
 980 tests/examples/snapshot/Makefile
 981 tests/examples/playrec/Makefile
 982 tests/examples/volume/Makefile
 983 tests/examples/v4l/Makefile
 984 tests/files/Makefile
 985 tests/icles/Makefile
 986 tests/icles/playback/Makefile
 987 docs/Makefile
 988 docs/design/Makefile
 989 docs/libs/Makefile
 990 docs/plugins/Makefile
 991 docs/version.entities
 992 po/Makefile.in
 993 common/Makefile
 994 common/m4/Makefile
 995 m4/Makefile
 996 )
 997
 998 dnl Create the config.h file for Visual Studio builds
 999 dnl Beware of spaces and /'s in some of the shell variable contents.
1000 sed \
1001     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
1002     -e 's/.* GST_INSTALL_PLUGINS_HELPER/#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
1003     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
1004     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
1005     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
1006     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
1007     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
1008     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
1009     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
1010     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
1011     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
1012     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
1013     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
1014     -e 's/.* HAVE_ISO_CODES$/#undef HAVE_ISO_CODES/' \
1015     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
1016     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
1017     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
1018     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
1019     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
1020     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
1021     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
1022     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
1023     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1024     -e 's/.* ISO_CODES_PREFIX$/#undef ISO_CODES_PREFIX/' \
1025     -e 's/.* ISO_CODES_VERSION$/#undef ISO_CODES_VERSION/' \
1026     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1027     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1028     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
1029     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1030     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
1031     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1032     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1033     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1034     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.10"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.10"\n#endif/' \
1035     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
1036     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1037     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directaudiosink\"/" \
1038     -e "s/.* DEFAULT_VIDEOSINK$/#define DEFAULT_VIDEOSINK \"directdrawsink\"/" \
1039     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1040     config.h.in >win32/common/config.h-new
1041
1042
1043
1044 AC_OUTPUT
1045
1046 AG_GST_OUTPUT_PLUGINS
1047 ORC_OUTPUT
1048