configure.ac

   1 AC_PREREQ([2.68])
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/pre
   8 AC_INIT([GStreamer Good Plug-ins],[1.3.0.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gst-plugins-good])
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.11 no-dist-gzip dist-xz tar-ustar subdir-objects])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  23
  24 dnl define the output header for config
  25 AC_CONFIG_HEADERS([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output with automake >= 1.11
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  35   [AM_DEFAULT_VERBOSITY=1
  36    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  37
  38 dnl our libraries and install dirs use GST_API_VERSION in the filename
  39 dnl to allow side-by-side installation of different API versions
  40 GST_API_VERSION=1.0
  41 AC_SUBST(GST_API_VERSION)
  42 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  43   [GStreamer API Version])
  44
  45 AG_GST_LIBTOOL_PREPARE
  46 AS_LIBTOOL(GST, 300, 0, 300)
  47
  48 dnl *** required versions of GStreamer stuff ***
  49 GST_REQ=1.3.0.1
  50 GSTPB_REQ=1.3.0.1
  51
  52 dnl *** autotools stuff ****
  53
  54 dnl allow for different autotools
  55 AS_AUTOTOOLS_ALTERNATE
  56
  57 dnl Add parameters for aclocal
  58 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  59
  60 dnl set up gettext
  61 dnl the version check needs to stay here because autopoint greps for it
  62 AM_GNU_GETTEXT_VERSION([0.17])
  63 AM_GNU_GETTEXT([external])
  64 AG_GST_GETTEXT([gst-plugins-good-$GST_API_VERSION])
  65
  66 dnl *** check for arguments to configure ***
  67
  68 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  69
  70 AG_GST_ARG_DEBUG
  71 AG_GST_ARG_PROFILING
  72 AG_GST_ARG_VALGRIND
  73 AG_GST_ARG_GCOV
  74
  75 AG_GST_ARG_EXAMPLES
  76
  77 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  78 AG_GST_ARG_WITH_PACKAGE_NAME
  79 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  80
  81 AG_GST_ARG_WITH_PLUGINS
  82
  83 AG_GST_ARG_ENABLE_EXTERNAL
  84
  85 AG_GST_ARG_ENABLE_EXPERIMENTAL
  86
  87 dnl *** checks for platform ***
  88
  89 dnl * hardware/architecture *
  90
  91 dnl common/m4/gst-arch.m4
  92 dnl check CPU type
  93 AG_GST_ARCH
  94
  95 dnl Determine endianness
  96 AC_C_BIGENDIAN
  97
  98 dnl *** checks for programs ***
  99
 100 dnl find a compiler
 101 AC_PROG_CC
 102 AC_PROG_CC_STDC
 103
 104 dnl determine c++ compiler
 105 AC_PROG_CXX
 106 dnl determine if c++ is available on this system
 107 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 108
 109 dnl determine c++ preprocessor
 110 dnl FIXME: do we need this ?
 111 AC_PROG_CXXCPP
 112
 113 AC_PROG_OBJC
 114
 115 dnl check if the compiler supports '-c' and '-o' options
 116 AM_PROG_CC_C_O
 117
 118 dnl find an assembler
 119 AM_PROG_AS
 120
 121 dnl check if the compiler supports do while(0) macros
 122 AG_GST_CHECK_DOWHILE_MACROS
 123
 124 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 125 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 126
 127 dnl check for documentation tools
 128 GTK_DOC_CHECK([1.12])
 129 AG_GST_PLUGIN_DOCS([1.12])
 130
 131 dnl *** checks for libraries ***
 132
 133 dnl check for libm, for sin()
 134 LT_LIB_M
 135 AC_SUBST(LIBM)
 136
 137 AC_CHECK_FUNCS(clock_gettime, [], [
 138   AC_CHECK_LIB(rt, clock_gettime, [
 139     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 140     LIBRT="-lrt"
 141     AC_SUBST([LIBRT])
 142   ])
 143 ])
 144
 145 dnl *** checks for header files ***
 146
 147 dnl check if we have ANSI C header files
 148 AC_HEADER_STDC
 149
 150 dnl used by ext/wavpack
 151 AX_CREATE_STDINT_H
 152
 153 dnl used in gst/udp
 154 AC_CHECK_HEADERS([sys/time.h])
 155
 156 dnl used in gst/udp
 157 AC_CHECK_HEADERS([sys/socket.h])
 158
 159 dnl *** checks for types/defines ***
 160
 161 dnl Check for FIONREAD ioctl declaration.  This check is needed
 162 dnl for the UDP plugin to build on Solaris
 163 GST_CHECK_FIONREAD
 164
 165 dnl *** checks for structures ***
 166
 167 dnl *** checks for compiler characteristics ***
 168
 169 dnl check if we have GCC inline-asm
 170 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 171 if test x$HAVE_GCC_ASM = xyes ; then
 172   AC_DEFINE(HAVE_GCC_ASM, 1,
 173     [Define if compiler supports gcc inline assembly])
 174 fi
 175 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 176
 177 dnl *** checks for library functions ***
 178
 179 LIBS_SAVE=$LIBS
 180 LIBS="$LIBS $LIBM"
 181 AC_CHECK_FUNCS(rint sinh cosh asinh fpclass)
 182 LIBS=$LIBS_SAVE
 183
 184 dnl Check whether isinf() is defined by math.h
 185 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
 186     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; int i=isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
 187 if test "$ac_cv_have_isinf" = "yes"
 188 then
 189     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
 190 fi
 191
 192 dnl Check for mmap (needed by electricfence plugin)
 193 AC_FUNC_MMAP
 194 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 195
 196 dnl Check for mmap (needed by electricfence plugin)
 197
 198 AC_CHECK_TYPE([struct ip_mreqn], [
 199               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
 200               [#include <netinet/in.h>])
 201
 202 dnl *** checks for dependency libraries ***
 203
 204
 205 dnl GLib
 206 GLIB_REQ=2.32.0
 207 AG_GST_GLIB_CHECK([$GLIB_REQ])
 208
 209 dnl Orc
 210 ORC_CHECK([0.4.17])
 211
 212 dnl checks for gstreamer
 213 dnl uninstalled is selected preferentially -- see pkg-config(1)
 214 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 215 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 216 AG_GST_CHECK_GST_CONTROLLER($GST_API_VERSION, [$GST_REQ], yes)
 217 AG_GST_CHECK_GST_NET($GST_API_VERSION, [$GST_REQ], yes)
 218 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 219 AG_GST_CHECK_GST_PLUGINS_BASE($GST_API_VERSION, [$GSTPB_REQ], yes)
 220
 221 GST_TOOLS_DIR=`$PKG_CONFIG --variable=toolsdir gstreamer-$GST_API_VERSION`
 222 if test -z $GST_TOOLS_DIR; then
 223   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 224 fi
 225 AC_SUBST(GST_TOOLS_DIR)
 226
 227 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 228 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 229
 230 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 231
 232 dnl Check for documentation xrefs
 233 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 234 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 235 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_API_VERSION`"
 236 AC_SUBST(GLIB_PREFIX)
 237 AC_SUBST(GST_PREFIX)
 238 AC_SUBST(GSTPB_PREFIX)
 239
 240 dnl GTK is optional and used in examples
 241 HAVE_GTK=no
 242 GTK_REQ=3.0.0
 243 if test "x$BUILD_EXAMPLES" = "xyes"; then
 244   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 245   dnl some examples need gtk+-x11
 246   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 247   AC_SUBST(GTK_LIBS)
 248   AC_SUBST(GTK_CFLAGS)
 249 fi
 250 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 251 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 252
 253 dnl *** set variables based on configure arguments ***
 254
 255 dnl set license and copyright notice
 256 GST_LICENSE="LGPL"
 257 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 258 AC_SUBST(GST_LICENSE)
 259
 260 dnl set location of plugin directory
 261 AG_GST_SET_PLUGINDIR
 262
 263 dnl set release date/time
 264 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 265   ["${srcdir}/gst-plugins-good.doap"],
 266   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 267
 268 dnl build static plugins or not
 269 AC_MSG_CHECKING([whether to build static plugins or not])
 270 AC_ARG_ENABLE(
 271   static-plugins,
 272   AC_HELP_STRING(
 273     [--enable-static-plugins],
 274     [build static plugins @<:@default=no@:>@]),
 275   [AS_CASE(
 276     [$enableval], [no], [], [yes], [],
 277     [AC_MSG_ERROR([bad value "$enableval" for --enable-static-plugins])])],
 278   [enable_static_plugins=no])
 279 AC_MSG_RESULT([$enable_static_plugins])
 280 if test "x$enable_static_plugins" = xyes; then
 281   AC_DEFINE(GST_PLUGIN_BUILD_STATIC, 1,
 282     [Define if static plugins should be built])
 283   GST_PLUGIN_LIBTOOLFLAGS=""
 284 else
 285   GST_PLUGIN_LIBTOOLFLAGS="--tag=disable-static"
 286 fi
 287 AC_SUBST(GST_PLUGIN_LIBTOOLFLAGS)
 288 AM_CONDITIONAL(GST_PLUGIN_BUILD_STATIC, test "x$enable_static_plugins" = "xyes")
 289
 290 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 291 dnl make sure it doesn't complain about unused variables if debugging is disabled
 292 NO_WARNINGS=""
 293 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 294
 295 dnl define an ERROR_CFLAGS Makefile variable
 296 dnl -Wundef: too many broken headers
 297 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 298       -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 299       -Wwrite-strings -Wold-style-definition -Waggregate-return
 300       -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 301       -Wnested-externs $NO_WARNINGS])
 302
 303 dnl define an ERROR_CXXFLAGS Makefile variable
 304 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 305         -Wmissing-declarations -Wredundant-decls
 306         -Wwrite-strings
 307         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 308         $NO_WARNINGS])
 309
 310 dnl define an ERROR_OBJCFLAGS Makefile variable
 311 AG_GST_SET_ERROR_OBJCFLAGS($FATAL_WARNINGS, [
 312       -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 313       -Wwrite-strings -Wold-style-definition
 314       -Winit-self -Wmissing-include-dirs -Wno-multichar
 315       -Wnested-externs $NO_WARNINGS])
 316
 317 dnl define correct level for debugging messages
 318 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 319
 320 dnl used in examples
 321 AG_GST_DEFAULT_ELEMENTS
 322
 323 dnl *** plug-ins to include ***
 324
 325 dnl these are all the gst plug-ins, compilable without additional libs
 326 dnl videofilter is at the top because others depend on it
 327 AG_GST_CHECK_PLUGIN(alpha)
 328 AG_GST_CHECK_PLUGIN(apetag)
 329 AG_GST_CHECK_PLUGIN(audiofx)
 330 AG_GST_CHECK_PLUGIN(audioparsers)
 331 AG_GST_CHECK_PLUGIN(auparse)
 332 AG_GST_CHECK_PLUGIN(autodetect)
 333 AG_GST_CHECK_PLUGIN(avi)
 334 AG_GST_CHECK_PLUGIN(cutter)
 335 AG_GST_CHECK_PLUGIN(debugutils)
 336 AG_GST_CHECK_PLUGIN(deinterlace)
 337 AG_GST_CHECK_PLUGIN(dtmf)
 338 AG_GST_CHECK_PLUGIN(effectv)
 339 AG_GST_CHECK_PLUGIN(equalizer)
 340 AG_GST_CHECK_PLUGIN(flv)
 341 AG_GST_CHECK_PLUGIN(flx)
 342 AG_GST_CHECK_PLUGIN(goom)
 343 AG_GST_CHECK_PLUGIN(goom2k1)
 344 AG_GST_CHECK_PLUGIN(icydemux)
 345 AG_GST_CHECK_PLUGIN(id3demux)
 346 AG_GST_CHECK_PLUGIN(imagefreeze)
 347 AG_GST_CHECK_PLUGIN(interleave)
 348 AG_GST_CHECK_PLUGIN(isomp4)
 349 AG_GST_CHECK_PLUGIN(law)
 350 AG_GST_CHECK_PLUGIN(level)
 351 AG_GST_CHECK_PLUGIN(matroska)
 352 AG_GST_CHECK_PLUGIN(monoscope)
 353 AG_GST_CHECK_PLUGIN(multifile)
 354 AG_GST_CHECK_PLUGIN(multipart)
 355 AG_GST_CHECK_PLUGIN(replaygain)
 356 AG_GST_CHECK_PLUGIN(rtp)
 357 AG_GST_CHECK_PLUGIN(rtpmanager)
 358 AG_GST_CHECK_PLUGIN(rtsp)
 359 AG_GST_CHECK_PLUGIN(shapewipe)
 360 AG_GST_CHECK_PLUGIN(smpte)
 361 AG_GST_CHECK_PLUGIN(spectrum)
 362 AG_GST_CHECK_PLUGIN(udp)
 363 AG_GST_CHECK_PLUGIN(videobox)
 364 AG_GST_CHECK_PLUGIN(videocrop)
 365 AG_GST_CHECK_PLUGIN(videofilter)
 366 AG_GST_CHECK_PLUGIN(videomixer)
 367 AG_GST_CHECK_PLUGIN(wavenc)
 368 AG_GST_CHECK_PLUGIN(wavparse)
 369 AG_GST_CHECK_PLUGIN(y4m)
 370
 371 dnl disable experimental plug-ins
 372 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 373   AG_GST_DISABLE_PLUGIN(monoscope)
 374 fi
 375
 376 dnl *** sys plug-ins ***
 377
 378 echo
 379 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 380 echo
 381
 382 dnl DirectSound
 383 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 384 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 385   HAVE_DIRECTSOUND="no"
 386   save_CFLAGS="$CFLAGS"
 387   save_LDFLAGS="$LDFLAGS"
 388   save_LIBS="$LIBS"
 389   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 390   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 391   LIBS="$LIBS -ldsound -ldxerr9 -luser32"
 392   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 393   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 394 #include <windows.h>
 395 #include <dxerr9.h>
 396 #include <dsound.h>
 397 ]], [[
 398   DXGetErrorString9 (0);
 399   DirectSoundCreate(NULL, NULL, NULL);
 400 ]])
 401 ],
 402     [HAVE_DIRECTSOUND="yes"],
 403     [HAVE_DIRECTSOUND="no"])
 404   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 405   CFLAGS=$save_CFLAGS
 406   LDFLAGS=$save_LDFLAGS
 407   LIBS=$save_LIBS
 408
 409   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 410     dnl this is much more than we want
 411     DIRECTSOUND_LIBS="-ldsound -ldxerr9 -luser32"
 412     AC_SUBST(DIRECTSOUND_CFLAGS)
 413     AC_SUBST(DIRECTSOUND_LDFLAGS)
 414     AC_SUBST(DIRECTSOUND_LIBS)
 415   fi
 416   AC_SUBST(HAVE_DIRECTSOUND)
 417 ])
 418
 419 dnl *** Win32 WaveOut ***
 420 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVEFORM, true)
 421 AG_GST_CHECK_FEATURE(WAVEFORM, [Win32 WaveForm], waveformsink, [
 422   AC_CHECK_HEADER(mmsystem.h, HAVE_WAVEFORM="yes", HAVE_WAVEFORM="no", [#include <windows.h>])
 423 ])
 424
 425 dnl *** OSS audio *** (Linux, *BSD)
 426 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 427 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 428  HAVE_OSS="yes"
 429 dnl Linux and newer BSD versions :
 430  AC_CHECK_HEADER(sys/soundcard.h, [
 431    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 432    ] , [
 433 dnl Some old BSD versions and also newer OpenBSD versions :
 434    AC_CHECK_HEADER(soundcard.h, [
 435      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 436      ], [
 437   dnl Some old BSD versions :
 438      AC_CHECK_HEADER(machine/soundcard.h, [
 439        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 440          [Define if OSS includes are in /machine/])
 441        ], [
 442        HAVE_OSS="no"
 443      ])
 444    ])
 445  ])
 446 ])
 447
 448 dnl *** oss4 ***
 449 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS4, true)
 450 AG_GST_CHECK_FEATURE(OSS4, [Open Sound System 4], oss4, [
 451   AC_MSG_CHECKING([Checking if we can build the OSS4 elements])
 452   AC_CHECK_HEADERS([fcntl.h sys/ioctl.h sys/stat.h sys/types.h],
 453       [test -z "$OSS4_MISSING_HEADER" && HAVE_OSS4="yes"],
 454       [OSS4_MISSING_HEADER="yes";HAVE_OSS4="no"])
 455 ])
 456
 457 dnl *** Sun Audio ***
 458 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 459 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 460   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 461 ])
 462
 463 dnl *** OSX Audio ***
 464 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 465 HAVE_IOS="no"
 466 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 467   AC_CHECK_HEADER(CoreAudio/CoreAudio.h,
 468     [HAVE_OSX_AUDIO="yes"],
 469     [AC_CHECK_HEADER(CoreAudio/CoreAudioTypes.h,
 470     [
 471       HAVE_OSX_AUDIO="yes"
 472       HAVE_IOS="yes"
 473     ], [
 474       HAVE_OSX_AUDIO="no"
 475       HAVE_IOS="no"
 476     ])]
 477   )
 478 ])
 479 if test "x$HAVE_IOS" = "xyes"; then
 480   AC_DEFINE(HAVE_IOS, 1, [building for iOS platofrm])
 481 fi
 482 AM_CONDITIONAL(HAVE_IOS, test "x$HAVE_IOS" = "xyes")
 483
 484 dnl *** OS X video ***
 485 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 486 HAVE_OSX_VIDEO="no"
 487 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 488   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 489
 490   dnl in case header OpenGL/gl.h is found on other platforms (or older, unsupported OS X)
 491   dnl also require Snow Leopard or newer
 492
 493   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 494         #include <AvailabilityMacros.h>
 495         #if MAC_OS_X_VERSION_MIN_REQUIRED < 1060
 496         #error Too old OSX version
 497         #endif
 498       ]], [[return 0;]])],[HAVE_OSX_VIDEO="yes"],[HAVE_OSX_VIDEO="no"])
 499 ])
 500
 501 dnl *** Video 4 Linux 2 ***
 502 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 503 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 504 HAVE_GST_V4L2=no
 505 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], video4linux2, [
 506   AC_MSG_CHECKING([Checking for video4linux2 header ...])
 507   AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_GST_V4L2=yes ],
 508   [
 509     AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_GST_V4L2=yes ])
 510   ])
 511   if test "x$HAVE_VIDEODEV" = "xno"; then
 512      AC_MSG_WARN([video4linux2 was not found])
 513   fi
 514 ])
 515
 516 # Optional gudev for device probing
 517 AC_ARG_WITH([gudev],
 518   AS_HELP_STRING([--with-gudev],[device detection with gudev]),
 519   [],
 520   [with_gudev=check])
 521 if test x$HAVE_GST_V4L2 = xyes; then
 522   if test x$with_gudev != xno; then
 523     PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 147 ],
 524       [ AC_DEFINE(HAVE_GUDEV, 1,
 525           [Whether gudev is available for device detection])
 526       ],
 527       [true])
 528   fi
 529 fi
 530
 531 AC_SUBST(GUDEV_CFLAGS)
 532 AC_SUBST(GUDEV_LIBS)
 533
 534 # Make libv4l2 non-automagic
 535 AC_ARG_WITH([libv4l2],
 536   AS_HELP_STRING([--with-libv4l2],[support video buffer conversion using libv4l2]),
 537   [],
 538   [with_libv4l2=check])
 539 if test x$HAVE_GST_V4L2 = xyes; then
 540   if test x$with_libv4l2 != xno; then
 541       PKG_CHECK_MODULES(LIBV4L2, libv4l2,
 542           [ have_libv4l2=yes
 543             AC_DEFINE(HAVE_LIBV4L2, 1,
 544                 [Whether libv4l2 is available for video buffer conversion])
 545           ], [
 546           have_libv4l2=no
 547           ])
 548   else
 549     have_libv4l2=no
 550   fi
 551 fi
 552
 553 dnl Check for X11
 554 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 555 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 556                   [ximagesrc], [
 557   AC_PATH_XTRA
 558
 559   dnl now try to find the HEADER
 560   ac_cflags_save="$CFLAGS"
 561   ac_cppflags_save="$CPPFLAGS"
 562   CFLAGS="$CFLAGS $X_CFLAGS"
 563   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 564   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 565
 566   if test "x$HAVE_X" = "xno"
 567   then
 568     AC_MSG_NOTICE([cannot find X11 development files])
 569   else
 570     dnl this is much more than we want
 571     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 572     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 573     dnl it does not add the libs; therefore we add them here
 574     X_LIBS="$X_LIBS -lX11"
 575     AC_SUBST(X_CFLAGS)
 576     AC_SUBST(X_LIBS)
 577
 578     dnl check for Xfixes
 579     PKG_CHECK_MODULES(XFIXES, xfixes, HAVE_XFIXES="yes", HAVE_XFIXES="no")
 580     if test "x$HAVE_XFIXES" = "xyes"
 581     then
 582         XFIXES_CFLAGS="-DHAVE_XFIXES $XFIXES_CFLAGS"
 583     fi
 584     AC_SUBST(XFIXES_LIBS)
 585     AC_SUBST(XFIXES_CFLAGS)
 586
 587     dnl check for Xdamage
 588     PKG_CHECK_MODULES(XDAMAGE, xdamage, HAVE_XDAMAGE="yes", HAVE_XDAMAGE="no")
 589     if test "x$HAVE_XDAMAGE" = "xyes"
 590     then
 591         XDAMAGE_CFLAGS="-DHAVE_XDAMAGE $XDAMAGE_CFLAGS"
 592     fi
 593     AC_SUBST(XDAMAGE_LIBS)
 594     AC_SUBST(XDAMAGE_CFLAGS)
 595   fi
 596   AC_SUBST(HAVE_X)
 597   CFLAGS="$ac_cflags_save"
 598   CPPFLAGS="$ac_cppflags_save"
 599 ])
 600
 601 dnl FIXME: this should be rolled into the test above, it's just an additional
 602 dnl feature of the ximagesrc plug-in
 603 dnl This is the same as in gst-plugins-base
 604 dnl check for X Shm
 605 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 606 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 607   if test x$HAVE_X = xyes; then
 608     AC_CHECK_LIB(Xext, XShmAttach,
 609                  HAVE_XSHM="yes", HAVE_XSHM="no",
 610                  $X_LIBS)
 611     if test "x$HAVE_XSHM" = "xyes"; then
 612       XSHM_LIBS="-lXext"
 613     else
 614       dnl On AIX, it is in XextSam instead, but we still need -lXext
 615       AC_CHECK_LIB(XextSam, XShmAttach,
 616                    HAVE_XSHM="yes", HAVE_XSHM="no",
 617                    $X_LIBS)
 618       if test "x$HAVE_XSHM" = "xyes"; then
 619         XSHM_LIBS="-lXext -lXextSam"
 620       fi
 621     fi
 622   fi
 623 ], ,[
 624   AC_SUBST(HAVE_XSHM)
 625   AC_SUBST(XSHM_LIBS)
 626 ])
 627
 628 dnl *** ext plug-ins ***
 629 dnl keep this list sorted alphabetically !
 630
 631 if test "x$BUILD_EXTERNAL" = "xyes"; then
 632
 633 echo
 634 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 635 echo
 636
 637 dnl *** aalib ***
 638 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 639 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 640   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 641 ])
 642
 643 dnl *** cairo ***
 644 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 645 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering and gobject bindings], cairo, [
 646   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.10.0 cairo-gobject >= 1.10.0)
 647 ])
 648
 649 dnl *** FLAC ***
 650 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 651 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 652   AG_GST_PKG_CHECK_MODULES(FLAC, flac >= 1.1.4)
 653 ])
 654
 655 dnl *** GDK pixbuf ***
 656 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 657 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 658   AG_GST_PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0 >= 2.8.0)
 659 ])
 660
 661 dnl *** Jack ***
 662 translit(dnm, m, l) AM_CONDITIONAL(USE_JACK, true)
 663 AG_GST_CHECK_FEATURE(JACK, Jack, jack, [
 664   PKG_CHECK_MODULES(JACK, jack >= 0.99.10, HAVE_JACK="yes", HAVE_JACK="no")
 665   AC_SUBST(JACK_CFLAGS)
 666   AC_SUBST(JACK_LIBS)
 667
 668   AG_GST_PKG_CHECK_MODULES(JACK_0_120_1, jack >= 0.120.1 jack < 1.0)
 669   if test x$HAVE_JACK_0_120_1 = xyes; then
 670     AC_DEFINE(HAVE_JACK_0_120_1, 1, [defined if jack >= 0.120.1 is available])
 671   fi
 672   AG_GST_PKG_CHECK_MODULES(JACK_1_9_7, jack >= 1.9.7)
 673   if test x$HAVE_JACK_1_9_7 = xyes; then
 674     AC_DEFINE(HAVE_JACK_1_9_7, 1, [defined if jack >= 1.9.7 is available])
 675   fi
 676
 677 ])
 678
 679 dnl *** jpeg ***
 680 dnl FIXME: we could use header checks here as well IMO
 681 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 682 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 683   AC_ARG_WITH(jpeg-mmx,
 684     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 685   OLD_LIBS="$LIBS"
 686   if test x$with_jpeg_mmx != x; then
 687     LIBS="$LIBS -L$with_jpeg_mmx"
 688   fi
 689   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 690   JPEG_LIBS="$LIBS -ljpeg-mmx"
 691   LIBS="$OLD_LIBS"
 692   if test x$HAVE_JPEG != xyes; then
 693     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 694     JPEG_LIBS="-ljpeg"
 695   fi
 696   AC_SUBST(JPEG_LIBS)
 697 ])
 698
 699 dnl *** libcaca ***
 700 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 701 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 702   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 703 ])
 704
 705 dnl *** libdv ***
 706 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 707 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 708   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 709 ])
 710
 711 dnl *** libpng ***
 712 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 713 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 714   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng >= 1.2)
 715 ])
 716
 717 dnl *** pulseaudio ***
 718 translit(dnm, m, l) AM_CONDITIONAL(USE_PULSE, true)
 719 AG_GST_CHECK_FEATURE(PULSE, [pulseaudio plug-in], pulseaudio, [
 720
 721   dnl used in ext/pulse/pulseutil.c
 722   AC_CHECK_HEADERS([process.h])
 723
 724   AG_GST_PKG_CHECK_MODULES(PULSE, libpulse >= 2.0)
 725 ])
 726
 727 dnl *** dv1394 ***
 728 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 729 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 730   dnl first test for libraw1394 >= 2.0.0
 731   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 2.0.0)
 732   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 733   dnl now see how far we got
 734   if test x$HAVE_RAW1394 = xyes && \
 735      test x$HAVE_LIBIEC61883 = xyes; then
 736        AG_GST_CHECK_LIBHEADER(AVC1394,
 737         avc1394, avc1394_send_command, $RAW1394_LIBS,
 738         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 739        AG_GST_CHECK_LIBHEADER(ROM1394,
 740         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 741         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 742        if test x$HAVE_AVC1394 = xyes && \
 743           test x$HAVE_AVC1394 = xyes && \
 744           test x$HAVE_ROM1394 = xyes; then
 745           HAVE_DV1394=yes
 746           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 747           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 748           AC_SUBST(DV1394_CFLAGS)
 749           AC_SUBST(DV1394_LIBS)
 750         fi
 751   else
 752        if test x$HAVE_RAW1394 = xno; then
 753           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 754           AG_GST_CHECK_LIBHEADER(AVC1394,
 755            avc1394, avc1394_send_command, $RAW1394_LIBS,
 756            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 757           AG_GST_CHECK_LIBHEADER(ROM1394,
 758            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 759            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 760           if test x$HAVE_RAW1394 = xyes && \
 761              test x$HAVE_AVC1394 = xyes && \
 762              test x$HAVE_ROM1394 = xyes; then
 763              HAVE_DV1394=yes
 764              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 765              DV1394_CFLAGS="$RAW1394_CFLAGS"
 766              if test x$HAVE_LIBIEC61883 = xyes; then
 767                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 768                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 769              fi
 770              AC_SUBST(DV1394_CFLAGS)
 771              AC_SUBST(DV1394_LIBS)
 772            fi
 773          fi
 774   fi
 775 ])
 776 AM_CONDITIONAL(USE_LIBIEC61883, [ test "x${HAVE_LIBIEC61883}" = xyes ] )
 777
 778 dnl *** shout2 ***
 779 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 780 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 781   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 782 ])
 783
 784 dnl *** soup ***
 785 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUP, true)
 786 AG_GST_CHECK_FEATURE(SOUP, [soup http client plugin (2.4)], souphttpsrc, [
 787   PKG_CHECK_MODULES(SOUP, libsoup-2.4 >= 2.40, [HAVE_SOUP="yes"], [HAVE_SOUP="no"])
 788   AC_SUBST(SOUP_CFLAGS)
 789   AC_SUBST(SOUP_LIBS)
 790 ])
 791
 792 dnl *** speex >= 1.0.4 or >= 1.1.5 ***
 793 dnl   1.1.4 and earlier were not API/ABI compatible with 1.0
 794 dnl   1.1.6 is the first to use a .pc/pkg-config file ***
 795 dnl   speex_jitter.h is 1.1.x only
 796 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 797 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 798   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 799   if test $HAVE_SPEEX = no
 800   then
 801     AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_bits_init, , speex/speex.h, [
 802       AC_CHECK_HEADER(speex/speex_jitter.h, [
 803         dnl speex 1.1.x :
 804         AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_encode_int, , speex/speex.h, [
 805           dnl speex 1.1.5 or + :
 806           HAVE_SPEEX="yes"
 807           SPEEX_LIBS="-lspeex"
 808           AC_SUBST(SPEEX_CFLAGS)
 809           AC_SUBST(SPEEX_LIBS)
 810         ],[
 811           HAVE_SPEEX="no"
 812         ])
 813       ],[
 814         dnl speex 1.0.x :
 815           AC_CHECK_DECL(SPEEX_GET_LOOKAHEAD, [
 816             dnl speex 1.0.4
 817             HAVE_SPEEX="yes"
 818             SPEEX_LIBS="-lspeex"
 819             AC_SUBST(SPEEX_CFLAGS)
 820             AC_SUBST(SPEEX_LIBS)
 821
 822             AC_DEFINE_UNQUOTED(SPEEX_1_0, 1,
 823               [defined if speex 1.0.x API detected])
 824         ],[
 825             HAVE_SPEEX="no"
 826             AC_MSG_NOTICE(You need at least 1.0.4 to compile the speex plugin)
 827         ], [
 828 #include <speex/speex.h>
 829         ])
 830       ])
 831     ])
 832   fi
 833 ])
 834
 835 dnl *** taglib ***
 836 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 837 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 838   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.5)
 839   if test "x$HAVE_CXX" != "xyes"; then
 840     USE_TAGLIB=false
 841     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 842   else
 843     dnl work around bug in taglib 1.5 headers, remove once there is a 1.6
 844     AS_CXX_COMPILER_FLAG([-Wno-attributes], [
 845         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS -Wno-attributes"
 846       ], [
 847         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS"
 848     ])
 849     AC_SUBST(TAGLIB_CXXFLAGS)
 850   fi
 851 ])
 852
 853 dnl *** vpx ***
 854 translit(dnm, m, l) AM_CONDITIONAL(USE_VPX, vpx)
 855 AG_GST_CHECK_FEATURE(VPX, [VPX decoder], vpx, [
 856   PKG_CHECK_MODULES(VPX, vpx >= 1.1.0, [HAVE_VPX="yes"], [HAVE_VPX="no"])
 857   HAVE_VP8=no
 858   HAVE_VP9=no
 859
 860   if test $HAVE_VPX = "yes"; then
 861     OLD_LIBS="$LIBS"
 862     OLD_CFLAGS="$CFLAGS"
 863     CFLAGS="$CFLAGS $VPX_CFLAGS"
 864     LIBS="$LIBS $VPX_LIBS"
 865     AC_CHECK_LIB(vpx, vpx_codec_vp8_cx_algo, [
 866       HAVE_VP8=yes
 867       AC_DEFINE(HAVE_VP8_ENCODER, 1, [Defined if the VP8 encoder is available])
 868     ])
 869     AC_CHECK_LIB(vpx, vpx_codec_vp8_dx_algo, [
 870       HAVE_VP8=yes
 871       AC_DEFINE(HAVE_VP8_DECODER, 1, [Defined if the VP8 decoder is available])
 872     ])
 873
 874     PKG_CHECK_MODULES(VPX_130, vpx >= 1.3.0, [
 875       AC_CHECK_LIB(vpx, vpx_codec_vp9_cx_algo, [
 876         HAVE_VP9=yes
 877         AC_DEFINE(HAVE_VP9_ENCODER, 1, [Defined if the VP9 encoder is available])
 878       ])
 879       AC_CHECK_LIB(vpx, vpx_codec_vp9_dx_algo, [
 880         HAVE_VP9=yes
 881         AC_DEFINE(HAVE_VP9_DECODER, 1, [Defined if the VP9 decoder is available])
 882       ])
 883     ], [true])
 884     LIBS="$OLD_LIBS"
 885     CFLAGS="$OLD_CFLAGS"
 886   fi
 887   AC_SUBST(VPX_LIBS)
 888   AC_SUBST(VPX_CFLAGS)
 889 ])
 890
 891 dnl *** wavpack ***
 892 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 893 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 894   PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.40.0, HAVE_WAVPACK=yes, [
 895     PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.20, [
 896       HAVE_WAVPACK=yes
 897       AC_DEFINE(WAVPACK_OLD_API, 1, [old wavpack API])
 898     ],[
 899       HAVE_WAVPACK=no
 900     ])
 901   ])
 902   AC_SUBST(WAVPACK_CFLAGS)
 903   AC_SUBST(WAVPACK_LIBS)
 904 ])
 905
 906 dnl *** qtdemux & matroska prefer to have zlib ***
 907 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 908 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for qtdemux/matroska],, [
 909   AG_GST_CHECK_LIBHEADER(ZLIB,
 910     z, uncompress,, zlib.h, [
 911     HAVE_ZLIB="yes"
 912     ZLIB_LIBS="-lz"
 913     AC_SUBST(ZLIB_LIBS)
 914   ])
 915 ])
 916
 917 dnl *** matroska prefers to have bz2 ***
 918 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
 919 AG_GST_CHECK_FEATURE(BZ2, [bz2 library for matroska ],, [
 920   save_LIBS=$LIBS
 921   LIBS="$LIBS -lbz2"
 922   AC_MSG_CHECKING([for BZ2_bzlibVersion in -lbz2])
 923   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <bzlib.h>]], [[const char *version = BZ2_bzlibVersion ();]])],[HAVE_BZ2=yes],[HAVE_BZ2=no])
 924   AC_MSG_RESULT($HAVE_BZ2)
 925   LIBS=$save_LIBS
 926   if test "x$HAVE_BZ2" = "xyes"; then
 927     BZ2_LIBS="-lbz2"
 928   fi
 929   AC_SUBST(BZ2_LIBS)
 930 ])
 931
 932 else
 933
 934 dnl not building plugins with external dependencies,
 935 dnl but we still need to set the conditionals
 936 AM_CONDITIONAL(USE_AALIB, false)
 937 AM_CONDITIONAL(USE_BZ2, false)
 938 AM_CONDITIONAL(USE_CAIRO, false)
 939 AM_CONDITIONAL(USE_DIRECTSOUND, false)
 940 AM_CONDITIONAL(USE_DV1394, false)
 941 AM_CONDITIONAL(USE_FLAC, false)
 942 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
 943 AM_CONDITIONAL(USE_JACK, false)
 944 AM_CONDITIONAL(USE_JPEG, false)
 945 AM_CONDITIONAL(USE_LIBCACA, false)
 946 AM_CONDITIONAL(USE_LIBDV, false)
 947 AM_CONDITIONAL(USE_LIBIEC61883, false)
 948 AM_CONDITIONAL(USE_LIBPNG, false)
 949 AM_CONDITIONAL(USE_OSS, false)
 950 AM_CONDITIONAL(USE_OSS4, false)
 951 AM_CONDITIONAL(USE_OSX_AUDIO, false)
 952 AM_CONDITIONAL(USE_OSX_VIDEO, false)
 953 AM_CONDITIONAL(USE_PULSE, false)
 954 AM_CONDITIONAL(USE_SHOUT2, false)
 955 AM_CONDITIONAL(USE_SOUP, false)
 956 AM_CONDITIONAL(USE_SPEEX, false)
 957 AM_CONDITIONAL(USE_SUNAUDIO, false)
 958 AM_CONDITIONAL(USE_TAGLIB, false)
 959 AM_CONDITIONAL(USE_VPX, false)
 960 AM_CONDITIONAL(USE_WAVEFORM, false)
 961 AM_CONDITIONAL(USE_WAVPACK, false)
 962 AM_CONDITIONAL(USE_X, false)
 963 AM_CONDITIONAL(USE_XSHM, false)
 964 AM_CONDITIONAL(USE_ZLIB, false)
 965
 966 fi dnl of EXT plugins
 967
 968 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 969
 970 dnl Overview:
 971 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 972 dnl GST_*:              flags shared by all built objects
 973 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 974 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
 975 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 976 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 977
 978 dnl GST_OPTION_CFLAGS
 979 if test "x$USE_DEBUG" = xyes; then
 980    PROFILE_CFLAGS="-g"
 981 fi
 982 AC_SUBST(PROFILE_CFLAGS)
 983
 984 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 985   dnl Define _only_ for git (not pre-releases or releases)
 986   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 987 else
 988   DEPRECATED_CFLAGS=""
 989 fi
 990 AC_SUBST(DEPRECATED_CFLAGS)
 991
 992 dnl every flag in GST_OPTION_CFLAGS, GST_OPTION_CXXFLAGS and GST_OPTION_OBJCFLAGS can be overridden
 993 dnl at make time with e.g. make ERROR_CFLAGS=""
 994 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 995 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 996 GST_OPTION_OBJCFLAGS="\$(WARNING_OBJCFLAGS) \$(ERROR_OBJCFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 997 AC_SUBST(GST_OPTION_CFLAGS)
 998 AC_SUBST(GST_OPTION_CXXFLAGS)
 999 AC_SUBST(GST_OPTION_OBJCFLAGS)
1000
1001 dnl our libraries need to be versioned correctly
1002 AC_SUBST(GST_LT_LDFLAGS)
1003
1004 dnl FIXME: do we want to rename to GST_ALL_* ?
1005 dnl prefer internal headers to already installed ones
1006 dnl also add builddir include for enumtypes and marshal
1007 dnl add ERROR_CFLAGS, but overridable
1008 GST_CFLAGS="$GST_CFLAGS -DGST_USE_UNSTABLE_API"
1009 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS)"
1010 GST_OBJCFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_OBJCFLAGS)"
1011 GST_CFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
1012 AC_SUBST(GST_CFLAGS)
1013 AC_SUBST(GST_CXXFLAGS)
1014 AC_SUBST(GST_OBJCFLAGS)
1015 AC_SUBST(GST_LIBS)
1016
1017 dnl LDFLAGS really should only contain flags, not libs - they get added before
1018 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1019 GST_ALL_LDFLAGS="-no-undefined"
1020 AC_SUBST(GST_ALL_LDFLAGS)
1021
1022 dnl this really should only contain flags, not libs - they get added before
1023 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1024 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_.*' $GST_ALL_LDFLAGS"
1025 AC_SUBST(GST_PLUGIN_LDFLAGS)
1026
1027 dnl *** output files ***
1028
1029 $MKDIR_P tests/check/orc
1030
1031 dnl keep this alphabetic per directory, please
1032 AC_CONFIG_FILES(
1033 Makefile
1034 gst/Makefile
1035 gst/alpha/Makefile
1036 gst/apetag/Makefile
1037 gst/audiofx/Makefile
1038 gst/audioparsers/Makefile
1039 gst/auparse/Makefile
1040 gst/autodetect/Makefile
1041 gst/avi/Makefile
1042 gst/cutter/Makefile
1043 gst/deinterlace/Makefile
1044 gst/dtmf/Makefile
1045 gst/debugutils/Makefile
1046 gst/effectv/Makefile
1047 gst/equalizer/Makefile
1048 gst/flv/Makefile
1049 gst/goom/Makefile
1050 gst/goom2k1/Makefile
1051 gst/id3demux/Makefile
1052 gst/icydemux/Makefile
1053 gst/imagefreeze/Makefile
1054 gst/interleave/Makefile
1055 gst/isomp4/Makefile
1056 gst/law/Makefile
1057 gst/level/Makefile
1058 gst/matroska/Makefile
1059 gst/monoscope/Makefile
1060 gst/multifile/Makefile
1061 gst/multipart/Makefile
1062 gst/replaygain/Makefile
1063 gst/rtp/Makefile
1064 gst/rtpmanager/Makefile
1065 gst/rtsp/Makefile
1066 gst/shapewipe/Makefile
1067 gst/smpte/Makefile
1068 gst/spectrum/Makefile
1069 gst/udp/Makefile
1070 gst/videobox/Makefile
1071 gst/videocrop/Makefile
1072 gst/videofilter/Makefile
1073 gst/videomixer/Makefile
1074 gst/wavenc/Makefile
1075 gst/wavparse/Makefile
1076 gst/flx/Makefile
1077 gst/y4m/Makefile
1078 ext/Makefile
1079 ext/aalib/Makefile
1080 ext/cairo/Makefile
1081 ext/dv/Makefile
1082 ext/flac/Makefile
1083 ext/gdk_pixbuf/Makefile
1084 ext/jack/Makefile
1085 ext/jpeg/Makefile
1086 ext/libcaca/Makefile
1087 ext/libpng/Makefile
1088 ext/pulse/Makefile
1089 ext/raw1394/Makefile
1090 ext/shout2/Makefile
1091 ext/soup/Makefile
1092 ext/speex/Makefile
1093 ext/taglib/Makefile
1094 ext/vpx/Makefile
1095 ext/wavpack/Makefile
1096 sys/Makefile
1097 sys/directsound/Makefile
1098 sys/oss/Makefile
1099 sys/oss4/Makefile
1100 sys/osxaudio/Makefile
1101 sys/osxvideo/Makefile
1102 sys/sunaudio/Makefile
1103 sys/v4l2/Makefile
1104 sys/waveform/Makefile
1105 sys/ximage/Makefile
1106 po/Makefile.in
1107 tests/Makefile
1108 tests/check/Makefile
1109 tests/examples/Makefile
1110 tests/examples/audiofx/Makefile
1111 tests/examples/cairo/Makefile
1112 tests/examples/equalizer/Makefile
1113 tests/examples/jack/Makefile
1114 tests/examples/level/Makefile
1115 tests/examples/pulse/Makefile
1116 tests/examples/rtp/Makefile
1117 tests/examples/shapewipe/Makefile
1118 tests/examples/spectrum/Makefile
1119 tests/examples/v4l2/Makefile
1120 tests/files/Makefile
1121 tests/icles/Makefile
1122 common/Makefile
1123 common/m4/Makefile
1124 m4/Makefile
1125 docs/Makefile
1126 docs/plugins/Makefile
1127 docs/version.entities
1128 pkgconfig/Makefile
1129 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1130 gst-plugins-good.spec
1131 )
1132
1133 dnl Create the config.h file for Visual Studio builds
1134 dnl Beware of spaces and /'s in some of the shell variable contents.
1135 sed \
1136     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"\n\n#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
1137     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
1138     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
1139     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
1140     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
1141     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
1142     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
1143     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
1144     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
1145     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
1146     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
1147     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
1148     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
1149     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
1150     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
1151     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
1152     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
1153     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
1154     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
1155     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1156     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1157     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1158     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
1159     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1160     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
1161     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1162     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1163     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1164     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
1165     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
1166     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1167     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
1168     -e "s/.* DEFAULT_AUDIOSRC$/#define DEFAULT_AUDIOSRC \"audiotestsrc\"/" \
1169     -e "s/.* DEFAULT_VIDEOSRC$/#define DEFAULT_VIDEOSRC \"videotestsrc\"/" \
1170     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1171     config.h.in >win32/common/config.h-new
1172
1173 AC_OUTPUT
1174
1175 AG_GST_OUTPUT_PLUGINS
1176 ORC_OUTPUT
1177