configure.ac

   1 AC_PREREQ(2.60)
   2 dnl initialize autoconf
   3 dnl when going to/from release please set the nano (fourth number) right !
   4 dnl releases only do Wall, cvs and prerelease does Werror too
   5 AC_INIT(Gst-RTSP, 0.10.8.1,
   6     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
   7     gst-rtsp)
   8 AG_GST_INIT
   9
  10 dnl initialize automake
  11 AM_INIT_AUTOMAKE([-Wno-portability 1.10])
  12
  13 dnl define PACKAGE_VERSION_* variables
  14 AS_VERSION
  15
  16 dnl check if this is a release version
  17 AS_NANO(GST_GIT="no", GST_GIT="yes")
  18
  19 dnl can autoconf find the source ?
  20 AC_CONFIG_SRCDIR([gst/rtsp-server/rtsp-server.c])
  21
  22 dnl define the output header for config
  23 AM_CONFIG_HEADER([config.h])
  24
  25 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  26 AM_MAINTAINER_MODE
  27
  28 dnl sets host_* variables
  29 AC_CANONICAL_HOST
  30
  31 dnl use pretty build output with automake >= 1.11
  32 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  33   [AM_DEFAULT_VERBOSITY=1
  34    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  35
  36 dnl our libraries and install dirs use major.minor as a version
  37 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  38 dnl we override it here if we need to for the release candidate of new series
  39 GST_MAJORMINOR=0.10
  40 AC_SUBST(GST_MAJORMINOR)
  41
  42 AM_PROG_LIBTOOL
  43
  44 dnl *** required versions of GStreamer stuff ***
  45 GST_REQ=0.10.31
  46 GSTPB_REQ=0.10.31
  47
  48 dnl *** autotools stuff ****
  49
  50 dnl allow for different autotools
  51 AS_AUTOTOOLS_ALTERNATE
  52
  53 dnl Add parameters for aclocal
  54 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  55 AC_CONFIG_MACRO_DIR([m4])
  56
  57 dnl set up gettext
  58 dnl the version check needs to stay here because autopoint greps for it
  59 AM_GNU_GETTEXT_VERSION([0.17])
  60 AM_GNU_GETTEXT([external])
  61 AG_GST_GETTEXT([gstreamer-$GST_MAJORMINOR])
  62
  63 dnl *** check for arguments to configure ***
  64
  65 AG_GST_ARG_DEBUG
  66 AG_GST_ARG_VALGRIND
  67 AG_GST_ARG_GCOV
  68 AG_GST_ARG_WITH_PACKAGE_NAME
  69 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  70
  71 AG_GST_PKG_CONFIG_PATH
  72
  73 dnl *** checks for platform ***
  74
  75 dnl * hardware/architecture *
  76
  77 dnl *** checks for programs ***
  78
  79 dnl find a compiler
  80 AC_PROG_CC
  81 AM_PROG_CC_C_O
  82
  83 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
  84 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
  85
  86 dnl check for gobject-introspection
  87 GOBJECT_INTROSPECTION_CHECK([0.6.3])
  88
  89 dnl check for documentation tools
  90 AG_GST_DOCBOOK_CHECK
  91 GTK_DOC_CHECK([1.3])
  92
  93 dnl check for python
  94 AM_PATH_PYTHON
  95 AC_MSG_CHECKING(for python >= 2.3)
  96 prog="
  97 import sys, string
  98 minver = (2,3,0,'final',0)
  99 if sys.version_info < minver:
 100   sys.exit(1)
 101 sys.exit(0)"
 102
 103 if $PYTHON -c "$prog" 1>&AC_FD_CC 2>&AC_FD_CC
 104 then
 105   HAVE_PYTHON=yes
 106   AC_MSG_RESULT(okay)
 107 else
 108   HAVE_PYTHON=no
 109   AC_MSG_RESULT(no python)
 110 fi
 111
 112 AM_CHECK_PYTHON_HEADERS([HAVE_PYTHON_HEADERS=yes],[HAVE_PYTHON_HEADERS=no])
 113
 114 dnl check for pygobject (optional, used in the bindings)
 115 PYGOBJECT_REQ=2.11.2
 116 PKG_CHECK_MODULES(PYGOBJECT, pygobject-2.0 >= $PYGOBJECT_REQ,
 117   [HAVE_PYGOBJECT="yes"], [HAVE_PYGOBJECT="no"])
 118 AC_SUBST(PYGOBJECT_CFLAGS)
 119
 120 dnl check for gst-python
 121 PKG_CHECK_MODULES(PYGST, gst-python-0.10,
 122   [HAVE_PYGST="yes"], [HAVE_PYGST="no"])
 123
 124 if test "x$HAVE_PYGST" = "xyes"; then
 125   PYGST_DEFSDIR=`pkg-config gst-python-0.10 --variable=defsdir`
 126 fi
 127 AC_SUBST(PYGST_DEFSDIR, $PYGST_DEFSDIR)
 128
 129 if test \
 130     "x$HAVE_PYTHON" = "xyes" -a \
 131     "x$HAVE_PYTHON_HEADERS" = "xyes" -a \
 132     "x$HAVE_PYGOBJECT" = "xyes" -a \
 133     "x$HAVE_PYGST" = "xyes"; then
 134   HAVE_PYTHON_BINDINGS="yes"
 135 else
 136   HAVE_PYTHON_BINDINGS="no"
 137 fi
 138
 139 AM_CONDITIONAL(WITH_PYTHON, [test "x$HAVE_PYTHON_BINDINGS" = "xyes"])
 140
 141 dnl Check for Vala
 142 AC_ARG_ENABLE([vala],
 143   AC_HELP_STRING([--enable-vala],[enable Vala bindings (default=yes)]),
 144   [case "${enableval}" in
 145     yes) enable_vala=yes ;;
 146     no)  enable_vala=no ;;
 147     *) AC_MSG_ERROR(bad value ${enableval} for --enable-vala) ;;
 148    esac
 149   ],
 150   [enable_vala=yes]) dnl Default value
 151 AM_CONDITIONAL(WITH_VALA, [test "x$enable_vala" = "xyes"])
 152
 153 dnl *** checks for libraries ***
 154
 155 dnl *** checks for header files ***
 156
 157 dnl *** checks for types/defines ***
 158
 159 dnl *** checks for structures ***
 160
 161 dnl *** checks for compiler characteristics ***
 162
 163 dnl *** checks for library functions ***
 164
 165 dnl *** checks for dependancy libraries ***
 166
 167 dnl GLib is required (GStreamer is ok with GLib-2.8, but we want at least 2.10)
 168 GLIB_REQ=2.10.0
 169 AC_SUBST([GLIB_REQ])
 170 AG_GST_GLIB_CHECK([$GLIB_REQ])
 171
 172 dnl checks for gstreamer
 173 dnl uninstalled is selected preferentially -- see pkg-config(1)
 174 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], [yes])
 175
 176 GST_TOOLS_DIR=`$PKG_CONFIG --variable=toolsdir gstreamer-$GST_MAJORMINOR`
 177 if test -z $GST_TOOLS_DIR; then
 178   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 179 fi
 180 AC_SUBST(GST_TOOLS_DIR)
 181
 182 GST_PLUGINS_DIR=`$PKG_CONFIG gstreamer-$GST_MAJORMINOR --variable pluginsdir`
 183 AC_SUBST(GST_PLUGINS_DIR)
 184 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 185
 186 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], [yes])
 187
 188 AG_GST_CHECK_GST_PLUGINS_BASE($GST_MAJORMINOR, [$GSTPB_REQ], [yes])
 189 GSTPB_PLUGINS_DIR=`$PKG_CONFIG gstreamer-plugins-base-$GST_MAJORMINOR --variable pluginsdir`
 190 AC_SUBST(GSTPB_PLUGINS_DIR)
 191 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 192
 193 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 194
 195 dnl FIXME: get rid of this by making sure gstreamer-check brings it in
 196 dnl check for "check", unit testing library/header
 197 AM_PATH_CHECK(0.9.2, HAVE_CHECK=yes, HAVE_CHECK=no)
 198 AM_CONDITIONAL(HAVE_CHECK, test "x$HAVE_CHECK" = "xyes")
 199
 200 dnl *** set variables based on configure arguments ***
 201
 202 dnl set license and copyright notice
 203 GST_LICENSE="LGPL"
 204 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 205 AC_SUBST(GST_LICENSE)
 206
 207 dnl set location of plugin directory
 208 AG_GST_SET_PLUGINDIR
 209
 210 dnl define an ERROR_CFLAGS Makefile variable
 211 AG_GST_SET_ERROR_CFLAGS($GST_GIT)
 212
 213 dnl define correct level for debugging messages
 214 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 215
 216 dnl used in examples
 217 AG_GST_DEFAULT_ELEMENTS
 218
 219 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 220
 221 dnl Overview:
 222 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 223 dnl GST_*:              flags shared by built objects to link against GStreamer
 224 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 225 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 226 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 227 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 228
 229 dnl GST_OPTION_CFLAGS
 230 if test "x$USE_DEBUG" = xyes; then
 231    PROFILE_CFLAGS="-g"
 232 fi
 233 AC_SUBST(PROFILE_CFLAGS)
 234
 235 DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 236 AC_SUBST(DEPRECATED_CFLAGS)
 237
 238 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 239 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 240 AC_SUBST(GST_OPTION_CFLAGS)
 241
 242 dnl FIXME: do we want to rename to GST_ALL_* ?
 243 dnl prefer internal headers to already installed ones
 244 dnl add GST_OPTION_CFLAGS, but overridable
 245 GST_CFLAGS="$GST_CFLAGS \$(GST_OPTION_CFLAGS)"
 246 AC_SUBST(GST_CFLAGS)
 247 AC_SUBST(GST_LIBS)
 248
 249 dnl GST_ALL_*
 250 dnl vars common to for all internal objects (core libs, elements, applications)
 251 dnl CFLAGS:
 252 dnl - src and build dirs need to be added because every piece that gets built
 253 dnl   will need the GStreamer source and generated headers
 254 GST_ALL_CFLAGS="-I\$(top_srcdir) -I\$(top_builddir) $GST_CFLAGS \$(GST_OPTION_CFLAGS)"
 255 AC_SUBST([GST_ALL_CFLAGS])
 256
 257 dnl FIXME: check if LTLIBINTL is needed everywhere
 258 dnl I presume it is given that it contains the symbols that _() stuff maps to
 259 GST_ALL_LIBS="$GST_LIBS $LTLIBINTL \$(GCOV_LIBS)"
 260 AC_SUBST([GST_ALL_LIBS])
 261
 262 dnl LDFLAGS really should only contain flags, not libs - they get added before
 263 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 264 GST_ALL_LDFLAGS="-no-undefined"
 265 AC_SUBST(GST_ALL_LDFLAGS)
 266
 267 dnl GST_OBJ_*
 268 dnl default vars for all internal objects built on libgstphonon
 269 dnl includes GST_ALL_*
 270 GST_OBJ_CFLAGS="\$(GST_ALL_CFLAGS)"
 271 AC_SUBST([GST_OBJ_CFLAGS])
 272 GST_OBJ_LIBS="\$(top_builddir)/gst-phonon/libgstphonon.la \$(GST_ALL_LIBS)"
 273 AC_SUBST([GST_OBJ_LIBS])
 274
 275 dnl this really should only contain flags, not libs - they get added before
 276 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 277
 278 dnl *** output files ***
 279
 280 dnl keep this alphabetic per directory, please
 281 AC_CONFIG_FILES([
 282 Makefile
 283 gst-rtsp.spec
 284 common/Makefile
 285 common/m4/Makefile
 286 gst/Makefile
 287 gst/rtsp-server/Makefile
 288 examples/Makefile
 289 tests/Makefile
 290 bindings/Makefile
 291 bindings/python/Makefile
 292 bindings/python/codegen/Makefile
 293 bindings/vala/Makefile
 294 pkgconfig/Makefile
 295 pkgconfig/gst-rtsp-server.pc
 296 pkgconfig/gst-rtsp-server-uninstalled.pc
 297 docs/Makefile
 298 docs/version.entities
 299 docs/libs/Makefile
 300 ])
 301 AC_OUTPUT
 302
 303 echo "
 304
 305 Configuration
 306         Version                    : ${VERSION}
 307         Source code location       : ${srcdir}
 308         Prefix                     : ${prefix}
 309         Compiler                   : ${CC}
 310         Vala bindings              : ${enable_vala}
 311         Python bindings:           : ${HAVE_PYTHON_BINDINGS}
 312
 313 Gst-rtsp-server configured. Type 'make' to build.
 314 "