configure.ac

   1 AC_PREREQ(2.60)
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, git and prerelease does Werror too
   6 AC_INIT(GStreamer, 0.10.35.1,
   7     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
   8     gstreamer)
   9 AG_GST_INIT
  10
  11 dnl initialize automake (we require GNU make)
  12 AM_INIT_AUTOMAKE([-Wno-portability 1.10])
  13
  14 dnl define PACKAGE_VERSION_* variables
  15 AS_VERSION
  16
  17 dnl check if this is a release version
  18 AS_NANO(GST_GIT="no", GST_GIT="yes")
  19
  20 dnl can autoconf find the source ?
  21 AC_CONFIG_SRCDIR([gst/gst.c])
  22
  23 dnl define the output header for config
  24 AM_CONFIG_HEADER([config.h])
  25
  26 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  27 AM_MAINTAINER_MODE
  28
  29 dnl sets host_* variables
  30 AC_CANONICAL_HOST
  31
  32 dnl use pretty build output with automake >= 1.11
  33 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  34   [AM_DEFAULT_VERBOSITY=1
  35    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  36
  37 dnl our libraries and install dirs use major.minor as a version
  38 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  39 dnl we override it here for release candidates for a new series
  40 GST_MAJORMINOR=0.10
  41 AC_SUBST(GST_MAJORMINOR)
  42 AC_DEFINE_UNQUOTED(GST_MAJORMINOR, "$GST_MAJORMINOR",
  43   [library major.minor version])
  44
  45 dnl CURRENT, REVISION, AGE
  46 dnl - library source changed -> increment REVISION
  47 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  48 dnl - interfaces added -> increment AGE
  49 dnl - interfaces removed -> AGE = 0
  50 dnl sets GST_LT_LDFLAGS
  51 AS_LIBTOOL(GST, 29, 0, 29)
  52
  53 dnl FIXME: this macro doesn't actually work;
  54 dnl the generated libtool script has no support for the listed tags.
  55 dnl So this needs to be fixed first if we want to use this
  56 dnl AS_LIBTOOL_TAGS
  57
  58 AC_LIBTOOL_WIN32_DLL
  59 AM_PROG_LIBTOOL
  60
  61 dnl *** autotools stuff ****
  62
  63 dnl allow for different autotools
  64 AS_AUTOTOOLS_ALTERNATE
  65
  66 dnl Add parameters for aclocal (keep in sync with Makefile.am)
  67 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  68
  69 dnl set up gettext
  70 dnl the version check needs to stay here because autopoint greps for it
  71 AM_GNU_GETTEXT_VERSION([0.17])
  72 AM_GNU_GETTEXT([external])
  73 AG_GST_GETTEXT([gstreamer-$GST_MAJORMINOR])
  74
  75 dnl *** check for arguments to configure ***
  76
  77 dnl subsystems - can influence other decisions so needs to be high up
  78 dnl we need to AM_CONDITIONAL them here for automake 1.6.x compatibility
  79 AG_GST_CHECK_SUBSYSTEM_DISABLE(GST_DEBUG,[debugging subsystem])
  80 AM_CONDITIONAL(GST_DISABLE_GST_DEBUG, test "x$GST_DISABLE_GST_DEBUG" = "xyes")
  81 AG_GST_CHECK_SUBSYSTEM_DISABLE(LOADSAVE,[pipeline XML load/save])
  82 AM_CONDITIONAL(GST_DISABLE_LOADSAVE, test "x$GST_DISABLE_LOADSAVE" = "xyes")
  83 dnl define a substitution to use in docs/gst/gstreamer.types
  84 if test "x$GST_DISABLE_LOADSAVE" = "xyes"
  85 then
  86   GST_LOADSAVE_DOC_TYPES="%"
  87 else
  88   GST_LOADSAVE_DOC_TYPES=
  89 fi
  90 AC_SUBST(GST_LOADSAVE_DOC_TYPES)
  91 AG_GST_CHECK_SUBSYSTEM_DISABLE(PARSE,[command-line parser])
  92 AM_CONDITIONAL(GST_DISABLE_PARSE, test "x$GST_DISABLE_PARSE" = "xyes")
  93 if test "x$GST_DISABLE_PARSE" = xyes; then
  94   AC_DEFINE(GST_DISABLE_PARSE, 1,
  95     [Define if pipeline parsing code is disabled])
  96 fi
  97 AG_GST_CHECK_SUBSYSTEM_DISABLE(OPTION_PARSING,[option parsing when gst_init])
  98 AM_CONDITIONAL(GST_DISABLE_OPTION_PARSING, test "x$GST_DISABLE_OPTION_PARSING" = "xyes")
  99 if test "x$GST_DISABLE_OPTION_PARSING" = xyes; then
 100   AC_DEFINE(GST_DISABLE_OPTION_PARSING, 1,
 101     [Define if option parsing is disabled])
 102 fi
 103 AG_GST_CHECK_SUBSYSTEM_DISABLE(TRACE,[tracing subsystem])
 104 AM_CONDITIONAL(GST_DISABLE_TRACE, test "x$GST_DISABLE_TRACE" = "xyes")
 105 AG_GST_CHECK_SUBSYSTEM_DISABLE(ALLOC_TRACE,[allocation tracing])
 106 AM_CONDITIONAL(GST_DISABLE_ALLOC_TRACE, test "x$GST_DISABLE_ALLOC_TRACE" = "xyes")
 107 AG_GST_CHECK_SUBSYSTEM_DISABLE(REGISTRY,[plugin registry])
 108 AM_CONDITIONAL(GST_DISABLE_REGISTRY, test "x$GST_DISABLE_REGISTRY" = "xyes")
 109 dnl define a substitution to use in docs/gst/gstreamer.types
 110 if test "x$GST_DISABLE_REGISTRY" = "xyes"
 111 then
 112   GST_REGISTRY_DOC_TYPES="%"
 113 else
 114   GST_REGISTRY_DOC_TYPES=
 115 fi
 116 AC_SUBST(GST_REGISTRY_DOC_TYPES)
 117 AG_GST_CHECK_SUBSYSTEM_DISABLE(NET,[network distribution])
 118 AM_CONDITIONAL(GST_DISABLE_NET, test "x$GST_DISABLE_NET" = "xyes")
 119 AG_GST_CHECK_SUBSYSTEM_DISABLE(PLUGIN,[plugin])
 120 AM_CONDITIONAL(GST_DISABLE_PLUGIN, test "x$GST_DISABLE_PLUGIN" = "xyes")
 121
 122 AG_GST_ARG_DEBUG
 123 AG_GST_ARG_PROFILING
 124 AG_GST_ARG_VALGRIND
 125 AG_GST_ARG_GCOV
 126
 127 AG_GST_ARG_EXAMPLES
 128
 129 AG_GST_ARG_WITH_PKG_CONFIG_PATH
 130 AG_GST_ARG_WITH_PACKAGE_NAME
 131 AG_GST_ARG_WITH_PACKAGE_ORIGIN
 132
 133 AG_GST_PKG_CONFIG_PATH
 134
 135 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 136   ["${srcdir}/gstreamer.doap"],
 137   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 138
 139 dnl building of tests
 140 AC_ARG_ENABLE(tests,
 141   AC_HELP_STRING([--disable-tests], [disable building test apps]),
 142   [
 143     case "${enableval}" in
 144       yes) BUILD_TESTS=yes ;;
 145       no)  BUILD_TESTS=no ;;
 146       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 147     esac
 148   ],
 149 [BUILD_TESTS=yes]) dnl Default value
 150 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 151
 152 dnl tests known to fail
 153 AC_ARG_ENABLE(failing-tests,
 154   AC_HELP_STRING([--disable-failing-tests],
 155     [disable building tests known to fail]),
 156   [
 157     case "${enableval}" in
 158       yes) BUILD_FAILING_TESTS=yes ;;
 159       no)  BUILD_FAILING_TESTS=no ;;
 160       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-failing-tests) ;;
 161     esac
 162   ],
 163   [BUILD_FAILING_TESTS=no]) dnl Default value
 164 AM_CONDITIONAL(BUILD_FAILING_TESTS, test "x$BUILD_FAILING_TESTS" = "xyes")
 165 if test x$BUILD_FAILING_TESTS = xyes; then
 166   AC_MSG_WARN([building tests known to fail, use --disable-failing-tests to disable])
 167 else
 168   AC_MSG_WARN([Sissy ! By asking to not build the tests known to fail, you hereby waive your right to customer support.  If you do not agree with this EULA, please press Ctrl-C before the next line is printed.  By allowing the next line to be printed, you expressly acknowledge your acceptance of this EULA.])
 169 fi
 170
 171 dnl poison destroyed objects
 172 AC_ARG_ENABLE(poisoning,
 173   AC_HELP_STRING([--enable-poisoning],
 174     [enable poisoning of deallocated objects]),
 175   [
 176     case "${enableval}" in
 177       yes) USE_POISONING=yes ;;
 178       no)  USE_POISONING=no ;;
 179       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-poisoning) ;;
 180     esac
 181   ],
 182   [USE_POISONING=no]) dnl Default value
 183 if test "x$USE_POISONING" = xyes; then
 184   AC_DEFINE(USE_POISONING, 1,
 185     [Define if we should poison deallocated memory])
 186 fi
 187
 188 dnl *** checks for platform ***
 189
 190 dnl * hardware/architecture *
 191
 192 dnl common/m4/gst-arch.m4
 193 dnl check CPU type
 194 AG_GST_ARCH
 195 dnl substitution for win32/common/config.h
 196 HOST_CPU=$host_cpu
 197 AC_SUBST(HOST_CPU)
 198
 199 dnl common/m4/gst-arch.m4
 200 dnl check for unaligned access
 201 AG_GST_UNALIGNED_ACCESS
 202 dnl create a configure variable for gst/gstconfig.h
 203 if test x${as_cv_unaligned_access} = xyes ; then
 204   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 1"
 205 else
 206   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 0"
 207 fi
 208 AC_SUBST(GST_HAVE_UNALIGNED_ACCESS_DEFINE)
 209
 210 dnl check for platform specific settings
 211 AG_GST_PLATFORM
 212
 213 dnl * software *
 214
 215 dnl check for large file support
 216 dnl affected plugins must include config.h
 217 AC_SYS_LARGEFILE
 218
 219 dnl *** checks for programs ***
 220
 221 dnl find a compiler
 222 AC_PROG_CC
 223 AC_PROG_CC_STDC
 224
 225 dnl check if the compiler supports '-c' and '-o' options
 226 AM_PROG_CC_C_O
 227
 228 dnl find an assembler
 229 AM_PROG_AS
 230
 231 dnl determine if c++ is available on this system
 232 AC_PROG_CXX
 233 dnl CXX may be set to some default even if no c++ compiler is available
 234 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 235 AC_LANG_PUSH([C++])
 236 AC_TRY_COMPILE([ class Foo { int bar; };], , working_cxx=yes, working_cxx=no)
 237 AC_LANG_POP([C++])
 238 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 239 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 240
 241 dnl Perl is used in building documentation and in the version checks
 242 AC_PATH_PROG(PERL_PATH, perl, no)
 243 if test x$PERL_PATH = xno; then
 244   AC_MSG_ERROR(Could not find perl)
 245 fi
 246
 247 dnl we require flex and bison for building the parser
 248 if test "x$GST_DISABLE_PARSE" != xyes; then
 249   AG_GST_BISON_CHECK
 250   AG_GST_FLEX_CHECK
 251 fi
 252
 253 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 254 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 255
 256 dnl check for gobject-introspection
 257 GOBJECT_INTROSPECTION_CHECK([0.6.8])
 258
 259 dnl check for documentation tools
 260 AG_GST_DOCBOOK_CHECK
 261 GTK_DOC_CHECK([1.3])
 262 AS_PATH_PYTHON([2.1])
 263 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 264
 265 dnl *** checks for libraries ***
 266
 267 dnl check for libm, for sin()
 268 AC_CHECK_LIBM
 269 AC_SUBST(LIBM)
 270
 271 dnl *** checks for header files ***
 272
 273 dnl check if we have ANSI C header files
 274 AC_HEADER_STDC
 275
 276 dnl Check for ucontext.h
 277 AC_CHECK_HEADERS([ucontext.h])
 278
 279 dnl Check for sys/socket.h
 280 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 281 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 282
 283 dnl check for sys/times.h for tests/examples/adapter/
 284 AC_CHECK_HEADERS([sys/times.h], HAVE_SYS_TIMES_H=yes)
 285 AC_CHECK_HEADERS([unistd.h], HAVE_UNISTD_H=yes)
 286 AM_CONDITIONAL(HAVE_SYS_TIMES_H_AND_UNISTD_H, test "x$HAVE_SYS_TIMES_H" = "xyes" -a "x$HAVE_UNISTD_H" = "xyes")
 287
 288 dnl Check for process.h for getpid() on win32
 289 AC_CHECK_HEADERS([process.h])
 290
 291 dnl Check for sys/utsname.h for uname
 292 AC_CHECK_HEADERS([sys/utsname.h])
 293
 294 dnl Check for stdio_ext.f for __fbufsize
 295 AC_CHECK_HEADERS([stdio_ext.h])
 296
 297 dnl check for pthreads
 298 AC_CHECK_HEADERS([pthread.h], HAVE_PTHREAD_H=yes)
 299 AM_CONDITIONAL(HAVE_PTHREAD_H, test "x$HAVE_PTHREAD_H" = "xyes")
 300
 301 dnl check for sys/prctl for setting thread name on Linux
 302 AC_CHECK_HEADERS([sys/prctl.h], HAVE_SYS_PRCTL_H=yes)
 303
 304 dnl Check for valgrind.h
 305 dnl separate from HAVE_VALGRIND because you can have the program, but not
 306 dnl the dev package
 307 AC_CHECK_HEADERS([valgrind/valgrind.h], HAVE_VALGRIND_H=yes)
 308
 309 dnl used in gst/gstpoll.c
 310 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 311 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 312 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 313   WIN32_LIBS="-lws2_32"
 314   AC_SUBST(WIN32_LIBS)
 315 fi
 316
 317 dnl check for GMP/GSL, used by the gst_util_uint64_scale unit test only
 318 if test "x$BUILD_TESTS" = "xyes"; then
 319   AG_GST_CHECK_LIBHEADER(GMP, gmp,
 320                          __gmpz_init_set_d, ,
 321                          gmp.h,
 322                          GMP_LIBS="-lgmp"
 323                          AC_SUBST(GMP_LIBS)
 324                          AC_DEFINE(HAVE_GMP, [1],[Have GMP library]))
 325   AG_GST_CHECK_LIBHEADER(GSL, gsl,
 326                          gsl_rng_uniform_int, -lgslcblas,
 327                          gsl/gsl_rng.h,
 328                          GSL_LIBS="-lgsl -lgslcblas"
 329                          AC_SUBST(GSL_LIBS)
 330                          AC_DEFINE(HAVE_GSL, [1],[Have GSL library]))
 331 fi
 332
 333 dnl *** checks for types/defines ***
 334
 335 dnl *** checks for structures ***
 336
 337 dnl *** checks for compiler characteristics ***
 338
 339 dnl check if the compiler supports __uint128_t (gcc)
 340 dnl Actually check for 128-bit division, since that's what we use
 341 dnl uint128_t for.
 342 AC_CACHE_CHECK(for __uint128_t, gst_cv_uint128_t,
 343     AC_TRY_LINK([ ], [
 344       static __uint128_t v1 = 100;
 345       static __uint128_t v2 = 10;
 346       static __uint128_t u;
 347       u = v1 / v2;
 348     ], [
 349       gst_cv_uint128_t=yes
 350     ], [
 351       gst_cv_uint128_t=no
 352     ])
 353 )
 354 if test x$gst_cv_uint128_t = xyes; then
 355   AC_DEFINE(HAVE_UINT128_T, 1, [Have __uint128_t type])
 356 fi
 357
 358 dnl *** checking for tm_gmtoff ***
 359 AC_MSG_CHECKING([for tm_gmtoff])
 360 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 361         #include <time.h>
 362         int main(void) {
 363           struct tm t;
 364           t.tm_gmtoff = 0;
 365           exit(0);
 366         }]])],
 367   [have_tm_gmtoff=yes
 368    AC_DEFINE(HAVE_TM_GMTOFF,1,[Have tm_gmtoff field in struct tm])],
 369   [have_tm_gmtoff=no],
 370   [have_tm_gmtoff="no (cross compiling)"])
 371 AC_MSG_RESULT($have_tm_gmtoff)
 372
 373
 374 dnl *** checks for library functions ***
 375
 376 AC_CHECK_FUNCS([gmtime_r])
 377 AC_CHECK_FUNCS([localtime_r])
 378 AC_CHECK_FUNCS([sigaction])
 379
 380 dnl check for fseeko()
 381 AC_FUNC_FSEEKO
 382 dnl check for ftello()
 383 AC_CHECK_FUNCS([ftello])
 384
 385 AC_CHECK_FUNCS([fgetpos])
 386 AC_CHECK_FUNCS([fsetpos])
 387
 388 dnl check for poll(), ppoll() and pselect()
 389 AC_CHECK_FUNCS([poll])
 390 AC_CHECK_FUNCS([ppoll])
 391 AC_CHECK_FUNCS([pselect])
 392
 393 dnl ****************************************
 394 dnl *** GLib POLL* compatibility defines ***
 395 dnl ****************************************
 396
 397 AC_MSG_CHECKING([for broken poll])
 398 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 399         #include <stdlib.h>
 400         #include <fcntl.h>
 401         #include <poll.h>
 402         #ifdef HAVE_SYS_POLL_H
 403         #include <sys/poll.h>
 404         #endif
 405         int main(void) {
 406           struct pollfd fds[1];
 407           int fd;
 408           fd = open("/dev/null", 1);
 409           fds[0].fd = fd;
 410           fds[0].events = POLLIN;
 411           fds[0].revents = 0;
 412           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
 413                 exit(1);  /* Does not work for devices -- fail */
 414           }
 415           exit(0);
 416         }]])],
 417   [broken_poll=no],
 418   [broken_poll=yes
 419    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
 420   [broken_poll="no (cross compiling)"])
 421 AC_MSG_RESULT($broken_poll)
 422
 423 dnl check for mmap()
 424 AC_FUNC_MMAP
 425 AM_CONDITIONAL(HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 426
 427 dnl check for posix_memalign(), getpagesize()
 428 AC_CHECK_FUNCS([posix_memalign])
 429 AC_CHECK_FUNCS([getpagesize])
 430
 431 dnl Check for POSIX timers
 432 AC_CHECK_FUNCS(clock_gettime, [], [
 433   AC_CHECK_LIB(rt, clock_gettime, [
 434     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 435     LIBS="$LIBS -lrt"
 436   ])
 437 ])
 438
 439 AC_CACHE_CHECK(for posix timers, gst_cv_posix_timers,
 440     AC_TRY_COMPILE([
 441 #include <time.h>
 442 #ifdef HAVE_UNISTD_H
 443 #include <unistd.h>
 444 #endif
 445     ], [
 446 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 447 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 448 #endif
 449     ], [
 450       gst_cv_posix_timers=yes
 451     ], [
 452       gst_cv_posix_timers=no
 453     ])
 454 )
 455
 456 if test "$gst_cv_posix_timers" = "yes"; then
 457   AC_DEFINE(HAVE_POSIX_TIMERS,1,[Have posix timers])
 458   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 1"
 459 else
 460   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 0"
 461 fi
 462 AC_SUBST(GST_HAVE_POSIX_TIMERS_DEFINE)
 463 AM_CONDITIONAL(GST_HAVE_POSIX_TIMERS, test "$gst_cv_posix_timers" = "yes")
 464
 465 AC_CACHE_CHECK(for monotonic clock, gst_cv_monotonic_clock,
 466     AC_TRY_COMPILE([
 467 #include <time.h>
 468 #ifdef HAVE_UNISTD_H
 469 #include <unistd.h>
 470 #endif
 471     ], [
 472 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 473 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 474 #endif
 475     ], [
 476       gst_cv_monotonic_clock=yes
 477     ], [
 478       gst_cv_monotonic_clock=no
 479     ])
 480 )
 481
 482 if test "$gst_cv_monotonic_clock" = "yes"; then
 483   AC_DEFINE(HAVE_MONOTONIC_CLOCK,1,[Have a monotonic clock])
 484   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 1"
 485 else
 486   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 0"
 487 fi
 488 AC_SUBST(GST_HAVE_MONOTONIC_CLOCK_DEFINE)
 489 AM_CONDITIONAL(GST_HAVE_MONOTONIC_CLOCK, test "$gst_cv_monotonic_clock" = "yes")
 490
 491 dnl Check for a way to display the function name in debug output
 492 AG_GST_CHECK_FUNCTION
 493
 494 dnl test for register_printf_specifier or register_printf_function
 495 AC_CHECK_FUNCS([register_printf_specifier register_printf_function],
 496     [HAVE_PRINTF_EXTENSION=yes])
 497
 498 if test "$HAVE_PRINTF_EXTENSION" = yes; then
 499   GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE="#define GST_PTR_FORMAT \"P\""
 500   GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE="#define GST_SEGMENT_FORMAT \"Q\""
 501   GST_USING_PRINTF_EXTENSION_DEFINE="#define GST_USING_PRINTF_EXTENSION"
 502   AC_DEFINE(HAVE_PRINTF_EXTENSION, 1,
 503       [Defined if we have printf specifier extensions available])
 504 else
 505     GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE="#define GST_PTR_FORMAT \"p\""
 506     GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE="#define GST_SEGMENT_FORMAT \"p\""
 507     GST_USING_PRINTF_EXTENSION_DEFINE="#undef GST_USING_PRINTF_EXTENSION"
 508 fi
 509 AC_SUBST(GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE)
 510 AC_SUBST(GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE)
 511 AC_SUBST(GST_USING_PRINTF_EXTENSION_DEFINE)
 512
 513 dnl test if we have dladdr(); we use it for debugging; see gst/gstinfo.c
 514 save_cflags="$CFLAGS"
 515 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 516 AC_CHECK_LIB(dl, dladdr,
 517    AC_DEFINE(HAVE_DLADDR, 1, [Defined if we have dladdr ()])
 518    LIBS="$LIBS -ldl")
 519 CFLAGS="$save_cflags"
 520
 521 dnl *** checks for socket and nsl libraries ***
 522 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 523 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
 524
 525 dnl check for inet_aton()
 526 save_libs="$LIBS"
 527 AC_CHECK_FUNC(inet_aton, ,
 528    AC_CHECK_LIB(nsl, inet_aton, ,
 529       AC_CHECK_LIB(socket, inet_aton, ,
 530          AC_CHECK_LIB(resolv, inet_aton, ,[AC_DEFINE(NO_INET_ATON, 1, [Define if you have no native inet_aton() function.])]))))
 531 INET_ATON_LIBS=$LIBS
 532 AC_SUBST(INET_ATON_LIBS)
 533 LIBS="$save_libs"
 534
 535 dnl *** checks for dependency libraries ***
 536
 537 dnl GLib
 538 GLIB_REQ=2.24
 539
 540 AG_GST_GLIB_CHECK([$GLIB_REQ])
 541
 542 dnl FIXME: 0.11: Guess we need to keep this around until 0.11
 543 GST_HAVE_GLIB_2_8_DEFINE="#define GST_HAVE_GLIB_2_8 1"
 544 AC_SUBST(GST_HAVE_GLIB_2_8_DEFINE)
 545
 546 dnl Check for glib2 without extra fat, useful for the unversioned tool frontends
 547 PKG_CHECK_MODULES(GLIB_ONLY, glib-2.0 >= $GLIB_REQ)
 548
 549 dnl Check for documentation xrefs
 550 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 551 AC_SUBST(GLIB_PREFIX)
 552
 553 dnl libxml2 is only needed for xml loading/saving of pipelines these days
 554 if test "x$GST_DISABLE_LOADSAVE" = "xyes"
 555 then
 556   AC_MSG_NOTICE([XML registry and load/save are disabled, not checking for libxml2])
 557   GST_DISABLE_XML_DEFINE="#define GST_DISABLE_XML 1"
 558 else
 559   dnl check for libxml2 with minimum req version
 560   AG_GST_LIBXML2_CHECK(2.4.9)
 561   GST_DISABLE_XML_DEFINE="/* #undef GST_DISABLE_XML */"
 562 fi
 563 AC_SUBST(GST_DISABLE_XML_DEFINE)
 564
 565 dnl building of unit test libraries
 566 AC_ARG_ENABLE(check,
 567   AC_HELP_STRING([--disable-check], [disable building unit test libraries]),
 568   [
 569     case "${enableval}" in
 570       yes) BUILD_CHECK=yes ;;
 571       no)  BUILD_CHECK=no ;;
 572       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-check) ;;
 573     esac
 574   ], [
 575     dnl Default value
 576     case $host_os in
 577       mingw* | msvc* | mks*) BUILD_CHECK=no ;;
 578       *) BUILD_CHECK=yes ;;
 579     esac
 580 ])
 581 dnl bit of a misnomer, but keep the conditional named like this so we don't
 582 dnl have to change too much elsewhere
 583 AM_CONDITIONAL(HAVE_CHECK, test "x$BUILD_CHECK" = "xyes")
 584
 585 dnl configure the desired buffer alignment
 586 AC_ARG_WITH([buffer-alignment],
 587   AS_HELP_STRING([--with-buffer-alignment],[8,N,malloc,pagesize (default is 32)]),
 588   [
 589     if test "x$withval" = "xyes"
 590     then
 591       AC_DEFINE(BUFFER_ALIGNMENT, 32, [Buffer alignment to use])
 592     else
 593       case "${withval}" in
 594         malloc) AC_DEFINE(BUFFER_ALIGNMENT_MALLOC, 1, [Buffer alignment by malloc default]) ;;
 595         pagesize)  AC_DEFINE(BUFFER_ALIGNMENT_PAGESIZE, 1, [Buffer alignment by pagesize]) ;;
 596         *)   AC_DEFINE_UNQUOTED(BUFFER_ALIGNMENT, ${withval}, [Buffer alignment to use]) ;;
 597       esac
 598     fi
 599   ], [
 600     AC_DEFINE(BUFFER_ALIGNMENT_MALLOC, 1, [Buffer alignment by malloc default])
 601   ]
 602 )
 603
 604 dnl Check for -Bsymbolic-functions linker flag used to avoid
 605 dnl intra-library PLT jumps, if available.
 606 AC_ARG_ENABLE(Bsymbolic,
 607               [AC_HELP_STRING([--disable-Bsymbolic],
 608                               [avoid linking with -Bsymbolic])],,
 609               [SAVED_LDFLAGS="${LDFLAGS}"
 610                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 611                LDFLAGS=-Wl,-Bsymbolic-functions
 612                AC_TRY_LINK([], [int main (void) { return 0; }],
 613                            AC_MSG_RESULT(yes)
 614                            enable_Bsymbolic=yes,
 615                            AC_MSG_RESULT(no)
 616                            enable_Bsymbolic=no)
 617                LDFLAGS="${SAVED_LDFLAGS}"])
 618
 619
 620 dnl *** set variables based on configure arguments
 621
 622 dnl set license and copyright notice
 623 GST_LICENSE="LGPL"
 624 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 625 AC_SUBST(GST_LICENSE)
 626
 627 dnl define LIBDIR, GST_DATADIR so we can inform people where we live
 628 AS_AC_EXPAND(LIBDIR, $libdir)
 629 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [library dir])
 630 AS_AC_EXPAND(DATADIR, $datadir)
 631 AC_DEFINE_UNQUOTED(GST_DATADIR, "$DATADIR", [data dir])
 632
 633 dnl set location of plugin directory
 634 AG_GST_SET_PLUGINDIR
 635
 636 dnl FIXME: add LIBXML_PKG here if we use it
 637 GST_PKG_DEPS="glib-2.0, gobject-2.0, gmodule-no-export-2.0, gthread-2.0"
 638 AC_SUBST(GST_PKG_DEPS)
 639
 640 dnl make sure it doesn't complain about unused variables if debugging is disabled
 641 NO_WARNINGS=""
 642 if test "x${GST_DISABLE_GST_DEBUG}" = "xyes"; then
 643   NO_WARNINGS="-Wno-unused"
 644 fi
 645
 646 dnl define an ERROR_CFLAGS Makefile variable
 647 AG_GST_SET_ERROR_CFLAGS($GST_GIT, [-Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef -Wwrite-strings -Wformat-nonliteral -Wformat-security -Wold-style-definition -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return -Wno-multichar -Wnested-externs $NO_WARNINGS])
 648
 649 dnl define correct level for debugging messages
 650 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 651
 652 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 653
 654 dnl Overview:
 655 dnl GST_OPTION_CFLAGS:  common cflags for profiling, debugging, errors, ...
 656 dnl GST_ALL_*:          vars shared by all built objects
 657 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 658 dnl GST_OBJ_*:          additional vars to link to the core library
 659 dnl                     include GST_ALL_*
 660 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 661 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 662
 663 dnl GST_OPTION_CFLAGS
 664 if test "x$USE_DEBUG" = xyes; then
 665    PROFILE_CFLAGS="-g"
 666 fi
 667 AC_SUBST(PROFILE_CFLAGS)
 668
 669 # GST_DISABLE_DEPRECATED: hide the visibility of deprecated
 670 # functionality from the API that gstreamer uses
 671 # GST_REMOVE_DEPRECATED: don't compile deprecated functionality (breaks ABI)
 672 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 673   dnl Define _only_ when compiling from git (not for pre-releases or releases)
 674   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 675 else
 676   DEPRECATED_CFLAGS=""
 677 fi
 678 AC_SUBST(DEPRECATED_CFLAGS)
 679
 680 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time via e.g.
 681 dnl make DEPRECATED_CFLAGS=''
 682 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 683 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 684 AC_SUBST(GST_OPTION_CFLAGS)
 685 AC_SUBST(GST_OPTION_CXXFLAGS)
 686
 687 dnl GST_ALL_*
 688 dnl vars common to for all internal objects (core libs, elements, applications)
 689 dnl CFLAGS:
 690 dnl - XML needs to be added because xmlPtr is used in core
 691 dnl - src and build dirs need to be added because every piece that gets built
 692 dnl   will need the GStreamer source and generated headers
 693 dnl LIBS: XML doesn't need to be added because we don't explicitly use symbols
 694 dnl       from LibXML except for in the core library
 695 GST_ALL_CXXFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir)/libs -I\$(top_builddir) $GLIB_CFLAGS \$(GLIB_EXTRA_CFLAGS) $XML_CFLAGS \$(GST_OPTION_CXXFLAGS) \$(ERROR_CXXFLAGS)"
 696 GST_ALL_CFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir)/libs -I\$(top_builddir) $GLIB_CFLAGS \$(GLIB_EXTRA_CFLAGS) $XML_CFLAGS \$(GST_OPTION_CFLAGS) \$(ERROR_CFLAGS)"
 697
 698 dnl FIXME: check if LTLIBINTL is needed everywhere
 699 dnl I presume it is given that it contains the symbols that _() stuff maps to
 700 GST_ALL_LIBS="$GLIB_LIBS $LTLIBINTL \$(GCOV_LIBS)"
 701
 702 dnl LDFLAGS really should only contain flags, not libs - they get added before
 703 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 704 GST_ALL_LDFLAGS="-no-undefined"
 705 if test "x${enable_Bsymbolic}" = "xyes"; then
 706   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 707 fi
 708
 709 AC_SUBST(GST_ALL_CFLAGS)
 710 AC_SUBST(GST_ALL_CXXFLAGS)
 711 AC_SUBST(GST_ALL_LIBS)
 712 AC_SUBST(GST_ALL_LDFLAGS)
 713
 714 dnl GST_LIB_LDFLAGS
 715 dnl linker flags shared by all libraries
 716 dnl LDFLAGS modifier defining exported symbols from built libraries
 717 GST_LIB_LDFLAGS="-export-symbols-regex \^[_]*\(gst_\|Gst\|GST_\).*"
 718 AC_SUBST(GST_LIB_LDFLAGS)
 719
 720 dnl GST_OBJ_*
 721 dnl default vars for all internal objects built on libgstreamer
 722 dnl includes GST_ALL_*
 723 GST_OBJ_CFLAGS="\$(GST_ALL_CFLAGS)"
 724 GST_OBJ_CXXFLAGS="\$(GST_ALL_CXXFLAGS)"
 725 GST_OBJ_LIBS="\$(top_builddir)/gst/libgstreamer-$GST_MAJORMINOR.la \$(GST_ALL_LIBS)"
 726 AC_SUBST(GST_OBJ_CFLAGS)
 727 AC_SUBST(GST_OBJ_CXXFLAGS)
 728 AC_SUBST(GST_OBJ_LIBS)
 729
 730 dnl GST_PLUGIN_LDFLAGS
 731 dnl LDFLAGS for plugins; includes GST_ALL_LDFLAGS
 732 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
 733 AC_SUBST(GST_PLUGIN_LDFLAGS, "$GST_PLUGIN_LDFLAGS")
 734
 735 dnl plugin scanner locations
 736 AS_AC_EXPAND(GST_PLUGIN_SCANNER_INSTALLED,${libexecdir}/gstreamer-$GST_MAJORMINOR/gst-plugin-scanner)
 737 AC_DEFINE_UNQUOTED(GST_PLUGIN_SCANNER_INSTALLED,
 738     "$GST_PLUGIN_SCANNER_INSTALLED", [location of the installed gst-plugin-scanner])
 739 AC_SUBST(GST_PLUGIN_SCANNER_INSTALLED)
 740
 741 dnl things for our internal libcheck (must be called even if building
 742 dnl libcheck is disabled because it defines conditionals)
 743 AG_GST_CHECK_CHECKS()
 744
 745 AC_CONFIG_FILES(
 746 Makefile
 747 gst/Makefile
 748 gst/gstconfig.h
 749 gst/gstversion.h
 750 gst/parse/Makefile
 751 libs/Makefile
 752 libs/gst/Makefile
 753 libs/gst/base/Makefile
 754 libs/gst/check/Makefile
 755 libs/gst/check/libcheck/Makefile
 756 libs/gst/check/libcheck/check.h
 757 libs/gst/controller/Makefile
 758 libs/gst/dataprotocol/Makefile
 759 libs/gst/helpers/Makefile
 760 libs/gst/net/Makefile
 761 plugins/Makefile
 762 plugins/indexers/Makefile
 763 plugins/elements/Makefile
 764 po/Makefile.in
 765 tests/Makefile
 766 tests/benchmarks/Makefile
 767 tests/check/Makefile
 768 tests/misc/Makefile
 769 tests/examples/Makefile
 770 tests/examples/adapter/Makefile
 771 tests/examples/controller/Makefile
 772 tests/examples/stepping/Makefile
 773 tests/examples/helloworld/Makefile
 774 tests/examples/launch/Makefile
 775 tests/examples/manual/Makefile
 776 tests/examples/metadata/Makefile
 777 tests/examples/queue/Makefile
 778 tests/examples/streams/Makefile
 779 tests/examples/typefind/Makefile
 780 tools/Makefile
 781 common/Makefile
 782 common/m4/Makefile
 783 docs/Makefile
 784 docs/design/Makefile
 785 docs/faq/Makefile
 786 docs/gst/Makefile
 787 docs/gst/gstreamer.types
 788 docs/libs/Makefile
 789 docs/plugins/Makefile
 790 docs/manual/Makefile
 791 docs/pwg/Makefile
 792 docs/slides/Makefile
 793 docs/xsl/Makefile
 794 docs/version.entities
 795 m4/Makefile
 796 pkgconfig/Makefile
 797 stamp.h
 798 pkgconfig/gstreamer.pc
 799 pkgconfig/gstreamer-uninstalled.pc
 800 pkgconfig/gstreamer-base.pc
 801 pkgconfig/gstreamer-base-uninstalled.pc
 802 pkgconfig/gstreamer-check.pc
 803 pkgconfig/gstreamer-check-uninstalled.pc
 804 pkgconfig/gstreamer-controller.pc
 805 pkgconfig/gstreamer-controller-uninstalled.pc
 806 pkgconfig/gstreamer-dataprotocol.pc
 807 pkgconfig/gstreamer-dataprotocol-uninstalled.pc
 808 pkgconfig/gstreamer-net.pc
 809 pkgconfig/gstreamer-net-uninstalled.pc
 810 gst-element-check.m4
 811 gstreamer.spec
 812 )
 813
 814 dnl Create the config.h file for Visual Studio builds
 815 dnl Beware of spaces and /'s in some of the shell variable contents.
 816 sed \
 817     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 818     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 819     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 820     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 821     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 822     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
 823     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 824     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 825     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
 826     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 827     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 828     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 829     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
 830     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 831     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 832     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 833     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 834     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 835     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 836     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
 837     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 838     -e 's/.* BUFFER_ALIGNMENT_MALLOC/#define BUFFER_ALIGNMENT_MALLOC 1/' \
 839     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 840     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 841     -e 's/.* PACKAGE$/#define PACKAGE "gstreamer"/' \
 842     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 843     -e 's/.* PACKAGE_NAME$/#define PACKAGE_NAME "'$PACKAGE_NAME'"/' \
 844     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 845     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 846     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 847     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.10"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.10"\n#endif/' \
 848     -e 's/.* GST_PLUGIN_SCANNER_INSTALLED$/#define GST_PLUGIN_SCANNER_INSTALLED LIBDIR "\\\\gst-plugin-scanner"/' \
 849     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 850     config.h.in >win32/common/config.h-new
 851
 852 AC_OUTPUT
 853
 854 dnl negate for output
 855 if test "x${GST_DISABLE_GST_DEBUG}" = "xno"; then enable_gst_debug="yes"; fi
 856 if test "x${GST_DISABLE_LOADSAVE}" = "xno"; then enable_loadsave="yes"; fi
 857 if test "x${GST_DISABLE_PARSE}" = "xno"; then enable_parse="yes"; fi
 858 if test "x${GST_DISABLE_OPTION_PARSING}" = "xno"; then enable_option_parsing="yes"; fi
 859 if test "x${GST_DISABLE_TRACE}" = "xno"; then enable_trace="yes"; fi
 860 if test "x${GST_DISABLE_ALLOC_TRACE}" = "xno"; then enable_alloc_trace="yes"; fi
 861 if test "x${GST_DISABLE_PLUGIN}" = "xno"; then enable_plugin="yes"; fi
 862 if test "x${GST_DISABLE_REGISTRY}" = "xno"; then enable_registry="yes"; fi
 863 if test "x${GST_DISABLE_NET}" = "xno"; then enable_net="yes"; fi
 864
 865 echo "
 866
 867 Configuration
 868         Version                    : ${VERSION}
 869         Source code location       : ${srcdir}
 870         Prefix                     : ${prefix}
 871         Compiler                   : ${CC}
 872         Package name               : ${GST_PACKAGE_NAME}
 873         Package origin             : ${GST_PACKAGE_ORIGIN}
 874
 875         Documentation (manuals)    : ${enable_docbook}
 876         Documentation (API)        : ${enable_gtk_doc}
 877
 878         Debug Logging              : ${enable_gst_debug}
 879         Pipeline XML load/save     : ${enable_loadsave}
 880         Command-line parser        : ${enable_parse}
 881         Option parsing in gst_init : ${enable_option_parsing}
 882         Tracing subsystem          : ${enable_trace}
 883         Allocation tracing         : ${enable_alloc_trace}
 884         Plugin registry            : ${enable_registry}
 885         Plugin support             : ${enable_plugin}
 886         Network support            : ${enable_net}
 887         Unit testing support       : ${BUILD_CHECK}
 888
 889         Debug                      : ${USE_DEBUG}
 890         Profiling                  : ${USE_PROFILING}
 891
 892         Building examples          : ${BUILD_EXAMPLES}
 893         Building test apps         : ${BUILD_TESTS}
 894         Building tests that fail   : ${BUILD_FAILING_TESTS}
 895 "