configure.ac

   1 AC_PREREQ([2.69])
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, git and prerelease does Werror too
   6 dnl
   7 AC_INIT([GStreamer],[1.11.1.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gstreamer])
   8 AG_GST_INIT
   9
  10 dnl initialize automake (we require GNU make)
  11 AM_INIT_AUTOMAKE([-Wno-portability 1.14 no-dist-gzip dist-xz tar-ustar subdir-objects])
  12
  13 dnl define PACKAGE_VERSION_* variables
  14 AS_VERSION
  15
  16 dnl check if this is a release version
  17 AS_NANO(GST_GIT="no", GST_GIT="yes")
  18
  19 dnl can autoconf find the source ?
  20 AC_CONFIG_SRCDIR([gst/gst.c])
  21
  22 dnl define the output header for config
  23 AC_CONFIG_HEADERS([config.h])
  24
  25 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  26 AM_MAINTAINER_MODE([enable])
  27
  28 dnl sets host_* variables
  29 AC_CANONICAL_HOST
  30
  31 dnl use pretty build output by default
  32 AM_SILENT_RULES([yes])
  33
  34 dnl GStreamer versioning, this is mostly informational
  35 GST_VERSION_MAJOR=$PACKAGE_VERSION_MAJOR
  36 GST_VERSION_MINOR=$PACKAGE_VERSION_MINOR
  37 GST_VERSION_MICRO=$PACKAGE_VERSION_MICRO
  38 GST_VERSION_NANO=$PACKAGE_VERSION_NANO
  39 AC_SUBST(GST_VERSION_MAJOR)
  40 AC_SUBST(GST_VERSION_MINOR)
  41 AC_SUBST(GST_VERSION_MICRO)
  42 AC_SUBST(GST_VERSION_NANO)
  43
  44 dnl our libraries and install dirs use GST_API_VERSION in the filename
  45 dnl to allow side-by-side installation of different API versions
  46 GST_API_VERSION=1.0
  47 AC_SUBST(GST_API_VERSION)
  48 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  49   [GStreamer API Version])
  50
  51 dnl CURRENT, REVISION, AGE
  52 dnl - library source changed -> increment REVISION
  53 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  54 dnl - interfaces added -> increment AGE
  55 dnl - interfaces removed -> AGE = 0
  56 dnl
  57 dnl Keep CURRENT as MINOR * 100 + MICRO
  58 dnl Ex : 1.0.0 => 0
  59 dnl      1.0.3 => 3
  60 dnl      1.1.0 => 100
  61 dnl      1.2.5 => 205
  62 dnl      1.10.9 (who knows) => 1009
  63 dnl
  64 dnl sets GST_LT_LDFLAGS
  65 AS_LIBTOOL(GST, 1101, 0, 1101)
  66
  67 dnl *** autotools stuff ****
  68
  69 dnl allow for different autotools
  70 AS_AUTOTOOLS_ALTERNATE
  71
  72 dnl Add parameters for aclocal (keep in sync with Makefile.am)
  73 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  74
  75 dnl set up gettext
  76 dnl the version check needs to stay here because autopoint greps for it
  77 AM_GNU_GETTEXT_VERSION([0.17])
  78 AM_GNU_GETTEXT([external])
  79 AG_GST_GETTEXT([gstreamer-$GST_API_VERSION])
  80
  81 dnl *** check for arguments to configure ***
  82
  83 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  84 AG_GST_ARG_ENABLE_EXTRA_CHECKS
  85
  86 dnl subsystems - can influence other decisions so needs to be high up
  87 dnl we need to AM_CONDITIONAL them here for automake 1.6.x compatibility
  88 AG_GST_CHECK_SUBSYSTEM_DISABLE(GST_DEBUG,[debugging subsystem])
  89 AM_CONDITIONAL(GST_DISABLE_GST_DEBUG, test "x$GST_DISABLE_GST_DEBUG" = "xyes")
  90 AG_GST_CHECK_SUBSYSTEM_DISABLE(GST_TRACER_HOOKS,[tracing subsystem hooks])
  91 AM_CONDITIONAL(GST_DISABLE_GST_TRACER_HOOKS, test "x$GST_DISABLE_GST_TRACER_HOOKS" = "xyes")
  92 AG_GST_CHECK_SUBSYSTEM_DISABLE(PARSE,[command-line parser])
  93 AM_CONDITIONAL(GST_DISABLE_PARSE, test "x$GST_DISABLE_PARSE" = "xyes")
  94 if test "x$GST_DISABLE_PARSE" = xyes; then
  95   AC_DEFINE(GST_DISABLE_PARSE, 1,
  96     [Define if pipeline parsing code is disabled])
  97 fi
  98 AG_GST_CHECK_SUBSYSTEM_DISABLE(OPTION_PARSING,[option parsing when gst_init])
  99 AM_CONDITIONAL(GST_DISABLE_OPTION_PARSING, test "x$GST_DISABLE_OPTION_PARSING" = "xyes")
 100 if test "x$GST_DISABLE_OPTION_PARSING" = xyes; then
 101   AC_DEFINE(GST_DISABLE_OPTION_PARSING, 1,
 102     [Define if option parsing is disabled])
 103 fi
 104 AG_GST_CHECK_SUBSYSTEM_DISABLE(REGISTRY,[plugin registry])
 105 AM_CONDITIONAL(GST_DISABLE_REGISTRY, test "x$GST_DISABLE_REGISTRY" = "xyes")
 106 dnl define a substitution to use in docs/gst/gstreamer.types
 107 if test "x$GST_DISABLE_REGISTRY" = "xyes"
 108 then
 109   GST_REGISTRY_DOC_TYPES="%"
 110 else
 111   GST_REGISTRY_DOC_TYPES=
 112 fi
 113 AC_SUBST(GST_REGISTRY_DOC_TYPES)
 114 AG_GST_CHECK_SUBSYSTEM_DISABLE(PLUGIN,[plugin])
 115 AM_CONDITIONAL(GST_DISABLE_PLUGIN, test "x$GST_DISABLE_PLUGIN" = "xyes")
 116
 117 AG_GST_ARG_DEBUG
 118 AG_GST_ARG_PROFILING
 119 AG_GST_ARG_VALGRIND
 120 AG_GST_ARG_GCOV
 121
 122 AG_GST_ARG_EXAMPLES
 123
 124 AG_GST_ARG_WITH_PKG_CONFIG_PATH
 125 AG_GST_ARG_WITH_PACKAGE_NAME
 126 AG_GST_ARG_WITH_PACKAGE_ORIGIN
 127
 128 AG_GST_PKG_CONFIG_PATH
 129
 130 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 131   ["${srcdir}/gstreamer.doap"],
 132   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 133
 134 # We only use this when building with MSVC, which is only done with the
 135 # alternate Meson build system files
 136 GSTCONFIG_BUILT_WITH_MSVC=0
 137 AC_SUBST(GSTCONFIG_BUILT_WITH_MSVC)
 138
 139 dnl check for bash completion
 140 AC_ARG_WITH([bash-completion-dir],
 141     AS_HELP_STRING([--with-bash-completion-dir[=PATH]],
 142         [Install the bash auto-completion script in this directory. @<:@default=yes@:>@]),
 143     [],
 144     [with_bash_completion_dir=yes])
 145
 146 if test "x$with_bash_completion_dir" = "xyes"
 147 then
 148     extra_args=
 149
 150     if test "x$prefix" != "xNONE"
 151     then
 152         extra_args="--define-variable=prefix=\"$prefix\""
 153     fi
 154
 155     PKG_CHECK_MODULES([BASH_COMPLETION], [bash-completion >= 2.0],
 156         [BASH_COMPLETION_DIR="`eval pkg-config $extra_args --variable=completionsdir bash-completion`"],
 157         [BASH_COMPLETION_DIR="$datadir/bash-completion/completions"])
 158     PKG_CHECK_MODULES([BASH_COMPLETION], [bash-completion >= 2.0],
 159         [BASH_HELPERS_DIR="`eval pkg-config $extra_args --variable=helpersdir bash-completion`"],
 160         [BASH_HELPERS_DIR="$datadir/bash-completion/helpers"])
 161 else
 162     BASH_COMPLETION_DIR="$with_bash_completion_dir/completions"
 163     BASH_HELPERS_DIR="$with_bash_completion_dir/helpers"
 164 fi
 165
 166 AC_SUBST([BASH_COMPLETION_DIR])
 167 AC_SUBST([BASH_HELPERS_DIR])
 168 AM_CONDITIONAL([ENABLE_BASH_COMPLETION],[test "x$with_bash_completion_dir" != "xno"])
 169
 170 dnl build static plugins or not
 171 AC_MSG_CHECKING([whether to build static plugins or not])
 172 AC_ARG_ENABLE(
 173   static-plugins,
 174   AC_HELP_STRING(
 175     [--enable-static-plugins],
 176     [build static plugins @<:@default=no@:>@]),
 177   [AS_CASE(
 178     [$enableval], [no], [], [yes], [],
 179     [AC_MSG_ERROR([bad value "$enableval" for --enable-static-plugins])])],
 180   [enable_static_plugins=no])
 181 AC_MSG_RESULT([$enable_static_plugins])
 182 if test "x$enable_static_plugins" = xyes; then
 183   AC_DEFINE(GST_PLUGIN_BUILD_STATIC, 1,
 184     [Define if static plugins should be built])
 185   GST_PLUGIN_LIBTOOLFLAGS=""
 186 else
 187   GST_PLUGIN_LIBTOOLFLAGS="--tag=disable-static"
 188 fi
 189 AC_SUBST(GST_PLUGIN_LIBTOOLFLAGS)
 190 AM_CONDITIONAL(GST_PLUGIN_BUILD_STATIC, test "x$enable_static_plugins" = "xyes")
 191
 192 dnl If only building static libraries, define GST_STATIC_COMPILATION. This is
 193 dnl needed only on Windows, but it doesn't hurt to have it everywhere.
 194 if test x$enable_static = xyes -a x$enable_shared = xno; then
 195   GST_OBJ_STATIC_CFLAGS="-DGST_STATIC_COMPILATION"
 196 fi
 197
 198 dnl building of tests
 199 AC_ARG_ENABLE(tests,
 200   AS_HELP_STRING([--disable-tests],[disable building test apps]),
 201   [
 202     case "${enableval}" in
 203       yes) BUILD_TESTS=yes ;;
 204       no)  BUILD_TESTS=no ;;
 205       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 206     esac
 207   ],
 208 [BUILD_TESTS=yes]) dnl Default value
 209 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 210
 211 dnl tests known to fail
 212 AC_ARG_ENABLE(failing-tests,
 213   AS_HELP_STRING([--disable-failing-tests],[disable building tests known to fail]),
 214   [
 215     case "${enableval}" in
 216       yes) BUILD_FAILING_TESTS=yes ;;
 217       no)  BUILD_FAILING_TESTS=no ;;
 218       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-failing-tests) ;;
 219     esac
 220   ],
 221   [BUILD_FAILING_TESTS=no]) dnl Default value
 222 AM_CONDITIONAL(BUILD_FAILING_TESTS, test "x$BUILD_FAILING_TESTS" = "xyes")
 223 if test x$BUILD_FAILING_TESTS = xyes; then
 224   AC_MSG_WARN([building tests known to fail, use --disable-failing-tests to disable])
 225 else
 226   AC_MSG_WARN([Sissy ! By asking to not build the tests known to fail, you hereby waive your right to customer support.  If you do not agree with this EULA, please press Ctrl-C before the next line is printed.  By allowing the next line to be printed, you expressly acknowledge your acceptance of this EULA.])
 227 fi
 228
 229 dnl building of benchmarks
 230 AC_ARG_ENABLE(benchmarks,
 231   AS_HELP_STRING([--disable-benchmarks],[disable building benchmarks apps]),
 232   [
 233     case "${enableval}" in
 234       yes) BUILD_BENCHMARKS=yes ;;
 235       no)  BUILD_BENCHMARKS=no ;;
 236       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-benchmarks) ;;
 237     esac
 238   ],
 239 [BUILD_BENCHMARKS=yes]) dnl Default value
 240 AM_CONDITIONAL(BUILD_BENCHMARKS, test "x$BUILD_BENCHMARKS" = "xyes")
 241
 242 dnl building of tools
 243 AC_ARG_ENABLE(tools,
 244   AS_HELP_STRING([--disable-tools],[disable building tools]),
 245   [
 246     case "${enableval}" in
 247       yes) BUILD_TOOLS=yes ;;
 248       no)  BUILD_TOOLS=no ;;
 249       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tools) ;;
 250     esac
 251   ],
 252 [BUILD_TOOLS=yes]) dnl Default value
 253 AM_CONDITIONAL(BUILD_TOOLS, test "x$BUILD_TOOLS" = "xyes")
 254
 255 dnl poison destroyed objects
 256 AC_ARG_ENABLE(poisoning,
 257   AS_HELP_STRING([--enable-poisoning],[enable poisoning of deallocated objects]),
 258   [
 259     case "${enableval}" in
 260       yes) USE_POISONING=yes ;;
 261       no)  USE_POISONING=no ;;
 262       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-poisoning) ;;
 263     esac
 264   ],
 265   [USE_POISONING=no]) dnl Default value
 266 if test "x$USE_POISONING" = xyes; then
 267   AC_DEFINE(USE_POISONING, 1,
 268     [Define if we should poison deallocated memory])
 269 fi
 270
 271 dnl PTP support parts
 272 AC_MSG_CHECKING([whether PTP support can be enabled])
 273 case "$host_os" in
 274   *android*)
 275     dnl Can't run on Android because of permissions
 276     HAVE_PTP=no
 277     ;;
 278   mingw*|pw32*|cygwin*)
 279     dnl Not ported to Windows yet
 280     HAVE_PTP=no
 281     ;;
 282   darwin*)
 283     dnl Can't run on iOS because of permissions
 284     AC_CHECK_HEADER(MobileCoreServices/MobileCoreServices.h, HAVE_PTP="no", HAVE_PTP="yes", [-])
 285     ;;
 286   linux*|darwin*|solaris*|netbsd*|freebsd*|openbsd*|kfreebsd*|dragonfly*|gnu*)
 287     HAVE_PTP=yes
 288     ;;
 289   *)
 290     HAVE_PTP=no
 291     ;;
 292 esac
 293 AC_MSG_RESULT([$HAVE_PTP])
 294
 295 dnl user/group to change to in gst-ptp-helper
 296 AC_ARG_WITH([ptp-helper-setuid-user],
 297   AS_HELP_STRING([--with-ptp-helper-setuid-user],[User to switch to when installing gst-ptp-helper setuid root]),
 298   [
 299     if test "x$withval" != "x"
 300     then
 301       AC_DEFINE_UNQUOTED(HAVE_PTP_HELPER_SETUID_USER, "$withval", [PTP helper setuid user])
 302     fi
 303   ], []
 304 )
 305
 306 dnl group/group to change to in gst-ptp-helper
 307 AC_ARG_WITH([ptp-helper-setuid-group],
 308   AS_HELP_STRING([--with-ptp-helper-setuid-group],[Group to switch to when installing gst-ptp-helper setuid root]),
 309   [
 310     if test "x$withval" != "x"
 311     then
 312       AC_DEFINE_UNQUOTED(HAVE_PTP_HELPER_SETUID_GROUP, "$withval", [PTP helper setuid group])
 313     fi
 314   ], []
 315 )
 316
 317 AC_ARG_WITH(
 318   ptp-helper-permissions,
 319   AC_HELP_STRING(
 320     [--with-ptp-helper-permissions],
 321     [how to gain PTP permissions (none, setuid-root, capabilities, auto)]),
 322     [],
 323     [with_ptp_helper_permissions=auto])
 324
 325 gst_ptp_have_cap=no
 326 AG_GST_CHECK_LIBHEADER(CAP, cap,
 327                        cap_init, ,
 328                        sys/capability.h,
 329                        CAP_LIBS="-lcap"
 330                        AC_SUBST(CAP_LIBS)
 331                        gst_ptp_have_cap=yes)
 332
 333 AC_PATH_PROG([SETCAP], [setcap], [no], [$PATH:/usr/bin:/bin:/usr/sbin:/sbin])
 334
 335 if test "x$HAVE_PTP" = "xyes"; then
 336 AC_DEFINE(HAVE_PTP, 1, [PTP support available])
 337
 338 AC_MSG_CHECKING([for SIOCGIFCONF, SIOCGIFFLAGS and SIOCGIFHWADDR])
 339 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 340     [[
 341         #include <sys/ioctl.h>
 342         #include <net/if.h>
 343     ]],
 344     [[
 345         struct ifreq ifr;
 346         struct ifconf ifc;
 347         ioctl(0, SIOCGIFCONF, &ifc);
 348         ioctl(0, SIOCGIFFLAGS, &ifr);
 349         ioctl(0, SIOCGIFHWADDR, &ifr);
 350         int dummy = ifr.ifr_hwaddr.sa_data[0];
 351     ]])], [
 352         AC_MSG_RESULT(yes)
 353         AC_DEFINE(HAVE_SIOCGIFCONF_SIOCGIFFLAGS_SIOCGIFHWADDR, 1, [SIOCGIFCONF, SIOCGIFFLAGS and SIOCGIFHWADDR is available])
 354     ], [
 355         AC_MSG_RESULT(no)
 356 ])
 357
 358 AC_MSG_CHECKING([for getifaddrs() and AF_LINK])
 359 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 360     [[
 361         #include <ifaddrs.h>
 362         #include <net/if.h>
 363         #include <net/if_dl.h>
 364     ]],
 365     [[
 366         struct ifaddrs *ifaddr;
 367         getifaddrs(&ifaddr);
 368         int dummy = (ifaddr->ifa_flags & IFF_LOOPBACK) && ifaddr->ifa_addr->sa_family != AF_LINK;
 369     ]])], [
 370         AC_MSG_RESULT(yes)
 371         AC_DEFINE(HAVE_GETIFADDRS_AF_LINK, 1, [getifaddrs() and AF_LINK is available])
 372     ], [
 373         AC_MSG_RESULT(no)
 374     ])
 375
 376 AC_MSG_CHECKING([how to install gst-ptp-helper])
 377 if test "x$with_ptp_helper_permissions" = "xauto"; then
 378     if test "x$gst_ptp_have_cap" = "xyes" -a "x$SETCAP" != "xno"; then
 379         with_ptp_helper_permissions="capabilities"
 380     else
 381         with_ptp_helper_permissions="setuid-root"
 382     fi
 383 fi
 384 AC_MSG_RESULT([$with_ptp_helper_permissions])
 385
 386 case "$with_ptp_helper_permissions" in
 387   none)
 388     ;;
 389   setuid-root)
 390      AC_DEFINE(HAVE_PTP_HELPER_SETUID, 1,
 391         [Use setuid-root for permissions in PTP helper])
 392     ;;
 393   capabilities)
 394      AC_DEFINE(HAVE_PTP_HELPER_CAPABILITIES, 1,
 395         [Use capabilities for permissions in PTP helper])
 396     ;;
 397   *)
 398     AC_MSG_ERROR(Invalid parameter [$with_ptp_helper_permissions])
 399     ;;
 400 esac
 401
 402 fi
 403
 404 AM_CONDITIONAL(HAVE_PTP, test "x$HAVE_PTP" = "xyes")
 405 AM_CONDITIONAL(HAVE_PTP_HELPER_SETUID, test "x$with_ptp_helper_permissions" = "xsetuid-root")
 406 AM_CONDITIONAL(HAVE_PTP_HELPER_CAPABILITIES, test "x$with_ptp_helper_permissions" = "xcapabilities")
 407
 408 dnl *** checks for platform ***
 409
 410 dnl * hardware/architecture *
 411
 412 dnl common/m4/gst-arch.m4
 413 dnl check CPU type
 414 AG_GST_ARCH
 415
 416 dnl check for platform specific settings
 417 AG_GST_PLATFORM
 418
 419 dnl * software *
 420
 421 dnl check for large file support
 422 dnl affected plugins must include config.h
 423 AC_SYS_LARGEFILE
 424
 425 dnl *** checks for programs ***
 426
 427 dnl find a compiler
 428 AC_PROG_CC
 429 AC_PROG_CC_STDC
 430
 431 dnl check if the compiler supports '-c' and '-o' options
 432 AM_PROG_CC_C_O
 433
 434 dnl find an assembler
 435 AM_PROG_AS
 436
 437 dnl determine if c++ is available on this system
 438 AC_PROG_CXX
 439 dnl CXX may be set to some default even if no c++ compiler is available
 440 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 441 AC_LANG_PUSH([C++])
 442 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ class Foo { int bar; };]], [[]])],[working_cxx=yes],[working_cxx=no])
 443 AC_LANG_POP([C++])
 444 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 445 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 446
 447 dnl Perl is used in building documentation and in the version checks
 448 AC_PATH_PROG(PERL_PATH, perl, no)
 449 if test x$PERL_PATH = xno; then
 450   AC_MSG_ERROR(Could not find perl)
 451 fi
 452
 453 dnl we require flex and bison for building the parser
 454 if test "x$GST_DISABLE_PARSE" != xyes; then
 455   AG_GST_BISON_CHECK
 456   AG_GST_FLEX_CHECK
 457 fi
 458
 459 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 460 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 461
 462 dnl check for gobject-introspection
 463 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 464
 465 dnl check for documentation tools
 466 GTK_DOC_CHECK([1.12])
 467 AG_GST_PLUGIN_DOCS([1.12])
 468
 469 dnl *** checks for libraries ***
 470
 471 dnl check for libm, for sin()
 472 LT_LIB_M
 473 AC_SUBST(LIBM)
 474
 475 dnl *** checks for header files ***
 476
 477 dnl check if we have ANSI C header files
 478 AC_HEADER_STDC
 479
 480 dnl Check for ucontext.h
 481 AC_CHECK_HEADERS([ucontext.h], [], [], [AC_INCLUDES_DEFAULT])
 482
 483 dnl Check for sys/socket.h
 484 AC_CHECK_HEADERS([sys/socket.h], [HAVE_SYS_SOCKET_H=yes], [HAVE_SYS_SOCKET_H=no], [AC_INCLUDES_DEFAULT])
 485 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 486
 487 dnl check for sys/times.h for tests/examples/adapter/
 488 AC_CHECK_HEADERS([sys/times.h], [HAVE_SYS_TIMES_H=yes], [HAVE_SYS_TIME_H=no], [AC_INCLUDES_DEFAULT])
 489 AC_CHECK_HEADERS([unistd.h], [HAVE_UNISTD_H=yes], [HAVE_UNISTD_H=no], [AC_INCLUDES_DEFAULT])
 490 AM_CONDITIONAL(HAVE_SYS_TIMES_H_AND_UNISTD_H, test "x$HAVE_SYS_TIMES_H" = "xyes" -a "x$HAVE_UNISTD_H" = "xyes")
 491
 492 dnl Check for process.h for getpid() on win32
 493 AC_CHECK_HEADERS([process.h], [], [], [AC_INCLUDES_DEFAULT])
 494
 495 dnl Check for sys/utsname.h for uname
 496 AC_CHECK_HEADERS([sys/utsname.h], [], [], [AC_INCLUDES_DEFAULT])
 497
 498 dnl Check for stdio_ext.f for __fbufsize
 499 AC_CHECK_HEADERS([stdio_ext.h], [], [], [AC_INCLUDES_DEFAULT])
 500
 501 dnl check for pthreads
 502 dnl without arguments AX_PTHREAD() will do AC_DEFINE(HAVE_PTHREAD)
 503 dnl which later checks use in their test code
 504 AX_PTHREAD()
 505 AM_CONDITIONAL(HAVE_PTHREAD, test "x$ax_pthread_ok" = "xyes")
 506
 507 dnl check for sys/prctl for setting thread name on Linux
 508 AC_CHECK_HEADERS([sys/prctl.h], [], [], [AC_INCLUDES_DEFAULT])
 509
 510 dnl check for pthread_setname_np(const char*)
 511 dnl which is present on OS X 10.6, iOS 3.2 and above
 512 AC_MSG_CHECKING(for pthread_setname_np(const char*))
 513 AC_LINK_IFELSE(
 514     [AC_LANG_PROGRAM(
 515         [#include <pthread.h>],
 516         [pthread_setname_np("example")])],
 517     [AC_MSG_RESULT(yes)
 518      AC_DEFINE(HAVE_PTHREAD_SETNAME_NP_WITHOUT_TID,1,
 519         [Have function pthread_setname_np(const char*)])],
 520     [AC_MSG_RESULT(no)])
 521
 522 dnl check for sys/uio.h for writev()
 523 AC_CHECK_HEADERS([sys/uio.h], [], [], [AC_INCLUDES_DEFAULT])
 524
 525 dnl Check for valgrind.h
 526 dnl separate from HAVE_VALGRIND because you can have the program, but not
 527 dnl the dev package
 528 AC_CHECK_HEADERS([valgrind/valgrind.h], [], [], [AC_INCLUDES_DEFAULT])
 529
 530 dnl used in gst/gstpoll.c
 531 AC_CHECK_HEADERS([winsock2.h], [HAVE_WINSOCK2_H=yes], [HAVE_WINSOCK2_H=no], [AC_INCLUDES_DEFAULT])
 532 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 533 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 534   WIN32_LIBS="-lws2_32"
 535   AC_SUBST(WIN32_LIBS)
 536 fi
 537
 538 dnl check for GMP/GSL, used by the gst_util_uint64_scale unit test only
 539 if test "x$BUILD_TESTS" = "xyes"; then
 540   AG_GST_CHECK_LIBHEADER(GMP, gmp,
 541                          __gmpz_init_set_d, ,
 542                          gmp.h,
 543                          GMP_LIBS="-lgmp"
 544                          AC_SUBST(GMP_LIBS)
 545                          AC_DEFINE(HAVE_GMP, [1],[Have GMP library]))
 546   AG_GST_CHECK_LIBHEADER(GSL, gsl,
 547                          gsl_rng_uniform_int, -lgslcblas,
 548                          gsl/gsl_rng.h,
 549                          GSL_LIBS="-lgsl -lgslcblas"
 550                          AC_SUBST(GSL_LIBS)
 551                          AC_DEFINE(HAVE_GSL, [1],[Have GSL library]))
 552 fi
 553
 554 dnl *** checks for types/defines ***
 555
 556 dnl *** checks for structures ***
 557
 558 dnl *** checks for compiler characteristics ***
 559
 560 dnl check if the compiler supports __uint128_t (gcc)
 561 dnl Actually check for 128-bit division, since that's what we use
 562 dnl uint128_t for.
 563 AC_CACHE_CHECK(for __uint128_t, gst_cv_uint128_t,
 564     AC_LINK_IFELSE([AC_LANG_PROGRAM([[ ]], [[
 565       static __uint128_t v1 = 100;
 566       static __uint128_t v2 = 10;
 567       static __uint128_t u;
 568       u = v1 / v2;
 569     ]])],[
 570       gst_cv_uint128_t=yes
 571     ],[
 572       gst_cv_uint128_t=no
 573     ])
 574 )
 575 if test x$gst_cv_uint128_t = xyes; then
 576   AC_DEFINE(HAVE_UINT128_T, 1, [Have __uint128_t type])
 577 fi
 578
 579 dnl *** checking for tm_gmtoff ***
 580 AC_MSG_CHECKING([for tm_gmtoff])
 581 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 582         #include <time.h>
 583         int main(void) {
 584           struct tm t;
 585           t.tm_gmtoff = 0;
 586           exit(0);
 587         }]])],
 588   [have_tm_gmtoff=yes
 589    AC_DEFINE(HAVE_TM_GMTOFF,1,[Have tm_gmtoff field in struct tm])],
 590   [have_tm_gmtoff=no],
 591   [have_tm_gmtoff="no (cross compiling)"])
 592 AC_MSG_RESULT($have_tm_gmtoff)
 593
 594
 595 dnl *** checks for library functions ***
 596
 597 AC_CHECK_FUNCS([strcasestr])
 598
 599 AC_CHECK_FUNCS([gmtime_r])
 600 AC_CHECK_FUNCS([localtime_r])
 601 AC_CHECK_FUNCS([sigaction])
 602 AC_CHECK_FUNCS([getrusage])
 603 AM_CONDITIONAL(HAVE_GETRUSAGE, test "x$ac_cv_func_getrusage" = "xyes")
 604 AC_CHECK_HEADERS([sys/resource.h])
 605
 606 dnl check for fseeko()
 607 AC_FUNC_FSEEKO
 608 dnl check for ftello()
 609 AC_CHECK_FUNCS([ftello])
 610
 611 AC_CHECK_FUNCS([fgetpos])
 612 AC_CHECK_FUNCS([fsetpos])
 613
 614 dnl check for poll(), ppoll() and pselect()
 615 AC_CHECK_HEADERS([sys/poll.h], [], [], [AC_INCLUDES_DEFAULT])
 616 AC_CHECK_HEADERS([poll.h], [], [], [AC_INCLUDES_DEFAULT])
 617 AC_CHECK_FUNCS([poll])
 618 AC_CHECK_FUNCS([ppoll])
 619 AC_CHECK_FUNCS([pselect])
 620
 621 dnl check for socketpair()
 622 AC_CHECK_FUNC(socketpair, [], [
 623   AC_CHECK_LIB(socket, socketpair, [
 624     SOCKET_LIBS="-lsocket"
 625     AC_SUBST(SOCKET_LIBS)
 626   ])
 627 ])
 628
 629 dnl ****************************************
 630 dnl *** GLib POLL* compatibility defines ***
 631 dnl ****************************************
 632
 633 AC_MSG_CHECKING([for broken poll])
 634 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 635         #include <stdlib.h>
 636         #include <fcntl.h>
 637         #ifdef HAVE_SYS_POLL_H
 638         #include <sys/poll.h>
 639         #endif
 640         #ifdef HAVE_POLL_H
 641         #include <poll.h>
 642         #endif
 643         int main(void) {
 644           struct pollfd fds[1];
 645           int fd;
 646           fd = open("/dev/null", 1);
 647           fds[0].fd = fd;
 648           fds[0].events = POLLIN;
 649           fds[0].revents = 0;
 650           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
 651                 exit(1);  /* Does not work for devices -- fail */
 652           }
 653           exit(0);
 654         }]])],
 655   [broken_poll=no],
 656   [broken_poll=yes
 657    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
 658   [broken_poll="no (cross compiling)"])
 659 AC_MSG_RESULT($broken_poll)
 660
 661 dnl check for getpagesize()
 662 AC_CHECK_FUNCS([getpagesize])
 663
 664 dnl Check for POSIX timers
 665 CLOCK_GETTIME_FOUND="no"
 666 AC_CHECK_FUNC(clock_gettime, [CLOCK_GETTIME_FOUND="yes"], [
 667   AC_CHECK_LIB(rt, clock_gettime, [
 668     CLOCK_GETTIME_FOUND="yes"
 669     LIBS="$LIBS -lrt"
 670   ], [
 671     AC_CHECK_LIB(pthread, clock_gettime, [
 672       CLOCK_GETTIME_FOUND="yes"
 673       LIBS="$LIBS -lpthread"
 674     ])
 675   ])
 676 ])
 677
 678 # With XCode 8, clock_gettime will be incorrectly detected as being available
 679 # regardless of what version of OS X you target because the symbol is available
 680 # in the .tbd file as a weak symbol.
 681 # See: https://bugzilla.gnome.org/show_bug.cgi?id=772451
 682 #
 683 # We cannot simply do AC_CHECK_FUNCS with -Wl,-no_weak_imports because the
 684 # autoconf check does its own prototype declaration that doesn't trigger that
 685 # compiler flag.
 686 #
 687 # It's only starting from macOS 10.12 and iOS 10.0 that clock_gettime is
 688 # actually available, so we can unconditionally disable it for older versions.
 689 case "$host_os" in
 690   darwin*)
 691     AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 692 #include <AvailabilityMacros.h>
 693 #include <TargetConditionals.h>
 694 #if defined(TARGET_OS_MAC)
 695 #  if MAC_OS_X_VERSION_MIN_REQUIRED < MAC_OS_X_VERSION_10_12
 696 #    error "Not compiling for OS X 10.12 or later"
 697 #  endif
 698 #else
 699 #  if __IPHONE_OS_VERSION_MIN_REQUIRED < __IPHONE_10_0
 700 #    error "Not compiling for iOS 10.0 or later"
 701 #  endif
 702 #endif
 703     ]])], [], [
 704     if test "$CLOCK_GETTIME_FOUND" = "yes"; then
 705       AC_MSG_NOTICE([Disabling incorrectly detected clock_gettime on OS X])
 706     fi
 707     CLOCK_GETTIME_FOUND="no"
 708     ])
 709     ;;
 710 esac
 711
 712 if test "$CLOCK_GETTIME_FOUND" = "yes"; then
 713   AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [Have clock_gettime])
 714 fi
 715
 716 AC_CACHE_CHECK(for posix timers, gst_cv_posix_timers,
 717     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 718 #include <time.h>
 719 #ifdef HAVE_UNISTD_H
 720 #include <unistd.h>
 721 #endif
 722     ]], [[
 723 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 724 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 725 #endif
 726     ]])],[
 727       gst_cv_posix_timers=yes
 728     ],[
 729       gst_cv_posix_timers=no
 730     ])
 731 )
 732
 733 if test "$gst_cv_posix_timers" = "yes"; then
 734   AC_DEFINE(HAVE_POSIX_TIMERS,1,[Have posix timers])
 735   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 1"
 736 else
 737   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 0"
 738 fi
 739 AC_SUBST(GST_HAVE_POSIX_TIMERS_DEFINE)
 740 AM_CONDITIONAL(GST_HAVE_POSIX_TIMERS, test "$gst_cv_posix_timers" = "yes")
 741
 742 AC_CACHE_CHECK(for monotonic clock, gst_cv_monotonic_clock,
 743     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 744 #include <time.h>
 745 #ifdef HAVE_UNISTD_H
 746 #include <unistd.h>
 747 #endif
 748     ]], [[
 749 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 750 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 751 #endif
 752     ]])],[
 753       gst_cv_monotonic_clock=yes
 754     ],[
 755       gst_cv_monotonic_clock=no
 756     ])
 757 )
 758
 759 if test "$gst_cv_monotonic_clock" = "yes"; then
 760   AC_DEFINE(HAVE_MONOTONIC_CLOCK,1,[Have a monotonic clock])
 761   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 1"
 762 else
 763   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 0"
 764 fi
 765 AC_SUBST(GST_HAVE_MONOTONIC_CLOCK_DEFINE)
 766 AM_CONDITIONAL(GST_HAVE_MONOTONIC_CLOCK, test "$gst_cv_monotonic_clock" = "yes")
 767
 768 dnl Check for a way to display the function name in debug output
 769 AG_GST_CHECK_FUNCTION
 770
 771 dnl test if we have dladdr(); we use it for debugging; see gst/gstinfo.c
 772 save_cflags="$CFLAGS"
 773 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 774 AC_CHECK_LIB(dl, dladdr,
 775    AC_DEFINE(HAVE_DLADDR, 1, [Defined if we have dladdr ()])
 776    LIBS="$LIBS -ldl")
 777 CFLAGS="$save_cflags"
 778
 779 dnl Check printf stuff
 780 if test "x${GST_DISABLE_GST_DEBUG}" != "xyes"; then
 781   AC_TYPE_LONG_LONG_INT
 782   AC_TYPE_UNSIGNED_LONG_LONG_INT
 783
 784   if test x$ac_cv_type_long_long_int$ac_cv_type_unsigned_long_long_int = xyesyes; then
 785     AC_DEFINE([HAVE_LONG_LONG], [1], [Define to 1 if the system has the type long long])
 786   fi
 787
 788   dnl /usr/share/aclocal/inttypes_h.m4 - ships with gettext apparently
 789   gl_AC_HEADER_INTTYPES_H
 790
 791   dnl /usr/share/aclocal/stdint_h.m4 - ships with gettext apparently
 792   gl_AC_HEADER_STDINT_H
 793
 794   AC_CHECK_TYPES(ptrdiff_t)
 795
 796   AC_TYPE_INTMAX_T
 797   AC_TYPE_SIZE_T
 798 fi
 799
 800 dnl *** checks for dependency libraries ***
 801
 802 dnl GLib
 803 GLIB_REQ=2.40.0
 804 AG_GST_GLIB_CHECK([$GLIB_REQ])
 805
 806 dnl Check for documentation xrefs
 807 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 808 AC_SUBST(GLIB_PREFIX)
 809
 810 dnl GTK is optional and only used in examples
 811 HAVE_GTK=no
 812 GTK_REQ=3.10
 813 if test "x$BUILD_EXAMPLES" = "xyes"; then
 814   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 815   AC_SUBST(GTK_LIBS)
 816   AC_SUBST(GTK_CFLAGS)
 817 fi
 818 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 819
 820 dnl libunwind is optionally used by the leaks tracer
 821 PKG_CHECK_MODULES(UNWIND, libunwind, HAVE_UNWIND=yes, HAVE_UNWIND=no)
 822 if test "x$HAVE_UNWIND" = "xyes"; then
 823   AC_DEFINE(HAVE_UNWIND, 1, [libunwind available])
 824 fi
 825
 826 dnl libdw is optionally used to add source lines and numbers to backtraces
 827 PKG_CHECK_MODULES(DW, libdw, HAVE_DW=yes, HAVE_DW=no)
 828 if test "x$HAVE_DW" = "xyes"; then
 829   AC_DEFINE(HAVE_DW, 1, [libdw available])
 830 fi
 831
 832 dnl Check for backtrace() from libc
 833 AC_CHECK_FUNC(backtrace, [
 834   AC_CHECK_HEADERS([execinfo.h], [
 835     AC_DEFINE(HAVE_BACKTRACE,1,[Have backtrace])
 836   ], [], [])
 837 ])
 838
 839 dnl building of unit test libraries
 840 AC_ARG_ENABLE(check,
 841   AS_HELP_STRING([--disable-check],[disable building unit test libraries]),
 842   [
 843     case "${enableval}" in
 844       yes) BUILD_CHECK=yes ;;
 845       no)  BUILD_CHECK=no ;;
 846       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-check) ;;
 847     esac
 848   ], [
 849     dnl Default value
 850     case $host_os in
 851       mingw* | msvc* | mks*) BUILD_CHECK=no ;;
 852       *) BUILD_CHECK=yes ;;
 853     esac
 854 ])
 855 dnl bit of a misnomer, but keep the conditional named like this so we don't
 856 dnl have to change too much elsewhere
 857 AM_CONDITIONAL(HAVE_CHECK, test "x$BUILD_CHECK" = "xyes")
 858
 859 dnl configure the desired memory alignment
 860 AC_ARG_WITH([memory-alignment],
 861   AS_HELP_STRING([--with-memory-alignment],[8,N,malloc,pagesize (default is 32)]),
 862   [
 863     if test "x$withval" = "xyes"
 864     then
 865       AC_DEFINE(MEMORY_ALIGNMENT, 32, [Memory alignment to use])
 866     else
 867       case "${withval}" in
 868         malloc) AC_DEFINE(MEMORY_ALIGNMENT_MALLOC, 1, [Memory alignment by malloc default]) ;;
 869         pagesize)  AC_DEFINE(MEMORY_ALIGNMENT_PAGESIZE, 1, [Memory alignment by pagesize]) ;;
 870         *)   AC_DEFINE_UNQUOTED(MEMORY_ALIGNMENT, ${withval}, [Memory alignment to use]) ;;
 871       esac
 872     fi
 873   ], [
 874     AC_DEFINE(MEMORY_ALIGNMENT_MALLOC, 1, [Memory alignment by malloc default])
 875   ]
 876 )
 877
 878 dnl Check for -Bsymbolic-functions linker flag used to avoid
 879 dnl intra-library PLT jumps, if available.
 880 AC_ARG_ENABLE(Bsymbolic,
 881               [AS_HELP_STRING([--disable-Bsymbolic],[avoid linking with -Bsymbolic])],,
 882               [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
 883                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 884                LDFLAGS=-Wl,-Bsymbolic-functions
 885                LIBS=
 886                AC_TRY_LINK([], [return 0],
 887                            AC_MSG_RESULT(yes)
 888                            enable_Bsymbolic=yes,
 889                            AC_MSG_RESULT(no)
 890                            enable_Bsymbolic=no)
 891                LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
 892
 893
 894 dnl *** set variables based on configure arguments
 895
 896 dnl set license and copyright notice
 897 GST_LICENSE="LGPL"
 898 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 899 AC_SUBST(GST_LICENSE)
 900
 901 dnl define LIBDIR, GST_DATADIR so we can inform people where we live
 902 AS_AC_EXPAND(LIBDIR, $libdir)
 903 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [library dir])
 904 AS_AC_EXPAND(DATADIR, $datadir)
 905 AC_DEFINE_UNQUOTED(GST_DATADIR, "$DATADIR", [data dir])
 906
 907 dnl set location of plugin directory
 908 AG_GST_SET_PLUGINDIR
 909
 910 dnl make sure it doesn't complain about unused variables if debugging is disabled
 911 NO_WARNINGS=""
 912 if test "x${GST_DISABLE_GST_DEBUG}" = "xyes"; then
 913   NO_WARNINGS="-Wno-unused"
 914 fi
 915
 916 dnl define an ERROR_CFLAGS Makefile variable
 917 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [-Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef -Wwrite-strings -Wformat-nonliteral -Wformat-security -Wold-style-definition -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return -Wno-multichar -Wnested-externs $NO_WARNINGS])
 918
 919 dnl special warning flags for gst/printf
 920 AS_COMPILER_FLAG([-Wno-format-nonliteral], [PRINTF_CFLAGS="-Wno-format-nonliteral"])
 921 AC_SUBST(PRINTF_CFLAGS)
 922
 923 dnl define correct level for debugging messages
 924 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 925
 926 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 927
 928 dnl Overview:
 929 dnl GST_OPTION_CFLAGS:  common cflags for profiling, debugging, errors, ...
 930 dnl GST_ALL_*:          vars shared by all built objects
 931 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 932 dnl GST_OBJ_*:          additional vars to link to the core library
 933 dnl                     include GST_ALL_*
 934 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 935 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 936
 937 dnl GST_OPTION_CFLAGS
 938 if test "x$USE_DEBUG" = xyes; then
 939    PROFILE_CFLAGS="-g"
 940 fi
 941 AC_SUBST(PROFILE_CFLAGS)
 942
 943 # GST_DISABLE_DEPRECATED: hide the visibility of deprecated
 944 # functionality from the API that gstreamer uses
 945 # GST_REMOVE_DEPRECATED: don't compile deprecated functionality (breaks ABI)
 946 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 947   dnl Define _only_ when compiling from git (not for pre-releases or releases)
 948   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 949 else
 950   DEPRECATED_CFLAGS=""
 951 fi
 952 AC_SUBST(DEPRECATED_CFLAGS)
 953
 954 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time via e.g.
 955 dnl make DEPRECATED_CFLAGS=''
 956 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 957 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 958 GST_OPTION_CFLAGS="$GST_OPTION_CFLAGS"
 959 GST_OPTION_CXXFLAGS="$GST_OPTION_CXXFLAGS"
 960 AC_SUBST(GST_OPTION_CFLAGS)
 961 AC_SUBST(GST_OPTION_CXXFLAGS)
 962
 963 dnl GST_ALL_*
 964 dnl vars common to for all internal objects (core libs, elements, applications)
 965 dnl CFLAGS:
 966 dnl - src and build dirs need to be added because every piece that gets built
 967 dnl   will need the GStreamer source and generated headers
 968 dnl LIBS: XML doesn't need to be added because we don't explicitly use symbols
 969 dnl       from LibXML except for in the core library
 970 GST_ALL_CXXFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir)/libs -I\$(top_builddir) $GLIB_CFLAGS \$(GLIB_EXTRA_CFLAGS) $XML_CFLAGS \$(GST_OPTION_CXXFLAGS) \$(ERROR_CXXFLAGS)"
 971 GST_ALL_CFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir)/libs -I\$(top_builddir) $GLIB_CFLAGS \$(GLIB_EXTRA_CFLAGS) $XML_CFLAGS \$(GST_OPTION_CFLAGS) \$(ERROR_CFLAGS)"
 972
 973 dnl FIXME: check if LTLIBINTL is needed everywhere
 974 dnl I presume it is given that it contains the symbols that _() stuff maps to
 975 GST_ALL_LIBS="$GLIB_LIBS $LTLIBINTL \$(GCOV_LIBS)"
 976
 977 dnl LDFLAGS really should only contain flags, not libs - they get added before
 978 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 979 GST_ALL_LDFLAGS="-no-undefined"
 980 if test "x${enable_Bsymbolic}" = "xyes"; then
 981   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 982 fi
 983
 984 AC_SUBST(GST_ALL_CFLAGS)
 985 AC_SUBST(GST_ALL_CXXFLAGS)
 986 AC_SUBST(GST_ALL_LIBS)
 987 AC_SUBST(GST_ALL_LDFLAGS)
 988
 989 dnl GST_LIB_LDFLAGS
 990 dnl linker flags shared by all libraries
 991 dnl LDFLAGS modifier defining exported symbols from built libraries
 992 GST_LIB_LDFLAGS="-export-symbols-regex \^[_]?\(gst_\|Gst\|GST_\).*"
 993 AC_SUBST(GST_LIB_LDFLAGS)
 994
 995 dnl GST_OBJ_*
 996 dnl default vars for all internal objects built on libgstreamer
 997 dnl includes GST_ALL_*
 998 GST_OBJ_CFLAGS="\$(GST_ALL_CFLAGS) $GST_OBJ_STATIC_CFLAGS"
 999 GST_OBJ_CXXFLAGS="\$(GST_ALL_CXXFLAGS) $GST_OBJ_STATIC_CFLAGS"
1000 GST_OBJ_LIBS="\$(top_builddir)/gst/libgstreamer-$GST_API_VERSION.la \$(GST_ALL_LIBS)"
1001 AC_SUBST(GST_OBJ_CFLAGS)
1002 AC_SUBST(GST_OBJ_CXXFLAGS)
1003 AC_SUBST(GST_OBJ_LIBS)
1004
1005 dnl GST_PLUGIN_LDFLAGS
1006 dnl LDFLAGS for plugins; includes GST_ALL_LDFLAGS
1007 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_.*' $GST_ALL_LDFLAGS"
1008 AC_SUBST(GST_PLUGIN_LDFLAGS, "$GST_PLUGIN_LDFLAGS")
1009
1010 dnl plugin scanner locations
1011 AS_AC_EXPAND(GST_PLUGIN_SCANNER_INSTALLED,${libexecdir}/gstreamer-$GST_API_VERSION/gst-plugin-scanner)
1012 AC_DEFINE_UNQUOTED(GST_PLUGIN_SCANNER_INSTALLED,
1013     "$GST_PLUGIN_SCANNER_INSTALLED", [location of the installed gst-plugin-scanner])
1014 AC_SUBST(GST_PLUGIN_SCANNER_INSTALLED)
1015
1016 dnl ptp helper locations
1017 AS_AC_EXPAND(GST_PTP_HELPER_INSTALLED,${libexecdir}/gstreamer-$GST_API_VERSION/gst-ptp-helper)
1018 AC_DEFINE_UNQUOTED(GST_PTP_HELPER_INSTALLED,
1019     "$GST_PTP_HELPER_INSTALLED", [location of the installed gst-ptp-helper])
1020 AC_SUBST(GST_PTP_HELPER_INSTALLED)
1021
1022 dnl things for our internal libcheck (must be called even if building
1023 dnl libcheck is disabled because it defines conditionals)
1024 AG_GST_CHECK_CHECKS
1025
1026 AC_CONFIG_FILES(
1027 Makefile
1028 data/Makefile
1029 gst/Makefile
1030 gst/gstconfig.h
1031 gst/gstversion.h
1032 gst/parse/Makefile
1033 gst/printf/Makefile
1034 libs/Makefile
1035 libs/gst/Makefile
1036 libs/gst/base/Makefile
1037 libs/gst/check/Makefile
1038 libs/gst/check/libcheck/Makefile
1039 libs/gst/check/internal-check.h:libs/gst/check/libcheck/check.h.in
1040 libs/gst/controller/Makefile
1041 libs/gst/helpers/Makefile
1042 libs/gst/net/Makefile
1043 plugins/Makefile
1044 plugins/elements/Makefile
1045 plugins/tracers/Makefile
1046 po/Makefile.in
1047 tests/Makefile
1048 tests/benchmarks/Makefile
1049 tests/check/Makefile
1050 tests/misc/Makefile
1051 tests/examples/Makefile
1052 tests/examples/adapter/Makefile
1053 tests/examples/controller/Makefile
1054 tests/examples/stepping/Makefile
1055 tests/examples/helloworld/Makefile
1056 tests/examples/memory/Makefile
1057 tests/examples/netclock/Makefile
1058 tests/examples/ptp/Makefile
1059 tests/examples/streamiddemux/Makefile
1060 tests/examples/streams/Makefile
1061 tools/Makefile
1062 common/Makefile
1063 common/m4/Makefile
1064 docs/Makefile
1065 docs/gst/Makefile
1066 docs/gst/gstreamer.types
1067 docs/libs/Makefile
1068 docs/plugins/Makefile
1069 docs/version.entities
1070 m4/Makefile
1071 pkgconfig/Makefile
1072 stamp.h
1073 pkgconfig/gstreamer.pc
1074 pkgconfig/gstreamer-uninstalled.pc
1075 pkgconfig/gstreamer-base.pc
1076 pkgconfig/gstreamer-base-uninstalled.pc
1077 pkgconfig/gstreamer-check.pc
1078 pkgconfig/gstreamer-check-uninstalled.pc
1079 pkgconfig/gstreamer-controller.pc
1080 pkgconfig/gstreamer-controller-uninstalled.pc
1081 pkgconfig/gstreamer-net.pc
1082 pkgconfig/gstreamer-net-uninstalled.pc
1083 )
1084
1085 AC_OUTPUT
1086
1087 dnl negate for output
1088 if test "x${GST_DISABLE_GST_DEBUG}" = "xno"; then enable_gst_debug="yes"; fi
1089 if test "x${GST_DISABLE_GST_TRACER_HOOKS}" = "xno"; then enable_gst_tracer_hooks="yes"; fi
1090 if test "x${GST_DISABLE_PARSE}" = "xno"; then enable_parse="yes"; fi
1091 if test "x${GST_DISABLE_OPTION_PARSING}" = "xno"; then enable_option_parsing="yes"; fi
1092 if test "x${GST_DISABLE_PLUGIN}" = "xno"; then enable_plugin="yes"; fi
1093 if test "x${GST_DISABLE_REGISTRY}" = "xno"; then enable_registry="yes"; fi
1094
1095 echo "
1096
1097 Configuration
1098         Version                    : ${VERSION}
1099         Source code location       : ${srcdir}
1100         Prefix                     : ${prefix}
1101         Compiler                   : ${CC}
1102         Package name               : ${GST_PACKAGE_NAME}
1103         Package origin             : ${GST_PACKAGE_ORIGIN}
1104
1105         API Documentation          : ${enable_gtk_doc}
1106
1107         Debug logging              : ${enable_gst_debug}
1108         Tracing subsystem hooks    : ${enable_gst_tracer_hooks}
1109         Command-line parser        : ${enable_parse}
1110         Option parsing in gst_init : ${enable_option_parsing}
1111         Plugin registry            : ${enable_registry}
1112         Plugin support             : ${enable_plugin}
1113         Static plugins             : ${enable_static_plugins}
1114         Unit testing support       : ${BUILD_CHECK}
1115         PTP clock support          : ${HAVE_PTP}
1116         libunwind support          : ${HAVE_UNWIND}
1117         libdw support              : ${HAVE_DW}
1118
1119         Debug                      : ${USE_DEBUG}
1120         Profiling                  : ${USE_PROFILING}
1121
1122         Building benchmarks        : ${BUILD_BENCHMARKS}
1123         Building examples          : ${BUILD_EXAMPLES}
1124         Building test apps         : ${BUILD_TESTS}
1125         Building tests that fail   : ${BUILD_FAILING_TESTS}
1126         Building tools             : ${BUILD_TOOLS}
1127 "