configure.ac

   1 AC_PREREQ(2.62)
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, git and prerelease does Werror too
   6 dnl
   7 AC_INIT(GStreamer, 1.0.1.1,
   8     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
   9     gstreamer)
  10 AG_GST_INIT
  11
  12 dnl initialize automake (we require GNU make)
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.11 no-dist-gzip dist-xz tar-ustar])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([gst/gst.c])
  23
  24 dnl define the output header for config
  25 AM_CONFIG_HEADER([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output with automake >= 1.11
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  35   [AM_DEFAULT_VERBOSITY=1
  36    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  37
  38 dnl GStreamer versioning, this is mostly informational
  39 GST_VERSION_MAJOR=$PACKAGE_VERSION_MAJOR
  40 GST_VERSION_MINOR=$PACKAGE_VERSION_MINOR
  41 GST_VERSION_MICRO=$PACKAGE_VERSION_MICRO
  42 GST_VERSION_NANO=$PACKAGE_VERSION_NANO
  43 AC_SUBST(GST_VERSION_MAJOR)
  44 AC_SUBST(GST_VERSION_MINOR)
  45 AC_SUBST(GST_VERSION_MICRO)
  46 AC_SUBST(GST_VERSION_NANO)
  47
  48 dnl our libraries and install dirs use GST_API_VERSION in the filename
  49 dnl to allow side-by-side installation of different API versions
  50 GST_API_VERSION=1.0
  51 AC_SUBST(GST_API_VERSION)
  52 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  53   [GStreamer API Version])
  54
  55 dnl CURRENT, REVISION, AGE
  56 dnl - library source changed -> increment REVISION
  57 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  58 dnl - interfaces added -> increment AGE
  59 dnl - interfaces removed -> AGE = 0
  60 dnl sets GST_LT_LDFLAGS
  61 AS_LIBTOOL(GST, 1, 0, 1)
  62
  63 dnl *** autotools stuff ****
  64
  65 dnl allow for different autotools
  66 AS_AUTOTOOLS_ALTERNATE
  67
  68 dnl Add parameters for aclocal (keep in sync with Makefile.am)
  69 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  70
  71 dnl set up gettext
  72 dnl the version check needs to stay here because autopoint greps for it
  73 AM_GNU_GETTEXT_VERSION([0.17])
  74 AM_GNU_GETTEXT([external])
  75 AG_GST_GETTEXT([gstreamer-$GST_API_VERSION])
  76
  77 dnl *** check for arguments to configure ***
  78
  79 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  80
  81 dnl subsystems - can influence other decisions so needs to be high up
  82 dnl we need to AM_CONDITIONAL them here for automake 1.6.x compatibility
  83 AG_GST_CHECK_SUBSYSTEM_DISABLE(GST_DEBUG,[debugging subsystem])
  84 AM_CONDITIONAL(GST_DISABLE_GST_DEBUG, test "x$GST_DISABLE_GST_DEBUG" = "xyes")
  85 AG_GST_CHECK_SUBSYSTEM_DISABLE(PARSE,[command-line parser])
  86 AM_CONDITIONAL(GST_DISABLE_PARSE, test "x$GST_DISABLE_PARSE" = "xyes")
  87 if test "x$GST_DISABLE_PARSE" = xyes; then
  88   AC_DEFINE(GST_DISABLE_PARSE, 1,
  89     [Define if pipeline parsing code is disabled])
  90 fi
  91 AG_GST_CHECK_SUBSYSTEM_DISABLE(OPTION_PARSING,[option parsing when gst_init])
  92 AM_CONDITIONAL(GST_DISABLE_OPTION_PARSING, test "x$GST_DISABLE_OPTION_PARSING" = "xyes")
  93 if test "x$GST_DISABLE_OPTION_PARSING" = xyes; then
  94   AC_DEFINE(GST_DISABLE_OPTION_PARSING, 1,
  95     [Define if option parsing is disabled])
  96 fi
  97 AG_GST_CHECK_SUBSYSTEM_DISABLE(TRACE,[tracing subsystem])
  98 AM_CONDITIONAL(GST_DISABLE_TRACE, test "x$GST_DISABLE_TRACE" = "xyes")
  99 AG_GST_CHECK_SUBSYSTEM_DISABLE(ALLOC_TRACE,[allocation tracing])
 100 AM_CONDITIONAL(GST_DISABLE_ALLOC_TRACE, test "x$GST_DISABLE_ALLOC_TRACE" = "xyes")
 101 AG_GST_CHECK_SUBSYSTEM_DISABLE(REGISTRY,[plugin registry])
 102 AM_CONDITIONAL(GST_DISABLE_REGISTRY, test "x$GST_DISABLE_REGISTRY" = "xyes")
 103 dnl define a substitution to use in docs/gst/gstreamer.types
 104 if test "x$GST_DISABLE_REGISTRY" = "xyes"
 105 then
 106   GST_REGISTRY_DOC_TYPES="%"
 107 else
 108   GST_REGISTRY_DOC_TYPES=
 109 fi
 110 AC_SUBST(GST_REGISTRY_DOC_TYPES)
 111 AG_GST_CHECK_SUBSYSTEM_DISABLE(PLUGIN,[plugin])
 112 AM_CONDITIONAL(GST_DISABLE_PLUGIN, test "x$GST_DISABLE_PLUGIN" = "xyes")
 113
 114 AG_GST_ARG_DEBUG
 115 AG_GST_ARG_PROFILING
 116 AG_GST_ARG_VALGRIND
 117 AG_GST_ARG_GCOV
 118
 119 AG_GST_ARG_EXAMPLES
 120
 121 AG_GST_ARG_WITH_PKG_CONFIG_PATH
 122 AG_GST_ARG_WITH_PACKAGE_NAME
 123 AG_GST_ARG_WITH_PACKAGE_ORIGIN
 124
 125 AG_GST_PKG_CONFIG_PATH
 126
 127 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 128   ["${srcdir}/gstreamer.doap"],
 129   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 130
 131 dnl building of tests
 132 AC_ARG_ENABLE(tests,
 133   AC_HELP_STRING([--disable-tests], [disable building test apps]),
 134   [
 135     case "${enableval}" in
 136       yes) BUILD_TESTS=yes ;;
 137       no)  BUILD_TESTS=no ;;
 138       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 139     esac
 140   ],
 141 [BUILD_TESTS=yes]) dnl Default value
 142 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 143
 144 dnl tests known to fail
 145 AC_ARG_ENABLE(failing-tests,
 146   AC_HELP_STRING([--disable-failing-tests],
 147     [disable building tests known to fail]),
 148   [
 149     case "${enableval}" in
 150       yes) BUILD_FAILING_TESTS=yes ;;
 151       no)  BUILD_FAILING_TESTS=no ;;
 152       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-failing-tests) ;;
 153     esac
 154   ],
 155   [BUILD_FAILING_TESTS=no]) dnl Default value
 156 AM_CONDITIONAL(BUILD_FAILING_TESTS, test "x$BUILD_FAILING_TESTS" = "xyes")
 157 if test x$BUILD_FAILING_TESTS = xyes; then
 158   AC_MSG_WARN([building tests known to fail, use --disable-failing-tests to disable])
 159 else
 160   AC_MSG_WARN([Sissy ! By asking to not build the tests known to fail, you hereby waive your right to customer support.  If you do not agree with this EULA, please press Ctrl-C before the next line is printed.  By allowing the next line to be printed, you expressly acknowledge your acceptance of this EULA.])
 161 fi
 162
 163 dnl building of benchmarks
 164 AC_ARG_ENABLE(benchmarks,
 165   AC_HELP_STRING([--disable-benchmarks], [disable building benchmarks apps]),
 166   [
 167     case "${enableval}" in
 168       yes) BUILD_BENCHMARKS=yes ;;
 169       no)  BUILD_BENCHMARKS=no ;;
 170       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-benchmarks) ;;
 171     esac
 172   ],
 173 [BUILD_BENCHMARKS=yes]) dnl Default value
 174 AM_CONDITIONAL(BUILD_BENCHMARKS, test "x$BUILD_BENCHMARKS" = "xyes")
 175
 176 dnl building of tools
 177 AC_ARG_ENABLE(tools,
 178   AC_HELP_STRING([--disable-tools], [disable building tools]),
 179   [
 180     case "${enableval}" in
 181       yes) BUILD_TOOLS=yes ;;
 182       no)  BUILD_TOOLS=no ;;
 183       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tools) ;;
 184     esac
 185   ],
 186 [BUILD_TOOLS=yes]) dnl Default value
 187 AM_CONDITIONAL(BUILD_TOOLS, test "x$BUILD_TOOLS" = "xyes")
 188
 189 dnl poison destroyed objects
 190 AC_ARG_ENABLE(poisoning,
 191   AC_HELP_STRING([--enable-poisoning],
 192     [enable poisoning of deallocated objects]),
 193   [
 194     case "${enableval}" in
 195       yes) USE_POISONING=yes ;;
 196       no)  USE_POISONING=no ;;
 197       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-poisoning) ;;
 198     esac
 199   ],
 200   [USE_POISONING=no]) dnl Default value
 201 if test "x$USE_POISONING" = xyes; then
 202   AC_DEFINE(USE_POISONING, 1,
 203     [Define if we should poison deallocated memory])
 204 fi
 205
 206 dnl *** checks for platform ***
 207
 208 dnl * hardware/architecture *
 209
 210 dnl common/m4/gst-arch.m4
 211 dnl check CPU type
 212 AG_GST_ARCH
 213 dnl substitution for win32/common/config.h
 214 HOST_CPU=$host_cpu
 215 AC_SUBST(HOST_CPU)
 216
 217 dnl common/m4/gst-arch.m4
 218 dnl check for unaligned access
 219 AG_GST_UNALIGNED_ACCESS
 220 dnl create a configure variable for gst/gstconfig.h
 221 if test x${as_cv_unaligned_access} = xyes ; then
 222   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 1"
 223 else
 224   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 0"
 225 fi
 226 AC_SUBST(GST_HAVE_UNALIGNED_ACCESS_DEFINE)
 227
 228 dnl check for platform specific settings
 229 AG_GST_PLATFORM
 230
 231 dnl * software *
 232
 233 dnl check for large file support
 234 dnl affected plugins must include config.h
 235 AC_SYS_LARGEFILE
 236
 237 dnl *** checks for programs ***
 238
 239 dnl find a compiler
 240 AC_PROG_CC
 241 AC_PROG_CC_STDC
 242
 243 dnl check if the compiler supports '-c' and '-o' options
 244 AM_PROG_CC_C_O
 245
 246 dnl find an assembler
 247 AM_PROG_AS
 248
 249 dnl determine if c++ is available on this system
 250 AC_PROG_CXX
 251 dnl CXX may be set to some default even if no c++ compiler is available
 252 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 253 AC_LANG_PUSH([C++])
 254 AC_TRY_COMPILE([ class Foo { int bar; };], , working_cxx=yes, working_cxx=no)
 255 AC_LANG_POP([C++])
 256 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 257 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 258
 259 dnl Perl is used in building documentation and in the version checks
 260 AC_PATH_PROG(PERL_PATH, perl, no)
 261 if test x$PERL_PATH = xno; then
 262   AC_MSG_ERROR(Could not find perl)
 263 fi
 264
 265 dnl we require flex and bison for building the parser
 266 if test "x$GST_DISABLE_PARSE" != xyes; then
 267   AG_GST_BISON_CHECK
 268   AG_GST_FLEX_CHECK
 269 fi
 270
 271 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 272 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 273
 274 dnl check for gobject-introspection
 275 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 276
 277 dnl check for documentation tools
 278 AG_GST_DOCBOOK_CHECK
 279 GTK_DOC_CHECK([1.12])
 280 AS_PATH_PYTHON([2.1])
 281 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 282
 283 dnl *** checks for libraries ***
 284
 285 dnl check for libm, for sin()
 286 LT_LIB_M
 287 AC_SUBST(LIBM)
 288
 289 dnl *** checks for header files ***
 290
 291 dnl check if we have ANSI C header files
 292 AC_HEADER_STDC
 293
 294 dnl Check for ucontext.h
 295 AC_CHECK_HEADERS([ucontext.h], [], [], [AC_INCLUDES_DEFAULT])
 296
 297 dnl Check for sys/socket.h
 298 AC_CHECK_HEADERS([sys/socket.h], [HAVE_SYS_SOCKET_H=yes], [HAVE_SYS_SOCKET_H=no], [AC_INCLUDES_DEFAULT])
 299 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 300
 301 dnl check for sys/times.h for tests/examples/adapter/
 302 AC_CHECK_HEADERS([sys/times.h], [HAVE_SYS_TIMES_H=yes], [HAVE_SYS_TIME_H=no], [AC_INCLUDES_DEFAULT])
 303 AC_CHECK_HEADERS([unistd.h], [HAVE_UNISTD_H=yes], [HAVE_UNISTD_H=no], [AC_INCLUDES_DEFAULT])
 304 AM_CONDITIONAL(HAVE_SYS_TIMES_H_AND_UNISTD_H, test "x$HAVE_SYS_TIMES_H" = "xyes" -a "x$HAVE_UNISTD_H" = "xyes")
 305
 306 dnl Check for process.h for getpid() on win32
 307 AC_CHECK_HEADERS([process.h], [], [], [AC_INCLUDES_DEFAULT])
 308
 309 dnl Check for sys/utsname.h for uname
 310 AC_CHECK_HEADERS([sys/utsname.h], [], [], [AC_INCLUDES_DEFAULT])
 311
 312 dnl Check for stdio_ext.f for __fbufsize
 313 AC_CHECK_HEADERS([stdio_ext.h], [], [], [AC_INCLUDES_DEFAULT])
 314
 315 dnl check for pthreads
 316 AC_CHECK_HEADERS([pthread.h], [HAVE_PTHREAD_H=yes], [HAVE_PTHREAD_H=no], [AC_INCLUDES_DEFAULT])
 317 AM_CONDITIONAL(HAVE_PTHREAD_H, test "x$HAVE_PTHREAD_H" = "xyes")
 318
 319 dnl check for sys/prctl for setting thread name on Linux
 320 AC_CHECK_HEADERS([sys/prctl.h], [], [], [AC_INCLUDES_DEFAULT])
 321
 322 dnl Check for valgrind.h
 323 dnl separate from HAVE_VALGRIND because you can have the program, but not
 324 dnl the dev package
 325 AC_CHECK_HEADERS([valgrind/valgrind.h], [], [], [AC_INCLUDES_DEFAULT])
 326
 327 dnl used in gst/gstpoll.c
 328 AC_CHECK_HEADERS([winsock2.h], [HAVE_WINSOCK2_H=yes], [HAVE_WINSOCK2_H=no], [AC_INCLUDES_DEFAULT])
 329 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 330 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 331   WIN32_LIBS="-lws2_32"
 332   AC_SUBST(WIN32_LIBS)
 333 fi
 334
 335 dnl check for GMP/GSL, used by the gst_util_uint64_scale unit test only
 336 if test "x$BUILD_TESTS" = "xyes"; then
 337   AG_GST_CHECK_LIBHEADER(GMP, gmp,
 338                          __gmpz_init_set_d, ,
 339                          gmp.h,
 340                          GMP_LIBS="-lgmp"
 341                          AC_SUBST(GMP_LIBS)
 342                          AC_DEFINE(HAVE_GMP, [1],[Have GMP library]))
 343   AG_GST_CHECK_LIBHEADER(GSL, gsl,
 344                          gsl_rng_uniform_int, -lgslcblas,
 345                          gsl/gsl_rng.h,
 346                          GSL_LIBS="-lgsl -lgslcblas"
 347                          AC_SUBST(GSL_LIBS)
 348                          AC_DEFINE(HAVE_GSL, [1],[Have GSL library]))
 349 fi
 350
 351 dnl *** checks for types/defines ***
 352
 353 dnl *** checks for structures ***
 354
 355 dnl *** checks for compiler characteristics ***
 356
 357 dnl check if the compiler supports __uint128_t (gcc)
 358 dnl Actually check for 128-bit division, since that's what we use
 359 dnl uint128_t for.
 360 AC_CACHE_CHECK(for __uint128_t, gst_cv_uint128_t,
 361     AC_TRY_LINK([ ], [
 362       static __uint128_t v1 = 100;
 363       static __uint128_t v2 = 10;
 364       static __uint128_t u;
 365       u = v1 / v2;
 366     ], [
 367       gst_cv_uint128_t=yes
 368     ], [
 369       gst_cv_uint128_t=no
 370     ])
 371 )
 372 if test x$gst_cv_uint128_t = xyes; then
 373   AC_DEFINE(HAVE_UINT128_T, 1, [Have __uint128_t type])
 374 fi
 375
 376 dnl *** checking for tm_gmtoff ***
 377 AC_MSG_CHECKING([for tm_gmtoff])
 378 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 379         #include <time.h>
 380         int main(void) {
 381           struct tm t;
 382           t.tm_gmtoff = 0;
 383           exit(0);
 384         }]])],
 385   [have_tm_gmtoff=yes
 386    AC_DEFINE(HAVE_TM_GMTOFF,1,[Have tm_gmtoff field in struct tm])],
 387   [have_tm_gmtoff=no],
 388   [have_tm_gmtoff="no (cross compiling)"])
 389 AC_MSG_RESULT($have_tm_gmtoff)
 390
 391
 392 dnl *** checks for library functions ***
 393
 394 AC_CHECK_FUNCS([gmtime_r])
 395 AC_CHECK_FUNCS([localtime_r])
 396 AC_CHECK_FUNCS([sigaction])
 397
 398 dnl check for fseeko()
 399 AC_FUNC_FSEEKO
 400 dnl check for ftello()
 401 AC_CHECK_FUNCS([ftello])
 402
 403 AC_CHECK_FUNCS([fgetpos])
 404 AC_CHECK_FUNCS([fsetpos])
 405
 406 dnl check for poll(), ppoll() and pselect()
 407 AC_CHECK_HEADERS([sys/poll.h], [], [], [AC_INCLUDES_DEFAULT])
 408 AC_CHECK_HEADERS([poll.h], [], [], [AC_INCLUDES_DEFAULT])
 409 AC_CHECK_FUNCS([poll])
 410 AC_CHECK_FUNCS([ppoll])
 411 AC_CHECK_FUNCS([pselect])
 412
 413 dnl ****************************************
 414 dnl *** GLib POLL* compatibility defines ***
 415 dnl ****************************************
 416
 417 AC_MSG_CHECKING([for broken poll])
 418 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 419         #include <stdlib.h>
 420         #include <fcntl.h>
 421         #ifdef HAVE_SYS_POLL_H
 422         #include <sys/poll.h>
 423         #endif
 424         #ifdef HAVE_POLL_H
 425         #include <poll.h>
 426         #endif
 427         int main(void) {
 428           struct pollfd fds[1];
 429           int fd;
 430           fd = open("/dev/null", 1);
 431           fds[0].fd = fd;
 432           fds[0].events = POLLIN;
 433           fds[0].revents = 0;
 434           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
 435                 exit(1);  /* Does not work for devices -- fail */
 436           }
 437           exit(0);
 438         }]])],
 439   [broken_poll=no],
 440   [broken_poll=yes
 441    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
 442   [broken_poll="no (cross compiling)"])
 443 AC_MSG_RESULT($broken_poll)
 444
 445 dnl check for mmap()
 446 AC_FUNC_MMAP
 447 AM_CONDITIONAL(HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 448
 449 dnl check for posix_memalign(), getpagesize()
 450 AC_CHECK_FUNCS([posix_memalign])
 451 AC_CHECK_FUNCS([getpagesize])
 452
 453 dnl Check for POSIX timers
 454 AC_CHECK_FUNCS(clock_gettime, [], [
 455   AC_CHECK_LIB(rt, clock_gettime, [
 456     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 457     LIBS="$LIBS -lrt"
 458   ])
 459 ])
 460
 461 AC_CACHE_CHECK(for posix timers, gst_cv_posix_timers,
 462     AC_TRY_COMPILE([
 463 #include <time.h>
 464 #ifdef HAVE_UNISTD_H
 465 #include <unistd.h>
 466 #endif
 467     ], [
 468 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 469 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 470 #endif
 471     ], [
 472       gst_cv_posix_timers=yes
 473     ], [
 474       gst_cv_posix_timers=no
 475     ])
 476 )
 477
 478 if test "$gst_cv_posix_timers" = "yes"; then
 479   AC_DEFINE(HAVE_POSIX_TIMERS,1,[Have posix timers])
 480   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 1"
 481 else
 482   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 0"
 483 fi
 484 AC_SUBST(GST_HAVE_POSIX_TIMERS_DEFINE)
 485 AM_CONDITIONAL(GST_HAVE_POSIX_TIMERS, test "$gst_cv_posix_timers" = "yes")
 486
 487 AC_CACHE_CHECK(for monotonic clock, gst_cv_monotonic_clock,
 488     AC_TRY_COMPILE([
 489 #include <time.h>
 490 #ifdef HAVE_UNISTD_H
 491 #include <unistd.h>
 492 #endif
 493     ], [
 494 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 495 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 496 #endif
 497     ], [
 498       gst_cv_monotonic_clock=yes
 499     ], [
 500       gst_cv_monotonic_clock=no
 501     ])
 502 )
 503
 504 if test "$gst_cv_monotonic_clock" = "yes"; then
 505   AC_DEFINE(HAVE_MONOTONIC_CLOCK,1,[Have a monotonic clock])
 506   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 1"
 507 else
 508   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 0"
 509 fi
 510 AC_SUBST(GST_HAVE_MONOTONIC_CLOCK_DEFINE)
 511 AM_CONDITIONAL(GST_HAVE_MONOTONIC_CLOCK, test "$gst_cv_monotonic_clock" = "yes")
 512
 513 dnl Check for a way to display the function name in debug output
 514 AG_GST_CHECK_FUNCTION
 515
 516 dnl test for register_printf_specifier or register_printf_function
 517 AC_CHECK_FUNCS([register_printf_specifier register_printf_function],
 518     [HAVE_PRINTF_EXTENSION=yes])
 519
 520 if test "$HAVE_PRINTF_EXTENSION" = yes; then
 521   GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE="#define GST_PTR_FORMAT \"P\""
 522   GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE="#define GST_SEGMENT_FORMAT \"Q\""
 523   GST_USING_PRINTF_EXTENSION_DEFINE="#define GST_USING_PRINTF_EXTENSION"
 524   AC_DEFINE(HAVE_PRINTF_EXTENSION, 1,
 525       [Defined if we have printf specifier extensions available])
 526 else
 527     GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE="#define GST_PTR_FORMAT \"p\""
 528     GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE="#define GST_SEGMENT_FORMAT \"p\""
 529     GST_USING_PRINTF_EXTENSION_DEFINE="#undef GST_USING_PRINTF_EXTENSION"
 530 fi
 531 AC_SUBST(GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE)
 532 AC_SUBST(GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE)
 533 AC_SUBST(GST_USING_PRINTF_EXTENSION_DEFINE)
 534
 535 dnl test if we have dladdr(); we use it for debugging; see gst/gstinfo.c
 536 save_cflags="$CFLAGS"
 537 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 538 AC_CHECK_LIB(dl, dladdr,
 539    AC_DEFINE(HAVE_DLADDR, 1, [Defined if we have dladdr ()])
 540    LIBS="$LIBS -ldl")
 541 CFLAGS="$save_cflags"
 542
 543 dnl *** checks for dependency libraries ***
 544
 545 dnl GLib
 546 GLIB_REQ=2.32.0
 547 AG_GST_GLIB_CHECK([$GLIB_REQ])
 548
 549 dnl Check for documentation xrefs
 550 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 551 AC_SUBST(GLIB_PREFIX)
 552
 553 dnl building of unit test libraries
 554 AC_ARG_ENABLE(check,
 555   AC_HELP_STRING([--disable-check], [disable building unit test libraries]),
 556   [
 557     case "${enableval}" in
 558       yes) BUILD_CHECK=yes ;;
 559       no)  BUILD_CHECK=no ;;
 560       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-check) ;;
 561     esac
 562   ], [
 563     dnl Default value
 564     case $host_os in
 565       mingw* | msvc* | mks*) BUILD_CHECK=no ;;
 566       *) BUILD_CHECK=yes ;;
 567     esac
 568 ])
 569 dnl bit of a misnomer, but keep the conditional named like this so we don't
 570 dnl have to change too much elsewhere
 571 AM_CONDITIONAL(HAVE_CHECK, test "x$BUILD_CHECK" = "xyes")
 572
 573 dnl configure the desired memory alignment
 574 AC_ARG_WITH([memory-alignment],
 575   AS_HELP_STRING([--with-memory-alignment],[8,N,malloc,pagesize (default is 32)]),
 576   [
 577     if test "x$withval" = "xyes"
 578     then
 579       AC_DEFINE(MEMORY_ALIGNMENT, 32, [Memory alignment to use])
 580     else
 581       case "${withval}" in
 582         malloc) AC_DEFINE(MEMORY_ALIGNMENT_MALLOC, 1, [Memory alignment by malloc default]) ;;
 583         pagesize)  AC_DEFINE(MEMORY_ALIGNMENT_PAGESIZE, 1, [Memory alignment by pagesize]) ;;
 584         *)   AC_DEFINE_UNQUOTED(MEMORY_ALIGNMENT, ${withval}, [Memory alignment to use]) ;;
 585       esac
 586     fi
 587   ], [
 588     AC_DEFINE(MEMORY_ALIGNMENT_MALLOC, 1, [Memory alignment by malloc default])
 589   ]
 590 )
 591
 592 dnl Check for -Bsymbolic-functions linker flag used to avoid
 593 dnl intra-library PLT jumps, if available.
 594 AC_ARG_ENABLE(Bsymbolic,
 595               [AC_HELP_STRING([--disable-Bsymbolic],
 596                               [avoid linking with -Bsymbolic])],,
 597               [SAVED_LDFLAGS="${LDFLAGS}"
 598                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 599                LDFLAGS=-Wl,-Bsymbolic-functions
 600                AC_TRY_LINK([], [int main (void) { return 0; }],
 601                            AC_MSG_RESULT(yes)
 602                            enable_Bsymbolic=yes,
 603                            AC_MSG_RESULT(no)
 604                            enable_Bsymbolic=no)
 605                LDFLAGS="${SAVED_LDFLAGS}"])
 606
 607
 608 dnl *** set variables based on configure arguments
 609
 610 dnl set license and copyright notice
 611 GST_LICENSE="LGPL"
 612 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 613 AC_SUBST(GST_LICENSE)
 614
 615 dnl define LIBDIR, GST_DATADIR so we can inform people where we live
 616 AS_AC_EXPAND(LIBDIR, $libdir)
 617 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [library dir])
 618 AS_AC_EXPAND(DATADIR, $datadir)
 619 AC_DEFINE_UNQUOTED(GST_DATADIR, "$DATADIR", [data dir])
 620
 621 dnl set location of plugin directory
 622 AG_GST_SET_PLUGINDIR
 623
 624 GST_PKG_DEPS="glib-2.0, gobject-2.0, gmodule-no-export-2.0, gthread-2.0"
 625 AC_SUBST(GST_PKG_DEPS)
 626
 627 dnl make sure it doesn't complain about unused variables if debugging is disabled
 628 NO_WARNINGS=""
 629 if test "x${GST_DISABLE_GST_DEBUG}" = "xyes"; then
 630   NO_WARNINGS="-Wno-unused"
 631 fi
 632
 633 dnl define an ERROR_CFLAGS Makefile variable
 634 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [-Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef -Wwrite-strings -Wformat-nonliteral -Wformat-security -Wold-style-definition -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return -Wno-multichar -Wnested-externs $NO_WARNINGS])
 635
 636 dnl define correct level for debugging messages
 637 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 638
 639 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 640
 641 dnl Overview:
 642 dnl GST_OPTION_CFLAGS:  common cflags for profiling, debugging, errors, ...
 643 dnl GST_ALL_*:          vars shared by all built objects
 644 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 645 dnl GST_OBJ_*:          additional vars to link to the core library
 646 dnl                     include GST_ALL_*
 647 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 648 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 649
 650 dnl GST_OPTION_CFLAGS
 651 if test "x$USE_DEBUG" = xyes; then
 652    PROFILE_CFLAGS="-g"
 653 fi
 654 AC_SUBST(PROFILE_CFLAGS)
 655
 656 # GST_DISABLE_DEPRECATED: hide the visibility of deprecated
 657 # functionality from the API that gstreamer uses
 658 # GST_REMOVE_DEPRECATED: don't compile deprecated functionality (breaks ABI)
 659 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 660   dnl Define _only_ when compiling from git (not for pre-releases or releases)
 661   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 662 else
 663   DEPRECATED_CFLAGS=""
 664 fi
 665 AC_SUBST(DEPRECATED_CFLAGS)
 666
 667 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time via e.g.
 668 dnl make DEPRECATED_CFLAGS=''
 669 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 670 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 671 GST_OPTION_CFLAGS="$GST_OPTION_CFLAGS"
 672 GST_OPTION_CXXFLAGS="$GST_OPTION_CXXFLAGS"
 673 AC_SUBST(GST_OPTION_CFLAGS)
 674 AC_SUBST(GST_OPTION_CXXFLAGS)
 675
 676 dnl GST_ALL_*
 677 dnl vars common to for all internal objects (core libs, elements, applications)
 678 dnl CFLAGS:
 679 dnl - src and build dirs need to be added because every piece that gets built
 680 dnl   will need the GStreamer source and generated headers
 681 dnl LIBS: XML doesn't need to be added because we don't explicitly use symbols
 682 dnl       from LibXML except for in the core library
 683 GST_ALL_CXXFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir)/libs -I\$(top_builddir) $GLIB_CFLAGS \$(GLIB_EXTRA_CFLAGS) $XML_CFLAGS \$(GST_OPTION_CXXFLAGS) \$(ERROR_CXXFLAGS)"
 684 GST_ALL_CFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir)/libs -I\$(top_builddir) $GLIB_CFLAGS \$(GLIB_EXTRA_CFLAGS) $XML_CFLAGS \$(GST_OPTION_CFLAGS) \$(ERROR_CFLAGS)"
 685
 686 dnl FIXME: check if LTLIBINTL is needed everywhere
 687 dnl I presume it is given that it contains the symbols that _() stuff maps to
 688 GST_ALL_LIBS="$GLIB_LIBS $LTLIBINTL \$(GCOV_LIBS)"
 689
 690 dnl LDFLAGS really should only contain flags, not libs - they get added before
 691 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 692 GST_ALL_LDFLAGS="-no-undefined"
 693 if test "x${enable_Bsymbolic}" = "xyes"; then
 694   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 695 fi
 696
 697 AC_SUBST(GST_ALL_CFLAGS)
 698 AC_SUBST(GST_ALL_CXXFLAGS)
 699 AC_SUBST(GST_ALL_LIBS)
 700 AC_SUBST(GST_ALL_LDFLAGS)
 701
 702 dnl GST_LIB_LDFLAGS
 703 dnl linker flags shared by all libraries
 704 dnl LDFLAGS modifier defining exported symbols from built libraries
 705 GST_LIB_LDFLAGS="-export-symbols-regex \^[_]?\(gst_\|Gst\|GST_\).*"
 706 AC_SUBST(GST_LIB_LDFLAGS)
 707
 708 dnl GST_OBJ_*
 709 dnl default vars for all internal objects built on libgstreamer
 710 dnl includes GST_ALL_*
 711 GST_OBJ_CFLAGS="\$(GST_ALL_CFLAGS)"
 712 GST_OBJ_CXXFLAGS="\$(GST_ALL_CXXFLAGS)"
 713 GST_OBJ_LIBS="\$(top_builddir)/gst/libgstreamer-$GST_API_VERSION.la \$(GST_ALL_LIBS)"
 714 AC_SUBST(GST_OBJ_CFLAGS)
 715 AC_SUBST(GST_OBJ_CXXFLAGS)
 716 AC_SUBST(GST_OBJ_LIBS)
 717
 718 dnl GST_PLUGIN_LDFLAGS
 719 dnl LDFLAGS for plugins; includes GST_ALL_LDFLAGS
 720 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
 721 AC_SUBST(GST_PLUGIN_LDFLAGS, "$GST_PLUGIN_LDFLAGS")
 722
 723 dnl plugin scanner locations
 724 AS_AC_EXPAND(GST_PLUGIN_SCANNER_INSTALLED,${libexecdir}/gstreamer-$GST_API_VERSION/gst-plugin-scanner)
 725 AC_DEFINE_UNQUOTED(GST_PLUGIN_SCANNER_INSTALLED,
 726     "$GST_PLUGIN_SCANNER_INSTALLED", [location of the installed gst-plugin-scanner])
 727 AC_SUBST(GST_PLUGIN_SCANNER_INSTALLED)
 728
 729 dnl things for our internal libcheck (must be called even if building
 730 dnl libcheck is disabled because it defines conditionals)
 731 AG_GST_CHECK_CHECKS()
 732
 733 AC_CONFIG_FILES(
 734 Makefile
 735 gst/Makefile
 736 gst/gstconfig.h
 737 gst/gstversion.h
 738 gst/parse/Makefile
 739 libs/Makefile
 740 libs/gst/Makefile
 741 libs/gst/base/Makefile
 742 libs/gst/check/Makefile
 743 libs/gst/check/libcheck/Makefile
 744 libs/gst/check/libcheck/check.h
 745 libs/gst/controller/Makefile
 746 libs/gst/helpers/Makefile
 747 libs/gst/net/Makefile
 748 plugins/Makefile
 749 plugins/elements/Makefile
 750 po/Makefile.in
 751 tests/Makefile
 752 tests/benchmarks/Makefile
 753 tests/check/Makefile
 754 tests/misc/Makefile
 755 tests/examples/Makefile
 756 tests/examples/adapter/Makefile
 757 tests/examples/controller/Makefile
 758 tests/examples/stepping/Makefile
 759 tests/examples/helloworld/Makefile
 760 tests/examples/launch/Makefile
 761 tests/examples/manual/Makefile
 762 tests/examples/memory/Makefile
 763 tests/examples/metadata/Makefile
 764 tests/examples/queue/Makefile
 765 tests/examples/streams/Makefile
 766 tests/examples/typefind/Makefile
 767 tools/Makefile
 768 common/Makefile
 769 common/m4/Makefile
 770 docs/Makefile
 771 docs/design/Makefile
 772 docs/faq/Makefile
 773 docs/gst/Makefile
 774 docs/gst/gstreamer.types
 775 docs/libs/Makefile
 776 docs/plugins/Makefile
 777 docs/manual/Makefile
 778 docs/pwg/Makefile
 779 docs/slides/Makefile
 780 docs/xsl/Makefile
 781 docs/version.entities
 782 m4/Makefile
 783 pkgconfig/Makefile
 784 stamp.h
 785 pkgconfig/gstreamer.pc
 786 pkgconfig/gstreamer-uninstalled.pc
 787 pkgconfig/gstreamer-base.pc
 788 pkgconfig/gstreamer-base-uninstalled.pc
 789 pkgconfig/gstreamer-check.pc
 790 pkgconfig/gstreamer-check-uninstalled.pc
 791 pkgconfig/gstreamer-controller.pc
 792 pkgconfig/gstreamer-controller-uninstalled.pc
 793 pkgconfig/gstreamer-net.pc
 794 pkgconfig/gstreamer-net-uninstalled.pc
 795 gstreamer.spec
 796 )
 797
 798 dnl Create the config.h file for Visual Studio builds
 799 dnl Beware of spaces and /'s in some of the shell variable contents.
 800 sed \
 801     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 802     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 803     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 804     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 805     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 806     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
 807     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 808     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 809     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
 810     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 811     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 812     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 813     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 814     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 815     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 816     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 817     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 818     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 819     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
 820     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 821     -e 's/.* MEMORY_ALIGNMENT_MALLOC/#define MEMORY_ALIGNMENT_MALLOC 1/' \
 822     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 823     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 824     -e 's/.* PACKAGE$/#define PACKAGE "gstreamer"/' \
 825     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 826     -e 's/.* PACKAGE_NAME$/#define PACKAGE_NAME "'$PACKAGE_NAME'"/' \
 827     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 828     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 829     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 830     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-1.0"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-1.0"\n#endif/' \
 831     -e 's/.* GST_PLUGIN_SCANNER_INSTALLED$/#define GST_PLUGIN_SCANNER_INSTALLED LIBDIR "\\\\gst-plugin-scanner"/' \
 832     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 833     config.h.in >win32/common/config.h-new
 834
 835 AC_OUTPUT
 836
 837 dnl negate for output
 838 if test "x${GST_DISABLE_GST_DEBUG}" = "xno"; then enable_gst_debug="yes"; fi
 839 if test "x${GST_DISABLE_PARSE}" = "xno"; then enable_parse="yes"; fi
 840 if test "x${GST_DISABLE_OPTION_PARSING}" = "xno"; then enable_option_parsing="yes"; fi
 841 if test "x${GST_DISABLE_TRACE}" = "xno"; then enable_trace="yes"; fi
 842 if test "x${GST_DISABLE_ALLOC_TRACE}" = "xno"; then enable_alloc_trace="yes"; fi
 843 if test "x${GST_DISABLE_PLUGIN}" = "xno"; then enable_plugin="yes"; fi
 844 if test "x${GST_DISABLE_REGISTRY}" = "xno"; then enable_registry="yes"; fi
 845
 846 echo "
 847
 848 Configuration
 849         Version                    : ${VERSION}
 850         Source code location       : ${srcdir}
 851         Prefix                     : ${prefix}
 852         Compiler                   : ${CC}
 853         Package name               : ${GST_PACKAGE_NAME}
 854         Package origin             : ${GST_PACKAGE_ORIGIN}
 855
 856         Documentation (manuals)    : ${enable_docbook}
 857         Documentation (API)        : ${enable_gtk_doc}
 858
 859         Debug Logging              : ${enable_gst_debug}
 860         Command-line parser        : ${enable_parse}
 861         Option parsing in gst_init : ${enable_option_parsing}
 862         Tracing subsystem          : ${enable_trace}
 863         Allocation tracing         : ${enable_alloc_trace}
 864         Plugin registry            : ${enable_registry}
 865         Plugin support             : ${enable_plugin}
 866         Unit testing support       : ${BUILD_CHECK}
 867
 868         Debug                      : ${USE_DEBUG}
 869         Profiling                  : ${USE_PROFILING}
 870
 871         Building benchmarks        : ${BUILD_BENCHMARKS}
 872         Building examples          : ${BUILD_EXAMPLES}
 873         Building test apps         : ${BUILD_TESTS}
 874         Building tests that fail   : ${BUILD_FAILING_TESTS}
 875         Building tools             : ${BUILD_TOOLS}
 876 "