configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, cvs and prerelease does Werror too
   6 AC_INIT(GStreamer, 0.10.5,
   7     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
   8     gstreamer)
   9
  10 dnl initialize automake
  11 AM_INIT_AUTOMAKE
  12
  13 dnl define PACKAGE_VERSION_* variables
  14 AS_VERSION
  15
  16 dnl check if this is a release version
  17 AS_NANO(GST_CVS="no", GST_CVS="yes")
  18
  19 dnl can autoconf find the source ?
  20 AC_CONFIG_SRCDIR([gst/gst.c])
  21
  22 dnl define the output header for config
  23 AM_CONFIG_HEADER([config.h])
  24
  25 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  26 AM_MAINTAINER_MODE
  27
  28 dnl sets host_* variables
  29 AC_CANONICAL_HOST
  30
  31 dnl our libraries and install dirs use major.minor as a version
  32 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  33 dnl we override it here for release candidates for a new series
  34 GST_MAJORMINOR=0.10
  35 AC_SUBST(GST_MAJORMINOR)
  36
  37 dnl CURRENT, REVISION, AGE
  38 dnl - library source changed -> increment REVISION
  39 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  40 dnl - interfaces added -> increment AGE
  41 dnl - interfaces removed -> AGE = 0
  42 dnl sets GST_LT_LDFLAGS
  43 AS_LIBTOOL(GST, 6, 0, 6)
  44
  45 dnl FIXME: this macro doesn't actually work;
  46 dnl the generated libtool script has no support for the listed tags.
  47 dnl So this needs to be fixed first if we want to use this
  48 dnl AS_LIBTOOL_TAGS
  49
  50 AM_PROG_LIBTOOL
  51
  52 dnl *** autotools stuff ****
  53
  54 dnl allow for different autotools
  55 AS_AUTOTOOLS_ALTERNATE
  56
  57 dnl Add parameters for aclocal
  58 AC_SUBST(ACLOCAL_AMFLAGS, "-I common/m4")
  59
  60 dnl set up gettext
  61 dnl the version check needs to stay here because autopoint greps for it
  62 AM_GNU_GETTEXT_VERSION([0.11.5])
  63 AM_GNU_GETTEXT([external])
  64 GST_GETTEXT([gstreamer-$GST_MAJORMINOR])
  65
  66 dnl *** check for arguments to configure ***
  67
  68 dnl subsystems - can influence other decisions so needs to be high up
  69 dnl we need to AM_CONDITIONAL them here for automake 1.6.x compatibility
  70 GST_CHECK_SUBSYSTEM_DISABLE(GST_DEBUG,[debugging subsystem])
  71 AM_CONDITIONAL(GST_DISABLE_GST_DEBUG, test "x$GST_GST_DISABLE_DEBUG" = "xyes")
  72 GST_CHECK_SUBSYSTEM_DISABLE(LOADSAVE,[pipeline XML load/save])
  73 AM_CONDITIONAL(GST_DISABLE_LOADSAVE, test "x$GST_DISABLE_LOADSAVE" = "xyes")
  74 dnl define a substitution to use in docs/gst/gstreamer.types
  75 if test "x$GST_DISABLE_LOADSAVE" = "xyes"
  76 then
  77   GST_LOADSAVE_DOC_TYPES="%"
  78 else
  79   GST_LOADSAVE_DOC_TYPES=
  80 fi
  81 AC_SUBST(GST_LOADSAVE_DOC_TYPES)
  82 GST_CHECK_SUBSYSTEM_DISABLE(PARSE,[command-line parser])
  83 AM_CONDITIONAL(GST_DISABLE_PARSE, test "x$GST_DISABLE_PARSE" = "xyes")
  84 if test "x$GST_DISABLE_PARSE" = xyes; then
  85   AC_DEFINE(GST_DISABLE_PARSE, 1,
  86     [Define if pipeline parsing code is disabled])
  87 fi
  88 GST_CHECK_SUBSYSTEM_DISABLE(TRACE,[tracing subsystem])
  89 AM_CONDITIONAL(GST_DISABLE_TRACE, test "x$GST_DISABLE_TRACE" = "xyes")
  90 GST_CHECK_SUBSYSTEM_DISABLE(ALLOC_TRACE,[allocation tracing])
  91 AM_CONDITIONAL(GST_DISABLE_ALLOC_TRACE, test "x$GST_DISABLE_ALLOC_TRACE" = "xyes")
  92 GST_CHECK_SUBSYSTEM_DISABLE(REGISTRY,[plugin registry])
  93 AM_CONDITIONAL(GST_DISABLE_REGISTRY, test "x$GST_DISABLE_REGISTRY" = "xyes")
  94 dnl define a substitution to use in docs/gst/gstreamer.types
  95 if test "x$GST_DISABLE_REGISTRY" = "xyes"
  96 then
  97   GST_REGISTRY_DOC_TYPES="%"
  98 else
  99   GST_REGISTRY_DOC_TYPES=
 100 fi
 101 AC_SUBST(GST_REGISTRY_DOC_TYPES)
 102 GST_CHECK_SUBSYSTEM_DISABLE(ENUMTYPES,[enum types])
 103 AM_CONDITIONAL(GST_DISABLE_ENUMTYPES, test "x$GST_DISABLE_ENUMTYPES" = "xyes")
 104 GST_CHECK_SUBSYSTEM_DISABLE(INDEX,[index])
 105 AM_CONDITIONAL(GST_DISABLE_INDEX, test "x$GST_DISABLE_INDEX" = "xyes")
 106 GST_CHECK_SUBSYSTEM_DISABLE(NET,[network distribution])
 107 AM_CONDITIONAL(GST_DISABLE_NET, test "x$GST_DISABLE_NET" = "xyes")
 108 GST_CHECK_SUBSYSTEM_DISABLE(PLUGIN,[plugin])
 109 AM_CONDITIONAL(GST_DISABLE_PLUGIN, test "x$GST_DISABLE_PLUGIN" = "xyes")
 110 GST_CHECK_SUBSYSTEM_DISABLE(URI,[uri handlers])
 111 AM_CONDITIONAL(GST_DISABLE_URI, test "x$GST_DISABLE_URI" = "xyes")
 112
 113 GST_ARG_DEBUG
 114 GST_ARG_PROFILING
 115 GST_ARG_VALGRIND
 116 GST_ARG_GCOV
 117
 118 GST_ARG_EXAMPLES
 119
 120 GST_ARG_WITH_PKG_CONFIG_PATH
 121 GST_ARG_WITH_PACKAGE_NAME
 122 GST_ARG_WITH_PACKAGE_ORIGIN
 123
 124 dnl use a cache dir for storing element registry info.
 125 GST_CACHE_DIR=${localstatedir}/cache/gstreamer-$GST_MAJORMINOR
 126
 127 AC_ARG_WITH(cachedir,
 128   AC_HELP_STRING([--with-cachedir],
 129     [specify path to use for plugin and command completion registries]),
 130   [
 131     case "${withval}" in
 132       yes) AC_MSG_ERROR(bad value ${withval} for --with-cachedir) ;;
 133       no)  AC_MSG_ERROR(bad value ${withval} for --with-cachedir) ;;
 134       *)   GST_CACHE_DIR="${withval}" ;;
 135     esac
 136   ],
 137   [:]) dnl Default value
 138
 139 AS_AC_EXPAND(GST_CACHE_DIR, $GST_CACHE_DIR)
 140 AC_DEFINE_UNQUOTED(GST_CACHE_DIR, "$GST_CACHE_DIR", [Location of registry])
 141 AC_MSG_NOTICE(Using $GST_CACHE_DIR as registry cache dir)
 142
 143 dnl building of tests
 144 AC_ARG_ENABLE(tests,
 145   AC_HELP_STRING([--disable-tests], [disable building test apps]),
 146   [
 147     case "${enableval}" in
 148       yes) BUILD_TESTS=yes ;;
 149       no)  BUILD_TESTS=no ;;
 150       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 151     esac
 152   ],
 153 [BUILD_TESTS=yes]) dnl Default value
 154 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 155
 156 dnl tests known to fail
 157 AC_ARG_ENABLE(failing-tests,
 158   AC_HELP_STRING([--disable-failing-tests],
 159     [disable building tests known to fail]),
 160   [
 161     case "${enableval}" in
 162       yes) BUILD_FAILING_TESTS=yes ;;
 163       no)  BUILD_FAILING_TESTS=no ;;
 164       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-failing-tests) ;;
 165     esac
 166   ],
 167   [BUILD_FAILING_TESTS=no]) dnl Default value
 168 AM_CONDITIONAL(BUILD_FAILING_TESTS, test "x$BUILD_FAILING_TESTS" = "xyes")
 169 if test x$BUILD_FAILING_TESTS = xyes; then
 170   AC_MSG_WARN([building tests known to fail, use --disable-failing-tests to disable])
 171 else
 172   AC_MSG_WARN([Sissy ! By asking to not build the tests known to fail, you hereby waive your right to customer support.  If you do not agree with this EULA, please press Ctrl-C before the next line is printed.  By allowing the next line to be printed, you expressly acknowledge your acceptance of this EULA.])
 173 fi
 174
 175 dnl poison destroyed objects
 176 AC_ARG_ENABLE(poisoning,
 177   AC_HELP_STRING([--enable-poisoning],
 178     [enable poisoning of deallocated objects]),
 179   [
 180     case "${enableval}" in
 181       yes) USE_POISONING=yes ;;
 182       no)  USE_POISONING=no ;;
 183       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-poisoning) ;;
 184     esac
 185   ],
 186   [USE_POISONING=no]) dnl Default value
 187 if test "x$USE_POISONING" = xyes; then
 188   AC_DEFINE(USE_POISONING, 1,
 189     [Define if we should poison deallocated memory])
 190 fi
 191
 192 dnl *** checks for platform ***
 193
 194 dnl * hardware/architecture *
 195
 196 dnl common/m4/gst-arch.m4
 197 dnl check CPU type
 198 GST_ARCH
 199 dnl substitution for win32/common/config.h
 200 HOST_CPU=$host_cpu
 201 AC_SUBST(HOST_CPU)
 202
 203 dnl common/m4/gst-arch.m4
 204 dnl check for unaligned access
 205 GST_UNALIGNED_ACCESS
 206 dnl create a configure variable for gst/gstconfig.h
 207 if test x${as_cv_unaligned_access} = xyes ; then
 208   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 1"
 209 else
 210   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 0"
 211 fi
 212 AC_SUBST(GST_HAVE_UNALIGNED_ACCESS_DEFINE)
 213
 214 dnl * software *
 215
 216 dnl check for large file support
 217 dnl affected plugins must include config.h
 218 AC_SYS_LARGEFILE
 219
 220 dnl HAVE_WIN32 currently means "disable POSIXisms".
 221 case "$host" in
 222   *-*-mingw*)
 223     AC_DEFINE_UNQUOTED(HAVE_WIN32, 1, [Defined if compiling for Windows])
 224     ;;
 225   *)
 226     ;;
 227 esac
 228
 229 dnl *** checks for programs ***
 230
 231 dnl find a compiler
 232 AC_PROG_CC
 233
 234 dnl find an assembler
 235 AM_PROG_AS
 236
 237 dnl we use awk in the bison version check
 238 AC_PROG_AWK
 239
 240 dnl we require bison for building the parser
 241 dnl FIXME: check if AC_PROG_YACC is suitable here
 242 dnl FIXME: make precious
 243 AC_PATH_PROG(BISON_PATH, bison, no)
 244 if test x$BISON_PATH = xno; then
 245   AC_MSG_ERROR(Could not find bison)
 246 fi
 247
 248 dnl check bison version
 249 AC_MSG_CHECKING([bison version])
 250
 251 if $BISON_PATH --version | head -n 1 | $AWK '{ if ($4 < 1.35) exit 1; else exit 0;}';
 252 then
 253   AC_MSG_RESULT([ok])
 254 else
 255   AC_MSG_RESULT([too old.])
 256   AC_MSG_ERROR([Your bison version is too old, v1.35 or later is required.])
 257 fi
 258
 259 dnl we require flex for building the parser
 260 dnl FIXME: check if AC_PROG_LEX is suitable here
 261 AC_PATH_PROG(FLEX_PATH, flex, no)
 262 if test x$FLEX_PATH = xno; then
 263   AC_MSG_ERROR(Could not find flex)
 264 fi
 265
 266 dnl Perl is used in building documentation
 267 AC_PATH_PROG(PERL_PATH, perl, no)
 268 if test x$PERL_PATH = xno; then
 269   AC_MSG_ERROR(Could not find perl)
 270 fi
 271
 272 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 273 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 274
 275 dnl check for documentation tools
 276 GST_DOCBOOK_CHECK
 277 GTK_DOC_CHECK([1.3])
 278 AS_PATH_PYTHON([2.1])
 279
 280 dnl *** checks for libraries ***
 281
 282 dnl For interactive UNIX (a Sun thing)
 283 dnl FIXME: this adds -lcposix to LIBS, but I doubt we use LIBS
 284 AC_ISC_POSIX
 285
 286 dnl *** checks for header files ***
 287
 288 dnl check if we have ANSI C header files
 289 AC_HEADER_STDC
 290
 291 dnl Check for ucontext.h
 292 AC_CHECK_HEADERS([ucontext.h])
 293 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 294 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 295 AC_CHECK_HEADERS([process.h])
 296
 297 dnl *** checks for types/defines ***
 298
 299 dnl *** checks for structures ***
 300
 301 dnl *** checks for compiler characteristics ***
 302
 303 dnl make sure we can use "inline" from C code
 304 AC_C_INLINE
 305
 306 OPT_CFLAGS=
 307 dnl Check for some compiler flags that optimize our code.
 308 if test "x$GCC" = xyes; then
 309   AS_COMPILER_FLAG(-fno-common, OPT_CFLAGS="$OPT_CFLAGS -fno-common")
 310 fi
 311
 312 dnl FIXME: decide what kind of flag this is, maybe it's not an optimization
 313 dnl flag
 314 dnl check if we should use -Wa,-mregnames on PowerPC, so we can use
 315 dnl symbolic register names in inline asm
 316 if test x$HAVE_CPU_PPC = xyes ; then
 317   AS_COMPILER_FLAG(["-Wa,-mregnames"],
 318     [OPT_CFLAGS="$OPT_CFLAGS -Wa,-mregnames"])
 319 fi
 320
 321 dnl *** checks for library functions ***
 322
 323 AC_CHECK_FUNCS([sigaction])
 324
 325 dnl check for fseeko()
 326 AC_FUNC_FSEEKO
 327 dnl check for ftello()
 328 AC_CHECK_FUNCS([ftello])
 329
 330 AC_CHECK_FUNCS([fgetpos])
 331 AC_CHECK_FUNCS([fsetpos])
 332
 333 dnl check for mmap()
 334 AC_FUNC_MMAP
 335 AM_CONDITIONAL(HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 336
 337 dnl Check for a way to display the function name in debug output
 338 GST_CHECK_FUNCTION
 339
 340 dnl test for register_printf_function
 341 AC_CHECK_FUNC(register_printf_function,
 342   [
 343     GST_PRINTF_EXTENSION_FORMAT_DEFINE="#define GST_PTR_FORMAT \"P\""
 344     AC_DEFINE(HAVE_PRINTF_EXTENSION, 1,
 345       [Defined if we have register_printf_function ()])
 346   ],
 347   GST_PRINTF_EXTENSION_FORMAT_DEFINE="#define GST_PTR_FORMAT \"p\""
 348 )
 349 AC_SUBST(GST_PRINTF_EXTENSION_FORMAT_DEFINE)
 350
 351 dnl test if we have dladdr(); we use it for debugging; see gst/gstinfo.c
 352 save_cflags="$CFLAGS"
 353 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 354 AC_CHECK_LIB(dl, dladdr,
 355    AC_DEFINE(HAVE_DLADDR, 1,
 356              [Defined if we have dladdr ()]))
 357 CFLAGS="$save_cflags"
 358
 359 dnl *** checks for dependancy libraries ***
 360
 361 dnl GLib
 362
 363 GST_GLIB_CHECK([2.6])
 364
 365 dnl GLib 2.8 has some bug fixes that we like, so make sure our code knows
 366 AC_MSG_CHECKING([glib version >= 2.8])
 367 if pkg-config --atleast-version=2.8 glib-2.0; then
 368   AC_MSG_RESULT(yes)
 369   GST_HAVE_GLIB_2_8_DEFINE="#define GST_HAVE_GLIB_2_8 1"
 370 else
 371   AC_MSG_RESULT(no)
 372   GST_HAVE_GLIB_2_8_DEFINE="/* #undef GST_HAVE_GLIB_2_8 */"
 373 fi
 374 AC_SUBST(GST_HAVE_GLIB_2_8_DEFINE)
 375
 376 dnl Check for glib2 without extra fat, useful for the unversioned tool frontends
 377 PKG_CHECK_MODULES(GLIB_ONLY, glib-2.0 >= $GLIB_REQ)
 378
 379 dnl libxml 2, which is/should be optional (FIXME)
 380 if test "x$GST_DISABLE_LOADSAVE" = "xyes" && \
 381    test "x$GST_DISABLE_REGISTRY" = "xyes"
 382 then
 383   AC_MSG_NOTICE([Registry and load/save are disabled, not checking for libxml2])
 384 else
 385   dnl check for libxml2 with minimum req version
 386   GST_LIBXML2_CHECK(2.4.9)
 387 fi
 388
 389 dnl check for "check", unit testing library/header
 390 AM_PATH_CHECK(0.9.2,
 391     [
 392         HAVE_CHECK=yes
 393         AC_MSG_NOTICE(CHECK_CFLAGS: $CHECK_CFLAGS)
 394         AC_MSG_NOTICE(CHECK_LIBS: $CHECK_LIBS)
 395     ],
 396     HAVE_CHECK=no)
 397 AM_CONDITIONAL(HAVE_CHECK, test "x$HAVE_CHECK" = "xyes")
 398
 399 dnl *** set variables based on configure arguments
 400
 401 dnl set license and copyright notice
 402 GST_LICENSE="LGPL"
 403 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 404 AC_SUBST(GST_LICENSE)
 405
 406 dnl define LIBDIR so we can inform people where we live
 407 AS_AC_EXPAND(LIBDIR, $libdir)
 408 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [library dir])
 409
 410 dnl set location of plugin directory
 411 GST_SET_PLUGINDIR
 412
 413 dnl FIXME: add LIBXML_PKG here
 414 GST_PKG_DEPS="glib-2.0, gobject-2.0, gmodule-2.0, gthread-2.0"
 415 AC_SUBST(GST_PKG_DEPS)
 416
 417 dnl define an ERROR_CFLAGS Makefile variable
 418 GST_SET_ERROR_CFLAGS($GST_CVS)
 419
 420 dnl define correct level for debugging messages
 421 GST_SET_LEVEL_DEFAULT($GST_CVS)
 422
 423 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 424
 425 dnl Overview:
 426 dnl GST_OPTION_CFLAGS:  common cflags for profiling, debugging, errors, ...
 427 dnl GST_ALL_*:          vars shared by all built objects
 428 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 429 dnl GST_OBJ_*:          additional vars to link to the core library
 430 dnl                     include GST_ALL_*
 431 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 432 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 433
 434 dnl GST_OPTION_CFLAGS
 435 if test "x$USE_DEBUG" = xyes; then
 436    PROFILE_CFLAGS="-g"
 437 fi
 438 AC_SUBST(PROFILE_CFLAGS)
 439
 440 DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 441 AC_SUBST(DEPRECATED_CFLAGS)
 442
 443 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 444 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 445 AC_SUBST(GST_OPTION_CFLAGS)
 446
 447 dnl GST_ALL_*
 448 dnl vars common to for all internal objects (core libs, elements, applications)
 449 dnl CFLAGS:
 450 dnl - XML needs to be added because xmlPtr is used in core
 451 dnl - src and build dirs need to be added because every piece that gets built
 452 dnl   will need the GStreamer source and generated headers
 453 dnl LIBS: XML doesn't need to be added because we don't explicitly use symbols
 454 dnl       from LibXML except for in the core library
 455 GST_ALL_CFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir) $GLIB_CFLAGS $XML_CFLAGS \$(GST_OPTION_CFLAGS)"
 456 dnl FIXME: check if LTLIBINTL is needed everywhere
 457 dnl I presume it is given that it contains the symbols that _() stuff maps to
 458 GST_ALL_LIBS="$GLIB_LIBS $LTLIBINTL"
 459 dnl LDFLAGS really should only contain flags, not libs - they get added before
 460 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 461 GST_ALL_LDFLAGS="-no-undefined"
 462
 463 AC_SUBST(GST_ALL_CFLAGS)
 464 AC_SUBST(GST_ALL_LIBS)
 465 AC_SUBST(GST_ALL_LDFLAGS)
 466
 467 dnl GST_LIB_LDFLAGS
 468 dnl linker flags shared by all libraries
 469 dnl LDFLAGS modifier defining exported symbols from built libraries
 470 GST_LIB_LDFLAGS="-export-symbols-regex [_]*\(gst_\|Gst\|GST_\).*"
 471 AC_SUBST(GST_LIB_LDFLAGS)
 472
 473 dnl GST_OBJ_*
 474 dnl default vars for all internal objects built on libgstreamer
 475 dnl includes GST_ALL_*
 476 GST_OBJ_CFLAGS="\$(GST_ALL_CFLAGS)"
 477 GST_OBJ_LIBS="\$(top_builddir)/gst/libgstreamer-$GST_MAJORMINOR.la \$(GST_ALL_LIBS)"
 478 AC_SUBST(GST_OBJ_CFLAGS)
 479 AC_SUBST(GST_OBJ_LIBS)
 480
 481 dnl GST_PLUGIN_LDFLAGS
 482 dnl LDFLAGS for plugins; includes GST_ALL_LDFLAGS
 483 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 484 AC_SUBST(GST_PLUGIN_LDFLAGS, "$GST_PLUGIN_LDFLAGS")
 485
 486 AC_CONFIG_FILES(
 487 Makefile
 488 gst/Makefile
 489 gst/gstconfig.h
 490 gst/gstversion.h
 491 gst/parse/Makefile
 492 libs/Makefile
 493 libs/gst/Makefile
 494 libs/gst/base/Makefile
 495 libs/gst/check/Makefile
 496 libs/gst/controller/Makefile
 497 libs/gst/dataprotocol/Makefile
 498 libs/gst/net/Makefile
 499 plugins/Makefile
 500 plugins/indexers/Makefile
 501 plugins/elements/Makefile
 502 po/Makefile.in
 503 tests/Makefile
 504 tests/benchmarks/Makefile
 505 tests/check/Makefile
 506 tests/misc/Makefile
 507 tests/examples/Makefile
 508 tests/examples/controller/Makefile
 509 tests/examples/helloworld/Makefile
 510 tests/examples/launch/Makefile
 511 tests/examples/metadata/Makefile
 512 tests/examples/queue/Makefile
 513 tests/examples/typefind/Makefile
 514 tests/examples/xml/Makefile
 515 tools/Makefile
 516 common/Makefile
 517 common/m4/Makefile
 518 docs/Makefile
 519 docs/design/Makefile
 520 docs/faq/Makefile
 521 docs/gst/Makefile
 522 docs/gst/gstreamer.types
 523 docs/libs/Makefile
 524 docs/plugins/Makefile
 525 docs/manual/Makefile
 526 docs/pwg/Makefile
 527 docs/slides/Makefile
 528 docs/xsl/Makefile
 529 docs/version.entities
 530 win32/common/config.h
 531 pkgconfig/Makefile
 532 stamp.h
 533 pkgconfig/gstreamer.pc
 534 pkgconfig/gstreamer-uninstalled.pc
 535 pkgconfig/gstreamer-base.pc
 536 pkgconfig/gstreamer-base-uninstalled.pc
 537 pkgconfig/gstreamer-check.pc
 538 pkgconfig/gstreamer-check-uninstalled.pc
 539 pkgconfig/gstreamer-controller.pc
 540 pkgconfig/gstreamer-controller-uninstalled.pc
 541 pkgconfig/gstreamer-dataprotocol.pc
 542 pkgconfig/gstreamer-dataprotocol-uninstalled.pc
 543 pkgconfig/gstreamer-net.pc
 544 pkgconfig/gstreamer-net-uninstalled.pc
 545 gstreamer.spec
 546 )
 547
 548 AC_OUTPUT