configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, cvs and prerelease does Werror too
   6 AC_INIT(GStreamer, 0.10.13.1,
   7     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
   8     gstreamer)
   9 AG_GST_INIT
  10
  11 dnl initialize automake
  12 AM_INIT_AUTOMAKE
  13
  14 dnl define PACKAGE_VERSION_* variables
  15 AS_VERSION
  16
  17 dnl check if this is a release version
  18 AS_NANO(GST_CVS="no", GST_CVS="yes")
  19
  20 dnl can autoconf find the source ?
  21 AC_CONFIG_SRCDIR([gst/gst.c])
  22
  23 dnl define the output header for config
  24 AM_CONFIG_HEADER([config.h])
  25
  26 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  27 AM_MAINTAINER_MODE
  28
  29 dnl sets host_* variables
  30 AC_CANONICAL_HOST
  31
  32 dnl our libraries and install dirs use major.minor as a version
  33 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  34 dnl we override it here for release candidates for a new series
  35 GST_MAJORMINOR=0.10
  36 AC_SUBST(GST_MAJORMINOR)
  37 AC_DEFINE_UNQUOTED(GST_MAJORMINOR, "$GST_MAJORMINOR",
  38   [library major.minor version])
  39
  40 dnl CURRENT, REVISION, AGE
  41 dnl - library source changed -> increment REVISION
  42 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  43 dnl - interfaces added -> increment AGE
  44 dnl - interfaces removed -> AGE = 0
  45 dnl sets GST_LT_LDFLAGS
  46 AS_LIBTOOL(GST, 12, 0, 12)
  47
  48 dnl FIXME: this macro doesn't actually work;
  49 dnl the generated libtool script has no support for the listed tags.
  50 dnl So this needs to be fixed first if we want to use this
  51 dnl AS_LIBTOOL_TAGS
  52
  53 AM_PROG_LIBTOOL
  54
  55 dnl *** autotools stuff ****
  56
  57 dnl allow for different autotools
  58 AS_AUTOTOOLS_ALTERNATE
  59
  60 dnl Add parameters for aclocal
  61 AC_SUBST(ACLOCAL_AMFLAGS, "-I common/m4")
  62
  63 dnl set up gettext
  64 dnl the version check needs to stay here because autopoint greps for it
  65 AM_GNU_GETTEXT_VERSION([0.11.5])
  66 AM_GNU_GETTEXT([external])
  67 AG_GST_GETTEXT([gstreamer-$GST_MAJORMINOR])
  68
  69 dnl *** check for arguments to configure ***
  70
  71 dnl subsystems - can influence other decisions so needs to be high up
  72 dnl we need to AM_CONDITIONAL them here for automake 1.6.x compatibility
  73 AG_GST_CHECK_SUBSYSTEM_DISABLE(GST_DEBUG,[debugging subsystem])
  74 AM_CONDITIONAL(GST_DISABLE_GST_DEBUG, test "x$GST_DISABLE_GST_DEBUG" = "xyes")
  75 AG_GST_CHECK_SUBSYSTEM_DISABLE(LOADSAVE,[pipeline XML load/save])
  76 AM_CONDITIONAL(GST_DISABLE_LOADSAVE, test "x$GST_DISABLE_LOADSAVE" = "xyes")
  77 dnl define a substitution to use in docs/gst/gstreamer.types
  78 if test "x$GST_DISABLE_LOADSAVE" = "xyes"
  79 then
  80   GST_LOADSAVE_DOC_TYPES="%"
  81 else
  82   GST_LOADSAVE_DOC_TYPES=
  83 fi
  84 AC_SUBST(GST_LOADSAVE_DOC_TYPES)
  85 AG_GST_CHECK_SUBSYSTEM_DISABLE(PARSE,[command-line parser])
  86 AM_CONDITIONAL(GST_DISABLE_PARSE, test "x$GST_DISABLE_PARSE" = "xyes")
  87 if test "x$GST_DISABLE_PARSE" = xyes; then
  88   AC_DEFINE(GST_DISABLE_PARSE, 1,
  89     [Define if pipeline parsing code is disabled])
  90 fi
  91 AG_GST_CHECK_SUBSYSTEM_DISABLE(TRACE,[tracing subsystem])
  92 AM_CONDITIONAL(GST_DISABLE_TRACE, test "x$GST_DISABLE_TRACE" = "xyes")
  93 AG_GST_CHECK_SUBSYSTEM_DISABLE(ALLOC_TRACE,[allocation tracing])
  94 AM_CONDITIONAL(GST_DISABLE_ALLOC_TRACE, test "x$GST_DISABLE_ALLOC_TRACE" = "xyes")
  95 AG_GST_CHECK_SUBSYSTEM_DISABLE(REGISTRY,[plugin registry])
  96 AM_CONDITIONAL(GST_DISABLE_REGISTRY, test "x$GST_DISABLE_REGISTRY" = "xyes")
  97 dnl define a substitution to use in docs/gst/gstreamer.types
  98 if test "x$GST_DISABLE_REGISTRY" = "xyes"
  99 then
 100   GST_REGISTRY_DOC_TYPES="%"
 101 else
 102   GST_REGISTRY_DOC_TYPES=
 103 fi
 104 AC_SUBST(GST_REGISTRY_DOC_TYPES)
 105 AG_GST_CHECK_SUBSYSTEM_DISABLE(ENUMTYPES,[enum types])
 106 AM_CONDITIONAL(GST_DISABLE_ENUMTYPES, test "x$GST_DISABLE_ENUMTYPES" = "xyes")
 107 AG_GST_CHECK_SUBSYSTEM_DISABLE(INDEX,[index])
 108 AM_CONDITIONAL(GST_DISABLE_INDEX, test "x$GST_DISABLE_INDEX" = "xyes")
 109 AG_GST_CHECK_SUBSYSTEM_DISABLE(NET,[network distribution])
 110 AM_CONDITIONAL(GST_DISABLE_NET, test "x$GST_DISABLE_NET" = "xyes")
 111 AG_GST_CHECK_SUBSYSTEM_DISABLE(PLUGIN,[plugin])
 112 AM_CONDITIONAL(GST_DISABLE_PLUGIN, test "x$GST_DISABLE_PLUGIN" = "xyes")
 113 AG_GST_CHECK_SUBSYSTEM_DISABLE(URI,[uri handlers])
 114 AM_CONDITIONAL(GST_DISABLE_URI, test "x$GST_DISABLE_URI" = "xyes")
 115
 116 AG_GST_ARG_DEBUG
 117 AG_GST_ARG_PROFILING
 118 AG_GST_ARG_VALGRIND
 119 AG_GST_ARG_GCOV
 120
 121 AG_GST_ARG_EXAMPLES
 122
 123 AG_GST_ARG_WITH_PKG_CONFIG_PATH
 124 AG_GST_ARG_WITH_PACKAGE_NAME
 125 AG_GST_ARG_WITH_PACKAGE_ORIGIN
 126
 127 dnl use a cache dir for storing element registry info.
 128 GST_CACHE_DIR=${localstatedir}/cache/gstreamer-$GST_MAJORMINOR
 129
 130 AC_ARG_WITH(cachedir,
 131   AC_HELP_STRING([--with-cachedir],
 132     [specify path to use for plugin and command completion registries]),
 133   [
 134     case "${withval}" in
 135       yes) AC_MSG_ERROR(bad value ${withval} for --with-cachedir) ;;
 136       no)  AC_MSG_ERROR(bad value ${withval} for --with-cachedir) ;;
 137       *)   GST_CACHE_DIR="${withval}" ;;
 138     esac
 139   ],
 140   [:]) dnl Default value
 141
 142 AS_AC_EXPAND(GST_CACHE_DIR, $GST_CACHE_DIR)
 143 AC_DEFINE_UNQUOTED(GST_CACHE_DIR, "$GST_CACHE_DIR", [Location of registry])
 144 AC_MSG_NOTICE(Using $GST_CACHE_DIR as registry cache dir)
 145
 146 dnl building of tests
 147 AC_ARG_ENABLE(tests,
 148   AC_HELP_STRING([--disable-tests], [disable building test apps]),
 149   [
 150     case "${enableval}" in
 151       yes) BUILD_TESTS=yes ;;
 152       no)  BUILD_TESTS=no ;;
 153       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 154     esac
 155   ],
 156 [BUILD_TESTS=yes]) dnl Default value
 157 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 158
 159 dnl tests known to fail
 160 AC_ARG_ENABLE(failing-tests,
 161   AC_HELP_STRING([--disable-failing-tests],
 162     [disable building tests known to fail]),
 163   [
 164     case "${enableval}" in
 165       yes) BUILD_FAILING_TESTS=yes ;;
 166       no)  BUILD_FAILING_TESTS=no ;;
 167       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-failing-tests) ;;
 168     esac
 169   ],
 170   [BUILD_FAILING_TESTS=no]) dnl Default value
 171 AM_CONDITIONAL(BUILD_FAILING_TESTS, test "x$BUILD_FAILING_TESTS" = "xyes")
 172 if test x$BUILD_FAILING_TESTS = xyes; then
 173   AC_MSG_WARN([building tests known to fail, use --disable-failing-tests to disable])
 174 else
 175   AC_MSG_WARN([Sissy ! By asking to not build the tests known to fail, you hereby waive your right to customer support.  If you do not agree with this EULA, please press Ctrl-C before the next line is printed.  By allowing the next line to be printed, you expressly acknowledge your acceptance of this EULA.])
 176 fi
 177
 178 dnl poison destroyed objects
 179 AC_ARG_ENABLE(poisoning,
 180   AC_HELP_STRING([--enable-poisoning],
 181     [enable poisoning of deallocated objects]),
 182   [
 183     case "${enableval}" in
 184       yes) USE_POISONING=yes ;;
 185       no)  USE_POISONING=no ;;
 186       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-poisoning) ;;
 187     esac
 188   ],
 189   [USE_POISONING=no]) dnl Default value
 190 if test "x$USE_POISONING" = xyes; then
 191   AC_DEFINE(USE_POISONING, 1,
 192     [Define if we should poison deallocated memory])
 193 fi
 194
 195 dnl Use binary registry
 196 AC_ARG_ENABLE(binary-registry,
 197   AC_HELP_STRING([--enable-binary-registry],
 198     [enable experimental binary registry]),
 199   [
 200     case "${enableval}" in
 201       yes) USE_BINARY_REGISTRY=yes ;;
 202       no)  USE_BINARY_REGISTRY=no ;;
 203       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-binary-registry) ;;
 204     esac
 205   ],
 206   [USE_BINARY_REGISTRY=no]) dnl Default value
 207 if test "x$USE_BINARY_REGISTRY" = xyes; then
 208   AC_DEFINE(USE_BINARY_REGISTRY, 1,
 209     [Define if we should use binary registry instead xml registry])
 210 fi
 211 AM_CONDITIONAL(USE_BINARY_REGISTRY, test "x$USE_BINARY_REGISTRY" = "xyes")
 212
 213 dnl *** checks for platform ***
 214
 215 dnl * hardware/architecture *
 216
 217 dnl common/m4/gst-arch.m4
 218 dnl check CPU type
 219 AG_GST_ARCH
 220 dnl substitution for win32/common/config.h
 221 HOST_CPU=$host_cpu
 222 AC_SUBST(HOST_CPU)
 223
 224 dnl common/m4/gst-arch.m4
 225 dnl check for unaligned access
 226 AG_GST_UNALIGNED_ACCESS
 227 dnl create a configure variable for gst/gstconfig.h
 228 if test x${as_cv_unaligned_access} = xyes ; then
 229   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 1"
 230 else
 231   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 0"
 232 fi
 233 AC_SUBST(GST_HAVE_UNALIGNED_ACCESS_DEFINE)
 234
 235 dnl * software *
 236
 237 dnl check for large file support
 238 dnl affected plugins must include config.h
 239 AC_SYS_LARGEFILE
 240
 241 dnl HAVE_WIN32 currently means "disable POSIXisms".
 242 case "$host" in
 243   *-*-mingw*)
 244     AC_DEFINE_UNQUOTED(HAVE_WIN32, 1, [Defined if compiling for Windows])
 245     ;;
 246   *)
 247     ;;
 248 esac
 249
 250 dnl *** checks for programs ***
 251
 252 dnl find a compiler
 253 AC_PROG_CC
 254
 255 dnl find an assembler
 256 AM_PROG_AS
 257
 258 dnl Perl is used in building documentation and in the version checks
 259 AC_PATH_PROG(PERL_PATH, perl, no)
 260 if test x$PERL_PATH = xno; then
 261   AC_MSG_ERROR(Could not find perl)
 262 fi
 263
 264 dnl we require flex and bison for building the parser
 265 AG_GST_BISON_CHECK
 266 AG_GST_FLEX_CHECK
 267
 268 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 269 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 270
 271 dnl check for documentation tools
 272 AG_GST_DOCBOOK_CHECK
 273 GTK_DOC_CHECK([1.3])
 274 AS_PATH_PYTHON([2.1])
 275 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 276
 277 dnl *** checks for libraries ***
 278
 279 dnl For interactive UNIX (a Sun thing)
 280 dnl FIXME: this adds -lcposix to LIBS, but I doubt we use LIBS
 281 AC_ISC_POSIX
 282
 283 dnl *** checks for header files ***
 284
 285 dnl check if we have ANSI C header files
 286 AC_HEADER_STDC
 287
 288 dnl Check for ucontext.h
 289 AC_CHECK_HEADERS([ucontext.h])
 290
 291 dnl Check for sys/socket.h
 292 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 293 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 294
 295 dnl check for sys/times.h for tests/examples/adapter/
 296 AC_CHECK_HEADERS([sys/times.h], HAVE_SYS_TIMES_H=yes)
 297 AC_CHECK_HEADERS([unistd.h], HAVE_UNISTD_H=yes)
 298 AM_CONDITIONAL(HAVE_SYS_TIMES_H_AND_UNISTD_H, test "x$HAVE_SYS_TIMES_H" = "xyes" -a "x$HAVE_UNISTD_H" = "xyes")
 299
 300 dnl Check for process.h for getpid() on win32
 301 AC_CHECK_HEADERS([process.h])
 302
 303 dnl Check for sys/utsname.h for uname
 304 AC_CHECK_HEADERS([sys/utsname.h])
 305
 306 dnl *** checks for types/defines ***
 307
 308 dnl *** checks for structures ***
 309
 310 dnl *** checks for compiler characteristics ***
 311
 312 dnl make sure we can use "inline" from C code
 313 AC_C_INLINE
 314
 315 OPT_CFLAGS=
 316 dnl Check for some compiler flags that optimize our code.
 317 if test "x$GCC" = xyes; then
 318   AS_COMPILER_FLAG(-fno-common, OPT_CFLAGS="$OPT_CFLAGS -fno-common")
 319 fi
 320
 321 dnl FIXME: decide what kind of flag this is, maybe it's not an optimization
 322 dnl flag
 323 dnl check if we should use -Wa,-mregnames on PowerPC, so we can use
 324 dnl symbolic register names in inline asm
 325 if test x$HAVE_CPU_PPC = xyes ; then
 326   AS_COMPILER_FLAG(["-Wa,-mregnames"],
 327     [OPT_CFLAGS="$OPT_CFLAGS -Wa,-mregnames"])
 328 fi
 329
 330 dnl *** checks for library functions ***
 331
 332 AC_CHECK_FUNCS([sigaction])
 333
 334 dnl we use fork in the registry code
 335 AC_CHECK_FUNCS([fork])
 336
 337 dnl check for fseeko()
 338 AC_FUNC_FSEEKO
 339 dnl check for ftello()
 340 AC_CHECK_FUNCS([ftello])
 341
 342 AC_CHECK_FUNCS([fgetpos])
 343 AC_CHECK_FUNCS([fsetpos])
 344
 345 dnl check for mmap()
 346 AC_FUNC_MMAP
 347 AM_CONDITIONAL(HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 348
 349 dnl Check for a way to display the function name in debug output
 350 AG_GST_CHECK_FUNCTION
 351
 352 dnl test for register_printf_function
 353 AC_CHECK_FUNC(register_printf_function,
 354   [
 355     GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE="#define GST_PTR_FORMAT \"P\""
 356     GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE="#define GST_SEGMENT_FORMAT \"Q\""
 357     GST_USING_PRINTF_EXTENSION_DEFINE="#define GST_USING_PRINTF_EXTENSION"
 358     AC_DEFINE(HAVE_PRINTF_EXTENSION, 1,
 359       [Defined if we have register_printf_function ()])
 360   ], [
 361     GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE="#define GST_PTR_FORMAT \"p\""
 362     GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE="#define GST_SEGMENT_FORMAT \"p\""
 363     GST_USING_PRINTF_EXTENSION_DEFINE="#undef GST_USING_PRINTF_EXTENSION"
 364   ]
 365 )
 366 AC_SUBST(GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE)
 367 AC_SUBST(GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE)
 368 AC_SUBST(GST_USING_PRINTF_EXTENSION_DEFINE)
 369
 370 dnl test if we have dladdr(); we use it for debugging; see gst/gstinfo.c
 371 save_cflags="$CFLAGS"
 372 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 373 AC_CHECK_LIB(dl, dladdr,
 374    AC_DEFINE(HAVE_DLADDR, 1,
 375              [Defined if we have dladdr ()]))
 376 CFLAGS="$save_cflags"
 377
 378 dnl check for inet_aton()
 379 save_libs="$LIBS"
 380 AC_CHECK_FUNC(inet_aton, ,
 381    AC_CHECK_LIB(nsl, inet_aton, ,
 382       AC_CHECK_LIB(socket, inet_aton, ,
 383          AC_CHECK_LIB(resolv, inet_aton, ,[AC_DEFINE(NO_INET_ATON, 1, [Define if you have no native inet_aton() function.])]))))
 384 INET_ATON_LIBS=$LIBS
 385 AC_SUBST(INET_ATON_LIBS)
 386 LIBS="$save_libs"
 387
 388 dnl *** checks for dependency libraries ***
 389
 390 dnl GLib
 391
 392 AG_GST_GLIB_CHECK([2.8])
 393
 394 dnl FIXME: 0.11: Guess we need to keep this around until 0.11
 395 GST_HAVE_GLIB_2_8_DEFINE="#define GST_HAVE_GLIB_2_8 1"
 396 AC_SUBST(GST_HAVE_GLIB_2_8_DEFINE)
 397
 398 dnl Check for glib2 without extra fat, useful for the unversioned tool frontends
 399 PKG_CHECK_MODULES(GLIB_ONLY, glib-2.0 >= $GLIB_REQ)
 400
 401 dnl Check for documentation xrefs
 402 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 403 AC_SUBST(GLIB_PREFIX)
 404
 405 dnl libxml 2 is optional in some cases
 406 if test "x$GST_DISABLE_LOADSAVE" = "xyes" && \
 407    ( test "x$GST_DISABLE_REGISTRY" = "xyes" || \
 408    test "x$USE_BINARY_REGISTRY" = "xyes" )
 409 then
 410   AC_MSG_NOTICE([XML registry and load/save are disabled, not checking for libxml2])
 411   GST_DISABLE_XML_DEFINE="#define GST_DISABLE_XML 1"
 412 else
 413   dnl check for libxml2 with minimum req version
 414   AG_GST_LIBXML2_CHECK(2.4.9)
 415   GST_DISABLE_XML_DEFINE="/* #undef GST_DISABLE_XML */"
 416 fi
 417 AC_SUBST(GST_DISABLE_XML_DEFINE)
 418
 419 dnl check for "check", unit testing library/header
 420 AM_PATH_CHECK(0.9.2,
 421     [
 422         HAVE_CHECK=yes
 423         AC_MSG_NOTICE(CHECK_CFLAGS: $CHECK_CFLAGS)
 424         AC_MSG_NOTICE(CHECK_LIBS: $CHECK_LIBS)
 425     ],
 426     HAVE_CHECK=no)
 427 AM_CONDITIONAL(HAVE_CHECK, test "x$HAVE_CHECK" = "xyes")
 428
 429 dnl *** set variables based on configure arguments
 430
 431 dnl set license and copyright notice
 432 GST_LICENSE="LGPL"
 433 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 434 AC_SUBST(GST_LICENSE)
 435
 436 dnl define LIBDIR so we can inform people where we live
 437 AS_AC_EXPAND(LIBDIR, $libdir)
 438 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [library dir])
 439
 440 dnl set location of plugin directory
 441 AG_GST_SET_PLUGINDIR
 442
 443 dnl FIXME: add LIBXML_PKG here if we use it
 444 GST_PKG_DEPS="glib-2.0, gobject-2.0, gmodule-no-export-2.0, gthread-2.0"
 445 AC_SUBST(GST_PKG_DEPS)
 446
 447 dnl define an ERROR_CFLAGS Makefile variable
 448 AG_GST_SET_ERROR_CFLAGS($GST_CVS)
 449
 450 dnl define correct level for debugging messages
 451 AG_GST_SET_LEVEL_DEFAULT($GST_CVS)
 452
 453 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 454
 455 dnl Overview:
 456 dnl GST_OPTION_CFLAGS:  common cflags for profiling, debugging, errors, ...
 457 dnl GST_ALL_*:          vars shared by all built objects
 458 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 459 dnl GST_OBJ_*:          additional vars to link to the core library
 460 dnl                     include GST_ALL_*
 461 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 462 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 463
 464 dnl GST_OPTION_CFLAGS
 465 if test "x$USE_DEBUG" = xyes; then
 466    PROFILE_CFLAGS="-g"
 467 fi
 468 AC_SUBST(PROFILE_CFLAGS)
 469
 470 # GST_DISABLE_DEPRECATED: hide the visibility of deprecated
 471 # functionality from the API that gstreamer uses
 472 # GST_REMOVE_DEPRECATED: don't compile deprecated functionality (breaks ABI)
 473 DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 474 AC_SUBST(DEPRECATED_CFLAGS)
 475
 476 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 477 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 478 AC_SUBST(GST_OPTION_CFLAGS)
 479
 480 dnl GST_ALL_*
 481 dnl vars common to for all internal objects (core libs, elements, applications)
 482 dnl CFLAGS:
 483 dnl - XML needs to be added because xmlPtr is used in core
 484 dnl - src and build dirs need to be added because every piece that gets built
 485 dnl   will need the GStreamer source and generated headers
 486 dnl LIBS: XML doesn't need to be added because we don't explicitly use symbols
 487 dnl       from LibXML except for in the core library
 488 GST_ALL_CFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir) $GLIB_CFLAGS $XML_CFLAGS \$(GST_OPTION_CFLAGS)"
 489
 490 dnl FIXME: check if LTLIBINTL is needed everywhere
 491 dnl I presume it is given that it contains the symbols that _() stuff maps to
 492 GST_ALL_LIBS="$GLIB_LIBS $LTLIBINTL \$(GCOV_LIBS)"
 493
 494 dnl LDFLAGS really should only contain flags, not libs - they get added before
 495 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 496 GST_ALL_LDFLAGS="-no-undefined"
 497
 498 AC_SUBST(GST_ALL_CFLAGS)
 499 AC_SUBST(GST_ALL_LIBS)
 500 AC_SUBST(GST_ALL_LDFLAGS)
 501
 502 dnl GST_LIB_LDFLAGS
 503 dnl linker flags shared by all libraries
 504 dnl LDFLAGS modifier defining exported symbols from built libraries
 505 GST_LIB_LDFLAGS="-export-symbols-regex \^[_]*\(gst_\|Gst\|GST_\).*"
 506 AC_SUBST(GST_LIB_LDFLAGS)
 507
 508 dnl GST_OBJ_*
 509 dnl default vars for all internal objects built on libgstreamer
 510 dnl includes GST_ALL_*
 511 GST_OBJ_CFLAGS="\$(GST_ALL_CFLAGS)"
 512 GST_OBJ_LIBS="\$(top_builddir)/gst/libgstreamer-$GST_MAJORMINOR.la \$(GST_ALL_LIBS)"
 513 AC_SUBST(GST_OBJ_CFLAGS)
 514 AC_SUBST(GST_OBJ_LIBS)
 515
 516 dnl GST_PLUGIN_LDFLAGS
 517 dnl LDFLAGS for plugins; includes GST_ALL_LDFLAGS
 518 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 519 AC_SUBST(GST_PLUGIN_LDFLAGS, "$GST_PLUGIN_LDFLAGS")
 520
 521 AC_CONFIG_FILES(
 522 Makefile
 523 gst/Makefile
 524 gst/gstconfig.h
 525 gst/gstversion.h
 526 gst/parse/Makefile
 527 libs/Makefile
 528 libs/gst/Makefile
 529 libs/gst/base/Makefile
 530 libs/gst/check/Makefile
 531 libs/gst/controller/Makefile
 532 libs/gst/dataprotocol/Makefile
 533 libs/gst/net/Makefile
 534 plugins/Makefile
 535 plugins/indexers/Makefile
 536 plugins/elements/Makefile
 537 po/Makefile.in
 538 tests/Makefile
 539 tests/benchmarks/Makefile
 540 tests/check/Makefile
 541 tests/misc/Makefile
 542 tests/examples/Makefile
 543 tests/examples/adapter/Makefile
 544 tests/examples/controller/Makefile
 545 tests/examples/helloworld/Makefile
 546 tests/examples/launch/Makefile
 547 tests/examples/manual/Makefile
 548 tests/examples/metadata/Makefile
 549 tests/examples/queue/Makefile
 550 tests/examples/typefind/Makefile
 551 tests/examples/xml/Makefile
 552 tools/Makefile
 553 common/Makefile
 554 common/m4/Makefile
 555 docs/Makefile
 556 docs/design/Makefile
 557 docs/faq/Makefile
 558 docs/gst/Makefile
 559 docs/gst/gstreamer.types
 560 docs/libs/Makefile
 561 docs/plugins/Makefile
 562 docs/manual/Makefile
 563 docs/pwg/Makefile
 564 docs/slides/Makefile
 565 docs/xsl/Makefile
 566 docs/version.entities
 567 win32/common/config.h
 568 pkgconfig/Makefile
 569 stamp.h
 570 pkgconfig/gstreamer.pc
 571 pkgconfig/gstreamer-uninstalled.pc
 572 pkgconfig/gstreamer-base.pc
 573 pkgconfig/gstreamer-base-uninstalled.pc
 574 pkgconfig/gstreamer-check.pc
 575 pkgconfig/gstreamer-check-uninstalled.pc
 576 pkgconfig/gstreamer-controller.pc
 577 pkgconfig/gstreamer-controller-uninstalled.pc
 578 pkgconfig/gstreamer-dataprotocol.pc
 579 pkgconfig/gstreamer-dataprotocol-uninstalled.pc
 580 pkgconfig/gstreamer-net.pc
 581 pkgconfig/gstreamer-net-uninstalled.pc
 582 gst-element-check.m4
 583 gstreamer.spec
 584 )
 585
 586 AC_OUTPUT