configure.ac

   1 AC_PREREQ(2.60)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/prerelease
   8 AC_INIT(GStreamer Base Plug-ins, 0.10.32.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-base)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability 1.10])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use major.minor as a version
  41 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  42 dnl we override it here if we need to for the release candidate of new series
  43 GST_MAJORMINOR=0.10
  44 AC_SUBST(GST_MAJORMINOR)
  45
  46 dnl CURRENT, REVISION, AGE
  47 dnl - library source changed -> increment REVISION
  48 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  49 dnl - interfaces added -> increment AGE
  50 dnl - interfaces removed -> AGE = 0
  51 dnl sets GST_LT_LDFLAGS
  52 AS_LIBTOOL(GST, 23, 0, 23)
  53
  54 dnl FIXME: this macro doesn't actually work;
  55 dnl the generated libtool script has no support for the listed tags.
  56 dnl So this needs to be fixed first if we want to use this
  57 dnl AS_LIBTOOL_TAGS
  58
  59 AC_LIBTOOL_WIN32_DLL
  60 AM_PROG_LIBTOOL
  61
  62 dnl *** required versions of GStreamer stuff ***
  63 GST_REQ=0.10.32
  64
  65 dnl *** autotools stuff ****
  66
  67 dnl allow for different autotools
  68 AS_AUTOTOOLS_ALTERNATE
  69
  70 dnl Add parameters for aclocal
  71 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  72
  73 dnl set up gettext
  74 dnl the version check needs to stay here because autopoint greps for it
  75 AM_GNU_GETTEXT_VERSION([0.17])
  76 AM_GNU_GETTEXT([external])
  77 AG_GST_GETTEXT([gst-plugins-base-$GST_MAJORMINOR])
  78
  79 dnl *** check for arguments to configure ***
  80
  81 AG_GST_ARG_DEBUG
  82 AG_GST_ARG_PROFILING
  83 AG_GST_ARG_VALGRIND
  84 AG_GST_ARG_GCOV
  85
  86 AG_GST_ARG_EXAMPLES
  87
  88 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  89 AG_GST_ARG_WITH_PACKAGE_NAME
  90 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  91
  92 AG_GST_PKG_CONFIG_PATH
  93
  94 dnl let distro override plugin install helper path
  95 AC_ARG_WITH(install-plugins-helper,
  96   AC_HELP_STRING([--with-install-plugins-helper],
  97     [specify path of helper script to call to install plugins]),
  98   [
  99     case "${withval}" in
 100       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 101       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 102       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
 103     esac
 104   ],
 105   [
 106     dnl Default value
 107     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 108   ]
 109 )
 110 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 111 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 112     [plugin install helper script])
 113 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 114
 115 AG_GST_ARG_WITH_PLUGINS
 116
 117 AG_GST_ARG_ENABLE_EXTERNAL
 118
 119 AG_GST_ARG_ENABLE_EXPERIMENTAL
 120
 121 dnl *** checks for platform ***
 122
 123 dnl * hardware/architecture *
 124
 125 dnl common/m4/gst-arch.m4
 126 dnl check CPU type
 127 AG_GST_ARCH
 128
 129 dnl check for large file support
 130 dnl affected plugins must include config.h
 131 AC_SYS_LARGEFILE
 132
 133 dnl *** checks for programs ***
 134
 135 dnl find a compiler
 136 AC_PROG_CC
 137 AC_PROG_CC_STDC
 138 AC_PROG_CXX
 139
 140 dnl determine if c++ is available on this system
 141 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 142
 143 dnl determine c++ preprocessor
 144 dnl FIXME: do we need this ?
 145 AC_PROG_CXXCPP
 146
 147 dnl check if the compiler supports '-c' and '-o' options
 148 AM_PROG_CC_C_O
 149
 150 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 151 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 152
 153 dnl check for gobject-introspection
 154 GOBJECT_INTROSPECTION_CHECK([0.9.12])
 155
 156 dnl check for documentation tools
 157 GTK_DOC_CHECK([1.3])
 158 AS_PATH_PYTHON([2.1])
 159 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 160
 161 dnl *** checks for libraries ***
 162
 163 dnl libm, for sin() etc.
 164 AC_CHECK_LIBM
 165 AC_SUBST(LIBM)
 166
 167 dnl *** checks for header files ***
 168
 169 dnl check if we have ANSI C header files
 170 AC_HEADER_STDC
 171
 172 dnl used in gst/ffmpegcolorspace/mem.c
 173 dnl FIXME: could be fixed by redefining av_malloc and av_free to GLib's
 174 AC_CHECK_HEADERS([malloc.h])
 175
 176 ac_cppflags_save="$CPPFLAGS"
 177 CPPFLAGS="`$PKG_CONFIG --cflags libxml-2.0`"
 178 AC_COMPILE_IFELSE(
 179   AC_LANG_PROGRAM([
 180 #include <libxml/HTMLparser.h>
 181                      ],[
 182 #ifndef LIBXML_HTML_ENABLED
 183 #error libxml2 has no HTML support
 184 #endif /* LIBXML_HTML_ENABLED */
 185                    ]), HAVE_LIBXML_HTML="yes", HAVE_LIBXML_HTML="no")
 186 CPPFLAGS="$ac_cppflags_save"
 187 AM_CONDITIONAL(HAVE_LIBXML_HTML, test "x$HAVE_LIBXML_HTML" = "xyes")
 188
 189 dnl used in gst/tcp
 190 AC_CHECK_HEADERS([sys/socket.h],
 191   HAVE_SYS_SOCKET_H="yes", HAVE_SYS_SOCKET_H="no")
 192 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 193
 194 dnl used in gst-libs/gst/rtsp
 195 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 196 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 197   WIN32_LIBS="-lws2_32"
 198   AC_SUBST(WIN32_LIBS)
 199 fi
 200
 201 dnl check for hstrerror, for gst-libs/gst/rtsp
 202 save_libs="$LIBS"
 203 AC_CHECK_FUNC(hstrerror, ,
 204     AC_CHECK_LIB(resolv, hstrerror, ,
 205         [AC_DEFINE(NO_HSTRERROR, 1,
 206              [Define if you have no native hstrerror() function.])]))
 207 HSTRERROR_LIBS=$LIBS
 208 AC_SUBST(HSTRERROR_LIBS)
 209 LIBS="$save_libs"
 210
 211 dnl used in gst-libs/gst/pbutils and associated unit test
 212 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h])
 213
 214 dnl ffmpegcolorspace includes _stdint.h
 215 dnl also, Windows does not have long long
 216 AX_CREATE_STDINT_H
 217
 218 dnl *** checks for functions ***
 219 AC_CHECK_FUNCS([localtime_r gmtime_r])
 220
 221 dnl *** checks for math functions ***
 222 LIBS_SAVE=$LIBS
 223 LIBS="$LIBS $LIBM"
 224 AC_CHECK_FUNCS(log2)
 225 LIBS=$LIBS_SAVE
 226
 227 dnl *** checks for types/defines ***
 228
 229 dnl Check for FIONREAD ioctl declaration
 230 dnl used in gst/tcp
 231 GST_CHECK_FIONREAD
 232
 233 dnl *** checks for structures ***
 234
 235 dnl *** checks for compiler characteristics ***
 236
 237 dnl *** checks for library functions ***
 238
 239 dnl check for fseeko()
 240 AC_FUNC_FSEEKO
 241
 242 dnl Check for fast float to int casting as defined in C99
 243 dnl used in gst-libs/gst/floatcast/floatcast.h
 244 save_libs=$LIBS
 245 LIBS="$LIBS $LIBM"
 246 AC_C99_FUNC_LRINT
 247 AC_C99_FUNC_LRINTF
 248 LIBS=$save_libs
 249
 250 dnl Check for a way to display the function name in debug output
 251 AG_GST_CHECK_FUNCTION
 252
 253 dnl *** checks for socket and nsl libraries ***
 254 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 255 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
 256
 257 dnl *** checks for dependency libraries ***
 258
 259 dnl GLib is required
 260 AG_GST_GLIB_CHECK([2.22])
 261
 262 ORC_CHECK([0.4.11])
 263
 264 dnl checks for gstreamer
 265 dnl uninstalled is selected preferentially -- see pkg-config(1)
 266 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 267 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 268 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ], yes)
 269 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 270 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 271 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 272
 273 dnl Check for documentation xrefs
 274 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 275 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 276 AC_SUBST(GLIB_PREFIX)
 277 AC_SUBST(GST_PREFIX)
 278
 279 dnl GTK is optional and only used in examples
 280 HAVE_GTK=no
 281 HAVE_GTK_X11=no
 282 GTK2_REQ=2.14.0
 283 GTK3_REQ=2.91.3
 284 if test "x$BUILD_EXAMPLES" = "xyes"; then
 285   AC_MSG_CHECKING([which gtk+ version to compile examples against (optional)])
 286   AC_ARG_WITH([gtk],
 287     AC_HELP_STRING([--with-gtk=3.0|2.0],
 288                    [which gtk+ version to compile against (default: 2.0)]),
 289     [case "$with_gtk" in
 290         2.0) GTK_REQ=$GTK2_REQ ;;
 291         3.0) GTK_REQ=$GTK3_REQ ;;
 292         *) AC_MSG_ERROR([invalid gtk+ version specified]);;
 293     esac],
 294     [with_gtk=2.0
 295      GTK_REQ=$GTK2_REQ])
 296   AC_MSG_RESULT([$with_gtk (>= $GTK_REQ)])
 297   PKG_CHECK_MODULES(GTK, gtk+-$with_gtk >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 298   dnl some examples need gtk+-x11
 299   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-$with_gtk >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 300   AC_SUBST(GTK_LIBS)
 301   AC_SUBST(GTK_CFLAGS)
 302 fi
 303 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 304 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 305
 306 dnl QT is optional and only used in examples
 307 PKG_CHECK_MODULES(QT, QtGui >= 4.6, [
 308   HAVE_QT_GV=yes
 309   HAVE_QT=yes
 310 ], [
 311   HAVE_QT_GV=no
 312   PKG_CHECK_MODULES(QT, QtGui >= 4.0, HAVE_QT=yes, HAVE_QT=no)
 313 ])
 314 if test "x$HAVE_QT" = "xyes"; then
 315   AC_MSG_CHECKING([Qt moc])
 316   QT4_MOC=`$PKG_CONFIG --variable=moc_location QtGui`
 317   AC_MSG_RESULT($QT4_MOC)
 318   AC_SUBST(QT4_MOC)
 319 fi
 320 AM_CONDITIONAL(HAVE_QT, test "x$HAVE_QT" = "xyes")
 321 AM_CONDITIONAL(HAVE_QT_GV, test "x$HAVE_QT_GV" = "xyes")
 322
 323 dnl chck for linux headers needed by the joystick seek example
 324 AC_COMPILE_IFELSE(
 325 [
 326   AC_LANG_PROGRAM([
 327     #include <linux/input.h>
 328     #include <linux/joystick.h>
 329   ],[
 330     struct js_event js;
 331     js.type = JS_EVENT_AXIS;
 332   ])
 333 ], [
 334   HAVE_LINUX_JOYSTICK_HEADERS="yes"
 335 ], [
 336   HAVE_LINUX_JOYSTICK_HEADERS="no"
 337 ])
 338 AM_CONDITIONAL(HAVE_LINUX_JOYSTICK_HEADERS, test "x$HAVE_LINUX_JOYSTICK_HEADERS" = "xyes")
 339
 340 dnl Check for -Bsymbolic-functions linker flag used to avoid
 341 dnl intra-library PLT jumps, if available.
 342 AC_ARG_ENABLE(Bsymbolic,
 343               [AC_HELP_STRING([--disable-Bsymbolic],
 344                               [avoid linking with -Bsymbolic])],,
 345               [SAVED_LDFLAGS="${LDFLAGS}"
 346                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 347                LDFLAGS=-Wl,-Bsymbolic-functions
 348                AC_TRY_LINK([], [int main (void) { return 0; }],
 349                            AC_MSG_RESULT(yes)
 350                            enable_Bsymbolic=yes,
 351                            AC_MSG_RESULT(no)
 352                            enable_Bsymbolic=no)
 353                LDFLAGS="${SAVED_LDFLAGS}"])
 354
 355
 356 dnl *** set variables based on configure arguments ***
 357
 358 dnl set license and copyright notice
 359 GST_LICENSE="LGPL"
 360 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 361 AC_SUBST(GST_LICENSE)
 362
 363 dnl set location of plugin directory
 364 AG_GST_SET_PLUGINDIR
 365
 366 dnl set release date/time
 367 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 368   ["${srcdir}/gst-plugins-base.doap"],
 369   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 370
 371 dnl define an ERROR_CFLAGS Makefile variable
 372 dnl -Wformat-nonliteral - see ext/pango/gstclockoverlay.c and http://gcc.gnu.org/bugzilla/show_bug.cgi?id=39438
 373 AG_GST_SET_ERROR_CFLAGS($GST_GIT, [
 374     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef
 375     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 376     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 377     -Wno-multichar -Wnested-externs ])
 378
 379 dnl define an ERROR_CXXFLAGS Makefile variable
 380 AG_GST_SET_ERROR_CXXFLAGS($GST_GIT, [
 381     -Wmissing-declarations -Wredundant-decls -Wundef
 382     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 383     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 384     -Wno-multichar])
 385
 386 dnl define correct level for debugging messages
 387 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 388
 389 dnl used in examples
 390 AG_GST_DEFAULT_ELEMENTS
 391
 392 dnl needed for encoding-target
 393 GST_DATADIR="$GST_PREFIX/share"
 394 AC_DEFINE_UNQUOTED(GST_DATADIR, "$GST_DATADIR", [system wide data directory])
 395 AC_DEFINE_UNQUOTED(GST_MAJORMINOR, "$GST_MAJORMINOR", [major/minor version])
 396
 397 dnl behaviour of speex based audio resampler
 398 AC_MSG_CHECKING(which audio resample format to use for integer)
 399 AC_ARG_WITH([audioresample_format],
 400         AS_HELP_STRING([--with-audioresample-format],[Which implementation should be used for integer audio resampling, int/float/auto, (default is auto)]),
 401         [ac_cv_audioresample_format=$withval], [ac_cv_audioresample_format=auto])dnl
 402 AC_MSG_RESULT($ac_cv_audioresample_format)
 403 case $ac_cv_audioresample_format in
 404   int)
 405     AC_DEFINE(AUDIORESAMPLE_FORMAT_INT,1,[The int implementation should be used for integer audio resampling])
 406     AC_SUBST(AUDIORESAMPLE_FORMAT_INT)
 407   ;;
 408   float)
 409     AC_DEFINE(AUDIORESAMPLE_FORMAT_FLOAT,1,[The float implementation should be used for integer audio resampling])
 410     AC_SUBST(AUDIORESAMPLE_FORMAT_FLOAT)
 411   ;;
 412   auto)
 413     AC_DEFINE(AUDIORESAMPLE_FORMAT_AUTO,1,[The implementation that should be used for integer audio resampling witll be benchmarked at runtime])
 414     AC_SUBST(AUDIORESAMPLE_FORMAT_AUTO)
 415 esac
 416
 417 dnl *** plug-ins to include ***
 418
 419 dnl these are all the gst plug-ins, compilable without additional libs
 420 AG_GST_CHECK_PLUGIN(adder)
 421 AG_GST_CHECK_PLUGIN(app)
 422 AG_GST_CHECK_PLUGIN(audioconvert)
 423 AG_GST_CHECK_PLUGIN(audiorate)
 424 AG_GST_CHECK_PLUGIN(audiotestsrc)
 425 AG_GST_CHECK_PLUGIN(encoding)
 426 AG_GST_CHECK_PLUGIN(ffmpegcolorspace)
 427 AG_GST_CHECK_PLUGIN(gdp)
 428 AG_GST_CHECK_PLUGIN(playback)
 429 AG_GST_CHECK_PLUGIN(audioresample)
 430 AG_GST_CHECK_PLUGIN(subparse)
 431 AG_GST_CHECK_PLUGIN(tcp)
 432 AG_GST_CHECK_PLUGIN(typefind)
 433 AG_GST_CHECK_PLUGIN(videotestsrc)
 434 AG_GST_CHECK_PLUGIN(videorate)
 435 AG_GST_CHECK_PLUGIN(videoscale)
 436 AG_GST_CHECK_PLUGIN(volume)
 437
 438 dnl check for gstreamer core features (subsystems)
 439 dnl FIXME: this assumes srcdir == builddir for uninstalled setups
 440 GST_CONFIGPATH=`$PKG_CONFIG --variable=includedir gstreamer-0.10`"/gst/gstconfig.h"
 441 AG_GST_PARSE_SUBSYSTEM_DISABLES($GST_CONFIGPATH)
 442 AM_CONDITIONAL(USE_XML, test $GST_DISABLE_XML != "1")
 443
 444 dnl disable plug-ins that require libxml2's HTML support if it is not available
 445 if test "x$HAVE_LIBXML_HTML" != "xyes"; then
 446   AG_GST_DISABLE_PLUGIN(subparse)
 447 fi
 448
 449 dnl disable plug-ins that require sys/socket.h if it is not available
 450 if test "x$HAVE_SYS_SOCKET_H" != "xyes"; then
 451   AG_GST_DISABLE_PLUGIN(tcp)
 452 fi
 453
 454 dnl iso-codes is optional, used by libgsttag
 455 AC_ARG_ENABLE(iso-codes,
 456 AC_HELP_STRING([--enable-iso-codes],[use iso-codes if installed]),
 457 [case "${enableval}" in
 458   yes) enable_iso_codes=yes ;;
 459   no)  enable_iso_codes=no ;;
 460   *) AC_MSG_ERROR(bad value ${enableval} for --enable-iso-codes) ;;
 461 esac
 462 ],
 463 [enable_iso_codes=yes]) dnl Default value
 464
 465 AC_MSG_CHECKING([whether to use iso-codes if they are available])
 466 if test "x$enable_iso_codes" = "xyes"; then
 467   AC_MSG_RESULT([yes])
 468   have_iso_codes=no
 469   AC_MSG_CHECKING([whether iso-codes are available on this system])
 470   if $PKG_CONFIG iso-codes; then
 471     AC_MSG_RESULT([yes])
 472     AC_MSG_CHECKING([whether iso-codes has iso-639 domain])
 473     if $PKG_CONFIG --variable=domains iso-codes | $GREP -q 639 ; then
 474       AC_MSG_RESULT([yes])
 475       AC_MSG_CHECKING([for iso-codes prefix])
 476       ISO_CODES_PREFIX=`$PKG_CONFIG --variable=prefix iso-codes`
 477       if test -d "$ISO_CODES_PREFIX"; then
 478         AC_MSG_RESULT([yes])
 479         AC_MSG_CHECKING([ISO_CODES_PREFIX])
 480         AC_MSG_RESULT([$ISO_CODES_PREFIX])
 481         ISO_639_DOMAIN="iso_639"
 482         AC_MSG_CHECKING([ISO_639_DOMAIN])
 483         AC_MSG_RESULT([$ISO_639_DOMAIN])
 484         have_iso_codes=yes
 485         AC_DEFINE([HAVE_ISO_CODES], [1], [make use of iso-codes for ISO-639])
 486         AC_DEFINE_UNQUOTED([ISO_CODES_PREFIX], ["$ISO_CODES_PREFIX"], [prefix])
 487         ISO_CODES_VERSION=`$PKG_CONFIG --modversion iso-codes`
 488         AC_DEFINE_UNQUOTED([ISO_CODES_VERSION], ["$ISO_CODES_VERSION"], [ ])
 489       else
 490         AC_MSG_RESULT([no])
 491       fi
 492     else
 493       AC_MSG_RESULT([no])
 494     fi
 495   else
 496     AC_MSG_RESULT([no])
 497   fi
 498   AM_CONDITIONAL(USE_ISO_CODES, test "x$have_iso_codes" = "xyes")
 499 else
 500   AC_MSG_RESULT([no (disabled via --disable-iso-codes)])
 501   AM_CONDITIONAL(USE_ISO_CODES, false)
 502 fi
 503
 504 dnl *** sys plug-ins ***
 505
 506 echo
 507 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 508 echo
 509
 510 dnl *** X11 ***
 511 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 512 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 513                   [ximagesink], [
 514   AC_PATH_XTRA
 515   ac_cflags_save="$CFLAGS"
 516   ac_cppflags_save="$CPPFLAGS"
 517   CFLAGS="$CFLAGS $X_CFLAGS"
 518   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 519
 520   dnl now try to find the HEADER
 521   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 522
 523   if test "x$HAVE_X" = "xno"
 524   then
 525     AC_MSG_NOTICE([cannot find X11 development files])
 526   else
 527     dnl this is much more than we want
 528     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 529     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 530     dnl it does not add the libs; therefore we add them here
 531     X_LIBS="$X_LIBS -lX11"
 532     AC_SUBST(X_CFLAGS)
 533     AC_SUBST(X_LIBS)
 534   fi
 535   AC_SUBST(HAVE_X)
 536   CFLAGS="$ac_cflags_save"
 537   CPPFLAGS="$ac_cppflags_save"
 538 ])
 539
 540 dnl Check for Xv extension
 541 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 542 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 543                   [xvimagesink], [
 544   AG_GST_CHECK_XV
 545 ])
 546
 547 dnl check for X Shm
 548 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 549 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 550   if test x$HAVE_X = xyes; then
 551     AC_CHECK_LIB(Xext, XShmAttach,
 552                  HAVE_XSHM="yes", HAVE_XSHM="no",
 553                  $X_LIBS)
 554     if test "x$HAVE_XSHM" = "xyes"; then
 555       XSHM_LIBS="-lXext"
 556     else
 557       dnl On AIX, it is in XextSam instead, but we still need -lXext
 558       AC_CHECK_LIB(XextSam, XShmAttach,
 559                    HAVE_XSHM="yes", HAVE_XSHM="no",
 560                    $X_LIBS)
 561       if test "x$HAVE_XSHM" = "xyes"; then
 562         XSHM_LIBS="-lXext -lXextSam"
 563       fi
 564     fi
 565   fi
 566 ], , [
 567   AC_SUBST(HAVE_XSHM)
 568   AC_SUBST(XSHM_LIBS)
 569 ])
 570
 571 dnl v4l/v4l2 checks have been moved down because they require X
 572
 573 dnl *** Video 4 Linux ***
 574 dnl for information about the header/define, see sys/v4l/gstv4lelement.h
 575 dnl renamed to GST_V4L in accordance with V4L2 below
 576 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L, true)
 577 AG_GST_CHECK_FEATURE(GST_V4L, [Video 4 Linux], video4linux, [
 578   AC_CHECK_DECL(VID_TYPE_MPEG_ENCODER, HAVE_GST_V4L="yes", HAVE_GST_V4L="no", [
 579 #include <sys/types.h>
 580 #define _LINUX_TIME_H
 581 #define __user
 582 #include <linux/videodev.h>
 583   ])
 584
 585   dnl we can build v4l without Xv, but then we won't have XOverlay support
 586   if test "x$HAVE_GST_V4L" = "xyes" -a "x$HAVE_XVIDEO" != "xyes"
 587   then
 588     AC_MSG_NOTICE([NO XVIDEO FOUND, VIDEO4LINUX WILL BE BUILT])
 589     AC_MSG_NOTICE([WITHOUT XOVERLAY SUPPORT])
 590   fi
 591 ])
 592
 593 # Optional gudev for device probing
 594 AC_ARG_WITH([gudev],
 595   AC_HELP_STRING([--with-gudev],
 596     [device detection with gudev]),
 597   [],
 598   [with_gudev=check])
 599 if test x$HAVE_GST_V4L = xyes; then
 600   if test x$with_gudev != xno; then
 601       PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 143 ],
 602           [ have_gudev=yes
 603             AC_DEFINE(HAVE_GUDEV, 1,
 604                [Whether gudev is available for device detection])
 605             AC_DEFINE([G_UDEV_API_IS_SUBJECT_TO_CHANGE], 1, [I know the API is subject to change.])
 606           ], [
 607           have_gudev=no
 608           ])
 609   else
 610     have_gudev=no
 611   fi
 612 fi
 613 AC_SUBST(GUDEV_CFLAGS)
 614 AC_SUBST(GUDEV_LIBS)
 615
 616 dnl *** ext plug-ins ***
 617 dnl keep this list sorted alphabetically !
 618
 619 if test "x$BUILD_EXTERNAL" = "xyes"; then
 620
 621 echo
 622 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 623 echo
 624
 625 dnl *** alsa ***
 626 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 627 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 628   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 629     HAVE_ALSA="yes"
 630     AC_SUBST(ALSA_CFLAGS)
 631     AC_SUBST(ALSA_LIBS)
 632   ], [
 633     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 634   ])
 635 ])
 636
 637 dnl *** CDParanoia ***
 638 dnl Note: upstream has a pkg-config file only in post-10.2 SVN so far
 639 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 640 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 641   PKG_CHECK_MODULES(CDPARANOIA, cdparanoia-3 >= 10.2, [
 642     HAVE_CDPARANOIA="yes"
 643   ], [
 644     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 645                         cdda_open, -lm,
 646                         cdda_interface.h,
 647                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 648                         HEADER_DIR="no"
 649                         FOUND_CDPARANOIA="yes")
 650     if test "x$FOUND_CDPARANOIA" != "xyes";
 651     then
 652       AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 653                           cdda_open, -lm,
 654                           cdda/cdda_interface.h,
 655                           CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 656                           HEADER_DIR="yes"
 657                           FOUND_CDPARANOIA="yes")
 658     fi
 659     if test "x$HEADER_DIR" = "xyes";
 660     then
 661       AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 662                          defined if cdda headers are in a cdda/ directory)
 663     fi
 664     if test "x$FOUND_CDPARANOIA" = "xyes";
 665     then
 666       AC_CHECK_LIB(cdda_paranoia,
 667                    paranoia_cachemodel_size,
 668                    : ,
 669                    HAVE_CDPARANOIA=no,
 670                  [-lcdda_interface])
 671     fi
 672
 673     AC_SUBST(CDPARANOIA_LIBS)
 674   ])
 675 ])
 676 dnl FIXME : add second check somehow if that is necessary
 677 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 678 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 679
 680 dnl *** GNOME VFS ***
 681 translit(dnm, m, l) AM_CONDITIONAL(USE_GNOME_VFS, true)
 682 AG_GST_CHECK_FEATURE(GNOME_VFS, [GNOME VFS], gnomevfs, [
 683   PKG_CHECK_MODULES(GNOME_VFS, gnome-vfs-2.0, [
 684       HAVE_GNOME_VFS="yes"
 685       AC_SUBST(GNOME_VFS_CFLAGS)
 686       AC_SUBST(GNOME_VFS_LIBS)
 687       GNOME_VFS_MODULES_DIR="`$PKG_CONFIG --variable=modulesdir gnome-vfs-2.0`"
 688       AC_DEFINE_UNQUOTED(GNOME_VFS_MODULES_DIR, "$GNOME_VFS_MODULES_DIR",
 689              [The GnomeVFS modules directory.])
 690     ],[
 691       HAVE_GNOME_VFS="no"
 692     ]
 693     )
 694 ])
 695
 696 dnl *** ivorbis ***
 697 dnl AM_PATH_IVORBIS only takes two options
 698 translit(dnm, m, l) AM_CONDITIONAL(USE_IVORBIS, true)
 699 AG_GST_CHECK_FEATURE(IVORBIS, [integer vorbis plug-in], ivorbisdec, [
 700   AG_GST_PKG_CHECK_MODULES(IVORBIS, vorbisidec)
 701   if test $HAVE_IVORBIS = no
 702   then
 703     IVORBIS_LIBS=
 704     IVORBIS_CFLAGS=
 705     AC_CHECK_LIB(vorbisidec, vorbis_block_init,
 706       [IVORBIS_LIBS=-lvorbisidec
 707       HAVE_IVORBIS=yes
 708       case $host in
 709       arm-*-*)
 710         IVORBIS_CFLAGS="-D_ARM_ASSEM_ $IVORBIS_CFLAGS"
 711       esac
 712       ],
 713       HAVE_IVORBIS=no)
 714     AC_SUBST(IVORBIS_LIBS)
 715     AC_SUBST(IVORBIS_CFLAGS)
 716   fi
 717 ])
 718
 719 dnl *** libgio ***
 720 translit(dnm, m, l) AM_CONDITIONAL(USE_GIO, true)
 721 AG_GST_CHECK_FEATURE(GIO, [GIO library], gio, [
 722   PKG_CHECK_MODULES(GIO, gio-2.0 >= 2.16, [
 723     HAVE_GIO="yes"
 724     GIO_MODULE_DIR="`$PKG_CONFIG --variable=giomoduledir gio-2.0`"
 725     AC_DEFINE_UNQUOTED(GIO_MODULE_DIR, "$GIO_MODULE_DIR",
 726            [The GIO modules directory.])
 727     GIO_LIBDIR="`$PKG_CONFIG --variable=libdir gio-2.0`"
 728     AC_DEFINE_UNQUOTED(GIO_LIBDIR, "$GIO_LIBDIR",
 729            [The GIO library directory.])
 730   ], [
 731     HAVE_GIO="no"
 732     AC_MSG_RESULT(no)
 733   ])
 734   AC_SUBST(GIO_CFLAGS)
 735   AC_SUBST(GIO_LIBS)
 736   AC_SUBST(GIO_LDFLAGS)
 737 ])
 738
 739 dnl *** libvisual ***
 740 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 741 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 742   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 743   if test $HAVE_LIBVISUAL = no
 744   then
 745     AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0)
 746     if test x$HAVE_LIBVISUAL = xyes; then
 747       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.2`"
 748     fi
 749   else
 750     if test x$HAVE_LIBVISUAL = xyes; then
 751       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.4`"
 752     fi
 753   fi
 754   AC_MSG_NOTICE([libvisual pluginsdir: $LIBVIS_PLUGINSDIR])
 755   if test x$LIBVIS_PLUGINSDIR != x; then
 756     AC_DEFINE_UNQUOTED(LIBVISUAL_PLUGINSBASEDIR,
 757         "$LIBVIS_PLUGINSDIR",
 758         [directory in which the detected libvisual's plugins are located])
 759   fi
 760 ])
 761
 762 dnl *** ogg ***
 763 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 764 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 765   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 766   if test $HAVE_OGG = no
 767   then
 768     XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
 769     AS_SCRUB_INCLUDE(OGG_CFLAGS)
 770   fi
 771 ])
 772
 773 dnl *** pango ***
 774 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 775 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 776   AG_GST_PKG_CHECK_MODULES(PANGO, pango >= 1.16.0  pangocairo >= 1.16.0)
 777 ])
 778
 779 dnl *** theora ***
 780 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 781 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 782   AG_GST_PKG_CHECK_MODULES(THEORA, theoradec >= 1.1 theoraenc >= 1.1)
 783 ])
 784
 785 dnl *** vorbis ***
 786 dnl AM_PATH_VORBIS only takes two options
 787 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 788 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 789   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 790   if test $HAVE_VORBIS = no
 791   then
 792     XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
 793     AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
 794   fi
 795 ])
 796
 797 if test "x$HAVE_VORBIS" = "xyes"; then
 798   ac_cflags_save="$CFLAGS"
 799   AC_COMPILE_IFELSE(
 800     AC_LANG_PROGRAM([
 801 #include <vorbis/codec.h>
 802                      ],[
 803 vorbis_dsp_state *v;
 804
 805 vorbis_synthesis_restart (v);
 806                      ]), HAVE_VSR=yes, HAVE_VSR=no)
 807   if test "x$HAVE_VSR" = "xyes"; then
 808     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 809                        [defined if vorbis_synthesis_restart is present])
 810   fi
 811   CFLAGS="$ac_cflags_save"
 812 fi
 813
 814 else
 815
 816 dnl not building plugins with external dependencies,
 817 dnl but we still need to set the conditionals
 818 AM_CONDITIONAL(USE_ALSA, false)
 819 AM_CONDITIONAL(USE_CDPARANOIA, false)
 820 AM_CONDITIONAL(USE_GIO, false)
 821 AM_CONDITIONAL(USE_GNOME_VFS, false)
 822 AM_CONDITIONAL(USE_IVORBIS, false)
 823 AM_CONDITIONAL(USE_LIBVISUAL, false)
 824 AM_CONDITIONAL(USE_OGG, false)
 825 AM_CONDITIONAL(USE_PANGO, false)
 826 AM_CONDITIONAL(USE_THEORA, false)
 827 AM_CONDITIONAL(USE_VORBIS, false)
 828
 829 fi dnl of EXT plugins
 830
 831 dnl seeking needs freetype, so check for it here
 832 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 833   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 834 ])
 835 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 836 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 837 AC_SUBST(FT2_CFLAGS)
 838 AC_SUBST(FT2_LIBS)
 839
 840 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 841
 842 dnl Overview:
 843 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 844 dnl GST_*:              flags shared by built objects to link against GStreamer
 845 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 846 dnl                          (compare to other modules) or for i18n
 847 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 848 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 849 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 850 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 851
 852 dnl GST_OPTION_CFLAGS
 853 if test "x$USE_DEBUG" = xyes; then
 854    PROFILE_CFLAGS="-g"
 855 fi
 856 AC_SUBST(PROFILE_CFLAGS)
 857
 858 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 859   dnl Define _only_ when compiling a git version (not pre-releases or releases)
 860   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 861 else
 862   DEPRECATED_CFLAGS=""
 863 fi
 864 AC_SUBST(DEPRECATED_CFLAGS)
 865
 866 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 867 dnl at make time with e.g. make ERROR_CFLAGS=""
 868 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 869 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 870 AC_SUBST(GST_OPTION_CFLAGS)
 871 AC_SUBST(GST_OPTION_CXXFLAGS)
 872
 873 dnl our libraries need to be versioned correctly
 874 AC_SUBST(GST_LT_LDFLAGS)
 875
 876 dnl GST_PLUGINS_BASE_CFLAGS
 877 dnl prefer internal headers to already installed ones
 878 dnl also add builddir include for enumtypes and marshal
 879 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 880 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 881
 882 dnl FIXME: do we want to rename to GST_ALL_* ?
 883 dnl add GST_OPTION_CFLAGS, but overridable
 884 GST_CXXFLAGS="$GLIB_CFLAGS $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS)"
 885 GST_CFLAGS="$GLIB_CFLAGS $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
 886 AC_SUBST(GST_CFLAGS)
 887 AC_SUBST(GST_CXXFLAGS)
 888 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 889 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 890 AC_SUBST(GST_LIBS)
 891
 892 dnl LDFLAGS really should only contain flags, not libs - they get added before
 893 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 894 GST_ALL_LDFLAGS="-no-undefined"
 895 if test "x${enable_Bsymbolic}" = "xyes"; then
 896   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 897 fi
 898 AC_SUBST(GST_ALL_LDFLAGS)
 899
 900 dnl GST_LIB_LDFLAGS
 901 dnl linker flags shared by all libraries
 902 dnl LDFLAGS modifier defining exported symbols from built libraries
 903 dnl (export _gst_foo but not __gst_foo)
 904 GST_LIB_LDFLAGS="-export-symbols-regex ^_?\(gst_\|Gst\|GST_\).*"
 905 AC_SUBST(GST_LIB_LDFLAGS)
 906
 907 dnl this really should only contain flags, not libs - they get added before
 908 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 909 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 910 AC_SUBST(GST_PLUGIN_LDFLAGS)
 911
 912 dnl *** output files ***
 913
 914 AC_CONFIG_FILES(
 915 Makefile
 916 gst-plugins-base.spec
 917 gst/Makefile
 918 gst/adder/Makefile
 919 gst/app/Makefile
 920 gst/audioconvert/Makefile
 921 gst/audiorate/Makefile
 922 gst/audiotestsrc/Makefile
 923 gst/encoding/Makefile
 924 gst/ffmpegcolorspace/Makefile
 925 gst/gdp/Makefile
 926 gst/playback/Makefile
 927 gst/audioresample/Makefile
 928 gst/subparse/Makefile
 929 gst/tcp/Makefile
 930 gst/typefind/Makefile
 931 gst/videotestsrc/Makefile
 932 gst/videorate/Makefile
 933 gst/videoscale/Makefile
 934 gst/volume/Makefile
 935 sys/Makefile
 936 sys/ximage/Makefile
 937 sys/xvimage/Makefile
 938 sys/v4l/Makefile
 939 ext/Makefile
 940 ext/alsa/Makefile
 941 ext/cdparanoia/Makefile
 942 ext/gnomevfs/Makefile
 943 ext/gio/Makefile
 944 ext/libvisual/Makefile
 945 ext/ogg/Makefile
 946 ext/pango/Makefile
 947 ext/theora/Makefile
 948 ext/vorbis/Makefile
 949 gst-libs/Makefile
 950 gst-libs/gst/Makefile
 951 gst-libs/gst/audio/Makefile
 952 gst-libs/gst/app/Makefile
 953 gst-libs/gst/cdda/Makefile
 954 gst-libs/gst/fft/Makefile
 955 gst-libs/gst/floatcast/Makefile
 956 gst-libs/gst/interfaces/Makefile
 957 gst-libs/gst/netbuffer/Makefile
 958 gst-libs/gst/riff/Makefile
 959 gst-libs/gst/rtp/Makefile
 960 gst-libs/gst/rtsp/Makefile
 961 gst-libs/gst/sdp/Makefile
 962 gst-libs/gst/tag/Makefile
 963 gst-libs/gst/pbutils/Makefile
 964 gst-libs/gst/pbutils/gstpluginsbaseversion.h
 965 gst-libs/gst/video/Makefile
 966 tools/Makefile
 967 pkgconfig/Makefile
 968 pkgconfig/gstreamer-audio.pc
 969 pkgconfig/gstreamer-audio-uninstalled.pc
 970 pkgconfig/gstreamer-app.pc
 971 pkgconfig/gstreamer-app-uninstalled.pc
 972 pkgconfig/gstreamer-cdda.pc
 973 pkgconfig/gstreamer-cdda-uninstalled.pc
 974 pkgconfig/gstreamer-fft.pc
 975 pkgconfig/gstreamer-fft-uninstalled.pc
 976 pkgconfig/gstreamer-floatcast.pc
 977 pkgconfig/gstreamer-floatcast-uninstalled.pc
 978 pkgconfig/gstreamer-interfaces.pc
 979 pkgconfig/gstreamer-interfaces-uninstalled.pc
 980 pkgconfig/gstreamer-netbuffer.pc
 981 pkgconfig/gstreamer-netbuffer-uninstalled.pc
 982 pkgconfig/gstreamer-pbutils.pc
 983 pkgconfig/gstreamer-pbutils-uninstalled.pc
 984 pkgconfig/gstreamer-riff.pc
 985 pkgconfig/gstreamer-riff-uninstalled.pc
 986 pkgconfig/gstreamer-rtp.pc
 987 pkgconfig/gstreamer-rtp-uninstalled.pc
 988 pkgconfig/gstreamer-rtsp.pc
 989 pkgconfig/gstreamer-rtsp-uninstalled.pc
 990 pkgconfig/gstreamer-sdp.pc
 991 pkgconfig/gstreamer-sdp-uninstalled.pc
 992 pkgconfig/gstreamer-tag.pc
 993 pkgconfig/gstreamer-tag-uninstalled.pc
 994 pkgconfig/gstreamer-video.pc
 995 pkgconfig/gstreamer-video-uninstalled.pc
 996 pkgconfig/gstreamer-plugins-base.pc
 997 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 998 tests/Makefile
 999 tests/check/Makefile
1000 tests/examples/Makefile
1001 tests/examples/app/Makefile
1002 tests/examples/dynamic/Makefile
1003 tests/examples/encoding/Makefile
1004 tests/examples/gio/Makefile
1005 tests/examples/overlay/Makefile
1006 tests/examples/seek/Makefile
1007 tests/examples/snapshot/Makefile
1008 tests/examples/playrec/Makefile
1009 tests/examples/volume/Makefile
1010 tests/examples/v4l/Makefile
1011 tests/files/Makefile
1012 tests/icles/Makefile
1013 tests/icles/playback/Makefile
1014 docs/Makefile
1015 docs/design/Makefile
1016 docs/libs/Makefile
1017 docs/plugins/Makefile
1018 docs/version.entities
1019 po/Makefile.in
1020 common/Makefile
1021 common/m4/Makefile
1022 m4/Makefile
1023 )
1024
1025 dnl Create the config.h file for Visual Studio builds
1026 dnl Beware of spaces and /'s in some of the shell variable contents.
1027 sed \
1028     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
1029     -e 's/.* GST_INSTALL_PLUGINS_HELPER/#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
1030     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
1031     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
1032     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
1033     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
1034     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
1035     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
1036     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
1037     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
1038     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
1039     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
1040     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
1041     -e 's/.* HAVE_ISO_CODES$/#undef HAVE_ISO_CODES/' \
1042     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
1043     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
1044     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
1045     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
1046     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
1047     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
1048     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
1049     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
1050     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1051     -e 's/.* ISO_CODES_PREFIX$/#undef ISO_CODES_PREFIX/' \
1052     -e 's/.* ISO_CODES_VERSION$/#undef ISO_CODES_VERSION/' \
1053     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1054     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1055     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
1056     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1057     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
1058     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1059     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1060     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1061     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.10"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.10"\n#endif/' \
1062     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
1063     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1064     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directaudiosink\"/" \
1065     -e "s/.* DEFAULT_VIDEOSINK$/#define DEFAULT_VIDEOSINK \"directdrawsink\"/" \
1066     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1067     config.h.in >win32/common/config.h-new
1068
1069
1070
1071 AC_OUTPUT
1072
1073 AG_GST_OUTPUT_PLUGINS
1074 ORC_OUTPUT
1075