configure.ac

   1 AC_PREREQ([2.69])
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, git and prerelease does Werror too
   6 dnl
   7 AC_INIT([GStreamer],[1.17.0.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gstreamer])
   8 AG_GST_INIT
   9
  10 dnl initialize automake (we require GNU make)
  11 AM_INIT_AUTOMAKE([-Wno-portability 1.14 no-dist-gzip dist-xz tar-ustar subdir-objects])
  12
  13 dnl define PACKAGE_VERSION_* variables
  14 AS_VERSION
  15
  16 dnl check if this is a release version
  17 AS_NANO(GST_GIT="no", GST_GIT="yes")
  18
  19 dnl can autoconf find the source ?
  20 AC_CONFIG_SRCDIR([gst/gst.c])
  21
  22 dnl define the output header for config
  23 AC_CONFIG_HEADERS([config.h])
  24
  25 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  26 AM_MAINTAINER_MODE([enable])
  27
  28 dnl sets host_* variables
  29 AC_CANONICAL_HOST
  30
  31 dnl use pretty build output by default
  32 AM_SILENT_RULES([yes])
  33
  34 dnl GStreamer versioning, this is mostly informational
  35 GST_VERSION_MAJOR=$PACKAGE_VERSION_MAJOR
  36 GST_VERSION_MINOR=$PACKAGE_VERSION_MINOR
  37 GST_VERSION_MICRO=$PACKAGE_VERSION_MICRO
  38 GST_VERSION_NANO=$PACKAGE_VERSION_NANO
  39 AC_SUBST(GST_VERSION_MAJOR)
  40 AC_SUBST(GST_VERSION_MINOR)
  41 AC_SUBST(GST_VERSION_MICRO)
  42 AC_SUBST(GST_VERSION_NANO)
  43
  44 dnl our libraries and install dirs use GST_API_VERSION in the filename
  45 dnl to allow side-by-side installation of different API versions
  46 GST_API_VERSION=1.0
  47 AC_SUBST(GST_API_VERSION)
  48 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  49   [GStreamer API Version])
  50
  51 dnl CURRENT, REVISION, AGE
  52 dnl - library source changed -> increment REVISION
  53 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  54 dnl - interfaces added -> increment AGE
  55 dnl - interfaces removed -> AGE = 0
  56 dnl
  57 dnl Keep CURRENT as MINOR * 100 + MICRO
  58 dnl Ex : 1.0.0 => 0
  59 dnl      1.0.3 => 3
  60 dnl      1.1.0 => 100
  61 dnl      1.2.5 => 205
  62 dnl      1.10.9 (who knows) => 1009
  63 dnl
  64 dnl sets GST_LT_LDFLAGS
  65 AS_LIBTOOL(GST, 1700, 0, 1700)
  66
  67 dnl *** autotools stuff ****
  68
  69 dnl allow for different autotools
  70 AS_AUTOTOOLS_ALTERNATE
  71
  72 dnl Add parameters for aclocal (keep in sync with Makefile.am)
  73 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  74
  75 dnl set up gettext
  76 dnl the version check needs to stay here because autopoint greps for it
  77 AM_GNU_GETTEXT_VERSION([0.17])
  78 AM_GNU_GETTEXT([external])
  79 AG_GST_GETTEXT([gstreamer-$GST_API_VERSION])
  80
  81 dnl *** check for arguments to configure ***
  82
  83 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  84 AG_GST_ARG_ENABLE_EXTRA_CHECKS
  85
  86 dnl subsystems - can influence other decisions so needs to be high up
  87 dnl we need to AM_CONDITIONAL them here for automake 1.6.x compatibility
  88 AG_GST_CHECK_SUBSYSTEM_DISABLE(GST_DEBUG,[debugging subsystem])
  89 AM_CONDITIONAL(GST_DISABLE_GST_DEBUG, test "x$GST_DISABLE_GST_DEBUG" = "xyes")
  90 AG_GST_CHECK_SUBSYSTEM_DISABLE(GST_TRACER_HOOKS,[tracing subsystem hooks])
  91 AM_CONDITIONAL(GST_DISABLE_GST_TRACER_HOOKS, test "x$GST_DISABLE_GST_TRACER_HOOKS" = "xyes")
  92 if test "x$GST_DISABLE_GST_TRACER_HOOKS" = xyes; then
  93   AC_DEFINE(GST_DISABLE_GST_TRACER_HOOKS, 1,
  94     [Define if tracing subsystem hooks is disabled])
  95 fi
  96 AG_GST_CHECK_SUBSYSTEM_DISABLE(PARSE,[command-line parser])
  97 AM_CONDITIONAL(GST_DISABLE_PARSE, test "x$GST_DISABLE_PARSE" = "xyes")
  98 if test "x$GST_DISABLE_PARSE" = xyes; then
  99   AC_DEFINE(GST_DISABLE_PARSE, 1,
 100     [Define if pipeline parsing code is disabled])
 101 fi
 102 AG_GST_CHECK_SUBSYSTEM_DISABLE(OPTION_PARSING,[option parsing when gst_init])
 103 AM_CONDITIONAL(GST_DISABLE_OPTION_PARSING, test "x$GST_DISABLE_OPTION_PARSING" = "xyes")
 104 if test "x$GST_DISABLE_OPTION_PARSING" = xyes; then
 105   AC_DEFINE(GST_DISABLE_OPTION_PARSING, 1,
 106     [Define if option parsing is disabled])
 107 fi
 108 AG_GST_CHECK_SUBSYSTEM_DISABLE(REGISTRY,[plugin registry])
 109 AM_CONDITIONAL(GST_DISABLE_REGISTRY, test "x$GST_DISABLE_REGISTRY" = "xyes")
 110 dnl define a substitution to use in docs/gst/gstreamer.types
 111 if test "x$GST_DISABLE_REGISTRY" = "xyes"
 112 then
 113   GST_REGISTRY_DOC_TYPES="%"
 114 else
 115   GST_REGISTRY_DOC_TYPES=
 116 fi
 117 AC_SUBST(GST_REGISTRY_DOC_TYPES)
 118 AG_GST_CHECK_SUBSYSTEM_DISABLE(PLUGIN,[plugin])
 119 AM_CONDITIONAL(GST_DISABLE_PLUGIN, test "x$GST_DISABLE_PLUGIN" = "xyes")
 120
 121 GST_DISABLE_CAST_CHECKS_DEFINE=0
 122 AC_SUBST(GST_DISABLE_CAST_CHECKS_DEFINE)
 123
 124 GST_DISABLE_GLIB_ASSERTS_DEFINE=0
 125 AC_SUBST(GST_DISABLE_GLIB_ASSERTS_DEFINE)
 126
 127 GST_DISABLE_GLIB_CHECKS_DEFINE=0
 128 AC_SUBST(GST_DISABLE_GLIB_CHECKS_DEFINE)
 129
 130
 131 AG_GST_ARG_DEBUG
 132 AG_GST_ARG_PROFILING
 133 AG_GST_ARG_VALGRIND
 134 AG_GST_ARG_GCOV
 135
 136 AG_GST_ARG_EXAMPLES
 137
 138 AG_GST_ARG_WITH_PKG_CONFIG_PATH
 139 AG_GST_ARG_WITH_PACKAGE_NAME
 140 AG_GST_ARG_WITH_PACKAGE_ORIGIN
 141
 142 AG_GST_PKG_CONFIG_PATH
 143
 144 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 145   ["${srcdir}/gstreamer.doap"],
 146   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 147
 148 # We only use this when building with MSVC, which is only done with the
 149 # alternate Meson build system files
 150 GSTCONFIG_BUILT_WITH_MSVC=0
 151 AC_SUBST(GSTCONFIG_BUILT_WITH_MSVC)
 152
 153 dnl check for bash completion
 154 AC_ARG_WITH([bash-completion-dir],
 155     AS_HELP_STRING([--with-bash-completion-dir[=PATH]],
 156         [Install the bash auto-completion script in this directory. @<:@default=yes@:>@]),
 157     [],
 158     [with_bash_completion_dir=yes])
 159
 160 if test "x$with_bash_completion_dir" = "xyes"
 161 then
 162     extra_args=
 163
 164     if test "x$prefix" != "xNONE"
 165     then
 166         extra_args="--define-variable=prefix=\"$prefix\""
 167     fi
 168
 169     PKG_CHECK_MODULES([BASH_COMPLETION], [bash-completion >= 2.0],
 170         [
 171           BASH_COMPLETION_DIR="`eval pkg-config $extra_args --variable=completionsdir bash-completion`"
 172           BASH_HELPERS_DIR="`eval pkg-config $extra_args --variable=helpersdir bash-completion`"
 173         ],
 174         [
 175           BASH_COMPLETION_DIR="$datadir/bash-completion/completions"
 176           BASH_HELPERS_DIR="$datadir/bash-completion/helpers"
 177         ])
 178 else
 179     BASH_COMPLETION_DIR="$with_bash_completion_dir/completions"
 180     BASH_HELPERS_DIR="$with_bash_completion_dir/helpers"
 181 fi
 182
 183 AC_SUBST([BASH_COMPLETION_DIR])
 184 AC_SUBST([BASH_HELPERS_DIR])
 185 AM_CONDITIONAL([ENABLE_BASH_COMPLETION],[test "x$with_bash_completion_dir" != "xno"])
 186
 187 dnl If only building static libraries, define GST_STATIC_COMPILATION. This is
 188 dnl needed only on Windows, but it doesn't hurt to have it everywhere.
 189 if test x$enable_static = xyes -a x$enable_shared = xno; then
 190   GST_OBJ_STATIC_CFLAGS="-DGST_STATIC_COMPILATION"
 191 fi
 192
 193 dnl building of tests
 194 AC_ARG_ENABLE(tests,
 195   AS_HELP_STRING([--disable-tests],[disable building test apps]),
 196   [
 197     case "${enableval}" in
 198       yes) BUILD_TESTS=yes ;;
 199       no)  BUILD_TESTS=no ;;
 200       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 201     esac
 202   ],
 203 [BUILD_TESTS=yes]) dnl Default value
 204 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 205
 206 dnl tests known to fail
 207 AC_ARG_ENABLE(failing-tests,
 208   AS_HELP_STRING([--disable-failing-tests],[disable building tests known to fail]),
 209   [
 210     case "${enableval}" in
 211       yes) BUILD_FAILING_TESTS=yes ;;
 212       no)  BUILD_FAILING_TESTS=no ;;
 213       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-failing-tests) ;;
 214     esac
 215   ],
 216   [BUILD_FAILING_TESTS=no]) dnl Default value
 217 AM_CONDITIONAL(BUILD_FAILING_TESTS, test "x$BUILD_FAILING_TESTS" = "xyes")
 218 if test x$BUILD_FAILING_TESTS = xyes; then
 219   AC_MSG_WARN([building tests known to fail, use --disable-failing-tests to disable])
 220 else
 221   AC_MSG_WARN([By asking to not build the tests known to fail, you hereby waive your right to customer support.  If you do not agree with this EULA, please press Ctrl-C before the next line is printed.  By allowing the next line to be printed, you expressly acknowledge your acceptance of this EULA.])
 222 fi
 223
 224 dnl building of benchmarks
 225 AC_ARG_ENABLE(benchmarks,
 226   AS_HELP_STRING([--disable-benchmarks],[disable building benchmarks apps]),
 227   [
 228     case "${enableval}" in
 229       yes) BUILD_BENCHMARKS=yes ;;
 230       no)  BUILD_BENCHMARKS=no ;;
 231       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-benchmarks) ;;
 232     esac
 233   ],
 234 [BUILD_BENCHMARKS=yes]) dnl Default value
 235 AM_CONDITIONAL(BUILD_BENCHMARKS, test "x$BUILD_BENCHMARKS" = "xyes")
 236
 237 dnl building of tools
 238 AC_ARG_ENABLE(tools,
 239   AS_HELP_STRING([--disable-tools],[disable building tools]),
 240   [
 241     case "${enableval}" in
 242       yes) BUILD_TOOLS=yes ;;
 243       no)  BUILD_TOOLS=no ;;
 244       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tools) ;;
 245     esac
 246   ],
 247 [BUILD_TOOLS=yes]) dnl Default value
 248 AM_CONDITIONAL(BUILD_TOOLS, test "x$BUILD_TOOLS" = "xyes")
 249
 250 dnl poison destroyed objects
 251 AC_ARG_ENABLE(poisoning,
 252   AS_HELP_STRING([--enable-poisoning],[enable poisoning of deallocated objects]),
 253   [
 254     case "${enableval}" in
 255       yes) USE_POISONING=yes ;;
 256       no)  USE_POISONING=no ;;
 257       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-poisoning) ;;
 258     esac
 259   ],
 260   [USE_POISONING=$GST_GIT]) dnl Default value
 261 if test "x$USE_POISONING" = xyes; then
 262   AC_DEFINE(USE_POISONING, 1,
 263     [Define if we should poison deallocated memory])
 264 fi
 265
 266 dnl PTP support parts
 267 AC_MSG_CHECKING([whether PTP support can be enabled])
 268 case "$host_os" in
 269   *android*)
 270     dnl Can't run on Android because of permissions
 271     HAVE_PTP=no
 272     ;;
 273   mingw*|pw32*|cygwin*)
 274     dnl Not ported to Windows yet
 275     HAVE_PTP=no
 276     ;;
 277   darwin*)
 278     dnl Can't run on iOS because of permissions
 279     AC_CHECK_HEADER(MobileCoreServices/MobileCoreServices.h, HAVE_PTP="no", HAVE_PTP="yes", [-])
 280     ;;
 281   linux*|darwin*|solaris*|netbsd*|freebsd*|openbsd*|kfreebsd*|dragonfly*|gnu*)
 282     HAVE_PTP=yes
 283     ;;
 284   *)
 285     HAVE_PTP=no
 286     ;;
 287 esac
 288 AC_MSG_RESULT([$HAVE_PTP])
 289
 290 dnl user/group to change to in gst-ptp-helper
 291 AC_ARG_WITH([ptp-helper-setuid-user],
 292   AS_HELP_STRING([--with-ptp-helper-setuid-user],[User to switch to when installing gst-ptp-helper setuid root]),
 293   [
 294     if test "x$withval" != "x"
 295     then
 296       AC_DEFINE_UNQUOTED(HAVE_PTP_HELPER_SETUID_USER, "$withval", [PTP helper setuid user])
 297     fi
 298   ], []
 299 )
 300
 301 dnl group/group to change to in gst-ptp-helper
 302 AC_ARG_WITH([ptp-helper-setuid-group],
 303   AS_HELP_STRING([--with-ptp-helper-setuid-group],[Group to switch to when installing gst-ptp-helper setuid root]),
 304   [
 305     if test "x$withval" != "x"
 306     then
 307       AC_DEFINE_UNQUOTED(HAVE_PTP_HELPER_SETUID_GROUP, "$withval", [PTP helper setuid group])
 308     fi
 309   ], []
 310 )
 311
 312 AC_ARG_WITH(
 313   ptp-helper-permissions,
 314   AC_HELP_STRING(
 315     [--with-ptp-helper-permissions],
 316     [how to gain PTP permissions (none, setuid-root, capabilities, auto)]),
 317     [],
 318     [with_ptp_helper_permissions=auto])
 319
 320 gst_ptp_have_cap=no
 321 AG_GST_CHECK_LIBHEADER(CAP, cap,
 322                        cap_init, ,
 323                        sys/capability.h,
 324                        CAP_LIBS="-lcap"
 325                        AC_SUBST(CAP_LIBS)
 326                        gst_ptp_have_cap=yes)
 327
 328 AC_PATH_PROG([SETCAP], [setcap], [no], [$PATH:/usr/bin:/bin:/usr/sbin:/sbin])
 329
 330 if test "x$HAVE_PTP" = "xyes"; then
 331 AC_DEFINE(HAVE_PTP, 1, [PTP support available])
 332
 333 AC_MSG_CHECKING([for SIOCGIFCONF, SIOCGIFFLAGS and SIOCGIFHWADDR])
 334 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 335     [[
 336         #include <sys/ioctl.h>
 337         #include <net/if.h>
 338     ]],
 339     [[
 340         struct ifreq ifr;
 341         struct ifconf ifc;
 342         ioctl(0, SIOCGIFCONF, &ifc);
 343         ioctl(0, SIOCGIFFLAGS, &ifr);
 344         ioctl(0, SIOCGIFHWADDR, &ifr);
 345         int dummy = ifr.ifr_hwaddr.sa_data[0];
 346     ]])], [
 347         AC_MSG_RESULT(yes)
 348         AC_DEFINE(HAVE_SIOCGIFCONF_SIOCGIFFLAGS_SIOCGIFHWADDR, 1, [SIOCGIFCONF, SIOCGIFFLAGS and SIOCGIFHWADDR is available])
 349     ], [
 350         AC_MSG_RESULT(no)
 351 ])
 352
 353 AC_MSG_CHECKING([for getifaddrs() and AF_LINK])
 354 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 355     [[
 356         #include <ifaddrs.h>
 357         #include <net/if.h>
 358         #include <net/if_dl.h>
 359     ]],
 360     [[
 361         struct ifaddrs *ifaddr;
 362         getifaddrs(&ifaddr);
 363         int dummy = (ifaddr->ifa_flags & IFF_LOOPBACK) && ifaddr->ifa_addr->sa_family != AF_LINK;
 364     ]])], [
 365         AC_MSG_RESULT(yes)
 366         AC_DEFINE(HAVE_GETIFADDRS_AF_LINK, 1, [getifaddrs() and AF_LINK is available])
 367     ], [
 368         AC_MSG_RESULT(no)
 369     ])
 370
 371 AC_MSG_CHECKING([how to install gst-ptp-helper])
 372 if test "x$with_ptp_helper_permissions" = "xauto"; then
 373     if test "x$gst_ptp_have_cap" = "xyes" -a "x$SETCAP" != "xno"; then
 374         with_ptp_helper_permissions="capabilities"
 375     else
 376         with_ptp_helper_permissions="setuid-root"
 377     fi
 378 fi
 379 AC_MSG_RESULT([$with_ptp_helper_permissions])
 380
 381 case "$with_ptp_helper_permissions" in
 382   none)
 383     ;;
 384   setuid-root)
 385      AC_DEFINE(HAVE_PTP_HELPER_SETUID, 1,
 386         [Use setuid-root for permissions in PTP helper])
 387     ;;
 388   capabilities)
 389      AC_DEFINE(HAVE_PTP_HELPER_CAPABILITIES, 1,
 390         [Use capabilities for permissions in PTP helper])
 391     ;;
 392   *)
 393     AC_MSG_ERROR(Invalid parameter [$with_ptp_helper_permissions])
 394     ;;
 395 esac
 396
 397 fi
 398
 399 AM_CONDITIONAL(HAVE_PTP, test "x$HAVE_PTP" = "xyes")
 400 AM_CONDITIONAL(HAVE_PTP_HELPER_SETUID, test "x$with_ptp_helper_permissions" = "xsetuid-root")
 401 AM_CONDITIONAL(HAVE_PTP_HELPER_CAPABILITIES, test "x$with_ptp_helper_permissions" = "xcapabilities")
 402
 403 dnl *** checks for platform ***
 404
 405 dnl * hardware/architecture *
 406
 407 dnl common/m4/gst-arch.m4
 408 dnl check CPU type
 409 AG_GST_ARCH
 410
 411 dnl check for platform specific settings
 412 AG_GST_PLATFORM
 413
 414 dnl * software *
 415
 416 dnl check for large file support
 417 dnl affected plugins must include config.h
 418 AC_SYS_LARGEFILE
 419
 420 dnl *** checks for programs ***
 421
 422 dnl find a compiler
 423 AC_PROG_CC
 424 AC_PROG_CC_STDC
 425
 426 dnl check if the compiler supports '-c' and '-o' options
 427 AM_PROG_CC_C_O
 428
 429 dnl find an assembler
 430 AM_PROG_AS
 431
 432 dnl determine if c++ is available on this system
 433 AC_PROG_CXX
 434 dnl CXX may be set to some default even if no c++ compiler is available
 435 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 436 AC_LANG_PUSH([C++])
 437 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ class Foo { int bar; };]], [[]])],[working_cxx=yes],[working_cxx=no])
 438 AC_LANG_POP([C++])
 439 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 440 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 441
 442 dnl Perl is used in building documentation and in the version checks
 443 AC_PATH_PROG(PERL_PATH, perl, no)
 444 if test x$PERL_PATH = xno; then
 445   AC_MSG_ERROR(Could not find perl)
 446 fi
 447
 448 dnl we require flex and bison for building the parser
 449 if test "x$GST_DISABLE_PARSE" != xyes; then
 450   AG_GST_BISON_CHECK
 451   AG_GST_FLEX_CHECK
 452 fi
 453
 454 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 455 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 456
 457 dnl check for gobject-introspection
 458 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 459
 460 dnl *** checks for libraries ***
 461
 462 dnl check for libm, for sin()
 463 LT_LIB_M
 464 AC_SUBST(LIBM)
 465
 466 dnl *** checks for header files ***
 467
 468 dnl check if we have ANSI C header files
 469 AC_HEADER_STDC
 470
 471 dnl Check for ucontext.h
 472 AC_CHECK_HEADERS([ucontext.h], [], [], [AC_INCLUDES_DEFAULT])
 473
 474 dnl Check for sys/socket.h
 475 AC_CHECK_HEADERS([sys/socket.h], [HAVE_SYS_SOCKET_H=yes], [HAVE_SYS_SOCKET_H=no], [AC_INCLUDES_DEFAULT])
 476 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 477
 478 dnl check for sys/times.h for tests/examples/adapter/
 479 AC_CHECK_HEADERS([sys/times.h], [HAVE_SYS_TIMES_H=yes], [HAVE_SYS_TIME_H=no], [AC_INCLUDES_DEFAULT])
 480 AC_CHECK_HEADERS([unistd.h], [HAVE_UNISTD_H=yes], [HAVE_UNISTD_H=no], [AC_INCLUDES_DEFAULT])
 481 AM_CONDITIONAL(HAVE_SYS_TIMES_H_AND_UNISTD_H, test "x$HAVE_SYS_TIMES_H" = "xyes" -a "x$HAVE_UNISTD_H" = "xyes")
 482
 483 dnl Check for process.h for getpid() on win32
 484 AC_CHECK_HEADERS([process.h], [], [], [AC_INCLUDES_DEFAULT])
 485
 486 dnl Check for sys/utsname.h for uname
 487 AC_CHECK_HEADERS([sys/utsname.h], [], [], [AC_INCLUDES_DEFAULT])
 488
 489 dnl Check for stdio_ext.f for __fbufsize
 490 AC_CHECK_HEADERS([stdio_ext.h], [], [], [AC_INCLUDES_DEFAULT])
 491
 492 dnl check for pthreads
 493 dnl without arguments AX_PTHREAD() will do AC_DEFINE(HAVE_PTHREAD)
 494 dnl which later checks use in their test code
 495 AX_PTHREAD()
 496 AM_CONDITIONAL(HAVE_PTHREAD, test "x$ax_pthread_ok" = "xyes")
 497
 498 dnl check for sys/prctl for setting thread name on Linux
 499 AC_CHECK_HEADERS([sys/prctl.h], [], [], [AC_INCLUDES_DEFAULT])
 500
 501 dnl check for pthread_setname_np(const char*)
 502 dnl which is present on OS X 10.6, iOS 3.2 and above
 503 AC_MSG_CHECKING(for pthread_setname_np(const char*))
 504 AC_LINK_IFELSE(
 505     [AC_LANG_PROGRAM(
 506         [#include <pthread.h>],
 507         [pthread_setname_np("example")])],
 508     [AC_MSG_RESULT(yes)
 509      AC_DEFINE(HAVE_PTHREAD_SETNAME_NP_WITHOUT_TID,1,
 510         [Have function pthread_setname_np(const char*)])],
 511     [AC_MSG_RESULT(no)])
 512
 513 dnl check for sys/uio.h for writev()
 514 AC_CHECK_HEADERS([sys/uio.h], [], [], [AC_INCLUDES_DEFAULT])
 515
 516 dnl Check for valgrind.h
 517 dnl separate from HAVE_VALGRIND because you can have the program, but not
 518 dnl the dev package
 519 AC_CHECK_HEADERS([valgrind/valgrind.h], [], [], [AC_INCLUDES_DEFAULT])
 520
 521 dnl used in gst/gstpoll.c
 522 AC_CHECK_HEADERS([winsock2.h], [HAVE_WINSOCK2_H=yes], [HAVE_WINSOCK2_H=no], [AC_INCLUDES_DEFAULT])
 523 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 524 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 525   WIN32_LIBS="-lws2_32"
 526   AC_SUBST(WIN32_LIBS)
 527 fi
 528
 529 dnl check for GMP/GSL, used by the gst_util_uint64_scale unit test only
 530 if test "x$BUILD_TESTS" = "xyes"; then
 531   AG_GST_CHECK_LIBHEADER(GMP, gmp,
 532                          __gmpz_init_set_d, ,
 533                          gmp.h,
 534                          GMP_LIBS="-lgmp"
 535                          AC_SUBST(GMP_LIBS)
 536                          AC_DEFINE(HAVE_GMP, [1],[Have GMP library]))
 537   AG_GST_CHECK_LIBHEADER(GSL, gsl,
 538                          gsl_rng_uniform_int, -lgslcblas,
 539                          gsl/gsl_rng.h,
 540                          GSL_LIBS="-lgsl -lgslcblas"
 541                          AC_SUBST(GSL_LIBS)
 542                          AC_DEFINE(HAVE_GSL, [1],[Have GSL library]))
 543 fi
 544
 545 dnl *** checks for types/defines ***
 546
 547 dnl *** checks for structures ***
 548
 549 dnl *** checks for compiler characteristics ***
 550
 551 dnl check if the compiler supports __uint128_t (gcc)
 552 dnl Actually check for 128-bit division, since that's what we use
 553 dnl uint128_t for.
 554 AC_CACHE_CHECK(for __uint128_t, gst_cv_uint128_t,
 555     AC_LINK_IFELSE([AC_LANG_PROGRAM([[ ]], [[
 556       static __uint128_t v1 = 100;
 557       static __uint128_t v2 = 10;
 558       static __uint128_t u;
 559       u = v1 / v2;
 560     ]])],[
 561       gst_cv_uint128_t=yes
 562     ],[
 563       gst_cv_uint128_t=no
 564     ])
 565 )
 566 if test x$gst_cv_uint128_t = xyes; then
 567   AC_DEFINE(HAVE_UINT128_T, 1, [Have __uint128_t type])
 568 fi
 569
 570 dnl *** checking for tm_gmtoff ***
 571 AC_MSG_CHECKING([for tm_gmtoff])
 572 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 573         #include <time.h>
 574         int main(void) {
 575           struct tm t;
 576           t.tm_gmtoff = 0;
 577           exit(0);
 578         }]])],
 579   [have_tm_gmtoff=yes
 580    AC_DEFINE(HAVE_TM_GMTOFF,1,[Have tm_gmtoff field in struct tm])],
 581   [have_tm_gmtoff=no],
 582   [have_tm_gmtoff="no (cross compiling)"])
 583 AC_MSG_RESULT($have_tm_gmtoff)
 584
 585
 586 dnl *** checks for library functions ***
 587
 588 AC_CHECK_FUNCS([strcasestr])
 589
 590 AC_CHECK_FUNCS([gmtime_r])
 591 AC_CHECK_FUNCS([localtime_r])
 592 AC_CHECK_FUNCS([sigaction])
 593 AC_CHECK_FUNCS([getrusage])
 594 AM_CONDITIONAL(HAVE_GETRUSAGE, test "x$ac_cv_func_getrusage" = "xyes")
 595 AC_CHECK_HEADERS([sys/resource.h])
 596
 597 dnl check for fseeko()
 598 AC_FUNC_FSEEKO
 599 dnl check for ftello()
 600 AC_CHECK_FUNCS([ftello])
 601
 602 AC_CHECK_FUNCS([fgetpos])
 603 AC_CHECK_FUNCS([fsetpos])
 604
 605 dnl check for poll(), ppoll() and pselect()
 606 AC_CHECK_HEADERS([sys/poll.h], [], [], [AC_INCLUDES_DEFAULT])
 607 AC_CHECK_HEADERS([poll.h], [], [], [AC_INCLUDES_DEFAULT])
 608 AC_CHECK_FUNCS([poll])
 609 AC_CHECK_FUNCS([ppoll])
 610 AC_CHECK_FUNCS([pselect])
 611
 612 dnl check for socketpair()
 613 AC_CHECK_FUNC(socketpair, [], [
 614   AC_CHECK_LIB(socket, socketpair, [
 615     SOCKET_LIBS="-lsocket"
 616     AC_SUBST(SOCKET_LIBS)
 617   ])
 618 ])
 619
 620 dnl ****************************************
 621 dnl *** GLib POLL* compatibility defines ***
 622 dnl ****************************************
 623
 624 AC_MSG_CHECKING([for broken poll])
 625 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 626         #include <stdlib.h>
 627         #include <fcntl.h>
 628         #ifdef HAVE_SYS_POLL_H
 629         #include <sys/poll.h>
 630         #endif
 631         #ifdef HAVE_POLL_H
 632         #include <poll.h>
 633         #endif
 634         int main(void) {
 635           struct pollfd fds[1];
 636           int fd;
 637           fd = open("/dev/null", 1);
 638           fds[0].fd = fd;
 639           fds[0].events = POLLIN;
 640           fds[0].revents = 0;
 641           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
 642                 exit(1);  /* Does not work for devices -- fail */
 643           }
 644           exit(0);
 645         }]])],
 646   [broken_poll=no],
 647   [broken_poll=yes
 648    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
 649   [broken_poll="no (cross compiling)"])
 650 AC_MSG_RESULT($broken_poll)
 651
 652 dnl check for getpagesize()
 653 AC_CHECK_FUNCS([getpagesize])
 654
 655 dnl Check for POSIX timers
 656 CLOCK_GETTIME_FOUND="no"
 657 AC_CHECK_FUNC(clock_gettime, [CLOCK_GETTIME_FOUND="yes"], [
 658   AC_CHECK_LIB(rt, clock_gettime, [
 659     CLOCK_GETTIME_FOUND="yes"
 660     LIBS="$LIBS -lrt"
 661   ], [
 662     AC_CHECK_LIB(pthread, clock_gettime, [
 663       CLOCK_GETTIME_FOUND="yes"
 664       LIBS="$LIBS -lpthread"
 665     ])
 666   ])
 667 ])
 668
 669 # With XCode 8, clock_gettime will be incorrectly detected as being available
 670 # regardless of what version of OS X you target because the symbol is available
 671 # in the .tbd file as a weak symbol.
 672 # See: https://bugzilla.gnome.org/show_bug.cgi?id=772451
 673 #
 674 # We cannot simply do AC_CHECK_FUNCS with -Wl,-no_weak_imports because the
 675 # autoconf check does its own prototype declaration that doesn't trigger that
 676 # compiler flag.
 677 #
 678 # It's only starting from macOS 10.12 and iOS 10.0 that clock_gettime is
 679 # actually available, so we can unconditionally disable it for older versions.
 680 case "$host_os" in
 681   darwin*)
 682     AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 683 #include <AvailabilityMacros.h>
 684 #include <TargetConditionals.h>
 685 #if defined(TARGET_OS_MAC)
 686 #  if MAC_OS_X_VERSION_MIN_REQUIRED < MAC_OS_X_VERSION_10_12
 687 #    error "Not compiling for OS X 10.12 or later"
 688 #  endif
 689 #else
 690 #  if __IPHONE_OS_VERSION_MIN_REQUIRED < __IPHONE_10_0
 691 #    error "Not compiling for iOS 10.0 or later"
 692 #  endif
 693 #endif
 694     ]])], [], [
 695     if test "$CLOCK_GETTIME_FOUND" = "yes"; then
 696       AC_MSG_NOTICE([Disabling incorrectly detected clock_gettime on OS X])
 697     fi
 698     CLOCK_GETTIME_FOUND="no"
 699     ])
 700     ;;
 701 esac
 702
 703 if test "$CLOCK_GETTIME_FOUND" = "yes"; then
 704   AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [Have clock_gettime])
 705 fi
 706
 707 AC_CACHE_CHECK(for posix timers, gst_cv_posix_timers,
 708     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 709 #include <time.h>
 710 #ifdef HAVE_UNISTD_H
 711 #include <unistd.h>
 712 #endif
 713     ]], [[
 714 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 715 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 716 #endif
 717     ]])],[
 718       gst_cv_posix_timers=yes
 719     ],[
 720       gst_cv_posix_timers=no
 721     ])
 722 )
 723
 724 if test "$gst_cv_posix_timers" = "yes"; then
 725   AC_DEFINE(HAVE_POSIX_TIMERS,1,[Have posix timers])
 726   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 1"
 727 else
 728   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 0"
 729 fi
 730 AC_SUBST(GST_HAVE_POSIX_TIMERS_DEFINE)
 731 AM_CONDITIONAL(GST_HAVE_POSIX_TIMERS, test "$gst_cv_posix_timers" = "yes")
 732
 733 AC_CACHE_CHECK(for monotonic clock, gst_cv_monotonic_clock,
 734     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 735 #include <time.h>
 736 #ifdef HAVE_UNISTD_H
 737 #include <unistd.h>
 738 #endif
 739     ]], [[
 740 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 741 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 742 #endif
 743     ]])],[
 744       gst_cv_monotonic_clock=yes
 745     ],[
 746       gst_cv_monotonic_clock=no
 747     ])
 748 )
 749
 750 if test "$gst_cv_monotonic_clock" = "yes"; then
 751   AC_DEFINE(HAVE_MONOTONIC_CLOCK,1,[Have a monotonic clock])
 752   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 1"
 753 else
 754   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 0"
 755 fi
 756 AC_SUBST(GST_HAVE_MONOTONIC_CLOCK_DEFINE)
 757 AM_CONDITIONAL(GST_HAVE_MONOTONIC_CLOCK, test "$gst_cv_monotonic_clock" = "yes")
 758
 759 dnl Check for a way to display the function name in debug output
 760 AG_GST_CHECK_FUNCTION
 761
 762 dnl test if we have dladdr(); we use it for debugging; see gst/gstinfo.c
 763 save_cflags="$CFLAGS"
 764 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 765 AC_CHECK_LIB(dl, dladdr,
 766    AC_DEFINE(HAVE_DLADDR, 1, [Defined if we have dladdr ()])
 767    LIBS="$LIBS -ldl")
 768 CFLAGS="$save_cflags"
 769
 770 dnl Check printf stuff
 771 if test "x${GST_DISABLE_GST_DEBUG}" != "xyes"; then
 772   AC_TYPE_LONG_LONG_INT
 773   AC_TYPE_UNSIGNED_LONG_LONG_INT
 774
 775   if test x$ac_cv_type_long_long_int$ac_cv_type_unsigned_long_long_int = xyesyes; then
 776     AC_DEFINE([HAVE_LONG_LONG], [1], [Define to 1 if the system has the type long long])
 777   fi
 778
 779   dnl /usr/share/aclocal/inttypes_h.m4 - ships with gettext apparently
 780   gl_AC_HEADER_INTTYPES_H
 781
 782   dnl /usr/share/aclocal/stdint_h.m4 - ships with gettext apparently
 783   gl_AC_HEADER_STDINT_H
 784
 785   AC_CHECK_TYPES(ptrdiff_t)
 786
 787   AC_TYPE_INTMAX_T
 788   AC_TYPE_SIZE_T
 789 fi
 790
 791 dnl *** checks for dependency libraries ***
 792
 793 dnl GLib
 794 GLIB_REQ=2.44.0
 795 AG_GST_GLIB_CHECK([$GLIB_REQ])
 796
 797 dnl Check for documentation xrefs
 798 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 799 AC_SUBST(GLIB_PREFIX)
 800
 801 dnl GTK is optional and only used in examples
 802 HAVE_GTK=no
 803 GTK_REQ=3.10
 804 if test "x$BUILD_EXAMPLES" = "xyes"; then
 805   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 806   AC_SUBST(GTK_LIBS)
 807   AC_SUBST(GTK_CFLAGS)
 808 fi
 809 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 810
 811 dnl libunwind is optionally used by the leaks tracer
 812 AC_ARG_WITH([unwind],[AS_HELP_STRING([--with-unwind=yes|no|auto],[use libunwind])],
 813             [], [with_unwind=auto])
 814 if [ test "x${with_unwind}" != "xno" ]; then
 815   PKG_CHECK_MODULES(UNWIND, [libunwind],
 816       [
 817         HAVE_UNWIND=yes
 818         AC_DEFINE(HAVE_UNWIND, 1, [libunwind available])
 819         UNWIND_REQUIRE=libunwind
 820         AC_SUBST(UNWIND_REQUIRE)
 821       ],
 822       [
 823         HAVE_UNWIND=no
 824         if [ test "x${with_unwind}" = "xyes" ]; then
 825           AC_MSG_ERROR([could not find libunwind])
 826         fi
 827       ])
 828 else
 829   HAVE_UNWIND=no
 830 fi
 831
 832 dnl libdw is optionally used to add source lines and numbers to backtraces
 833 AC_ARG_WITH([dw],[AS_HELP_STRING([--with-dw=yes|no|auto],[use libdw])],
 834             [], [with_dw=auto])
 835 if [ test "x${with_dw}" != "xno" ]; then
 836   PKG_CHECK_MODULES(DW, [libdw],
 837       [
 838         HAVE_DW=yes
 839         AC_DEFINE(HAVE_DW, 1, [libdw available])
 840         DW_REQUIRE=libdw
 841         AC_SUBST(DW_REQUIRE)
 842       ],
 843       [
 844         HAVE_DW=no
 845         if [ test "x${with_dw}" = "xyes" ]; then
 846           AC_MSG_ERROR([could not find libdw])
 847         fi
 848       ])
 849 else
 850   HAVE_DW=no
 851 fi
 852
 853 dnl Check for backtrace() from libc
 854 AC_CHECK_FUNC(backtrace, [
 855   AC_CHECK_HEADERS([execinfo.h], [
 856     AC_DEFINE(HAVE_BACKTRACE,1,[Have backtrace])
 857   ], [], [])
 858 ])
 859
 860 dnl building of unit test libraries
 861 AC_ARG_ENABLE(check,
 862   AS_HELP_STRING([--disable-check],[disable building unit test libraries]),
 863   [
 864     case "${enableval}" in
 865       yes) BUILD_CHECK=yes ;;
 866       no)  BUILD_CHECK=no ;;
 867       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-check) ;;
 868     esac
 869   ], [
 870     dnl Default value
 871     case $host_os in
 872       mingw* | msvc* | mks*) BUILD_CHECK=no ;;
 873       *) BUILD_CHECK=yes ;;
 874     esac
 875 ])
 876 dnl bit of a misnomer, but keep the conditional named like this so we don't
 877 dnl have to change too much elsewhere
 878 AM_CONDITIONAL(HAVE_CHECK, test "x$BUILD_CHECK" = "xyes")
 879
 880 dnl configure the desired memory alignment
 881 AC_ARG_WITH([memory-alignment],
 882   AS_HELP_STRING([--with-memory-alignment],[8,N,malloc,pagesize (default is 32)]),
 883   [
 884     if test "x$withval" = "xyes"
 885     then
 886       AC_DEFINE(MEMORY_ALIGNMENT, 32, [Memory alignment to use])
 887     else
 888       case "${withval}" in
 889         malloc) AC_DEFINE(MEMORY_ALIGNMENT_MALLOC, 1, [Memory alignment by malloc default]) ;;
 890         pagesize)  AC_DEFINE(MEMORY_ALIGNMENT_PAGESIZE, 1, [Memory alignment by pagesize]) ;;
 891         *)   AC_DEFINE_UNQUOTED(MEMORY_ALIGNMENT, ${withval}, [Memory alignment to use]) ;;
 892       esac
 893     fi
 894   ], [
 895     AC_DEFINE(MEMORY_ALIGNMENT_MALLOC, 1, [Memory alignment by malloc default])
 896   ]
 897 )
 898
 899 dnl Symbol visibility
 900 VISIBILITY_CFLAGS=""
 901 AS_COMPILER_FLAG([-fvisibility=hidden], [
 902   VISIBILITY_CFLAGS="-fvisibility=hidden"
 903   AC_DEFINE(GST_API_EXPORT, [extern __attribute__ ((visibility ("default")))], [public symbol export define])
 904 ], [
 905   VISIBILITY_CFLAGS=""
 906   AC_DEFINE(GST_API_EXPORT, [extern], [public symbol export define])
 907 ])
 908 AC_SUBST(VISIBILITY_CFLAGS)
 909
 910 dnl Check for -Bsymbolic-functions linker flag used to avoid
 911 dnl intra-library PLT jumps, if available.
 912 AC_ARG_ENABLE(Bsymbolic,
 913               [AS_HELP_STRING([--disable-Bsymbolic],[avoid linking with -Bsymbolic])],,
 914               [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
 915                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 916                LDFLAGS=-Wl,-Bsymbolic-functions
 917                LIBS=
 918                AC_TRY_LINK([], [return 0],
 919                            AC_MSG_RESULT(yes)
 920                            enable_Bsymbolic=yes,
 921                            AC_MSG_RESULT(no)
 922                            enable_Bsymbolic=no)
 923                LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
 924
 925
 926 dnl *** set variables based on configure arguments
 927
 928 dnl set license and copyright notice
 929 GST_LICENSE="LGPL"
 930 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 931 AC_SUBST(GST_LICENSE)
 932
 933 dnl define LIBDIR, GST_DATADIR so we can inform people where we live
 934 AS_AC_EXPAND(LIBDIR, $libdir)
 935 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [library dir])
 936 AS_AC_EXPAND(DATADIR, $datadir)
 937 AC_DEFINE_UNQUOTED(GST_DATADIR, "$DATADIR", [data dir])
 938
 939 dnl set location of plugin directory
 940 AG_GST_SET_PLUGINDIR
 941
 942 dnl make sure it doesn't complain about unused variables if debugging is disabled
 943 NO_WARNINGS=""
 944 if test "x${GST_DISABLE_GST_DEBUG}" = "xyes"; then
 945   NO_WARNINGS="-Wno-unused"
 946 fi
 947
 948 dnl define an ERROR_CFLAGS Makefile variable
 949 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [-Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef -Wwrite-strings -Wformat-nonliteral -Wformat-security -Wold-style-definition -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return -Wno-multichar -Wnested-externs $NO_WARNINGS])
 950
 951 dnl special warning flags for gst/printf
 952 AS_COMPILER_FLAG([-Wno-format-nonliteral], [PRINTF_CFLAGS="-Wno-format-nonliteral"])
 953 AC_SUBST(PRINTF_CFLAGS)
 954
 955 dnl disable strict aliasing
 956 AS_COMPILER_FLAG([-fno-strict-aliasing], [EXTRA_CFLAGS="-fno-strict-aliasing"])
 957 AC_SUBST(EXTRA_CFLAGS)
 958
 959 dnl define correct level for debugging messages
 960 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 961
 962 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 963
 964 dnl Overview:
 965 dnl GST_OPTION_CFLAGS:  common cflags for profiling, debugging, errors, ...
 966 dnl GST_ALL_*:          vars shared by all built objects
 967 dnl GST_LIB_LDFLAGS:    additional linker flags for all libraries
 968 dnl GST_OBJ_*:          additional vars to link to the core library
 969 dnl                     include GST_ALL_*
 970 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 971 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 972
 973 dnl GST_OPTION_CFLAGS
 974 if test "x$USE_DEBUG" = xyes; then
 975    PROFILE_CFLAGS="-g"
 976 fi
 977 AC_SUBST(PROFILE_CFLAGS)
 978
 979 # GST_DISABLE_DEPRECATED: hide the visibility of deprecated
 980 # functionality from the API that gstreamer uses
 981 # GST_REMOVE_DEPRECATED: don't compile deprecated functionality (breaks ABI)
 982 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 983   dnl Define _only_ when compiling from git (not for pre-releases or releases)
 984   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 985 else
 986   DEPRECATED_CFLAGS=""
 987 fi
 988 AC_SUBST(DEPRECATED_CFLAGS)
 989
 990 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time via e.g.
 991 dnl make DEPRECATED_CFLAGS=''
 992 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 993 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 994 GST_OPTION_CFLAGS="$GST_OPTION_CFLAGS"
 995 GST_OPTION_CXXFLAGS="$GST_OPTION_CXXFLAGS"
 996 AC_SUBST(GST_OPTION_CFLAGS)
 997 AC_SUBST(GST_OPTION_CXXFLAGS)
 998
 999 dnl GST_ALL_*
1000 dnl vars common to for all internal objects (core libs, elements, applications)
1001 dnl CFLAGS:
1002 dnl - src and build dirs need to be added because every piece that gets built
1003 dnl   will need the GStreamer source and generated headers
1004 dnl LIBS: XML doesn't need to be added because we don't explicitly use symbols
1005 dnl       from LibXML except for in the core library
1006 GST_ALL_CXXFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir)/libs -I\$(top_builddir) $GLIB_CFLAGS \$(GLIB_EXTRA_CFLAGS) $EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS) \$(ERROR_CXXFLAGS)"
1007 GST_ALL_CFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir)/libs -I\$(top_builddir) $GLIB_CFLAGS \$(GLIB_EXTRA_CFLAGS) $EXTRA_CFLAGS \$(GST_OPTION_CFLAGS) \$(ERROR_CFLAGS) \$(VISIBILITY_CFLAGS)"
1008
1009 dnl FIXME: check if LTLIBINTL is needed everywhere
1010 dnl I presume it is given that it contains the symbols that _() stuff maps to
1011 GST_ALL_LIBS="$GLIB_LIBS $LTLIBINTL \$(GCOV_LIBS)"
1012
1013 dnl LDFLAGS really should only contain flags, not libs - they get added before
1014 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1015 GST_ALL_LDFLAGS="-no-undefined"
1016 if test "x${enable_Bsymbolic}" = "xyes"; then
1017   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
1018 fi
1019
1020 AC_SUBST(GST_ALL_CFLAGS)
1021 AC_SUBST(GST_ALL_CXXFLAGS)
1022 AC_SUBST(GST_ALL_LIBS)
1023 AC_SUBST(GST_ALL_LDFLAGS)
1024
1025 dnl GST_LIB_LDFLAGS
1026 dnl linker flags shared by all libraries
1027 dnl LDFLAGS modifier defining exported symbols from built libraries
1028 GST_LIB_LDFLAGS=""
1029 AC_SUBST(GST_LIB_LDFLAGS)
1030
1031 dnl GST_OBJ_*
1032 dnl default vars for all internal objects built on libgstreamer
1033 dnl includes GST_ALL_*
1034 GST_OBJ_CFLAGS="\$(GST_ALL_CFLAGS) $GST_OBJ_STATIC_CFLAGS"
1035 GST_OBJ_CXXFLAGS="\$(GST_ALL_CXXFLAGS) $GST_OBJ_STATIC_CFLAGS"
1036 GST_OBJ_LIBS="\$(top_builddir)/gst/libgstreamer-$GST_API_VERSION.la \$(GST_ALL_LIBS)"
1037 AC_SUBST(GST_OBJ_CFLAGS)
1038 AC_SUBST(GST_OBJ_CXXFLAGS)
1039 AC_SUBST(GST_OBJ_LIBS)
1040
1041 dnl GST_PLUGIN_LDFLAGS
1042 dnl LDFLAGS for plugins; includes GST_ALL_LDFLAGS
1043 GST_PLUGIN_LDFLAGS="-module -avoid-version $GST_ALL_LDFLAGS"
1044 AC_SUBST(GST_PLUGIN_LDFLAGS, "$GST_PLUGIN_LDFLAGS")
1045
1046 dnl plugin scanner locations
1047 AS_AC_EXPAND(GST_PLUGIN_SCANNER_INSTALLED,${libexecdir}/gstreamer-$GST_API_VERSION/gst-plugin-scanner)
1048 AC_DEFINE_UNQUOTED(GST_PLUGIN_SCANNER_INSTALLED,
1049     "$GST_PLUGIN_SCANNER_INSTALLED", [location of the installed gst-plugin-scanner])
1050 AC_SUBST(GST_PLUGIN_SCANNER_INSTALLED)
1051
1052 case "${libexecdir}" in
1053   *libexec)
1054     GST_PLUGIN_SCANNER_SUBDIR="libexec";;
1055   *lib)
1056     GST_PLUGIN_SCANNER_SUBDIR="lib";;
1057   *)
1058     GST_PLUGIN_SCANNER_SUBDIR=`basename ${libexecdir}`;
1059     if test -z "$GST_PLUGIN_SCANNER_SUBDIR"; then
1060       AC_MSG_WARN([Couldn't determined libexecdir suffix, using "lib"])
1061       GST_PLUGIN_SCANNER_SUBDIR="lib";
1062     fi
1063     ;;
1064 esac
1065 AC_DEFINE_UNQUOTED(GST_PLUGIN_SCANNER_SUBDIR,
1066     "$GST_PLUGIN_SCANNER_SUBDIR", [libexecdir path component, used to find plugin-scanner on relocatable builds on windows])
1067
1068 case "${libdir}" in
1069   *lib64)
1070     GST_PLUGIN_SUBDIR="lib64";;
1071   *lib32)
1072     GST_PLUGIN_SUBDIR="lib32";;
1073   *lib)
1074     GST_PLUGIN_SUBDIR="lib";;
1075   *)
1076     GST_PLUGIN_SUBDIR=`basename ${libdir}`;
1077     if test -z "$GST_PLUGIN_SUBDIR"; then
1078       AC_MSG_WARN([Couldn't determined libdir suffix, using "lib"])
1079       GST_PLUGIN_SUBDIR="lib";
1080     fi
1081     ;;
1082 esac
1083 AC_DEFINE_UNQUOTED(GST_PLUGIN_SUBDIR,
1084     "$GST_PLUGIN_SUBDIR", [plugin directory path component, used to find plugins on relocatable builds on windows])
1085
1086 dnl completion helper locations
1087 AS_AC_EXPAND(GST_COMPLETION_HELPER_INSTALLED,${libexecdir}/gstreamer-$GST_API_VERSION/gst-completion-helper)
1088 AC_DEFINE_UNQUOTED(GST_COMPLETION_HELPER_INSTALLED,
1089     "$GST_COMPLETION_HELPER_INSTALLED", [location of the installed gst-completion-helper])
1090 AC_SUBST(GST_COMPLETION_HELPER_INSTALLED)
1091
1092 dnl ptp helper locations
1093 AS_AC_EXPAND(GST_PTP_HELPER_INSTALLED,${libexecdir}/gstreamer-$GST_API_VERSION/gst-ptp-helper)
1094 AC_DEFINE_UNQUOTED(GST_PTP_HELPER_INSTALLED,
1095     "$GST_PTP_HELPER_INSTALLED", [location of the installed gst-ptp-helper])
1096 AC_SUBST(GST_PTP_HELPER_INSTALLED)
1097
1098 dnl things for our internal libcheck (must be called even if building
1099 dnl libcheck is disabled because it defines conditionals)
1100 AG_GST_CHECK_CHECKS
1101
1102 AC_CONFIG_FILES(
1103 Makefile
1104 data/Makefile
1105 data/bash-completion/helpers/gst
1106 gst/Makefile
1107 gst/gstconfig.h
1108 gst/gstversion.h
1109 libs/gst/helpers/libgstreamer-gdb.py
1110 gst/parse/Makefile
1111 gst/printf/Makefile
1112 libs/Makefile
1113 libs/gst/Makefile
1114 libs/gst/base/Makefile
1115 libs/gst/check/Makefile
1116 libs/gst/check/libcheck/Makefile
1117 libs/gst/check/internal-check.h:libs/gst/check/libcheck/check.h.in
1118 libs/gst/controller/Makefile
1119 libs/gst/helpers/Makefile
1120 libs/gst/net/Makefile
1121 plugins/Makefile
1122 plugins/elements/Makefile
1123 plugins/tracers/Makefile
1124 po/Makefile.in
1125 tests/Makefile
1126 tests/benchmarks/Makefile
1127 tests/check/Makefile
1128 tests/misc/Makefile
1129 tests/examples/Makefile
1130 tests/examples/adapter/Makefile
1131 tests/examples/controller/Makefile
1132 tests/examples/stepping/Makefile
1133 tests/examples/helloworld/Makefile
1134 tests/examples/memory/Makefile
1135 tests/examples/netclock/Makefile
1136 tests/examples/ptp/Makefile
1137 tests/examples/streamiddemux/Makefile
1138 tests/examples/streams/Makefile
1139 tools/Makefile
1140 common/Makefile
1141 common/m4/Makefile
1142 m4/Makefile
1143 pkgconfig/Makefile
1144 stamp.h
1145 pkgconfig/gstreamer.pc
1146 pkgconfig/gstreamer-uninstalled.pc
1147 pkgconfig/gstreamer-base.pc
1148 pkgconfig/gstreamer-base-uninstalled.pc
1149 pkgconfig/gstreamer-check.pc
1150 pkgconfig/gstreamer-check-uninstalled.pc
1151 pkgconfig/gstreamer-controller.pc
1152 pkgconfig/gstreamer-controller-uninstalled.pc
1153 pkgconfig/gstreamer-net.pc
1154 pkgconfig/gstreamer-net-uninstalled.pc
1155 )
1156
1157 AC_OUTPUT
1158
1159 dnl negate for output
1160 if test "x${GST_DISABLE_GST_DEBUG}" = "xno"; then enable_gst_debug="yes"; fi
1161 if test "x${GST_DISABLE_GST_TRACER_HOOKS}" = "xno"; then enable_gst_tracer_hooks="yes"; fi
1162 if test "x${GST_DISABLE_PARSE}" = "xno"; then enable_parse="yes"; fi
1163 if test "x${GST_DISABLE_OPTION_PARSING}" = "xno"; then enable_option_parsing="yes"; fi
1164 if test "x${GST_DISABLE_PLUGIN}" = "xno"; then enable_plugin="yes"; fi
1165 if test "x${GST_DISABLE_REGISTRY}" = "xno"; then enable_registry="yes"; fi
1166
1167 echo "
1168
1169 Configuration
1170         Version                    : ${VERSION}
1171         Source code location       : ${srcdir}
1172         Prefix                     : ${prefix}
1173         Compiler                   : ${CC}
1174         Package name               : ${GST_PACKAGE_NAME}
1175         Package origin             : ${GST_PACKAGE_ORIGIN}
1176
1177         Debug logging              : ${enable_gst_debug}
1178         Tracing subsystem hooks    : ${enable_gst_tracer_hooks}
1179         Command-line parser        : ${enable_parse}
1180         Option parsing in gst_init : ${enable_option_parsing}
1181         Plugin registry            : ${enable_registry}
1182         Plugin support             : ${enable_plugin}
1183         Static plugins             : ${enable_static_plugins}
1184         Unit testing support       : ${BUILD_CHECK}
1185         PTP clock support          : ${HAVE_PTP}
1186         libunwind support          : ${HAVE_UNWIND}
1187         libdw support              : ${HAVE_DW}
1188
1189         Debug                      : ${USE_DEBUG}
1190         Profiling                  : ${USE_PROFILING}
1191
1192         Building benchmarks        : ${BUILD_BENCHMARKS}
1193         Building examples          : ${BUILD_EXAMPLES}
1194         Building test apps         : ${BUILD_TESTS}
1195         Building tests that fail   : ${BUILD_FAILING_TESTS}
1196         Building tools             : ${BUILD_TOOLS}
1197 "