configure.ac

   1 AC_PREREQ([2.69])
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/prerelease
   8 AC_INIT([GStreamer Base Plug-ins],[1.12.2],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gst-plugins-base])
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.14 no-dist-gzip dist-xz tar-ustar subdir-objects])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  23
  24 dnl define the output header for config
  25 AC_CONFIG_HEADERS([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output with automake >= 1.11
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  35   [AM_DEFAULT_VERBOSITY=1
  36    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  37
  38 dnl our libraries and install dirs use GST_API_VERSION in the filename
  39 dnl to allow side-by-side installation of different API versions
  40 GST_API_VERSION=1.0
  41 AC_SUBST(GST_API_VERSION)
  42 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  43   [GStreamer API Version])
  44
  45 dnl CURRENT, REVISION, AGE
  46 dnl - library source changed -> increment REVISION
  47 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  48 dnl - interfaces added -> increment AGE
  49 dnl - interfaces removed -> AGE = 0
  50 dnl
  51 dnl Keep CURRENT as MINOR * 100 + MICRO
  52 dnl Ex : 1.0.0 => 0
  53 dnl      1.0.3 => 3
  54 dnl      1.1.0 => 100
  55 dnl      1.2.5 => 205
  56 dnl      1.10.9 (who knows) => 1009
  57 dnl
  58 dnl sets GST_LT_LDFLAGS
  59 AS_LIBTOOL(GST, 1202, 0, 1202)
  60
  61 dnl *** required versions of GStreamer stuff ***
  62 GST_REQ=1.12.0
  63
  64 dnl *** autotools stuff ****
  65
  66 dnl allow for different autotools
  67 AS_AUTOTOOLS_ALTERNATE
  68
  69 dnl Add parameters for aclocal
  70 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  71
  72 dnl set up gettext
  73 dnl the version check needs to stay here because autopoint greps for it
  74 AM_GNU_GETTEXT_VERSION([0.17])
  75 AM_GNU_GETTEXT([external])
  76 AG_GST_GETTEXT([gst-plugins-base-$GST_API_VERSION])
  77
  78 dnl *** check for arguments to configure ***
  79
  80 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  81 AG_GST_ARG_ENABLE_EXTRA_CHECKS
  82
  83 AG_GST_ARG_DEBUG
  84 AG_GST_ARG_PROFILING
  85 AG_GST_ARG_VALGRIND
  86 AG_GST_ARG_GCOV
  87
  88 AG_GST_ARG_EXAMPLES
  89
  90 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  91 AG_GST_ARG_WITH_PACKAGE_NAME
  92 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  93
  94 AG_GST_PKG_CONFIG_PATH
  95
  96 dnl let distro override plugin install helper path
  97 AC_ARG_WITH(install-plugins-helper,
  98   AS_HELP_STRING([--with-install-plugins-helper],[specify path of helper script to call to install plugins]),
  99   [
 100     case "${withval}" in
 101       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 102       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 103       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
 104     esac
 105   ],
 106   [
 107     dnl Default value
 108     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 109   ]
 110 )
 111 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 112 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 113     [plugin install helper script])
 114 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 115
 116 AG_GST_ARG_WITH_PLUGINS
 117
 118 AG_GST_ARG_ENABLE_EXTERNAL
 119
 120 AG_GST_ARG_ENABLE_EXPERIMENTAL
 121
 122 dnl *** checks for platform ***
 123 AG_GST_PLATFORM
 124
 125 dnl * hardware/architecture *
 126
 127 dnl common/m4/gst-arch.m4
 128 dnl check CPU type
 129 AG_GST_ARCH
 130
 131 dnl check for large file support
 132 dnl affected plugins must include config.h
 133 AC_SYS_LARGEFILE
 134
 135 dnl *** checks for programs ***
 136
 137 dnl find a compiler
 138 AC_PROG_CC
 139 AC_PROG_CC_STDC
 140
 141 dnl check if the compiler supports '-c' and '-o' options
 142 AM_PROG_CC_C_O
 143
 144 dnl determine if c++ is available on this system
 145 AC_PROG_CXX
 146 dnl CXX may be set to some default even if no c++ compiler is available
 147 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 148 AC_LANG_PUSH([C++])
 149 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ class Foo { int bar; };]], [[]])],[working_cxx=yes],[working_cxx=no])
 150 AC_LANG_POP([C++])
 151 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 152 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 153
 154 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 155 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 156
 157 dnl check for supporting tbm
 158 AC_MSG_CHECKING([for supporting tbm])
 159 AC_ARG_ENABLE(tbm, AC_HELP_STRING([--enable-tbm], [tbm support]),
 160   [
 161     case "${enableval}" in
 162       yes) USE_TBM=yes ;;
 163       no)  USE_TBM=no ;;
 164       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-tbm) ;;
 165     esac
 166   ],
 167   [USE_TBM=no])
 168 AM_CONDITIONAL(USE_TBM, test "x$USE_TBM" = "xyes")
 169 AC_MSG_RESULT([$USE_TBM])
 170 if test "x$USE_TBM" = "xyes"; then
 171   AC_DEFINE(USE_TBM, 1, [tbm support])
 172 fi
 173
 174 dnl Check for tv-product
 175 AC_ARG_ENABLE(tv, AC_HELP_STRING([--enable-tv], [use tv]),
 176         [
 177           case "${enableval}" in
 178            yes) HAVE_TV_PRODUCT=yes ;;
 179            no)  HAVE_TV_PRODUCT=no ;;
 180            *)   AC_MSG_ERROR(bad value ${enableval} for --enable-tv) ;;
 181           esac
 182         ],)
 183 AM_CONDITIONAL([HAVE_TV_PRODUCT], [test "x$HAVE_TV_PRODUCT" = "xyes"])
 184
 185 dnl check for gobject-introspection
 186 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 187
 188 dnl check for documentation tools
 189 GTK_DOC_CHECK([1.12])
 190 AG_GST_PLUGIN_DOCS([1.12])
 191
 192 dnl *** checks for libraries ***
 193
 194 dnl libm, for sin() etc.
 195 LT_LIB_M
 196 AC_SUBST(LIBM)
 197
 198 dnl check for pthreads
 199 AX_PTHREAD
 200
 201 dnl *** checks for header files ***
 202
 203 dnl check if we have ANSI C header files
 204 AC_HEADER_STDC
 205
 206 dnl check for GCC specific SSE headers
 207 dnl these are used by the speex resampler code
 208 AC_CHECK_HEADERS([xmmintrin.h emmintrin.h smmintrin.h])
 209
 210 dnl also check which architecture we're on for building files with intrinsics
 211 dnl separately
 212 AC_CHECK_DECLS([__i386__], [HAVE_X86=1])
 213 AC_CHECK_DECLS([__x86_64__], [HAVE_X86=1])
 214
 215 dnl check for -m* compiler flags too
 216 SSE_CFLAGS="-msse"
 217 SSE2_CFLAGS="-msse2"
 218 SSE41_CFLAGS="-msse4.1"
 219
 220 AS_COMPILER_FLAG([$SSE_CFLAGS], [HAVE_SSE=1], [HAVE_SSE=0])
 221 AS_COMPILER_FLAG([$SSE2_CFLAGS], [HAVE_SSE2=1], [HAVE_SSE2=0])
 222 AS_COMPILER_FLAG([$SSE41_CFLAGS], [HAVE_SSE41=1], [HAVE_SSE41=0])
 223
 224 AM_CONDITIONAL(HAVE_X86, [test "x${HAVE_X86}" = "x1"])
 225
 226 AC_DEFINE_UNQUOTED(HAVE_SSE, [$HAVE_SSE], [SSE support is enabled])
 227 AC_DEFINE_UNQUOTED(HAVE_SSE2, [$HAVE_SSE2], [SSE2 support is enabled])
 228 AC_DEFINE_UNQUOTED(HAVE_SSE41, [$HAVE_SSE41], [SSE4.1 support is enabled])
 229
 230 AC_SUBST(SSE_CFLAGS)
 231 AC_SUBST(SSE2_CFLAGS)
 232 AC_SUBST(SSE41_CFLAGS)
 233
 234 dnl used in gst/tcp
 235 AC_CHECK_HEADERS([sys/socket.h],
 236   [HAVE_SYS_SOCKET_H="yes"], [HAVE_SYS_SOCKET_H="no"], [AC_INCLUDES_DEFAULT])
 237 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 238
 239 dnl used in gst-libs/gst/rtsp
 240 AC_CHECK_HEADERS([winsock2.h], [HAVE_WINSOCK2_H=yes], [HAVE_WINSOCK2_H=no], [AC_INCLUDES_DEFAULT])
 241 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 242 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 243   WIN32_LIBS="-lws2_32"
 244   AC_SUBST(WIN32_LIBS)
 245 fi
 246
 247 dnl used in gst-libs/gst/pbutils and associated unit test
 248 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h], [], [], [AC_INCLUDES_DEFAULT])
 249
 250 dnl checks for ARM NEON support
 251 dnl this instruction set is used by the speex resampler code
 252 AC_MSG_CHECKING(for ARM NEON support in current arch/CFLAGS)
 253 AC_LINK_IFELSE([
 254 AC_LANG_PROGRAM([[
 255   #include <arm_neon.h>
 256   int32x4_t testfunc(int16_t *a, int16_t *b) {
 257       asm volatile ("vmull.s16 q0, d0, d0" : : : "q0");
 258       return vmull_s16(vld1_s16(a), vld1_s16(b));
 259   }
 260 ]])],
 261 [
 262   AC_DEFINE(HAVE_ARM_NEON,[],[ARM NEON support is enabled])
 263   AC_MSG_RESULT(yes)
 264 ],
 265 [
 266   AC_MSG_RESULT(no)
 267 ])
 268
 269 dnl also, Windows does not have long long
 270 AX_CREATE_STDINT_H
 271
 272 dnl *** checks for functions ***
 273 AC_CHECK_FUNCS([localtime_r gmtime_r])
 274
 275 dnl *** checks for math functions ***
 276 LIBS_SAVE=$LIBS
 277 LIBS="$LIBS $LIBM"
 278 AC_CHECK_FUNCS(log2)
 279 LIBS=$LIBS_SAVE
 280
 281 dnl *** checks for types/defines ***
 282
 283 dnl *** checks for structures ***
 284
 285 dnl *** checks for compiler characteristics ***
 286
 287 dnl *** checks for library functions ***
 288
 289 dnl check for fseeko()
 290 AC_FUNC_FSEEKO
 291
 292 dnl Check for fast float to int casting as defined in C99
 293 dnl used to be used in gst-libs/gst/floatcast/floatcast.h (FIXME: still needed?)
 294 save_libs=$LIBS
 295 LIBS="$LIBS $LIBM"
 296 #AC_C99_FUNC_LRINT
 297 #AC_C99_FUNC_LRINTF
 298 LIBS=$save_libs
 299
 300 dnl Check for a way to display the function name in debug output
 301 AG_GST_CHECK_FUNCTION
 302
 303 dnl *** checks for dependency libraries ***
 304
 305 dnl GLib
 306 GLIB_REQ=2.40.0
 307 AG_GST_GLIB_CHECK([$GLIB_REQ])
 308
 309 ORC_CHECK([0.4.24])
 310
 311 dnl checks for gstreamer
 312 dnl uninstalled is selected preferentially -- see pkg-config(1)
 313 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 314 AG_GST_CHECK_GST_NET($GST_API_VERSION, [$GST_REQ], yes)
 315 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 316 AG_GST_CHECK_GST_CONTROLLER($GST_API_VERSION, [$GST_REQ], yes)
 317 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 318 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 319
 320 dnl Check for documentation xrefs
 321 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 322 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 323 AC_SUBST(GLIB_PREFIX)
 324 AC_SUBST(GST_PREFIX)
 325
 326 dnl GTK is optional and only used in examples
 327 HAVE_GTK=no
 328 HAVE_GTK_X11=no
 329 GTK_REQ=3.10
 330 if test "x$BUILD_EXAMPLES" = "xyes"; then
 331   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 332   dnl some examples need gtk+-x11
 333   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 334   PKG_CHECK_MODULES(GTK_QUARTZ, gtk+-quartz-3.0 >= $GTK_REQ, HAVE_GTK_QUARTZ=yes, HAVE_GTK_QUARTZ=no)
 335   AC_SUBST(GTK_LIBS)
 336   AC_SUBST(GTK_CFLAGS)
 337 fi
 338 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 339 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 340 AM_CONDITIONAL(HAVE_GTK_QUARTZ, test "x$HAVE_GTK_QUARTZ" = "xyes")
 341
 342 HAVE_QT=no
 343 HAVE_QT_MOC=no
 344 dnl QT is optional and only used in examples
 345 PKG_CHECK_MODULES(QT, Qt5Gui Qt5Widgets, [
 346   HAVE_QT=yes
 347 ], [
 348   HAVE_QT=no
 349 ])
 350 if test "x$HAVE_QT" = "xyes"; then
 351   AC_CHECK_TOOL(QT_MOC, moc)
 352   AC_MSG_CHECKING([for Qt5 moc])
 353   mocversion=`$QT_MOC -v 2>&1`
 354   mocversiongrep=`echo $mocversion | grep "Qt 5\|moc 5"`
 355   if test x"$mocversiongrep" != x"$mocversion"; then
 356     AC_MSG_RESULT([no])
 357     # moc was not the qt5 one, try with moc-qt5
 358     AC_CHECK_TOOL(QT_MOC, moc-qt5)
 359     AC_MSG_CHECKING([for Qt5 moc-qt5])
 360     mocversion=`$QT_MOC -v 2>&1`
 361     mocversiongrep=`echo $mocversion | grep "Qt 5\|moc 5"`
 362     if test x"$mocversiongrep" != x"$mocversion"; then
 363       AC_CHECK_TOOL(QTCHOOSER, qtchooser)
 364       AC_MSG_CHECKING([for qtchooser])
 365       qt5tooldir=`QT_SELECT=qt5 qtchooser -print-env | grep QTTOOLDIR | cut -d '=' -f 2 | cut -d \" -f 2`
 366       mocversion=`$qt5tooldir/moc -v 2>&1`
 367       mocversiongrep=`echo $mocversion | grep "Qt 5\|moc 5"`
 368       if test x"$mocversiongrep" != x"$mocversion"; then
 369         # no valid moc found
 370         QT_MOC="no"
 371       else
 372         QT_MOC=$qt5tooldir/moc
 373       fi
 374     else
 375       QT_MOC=$QT_MOC
 376     fi
 377   fi
 378   AC_SUBST(QT_MOC)
 379   AC_MSG_RESULT([$QT_MOC])
 380 fi
 381 AM_CONDITIONAL(HAVE_QT, test "x$HAVE_QT" = "xyes")
 382 AM_CONDITIONAL(HAVE_QT_MOC, test "x$HAVE_QT_MOC" != "xno")
 383
 384 dnl chck for linux headers needed by the joystick seek example
 385 AC_COMPILE_IFELSE(
 386 [
 387   AC_LANG_PROGRAM([
 388     #include <linux/input.h>
 389     #include <linux/joystick.h>
 390   ],[
 391     struct js_event js;
 392     js.type = JS_EVENT_AXIS;
 393   ])
 394 ], [
 395   HAVE_LINUX_JOYSTICK_HEADERS="yes"
 396 ], [
 397   HAVE_LINUX_JOYSTICK_HEADERS="no"
 398 ])
 399 AM_CONDITIONAL(HAVE_LINUX_JOYSTICK_HEADERS, test "x$HAVE_LINUX_JOYSTICK_HEADERS" = "xyes")
 400
 401 dnl Check for -Bsymbolic-functions linker flag used to avoid
 402 dnl intra-library PLT jumps, if available.
 403 AC_ARG_ENABLE(Bsymbolic,
 404               [AS_HELP_STRING([--disable-Bsymbolic],[avoid linking with -Bsymbolic])],,
 405               [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
 406                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 407                LDFLAGS=-Wl,-Bsymbolic-functions
 408                LIBS=
 409                AC_TRY_LINK([], [return 0],
 410                            AC_MSG_RESULT(yes)
 411                            enable_Bsymbolic=yes,
 412                            AC_MSG_RESULT(no)
 413                            enable_Bsymbolic=no)
 414                LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
 415
 416
 417 dnl *** set variables based on configure arguments ***
 418
 419 dnl set license and copyright notice
 420 GST_LICENSE="LGPL"
 421 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 422 AC_SUBST(GST_LICENSE)
 423
 424 dnl set location of plugin directory
 425 AG_GST_SET_PLUGINDIR
 426
 427 dnl set release date/time
 428 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 429   ["${srcdir}/gst-plugins-base.doap"],
 430   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 431
 432 dnl build static plugins or not
 433 AC_MSG_CHECKING([whether to build static plugins or not])
 434 AC_ARG_ENABLE(
 435   static-plugins,
 436   AC_HELP_STRING(
 437     [--enable-static-plugins],
 438     [build static plugins @<:@default=no@:>@]),
 439   [AS_CASE(
 440     [$enableval], [no], [], [yes], [],
 441     [AC_MSG_ERROR([bad value "$enableval" for --enable-static-plugins])])],
 442   [enable_static_plugins=no])
 443 AC_MSG_RESULT([$enable_static_plugins])
 444 if test "x$enable_static_plugins" = xyes; then
 445   AC_DEFINE(GST_PLUGIN_BUILD_STATIC, 1,
 446     [Define if static plugins should be built])
 447   GST_PLUGIN_LIBTOOLFLAGS=""
 448 else
 449   GST_PLUGIN_LIBTOOLFLAGS="--tag=disable-static"
 450 fi
 451 AC_SUBST(GST_PLUGIN_LIBTOOLFLAGS)
 452 AM_CONDITIONAL(GST_PLUGIN_BUILD_STATIC, test "x$enable_static_plugins" = "xyes")
 453
 454 dnl If only building static libraries, define GST_STATIC_COMPILATION. This is
 455 dnl needed only on Windows, but it doesn't hurt to have it everywhere.
 456 if test x$enable_static = xyes -a x$enable_shared = xno; then
 457   GST_STATIC_CFLAGS="-DGST_STATIC_COMPILATION"
 458 fi
 459
 460 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 461 dnl make sure it doesn't complain about unused variables if debugging is disabled
 462 NO_WARNINGS=""
 463 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 464
 465 dnl define an ERROR_CFLAGS Makefile variable
 466 dnl -Wformat-nonliteral - see ext/pango/gstclockoverlay.c and http://gcc.gnu.org/bugzilla/show_bug.cgi?id=39438
 467 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 468     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef
 469     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 470     -Winit-self -Wmissing-include-dirs -Waddress
 471     -Wno-multichar -Wnested-externs $NO_WARNINGS])
 472
 473 dnl define an ERROR_CXXFLAGS Makefile variable
 474 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 475     -Wmissing-declarations -Wredundant-decls -Wundef
 476     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 477     -Winit-self -Wmissing-include-dirs -Waddress
 478     -Wno-multichar $NO_WARNINGS])
 479
 480 dnl define correct level for debugging messages
 481 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 482
 483 dnl used in examples
 484 AG_GST_DEFAULT_ELEMENTS
 485
 486 dnl needed for encoding-target
 487 GST_DATADIR="$GST_PREFIX/share"
 488 AC_DEFINE_UNQUOTED(GST_DATADIR, "$GST_DATADIR", [system wide data directory])
 489 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION", [major/minor version])
 490
 491 dnl behaviour of speex based audio resampler
 492 AC_MSG_CHECKING(which audio resample format to use for integer)
 493 AC_ARG_WITH([audioresample_format],
 494         AS_HELP_STRING([--with-audioresample-format],[Which implementation should be used for integer audio resampling, int/float/auto, (default is auto)]),
 495         [ac_cv_audioresample_format=$withval], [ac_cv_audioresample_format=auto])dnl
 496 AC_MSG_RESULT($ac_cv_audioresample_format)
 497 case $ac_cv_audioresample_format in
 498   int)
 499     AC_DEFINE(AUDIORESAMPLE_FORMAT_INT,1,[The int implementation should be used for integer audio resampling])
 500     AC_SUBST(AUDIORESAMPLE_FORMAT_INT)
 501   ;;
 502   float)
 503     AC_DEFINE(AUDIORESAMPLE_FORMAT_FLOAT,1,[The float implementation should be used for integer audio resampling])
 504     AC_SUBST(AUDIORESAMPLE_FORMAT_FLOAT)
 505   ;;
 506   auto)
 507     AC_DEFINE(AUDIORESAMPLE_FORMAT_AUTO,1,[The implementation that should be used for integer audio resampling witll be benchmarked at runtime])
 508     AC_SUBST(AUDIORESAMPLE_FORMAT_AUTO)
 509 esac
 510
 511 dnl Check for mmap (needed by allocators library)
 512 AC_CHECK_FUNC([mmap], [AC_DEFINE(HAVE_MMAP, 1, [Defined if mmap is supported])])
 513
 514 dnl *** plug-ins to include ***
 515
 516 dnl these are all the gst plug-ins, compilable without additional libs
 517 AG_GST_CHECK_PLUGIN(adder)
 518 AG_GST_CHECK_PLUGIN(app)
 519 AG_GST_CHECK_PLUGIN(audioconvert)
 520 AG_GST_CHECK_PLUGIN(audiorate)
 521 AG_GST_CHECK_PLUGIN(audiotestsrc)
 522 AG_GST_CHECK_PLUGIN(encoding)
 523 AG_GST_CHECK_PLUGIN(videoconvert)
 524 AG_GST_CHECK_PLUGIN(gio)
 525 AG_GST_CHECK_PLUGIN(playback)
 526 AG_GST_CHECK_PLUGIN(audioresample)
 527 AG_GST_CHECK_PLUGIN(rawparse)
 528 AG_GST_CHECK_PLUGIN(subparse)
 529 AG_GST_CHECK_PLUGIN(tcp)
 530 AG_GST_CHECK_PLUGIN(typefind)
 531 AG_GST_CHECK_PLUGIN(videotestsrc)
 532 AG_GST_CHECK_PLUGIN(videorate)
 533 AG_GST_CHECK_PLUGIN(videoscale)
 534 AG_GST_CHECK_PLUGIN(volume)
 535
 536 dnl iso-codes is optional, used by libgsttag
 537 AC_ARG_ENABLE(iso-codes,
 538 AS_HELP_STRING([--enable-iso-codes],[use iso-codes if installed]),
 539 [case "${enableval}" in
 540   yes) enable_iso_codes=yes ;;
 541   no)  enable_iso_codes=no ;;
 542   *) AC_MSG_ERROR(bad value ${enableval} for --enable-iso-codes) ;;
 543 esac
 544 ],
 545 [enable_iso_codes=yes]) dnl Default value
 546
 547 AC_MSG_CHECKING([whether to use iso-codes if they are available])
 548 if test "x$enable_iso_codes" = "xyes"; then
 549   AC_MSG_RESULT([yes])
 550   have_iso_codes=no
 551   AC_MSG_CHECKING([whether iso-codes are available on this system])
 552   if $PKG_CONFIG iso-codes; then
 553     AC_MSG_RESULT([yes])
 554     AC_MSG_CHECKING([whether iso-codes has iso-639 domain])
 555     if $PKG_CONFIG --variable=domains iso-codes | $GREP -q 639 ; then
 556       AC_MSG_RESULT([yes])
 557       AC_MSG_CHECKING([for iso-codes prefix])
 558       ISO_CODES_PREFIX=`$PKG_CONFIG --variable=prefix iso-codes`
 559       if test -d "$ISO_CODES_PREFIX"; then
 560         AC_MSG_RESULT([yes])
 561         AC_MSG_CHECKING([ISO_CODES_PREFIX])
 562         AC_MSG_RESULT([$ISO_CODES_PREFIX])
 563         ISO_639_DOMAIN="iso_639"
 564         AC_MSG_CHECKING([ISO_639_DOMAIN])
 565         AC_MSG_RESULT([$ISO_639_DOMAIN])
 566         have_iso_codes=yes
 567         AC_DEFINE([HAVE_ISO_CODES], [1], [make use of iso-codes for ISO-639])
 568         AC_DEFINE_UNQUOTED([ISO_CODES_PREFIX], ["$ISO_CODES_PREFIX"], [prefix])
 569         ISO_CODES_VERSION=`$PKG_CONFIG --modversion iso-codes`
 570         AC_DEFINE_UNQUOTED([ISO_CODES_VERSION], ["$ISO_CODES_VERSION"], [ ])
 571       else
 572         AC_MSG_RESULT([no])
 573       fi
 574     else
 575       AC_MSG_RESULT([no])
 576     fi
 577   else
 578     AC_MSG_RESULT([no])
 579   fi
 580   AM_CONDITIONAL(USE_ISO_CODES, test "x$have_iso_codes" = "xyes")
 581 else
 582   AC_MSG_RESULT([no (disabled via --disable-iso-codes)])
 583   AM_CONDITIONAL(USE_ISO_CODES, false)
 584 fi
 585
 586 dnl *** zlib is optionally used by id3 tag parsing in libgsttag ***
 587 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 588 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for ID3 parsing in libgsttag],, [
 589   PKG_CHECK_MODULES(ZLIB, [ zlib ], [
 590       HAVE_ZLIB="yes"
 591     ], [
 592       AG_GST_CHECK_LIBHEADER(ZLIB, z, uncompress,, zlib.h, [
 593         HAVE_ZLIB="yes"
 594         ZLIB_LIBS="-lz"
 595         AC_SUBST(ZLIB_LIBS)
 596       ])
 597     ])
 598 ])
 599
 600 dnl *** sys plug-ins ***
 601
 602 echo
 603 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 604 echo
 605
 606 dnl *** X11 ***
 607 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 608 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 609                   [ximagesink], [
 610   AG_GST_PKG_CHECK_MODULES(X, x11)
 611 ])
 612
 613 dnl Check for Xv extension
 614 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 615 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 616                   [xvimagesink], [
 617   AG_GST_PKG_CHECK_MODULES(XVIDEO, x11 xv)
 618 ])
 619
 620 dnl check for X Shm
 621 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 622 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], [ ], [
 623   if test x$HAVE_X = xyes; then
 624     PKG_CHECK_MODULES(XSHM, xext, [
 625       AC_CHECK_LIB(Xext, XShmAttach, [
 626         HAVE_XSHM="yes"
 627       ], [
 628         HAVE_XSHM="no"
 629         XSHM_LIBS=""
 630       ], [ $X_LIBS ])
 631     ], [
 632       HAVE_XSHM="no"
 633     ])
 634   fi
 635 ], , [
 636   AC_SUBST(HAVE_XSHM)
 637   AC_SUBST(XSHM_LIBS)
 638 ])
 639
 640 dnl *** ext plug-ins ***
 641 dnl keep this list sorted alphabetically !
 642
 643 if test "x$BUILD_EXTERNAL" = "xyes"; then
 644
 645 echo
 646 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 647 echo
 648
 649 dnl *** alsa ***
 650 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 651 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 652   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 653     HAVE_ALSA="yes"
 654     AC_SUBST(ALSA_CFLAGS)
 655     AC_SUBST(ALSA_LIBS)
 656   ], [
 657     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 658   ])
 659 ])
 660
 661 dnl *** CDParanoia ***
 662 dnl Note: upstream has a pkg-config file only in post-10.2 SVN so far
 663 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 664 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 665   PKG_CHECK_MODULES(CDPARANOIA, cdparanoia-3 >= 10.2, [
 666     HAVE_CDPARANOIA="yes"
 667   ], [
 668     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 669                         cdda_open, -lm,
 670                         cdda_interface.h,
 671                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 672                         HEADER_DIR="no"
 673                         FOUND_CDPARANOIA="yes")
 674     if test "x$FOUND_CDPARANOIA" != "xyes";
 675     then
 676       AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 677                           cdda_open, -lm,
 678                           cdda/cdda_interface.h,
 679                           CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 680                           HEADER_DIR="yes"
 681                           FOUND_CDPARANOIA="yes")
 682     fi
 683     if test "x$HEADER_DIR" = "xyes";
 684     then
 685       AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 686                          defined if cdda headers are in a cdda/ directory)
 687     fi
 688     if test "x$FOUND_CDPARANOIA" = "xyes";
 689     then
 690       AC_CHECK_LIB(cdda_paranoia,
 691                    paranoia_cachemodel_size,
 692                    : ,
 693                    HAVE_CDPARANOIA=no,
 694                  [-lcdda_interface])
 695     fi
 696
 697     AC_SUBST(CDPARANOIA_LIBS)
 698   ])
 699 ])
 700 dnl FIXME : add second check somehow if that is necessary
 701 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 702 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 703
 704 dnl *** ivorbis ***
 705 dnl AM_PATH_IVORBIS only takes two options
 706 translit(dnm, m, l) AM_CONDITIONAL(USE_IVORBIS, true)
 707 AG_GST_CHECK_FEATURE(IVORBIS, [integer vorbis plug-in], ivorbisdec, [
 708   AG_GST_PKG_CHECK_MODULES(IVORBIS, vorbisidec)
 709   if test $HAVE_IVORBIS = no
 710   then
 711     IVORBIS_LIBS=
 712     IVORBIS_CFLAGS=
 713     AC_CHECK_LIB(vorbisidec, vorbis_block_init,
 714       [IVORBIS_LIBS=-lvorbisidec
 715       HAVE_IVORBIS=yes
 716       case $host in
 717       arm-*-*)
 718         IVORBIS_CFLAGS="-D_ARM_ASSEM_ $IVORBIS_CFLAGS"
 719       esac
 720       ],
 721       HAVE_IVORBIS=no)
 722     AC_SUBST(IVORBIS_LIBS)
 723     AC_SUBST(IVORBIS_CFLAGS)
 724   else
 725     AC_CHECK_LIB(vorbisidec, vorbis_dsp_pcmout,
 726       AC_DEFINE([USE_TREMOLO],1, "Define if building for android"),
 727       USE_TREMOLO=no)
 728   fi
 729 ])
 730
 731 dnl *** libvisual ***
 732 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 733 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 734   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 735   if test x$HAVE_LIBVISUAL = xyes; then
 736     LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.4`"
 737   fi
 738   AC_MSG_NOTICE([libvisual pluginsdir: $LIBVIS_PLUGINSDIR])
 739   if test x$LIBVIS_PLUGINSDIR != x; then
 740     AC_DEFINE_UNQUOTED(LIBVISUAL_PLUGINSBASEDIR,
 741         "$LIBVIS_PLUGINSDIR",
 742         [directory in which the detected libvisual's plugins are located])
 743   fi
 744 ])
 745
 746 dnl *** ogg ***
 747 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 748 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 749   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 750 ])
 751
 752 dnl *** Opus ***
 753 translit(dnm, m, l) AM_CONDITIONAL(USE_OPUS, true)
 754 AG_GST_CHECK_FEATURE(OPUS, [opus], opus, [
 755   PKG_CHECK_MODULES(OPUS, opus >= 0.9.4, [
 756           AC_DEFINE([HAVE_OPUS], 1, [Define if Opus >= 0.9.4 is installed])
 757           HAVE_OPUS="yes"
 758   ], [
 759           HAVE_OPUS="no"
 760   ])
 761   AC_SUBST(OPUS_CFLAGS)
 762   AC_SUBST(OPUS_LIBS)
 763 ])
 764
 765 dnl *** pango ***
 766 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 767 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 768   AG_GST_PKG_CHECK_MODULES(PANGO, pango >= 1.22.0  pangocairo >= 1.22.0)
 769 ])
 770
 771 dnl *** theora ***
 772 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 773 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 774   AG_GST_PKG_CHECK_MODULES(THEORA, theoradec >= 1.1 theoraenc >= 1.1)
 775 ])
 776
 777 dnl *** vorbis ***
 778 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 779 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 780   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 781 ])
 782
 783 if test "x$HAVE_VORBIS" = "xyes"; then
 784   ac_cflags_save="$CFLAGS"
 785   AC_COMPILE_IFELSE([
 786     AC_LANG_PROGRAM([[
 787 #include <vorbis/codec.h>
 788                      ]],[[
 789 vorbis_dsp_state *v;
 790
 791 vorbis_synthesis_restart (v);
 792                      ]])], HAVE_VSR=yes, HAVE_VSR=no)
 793   if test "x$HAVE_VSR" = "xyes"; then
 794     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 795                        [defined if vorbis_synthesis_restart is present])
 796   fi
 797   CFLAGS="$ac_cflags_save"
 798 fi
 799
 800 else
 801
 802 dnl not building plugins with external dependencies,
 803 dnl but we still need to set the conditionals
 804 AM_CONDITIONAL(USE_ALSA, false)
 805 AM_CONDITIONAL(USE_CDPARANOIA, false)
 806 AM_CONDITIONAL(USE_IVORBIS, false)
 807 AM_CONDITIONAL(USE_LIBVISUAL, false)
 808 AM_CONDITIONAL(USE_OGG, false)
 809 AM_CONDITIONAL(USE_OPUS, false)
 810 AM_CONDITIONAL(USE_PANGO, false)
 811 AM_CONDITIONAL(USE_THEORA, false)
 812 AM_CONDITIONAL(USE_VORBIS, false)
 813
 814 fi dnl of EXT plugins
 815
 816 dnl *** gio-unix-2.0 for tests/check/pipelines/tcp.c ***
 817 PKG_CHECK_MODULES(GIO_UNIX_2_0, gio-unix-2.0 >= 2.24,
 818     HAVE_GIO_UNIX_2_0="yes",
 819     HAVE_GIO_UNIX_2_0="no")
 820 AM_CONDITIONAL(USE_GIO_UNIX_2_0, test "x$HAVE_GIO_UNIX_2_0" = "xyes")
 821
 822 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 823
 824 dnl Overview:
 825 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 826 dnl GST_*:              flags shared by built objects to link against GStreamer
 827 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 828 dnl                          (compare to other modules) or for i18n
 829 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 830 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 831 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 832 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 833
 834 dnl GST_OPTION_CFLAGS
 835 if test "x$USE_DEBUG" = xyes; then
 836    PROFILE_CFLAGS="-g"
 837 fi
 838 AC_SUBST(PROFILE_CFLAGS)
 839
 840 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 841   dnl Define _only_ when compiling a git version (not pre-releases or releases)
 842   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 843 else
 844   DEPRECATED_CFLAGS=""
 845 fi
 846 AC_SUBST(DEPRECATED_CFLAGS)
 847
 848 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 849 dnl at make time with e.g. make ERROR_CFLAGS=""
 850 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 851 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 852 AC_SUBST(GST_OPTION_CFLAGS)
 853 AC_SUBST(GST_OPTION_CXXFLAGS)
 854
 855 dnl our libraries need to be versioned correctly
 856 AC_SUBST(GST_LT_LDFLAGS)
 857
 858 dnl GST_PLUGINS_BASE_CFLAGS
 859 dnl prefer internal headers to already installed ones
 860 dnl also add builddir include for enumtypes and marshal
 861 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 862 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 863
 864 dnl FIXME: do we want to rename to GST_ALL_* ?
 865 dnl add GST_OPTION_CFLAGS, but overridable
 866 GST_CFLAGS="$GST_CFLAGS $GST_STATIC_CFLAGS"
 867 GST_CXXFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CXXFLAGS)"
 868 GST_CFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CFLAGS)"
 869 AC_SUBST(GST_CFLAGS)
 870 AC_SUBST(GST_CXXFLAGS)
 871 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 872 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 873 AC_SUBST(GST_LIBS)
 874
 875 dnl LDFLAGS really should only contain flags, not libs - they get added before
 876 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 877 GST_ALL_LDFLAGS="-no-undefined"
 878 if test "x${enable_Bsymbolic}" = "xyes"; then
 879   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 880 fi
 881 AC_SUBST(GST_ALL_LDFLAGS)
 882
 883 dnl GST_LIB_LDFLAGS
 884 dnl linker flags shared by all libraries
 885 dnl LDFLAGS modifier defining exported symbols from built libraries
 886 dnl (export _gst_foo but not __gst_foo)
 887 GST_LIB_LDFLAGS="-export-symbols-regex ^_?\(gst_\|Gst\|GST_\).*"
 888 AC_SUBST(GST_LIB_LDFLAGS)
 889
 890 dnl this really should only contain flags, not libs - they get added before
 891 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 892 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_.*' $GST_ALL_LDFLAGS"
 893 AC_SUBST(GST_PLUGIN_LDFLAGS)
 894
 895 dnl use tbm
 896 PKG_CHECK_MODULES(TBM, libdrm libtbm)
 897 AC_SUBST(TBM_CFLAGS)
 898 AC_SUBST(TBM_LIBS)
 899
 900 dnl use  mm-common
 901 PKG_CHECK_MODULES(MMCOMMON,mm-common)
 902 AC_SUBST(MMCOMMON_CFLAGS)
 903
 904 dnl *** output files ***
 905
 906 $MKDIR_P tests/check/orc
 907
 908 AC_CONFIG_FILES(
 909 Makefile
 910 gst/Makefile
 911 gst/adder/Makefile
 912 gst/app/Makefile
 913 gst/audioconvert/Makefile
 914 gst/audiorate/Makefile
 915 gst/audioresample/Makefile
 916 gst/audiotestsrc/Makefile
 917 gst/encoding/Makefile
 918 gst/videoconvert/Makefile
 919 gst/gio/Makefile
 920 gst/pbtypes/Makefile
 921 gst/playback/Makefile
 922 gst/rawparse/Makefile
 923 gst/subparse/Makefile
 924 gst/tcp/Makefile
 925 gst/typefind/Makefile
 926 gst/videotestsrc/Makefile
 927 gst/videorate/Makefile
 928 gst/videoscale/Makefile
 929 gst/volume/Makefile
 930 sys/Makefile
 931 sys/ximage/Makefile
 932 sys/xvimage/Makefile
 933 ext/Makefile
 934 ext/alsa/Makefile
 935 ext/cdparanoia/Makefile
 936 ext/libvisual/Makefile
 937 ext/ogg/Makefile
 938 ext/opus/Makefile
 939 ext/pango/Makefile
 940 ext/theora/Makefile
 941 ext/vorbis/Makefile
 942 gst-libs/Makefile
 943 gst-libs/gst/Makefile
 944 gst-libs/gst/allocators/Makefile
 945 gst-libs/gst/audio/Makefile
 946 gst-libs/gst/app/Makefile
 947 gst-libs/gst/fft/Makefile
 948 gst-libs/gst/riff/Makefile
 949 gst-libs/gst/rtp/Makefile
 950 gst-libs/gst/rtsp/Makefile
 951 gst-libs/gst/sdp/Makefile
 952 gst-libs/gst/tag/Makefile
 953 gst-libs/gst/pbutils/Makefile
 954 gst-libs/gst/pbutils/gstpluginsbaseversion.h
 955 gst-libs/gst/video/Makefile
 956 tools/Makefile
 957 pkgconfig/Makefile
 958 pkgconfig/gstreamer-allocators.pc
 959 pkgconfig/gstreamer-allocators-uninstalled.pc
 960 pkgconfig/gstreamer-audio.pc
 961 pkgconfig/gstreamer-audio-uninstalled.pc
 962 pkgconfig/gstreamer-app.pc
 963 pkgconfig/gstreamer-app-uninstalled.pc
 964 pkgconfig/gstreamer-fft.pc
 965 pkgconfig/gstreamer-fft-uninstalled.pc
 966 pkgconfig/gstreamer-pbutils.pc
 967 pkgconfig/gstreamer-pbutils-uninstalled.pc
 968 pkgconfig/gstreamer-riff.pc
 969 pkgconfig/gstreamer-riff-uninstalled.pc
 970 pkgconfig/gstreamer-rtp.pc
 971 pkgconfig/gstreamer-rtp-uninstalled.pc
 972 pkgconfig/gstreamer-rtsp.pc
 973 pkgconfig/gstreamer-rtsp-uninstalled.pc
 974 pkgconfig/gstreamer-sdp.pc
 975 pkgconfig/gstreamer-sdp-uninstalled.pc
 976 pkgconfig/gstreamer-tag.pc
 977 pkgconfig/gstreamer-tag-uninstalled.pc
 978 pkgconfig/gstreamer-video.pc
 979 pkgconfig/gstreamer-video-uninstalled.pc
 980 pkgconfig/gstreamer-plugins-base.pc
 981 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 982 tests/Makefile
 983 tests/check/Makefile
 984 tests/examples/Makefile
 985 tests/examples/app/Makefile
 986 tests/examples/audio/Makefile
 987 tests/examples/decodebin_next/Makefile
 988 tests/examples/dynamic/Makefile
 989 tests/examples/encoding/Makefile
 990 tests/examples/fft/Makefile
 991 tests/examples/gio/Makefile
 992 tests/examples/overlay/Makefile
 993 tests/examples/seek/Makefile
 994 tests/examples/snapshot/Makefile
 995 tests/examples/playback/Makefile
 996 tests/examples/playrec/Makefile
 997 tests/files/Makefile
 998 tests/icles/Makefile
 999 tests/icles/playback/Makefile
1000 docs/Makefile
1001 docs/libs/Makefile
1002 docs/plugins/Makefile
1003 docs/version.entities
1004 po/Makefile.in
1005 common/Makefile
1006 common/m4/Makefile
1007 m4/Makefile
1008 )
1009 AC_OUTPUT
1010
1011 AG_GST_OUTPUT_PLUGINS
1012 ORC_OUTPUT
1013