configure.ac

   1 AC_PREREQ(2.52)
   2
   3 AC_INIT
   4 AC_CANONICAL_TARGET
   5
   6 dnl when going to/from release please set the nano (fourth number) right !
   7 dnl releases only do Wall, cvs and prerelease does Werror too
   8 AS_VERSION(gstreamer, GST_VERSION, 0, 9, 2, 1,
   9     GST_CVS="no", GST_CVS="yes")
  10
  11 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  12 AM_MAINTAINER_MODE
  13 AM_INIT_AUTOMAKE($PACKAGE,$VERSION)
  14
  15 dnl our libraries and install dirs use major.minor as a version
  16 GST_MAJORMINOR=$GST_VERSION_MAJOR.$GST_VERSION_MINOR
  17 dnl we override it here for release candidates for a new series
  18 # GST_MAJORMINOR=0.9
  19 AC_SUBST(GST_MAJORMINOR)
  20
  21 AC_PROG_CC
  22 dnl For interactive UNIX (a Sun thing)
  23 AC_ISC_POSIX
  24
  25 dnl CURRENT, REVISION, AGE
  26 dnl - library source changed -> increment REVISION
  27 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  28 dnl - interfaces added -> increment AGE
  29 dnl - interfaces removed -> AGE = 0
  30 AS_LIBTOOL(GST, 6, 0, 0)
  31 AS_LIBTOOL_TAGS([])
  32 AM_PROG_LIBTOOL
  33
  34 AC_CONFIG_SRCDIR([gst/gst.c])
  35 AM_CONFIG_HEADER(config.h)
  36
  37 dnl Add parameters for aclocal
  38 AC_SUBST(ACLOCAL_AMFLAGS, "-I common/m4 -I .")
  39
  40 AM_PROG_CC_STDC
  41 AM_PROG_AS
  42 AS="${CC}"
  43
  44 dnl the gettext stuff needed
  45 AM_GNU_GETTEXT_VERSION(0.11.5)
  46 AM_GNU_GETTEXT([external])
  47
  48 GETTEXT_PACKAGE=gstreamer-$GST_MAJORMINOR
  49 AC_SUBST(GETTEXT_PACKAGE)
  50 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE], "$GETTEXT_PACKAGE",
  51                    [gettext package name])
  52
  53 dnl define LOCALEDIR in config.h
  54 AS_AC_EXPAND(LOCALEDIR, $datadir/locale)
  55 AC_DEFINE_UNQUOTED([LOCALEDIR], "$LOCALEDIR",
  56                    [gettext locale dir])
  57
  58 dnl define LIBDIR so we can inform people where we live
  59 AS_AC_EXPAND(LIBDIR, $libdir)
  60 AC_DEFINE_UNQUOTED([LIBDIR], "$LIBDIR",
  61                    [library dir])
  62
  63 GST_SET_ERROR_CFLAGS($GST_CVS)
  64
  65 dnl We disable static building for development, for time savings
  66 dnl *NOTE*: dnl this line before release, so release does static too
  67 dnl AM_DISABLE_STATIC
  68
  69 AC_HEADER_STDC([])
  70 AC_C_INLINE
  71
  72 dnl define correct errorlevel for debugging messages. We want to have GST_ERROR
  73 dnl messages printed when running cvs builds
  74 if test "x$GST_CVS" = "xyes"; then
  75   AC_DEFINE(GST_LEVEL_DEFAULT, GST_LEVEL_ERROR, [Default errorlevel to use])
  76 fi
  77
  78 dnl subsystems - can influence other decisions so needs to be high up
  79 dnl we need to do AM_CONDITIONAL them here for automake 1.6.x compatibility
  80 GST_CHECK_SUBSYSTEM_DISABLE(GST_DEBUG,[debugging subsystem])
  81 AM_CONDITIONAL(GST_DISABLE_GST_DEBUG, test "x$GST_DISABLE_GST_DEBUG" = "xyes")
  82 GST_CHECK_SUBSYSTEM_DISABLE(LOADSAVE,[pipeline XML load/save])
  83 AM_CONDITIONAL(GST_DISABLE_LOADSAVE, test "x$GST_DISABLE_LOADSAVE" = "xyes")
  84 GST_CHECK_SUBSYSTEM_DISABLE(PARSE,[command-line parser])
  85 AM_CONDITIONAL(GST_DISABLE_PARSE, test "x$GST_DISABLE_PARSE" = "xyes")
  86 GST_CHECK_SUBSYSTEM_DISABLE(TRACE,[tracing subsystem])
  87 AM_CONDITIONAL(GST_DISABLE_TRACE, test "x$GST_DISABLE_TRACE" = "xyes")
  88 GST_CHECK_SUBSYSTEM_DISABLE(ALLOC_TRACE,[allocation tracing])
  89 AM_CONDITIONAL(GST_DISABLE_ALLOC_TRACE, test "x$GST_DISABLE_ALLOC_TRACE" = "xyes")
  90 GST_CHECK_SUBSYSTEM_DISABLE(REGISTRY,[plugin registry])
  91 AM_CONDITIONAL(GST_DISABLE_REGISTRY, test "x$GST_DISABLE_REGISTRY" = "xyes")
  92 GST_CHECK_SUBSYSTEM_DISABLE(ENUMTYPES,[enum types])
  93 AM_CONDITIONAL(GST_DISABLE_ENUMTYPES, test "x$GST_DISABLE_ENUMTYPES" = "xyes")
  94 GST_CHECK_SUBSYSTEM_DISABLE(INDEX,[index])
  95 AM_CONDITIONAL(GST_DISABLE_INDEX, test "x$GST_DISABLE_INDEX" = "xyes")
  96 GST_CHECK_SUBSYSTEM_DISABLE(PLUGIN,[plugin])
  97 AM_CONDITIONAL(GST_DISABLE_PLUGIN, test "x$GST_DISABLE_PLUGIN" = "xyes")
  98 GST_CHECK_SUBSYSTEM_DISABLE(URI,[uri handlers])
  99 AM_CONDITIONAL(GST_DISABLE_URI, test "x$GST_DISABLE_URI" = "xyes")
 100
 101 dnl ##############################
 102 dnl # Do automated configuration #
 103 dnl ##############################
 104
 105 dnl Check for tools:
 106 dnl ================
 107
 108 dnl allow for different autotools
 109 AS_AUTOTOOLS_ALTERNATE()
 110
 111 dnl modify pkg-config path
 112 AC_ARG_WITH(pkg-config-path,
 113    AC_HELP_STRING([--with-pkg-config-path],
 114                   [colon-separated list of pkg-config(1) dirs]),
 115    [export PKG_CONFIG_PATH=${withval}])
 116
 117 GST_ARCH()
 118
 119 dnl ### Documentation checks
 120
 121 dnl Perl is used in building documentation
 122 AC_PATH_PROG(PERL_PATH, perl, no)
 123 if test x$PERL_PATH = xno; then
 124   AC_MSG_ERROR(Could not find perl)
 125 fi
 126
 127 GST_DOCBOOK_CHECK
 128 GTK_DOC_CHECK([1.3])
 129
 130 AC_PROG_AWK
 131
 132 dnl we require bison for building the parser
 133 dnl FIXME: check if AC_PROG_YACC is suitable here
 134 AC_PATH_PROG(BISON_PATH, bison, no)
 135 if test x$BISON_PATH = xno; then
 136   AC_MSG_ERROR(Could not find bison)
 137 fi
 138
 139 dnl check bison version
 140 AC_MSG_CHECKING([bison version])
 141
 142 if $BISON_PATH --version | head -n 1 | $AWK '{ if ($4 < 1.35) exit 1; else exit 0;}';
 143 then
 144   AC_MSG_RESULT([ok])
 145 else
 146   AC_MSG_RESULT([too old.])
 147   AC_MSG_ERROR([Your bison version is too old, v1.35 or later is required.])
 148 fi
 149
 150 dnl we require flex for building the parser
 151 dnl FIXME: check if AC_PROG_LEX is suitable here
 152 AC_PATH_PROG(FLEX_PATH, flex, no)
 153 if test x$FLEX_PATH = xno; then
 154   AC_MSG_ERROR(Could not find flex)
 155 fi
 156
 157 dnl check for large file support (affected
 158 dnl plugins must include config.h for this)
 159 AC_SYS_LARGEFILE
 160
 161 dnl check for mmap
 162 AC_FUNC_MMAP()
 163
 164 dnl check for makecontext and define HAVE_MAKECONTEXT if we have it
 165 AC_CHECK_MCSC()
 166 if test "$ac_cv_check_mcsc" = "yes"; then
 167   AC_DEFINE_UNQUOTED(HAVE_MAKECONTEXT, $HAVE_MAKECONTEXT,
 168                      [defined if we have makecontext ()])
 169 fi
 170
 171 dnl Check for a way to display the function name in debug output
 172 GST_CHECK_FUNCTION()
 173
 174 dnl check if we should use -Wa,-mregnames on PowerPC, so we can use
 175 dnl symbolic register names in inline asm
 176 if test x$HAVE_CPU_PPC = xyes ; then
 177   AS_COMPILER_FLAG(["-Wa,-mregnames"],
 178     [GST_INT_CFLAGS="$GST_INT_CFLAGS -Wa,-mregnames"],
 179     true)
 180 fi
 181
 182 AC_ARG_ENABLE(gcov,
 183   AC_HELP_STRING([--enable-gcov],[compile with coverage profiling instrumentation (gcc only)]),
 184   enable_gcov=$enableval,enable_gcov=no)
 185 if test x$enable_gcov = xyes ; then
 186   AS_COMPILER_FLAG(["-fprofile-arcs"],
 187     [GST_INT_CFLAGS="$GST_INT_CFLAGS -fprofile-arcs"],
 188     true)
 189   AS_COMPILER_FLAG(["-ftest-coverage"],
 190     [GST_INT_CFLAGS="$GST_INT_CFLAGS -ftest-coverage"],
 191     true)
 192   GST_INT_CFLAGS=`echo "$GST_INT_CFLAGS" | sed -e 's/-O[0-9]*//g'`
 193
 194   AC_DEFINE_UNQUOTED(GST_GCOV_ENABLED, 1, [Defined if gcov is enabled to force a rebuild due to config.h changing])
 195 fi
 196 AM_CONDITIONAL(GST_GCOV_ENABLED, test x$enable_gcov = xyes)
 197
 198 dnl Check for some compiler flags that optimize our code.
 199 if test "x$GCC" = xyes; then
 200   AS_COMPILER_FLAG(-fno-common,GST_INT_CFLAGS="$GST_INT_CFLAGS -fno-common",)
 201 fi
 202
 203 dnl HAVE_WIN32 currently means "disable POSIXisms".
 204 case "$host" in
 205   *-*-mingw*)
 206     AC_DEFINE_UNQUOTED(HAVE_WIN32, 1, [Defined if compiling for Windows])
 207     ;;
 208   *)
 209     ;;
 210 esac
 211
 212 GST_UNALIGNED_ACCESS()
 213 if test x${as_cv_unaligned_access} = xyes ; then
 214   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 1"
 215 else
 216   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 0"
 217 fi
 218 AC_SUBST(GST_HAVE_UNALIGNED_ACCESS_DEFINE)
 219
 220 dnl Check for essential libraries first:
 221 dnl ====================================
 222
 223 dnl === GLib 2 ===
 224 dnl Minimum required version of GLib2
 225 dnl required for compilation without warnings
 226 GLIB2_REQ="2.4"
 227 AC_SUBST(GLIB2_REQ)
 228
 229 dnl Check for glib2 with sugar on top
 230 PKG_CHECK_MODULES(GLIB2, glib-2.0 >= $GLIB2_REQ gobject-2.0 gthread-2.0 gmodule-2.0,HAVE_GLIB2=yes,HAVE_GLIB2=no)
 231 dnl for the poor souls who for example have glib in /usr/local
 232 AS_SCRUB_INCLUDE(GLIB2_CFLAGS)
 233 GLIB_LIBS=$GLIB2_LIBS
 234 GLIB_CFLAGS=$GLIB2_CFLAGS
 235 AC_SUBST(GLIB_LIBS)
 236 AC_SUBST(GLIB_CFLAGS)
 237
 238 if test "x$HAVE_GLIB2" = "xno"; then
 239   AC_MSG_ERROR([GStreamer requires GLib $GLIB2_REQ to compile.])
 240 fi
 241
 242 dnl Check for glib2 without extra fat, useful for the unversioned tool frontends
 243 PKG_CHECK_MODULES(GLIB_ONLY, glib-2.0 >= $GLIB2_REQ)
 244 AC_SUBST(GLIB_ONLY_CFLAGS)
 245 AC_SUBST(GLIB_ONLY_LIBS)
 246
 247 dnl === libxml 2 ===
 248 if test "x$GST_DISABLE_LOADSAVE" = "xyes" && test "x$GST_DISABLE_REGISTRY" = "xyes"
 249 then
 250   AC_MSG_NOTICE([Registry and load/save are disabled, not checking for libxml2])
 251 else
 252   dnl check for libxml2 with minimum req version
 253   GST_LIBXML2_CHECK(2.4.9)
 254 fi
 255
 256 dnl popt checks
 257 dnl FIXME: This test passes on popt 1.6.2, maybe earlier, but popt 1.6.2
 258 dnl        causes segfaults on gst_init. Write a working test if possible.
 259 GST_CHECK_LIBHEADER(POPT, popt, poptStrippedArgv,, popt.h, POPT_LIBS="-lpopt",
 260   AC_MSG_ERROR([popt 1.6.3 or newer is required to build gstreamer. You can
 261                 download the latest version from
 262                 ftp://ftp.rpm.org/pub/rpm/dist/])
 263 )
 264 AC_MSG_NOTICE(Checking for POPT_TABLEEND)
 265 AC_COMPILE_IFELSE([
 266 #include <popt.h>
 267 int main ()
 268 {
 269 #ifndef POPT_TABLEEND
 270 #error
 271 #else
 272   return 0;
 273 #endif
 274 }
 275 ],, [
 276   dnl it failed
 277   AC_MSG_ERROR([popt 1.6.3 or newer is required to build gstreamer. You can
 278                 download the latest version from
 279                 ftp://ftp.rpm.org/pub/rpm/dist/])
 280 ])
 281 AC_SUBST(POPT_CFLAGS)
 282 AC_SUBST(POPT_LIBS)
 283
 284 dnl Check for ucontext.h
 285 AC_CHECK_HEADER(ucontext.h, AC_DEFINE(HAVE_UCONTEXT_H, 1, [defined if we have ucontext.h]))
 286
 287 dnl check for "check", unit testing library/header
 288 AM_PATH_CHECK(0.9.2,
 289     [
 290         HAVE_CHECK=yes
 291         AC_MSG_NOTICE(CHECK_CFLAGS: $CHECK_CFLAGS)
 292         AC_MSG_NOTICE(CHECK_LIBS: $CHECK_LIBS)
 293     ],
 294     HAVE_CHECK=no)
 295 AM_CONDITIONAL(HAVE_CHECK, test "x$HAVE_CHECK" = "xyes")
 296
 297 dnl ######################################################################
 298 dnl # Check command line parameters, and set shell variables accordingly #
 299 dnl ######################################################################
 300
 301 dnl FIXME: simplify all this down using a few m4 macros
 302
 303 AC_ARG_ENABLE(fast-stack-trash,
 304 AC_HELP_STRING([--enable-fast-stack-trash],[use fast memory allocator (i586 or above)]),
 305 [case "${enableval}" in
 306   yes) USE_FAST_STACK_TRASH=yes;;
 307   noset) USE_FAST_STACK_TRASH=no;;
 308   no)  USE_FAST_STACK_TRASH=no;;
 309   *) AC_MSG_ERROR(bad value ${enableval} for --enable-atomic) ;;
 310 esac],
 311 [USE_FAST_STACK_TRASH=yes]) dnl Default value
 312
 313 AC_ARG_ENABLE(plugin-builddir,
 314 AC_HELP_STRING([--enable-plugin-builddir],[allow tests/demos to use non-installed plugins]),
 315 [case "${enableval}" in
 316   yes) PLUGINS_USE_BUILDDIR=yes ;;
 317   no)  PLUGINS_USE_BUILDDIR=no ;;
 318   *) AC_MSG_ERROR(bad value ${enableval} for --enable-plugin-builddir) ;;
 319 esac],
 320 [PLUGINS_USE_BUILDDIR=no]) dnl Default value
 321
 322 AC_ARG_ENABLE(profiling,
 323 AC_HELP_STRING([--enable-profiling],[adds -pg to compiler commandline, for profiling]),
 324 [case "${enableval}" in
 325   yes) USE_PROFILING=yes ;;
 326   no)  USE_PROFILING=no ;;
 327   *) AC_MSG_ERROR(bad value ${enableval} for --enable-profiling) ;;
 328 esac],
 329 [USE_PROFILING=no]) dnl Default value
 330
 331 dnl use a cache dir for storing element registry info.
 332 dnl default to building registry in the source tree if we are enabling plugin build dir
 333 if test "x$PLUGINS_USE_BUILDDIR" = "xyes"; then
 334   GST_CACHE_DIR=`pwd`
 335 else
 336   dnl ${localstatedir} points to PREFIX/var
 337   GST_CACHE_DIR=${localstatedir}/cache/gstreamer-$GST_MAJORMINOR
 338 fi
 339 AC_ARG_WITH(cachedir,
 340 AC_HELP_STRING([--with-cachedir],[specify path to use for plugin and command completion registries]),
 341 [case "${withval}" in
 342   yes) AC_MSG_ERROR(bad value ${withval} for --with-cachedir) ;;
 343   no) AC_MSG_ERROR(bad value ${withval} for --with-cachedir) ;;
 344   *) GST_CACHE_DIR="${withval}" ;;
 345 esac],
 346 [:]) dnl Default value
 347
 348 AS_AC_EXPAND(GST_CACHE_DIR, $GST_CACHE_DIR)
 349 AC_DEFINE_UNQUOTED(GST_CACHE_DIR, "$GST_CACHE_DIR", [Location of registry])
 350 AC_MSG_NOTICE(Using $GST_CACHE_DIR as registry cache dir)
 351
 352 dnl building of tests
 353 AC_ARG_ENABLE(tests,
 354 AC_HELP_STRING([--disable-tests],[disable building test apps]),
 355 [case "${enableval}" in
 356   yes) BUILD_TESTS=yes ;;
 357   no)  BUILD_TESTS=no ;;
 358   *) AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 359 esac],
 360 [BUILD_TESTS=yes]) dnl Default value
 361 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 362
 363 dnl tests known to fail
 364 AC_ARG_ENABLE(failing-tests,
 365 AC_HELP_STRING([--disable-failing-tests],[disable building tests known to fail]),
 366 [case "${enableval}" in
 367   yes) BUILD_FAILING_TESTS=yes ;;
 368   no)  BUILD_FAILING_TESTS=no ;;
 369   *) AC_MSG_ERROR(bad value ${enableval} for --disable-failing-tests) ;;
 370 esac],
 371 [BUILD_FAILING_TESTS=no]) dnl Default value
 372 AM_CONDITIONAL(BUILD_FAILING_TESTS, test "x$BUILD_FAILING_TESTS" = "xyes")
 373 if test x$BUILD_FAILING_TESTS = xyes; then
 374   AC_MSG_WARN([building tests known to fail, use --disable-failing-tests to disable])
 375 else
 376   AC_MSG_WARN([Sissy ! By asking to not build the tests known to fail, you hereby waive your right to customer support.  If you do not agree with this EULA, please press Ctrl-C before the next line is printed.  By allowing the next line to be printed, you expressly acknowledge your acceptance of this EULA.])
 377 fi
 378
 379 AC_ARG_ENABLE(examples,
 380 AC_HELP_STRING([--disable-examples],[disable building examples]),
 381 [case "${enableval}" in
 382   yes) BUILD_EXAMPLES=yes ;;
 383   no)  BUILD_EXAMPLES=no ;;
 384   *) AC_MSG_ERROR(bad value ${enableval} for --disable-examples) ;;
 385 esac],
 386 [BUILD_EXAMPLES=yes]) dnl Default value
 387 AM_CONDITIONAL(BUILD_EXAMPLES,      test "x$BUILD_EXAMPLES" = "xyes")
 388
 389 dnl poison destroyed objects
 390 AC_ARG_ENABLE(poisoning,
 391 AC_HELP_STRING([--enable-poisoning],[enable poisoning of deallocated objects]),
 392 [case "${enableval}" in
 393   yes) USE_POISONING=yes ;;
 394   no)  USE_POISONING=no ;;
 395   *) AC_MSG_ERROR(bad value ${enableval} for --enable-poisoning) ;;
 396 esac],
 397 [USE_POISONING=no]) dnl Default value
 398
 399 dnl Next, check for the optional components:
 400 dnl ========================================
 401
 402 dnl debugging stuff
 403 AC_ARG_ENABLE(debug,
 404 AC_HELP_STRING([--disable-debug],[disable addition of -g debugging info]),
 405 [case "${enableval}" in
 406   yes) USE_DEBUG=yes ;;
 407   no)  USE_DEBUG=no ;;
 408   *) AC_MSG_ERROR(bad value ${enableval} for --enable-debug) ;;
 409 esac],
 410 [USE_DEBUG=yes]) dnl Default value
 411
 412 dnl valgrind inclusion
 413 AC_ARG_ENABLE(valgrind,
 414 AC_HELP_STRING([--disable-valgrind],[disable run-time valgrind detection]),
 415 [case "${enableval}" in
 416   yes) USE_VALGRIND="$USE_DEBUG" ;;
 417   no)  USE_VALGRIND=no ;;
 418   *) AC_MSG_ERROR(bad value ${enableval} for --enable-valgrind) ;;
 419 esac],
 420 [USE_VALGRIND="$USE_DEBUG"]) dnl Default value
 421 VALGRIND_REQ="2.1"
 422 if test "x$USE_VALGRIND" = xyes; then
 423
 424   PKG_CHECK_MODULES(VALGRIND, valgrind > $VALGRIND_REQ, USE_VALGRIND="yes", USE_VALGRIND="no")
 425 fi
 426 if test "x$USE_VALGRIND" = xyes; then
 427   AC_DEFINE(HAVE_VALGRIND, 1, [Define if valgrind should be used])
 428   AC_MSG_NOTICE(Using extra code paths for valgrind)
 429 fi
 430 AC_SUBST(VALGRIND_CFLAGS)
 431 AC_SUBST(VALGRIND_LIBS)
 432
 433 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 434 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 435
 436 dnl ################################################
 437 dnl # Set defines according to variables set above #
 438 dnl ################################################
 439
 440
 441 dnl These should be "USE_*" instead of "HAVE_*", but some packages expect
 442 dnl HAVE_ and it is likely to be easier to stick with the old name
 443 if test "x$USE_FAST_STACK_TRASH" = xyes; then
 444   AC_DEFINE(USE_FAST_STACK_TRASH, 1, [Define if we should use i586 optimized stack functions])
 445 fi
 446
 447 if test "x$USE_POISONING" = xyes; then
 448   AC_DEFINE(USE_POISONING, 1, [Define if we should poison deallocated memory])
 449 fi
 450
 451 dnl test for sigaction()
 452 AC_CHECK_FUNC(sigaction,
 453    AC_DEFINE(HAVE_SIGACTION, 1,
 454              [Defined if we have sigaction ()]))
 455
 456 dnl test for register_printf_function
 457 AC_CHECK_FUNC(register_printf_function,
 458   [
 459     GST_PRINTF_EXTENSION_FORMAT_DEFINE="#define GST_PTR_FORMAT \"P\""
 460     AC_DEFINE(HAVE_PRINTF_EXTENSION, 1,
 461              [Defined if we have register_printf_function ()])
 462   ],
 463   GST_PRINTF_EXTENSION_FORMAT_DEFINE="#define GST_PTR_FORMAT \"p\""
 464 )
 465 AC_SUBST(GST_PRINTF_EXTENSION_FORMAT_DEFINE)
 466
 467 dnl test if we have dladdr(); we use it for debugging
 468 save_cflags="$CFLAGS"
 469 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 470 AC_CHECK_LIB(dl, dladdr,
 471    AC_DEFINE(HAVE_DLADDR, 1,
 472              [Defined if we have dladdr ()]))
 473 CFLAGS="$save_cflags"
 474
 475 if test "x$PLUGINS_USE_BUILDDIR" = xyes; then
 476   AC_DEFINE(PLUGINS_USE_BUILDDIR, 1, [Define if plugins should be loaded from the build tree - only developers should use this])
 477 fi
 478
 479 if test "x$USE_DEBUG" = xyes; then
 480    GST_INT_CFLAGS="$GST_INT_CFLAGS -g"
 481 fi
 482
 483 dnl #############################
 484 dnl # Set automake conditionals #
 485 dnl #############################
 486
 487 dnl These should be "USE_*" instead of "HAVE_*", but some packages expect
 488 dnl HAVE_ and it is likely to be easier to stick with the old name
 489 AM_CONDITIONAL(EXPERIMENTAL,        test "x$EXPERIMENTAL" = "yes")
 490 AM_CONDITIONAL(BROKEN,              test "x$BROKEN" = "yes")
 491 AM_CONDITIONAL(PLUGINS_USE_BUILDDIR,  test "x$PLUGINS_USE_BUILDDIR" = "xyes")
 492
 493
 494 dnl ############################
 495 dnl # Set up some more defines #
 496 dnl ############################
 497
 498 dnl set license and copyright notice
 499 AC_DEFINE(GST_LICENSE, "LGPL", [GStreamer license])
 500
 501 dnl package name in plugins
 502 AC_ARG_WITH(package-name,
 503 AC_HELP_STRING([--with-package-name],[specify package name to use in plugins]),
 504 [case "${withval}" in
 505   yes) AC_MSG_ERROR(bad value ${withval} for --with-package-name) ;;
 506   no) AC_MSG_ERROR(bad value ${withval} for --with-package-name) ;;
 507   *) GST_PACKAGE="${withval}" ;;
 508 esac],
 509 [
 510 dnl default value
 511 if test "x$GST_CVS" = "xyes"
 512 then
 513   dnl nano >= 1
 514   GST_PACKAGE="GStreamer CVS/prerelease"
 515 else
 516   GST_PACKAGE="GStreamer source release"
 517 fi
 518 ]
 519 )
 520 AC_MSG_NOTICE(Using $GST_PACKAGE as package name)
 521 AC_DEFINE_UNQUOTED(GST_PACKAGE, "$GST_PACKAGE", [package name in plugins])
 522
 523 dnl package origin URL
 524 AC_ARG_WITH(package-origin,
 525 AC_HELP_STRING([--with-package-origin],[specify package origin URL to use in plugins]),
 526 [case "${withval}" in
 527   yes) AC_MSG_ERROR(bad value ${withval} for --with-package-origin) ;;
 528   no) AC_MSG_ERROR(bad value ${withval} for --with-package-origin) ;;
 529   *) GST_ORIGIN="${withval}" ;;
 530 esac],
 531 [GST_ORIGIN="http://gstreamer.freedesktop.org/"]) dnl Default value
 532 AC_MSG_NOTICE(Using $GST_ORIGIN as package origin)
 533 AC_DEFINE_UNQUOTED(GST_ORIGIN, "$GST_ORIGIN", [package origin])
 534
 535 dnl Set location of plugin directory
 536 AS_AC_EXPAND(PLUGINS_DIR, ${libdir}/gstreamer-$GST_MAJORMINOR)
 537 AC_DEFINE_UNQUOTED(PLUGINS_DIR, "$PLUGINS_DIR", [Define the plugin directory])
 538 AC_SUBST(PLUGINS_DIR)
 539 AC_MSG_NOTICE([Using $PLUGINS_DIR as the plugin install location])
 540
 541 dnl Set location of uninstalled plugin directory
 542 PLUGINS_BUILDDIR=`pwd`
 543 AC_DEFINE_UNQUOTED(PLUGINS_BUILDDIR, "$PLUGINS_BUILDDIR", [Define the uninstalled plugin directory])
 544 AC_SUBST(PLUGINS_BUILDDIR)
 545
 546 dnl LDFLAGS modifier defining exported symbols from built objects
 547 EXPORT_LDFLAGS="-export-symbols-regex [_]*\(gst_\|Gst\|GST_\).*"
 548
 549 dnl GST_PKG_*:    the flags we use that are also used
 550 dnl               for external applications/.pc file
 551 dnl GST_LIB_*:    used for the main library
 552 dnl GST_OBJ_*:    the flags we use for all the objects internal to the core
 553 dnl GST_PLUGIN_*: additional flags we use for all plugins
 554
 555 dnl finalize _CFLAGS and _LIBS
 556 dnl flags exported for external applications and use in our pkg-config .pc files
 557 dnl since glib and xml are package deps, there's no need to include their cflags
 558 dnl in the pkg-config file
 559
 560 GST_PKG_DEPS="glib-2.0, gobject-2.0, gmodule-2.0, gthread-2.0"
 561 AC_SUBST(GST_PKG_CFLAGS)
 562 AC_SUBST(GST_PKG_LIBS)
 563 AC_SUBST(GST_PKG_DEPS)
 564
 565 dnl flags shared for all internal objects (core libs, elements, applications)
 566 dnl we disable deprecated internally
 567 dnl XML, GLib, popt, GST_INT, VALGRIND, and the right include for CFLAGS
 568 dnl no need to add XML, GLib, popt explicitly since libgstreamer pulls them in
 569 GST_INT_CFLAGS="$GLIB_CFLAGS $XML_CFLAGS $GST_PKG_CFLAGS \
 570  $GST_INT_CFLAGS \$(ERROR_CFLAGS) -DGST_DISABLE_DEPRECATED"
 571
 572 dnl Private vars for libgst only
 573 GST_LIB_CFLAGS="$GST_PKG_CFLAGS $GST_INT_CFLAGS \
 574   $VALGRIND_CFLAGS -I\$(top_srcdir)"
 575 GST_LIB_LIBS="$XML_LIBS $GLIB_LIBS -lpopt $GST_PKG_LIBS $LTLIBINTL $VALGRIND_LIBS"
 576 GST_LIB_LDFLAGS="$GST_LT_LDFLAGS -version-info $GST_LIBVERSION -no-undefined $EXPORT_LDFLAGS"
 577 AC_SUBST(GST_LIB_CFLAGS)
 578 AC_SUBST(GST_LIB_LIBS)
 579 AC_SUBST(GST_LIB_LDFLAGS)
 580
 581 dnl Vars for all internal objects built on libgstreamer
 582 GST_OBJ_CFLAGS="$GST_INT_CFLAGS -I\$(top_srcdir)/libs -I\$(top_srcdir)"
 583 GST_OBJ_LIBS="\$(top_builddir)/gst/libgstreamer-$GST_MAJORMINOR.la"
 584
 585 AC_SUBST(GST_OBJ_CFLAGS, "$GST_OBJ_CFLAGS")
 586 AC_SUBST(GST_OBJ_LIBS, "$GST_OBJ_LIBS")
 587
 588 dnl specific additional LDFLAGS for plugins
 589 GST_PLUGIN_LDFLAGS="-module -avoid-version -no-undefined $EXPORT_LDFLAGS"
 590 AC_SUBST(GST_PLUGIN_LDFLAGS, "$GST_PLUGIN_LDFLAGS")
 591
 592 plugindir="\$(libdir)/gstreamer-$GST_MAJORMINOR"
 593 AC_SUBST(plugindir)
 594
 595 dnl ##################################################
 596 dnl # deps for examples from manual                  #
 597 dnl ##################################################
 598
 599 PKG_CHECK_MODULES(LIBGNOMEUI, libgnomeui-2.0,
 600                   HAVE_LIBGNOMEUI="yes", HAVE_LIBGNOMEUI="no")
 601 AC_SUBST(LIBGNOMEUI_CFLAGS)
 602 AC_SUBST(LIBGNOMEUI_LIBS)
 603 AM_CONDITIONAL(HAVE_LIBGNOMEUI, test "x$HAVE_LIBGNOMEUI" = "xyes")
 604
 605 dnl ##################################################
 606 dnl # Prepare informative messages to display at end #
 607 dnl ##################################################
 608
 609 infomessages=
 610
 611 if test "x$PLUGINS_USE_BUILDDIR" = xyes; then
 612   infomessages="$infomessages
 613 *** Warning: You have configured using the --enable-plugin-builddir option.
 614
 615 This option is for development purposes only: binaries built with
 616 it should be used with code in the build tree only.  To build an
 617 installable version, use ./configure without the --enable-plugin-builddir
 618 option.  Note that the autogen.sh script supplies the plugin builddir
 619 option automatically -- run ./autogen.sh -- --disable-plugin-builddir to make
 620 an installable build.
 621
 622 "
 623 fi
 624
 625 dnl #########################
 626 dnl # Make the output files #
 627 dnl #########################
 628
 629 dnl libs/ext/Makefile
 630 dnl nothing there yet !
 631 AC_OUTPUT(
 632 Makefile
 633 include/Makefile
 634 gst/Makefile
 635 gst/gstconfig.h
 636 gst/gstversion.h
 637 gst/base/Makefile
 638 gst/check/Makefile
 639 gst/indexers/Makefile
 640 gst/elements/Makefile
 641 gst/parse/Makefile
 642 libs/Makefile
 643 libs/gst/Makefile
 644 libs/gst/controller/Makefile
 645 libs/gst/dataprotocol/Makefile
 646 po/Makefile.in
 647 check/Makefile
 648 tests/Makefile
 649 tests/instantiate/Makefile
 650 tests/memchunk/Makefile
 651 tests/muxing/Makefile
 652 tests/seeking/Makefile
 653 tests/sched/Makefile
 654 tests/threadstate/Makefile
 655 testsuite/Makefile
 656 testsuite/bytestream/Makefile
 657 testsuite/caps/Makefile
 658 testsuite/cleanup/Makefile
 659 testsuite/controller/Makefile
 660 testsuite/debug/Makefile
 661 testsuite/dlopen/Makefile
 662 testsuite/elements/Makefile
 663 testsuite/indexers/Makefile
 664 testsuite/negotiation/Makefile
 665 testsuite/pad/Makefile
 666 testsuite/parse/Makefile
 667 testsuite/plugin/Makefile
 668 testsuite/refcounting/Makefile
 669 testsuite/schedulers/Makefile
 670 testsuite/states/Makefile
 671 testsuite/threads/Makefile
 672 testsuite/trigger/Makefile
 673 examples/Makefile
 674 examples/controller/Makefile
 675 examples/cutter/Makefile
 676 examples/helloworld/Makefile
 677 examples/launch/Makefile
 678 examples/manual/Makefile
 679 examples/mixer/Makefile
 680 examples/metadata/Makefile
 681 examples/pingpong/Makefile
 682 examples/plugins/Makefile
 683 examples/pwg/Makefile
 684 examples/queue/Makefile
 685 examples/retag/Makefile
 686 examples/thread/Makefile
 687 examples/typefind/Makefile
 688 examples/xml/Makefile
 689 tools/Makefile
 690 common/Makefile
 691 common/m4/Makefile
 692 docs/Makefile
 693 docs/faq/Makefile
 694 docs/gst/Makefile
 695 docs/libs/Makefile
 696 docs/manual/Makefile
 697 docs/pwg/Makefile
 698 docs/xsl/Makefile
 699 docs/version.entities
 700 pkgconfig/Makefile
 701 stamp.h
 702 pkgconfig/gstreamer.pc
 703 pkgconfig/gstreamer-uninstalled.pc
 704 pkgconfig/gstreamer-base.pc
 705 pkgconfig/gstreamer-base-uninstalled.pc
 706 pkgconfig/gstreamer-check.pc
 707 pkgconfig/gstreamer-check-uninstalled.pc
 708 pkgconfig/gstreamer-controller.pc
 709 pkgconfig/gstreamer-controller-uninstalled.pc
 710 pkgconfig/gstreamer-dataprotocol.pc
 711 pkgconfig/gstreamer-dataprotocol-uninstalled.pc
 712 gstreamer.spec,
 713 echo "$infomessages", infomessages="$infomessages"
 714 )